home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / XMODEM / XMDC-1.AQM / XMDC-1.ASM
Assembly Source File  |  2000-06-30  |  8KB  |  229 lines
  1.  
  2. ; XMDC-1.ASM - XMODEMxx PATCH FILE FOR D.C. HAYES MODEM  11/17/83
  3. ;
  4. ; This file adapts XMODEMxx to the D.C. Hayes modem.  To use, first edit
  5. ; any options desired into XMODEMxx.ASM, then assemble (can use ASM.COM)
  6. ; and load to get XMODEMxx.COM.  Then edit this file as needed (check the
  7. ; CONOUT routine if you want to locally see file transfer time and the
  8. ; record count while programs are being sent).  Then assemble (can use
  9. ; ASM.COM) and merge via DDT or SID:
  10. ;
  11. ;    B>DDT XMODEMxx.COM
  12. ;    DDT VERS 2.2
  13. ;    NEXT  PC
  14. ;    1180 0100
  15. ;    -IXMDC-1.HEX        (note the 'I' command)
  16. ;    -R            ('R' loads in the .HEX file)
  17. ;    NEXT  PC
  18. ;    1180 0000
  19. ;    -G0            (return to CP/M)
  20. ;    B>SAVE 16 XMODEMxx.COM  (now have a modified .COM file)
  21. ;
  22. ; NOTE: Save 21 (rather than 16) if LOGCAL is YES
  23. ;
  24. ;=======================================================================
  25. ;
  26. ; 11/17/83 - Renamed to XMDC-1.ASM    - Irv Hoff 
  27. ; 10/22/83 - Updated to XMODEM77    - Irv Hoff
  28. ; 04/04/83 - Updated to XMODEM74    - Irv Hoff
  29. ; 03/17/83 - Updated to XMODEM73    - Irv Hoff
  30. ; 03/17/83 - Updated to XMODEM72    - Irv Hoff
  31. ; 03/15/83 - Updated to XMODEM71    - Irv Hoff
  32. ;
  33. ; 03/07/83  Added instructions on how to adapt this file to XMODEM70.COM.
  34. ;        Standardized the format.  Added automatic MSPEED from "BYE"
  35. ;        program.  Added CONOUT information.  Adapted from XM70PMMI.
  36. ;                    - Irv Hoff
  37. ;
  38. ;=======================================================================
  39. ; 
  40. YES:    EQU    0FFH
  41. NO:    EQU    0
  42. ;
  43. ;=======================================================================
  44. ;
  45. MODDATP: EQU    80H        ;data in port
  46. MODDATO: EQU    MODDATP        ;data out port
  47. MODCTLP: EQU    MODDATP+2    ;first control/status port
  48. MODCTL2: EQU    MODDATP+1    ;second control/status port
  49. MODSNDB: EQU    2        ;bit to test for send
  50. MODSNDR: EQU    2        ;value when ready
  51. MODRCVB: EQU    1        ;bit to test for receive
  52. MODRCVR: EQU    1        ;value when ready
  53. MODDCDB: EQU    40H        ;carrier detect bit
  54. MODDCDA: EQU    40H        ;value when active
  55. MODPARE: EQU    04H        ;value for parity error
  56. MODOVRE: EQU    10H        ;value for overrun error
  57. MODFRME: EQU    08H        ;value for framing error
  58. ;
  59.  
  60. LSPEED:    EQU    YES        ;yes if using 'BYE' with speed selection
  61.                 ;no if using 'SPEED' manual selection
  62. MSPEED:    EQU    3CH        ;location of baud rate factor (set by
  63.                 ;'BYE')  set location in 'BYE' to agree.
  64.                 ;3dh and 3eh often used by newer ver-
  65.                 ;sions of 'ZCPR'.
  66. XSPEED:    EQU    1        ;speed for file time transfer without
  67.                 ;auto-set.  use one of the following:
  68.                 ;0=110 1=300 2=450 3=600 4=710 5=1200
  69. BASE:    EQU    100H        ;start of cp/m normal program area
  70. ;
  71. ;-------------------------------------------------------------------
  72. ;
  73. ; Jump table: The jump table must be in exactly the same sequence as the
  74. ; one in XMODEM.  Note the ORG of 103H - This jump table has no jump to
  75. ; 'BEGIN'.
  76.  
  77. ;
  78.      ORG    BASE+3        ;start after 'JMP BEGIN'
  79. ;
  80. CONOUT:     JMP    00000H        ;must be 00000h if not used, see below
  81. PMINIT:     JMP    MINIT        ;initialization routine (if needed)
  82. PUNINIT: JMP    UNINIT        ;undo whatever 'MINIT' did (or return)
  83. PSENDR:     JMP    SENDR        ;send character (via pop psw)
  84. PCAROK:     JMP    CAROK        ;test for carrier
  85. PMDIN:     JMP    MDIN        ;receive data byte
  86. PGETCHR: JMP    GETCHR        ;get character from modem
  87. PRCVRDY: JMP    RCVRDY        ;check receive ready
  88. PSNDRDY: JMP    SNDRDY        ;check send ready
  89. PSPEED:     JMP    SPEED        ;get speed value for file transfer time
  90. PEXTRA1: JMP    EXTRA1        ;extra for custom routine
  91. PEXTRA2: JMP    EXTRA2        ;extra for custom routine
  92. PEXTRA3: JMP    EXTRA3        ;extra for custom routine
  93. ;
  94. ;=======================================================================
  95. ;
  96. ; -- To Display the Record Count on the CRT During Program Transfers --
  97. ;    
  98. ;    This one addition requires some work on the part of the user.
  99. ; When "BYE" is added, CP/M is normally moved lower to accomodate the
  100. ; new program above CP/M.  Whenever BYE is called to enable the RCPM
  101. ; capability, it steals some of the addresses contained in the BIOS jump
  102. ; vector table.  In order to display on the CRT during program transfers
  103. ; you need to get into the BIOS console output routine directly, else
  104. ; what is being displayed also tries to go out the modem.  This is a big
  105. ; NO-NO at that time.  (This cannot be done automatically by XMODEM,
  106. ; since BYE has already taken the address we need to find, by the time
  107. ; XMODEM is automatically activated by the remote station.)
  108. ;
  109. ;    So with the disk containing BYE, but prior to activating BYE, do
  110. ; this:
  111. ;        1) Cold reboot to move CP/M (and BIOS) to the new area
  112. ;            needed when BYE is activated on the same disk.
  113. ;        2) Use DDT and dump the area from 0000H to 0002H.  This
  114. ;                   gives the warm reboot address in BIOS.
  115. ;        3) Add 9 Bytes to that address to get your console out-
  116. ;             put jump vector.
  117. ;        4) Pick off the address contained in the jump vector and
  118. ;             install that in "CONOUT", below.  Example of one
  119. ;             system in use:
  120. ;
  121. ;            FIRST, COLD REBOOT WITH DISK CONTAINING "BYE"
  122. ;
  123. ;      0000  C3 03 E0    (location of warm reboot on disk with BYE
  124. ;
  125. ;            PRIOR TO ACTIVATING BYE BUT ON SAME DISK
  126. ;
  127. ;      E003  C3 E9 E0    (BIOS warm reboot jump vector on this disk)
  128. ;      E006  C3 00 E9    (BIOS get console status routine)
  129. ;      E009  C3 B7 E1    (BIOS console input routine)
  130. ;      E00C  C3 D4 E1    (BIOS console output routine)
  131. ;
  132. ;        The address we need is thus E1D4.  Put that below, in
  133. ;        our example it would be:    CONOUT   JMP   0E1D4H
  134. ;
  135. ;
  136. ;    CONOUT:      JMP    00000H    ;If you wish to show the record count
  137. ;                ;during program transfer, fill in this
  138. ;                ;address at 'CONOUT' above.
  139. ;
  140. ;                    - Irv Hoff
  141. ;
  142. ;=======================================================================
  143. ;
  144. ; ---> CAROK - check for presence of carrier.  RET with RZ = carrier on
  145. ;
  146. CAROK:    MVI    A,MODCTL2
  147.     IN    MODCTL2        ;read modem status
  148.     ANI    MODDCDB        ;get carrier detect bit
  149.     CPI    MODDCDA        ;test bit
  150.     RET
  151. ;
  152. ;=======================================================================
  153. ;
  154. EXTRA1:    RET            ;for later use
  155. EXTRA2:    RET            ;for later use
  156. EXTRA3:    RET            ;for later use
  157. ;
  158. ;=======================================================================
  159. ;
  160. ; ---> GETCHR - get a character, same as MDIN
  161. ; ---> MDIN - - get a character, same as GETCHR
  162. ;
  163. GETCHR:
  164. MDIN:    MVI    A,MODDATP
  165.     IN    MODDATP        ;get character from data in port
  166.     RET
  167. ;
  168. ;=======================================================================
  169. ;
  170. MINIT:    RET            ;no initialization required
  171. ;
  172. ;=======================================================================
  173. ;
  174. ; ---> RCVRDY - check receive ready.  RET with JZ = character available.
  175. ;            Return with error code in A-reg.
  176. ;
  177. RCVRDY:    MVI    A,MODCTL2
  178.     IN    MODCTL2        ;get modem status
  179.     PUSH    B        ;save scratch register
  180.     PUSH    PSW        ;check error status
  181.     ANI    MODFRME+MODOVRE+MODPARE
  182.     MOV    B,A        ;save it for a moment
  183.     POP    PSW
  184.     ANI    MODRCVB        ;isolate ready bit
  185.     CPI    MODRCVR        ;test it
  186.     MOV    A,B        ;get the error code char. back
  187.     POP    B
  188.     RET
  189. ;
  190. ;=======================================================================
  191. ;
  192. ; ---> SENDR - send character
  193. ;
  194. SENDR:    POP    PSW        ;get the character back
  195.     OUT    MODDATO        ;send it to the modem output
  196.     RET
  197. ;
  198. ;=======================================================================
  199. ;
  200. ; ---> SNDRDY - check if ready to send.
  201. ;
  202. SNDRDY:    MVI    A,MODCTL2
  203.     IN    MODCTL2        ;get status byte
  204.     ANI    MODSNDB        ;mask off bit to be tested
  205.     CPI    MODSNDR        ;set status flag
  206.     RET
  207. ;
  208. ;=======================================================================
  209. ;
  210. ; ---> SPEED - sets the time shown for program transfer.
  211. ;
  212. SPEED:     IF    LSPEED
  213.     LDA    MSPEED        ;get index for baud rate from 'BYE'
  214.      ENDIF
  215. ;
  216.      IF     NOT LSPEED
  217.     MVI    A,XSPEED    ;get index for baud rate from 'XSPEED'
  218.      ENDIF
  219. ;
  220.     RET
  221. ;
  222. ;=======================================================================
  223. ;
  224. UNINIT:    RET            ;not initialized, so no 'UN-INITIALIZE'
  225. ;
  226. ;=======================================================================
  227. ;
  228. ;
  229.     END