home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / XMODEM / XMKP-1.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  8KB  |  242 lines
  1.  
  2. ; XMKP-1.ASM - XMODEMxx overlay file for Kaypro computers  01/01/83
  3. ;
  4. ; This file adapts XMODEMxx to the Kaypro computer.  To use, first edit
  5. ; any options desired into XMODEMxx.ASM, then assemble (can use ASM.COM)
  6. ; and load to get XMODEMxx.COM.  Then edit this file as needed (check
  7. ; the CONOUT routine if you want to locally see file transfer time and
  8. ; the record count while programs are being sent or insure that USECON
  9. ; on ByeII or BYE3 is set YES.)  Then assemble (can use ASM.COM) and
  10. ; merge via DDT or SID:
  11. ;
  12. ;    B>DDT XMODEMxx.COM
  13. ;    DDT VERS 2.2
  14. ;    NEXT  PC
  15. ;    1100 0100
  16. ;    -IXKP-1.HEX        (note the 'I' command)
  17. ;    -R            ('R' loads in the .HEX file)
  18. ;    NEXT  PC
  19. ;    1100 0000
  20. ;    -G0            (return to CP/M)
  21. ;    B>SAVE 16 XMODEMxx.COM  (now have a modified .COM file)
  22. ;
  23. ; NOTE: Save 21 (rather than 16) if LOGCAL is YES.
  24. ;
  25. ;=======================================================================
  26. ;
  27. ; 01/01/84  Updated to XMODEM84        - Irv Hoff
  28. ; 04/04/83  Updated to XMODEM74        - Irv Hoff
  29. ; 03/27/83  Updated to XMODEM73        - Irv Hoff
  30. ; 03/17/83  Updated to XMODEM72        - Irv Hoff
  31. ; 03/15/83  Updated to XMODEM71        - Irv Hoff
  32. ;
  33. ; 03/07/83  Added instructions on how to adapt this file to XMODEM70.COM.
  34. ;        Standardized the format.  Added automatic MSPEED from "BYE"
  35. ;        program.  Added CONOUT information.  Adapted from XM70PMMI.
  36. ;                    - Irv Hoff
  37. ;
  38. ;=======================================================================
  39. ; 
  40. ; Define True and False
  41. ;
  42. YES:      EQU    0FFH
  43. NO:      EQU    0
  44. ;
  45. ;=======================================================================
  46. ;
  47. ; Modem & Data Equates
  48. ;
  49. MODDATP:  EQU    04H        ;data in port for kaypro computers
  50. MODCTLP:  EQU    MODDATP+2    ;control/status port
  51. MODSNDB:  EQU    04H        ;bit to test for send
  52. MODSNDR:  EQU    04H        ;value when ready
  53. MODRCVB:  EQU    01H        ;bit to test for receive
  54. MODRCVR:  EQU    01H        ;value when ready
  55. MODDCDB:  EQU    08H        ;carrier detect bit
  56. MODDCDA:  EQU    08H        ;value when active
  57. MODPARE:  EQU    10H        ;value for parity error
  58. MODOVRE:  EQU    20H        ;value for overrun error
  59. MODFRME:  EQU    40H        ;value for framing error
  60. MODRESI:  EQU   10H        ;reset external status/interrupts
  61. MODERES:  EQU   30H        ;error reset
  62. ;
  63. ;
  64. LSPEED:      EQU    YES        ;true if using by2-17ks or any bye2-xx
  65.                 ;false if using 'SPEED' manual selection
  66. MSPEED:      EQU    3CH        ;location of baud rate factor (set by
  67. ;                ;'BYE')  SET LOCATION IN 'BYE' TO AGREE.
  68. ;                ;3DH AND 3EH OFTEN USED BY NEWER VER-
  69. ;                ;SIONS OF 'ZCPR'.
  70. XSPEED:      EQU    1        ;speed for file time transfer without
  71. ;                ;AUTO-SET.  USE ONE OF THE FOLLOWING:
  72. ;                ;0=110 1=300 2=450 3=600 4=710 5=1200
  73. BASE:      EQU    100H        ;start of cp/m normal program area
  74. ;
  75. ;=======================================================================
  76. ;
  77. ; Jump table: The jump table must be in exactly the same sequence as the
  78. ; one in XMODEM.
  79. ;
  80.       ORG    BASE+3        ;start after 'JMP BEGIN'
  81. ;
  82. CONOUT:   JMP    0EBFDH        ;must be 00000h if not used, see below
  83.                 ;shown for kaypro-10 with cp/m 2.2d
  84. PMINIT:      JMP    MINIT        ;initialization routine (if needed)
  85. PUNINIT:  JMP    UNINIT        ;undo whatever 'MINIT' did (or return)
  86. PSENDR:      JMP    SENDR        ;send character (via pop psw)
  87. PCAROK:      JMP    CAROK        ;test for carrier
  88. PMDIN:      JMP    MDIN        ;receive data byte
  89. PGETCHR:  JMP    GETCHR        ;get character from modem
  90. PRCVRDY:  JMP    RCVRDY        ;check receive ready
  91. PSNDRDY:  JMP    SNDRDY        ;check send ready
  92. PSPEED:      JMP    SPEED        ;get speed value for file transfer time
  93. PEXTRA1:  JMP    EXTRA1        ;extra for custom routine
  94. PEXTRA2:  JMP    EXTRA2        ;extra for custom routine
  95. PEXTRA3:  JMP    EXTRA3        ;extra for custom routine
  96. ;
  97. ;=======================================================================
  98. ;
  99. ; -- To Display the Record Count on the CRT During Program Transfers --
  100. ;
  101. ;    The CRTOUT routine below may be used if you know the ports used
  102. ; by your CRT for status and data.  (Cannot be used with memory mapped
  103. ; displays.)  If using the CRTOUT routine, skip rest of this discussion.
  104. ;
  105. ;    This one addition requires some work on the part of the user.
  106. ; When "BYE" is added, CP/M is normally moved lower to accomodate the
  107. ; new program above CP/M.  Whenever BYE is called to enable the RCPM
  108. ; capability, it steals some of the addresses contained in the BIOS jump
  109. ; vector table.  In order to display on the CRT during program transfers
  110. ; you need to get into the BIOS console output routine directly, else
  111. ; what is being displayed also tries to go out the modem.  This is a big
  112. ; NO-NO at that time.  (This cannot be done automatically by XMODEM,
  113. ; since BYE has already taken the address we need to find, by the time
  114. ; XMODEM is automatically activated by the remote station.)
  115. ;
  116. ;    So with the disk containing BYE, but prior to activating BYE, do
  117. ; this:
  118. ;        1) Cold reboot to move CP/M (and BIOS) to the new area
  119. ;            needed when BYE is activated on the same disk.
  120. ;        2) Use DDT and dump the area from 0000H to 0002H.  This
  121. ;                   gives the warm reboot address in BIOS.
  122. ;        3) Add 9 Bytes to that address to get your console out-
  123. ;             put jump vector.
  124. ;        4) Pick off the address contained in the jump vector and
  125. ;             install that in "CONOUT", below.  Example of one
  126. ;             system in use:
  127. ;
  128. ;            FIRST, COLD REBOOT WITH DISK CONTAINING "BYE"
  129. ;
  130. ;      0000  C3 03 E0    (location of warm reboot on disk with BYE
  131. ;
  132. ;            PRIOR TO ACTIVATING BYE BUT ON SAME DISK
  133. ;
  134. ;      E003  C3 E9 E0    (BIOS warm reboot jump vector on this disk)
  135. ;      E006  C3 00 E9    (BIOS get console status routine)
  136. ;      E009  C3 B7 E1    (BIOS console input routine)
  137. ;      E00C  C3 D4 E1    (BIOS console output routine)
  138. ;
  139. ;        The address we need is thus E1D4.  Put that below, in
  140. ;        our example it would be:    CONOUT   JMP   0E1D4H
  141. ;
  142. ;
  143. ;    CONOUT:      JMP    00000H    ;If you wish to show the record count
  144. ;                ;during program transfer, fill in this
  145. ;                ;address at 'CONOUT' above.
  146. ;
  147. ;                    - Irv Hoff
  148. ;
  149. ;=======================================================================
  150. ;
  151. ; ---> CAROK - check for presence of carrier.  RET with Z = carrier on
  152. ;
  153. CAROK:
  154.     MVI    A,MODRESI    ;reset external status/interrupts
  155.     OUT    MODCTLP
  156.     IN    MODCTLP        ;get status
  157.     ANI    MODDCDB        ;get carrier detect bit
  158.     CPI    MODDCDA        ;test bit
  159.     RET
  160. ;
  161. ;=======================================================================
  162. ;
  163. EXTRA1:    RET            ;for later use
  164. EXTRA2:    RET            ;for later use
  165. EXTRA3:    RET            ;for later use
  166. ;
  167. ;=======================================================================
  168. ;
  169. ; ---> GETCHR - get a character, same as MDIN
  170. ; ---> MDIN - - get a character, same as GETCHR
  171. ;
  172. GETCHR:
  173. MDIN:    IN    MODDATP        ;get character from data in port
  174.     RET
  175. ;
  176. ;=======================================================================
  177. ;
  178. MINIT:    RET            ;no initialization required
  179. ;
  180. ;=======================================================================
  181. ;
  182. ; ---> RCVRDY - check receive ready.  RET with Z = character available.
  183. ;            Return with error code in A-reg.
  184. ;
  185. RCVRDY:    IN    MODCTLP        ;get modem status
  186.     PUSH    B        ;save scratch register
  187.     PUSH    PSW
  188.     MVI    A,1+MODRESI    ;select read register 1
  189.     OUT    MODCTLP
  190.     IN    MODCTLP        ;read the error status
  191.     ANI    MODFRME+MODOVRE+MODPARE
  192.     MOV    B,A        ;save it for a moment
  193.     MVI    A,MODERES
  194.     OUT    MODCTLP        ;do an error reset command
  195.     POP    PSW        ;now get modem status back
  196.     ANI    MODRCVB        ;isolate ready bit
  197.     CPI    MODRCVR        ;test it
  198.     MOV    A,B        ;get the error code char. back
  199.     POP    B
  200.     RET
  201. ;
  202. ;=======================================================================
  203. ;
  204. ; ---> SENDR - send character
  205. ;
  206. SENDR:    POP    PSW        ;get the character back
  207.     OUT    MODDATP        ;send it to the modem output
  208.     RET
  209. ;
  210. ;=======================================================================
  211. ;
  212. ; ---> SNDRDY - check if ready to send.
  213. ;
  214. SNDRDY:    IN    MODCTLP        ;get status byte
  215.     ANI    MODSNDB        ;isolate ready bit
  216.     CPI    MODSNDR        ;ready to send?
  217.     RET
  218. ;
  219. ;=======================================================================
  220. ;
  221. ; ---> SPEED - sets the time shown for program transfer.
  222. ;
  223. SPEED:    EQU    $
  224. ;
  225.      IF    LSPEED
  226.     LDA    MSPEED        ;get index for baud rate from 'BYE'
  227.      ENDIF
  228. ;
  229.      IF     NOT LSPEED
  230.     MVI    A,XSPEED    ;get index for baud rate from 'XSPEED'
  231.      ENDIF
  232. ;
  233.     RET
  234. ;
  235. ;=======================================================================
  236. ;
  237. UNINIT:    RET            ;not initialized, so no 'UN-INITIALIZE'
  238. ;
  239. ;=======================================================================
  240. ;
  241.     END
  242.