home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / MODEM7 / M7NH-2.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  10KB  |  316 lines
  1. ; M7NH-2.ASM -- North Star Horizon - HSIO-4 overlay file for MDM7xx. 01/14/84
  2. ;
  3. ; This overlay adapts the MDM7xx program to the North Star Horizon
  4. ; HSIO-4 serial I/O board. It uses the 8251 USART.
  5. ;
  6. ; You will want to look this file over carefully. There are a number of
  7. ; options that you can use to configure the program to suit your taste.
  8. ; It supports all the baud rates that the HSIO-4 supports even
  9. ; when it is not likeley you are running a dial up modem at that
  10. ; speed. I.E. 19200 baud. This still could be useful for a direct
  11. ; connection between two systems though.
  12. ;
  13. ; Edit this file for your preferences then follow the "TO USE:" example
  14. ; shown below.
  15. ;
  16. ;    TO USE: First edit this file filling in answers for your own
  17. ;        equipment.  Then assemble with ASM.COM or equivalent
  18. ;        assembler.  Then use DDT to overlay the the results
  19. ;        of this program to the original .COM file:
  20. ;
  21. ;        A>DDT MDM7xx.COM
  22. ;        DDT VERS 2.2
  23. ;        NEXT  PC
  24. ;        4300 0100
  25. ;        -IM712GP.HEX        (note the "I" command)
  26. ;        -R            ("R" loads in the .HEX file)
  27. ;        NEXT  PC
  28. ;        4300 0000
  29. ;        -G0            (return to CP/M)
  30. ;        A>SAVE 66 MDM712.COM    (now have a modified .COM file)
  31. ;
  32. ;    use    A>SAVE 68 MDM715.COM    for ver 7.15 and
  33. ;        A>SAVE 69 MDM716.COM    for ver 7.16
  34. ; Check the .DOC files for other versions.
  35. ;
  36. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  37. ;
  38. ; 01/14/83 - Rnamed and revised for mdm716    - Lloyd Miller
  39. ;        Adapted from MDM712GP.ASM
  40. ; 07/27/83 - Renamed to work with MDM712    - Irv Hoff
  41. ; 07/01/83 - Revised to work with MDM711    - Irv Hoff
  42. ; 07/01/83 - Revised to work with MDM710    - Irv Hoff
  43. ; 05/27/83 - Updated to work with MDM709    - Irv Hoff
  44. ; 05/15/83 - Revised to work with MDM708    - Irv Hoff
  45. ; 04/11/83 - Updated to work with MDM707    - Irv Hoff
  46. ; 04/04/83 - First version of this file        - Irv Hoff
  47. ;
  48. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  49. ;
  50. BELL:        EQU    07H        ;bell
  51. CR:        EQU    0DH        ;carriage return
  52. ESC:        EQU    1BH        ;escape
  53. LF:        EQU    0AH        ;linefeed
  54. ;
  55. YES:        EQU    0FFH
  56. NO:        EQU    0
  57. ;
  58. ;
  59. ; Change the following information to match your equipment
  60. ;
  61. ; THE FOLLOWING EQU CORRESPONDS TO PORT A OF THE HSIO-4
  62. ; 
  63. PORT:        EQU    010H
  64. MODCTL1:    EQU    PORT+3        ;MODEM CONTROL PORT
  65. MODDATP:    EQU    PORT+2        ;MODEM DATA IN PORT
  66. MODDATO:    EQU    PORT+2        ;MODEM DATA OUT PORT
  67. BAUDRP:        EQU    PORT        ;BAUD RATE PORT
  68. MODRCVB:    EQU    2        ;BIT TO TEST FOR RECEIVE
  69. MODRCVR:    EQU    2        ;VALUE WHEN READY
  70. MODSNDB:    EQU    1        ;BIT TO TEST FOR SEND
  71. MODSNDR:    EQU    1        ;VALUE WHEN READY
  72. ;
  73.         ORG    100H
  74. ;
  75. ;
  76. ; Change the clock speed to suit your system
  77. ;
  78.         DS    3    ;(for  "JMP   START" instruction)
  79. ;
  80. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  81. SMARTMODEM:    DB    NO    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  82. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  83. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  84.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  85. MSPEED:        DB    5    ;0=110 1=300 2=450 3=600 4=710 5=1200   107H
  86.                 ;6=2400 7=4800 8=9600 9=19200 default
  87. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
  88.                 ;default time to send character in ter-
  89.                 ;minal mode file transfer for slow BBS.
  90. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  91.                 ;default time for extra wait after CRLF
  92.                 ;in terminal mode file transfer
  93. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  94. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  95. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  96. ;
  97. ; ACKNAK IS OBSOLETE
  98.         DS    1
  99. ;ACKNAK:    DB    NO    ;yes=resend a record after any non-ACK    10DH
  100.                 ;no=resend a record after a valid-NAK
  101. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  102. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  103. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  104. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  105. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  106. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  107.                 ;terminal mode (added by remote echo)
  108. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  109. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  110.                 ;write logon sequence at location LOGON
  111. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  112. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  113.                 ;no=external command if EXTCHR precedes
  114. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  115. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  116. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  117.                 ;sending a file in terminal mode
  118. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  119.                 ;sending a file in terminal mode
  120. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  121. IGNORCTL:    DB    NO    ;yes=CTL-chars above ^M not displayed    11DH
  122. EXTRA1:        DB    0    ;for future expansion            11EH
  123. EXTRA2:        DB    0    ;for future expansion            11FH
  124. BRKCHR:        DB    '@'-40H    ;^@ = Send 300 ms. break tone        120H
  125. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  126. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  127. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  128. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  129. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  130. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  131. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        127H
  132. ;
  133.         DS    2        ;                128H
  134. ;
  135. IN$MODCTL1:    IN    MODCTL1 ! RET    ;in modem control port             12AH
  136.         DS    7
  137. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  138.         DS    7
  139. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  140.         DS    7
  141. ANI$MODRCVB:    ANI    MODRCVB    ! RET    ;bit to test for receive ready    148H
  142. CPI$MODRCVR:    CPI    MODRCVR    ! RET    ;value of rcv. bit when ready    14BH
  143. ANI$MODSNDB:    ANI    MODSNDB    ! RET    ;bit to test for send ready    14EH
  144. CPI$MODSNDR:    CPI    MODSNDR    ! RET    ;value of send bit when ready    151H
  145. ;
  146.         DS    12        ;                156H
  147. ;
  148. LOGONPTR:    DW    LOGON        ;for user message.        160H
  149.         DS    6        ;                162H
  150. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  151. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  152.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    16EH
  153.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    171H
  154.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    174H
  155. JMP$SETUPR:    JMP    SETUPR        ;                177H
  156. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  157. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  158. JMP$BREAK:    JMP    SENDBRK        ;                180H
  159. ;
  160. ;
  161. ; Do not change the following six lines.
  162. ;
  163. JMP$ILPRT:    DS    3        ;                183H
  164. JMP$INBUF    DS    3        ;                186H
  165. JMP$INLNCOMP:    DS    3        ;                189H
  166. JMP$INMODEM    DS    3        ;                18CH
  167. JMP$NXTSCRN:    DS    3        ;                18FH
  168. JMP$TIMER    DS    3        ;                192H
  169. ;
  170. ; 
  171. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  172. ; SCRNTEST to YES at 010AH (above).
  173. ;
  174. ; The following are set up for a Soroc terminal
  175. ;
  176. CLREOS:        CALL    JMP$ILPRT    ;                195H
  177.         DB    ESC,'Y',0,0,0    ;                198H
  178.         RET            ;                19DH
  179. ;
  180. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  181.         DB    ESC,'+',0,0,0    ;                1A1H
  182.         RET            ;                1A6H
  183.     
  184. ;
  185. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  186.         DB    'Version for external modem'
  187.         DB    ' on a North Star Horizon / HSIO-4 port A'
  188.         DB    CR,LF,0
  189.         RET
  190. ;.....
  191. ;
  192. ;
  193. ;-----------------------------------------------------------------------
  194. ;
  195. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  196. ;     end of your last routine should terminate by 0400H (601 bytes
  197. ;     available after start of SYSVER) if using the Hayes Smartmodem
  198. ;     or by address 0C00H (2659 bytes) otherwise.
  199. ;
  200. ;-----------------------------------------------------------------------
  201. ;
  202. ; You can put in a message at this location which can be called up with
  203. ; CTL-O if TRANLOGON has been set TRUE.  You can use several lines if
  204. ; desired.  End with a 0.
  205. ;
  206. LOGON:        DB    'How are you today?',CR,LF,0
  207. ;.....
  208. ;
  209. ;
  210. ; Add your own routine here to send a break tone to reset some time-share
  211. ; computers, if desired.
  212. ;
  213. SENDBRK:
  214.     MVI    A,2FH
  215.     OUT    MODCTL1
  216.     MVI    B,3
  217.     CALL    JMP$TIMER    ;300MS
  218.     JMP    RESUME
  219. ;.....
  220. ;
  221. ;
  222. ; Add your own routine here to put DTR low and/or send a break tone.
  223. ; Check other routines such as MDM709DP.ASM which is using this feature.
  224. ;
  225. GOODBYE:
  226.     MVI    A,18H    ; ERR RESET, SEND BREAK, DROP DTR
  227.     OUT    MODCTL1
  228.     RET
  229. ;.....
  230. ;
  231. ;
  232. ; You can use this area for any special initialization or setup you may
  233. ; wish to include.  Each must stop with a RET.  You can check the other
  234. ; available overlays for ideas how to write your own routines if that
  235. ; may be of some help.
  236. ;
  237. INITMOD:
  238.     MVI    A,3    ; stuff contreg in case it is waiting for sync bytes or
  239.     OUT    MODCTL1    ; has just been reset!
  240.     OUT    MODCTL1
  241.     MVI    A,40H    ; INTERNAL RESET TO USART
  242.     OUT    MODCTL1
  243.     XTHL ! XTHL    ; PAUSE FOR USART TO RESET
  244.     MVI    A,4EH    ; MODE ( ASYNC, 1 STOP, DISABLE PARITY,8BIT)
  245.     OUT    MODCTL1
  246. ; INIT SPEED 300 OR 1200 ONLY ( SET MSPEED BYTE ABOVE FOR INITIAL SPEED
  247.     LDA    MSPEED
  248.     CPI    1
  249.     MVI    A,6
  250.     JZ    INIT300
  251.     MVI    A,4
  252. INIT300:
  253.     OUT    BAUDRP
  254.     JMP    RESUME
  255. ;
  256. SETUPR:
  257.     CALL    JMP$ILPRT
  258.     DB    'SELECT SPEED -',CR,LF,LF
  259.     DB    ' A =   110 BAUD',CR,LF
  260.     DB    ' B =   300',CR,LF
  261.     DB    ' C =   600',CR,LF
  262.     DB    ' D =  1200',CR,LF
  263.     DB    ' E =  2400',CR,LF
  264.     DB    ' F =  4800',CR,LF
  265.     DB    ' G =  9600',CR,LF
  266.     DB    ' H = 19200',CR,LF
  267.     DB    '(CR TO RECONECT WITHOUT SPEED CHANGE)-',0
  268.     LXI    D,BAUDBUF
  269.     CALL    JMP$INBUF
  270.     LDA    BAUDBUF+1
  271.     ORA    A
  272.     JZ    RESUME
  273.     LDA    BAUDBUF+2
  274.     CPI    'H'+1
  275.     JNC    SETUPR
  276.     SUI    'A'
  277.     JC    SETUPR
  278.     ADD    A
  279.     MOV    C,A
  280.     MVI    B,0
  281.     LXI    H,BAUDTAB
  282.     DAD    B
  283.     MOV    A,M
  284.     STA    MSPEED
  285.     INX    H
  286.     MOV    A,M
  287.     OUT    BAUDRP
  288. RESUME:
  289.     MVI    A,37H    ; RTS, ERR RESET, RCV ENA, DTR, XMIT ENA
  290.     OUT    MODCTL1
  291.     RET
  292. BAUDBUF:    DB    1,0
  293.         DS    1
  294. BAUDTAB    DB    0,7
  295.     DB    1,6
  296.     DB    3,5
  297.     DB    5,4
  298.     DB    6,3
  299.     DB    7,2
  300.     DB    8,1
  301.     DB    9,0
  302.  
  303. ;
  304. ;
  305. ; If using the Hayes Smartmodem this is unavailable without a special
  306. ; change.
  307. ;
  308. SPCLMENU:  RET
  309. ;
  310. ;
  311. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  312. ;                 0C00H (without Smartmodem)
  313. ;.....
  314. ;
  315.       END
  316.