home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / XMODEM / XMLO-10.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  8KB  |  236 lines
  1.  
  2. ; XMLO-10.ASM - XMODEMxx overlay file for the Lobo Max-80 computer  06/15/84
  3. ;
  4. ; This file adapts XMODEMxx to the Lobo Max-80 computer.  To use, edit
  5. ; any options desired into XMODEMxx.ASM, then assemble (can use ASM.COM)
  6. ; and load to get XMODEMxx.COM.  Then edit this file as needed (check
  7. ; the CONOUT routine if you want to locally see file transfer time and
  8. ; the record count while programs are being sent or insure that USECON
  9. ; on ByeII or BYE3 is set YES.)  Then assemble (can use ASM.COM) and
  10. ; merge the .HEX file with XMODEMxx.COM by using MLOAD (part of the
  11. ; MEX modem program distribution and available separately from most
  12. ; RCP/M's):
  13. ;
  14. ;   MLOAD XMODEM.COM=XMODEMxx.COM,XMLO-10.HEX
  15. ;
  16. ; This will create XMODEM.COM, the ready-to-use program.
  17. ;
  18. ;=======================================================================
  19. ;
  20. ; 06/15/84  Rewritten and renamed    - Peter N. Glaskowsky
  21. ; 01/01/84  Updated to XMODEM84        - Irv Hoff
  22. ; 04/04/83  Updated to XMODEM74        - Irv Hoff
  23. ; 03/27/83  Updated to XMODEM73        - Irv Hoff
  24. ; 03/17/83  Updated to XMODEM72        - Irv Hoff
  25. ; 03/15/83  Updated to XMODEM71        - Irv Hoff
  26. ;
  27. ; 03/07/83  Added instructions on how to adapt this file to XMODEM70.COM.
  28. ;        Standardized the format.  Added automatic MSPEED from "BYE"
  29. ;        program.  Added CONOUT information.  Adapted from XM70PMMI.
  30. ;                    - Irv Hoff
  31. ;
  32. ;=======================================================================
  33. ; 
  34. ; Define True and False
  35. ;
  36. YES:      EQU    0FFH
  37. NO:      EQU    0
  38. ;
  39. ;=======================================================================
  40. ;
  41. ; Modem & Data Equates
  42. ;
  43. MODDATP:  EQU    0F7E4H        ;data in port for kaypro computers
  44. MODCTLP:  EQU    MODDATP+1    ;control/status port
  45. MODSNDB:  EQU    04H        ;bit to test for send
  46. MODSNDR:  EQU    04H        ;value when ready
  47. MODRCVB:  EQU    01H        ;bit to test for receive
  48. MODRCVR:  EQU    01H        ;value when ready
  49. MODDCDB:  EQU    08H        ;carrier detect bit
  50. MODDCDA:  EQU    08H        ;value when active
  51. MODPARE:  EQU    10H        ;value for parity error
  52. MODOVRE:  EQU    20H        ;value for overrun error
  53. MODFRME:  EQU    40H        ;value for framing error
  54. MODRESI:  EQU   10H        ;reset external status/interrupts
  55. MODERES:  EQU   30H        ;error reset
  56. ;
  57. ;
  58. LSPEED:      EQU    YES        ;true if using by2-17ks or any bye2-xx
  59.                 ;false if using 'SPEED' manual selection
  60. MSPEED:      EQU    3CH        ;location of baud rate factor (set by
  61. ;                ;'BYE')  SET LOCATION IN 'BYE' TO AGREE.
  62. ;                ;3DH AND 3EH OFTEN USED BY NEWER VER-
  63. ;                ;SIONS OF 'ZCPR'.
  64. XSPEED:      EQU    5        ;speed for file time transfer without
  65. ;                ;AUTO-SET.  USE ONE OF THE FOLLOWING:
  66. ;                ;0=110 1=300 2=450 3=600 4=710 5=1200
  67. BASE:      EQU    100H        ;start of cp/m normal program area
  68. ;
  69. ;=======================================================================
  70. ;
  71. ; Jump table: The jump table must be in exactly the same sequence as the
  72. ; one in XMODEM.
  73. ;
  74.       ORG    BASE+3        ;start after 'JMP BEGIN'
  75. ;
  76. CONOUT:   JMP    0C7AEH        ;must be 00000h if not used, see below
  77.                 ;shown for Max-80 with NZCPR V2.1
  78. PMINIT:      JMP    MINIT        ;initialization routine (if needed)
  79. PUNINIT:  JMP    UNINIT        ;undo whatever 'MINIT' did (or return)
  80. PSENDR:      JMP    SENDR        ;send character (via pop psw)
  81. PCAROK:      JMP    CAROK        ;test for carrier
  82. PMDIN:      JMP    MDIN        ;receive data byte
  83. PGETCHR:  JMP    GETCHR        ;get character from modem
  84. PRCVRDY:  JMP    RCVRDY        ;check receive ready
  85. PSNDRDY:  JMP    SNDRDY        ;check send ready
  86. PSPEED:      JMP    SPEED        ;get speed value for file transfer time
  87. PEXTRA1:  JMP    EXTRA1        ;extra for custom routine
  88. PEXTRA2:  JMP    EXTRA2        ;extra for custom routine
  89. PEXTRA3:  JMP    EXTRA3        ;extra for custom routine
  90. ;
  91. ;=======================================================================
  92. ;
  93. ; -- To Display the Record Count on the CRT During Program Transfers --
  94. ;
  95. ;    The CRTOUT routine below may be used if you know the ports used
  96. ; by your CRT for status and data.  (Cannot be used with memory mapped
  97. ; displays.)  If using the CRTOUT routine, skip rest of this discussion.
  98. ;
  99. ;    This one addition requires some work on the part of the user.
  100. ; When "BYE" is added, CP/M is normally moved lower to accomodate the
  101. ; new program above CP/M.  Whenever BYE is called to enable the RCPM
  102. ; capability, it steals some of the addresses contained in the BIOS jump
  103. ; vector table.  In order to display on the CRT during program transfers
  104. ; you need to get into the BIOS console output routine directly, else
  105. ; what is being displayed also tries to go out the modem.  This is a big
  106. ; NO-NO at that time.  (This cannot be done automatically by XMODEM,
  107. ; since BYE has already taken the address we need to find, by the time
  108. ; XMODEM is automatically activated by the remote station.)
  109. ;
  110. ;    So with the disk containing BYE, but prior to activating BYE, do
  111. ; this:
  112. ;        1) Cold reboot to move CP/M (and BIOS) to the new area
  113. ;            needed when BYE is activated on the same disk.
  114. ;        2) Use DDT and dump the area from 0000H to 0002H.  This
  115. ;                   gives the warm reboot address in BIOS.
  116. ;        3) Add 9 Bytes to that address to get your console out-
  117. ;             put jump vector.
  118. ;        4) Pick off the address contained in the jump vector and
  119. ;             install that in "CONOUT", below.  Example of one
  120. ;             system in use:
  121. ;
  122. ;            FIRST, COLD REBOOT WITH DISK CONTAINING "BYE"
  123. ;
  124. ;      0000  C3 03 E0    (location of warm reboot on disk with BYE
  125. ;
  126. ;            PRIOR TO ACTIVATING BYE BUT ON SAME DISK
  127. ;
  128. ;      E003  C3 E9 E0    (BIOS warm reboot jump vector on this disk)
  129. ;      E006  C3 00 E9    (BIOS get console status routine)
  130. ;      E009  C3 B7 E1    (BIOS console input routine)
  131. ;      E00C  C3 D4 E1    (BIOS console output routine)
  132. ;
  133. ;        The address we need is thus E1D4.  Put that below, in
  134. ;        our example it would be:    CONOUT   JMP   0E1D4H
  135. ;
  136. ;
  137. ;    CONOUT:      JMP    00000H    ;If you wish to show the record count
  138. ;                ;during program transfer, fill in this
  139. ;                ;address at 'CONOUT' above.
  140. ;
  141. ;                    - Irv Hoff
  142. ;
  143. ;=======================================================================
  144. ;
  145. ; ---> CAROK - check for presence of carrier.  RET with Z = carrier on
  146. ;
  147. CAROK:
  148.     MVI    A,MODRESI    ;reset external status/interrupts
  149.     STA    MODCTLP
  150.     LDA    MODCTLP        ;get status
  151.     ANI    MODDCDB        ;get carrier detect bit
  152.     CPI    MODDCDA        ;test bit
  153.     RET
  154. ;
  155. ;=======================================================================
  156. ;
  157. EXTRA1:    RET            ;for later use
  158. EXTRA2:    RET            ;for later use
  159. EXTRA3:    RET            ;for later use
  160. ;
  161. ;=======================================================================
  162. ;
  163. ; ---> GETCHR - get a character, same as MDIN
  164. ; ---> MDIN - - get a character, same as GETCHR
  165. ;
  166. GETCHR:
  167. MDIN:    LDA    MODDATP        ;get character from data in port
  168.     RET
  169. ;
  170. ;=======================================================================
  171. ;
  172. MINIT:    RET            ;no initialization required
  173. ;
  174. ;=======================================================================
  175. ;
  176. ; ---> RCVRDY - check receive ready.  RET with Z = character available.
  177. ;            Return with error code in A-reg.
  178. ;
  179. RCVRDY:    LDA    MODCTLP        ;get modem status
  180.     PUSH    B        ;save scratch register
  181.     PUSH    PSW
  182.     MVI    A,1+MODRESI    ;select read register 1
  183.     STA    MODCTLP
  184.     LDA    MODCTLP        ;read the error status
  185.     ANI    MODFRME+MODOVRE+MODPARE
  186.     MOV    B,A        ;save it for a moment
  187.     MVI    A,MODERES
  188.     STA    MODCTLP        ;do an error reset command
  189.     POP    PSW        ;now get modem status back
  190.     ANI    MODRCVB        ;isolate ready bit
  191.     CPI    MODRCVR        ;test it
  192.     MOV    A,B        ;get the error code char. back
  193.     POP    B
  194.     RET
  195. ;
  196. ;=======================================================================
  197. ;
  198. ; ---> SENDR - send character
  199. ;
  200. SENDR:    POP    PSW        ;get the character back
  201.     STA    MODDATP        ;send it to the modem output
  202.     RET
  203. ;
  204. ;=======================================================================
  205. ;
  206. ; ---> SNDRDY - check if ready to send.
  207. ;
  208. SNDRDY:    LDA    MODCTLP        ;get status byte
  209.     ANI    MODSNDB        ;isolate ready bit
  210.     CPI    MODSNDR        ;ready to send?
  211.     RET
  212. ;
  213. ;=======================================================================
  214. ;
  215. ; ---> SPEED - sets the time shown for program transfer.
  216. ;
  217. SPEED:    EQU    $
  218. ;
  219.      IF    LSPEED
  220.     LDA    MSPEED        ;get index for baud rate from 'BYE'
  221.      ENDIF
  222. ;
  223.      IF     NOT LSPEED
  224.     MVI    A,XSPEED    ;get index for baud rate from 'XSPEED'
  225.      ENDIF
  226. ;
  227.     RET
  228. ;
  229. ;=======================================================================
  230. ;
  231. UNINIT:    RET            ;not initialized, so no 'UN-INITIALIZE'
  232. ;
  233. ;=======================================================================
  234. ;
  235.     END
  236.