home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / XMODEM / XMAC-1.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  8KB  |  232 lines
  1.  
  2. ; XMAC-1.ASM - XMODEMxx PATCH FILE FOR APPLE-CAT MODEM  11/17/83
  3. ; 
  4. ; This file adapts XMODEMxx to the APPLE-CAT modem.  To use, first edit
  5. ; any options desired into XMODEMxx.ASM, then assemble (can use ASM.COM)
  6. ; and load to get XMODEMxx.COM.  Then edit this file as needed (check the
  7. ; CONOUT routine if you want to locally see file transfer time and the
  8. ; record count while programs are being sent).  Then assemble (can use
  9. ; ASM.COM) and merge via DDT or SID:
  10. ;
  11. ;    B>DDT XMODEMxx.COM
  12. ;    DDT VERS 2.2
  13. ;    NEXT  PC
  14. ;    1180 0100
  15. ;    -IXMAC-1.HEX        (note the 'I' command)
  16. ;    -R            ('R' loads in the .HEX file)
  17. ;    NEXT  PC
  18. ;    1180 0000
  19. ;    -G0            (return to CP/M)
  20. ;    B>SAVE 16 XMODEMxx.COM  (now have a modified .COM file)
  21. ;
  22. ; NOTE: Save 21 (rather than 16) if LOGCAL is YES
  23. ;
  24. ;=======================================================================
  25. ;
  26. ; 11/17/83 - Renamed to XMAC-1.ASM    - Irv Hoff
  27. ; 10/22/83 - Updated to XMODEM77    - Irv Hoff
  28. ; 04/04/83 - Updated to XMODEM74    - Irv Hoff
  29. ; 03/27/83 - Updated to XMODEM73    - Irv Hoff
  30. ; 03/17/83 - Updated to XMODEM72    - Irv Hoff
  31. ; 03/15/83 - Updated to XMODEM71    - Irv Hoff
  32. ;
  33. ; 03/07/83  Added instructions on how to adapt this file to XMODEM70.COM.
  34. ;        Standardized the format.  Added automatic MSPEED from "BYE"
  35. ;        program.  Added CONOUT information.  Adapted from XM70PMMI.
  36. ;                    - Irv Hoff
  37. ;
  38. ;=======================================================================
  39. ; 
  40. YES:    EQU    0FFH
  41. NO:    EQU    0
  42. ;
  43. ;=======================================================================
  44. ;
  45. SLOT:     EQU    2        ;for apple-cat modem
  46. SLOTVAL: EQU    SLOT*16        ;allows relocating modem slot    
  47. MODCTLP: EQU    0E080H+SLOTVAL    ;apple-cat carrier detect
  48. MODDATP: EQU    MODCTLP+0BH    ;data in port
  49. MODDATO: EQU    MODCTLP+0EH    ;data out port
  50. MODCTL2: EQU    MODCTLP+0FH    ;second control/status port
  51. MODSNDB: EQU    10H        ;bit to test for send
  52. MODSNDR: EQU    10H        ;value when ready
  53. MODRCVB: EQU    08H        ;bit to test for receive
  54. MODRCVR: EQU    08H        ;value when ready
  55. MODDCDB: EQU    20H        ;carrier detect bit
  56. MODDCDA: EQU    20H        ;value when active
  57. MODPARE: EQU    20H        ;value for parity error
  58. MODOVRE: EQU    80H        ;value for overrun error
  59. MODFRME: EQU    40H        ;value for framing error
  60. CATCLR:     EQU    MODCTLP+0DH    ;this is the cat xmtbyte
  61. CATVAL:     EQU    10H        ;sets cat to 103 answer mode and resets
  62.                 ;receive reg. full status when sta catclr
  63. ;
  64.  
  65. LSPEED:    EQU    YES        ;yes if using 'BYE' with speed selection
  66.                 ;no if using 'SPEED' manual selection
  67. MSPEED:    EQU    3CH        ;location of baud rate factor (set by
  68.                 ;'BYE')  set location in 'BYE' to agree.
  69.                 ;3dh and 3eh often used by newer ver-
  70.                 ;sions of 'ZCPR'.
  71. XSPEED:    EQU    1        ;speed for file time transfer without
  72.                 ;auto-set.  use one of the following:
  73.                 ;0=110 1=300 2=450 3=600 4=710 5=1200
  74. BASE:    EQU    100H        ;start of cp/m normal program area
  75. ;
  76. ;-------------------------------------------------------------------
  77. ;
  78. ; Jump table: The jump table must be in exactly the same sequence as the
  79. ; one in XMODEM.  Note the ORG of 103H - This jump table has no jump to
  80. ; 'BEGIN'.
  81.  
  82. ;
  83.      ORG    BASE+3        ;start after 'JMP BEGIN'
  84. ;
  85. CONOUT:     JMP    00000H        ;must be 00000h if not used, see below
  86. PMINIT:     JMP    MINIT        ;initialization routine (if needed)
  87. PUNINIT: JMP    UNINIT        ;undo whatever 'MINIT' did (or return)
  88. PSENDR:     JMP    SENDR        ;send character (via pop psw)
  89. PCAROK:     JMP    CAROK        ;test for carrier
  90. PMDIN:     JMP    MDIN        ;receive data byte
  91. PGETCHR: JMP    GETCHR        ;get character from modem
  92. PRCVRDY: JMP    RCVRDY        ;check receive ready
  93. PSNDRDY: JMP    SNDRDY        ;check send ready
  94. PSPEED:     JMP    SPEED        ;get speed value for file transfer time
  95. PEXTRA1: JMP    EXTRA1        ;extra for custom routine
  96. PEXTRA2: JMP    EXTRA2        ;extra for custom routine
  97. PEXTRA3: JMP    EXTRA3        ;extra for custom routine
  98. ;
  99. ;=======================================================================
  100. ;
  101. ; -- To Display the Record Count on the CRT During Program Transfers --
  102. ;    
  103. ;    This one addition requires some work on the part of the user.
  104. ; When "BYE" is added, CP/M is normally moved lower to accomodate the
  105. ; new program above CP/M.  Whenever BYE is called to enable the RCPM
  106. ; capability, it steals some of the addresses contained in the BIOS jump
  107. ; vector table.  In order to display on the CRT during program transfers
  108. ; you need to get into the BIOS console output routine directly, else
  109. ; what is being displayed also tries to go out the modem.  This is a big
  110. ; NO-NO at that time.  (This cannot be done automatically by XMODEM,
  111. ; since BYE has already taken the address we need to find, by the time
  112. ; XMODEM is automatically activated by the remote station.)
  113. ;
  114. ;    So with the disk containing BYE, but prior to activating BYE, do
  115. ; this:
  116. ;        1) Cold reboot to move CP/M (and BIOS) to the new area
  117. ;            needed when BYE is activated on the same disk.
  118. ;        2) Use DDT and dump the area from 0000H to 0002H.  This
  119. ;                   gives the warm reboot address in BIOS.
  120. ;        3) Add 9 Bytes to that address to get your console out-
  121. ;             put jump vector.
  122. ;        4) Pick off the address contained in the jump vector and
  123. ;             install that in "CONOUT", below.  Example of one
  124. ;             system in use:
  125. ;
  126. ;            FIRST, COLD REBOOT WITH DISK CONTAINING "BYE"
  127. ;
  128. ;      0000  C3 03 E0    (location of warm reboot on disk with BYE
  129. ;
  130. ;            PRIOR TO ACTIVATING BYE BUT ON SAME DISK
  131. ;
  132. ;      E003  C3 E9 E0    (BIOS warm reboot jump vector on this disk)
  133. ;      E006  C3 00 E9    (BIOS get console status routine)
  134. ;      E009  C3 B7 E1    (BIOS console input routine)
  135. ;      E00C  C3 D4 E1    (BIOS console output routine)
  136. ;
  137. ;        The address we need is thus E1D4.  Put that below, in
  138. ;        our example it would be:    CONOUT   JMP   0E1D4H
  139. ;
  140. ;
  141. ;    CONOUT:      JMP    00000H    ;If you wish to show the record count
  142. ;                ;during program transfer, fill in this
  143. ;                ;address at 'CONOUT' above.
  144. ;
  145. ;                    - Irv Hoff
  146. ;
  147. ;=======================================================================
  148. ;
  149. ; ---> CAROK - check for presence of carrier.  RET with Z = carrier on
  150. ;
  151. CAROK:    LDA    MODCTLP        ;check for carrier
  152.     ANI    MODDCDB        ;get carrier detect bit
  153.     CPI    MODDCDA        ;test bit
  154.     RET
  155. ;
  156. ;=======================================================================
  157. ;
  158. EXTRA1:    RET            ;for later use
  159. EXTRA2:    RET            ;for later use
  160. EXTRA3:    RET            ;for later use
  161. ;
  162. ;=======================================================================
  163. ;
  164. ; ---> GETCHR - get a character, same as MDIN
  165. ; ---> MDIN - - get a character, same as GETCHR
  166. ;
  167. GETCHR:
  168. MDIN:    MVI    A,CATVAL
  169.     STA    CATCLR
  170.     LDA    MODDATP        ;get the char, if any
  171.     RET
  172. ;
  173. ;=======================================================================
  174. ;
  175. MINIT:    RET            ;no initialization required
  176. ;
  177. ;=======================================================================
  178. ;
  179. ; ---> RCVRDY - check receive ready.  RET with Z = character available.
  180. ;            Return with error code in A-reg.
  181. ;
  182. RCVRDY:    LDA    MODCTL2        ;get modem status
  183.     PUSH    B        ;save scratch register
  184.     PUSH    PSW        ;check error status
  185.     ANI    MODFRME+MODOVRE+MODPARE
  186.     MOV    B,A        ;save it for a moment
  187.     POP    PSW
  188.     ANI    MODRCVB        ;isolate ready bit
  189.     CPI    MODRCVR        ;test it
  190.     MOV    A,B        ;get the error code char. back
  191.     POP    B
  192.     RET
  193. ;
  194. ;=======================================================================
  195. ;
  196. ; ---> SENDR - send character
  197. ;
  198. SENDR:    POP    PSW        ;get the character back
  199.     STA    MODDATO        ;send it to the modem output
  200.     RET
  201. ;
  202. ;=======================================================================
  203. ;
  204. ; ---> SNDRDY - check if ready to send.
  205. ;
  206. SNDRDY:    LDA    MODCTL2        ;get status byte
  207.     ANI    MODSNDB        ;isolate ready bit
  208.     CPI    MODSNDR        ;ready to send?
  209.     RET
  210. ;
  211. ;=======================================================================
  212. ;
  213. ; ---> SPEED - sets the time shown for program transfer.
  214. ;
  215. SPEED:     IF    LSPEED
  216.     LDA    MSPEED        ;get index for baud rate from 'BYE'
  217.      ENDIF
  218. ;
  219.      IF     NOT LSPEED
  220.     MVI    A,XSPEED    ;get index for baud rate from 'XSPEED'
  221.      ENDIF
  222. ;
  223.     RET
  224. ;
  225. ;=======================================================================
  226. ;
  227. UNINIT:    RET            ;not initialized, so no 'UN-INITIALIZE'
  228. ;
  229. ;=======================================================================
  230. ;
  231. ;
  232.     END