home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
CPM
/
MODEMS
/
MODEM7
/
NECMDMX.LBR
/
M7NE-2.ASM
next >
Wrap
Assembly Source File
|
2000-06-30
|
14KB
|
415 lines
; M7NE-2.ASM - NEC PC-8801 computer overlay file for MDM712 - 07/10/84
;
; You will want to look this file over carefully. There are a number of
; options that you can use to configure the program to suit your taste.
; This file adapts the NEC PC-8801 computer to the modem program.
; This file uses the INSTALL8 MODEM7B driver (incl. on this disk) linked
; to the TTY: device to obtain proper interrupt processing, necessary at
; higher Baud rates (>300). Changes cause more efficient operation at
; Baud rates of 300 and lower also. To use this overlay, you must set
; the serial port for 1200 baud (jumper 5), as the program then converts
; that to 300 baud whenever needed.
;
; If you edit this file for your preferences, follow the "TO USE:" example
; shown below.
;
; Use the "SET" command to change the baudrate when desired. It starts
; out at 300 baud when the program is first called up.
;
; TO USE: First edit this file filling in answers for your own
; equipment. Then assemble with ASM.COM or equivalent
; assembler. Then use DDT to overlay the the results
; of this program to the original .COM file:
;
; A>DDT MDM727.COM
; DDT VERS 2.2
; NEXT PC
; 4994 0100
; -IM7NE-2.HEX (note the "I" command)
; -R ("R" loads in the .HEX file)
; NEXT PC
; 4994 0000
; -G0 (return to CP/M)
; A>SAVE 73 NECMDM7.COM (now have a modified .COM file)
;
; = = = = = = = = = = = = = = = = = =
;
; 07/10/84 - Altered for Install8 MODEM7B.DRV drivers
; - Renamed to M7NE-2.ASM - Steven Sarna
; 11/11/83 - Renamed to M7NE-1.ASM, no changes - Irv Hoff
; 07/27/83 - Renamed for use with MDM712 - Irv Hoff
; 07/01/83 - Revised for use with MDM711 - Irv Hoff
; 06/22/83 - Revised for use with MDM710 - Irv Hoff
; 06/22/83 - Altered for use with MDM710 - Irv Hoff
; 06/22/83 - Altered MDM708DP for the NEC 8001
; computer using an external modem - Irv Hoff
;
; = = = = = = = = = = = = = = = = = =
;
BELL: EQU 07H ;bell
CR: EQU 0DH ;carriage return
ESC: EQU 1BH ;escape
LF: EQU 0AH ;linefeed
;
YES: EQU 0FFH
NO: EQU 0
;
;
WBOOT: EQU 01H ;CP/M Warm boot location
IOBYTE: EQU 03H ;CP/M I/O Byte location
PORT: EQU 20H ;NEC PC-8801 serial port
MODCTL1: EQU PORT+1 ;Modem status port
MODCTL2: EQU PORT+1 ;Modem control port
MODDATP: EQU PORT ;Modem data port
MODRCVB: EQU 02H ;Modem recv bit
MODRCVR: EQU 02H ;Modem recv ready bit
MODSNDB: EQU 07H ;Modem send mask
MODSNDR: EQU 05H ;Modem send ready bits
;8251 COMMAND INSTRUCTION FORMAT
RES: EQU 0100$0000B ; Internal Reset (To mode instruction)
RTS: EQU 0010$0000B ; Request to send
ERR: EQU 0001$0000B ; Error Reset
BRK: EQU 0000$1000B ; Send Break
REN: EQU 0000$0100B ; Recieve Enable
DTR: EQU 0000$0010B ; Data terminal ready
TEN: EQU 0000$0001B ; Transmit Enable
;8251 MODE INTRUCTION FORMAT
STOP1: EQU 0100$0000B ;Framing Control, 1 Stop bit
STOP1$5: EQU 1000$0000B ;1 and 1/2 Stop bits
STOP2: EQU 1100$0000B ;2 Stop bits
NO: EQU 00$0000B ;No Parity
ODD: EQU 01$0000B ;Odd parity
EVN: EQU 11$0000B ;Even parity
FIVE: EQU 0000B ;Five bit character length
SIX: EQU 0100B ;Six bit character length
SEVEN: EQU 1000B ;Seven bit character length
EIGHT: EQU 1100B ;Eight bit character length
X1: EQU 01B ;Asynchronous times one
X16: EQU 10B ;Asynchronous times sixteen
X64: EQU 11B ;Asynchronous times sixty-four
;BIOS ENTRY POINTS
CONST: EQU 006H ;Console status
CONIN: EQU 009H ;Console in
CONOUT: EQU 00CH ;Console out
LISTST: EQU 02DH ;List status
;
;
ORG 100H
;
DS 3 ;(for "JMP START" instruction)
PMMIMODEM: DB NO ;yes=PMMI S-100 Modem 103H
SMARTMODEM: DB YES ;yes=HAYES Smartmodem 104H
TOUCHPULSE: DB 'T' ;T=touch, P=pulse (Smartmodem-only) 105H
CLOCK: DB 5 ;clock speed in MHz x10, 25.5 MHz max. 106H
;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
;Due to interrupts on the PC-8801A, tick clock must be set to 5
MSPEED: DB 1 ;0=110 1=300 2=450 3=600 4=710 5=1200 107H
;6=2400 7=4800 8=9600 9=19200 default
BYTDLY: DB 5 ;0=0 delay 1=10ms 5=50 ms - 9=90 ms 108H
;default time to send character in ter-
;minal mode file transfer for slow BBS.
CRDLY: DB 5 ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
;default time for extra wait after CRLF
;in terminal mode file transfer
NOOFCOL: DB 5 ;number of DIR columns shown 10AH
SETUPTST: DB YES ;yes=user-added Setup routine 10BH
SCRNTEST: DB YES ;cursor control routine 10CH
ACKNAK: DB YES ;yes=resend a record after any non-ACK 10DH
;no=resend a record after a valid NAK
BAKUPBYTE: DB YES ;yes=change any file same name to .BAK 10EH
CRCDFLT: DB YES ;yes=default to CRC checking 10FH
TOGGLECRC: DB YES ;yes=allow toggling of CRC to Checksum 110H
CONVBKSP: DB NO ;yes=convert backspace to rub 111H
TOGGLEBK: DB YES ;yes=allow toggling of bksp to rub 112H
ADDLF: DB NO ;no=no LF after CR to send file in 113H
;terminal mode (added by remote echo)
TOGGLELF: DB YES ;yes=allow toggling of LF after CR 114H
TRANLOGON: DB NO ;yes=allow transmission of logon 115H
;write logon sequence at location LOGON
SAVCCP: DB YES ;yes=do not overwrite CCP 116H
LOCONEXTCHR: DB NO ;yes=local command if EXTCHR precedes 117H
;no=external command if EXTCHR precedes
TOGGLELOC: DB YES ;yes=allow toggling of LOCONEXTCHR 118H
LSTTST: DB NO ;no=printer not available (modem) 119H
XOFFTST: DB NO ;yes=chcks for XOFF from remote while 11AH
;sending a file in terminal mode
XONWAIT: DB NO ;yes=wait for XON after CR while 11BH
;sending a file in terminal mode
TOGXOFF: DB YES ;yes=allow toggling of XOFF checking 11CH
IGNORCTL: DB YES ;yes=CTL-chars above ^M not displayed 11DH
EXTRA1: DB 0 ;for future expansion 11EH
EXTRA2: DB 0 ;for future expansion 11FH
BRKCHR: DB '@'-40H ;^@ = Send a 300 ms. break tone 120H
NOCONNCT: DB 'N'-40H ;^N = Disconnect from the phone line 121H
LOGCHR: DB 'L'-40H ;^L = Send logon 122H
LSTCHR: DB 'P'-40H ;^P = Toggle printer 123H
UNSAVE: DB 'R'-40H ;^R = Close input text buffer 124H
TRANCHR: DB 'T'-40H ;^T = Transmit file to remote 125H
SAVECHR: DB 'Y'-40H ;^Y = Open input text buffer 126H
EXTCHR: DB '^'-40H ;^^ = Send next character 127H
;
;
DS 2 ; 128H
;
IN$MODCTL1: IN MODCTL1 ;In modem control port 12AH
RET ;left here for port I.D.
; ;not really used.
DS 7
OUT$MODDATP: JMP TTYOUT ;Out modem data port 134H
DS 7 ;replaced by TTY: output.
IN$MODDATP: JMP TTYIN ;In modem data port 13EH
DS 7 ;replaced by TTY: input.
ANI$MODRCVB: RET ;Logical AND not performed.
DS 2
CPI$MODRCVR: JMP TTY$IN$S ;Compare replaced by TTY:
; ;status routine.
ANI$MODSNDB: RET ;Logical AND not performed.
DS 2
CPI$MODSNDR: JMP TTY$OT$S ;Compare replaced by TTY:
DS 12 ;status routine.
;
LOGONPTR: DW LOGON ;for user message. 160H
DS 6 ; 162H
JMP$GOODBYE: JMP GOODBYE ; 168H
JMP$INITMOD: JMP INITMOD ;go to user written routine 16BH
RET ! NOP ! NOP ;(by-passes PMMI port) 16EH
RET ! NOP ! NOP ;(by-passes PMMI routine) 171H
RET ! NOP ! NOP ;(by-passes PMMI routine) 174H
JMP$SETUPR: JMP SETUPR ; 177H
JMP$SPCLMENU: JMP SPCLMENU ; 17AH
JMP$SYSVER: JMP SYSVER ; 17DH
JMP$BREAK: JMP SENDBRK ; 180H
;
;
; Do not change the following six lines.
;
JMP$ILPRT: DS 3 ; 183H
JMP$INBUF DS 3 ; 186H
JMP$INLNCOMP: DS 3 ; 189H
JMP$INMODEM DS 3 ; 18CH
JMP$NXTSCRN: DS 3 ; 18FH
JMP$TIMER: DS 3 ; 192H
;
;
; Clear sequences -- CLREOS is clear to end of screen, CLRSCRN is clear
; entire screen. Last entry must be 0. Any other 0's act as NOP's.
; The SCRNTST option must be set "YES" for these to work.
;
CLREOS: CALL JMP$ILPRT ; 195H
DB ESC,59H,0,0,0 ; 198H
RET ; 19DH
;
CLRSCRN: CALL JMP$ILPRT ; 19EH
DB 1EH,ESC,59H,0,0 ; 1A1H
RET ; 1A6H
;
;
SYSVER: CALL JMP$ILPRT ; 1A7H
DB 'Version for NEC PC-8801A computers'
DB CR,LF
DB 'For use with "INSTALL8 MODEM7B TTY:"'
DB CR,LF,0
RET
;.....
;
;
;-----------------------------------------------------------------------
;
; NOTE: You can change the SYSVER message to be longer or shorter. The
; end of your last routine should terminate by 0400H (601 bytes
; available after start of SYSVER) if using the Hayes Smartmodem
; or by address 0C00H (2659 bytes) otherwise.
;
;-----------------------------------------------------------------------
;
; You can put in a message at this location which can be called up with
; CTL-L if TRANLOGON has been set YES. You can put in several lines if
; desired. End with a 0.
;
;
LOGON: DB 'This is an NEC PC-8801A computer',CR,LF,0
;.....
;
;
;=======================================================================
;
; This routine allows a 300 ms. break tone to be send to reset some
; time-share computers.
;
SENDBRK: MVI A,RTS+ERR+BRK+REN+DTR+TEN ;SEND A BREAK TONE
JMP GOODBYE1
;.....
;
;
; This routine sends a 300 ms. break tone and sets DTR low for the same
; length of time to disconnect some modems such as the Bell 212A, etc.
;
GOODBYE: MVI A,ERR+BRK+TEN ;SEND BREAK, TURN OFF RTS & DTR
;
GOODBYE1: OUT MODCTL1 ;SEND TO STATUS PORT
MVI B,3 ;WAIT 300 MS.
CALL JMP$TIMER
MVI A,RTS+ERR+REN+DTR+TEN ;NORMAL SEND/RECEIVE WITH RTS & DTR
OUT MODCTL1 ;SEND TO STATUS PORT
RET
;.....
;
;
; NEC PC-8801 initialization -- sets the 8251A for 8 bits, 1 stop pulse,
; DTR high, requires jumper shunt be set (jumpered @ 5) to 1200 baud then
; divides by 64 for 300, or by 16 for 1200 baud via "SET" command. Set
; at present to default to 300 baud.
;
INITMOD: MVI A,1 ;TRANSFER TIME FOR 300 BAUD
STA MSPEED
MVI A,0 ;INSURE OUT OF MODE
OUT MODCTL1 ;MODEM STATUS PORT
OUT MODCTL1
OUT MODCTL1 ;3 TIMES GETS IT TO KNOWN STATUS
MVI A,RES ;INITIALIZE USART
OUT MODCTL1 ;MODEM STATUS PORT
;
INITMOD1: MVI A,STOP1+NO+EIGHT+X64 ;DEFAULT TO DIVIDE BY 64 FOR 300 BAUD
OUT MODCTL1 ;MODEM STATUS PORT
MVI A,RTS+ERR+REN+DTR+TEN ;RTS, DTR, RCV, XMT, ERROR RESET
OUT MODCTL1 ;MODEM STATUS PORT
RET
;
; NEC PC-8801 status subroutines. Alters IOBYTE to make TTY: give input
; and output status, and send TTY: input and output to CONsole
; CP/M device.
; Routines Modified to working condition by S. Michael Sarna
; Thanks to David Schmidt and Andrew Marrinson... R.I.P. June, 1984.
;
TTY$IN$S:
CALL SWAP ; Get the current I/O Byte and switch
MVI C,CONST ; Get console status
CALL BIOS ; Do the In status
INR A ; Set the appropriate flag
JMP EXIT1 ; Restore the old I/O Byte & leave
TTY$OT$S:
CALL SWAP ; Go to the correct I/O frame
MVI C,LISTST ; BIOS offset to get the list device status
CALL BIOS ; Do the Out status
INR A ; Set the flag appropiately
JMP EXIT1 ; Restore the old I/O Byte & leave
TTYOUT:
CALL SWAP ; One last I/O change
MVI C,CONOUT ; BIOS console input
CALL BIOS ; Send the character out
;The following delay is manditory to avoid an "undocumented hardware feature"
;in the 8251, as it seems you can't poll immediately after Xmt.
LXI B,03FFH ; Wait a little bit after sending
TTYOU1:
DCX B ; Count down
MOV A,B ; Check if counted down enough
ORA C
JNZ TTYOU1 ; If not zero, count down some more
JMP EXIT1
TTYIN:
CALL SWAP ; Turn into a TTY: system
MVI C,CONIN ; Direct console read
; Exit must follow here:
EXIT:
CALL BIOS ; Do the suggested I/O
EXIT1:
POP B ; Restore regs to normal
POP D
POP H
PUSH PSW ; Save the BIOS call status or data
LDA IO$BYT ; Get the old I/O Byte
STA IOBYTE ; move this to the I/O Byte location for CP/M
POP PSW ; Return the status or data
RET ; Go back to the caller
BIOS:
LHLD WBOOT ; Get the BIOS address
MOV L,C ; Set LSB of BIOS Routine
MOV C,A ; Set LSB of Arg
PCHL ; Go to the BIOS
SWAP:
XTHL ; old HL on stack, return address in HL
PUSH D ; Save other registers
PUSH B
PUSH H ; Return address back on stack
LXI H,IOBYTE ; Point to the current I/O Byte
PUSH PSW ; Save character to send
MOV A,M ; Fetch the current I/O Byte
MVI M,0 ; Set all devices to TTY:
STA IO$BYT ; Save the current I/O Byte
POP PSW ; Restore the character to send
RET
;
IO$BYT:
DS 1 ;
;
;
;
SETUPR: LXI D,BAUDBUF ;POINT TO NEW INPUT BUFFER
CALL JMP$ILPRT
DB 'Input Baud Rate (300, 1200): ',0
CALL JMP$INBUF
LXI D,BAUDBUF+2
CALL JMP$INLNCOMP ;COMPARE BAUDBUF+2 WITH CHARACTERS BELOW
DB '300',0
JNC OK300 ;GO IF GOT MATCH
CALL JMP$INLNCOMP
DB '1200',0
JNC OK1200
CALL JMP$ILPRT ;ALL MATCHES FAILED, TELL OPERATOR
DB '++ Incorrect entry ++',CR,LF,BELL,0
JMP SETUPR ;TRY AGAIN
;
OK300: MVI A,1 ;MSPEED 300 BAUD VALUE
MVI B,STOP1+NO+EIGHT+X64 ;DIVIDE BY 64 FOR 300 BAUD
JMP LOADBD ;GO LOAD THEM
;
OK1200: MVI A,5
MVI B,STOP1+NO+EIGHT+X16 ;DIVIDE BY 16 FOR 1200 BAUD
;
;
LOADBD: STA INITMOD+1 ;CHANGE TIME-TO-SEND TO MATCH BAUDRATE
MOV A,B ;GET BAUDRATE BYTE
STA INITMOD1+1 ;STORE IN INITMOD
JMP INITMOD ;REINITIALIZE TO NEW BAUDRATE, THEN DONE
;
;
BAUDBUF: DB 10,0
DS 10
;.....
;
;
; (END OF INITMOD AND SETUP ROUTINES)
;=======================================================================
;
;
; These routines can be used for your equipment. End with RET. If
; using the Hayes Smartmodem this is unavailable without a special ad-
; dress change.
;
SPCLMENU: RET
;
;=======================================================================
;
;
; NOTE: MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
; 0C00H (without Smartmodem)
;
END
;