home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / MODEM7 / M7QX-3.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  28KB  |  863 lines
  1. ; M7QX-3.ASM -- Epson QX-10 overlay file for VALDOCS 1.1X  06/06/84
  2. ;
  3. ;        Overlay file for MDM730 (and later), Epson QX-10, and the
  4. ;        D.C. Hayes Smartmodem 300 or 1200, US Robotics modems, the
  5. ;        Anchor Automation Signalman Mark XII, Prometheus, or similiar
  6. ;        modems which use the DC Hayes Smartmodem protocols.  It is
  7. ;         designed to be used with a .SYS extent as a VALDOCS applica-
  8. ;        tion from the <M>enu of Applications, <R>un specific program,
  9. ;        or <E>xit to TPM options.  It will also run under TPM-II
  10. ;        without VALDOCS (using a .SYS or .COM extent) or under
  11. ;        CP/M A2.21 or B2.20 if given a .COM file extent.  It
  12. ;         incorporates the special SET menu advantages of Bruce
  13. ;        Ratoff's ATXMODEM, plus it offers the ability to toggle
  14. ;        on or off the 7th bit mask. This permits the use of QX-10
  15. ;        graphics when desired, but retains the ability to use this
  16. ;        same program on mainframes such as Compuserve.  This overlay
  17. ;        is specifically tailored to MDM730 and makes direct calls to
  18. ;        addresses in the main program.  You must change these addresses
  19. ;        to use this overlay with a later MDM7XX series program.
  20. ;        For standardization among the four operating systems used on
  21. ;        the QX-10, I have chosen ^B for the sendbreak character,
  22. ;        and ^Z to transmit control characters above ^M to the remote.
  23. ;
  24. ;******************************************************************************
  25. ;
  26. ; NOTE:  All improvements to this overlay intended for distribution must be
  27. ; compatible with VALDOCS.  Send all updates to either the Technical RCPM/RBBS
  28. ; (313)846-6127, or CompuServe CP/MIG (PCS-47), Area XA0 along with a message
  29. ; addressed to the SYSOP.  They, in turn, will make official release.  If you
  30. ; wish to discuss the overlay, leave a message for Chris Hopkins, 71026,1407 on
  31. ; CompuServe's EpsOnLine SIG (PCS-19), or EMAIL.
  32. ;
  33. ;******************************************************************************
  34. ;
  35. ; Switch settings for the D.C. Hayes Smartmodem and Smartmodem 1200 are:
  36. ;
  37. ;    SW1    SW2    SW3    SW4    SW5    SW6    SW7    SW8
  38. ;    UP    ANY    ANY    ANY    ANY    UP    ANY*    DN
  39. ;
  40. ;   These settings are compatible with those used in VALDOCS MAIL to prevent
  41. ;   unnecessary changing of settings.  This program resets switches 2 thru 5
  42. ;   by software, so their physical settings have no effect.
  43. ;
  44. ;   *Depends on type of telephone jack used.
  45. ;.....
  46. ; You will want to look this file over carefully. There are a number of
  47. ; options that you can use to configure the program to suit your taste.
  48. ;
  49. ; Edit this file for your preferences then follow the "TO USE:" example
  50. ; shown below.
  51. ;
  52. ;    TO USE: First edit this file, filling in answers for your own
  53. ;        preferences.  Assemble with ASM.COM or equivalent
  54. ;        assembler to obtain a file named M7QX-3.HEX.  Then
  55. ;               use DDT to overlay the HEX file on the original .COM file:
  56. ;
  57. ;        A>DDT MDM730.COM
  58. ;        DDT VERS 2.2
  59. ;        NEXT  PC
  60. ;        4A00 0100
  61. ;        -IM7QX-3.HEX        (note the "I" command)
  62. ;        -R            ("R" loads in the .HEX file)
  63. ;        NEXT  PC
  64. ;        4A00 0000
  65. ;        -G0            (return to CP/M)
  66. ;               A>SAVE 73 QXMDM3.SYS   (now have a modified .SYS file)
  67. ;                    (can also make a .COM file now)
  68. ; 
  69. ;    =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  70. ; 06/06/84 - Renamed to M7QX-3.ASM and added addresses for MDM740.ASM. 
  71. ;        - Added BYEBYE messages for CP/M, TPM and VALDOCS. 
  72. ;        - Corrected error in hardware initiation that forgot to tell the
  73. ;         QX-10 baudrate timer the speed in use according to the CMOS. 
  74. ;       - Corrected timing problem in VALDOCS during ^T text transfer. 
  75. ;        - Corrected GOODBYE and SENDBRK to reset to parameters that were in
  76. ;         use before the break.  Previously, it always reset to 8 bit words,
  77. ;         1 stop bit and no parity. 
  78. ;        - Corrected timing problems for VALDOCS by placing CLOCKSET routine
  79. ;         at START.  Previously, timing set did not occur until INITMOD.
  80. ;                            -Chris Hopkins 
  81. ; 04/15/84 - Removed macros to allow assembly using ASM.COM, and revised to
  82. ;         work with MDM730. 
  83. ;        - Added cursor control routines for signon. 
  84. ;        - Added toggle in SET command to allow selection of QX-10 graphics
  85. ;         for use in the terminal mode.  Subsequent selection of 7-bit
  86. ;         words or 8-bit words with the 7th bit masked cancels the
  87. ;         graphics selection. - Chris Hopkins
  88. ; 03/11/84 - Renamed to M7QX-2.ASM and revised to work with MDM727.  
  89. ;        - Added subroutines to provide [ Using TPM ], [ Using CP/M ] and
  90. ;         [ Using VALDOCS ] statements following signon message. - CH 
  91. ; 01/22/84 - Revised M712QS.ASM to fit MDM718-720, renamed overlay to
  92. ;            M7QX-1.ASM to conform to new format. 
  93. ;        - Added sendbreak routine and revised signon - Chris Hopkins
  94. ; 10/13/83 - Checks for CP/M or TPM to prevent crashing CP/M
  95. ;         with TPM backdoor calls. - BRR
  96. ; 10/11/83 - Detects presence of SYSINIT and uses its interrupt-driven
  97. ;            serial routines if present. - BRR
  98. ; 10/10/83 - Stop bits, parity, word size in SETUPR - BRR
  99. ; 08/14/83 - Cosmetic changes only for MDM712    - Bruce Ratoff
  100. ; 07/26/83 - QX-10 version created from GP file - Bruce Ratoff
  101. ; 07/01/83 - Revised to work with MDM711    - Irv Hoff
  102. ; 07/01/83 - Revised to work with MDM710    - Irv Hoff
  103. ; 05/27/83 - Updated to work with MDM709    - Irv Hoff
  104. ; 05/15/83 - Revised to work with MDM708    - Irv Hoff
  105. ; 04/11/83 - Updated to work with MDM707    - Irv Hoff
  106. ; 04/04/83 - First version of this file        - Irv Hoff
  107. ;
  108. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  109. ;
  110. BELL:        EQU    07H        ;bell
  111. CR:        EQU    0DH        ;carriage return
  112. ESC:        EQU    1BH        ;escape
  113. LF:        EQU    0AH        ;linefeed
  114. ;
  115. YES:        EQU    0FFH
  116. NO:        EQU    0
  117. ;
  118. ;------------------------------------------------------------------------------
  119. ; The following equates are addresses in the main program of MDM730.COM.  If
  120. ; this overlay is adapted to a later version, these may have to be changed.
  121. ;
  122. PMMIMENU:    EQU    09EDH        ;addr of SPCLMENU in basic program 
  123.                     ;available as extra patch area.
  124.                     ;For MDM730 use 09EDH
  125.                     ;For MDM740 use 0A78H
  126.                     ;Must match byte of basic program.
  127. ;
  128. START:        EQU    13CAH        ;addr of START in basic program.
  129.                      ;For MDM730-740 use 13CAH
  130. ;
  131. SPEED4:        EQU    1A7EH        ;addr of SPEED4 in basic program.
  132.                     ;For MDM730-740 use 1A7EH
  133. ;
  134. TERML:        EQU    1F01H        ;addr of TERML in basic program.
  135.                     ;Use 1F01 for MDM730-740
  136. ;
  137. GRAFMASK:    EQU    TERML+10    ;addr of 7th bit mask in TERML
  138. ;
  139. BYEBYE:        EQU    404DH        ;addr of BYEBYE in basic program.
  140.                     ;For MDM730-740 use 404DH
  141. ;
  142. ;------------------------------------------------------------------------------
  143. ; The following information is specific to the Epson QX-10.
  144. ;
  145. PORT:        EQU    011H        ;QX-10 base port
  146. MODCTL1:    EQU    PORT+2        ;Modem control port
  147. MODDATP:    EQU    PORT        ;Modem data in port
  148. MODDATO:    EQU    PORT        ;Modem data out port
  149. TPORTS:        EQU    007H        ;Baud rate setup port
  150. TPORTC:        EQU    006H        ;Baud rate counter port
  151. MODRCVB:    EQU    1        ;Bit to test for receive
  152. MODRCVR:    EQU    1        ;Value when ready
  153. MODSNDB:    EQU    4        ;Bit to test for send
  154. MODSNDR:    EQU    4        ;Value when ready
  155. CRAM:        EQU    35        ;CMOS RAM baud rate storage
  156. MOSADR:        EQU    3DH        ;CMOS RAM address port
  157. MOSDAT:        EQU    3CH        ;CMOS RAM data port
  158. ;
  159.         ORG    100H
  160. ;.....
  161. ; Change the clock speed to suit your system
  162. ;
  163.         DS    3    ;(for  "JMP   START" instruction)
  164. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem, no=non-PMMI    103H
  165. AUTODIAL:    DB    YES    ;yes=HAYES Smartmodem or lookalike    104H
  166. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  167. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  168.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  169. MSPEED:        DB    1    ;When booting up, the program will set  107H
  170.                 ;this flag to match the QX-10's current
  171.                 ;CMOS baud rate.
  172. BYTDLY:        DB    5    ;0=0 delay, 1=10ms, 5=50ms - 9=90ms     108H
  173.                 ;default time to send character in ter-
  174.                 ;minal mode file transfer for slow BBS.
  175. CRDLY:        DB    5    ;0=0 delay, 1=100ms, 5=500ms - 9=900ms  109H
  176.                 ;default time for extra wait after CRLF
  177.                 ;in terminal mode file transfer
  178. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  179. SETUPTST:    DB    YES    ;yes=user-added SETUP routine        10BH
  180. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  181. RETRY:        DB    YES    ;yes=reset the error limit to try again 10DH
  182.                 ;no=abort after 10 consecutive errors
  183.                 ;(ARPANET users should select yes)
  184. BAKUPBYTE:    DB    YES    ;yes=change any file same name to .BAK    10EH
  185. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  186. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  187. CONVRUB:    DB    NO    ;yes=convert rub to backspace        111H
  188. TOGGLERUB:    DB    YES    ;yes=allow toggling of rub to backspace    112H
  189. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  190.                 ;terminal mode (added by remote echo)
  191. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  192. TRANLOGON:    DB    YES     ;yes=allow transmission of logon    115H
  193.                 ;write logon sequence at location LOGON
  194. SAVCCP:        DB    NO     ;yes=do not overwrite CCP        116H
  195. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  196.                 ;no=external command if EXTCHR precedes
  197. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  198. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  199. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  200.                 ;sending a file in terminal mode
  201. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  202.                 ;sending a file in terminal mode
  203. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  204. IGNORCTL:    DB    NO     ;yes=CTL-chars above ^M not displayed    11DH
  205. TPMFLG:        DB    NO    ;set by the program, always no here    11EH
  206. VALFLG:        DB    NO    ;set by the program, always no here    11FH
  207. BRKCHR:        DB    'B'-40H    ;^B = Send 300 ms. break tone        120H
  208.                 ;(CP/M A & B don't permit CONTROL-@)
  209. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  210. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  211. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  212. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  213. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  214. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  215. EXTCHR:        DB    'Z'-40H    ;^Z = Send next character        127H
  216.                 ;(CP/M A doesn't permit CONTROL-^ while
  217.                 ;..CP/M B requires SHIFT CONTROL-^ to get
  218.                 ;..the character, so we standardized with this)
  219.         DS    2    ;                    128H
  220. ;.....
  221. ; Handles in/out ports for data and status:
  222. ;
  223. IN$MODCTL1:    IN    MODCTL1 ! RET    ;in modem control port             12AH
  224.                     ;INITMOD makes this a jump to SYSI$STAT
  225.                     ;when run under VALDOCS
  226.         DS    7        ;spares
  227. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  228.                     ;INITMOD makes this a jump to SYSI$OUT
  229.                     ;when run under VALDOCS
  230.         DS    7        ;spares
  231. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  232.                     ;INITMOD makes this a jump to SYSI$IN
  233.                     ;when run under VALDOCS
  234.         DS    7        ;spares
  235. ANI$MODRCVB:    ANI    MODRCVB    ! RET    ;bit to test for receive ready    148H
  236. CPI$MODRCVR:    CPI    MODRCVR    ! RET    ;value of rcv. bit when ready    14BH
  237. ANI$MODSNDB:    ANI    MODSNDB    ! RET    ;bit to test for send ready    14EH
  238. CPI$MODSNDR:    CPI    MODSNDR    ! RET    ;value of send bit when ready    151H
  239.         DS    6        ;bypasses PMMI routines        156H
  240. ;
  241. OUT$MODCTL1:    RET    ! NOP     ! NOP    ;out modem control port #1    15AH
  242. OUT$MODCTL2:    RET     ! NOP     ! NOP    ;out modem control port #2    15DH
  243. ;
  244. LOGONPTR:    DW    LOGON        ;for user message.        160H
  245.         DS    3        ;do not change            162H
  246. JMP$DISCONNT:    RET    ! NOP    ! NOP    ;not needed with QX-10/Smartmdm 165H
  247. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  248. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  249.         RET     ! NOP     ! NOP    ;(by-passes PMMI routine)    16EH
  250.         RET     ! NOP     ! NOP    ;(by-passes PMMI routine)    171H
  251.         RET     ! NOP     ! NOP    ;(by-passes PMMI routine)    174H
  252. JMP$SETUPR:    JMP    SETUPR        ;                177H
  253. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  254. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  255. JMP$BREAK:    JMP    SENDBRK        ;INITMOD makes this a        180H
  256.                     ;jump to SYSI$BREAK when run 
  257.                     ;under VALDOCS
  258. ; Do not change the following six lines.  They go to specific locations in the 
  259. ; main program, not the overlay.
  260. ;
  261. JMP$ILPRT:    DS    3        ;                183H
  262. JMP$INBUF:    DS    3        ;                186H
  263. JMP$INLNCOMP:    DS    3        ;                189H
  264. JMP$INMODEM:    DS    3        ;                18CH
  265. JMP$NXTSCRN:    DS    3        ;                18FH
  266. JMP$TIMER:    DS    3        ;                192H
  267. ;.....
  268. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  269. ; SCRNTEST to YES at 010CH (above).  Room allowed for four bytes.  Last zero
  270. ; needed for stopping the string display.  Any extra zeros just act as NOPs.
  271. ;
  272. CLREOS:        CALL    JMP$ILPRT    ;                195H
  273.         DB    ESC,059H,0,0,0    ;Hex code for ESC Y        198H
  274.         RET            ;                19DH
  275. ;
  276. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  277.         DB    01AH,0,0,0,0    ;Hex for Control Z        1A1H
  278.         RET            ;                1A6H
  279. ;.....
  280. ; NOTE:  You can change the SYSVER and LOGON messages to be longer or
  281. ;        shorter.  The following overlay routines must terminate before 0400H.
  282. ;
  283. SYSVER:        CALL    CPMMODE        ;Set CP/M emulation mode    1A7H   
  284.         CALL    CLRSCRN        ;
  285.         CALL    JMP$ILPRT    ;
  286.         DB    ESC,3DH,2AH,3DH,'WELCOME TO QX-MODEM'
  287.         DB    ESC,3DH,2CH,3DH,'For the Epson QX-10'
  288.         DB    ESC,3DH,2EH,3FH,0
  289.         RET
  290. ;.....
  291. ; You can put a message at this location which will be called up with
  292. ; CTL-L if TRANLOGON has been set TRUE.  In this overlay version, approximately
  293. ; 8 bytes are available for LOGON message.  A common usage of this feature is
  294. ; 'FIRSTNAME;LASTNAME;PASSWORD' separated by semi-colons for use in signing
  295. ; on to remote bulletin boards with only one keystroke.  The logon capability
  296. ; has lost much of its importance with the addition of function keys to the 
  297. ; program.  The length of this overlay has left little room for the logon
  298. ; sequence.  End with a 0.
  299. ;
  300. LOGON:        DB    'Hello',CR,LF,0
  301. ;.....
  302. ; Sets DTR low for 300ms
  303. ;
  304. GOODBYE:    MVI    A,5        ;point to register 5
  305.         OUT    MODCTL1        
  306.         LDA    TXBYT        ;fetch the most recent TXBYT sent
  307.         ANI    7FH        ;set the DTR bit low
  308. ;
  309. GOODBYE1:    OUT    MODCTL1        ;send it
  310.         MVI    B,3        ;delay 300ms
  311.         CALL    JMP$TIMER
  312.         MVI    A,5        ;point to register 5
  313.         OUT    MODCTL1
  314.         LDA    TXBYT        ;restore previous condition by sending
  315.         OUT    MODCTL1        ;..the original TXBYT
  316.         RET
  317. ;.....
  318. ; This is a continuation of BYEBYE from end of overlay.
  319. ;
  320. BYEBYE1:    RZ            ;if CP/M, back to main program
  321.         LDA    VALFLG        ;if not CP/M, is it VALDOCS?
  322.         ORA    A
  323.         CZ    TPMMSG        ;no? then print TPM
  324.         CNZ    VALMSG        ;if yes, then VALDOCS
  325.         RET            ;back to main program
  326. ;.....
  327. ; The following SENDBRK routine sends a break tone to reset some time-share
  328. ; computers, such as BRS After Dark and Dialog's Knowledge Index.  However, it
  329. ; will usually cause an immediate disconnect when on line with an RBBS/RCPM
  330. ; system.  This routine is automatically replaced by SYSI$BREAK if run under
  331. ; VALDOCS.
  332. ;
  333. SENDBRK:        MVI        A,5        ;point to register 5
  334.                 OUT        MODCTL1
  335.                 LDA        TXBYT          ;get TXBYT currently in use      
  336.         ORI    10H        ;turn sendbreak bit on
  337.             JMP     GOODBYE1
  338. ;.....
  339. ; This routine shuttles from TPM to CP/M 
  340. ;
  341. CPMMODE:    LXI    D,0CCCCH    ;Put request for CP/M in D reg
  342. BDOSMODE:    MVI    C,12
  343.         JMP    5
  344. ;......
  345. ; This routine sets the CLOCK equate for computations at the very beginning of
  346. ; the main program.
  347. ;
  348. CLOCKSET:    LXI    H,0        ;Set HL to 0 since these three bytes
  349.                     ;were stolen from main program START
  350.                     ;subroutine
  351.         CALL    CPMMODE        ;get system version
  352.         MOV    A,E
  353.         CPI    'T'        ;is this CP/M?
  354.         RNZ            ;if CP/M, quit here
  355.         MVI    A,YES        ;store flag saying TPM in use
  356.         STA    TPMFLG
  357.         LXI    D,0        
  358.         CALL    BACKDOOR    ;if VALDOCS SYSINIT module is not
  359.                     ;loaded, returns 0FFH in A register
  360.         INR    A
  361.         RZ            ;If no SYSINIT, quit here
  362.         MVI    A,YES        ;tell flag that VALDOCS is loaded
  363.         STA    VALFLG
  364.         MVI    A,2        ;Replace clock value with this to
  365.         STA    CLOCK        ;..reduce apparent speed for overhead
  366.                     ;..calls if using VALDOCS
  367.         RET
  368. ;.....
  369. ; This routine checks to see what system the program is running under.  It
  370. ; announces it at signon and, if VALDOCS SYSINIT module is loaded, it rewrites
  371. ; code to direct the use of backdoor subroutines needed by VALDOCS.  
  372. ;
  373. INITMOD:    CALL     JMP$ILPRT
  374.         DB    '[ Using ',0
  375.         LDA     TPMFLG        ;is this CP/M or TPM?
  376.         ORA    A
  377.         PUSH    PSW
  378.         CZ    CPMMSG        ;if CP/M, go get message
  379.         POP    PSW
  380.         JZ    NOSYSINIT    ;..and go back to work
  381.         LDA    VALFLG        ;we're this far, must be TPM or VALDOCS
  382.         ORA    A        ;which is it?
  383.         PUSH    PSW
  384.         CZ    TPMMSG        ;if TPM, go get message
  385.         POP    PSW
  386.         JZ    NOSYSINIT    ;..and then skip ahead
  387.         CALL    VALMSG        ;now this far, must be VALDOCS
  388.         MVI    A,0C3H        ;Mod modem I/O to use BACKDOOR routines
  389.         STA    IN$MODCTL1
  390.         STA    OUT$MODDATP
  391.         STA    IN$MODDATP
  392.         LXI    H,SYSI$STAT
  393.         SHLD    IN$MODCTL1+1
  394.         LXI    H,SYSI$OUT
  395.         SHLD    OUT$MODDATP+1
  396.         LXI    H,SYSI$IN
  397.         SHLD    IN$MODDATP+1
  398.         LXI    H,SYSI$BREAK
  399.         SHLD    JMP$BREAK+1
  400.         MVI    A,2
  401.         STA    ANI$MODSNDB+1
  402.         STA    CPI$MODSNDR+1
  403.         MVI    A,11H        ;load op code for LXI D and then store
  404.         STA    SPEED4        ;..speed to insure correct...
  405.         LXI    H,1275        ;..timing is used under VALDOCS...
  406.         SHLD    SPEED4+1    ;..for ^T text transfers
  407.         MVI    A,0        ;put NOP to fill
  408.         STA    SPEED4+3
  409.         LXI    D,4FFH        ;Re-enable BACKDOOR interrupt stuff
  410.         CALL    BACKDOOR
  411. ;.....
  412. ; If SYSINIT was not loaded, program comes here to see if carrier is present
  413. ; (DCD active), and then reset the modem if not. 
  414. ;    
  415. NOSYSINIT:    CALL    JMP$ILPRT    ;send cursor to bottom of page
  416.         DB    ESC,3DH,36H,20H,0
  417.         MVI     A,CRAM        ;point to QX-10 CMOS baud rate address
  418.         DI            ;disable interrupts
  419.         OUT    MOSADR        ;
  420.         IN    MOSDAT        ;get CMOS status byte
  421.         EI            ;enable interrupts
  422.         ANI    0FH        ;set flags & strip off all but baudrate
  423.         CPI    3        ;operating at 300 baud?
  424.         JNZ     TEST1200    ;if not, see if 1200
  425.         LXI    H,CSPDTBL+12    ;if 300, point to that speed in table
  426. NOSYSINIT1:    MOV    E,M        ;load baudrate into D-E
  427.         INX    H        
  428.         MOV    D,M
  429.         XCHG            ;now put it in H-L
  430.         CALL    FINDRATE    ;tell the timer and set MSPEED flag
  431. NOSYSINIT2:    CALL    SIOINIT        ;send out default SIO initialization
  432.         CALL     IN$MODCTL1    ;look at status of DCD
  433.         ANI    8        ;is connection active?
  434.         RNZ            ;if yes, initialization already done
  435.         LXI    H,MDMRESET
  436.         CALL    SEND        ;Reset the modem
  437.         RET
  438. ;.....
  439. ; If baudrate set on CMOS was not 300, program comes here to see if it is 1200
  440. ; baud.  If not, a prompt is called to allow user to set either 300 or 1200.
  441. ; The Smartmodem can only be addressed at those two speeds.
  442. ;
  443. TEST1200:    CPI    5        ;is it 1200 baud?
  444.         PUSH    PSW        ;save the flags
  445.         CNZ    AGAIN        ;if not, means we weren't at 300 or
  446.                     ;1200, so get a SET prompt to fix.
  447.         POP    PSW        ;bring flags back
  448.         JNZ    NOSYSINIT2    ;continue with new speed from prompt
  449.         LXI    H,CSPDTBL+20    ;was 1200, so point to 1200 in table
  450.         JMP     NOSYSINIT1    ;back to work
  451. ;.....
  452. ; This series of bytes initialize the Smartmodem, and are taken from the
  453. ; owner's manual.
  454. ;
  455. MDMRESET:    DB    'ATE1M1Q0V1S0=0S11=55',CR,0
  456.                     ;E1=set switch 4, echo on in local cmd
  457.                     ;M1=speaker on til carrier detect
  458.                     ;Q0=set switch 3, result codes sent
  459.                     ;V1=set switch 2, word result codes
  460.                     ;S0=0=set switch 5, mdm will not answer
  461.                     ;S11=55=touchtone dial speed
  462.                     ;CR,0=send it. Must end with a zero
  463. ;
  464. CPMMSG:        CALL    JMP$ILPRT
  465.         DB    'CP/M ]',0
  466.         RET
  467. ;
  468. TPMMSG:        CALL    JMP$ILPRT
  469.         DB    'TPM ]',0
  470.         RET
  471. ;
  472. VALMSG:        CALL     JMP$ILPRT
  473.         DB    'VALDOCS ]',0
  474.         RET
  475. ;.....
  476. ; This subroutine is used in place of SENDBRK when running under VALDOCS
  477. ;
  478. SYSI$BREAK:    PUSH    D
  479.         LXI    D,07FFH        ;send break  
  480.         CALL    BACKDOOR
  481.         MVI    B,3        ;wait 300ms
  482.         CALL     JMP$TIMER
  483.         LXI    D,0700H     ;turn sendbreak off
  484.         CALL    BACKDOOR
  485.         POP     D
  486.         RET
  487. ;.....
  488. ; This subroutine is called in place of IN MODCTL1 when running under VALDOCS
  489. ;
  490. SYSI$STAT:    PUSH    D
  491.         MVI    D,3        ;Get SYSINIT serial port status byte
  492.                     ;and return it in the A register
  493.         CALL    BACKDOOR
  494.         POP    D
  495.         RET
  496. ;
  497. ;.....
  498. ; This subroutine is called in place of OUT MODDATP when running under VALDOCS
  499. ;
  500. SYSI$OUT:    PUSH    D
  501.         PUSH    PSW
  502.         MOV    E,A        ;get char to send from A and move to E
  503.         MVI    D,2        ;send it
  504.         CALL    BACKDOOR
  505.         POP    PSW
  506.         POP    D
  507.         RET
  508. ;
  509. ;......
  510. ; This subroutine is called in place of IN MODDATP when running under VALDOCS
  511. ;
  512. SYSI$IN:    PUSH    D
  513.         MVI    D,1        ;receive a character, put it in A
  514.         CALL    BACKDOOR
  515.         POP    D
  516.         RET
  517. ;.....
  518. ; This back door subroutine (BDS03) provides support for the B side of
  519. ; the 7201 MPSCC, otherwise known as the "serial port", when using VALDOCS.  
  520. ;
  521. BACKDOOR:    PUSH    H        ;Save unused registers
  522.         PUSH    B
  523.         PUSH    D        ;Save BACKDOOR call arguments
  524.         LXI    D,0AAAAH    ;Set TPM mode
  525.         CALL    BDOSMODE
  526.         POP    D        ;Get back BACKDOOR arguments
  527.         LXI    B,(3 SHL 8)+40    ;Function codes for BACKDOOR serial
  528.                     ;routines, 3 (BDS03) in the B reg
  529.                     ;and 40 in the C reg.
  530.         CALL    5        ;Call TPM
  531.         PUSH    PSW        ;Save result of BACKDOOR call
  532.         CALL    CPMMODE        ;Go back into CP/M mode
  533.         POP    PSW        ;Restore BACKDOOR result
  534.         POP    B        ;Restore registers
  535.         POP    H
  536.         RET
  537. ;.....
  538. ; Sends out the serial I/O initialization
  539. ;
  540. SIOINIT:    PUSH    H
  541.         MVI    C,MODCTL1    ;modem control port
  542.         MVI    B,MINLEN    ;length of modem init table
  543.         LXI    H,MINTBL    ;point to init table
  544.         DB    0EDH,0B3H    ;sneak in Z80 op code to OTIR the init
  545.                     ;table
  546.         POP    H
  547.         RET
  548. ;.....
  549. ; Modem initialization table.  Default settings: 8 bit words, no parity, 1 stop
  550. ; bit, transmit and receive enabled.
  551. ;
  552. MINTBL:        DB    4        ;point to register 4
  553. PARBYT:        DB    44H        ;the parity byte
  554.         DB    3        ;point to register 3
  555. RXBYT:        DB    0C1H        ;the receive byte 
  556.         DB    5        ;point to register 5
  557. TXBYT:        DB    0EAH        ;the transmit byte
  558. MINLEN:        EQU    $-MINTBL
  559. ;
  560. EVNPAR:        LXI    B,0FC03H
  561. SETPAR:        LDA    PARBYT
  562.         ANA    B
  563.         ORA    C
  564.         STA    PARBYT
  565. SETPXX:        CALL    SIOINIT    
  566.         JMP    GDLUP        ;go back for another parameter
  567. ;
  568. ODDPAR:        LXI    B,0FC01H
  569.         JMP    SETPAR
  570. ;
  571. NOPAR:        LXI    B,0FC00H
  572.         JMP    SETPAR
  573. ;
  574. ONESTOP:    LXI    B,0F304H
  575.         JMP    SETPAR
  576. ;
  577. TWOSTOP:    LXI    B,0F30CH
  578.         JMP    SETPAR
  579. ;
  580. BIT7:        MVI    A,7FH        ;load mask in A
  581.         STA    GRAFMASK    ;store it in main program TERML routine
  582.         MVI    A,41H
  583.         STA    RXBYT
  584.         MVI    A,0AAH
  585. BIT7XX:        STA    TXBYT
  586.         JMP    SETPXX
  587. ;
  588. GRAFON:        MVI    A,0FFH        ;load mask in A
  589.         STA    GRAFMASK    ;store it at TERML, lets 7th bit pass
  590.         JMP    BIT8
  591. ;
  592. GRAFOFF:    MVI    A,7FH        ;load mask in A
  593.         STA    GRAFMASK    ;store it at TERML, stops 7th bit
  594. BIT8:        MVI    A,0C1H        
  595.         STA    RXBYT
  596.         MVI    A,0EAH
  597.         JMP    BIT7XX
  598. ;.....
  599. ; Make modem's speed flag match QX-10's
  600. ;
  601. SETMSPEED:    MVI    A,CRAM        ;point to baudrate address
  602.         DI            ;stop interrupts
  603.         OUT    MOSADR        
  604.         IN    MOSDAT        ;get status byte
  605.         EI            ;ok to interrupt now
  606.         ANI    0FH        ;strip all but baudrate, set flags
  607.         LXI    H,MSPDTBL    ;load HL with table address
  608.         ADD    L        ;make the conversion
  609.         MOV    L,A        ;
  610.         JNC    SETMSPD2    ;carry? if not, jump
  611.         INR    H        ;if yes, increment MSB of pointer
  612. ;
  613. SETMSPD2:    MOV    A,M        ;move table value to register A
  614.         STA    MSPEED        ;store it at MSPEED
  615.         RET
  616. ;
  617. ;.....
  618. ; This table gives MSPEED values for QX-10 CMOS baud rate values.
  619. ; Note that lower rates do not match and approximations are used.
  620. ;
  621. MSPDTBL:    DB    0,0,0,1,3,5,6,7,8,2
  622. ;
  623. TBLADR:        DW    0
  624. ;
  625. ;******************************************************************************
  626. ;          NOTE: All above overlay routines must end before 0400H
  627. ;******************************************************************************
  628. ;
  629.         ORG    PMMIMENU    ;pop over to second patch area
  630.                     ;(overlays PMMI special menu)
  631. ;.....
  632. ; Clock speed table.  This gives the timer chip divisors for each baud rate.
  633. ; Must be in same order as MSPDTBL.
  634. ;
  635. CSPDTBL:    DW    110,1135     ; 0
  636.         DW    135,924         ; 1
  637.         DW    150,832         ; 2
  638.         DW    300,416         ; 3
  639.         DW    600,208         ; 4
  640.         DW    1200,104     ; 5
  641.         DW    2400,52         ; 6
  642.         DW    4800,26         ; 7
  643.         DW    9600,13         ; 8
  644.         DW    450,277         ; 9
  645. ;
  646. NXTARG:        CALL    SCNTOB
  647.         RC
  648. ;
  649. SCNNB:        LDAX    D
  650.         CPI    ' '
  651.         RNZ
  652.         INX    D
  653.         DCR    B
  654.         JNZ    SCNNB
  655.         STC
  656.         RET
  657. ;
  658. SCNTOB:        LDAX    D
  659.         CPI    ' '
  660.         RZ
  661.         RC
  662.         INX    D
  663.         DCR    B
  664.         JNZ    SCNTOB
  665.         STC
  666.         RET
  667.  
  668. ;
  669. KEYBUF:        DB    10
  670.         DB    0,0,0,0,0,0
  671.         DB    0,0,0,0,0,0
  672. ;..... 
  673. ; Send a string to the Smartmodem
  674. ;
  675. SEND:        MOV    A,M        ;Get a character
  676.         INX    H
  677.         ORA    A        ;End of the string?
  678.         RZ
  679.         MOV    C,A        ;No, send it
  680.         CALL    PUT
  681.         CALL    JMP$INMODEM    ;Eat echo
  682.         JMP    SEND
  683. ;
  684. PUT:        CALL    IN$MODCTL1    ;Get modem status
  685.         CALL    ANI$MODSNDB    ;Test send bits
  686.         CALL    CPI$MODSNDR
  687.         JNZ    PUT
  688.         MOV    A,C
  689.         JMP    OUT$MODDATP
  690. ;.....
  691. ; The following routine changes the baud rate, parity and word length for
  692. ; the QX-10 from the SET menu.
  693. ;
  694. SETUPR:        LDAX    D        ;Look at passed-in byte count
  695.         CPI    5        ;Enuf for possible baud rate?
  696.         JC    AGAIN        ;No, prompt for one
  697.         MOV    B,A        ;Save byte count
  698.         INX    D        ;Point to first byte
  699.         CALL    NXTARG        ;Skip to next argument
  700.         MOV    A,B
  701.         JNC    SETUP1
  702. ;
  703. AGAIN:        CALL    JMP$ILPRT
  704.         DB    'Enter Baud Rate and/or Options: ',0
  705.         LXI    D,KEYBUF
  706.         CALL    JMP$INBUF    ;read baud rate from console
  707.         LXI    D,KEYBUF+1
  708.         LDAX    D
  709.         INX    D
  710. ;
  711. SETUP1:        MOV    L,A        ;Force null at end of buffer
  712.         MVI    H,0        
  713.         DAD    D
  714.         MVI    M,0
  715.         LXI    H,0
  716. ;
  717. GDLUP:        LDAX    D
  718.         INX    D
  719.         ORA    A
  720.         JZ    GDONE
  721.         CPI    ' '        ;Ignore spaces
  722.         JZ    GDLUP
  723.         SUI    '0'        ;Try for digit
  724.         JC    BADRATE
  725.         CPI    10
  726.         JNC    BADRATE
  727.         MOV    B,H
  728.         MOV    C,L
  729.         DAD    H
  730.         DAD    H
  731.         DAD    B
  732.         DAD    H
  733.         MVI    B,0
  734.         MOV    C,A
  735.         DAD    B
  736.         JMP    GDLUP
  737. ;
  738. BADRATE:    ADI    '0'        ;Fix bias from conversion routine
  739.         CPI    'E'        ;Check option letters for
  740.         JZ    EVNPAR        ;Even parity
  741.         CPI    'O'
  742.         JZ    ODDPAR        ;Odd parity
  743.         CPI    'N'
  744.         JZ    NOPAR        ;No parity
  745.         CPI    'S'
  746.         JZ    ONESTOP        ;One stop bit
  747.         CPI    'T'
  748.         JZ    TWOSTOP        ;Two stop bits
  749.         CPI    'A'
  750.         JZ    BIT7        ;ASCII mode (7 data bits)
  751.         CPI    'B'
  752.         JZ    GRAFOFF        ;Binary mode (8 data bits) with 7th bit
  753.                     ;masked
  754.         CPI    'G'
  755.         JZ    GRAFON        ;8 data bits, but with no masking to
  756.                     ;permit use of QX-10 graphics in
  757.                     ;terminal mode
  758.         CALL    JMP$ILPRT    ;Anything else gets error
  759.         DB    CR,LF,'[ Invalid rate ]',CR,LF,0
  760.         JMP    AGAIN
  761. ;
  762. GDONE:        MOV    A,H
  763.         ORA    L
  764.         JZ    QUIT
  765. ;.....
  766. ; Enter here with baud rate in HL to set baud rate of timer.
  767. ;
  768. FINDRATE:    PUSH    H        ;save baud rate
  769.         LXI    H,CSPDTBL    ;load table address
  770.         SHLD    TBLADR        ;store it there
  771.         POP    H        ;get baud back
  772.         LXI    B,0A00H        
  773. ;
  774. CLP:        PUSH    H
  775.         LHLD    TBLADR        ;get address back
  776.         MOV    E,M        ;move value to E
  777.         INX    H        ;advance pointer
  778.         MOV    D,M        ;other half in D
  779.         INX    H
  780.         XTHL            
  781.         XCHG            ;switch
  782.         ORA    A        ;prepare for true subtract by clearing
  783.         DB    0EDH,52H    ;sneak in Z80 op code to SBC HL,DE
  784.         XCHG            ;switch again
  785.         XTHL
  786.         JZ    DOIT
  787.         INX    H
  788.         INX    H
  789.         SHLD    TBLADR
  790.         POP    H
  791.         INR    C
  792.         DCR    B
  793.         JNZ    CLP
  794.         JMP    BADRATE
  795. ;
  796. DOIT:        POP    D        
  797.         MVI    A,0B6H
  798.         OUT    TPORTS
  799.         MOV    A,M
  800.         INX    H
  801.         OUT    TPORTC
  802.         MOV    A,M
  803.         OUT    TPORTC
  804.         CALL    IN$MODDATP
  805.         CALL    IN$MODDATP
  806.         MVI    A,CRAM
  807.         DI            ;Disable interrupts
  808.         OUT    MOSADR
  809.         MOV    A,C
  810.         OUT    MOSDAT
  811.         EI            ;Enable interrupts
  812. ;
  813. QUIT:        JMP    SETMSPEED
  814. ;.....
  815. ; This special menu is unavailable without putting the actual address of
  816. ; SPCLMENU (in the basic program) in the overlay above at the PMMIMENU equate.
  817. ;
  818. SPCLMENU:    CALL    JMP$NXTSCRN
  819.         CALL    JMP$ILPRT
  820.         DB    '        Additional SET options for QX-10',cr,lf,lf
  821.         DB    '  Parity:',cr,lf
  822.         DB    '    E - Even',cr,lf
  823.         DB    '    O - Odd',cr,lf
  824.         DB    '    N - None',cr,lf,lf
  825.         DB    '  Stop bits:',cr,lf
  826.         DB    '    S - Single (1)',cr,lf
  827.         DB    '    T - Two    (2)',cr,lf,lf
  828.         DB    '  Data bits (word length):',cr,lf
  829.         DB    '    A - ASCII mode (7 data bits)',cr,lf
  830.         DB    '    B - Binary mode (8 data bits)',cr,lf
  831.         DB    '    G - Graphics mode (8 data bits, no masking)'
  832.         DB    CR,LF,LF
  833.         DB    '  Examples:',cr,lf
  834.         DB    '    SET 300ETA',cr,lf
  835.         DB    '    SET B',cr,lf
  836.         DB    '    SET NSG 1200',cr,lf
  837.         DB    0
  838.         RET
  839. ;
  840. ;******************************************************************************
  841. ;    NOTE:  THE ABOVE MUST TERMINATE PRIOR TO 0CBB FOR MDM730 THRU MDM740.
  842. ;******************************************************************************
  843. ;
  844. ;.....
  845. ; This routine modifies the basic program to call CLOCKSET before timing rates
  846. ; are computed.  The overlayed bytes (LXI H,0) are placed at the beginning
  847. ; of CLOCKSET.
  848. ;    
  849.         ORG    START
  850.         CALL    CLOCKSET
  851. ;.....
  852. ; This subroutine overlays BYEBYE of basic program to add capability of send-
  853. ; ing correct signoff messages as program exits through BYE command.
  854. ;     
  855.             ORG    BYEBYE+20
  856.         DB    CR,LF,'[ Exit to ',0
  857.         LDA    TPMFLG        ;is this CP/M or TPM?
  858.         ORA    A
  859.         CZ    CPMMSG        ;if CP/M, go get message
  860.         CALL    BYEBYE1        ;go continue this
  861. ;
  862.         END    
  863. ;