home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / MODEM7 / M7MMP4.AQM / M7MM+4.ASM
Assembly Source File  |  2000-06-30  |  38KB  |  1,355 lines
  1. ; M7MM+4.ASM     v4.0       Micromodem ][ overlay file for MDM717.  1/18/84
  2. ;
  3. ; rev 4.0 -    1/18/84      - Revised and renamed to M7MM+4.ASM.  Updated
  4. ;                for use with MDM717.COM.  Fixed bug in dial
  5. ;                retry reporting present in M7MM+3. - mah
  6. ;
  7. ;    *********************************************************
  8. ;    *            C A U T I O N            *
  9. ;    *                            *
  10. ;    *    This overlay will only work with MDM717.COM    *
  11. ;    * Use of this overlay with previous or future revisions *
  12. ;    * of MDM7xx will not result in an executable file.    *
  13. ;    *********************************************************
  14. ;
  15. ; rev 3.0 -    1/16/84     - Revised and renamed to M7MM+3.ASM.  Updated
  16. ;               for use with MDM716.COM.  Added alternate
  17. ;               dialing capability for Micromodem ][/e.
  18. ;               Also added ability to abort during carrier
  19. ;               wait. - mah
  20. ;
  21. ; rev 2.0 -    1/8/84     - Renamed to M7MM+2.ASM.  Added Micromodem ][/e 
  22. ;               support.  Includes touch tone dialing.  Also 
  23. ;               fix auto-redial connect bug. - mah
  24. ;
  25. ; rev 1.4 -    1/8/84     - Changed bank select logic to technique
  26. ;               used by ALS Engineering.  This allowed
  27. ;               more interrupt windows, and compacted
  28. ;               code.  Overlay is now independent of ALS
  29. ;               card and/or BIOS revision - mah
  30. ;
  31. ; rev 1.3 -    12/2/83  - Fixed premature carrier tone problem on
  32. ;               originate call function. - mah
  33. ;
  34. ; rev 1.2 -     12/1/83  - Added conditional code for ALS Rev B Card - mah
  35. ;               Renamed to M712MM+.ASM
  36. ;
  37. ; rev 1.1 -    11/20/83 - Corrected timing in pulse dialing for CP/M 2.2 - mah
  38. ;
  39. ; rev 1.0 -    10/12/83 - Original version (M712MM.ASM)
  40. ;
  41. ;    Written by:    Mark A. Howard - SYSOP
  42. ;            CNY Technical RBBS-RCP/M
  43. ;            315-437-4890
  44. ;            319 Tower Ave
  45. ;            Syracuse, N.Y.  13206
  46. ;
  47. ;
  48. ; This overlay is similar to most of the other overlays available
  49. ; for MDM7xx, but differs in the respect that it not only modifies
  50. ; areas intended for overlays, but also overlays portions of the
  51. ; root program.  This was done to allow use of the logical and I/O
  52. ; procedures built into the program for use with the PMMI modem.
  53. ; The PMMI modem resembles the Micromodem in many respects, and
  54. ; most of the features are available on the Micromodem.
  55. ;
  56. ; It is for this reason that M7MM+4 will only work with MDM717, and
  57. ; further revisions of the root program will cause this overlay to
  58. ; be incompatible.
  59. ;
  60. ;=============================================================================
  61. ;
  62. ;    TO USE: First edit this file filling in answers for your own
  63. ;        equipment.  Also edit the phone number library, M7NM-3.ASM
  64. ;        if the phone directory is desired. Optionally, MDMNUM.COM
  65. ;        may be used to change phone numbers later.  Assemble these
  66. ;        files with ASM.COM or MAC.COM or equivalent assembler. 
  67. ;
  68. ;========================== ASSEMBLY WITH CP/M 2.2 ===========================
  69. ;
  70. ;        Use DDT to overlay the the results of these program(s)
  71. ;        to the original .COM file:
  72. ;
  73. ;        A>DDT MDM717.COM
  74. ;        DDT VERS 2.2
  75. ;        NEXT  PC
  76. ;        4580 0100
  77. ;        -IM7MM+4.HEX        (note the "I" command)
  78. ;        -R            ("R" loads in the .HEX file)
  79. ;        NEXT  PC
  80. ;        4580 0000
  81. ;          * -IM7NM-3.HEX        (get the optional phone library)
  82. ;          * -R
  83. ;          * NEXT  PC
  84. ;          * 4580 0000
  85. ;        -G0            (return to CP/M)
  86. ;        A>SAVE 69 MDM7.COM    (now have a modified .COM file)
  87. ;
  88. ;          * - This step is optional - however editing the number
  89. ;          library and overlaying it in this manner is the only
  90. ;          way to set or modify the alternate dialing strings.
  91. ;
  92. ;======================== ASSEMBLY WITH CP/M 3.0 =========================
  93. ;
  94. ;        Use SID to overlay the results of these program(s)
  95. ;        to the original .COM file:
  96. ;
  97. ;        A>SAVE            (load the CP/M 3.0 SAVE transient)
  98. ;                    (note no messages)
  99. ;        A>SID MDM717.COM    (load the original .COM file)
  100. ;        CP/M 3 SID - Version 3.0
  101. ;        NEXT MSZE  PC  END
  102. ;        4580 4580 0100 xxxx    (xxxx depends on your sys)
  103. ;        #RM7MM+4.HEX        (load overlay, note "R" command)
  104. ;        NEXT MSZE  PC  END
  105. ;        xxxx 4580 0100 xxxx    (xxxx's are insignificant)
  106. ;          * #RM7NM-3.HEX        (get the optional phone # overlay)
  107. ;          * NEXT MSZE  PC  END
  108. ;          * xxxx 4580 0100 xxxx
  109. ;        #G0            (exit SID)
  110. ;
  111. ;        CP/M 3 SAVE - Version 3.0
  112. ;        Enter file (Type return to exit) : MDM7.COM  (name new file)
  113. ;        Beginning hex address 100             (from PC above)
  114. ;        Ending hex address    457F             (MSZE - 1)
  115. ;
  116. ;        A>            (you now have modified .COM file)
  117. ;
  118. ;          * This step is optional - however see note above
  119. ;
  120. ;============================================================================
  121. ;
  122. YES:        EQU    0FFH
  123. NO:        EQU    0
  124. ;
  125. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  126. ;
  127. ; ---------------------> CUSTOMIZATION EQUATES <----------------------
  128. ;
  129. ; --->    Change the following information to match your equipment  <---
  130. ;
  131. CPM2        EQU    NO    ;Apple ][/][+/][/e with most CP/M cards
  132. ALSCARD        EQU    YES    ;Apple ][/][+/][/e with ALS CP/M Card
  133. ;
  134. MMIIE        EQU    NO    ;Yes if Micromodem ][/e
  135. ;
  136. SLOT        EQU    2    ;Micromodem slot (usually 2)
  137. ;
  138. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  139. ;
  140. ;        System equates
  141. ;
  142. FCB          EQU    5CH        ;system FCB area
  143. PRINT        EQU    9        ;print string function
  144. BDOS        EQU    5        ;BDOS jump location
  145. ;
  146. ;        Ascii equates
  147. ;
  148. BELL:        EQU    07H        ;bell
  149. CR:        EQU    0DH        ;carriage return
  150. ESC:        EQU    1BH        ;escape
  151. LF:        EQU    0AH        ;linefeed
  152. CANCEL:        EQU    'X'-040H    ;cancel character
  153. ;
  154. ;        Performance equates
  155. ;
  156. WAITCD        EQU    250        ;secs * 10 to wait for carrier detect
  157. ;                     after dialing phone number
  158. WAITRD        EQU    30        ;secs * 10 to wait between continuous
  159. ;                     redial retries
  160. ;
  161. SLOTNUM    EQU    SLOT*16            ;offset to slot base address
  162. ;
  163.         IF    CPM2
  164. ;
  165. SLOTBAS        EQU    0E085H        ;I/O memory for most CP/M cards
  166. ;
  167.         ENDIF            ;CPM2
  168. ;
  169.         IF    ALSCARD
  170. ;
  171. SLOTBAS        EQU    0C085H        ;I/O memory for ALS CP/M Card
  172. ;
  173.         ENDIF            ;ALSCARD
  174. ;
  175. ;
  176. ;====================== MICROMODEM SPECIFIC EQUATES ======================
  177. ;
  178. ;
  179. ;        MODEM I/O EQUATES
  180. ;
  181. MODCTL2        EQU    SLOTBAS+SLOTNUM        ;IN RI, OUT CR2
  182. MODCTL1        EQU    MODCTL2+1        ;IN STATUS, OUT CR1
  183. MODDATP        EQU    MODCTL1+1        ;IN/OUT DATA
  184. ;
  185.         IF    MMIIE
  186. ;
  187. MODCTL3        EQU    MODCTL2-2        ;SPKR, TOUCH TONE REG
  188. ;
  189.         ENDIF            ;MMIIE
  190. ;
  191. ;        BIT MASKS FOR MODCTL1 INPUT
  192. ;
  193. MODSNDB        EQU    2        ;bit to test for send status
  194. MODSNDR        EQU    2        ;value when ready
  195. MODRCVB        EQU    1        ;bit to test for receive status
  196. MODRCVR        EQU    1        ;value when ready
  197. CARBIT        EQU    4        ;carrier detect* bit
  198. ;
  199. ;        BIT MASKS FOR MODCTL1 OUTPUT
  200. ;
  201. INITBITS    EQU    03H        ;the first time
  202. BRKBITS        EQU    60H        ;break signal bits
  203. D8NP2SB        EQU    11H        ;8 bit data, no parity, 2 stop
  204. D8NP1SB        EQU    15H        ;8 bit data, no parity, 1 stop
  205. D8EP1SB        EQU    19H        ;8 bit data, even parity, 1 stop
  206. D8OP1SB        EQU    1DH        ;8 bit data, odd parity, 1 stop
  207. ;
  208. ;        BIT MASK FOR MODCTL2 INPUT
  209. ;
  210. RNGBIT        EQU    80H        ;ring indicator* bit
  211. ;
  212. ;        BIT MASKS FOR MODCTL2 OUTPUT
  213. ;
  214. MODBIT        EQU    4        ;mode bit in cr2 (1=org 0=ans)
  215. SETBIT        EQU    8        ;set bit in cr2 (always 1)
  216. OFFBIT        EQU    80H        ;off hook bit in cr2 (0=hungup)
  217. TXEBIT        EQU    2        ;transmit enable bit (1=enable)
  218. NOTTXE        EQU    0FDH        ;not(txebit) for and mask
  219. BAUDBIT        EQU    1        ;baud rate bit (0=110 1=300)
  220. ;
  221. ;        SETUP WORDS FOR MODCTL2 OUTPUT
  222. ;
  223. ORIGMOD        EQU    MODBIT+OFFBIT+SETBIT
  224. ANSWMOD        EQU    OFFBIT+SETBIT
  225. ;
  226.         IF    MMIIE
  227. ;
  228. ;        BIT MASKS FOR MODCTL3 OUTPUT
  229. ;
  230. SPKRBIT        EQU    20H        ;1=speaker on
  231. TONEBIT        EQU    10H        ;1=tone on
  232. ;
  233.         ENDIF            ;MMIIE
  234. ;
  235. ;
  236. ;======================== ROOT PROGRAM ADDRESSES =========================
  237. ;
  238. ;    THESE ARE FIXED ADDRESSES OF ROUTINES AND VARIABLES REFERENCED
  239. ;    IN THE ROOT FROM THIS OVERLAY, AND ARE ONLY VALID FOR MDM712.
  240. ;
  241. KEYIN          EQU    27A4H        ;address of "keyin:" in root
  242. CRLF          EQU    278CH        ;address of "crlf:" in root
  243. TYPE          EQU    27B8H        ;address of "type:" in root
  244. STAT        EQU    2799H        ;address of "stat:" in root
  245. ERXIT          EQU    285AH        ;address of "erxit:" in root
  246. MOVE        EQU    28B2H        ;address of "move:" in root
  247. MOVER        EQU    2CFEH        ;address of "mover:" in root
  248. NEWLINE        EQU    4362H        ;address of "newline:" in root
  249. SPACES        EQU    436BH        ;address of "spaces:" in root
  250. CLRTST        EQU    43C5H        ;address of "clrtst:" in root
  251. KBDCHR        EQU    27C5H        ;address of "kbdchr:" on root
  252. MENU        EQU    2EF6H        ;address of "menu:" in root
  253. RETURN        EQU    15E2H        ;address of "return:" in root
  254. DECOUT        EQU    27D8H        ;address of "decout:" in root
  255. FIXCNT        EQU    28CBH        ;address of "fixcnt:" in root
  256. ;
  257. ALTDIAL1    EQU    0CDFH        ;address of alt dial string 1
  258. ALTDIAL2    EQU    0CF7H        ;address of alt dial string 2
  259. CMDBUF        EQU    4508H        ;address of command line buffer
  260. BUFFER        EQU    4A00H        ;address of data buffer
  261. NUMBLIB        EQU    0D0FH        ;address of phone number library
  262. LIBLEN        EQU    22H        ;length of a library line
  263. RBWAIT        EQU    50        ;wait 5 sec before redial
  264. ANSWFLG        EQU    44B2H        ;answer mode request flag
  265. ORIGFLG        EQU    44B6H        ;originate mode request flag
  266. CRFLAG        EQU    44F5H        ;continuous redial flag
  267. RINGBKFL    EQU    4504H        ;ringback flag
  268. DIALCT        EQU    44EAH        ;no. of dials attempted
  269. OPARITY          EQU    44BEH        ;odd parity flag in option table
  270. EPARITY          EQU    44BDH        ;even parity flag in option table
  271. MODCTLB        EQU    44FFH        ;storage byte for MODCTL1 word
  272. UARTCTLB    EQU    4506H        ;storage byte for current control word
  273. ;
  274. ;============================= OVERLAY CODE ===============================
  275. ;
  276.         ORG    100H
  277. ;
  278.         DS    3    ;(for  "JMP   START" instruction)
  279. ;
  280. PMMIMODEM:    DB    YES    ;but not really, just did this to get
  281.                 ;correct logic decisions made in root    103H
  282. SMARTMODEM:    DB    NO    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  283. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  284. ;
  285. ; ---------->     Note:    The clock speed for most CP/M Cards usually
  286. ;            works out to be 2 mhz.  Change the equate below
  287. ;            to adjust timing for program.
  288. ;
  289. CLOCK:        DB    20    ;clock speed in MHz x10, as above
  290. ;
  291. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200   107H
  292.                 ;6=2400 7=4800 8=9600 9=19200 default
  293. ;
  294. ; ------------>    Note:    The following equates affect default program
  295. ;            parameters.  The following configuration is what
  296. ;            is usually used, change any of the following if
  297. ;            different operation is desired.
  298. ;
  299. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
  300.                 ;default time to send character in ter-
  301.                 ;minal mode file transfer for slow BBS.
  302. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  303.                 ;default time for extra wait after CRLF
  304.                 ;in terminal mode file transfer
  305. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  306. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  307. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  308. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  309.                 ;no=resend a record after a valid-NAK
  310. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  311. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  312. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  313. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  314. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  315. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  316.                 ;terminal mode (added by remote echo)
  317. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  318. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  319.                 ;write logon sequence at location LOGON
  320. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  321. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  322.                 ;no=external command if EXTCHR precedes
  323. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  324. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  325. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  326.                 ;sending a file in terminal mode
  327. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  328.                 ;sending a file in terminal mode
  329. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  330. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  331. EXTRA1:        DB    0    ;for future expansion            11EH
  332. EXTRA2:        DB    0    ;for future expansion            11FH
  333. BRKCHR:        DB    '@'-40H    ;^@ = Send 300 ms. break tone        120H
  334. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  335. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  336. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  337. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  338. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  339. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  340. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        127H
  341. ;
  342. ;
  343.         DS    2        ;                128H
  344. ;
  345. IN$MODCTL1:    JMP    LDACTLP        ;in modem control port             12AH
  346.         DS    7        ;( IN STATUS )
  347. OUT$MODDATP:    JMP    STADATP     ;out modem data port        134H
  348.         DS    7        ;( OUT DATA  )
  349. IN$MODDATP:    JMP    LDADATP     ;in modem data port        13EH
  350.         DS    7        ;( IN DATA   )
  351. ANI$MODRCVB:    ANI    MODRCVB    ! RET    ;bit to test for receive ready    148H
  352. CPI$MODRCVR:    CPI    MODRCVR    ! RET    ;value of rcv. bit when ready    14BH
  353. ANI$MODSNDB:    ANI    MODSNDB    ! RET    ;bit to test for send ready    14EH
  354. CPI$MODSNDR:    CPI    MODSNDR    ! RET    ;value of send bit when ready    151H
  355. IN$MODCTL2:    JMP    LDACTL2        ;in modem control port #2    154H
  356.                     ;( IN RI     )
  357. OUTDUMMY:    DB    0,0,0        ;dummy old "out baudrp"        157H
  358. OUT$MODCTL1:    JMP    STACTLP        ;out modem control port #1    15AH
  359.                     ;( OUT CR1   )
  360. OUT$MODCTL2:    JMP    STACTL2        ;out modem control port #2    15DH
  361.                     ;( OUT CR2   )
  362. LOGONPTR:    DW    LOGON        ;for user message.        160H
  363. JMP$DIAL:    JMP    DIAL        ;called from RESTART:        162H
  364. JMP$DISCONNT:    JMP    DISCONNT    ;called from DONETCD: after...  165H
  365. JMP$GOODBYE:    JMP    GOODBYE        ;called from DONETCD:        168H
  366. JMP$INITMOD:    JMP    INITMOD        ;jump to from INITADR: for ret    16BH
  367. JMP$NEWBAUD:    JMP    NEWBAUD        ;called frm NOLST: for baud chg 16EH
  368. JMP$NOPARITY:    JMP    NOPARITY    ;called from DONETCB:        171H
  369. JMP$PARITY:    JMP    PARITY        ;called from RCVFIL: & SENDFIL: 174H
  370. JMP$SETUPR:    JMP    SETUPR        ;if SETUPTST true & not PMMI    177H
  371. JMP$SPCLMENU:    JMP    SPCLMENU    ;implements Micromodem menu    17AH
  372. JMP$SYSVER:    JMP    SYSVER        ;version message        17DH
  373. JMP$BREAK:    JMP    SENDBRK        ;if PMMI not true        180H
  374. ;
  375. ;
  376. ; Do not change the following six lines. These are jumps to specific
  377. ; subroutines in root program.
  378. ;
  379. JMP$ILPRT:    DS    3        ;print inline string until 0    183H
  380. JMP$INBUF    DS    3        ;same as CP/M func 10 but no ^C    186H
  381. JMP$INLNCOMP:    DS    3        ;compare inline string to (DE)    189H
  382. JMP$INMODEM    DS    3        ;modem input, timeout = 100 ms    18CH
  383. JMP$NXTSCRN:    DS    3        ;"hit any key to continue"    18FH
  384. JMP$TIMER    DS    3        ;wait .1 sec for (B reg)    192H
  385. ;
  386. ; 
  387. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  388. ; SCRNTEST to YES at 010AH (above).
  389. ;
  390. CLREOS:        CALL    JMP$ILPRT    ;                195H
  391.         DB    'K'-040H    ;for Apple ][ 80 col card    198H
  392.         DB    0,0,0,0        ;
  393.         RET            ;                19DH
  394. ;
  395. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  396.         DB    'L'-040H    ;for Apple ][ 80 col card    1A1H
  397.         DB    0,0,0,0        ;                
  398.         RET            ;                1A6H
  399.     
  400. ;
  401. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  402.         DB    'Version for '
  403. ;
  404.         IF    ALSCARD
  405. ;
  406.         DB    'ALS CP/M Card '
  407.         DB    CR,LF,'and '
  408. ;
  409.         ENDIF            ;ALSCARD
  410. ;
  411.         DB    'Micromodem ]['
  412. ;
  413.         IF    MMIIE
  414. ;
  415.         DB    '/e'
  416. ;
  417.         ENDIF            ;MMIIE
  418. ;
  419.         DB    ' as of 1/8/84'
  420.         DB    CR,LF,0
  421.         RET
  422. ;
  423. ;========================= BAUD RATE ROUTINES =============================
  424. ;
  425. ;......
  426. ;
  427. ;     Change baudrate on-the-fly with CTL-B (while in terminal mode)
  428. ;
  429. ;
  430. NEWBAUD:      CALL    JMP$ILPRT
  431.           DB    CR,LF,'Enter new Baudrate: ',0
  432.           LXI    H,FCB+9
  433.           MVI    M,' '        
  434. ;
  435. NEWBAUD1:     CALL    KEYIN        
  436.           CPI    CR        
  437.           CZ    CRLF        
  438.           JZ    FIXBAUD        
  439. ;.....
  440. ;
  441. ;
  442. NEWBAUD2:     CPI    '0'        
  443.           JC    NEWBAUD1
  444.           CPI    '9'+1
  445.           JNC    NEWBAUD1    
  446.           MOV    M,A        
  447.           CALL    TYPE        
  448.           INX    H        
  449.           JMP    NEWBAUD1    
  450. ;
  451.         ORG    024FH        ;"setbaud:" is called from within
  452.                     ;the root, so this address is fixed
  453. ;
  454. SETBAUD:    LDA    UARTCTLB    ;called from "restart0:"
  455.         ORI    BAUDBIT        ;set for default 300 baud
  456.         STA    UARTCTLB    ;
  457.         CALL    OUT$MODCTL2    ;
  458.         DB    00H        ;to fill in old routine
  459. ;
  460. FIXBAUD:    CALL    GETBAUD        ;c = baud rate
  461.         LDA    UARTCTLB    ;get current mode word
  462.         ANI    0FEH        ;strip old baud rate bit
  463.         ORA    C        ;setup new word
  464.         STA    UARTCTLB    ;update current mode word
  465.         MOV    A,C        ;
  466.         STA    MSPEED        ;update current modem speed
  467. ;
  468. OFFHOOK:    PUSH    B        ;save the used registers
  469.         PUSH    H        ;
  470.         LXI    H,7500        ;
  471. ;
  472. OFFDLY:        DCR    L        ;delay needed for modem
  473.         JNZ    OFFDLY        ;
  474.         DCR    H        ;
  475.         JNZ    OFFDLY        ;
  476.         POP    H        ;restore hl
  477.         LDA    UARTCTLB    ;get the current status
  478.         MOV    B,A        ;save current mode word in B
  479.         LDA    ANSWFLG        ;answer mode?
  480.         ORA    A        ;
  481.         JNZ    ORGCHEK        ;no - originate?
  482.         MVI    A,0FBH        ;yes - zap the mode bit for answer
  483.         ANA    B        ;
  484.         JMP    UPDATE        ;and update the modem
  485. ORGCHEK:    LDA    ORIGFLG        ;check for originate mode
  486.         ORA    A        ;
  487.         JZ    ORGMOD        ;yes, set originate
  488.         MOV    A,B        ;otherwise retain old status
  489.         JMP    UPDATE        ;and tell the modem
  490. ORGMOD:        MVI    A,MODBIT    ;
  491.         ORA    B        ;set the mode bit
  492. UPDATE:        ORI    OFFBIT        ;set the offhook bit
  493.         STA    UARTCTLB    ;update storage word
  494.         CALL    OUT$MODCTL2    ;go offhook in requested mode & baud
  495.         LDA    MODCTLB        ;update format register
  496.         CALL    OUT$MODCTL1    ;just in case
  497.         XRA    A        ;
  498.         POP    B        ;restore bc
  499.         RET            ;
  500. ;
  501. GETBAUD:    LDA    FCB+9        ;
  502.         ORA    A        ;
  503.         JZ    NOBAUD        ;no baud rate change
  504.         CPI    ' '        ;
  505.         JNZ    DOBAUD        ;
  506. NOBAUD:        POP    D        ;get rid of first ret addr
  507.         JMP    OFFHOOK        ;and go do offhook
  508. ;
  509. DOBAUD:        LXI    D,FCB+9        ;something's there, convert it
  510.         LXI    H,0        ;to binary and check validity
  511. ;
  512. DECLP:        LDAX    D        ;get a baud rate byte
  513.         INX    D        ;for the next time
  514.         CPI    ' '        ;skip spaces
  515.         JZ    DECLP        ;
  516.         CPI    '0'        ;check for numiscity
  517.         JC    BADRATE        ;c = non-numic
  518.         CPI    '9'+1        ;
  519.         JNC    BADRATE        ;nc = bad stuff
  520.         SUI    '0'        ;kill the ascii bias
  521.         MOV    B,H        ;put hl in bc
  522.         MOV    C,L        ;
  523.         DAD    H        ; x2
  524.         DAD    H        ; x4
  525.         DAD    B        ; x5
  526.         DAD    H        ; x10
  527.         ADD    L        ; now add value
  528.         MOV    L,A        ;
  529.         JNZ    DIGNC        ;
  530.         INR    H        ;
  531. ;
  532. DIGNC:        MOV    A,E        ;check for end of fcb
  533.         CPI    FCB+12        ;
  534.         JNZ    DECLP        ;nope, keep converting
  535.         MVI    C,0        ;now set c
  536.         PUSH    H        ;save binary baud rate
  537.         LXI    D,-110        ;for subtract
  538.         DAD    D        ;do it
  539.         MOV    A,H        ;
  540.         ORA    L        ;110 baud?
  541.         POP    H        ;restore baud rate
  542.         RZ            ;yes - with c = 0
  543.         INR    C        ;no, try 300
  544.         LXI    D,-300        ;
  545.         DAD    D        ;
  546.         MOV    A,H        ;
  547.         ORA    L        ;
  548.         RZ            ;yes, c = 1
  549. ;
  550. BADRATE        POP    H        ;(getbaud ret)
  551.         POP    H        ;(fixbaud/setbaud ret)
  552.         CALL    ERXIT        ;exit with error message
  553.         DB    '++ Invalid Baud Rate ++$'
  554. ;
  555. ;======================== PARITY ROUTINES ==============================
  556. ;
  557. ;.....
  558. ;
  559. PARITY:        LDA    OPARITY        ;check for odd parity flag
  560.         ORA    A        ;
  561.         JNZ    EVENPAR        ;not set, check for even
  562.         MVI    A,D8OP1SB    ;set odd parity
  563.         JMP    PARITY1        ;go do it
  564. ;
  565. EVENPAR:    LDA    EPARITY        ;check even parity flag
  566.         ORA    A        ;
  567.         RNZ            ;nop if neither set
  568.         MVI    A,D8EP1SB    ;set even parity
  569. ;
  570. PARITY1:    STA    MODCTLB        ;update current format word
  571.         JMP    OUT$MODCTL1    ;this will ret to caller
  572. ;
  573. NOPARITY:    MVI    A,D8NP2SB    ;2 stop bits for no parity
  574.         JMP    PARITY1        ;
  575.  
  576. ;
  577. ;
  578. ;=========================== DISCONNECT ROUTINE ============================
  579. ;
  580. ;.....
  581. ;
  582. GOODBYE:
  583. DISCONNT:    LDA    UARTCTLB    ;get the current mode word
  584.         ANI    07FH        ;
  585.         STA    UARTCTLB    ;hang up
  586.         CALL    OUT$MODCTL2    ;
  587. ;
  588.         IF    MMIIE
  589. ;
  590.         XRA    A        ;turn off the speaker
  591.         CALL    STACTL3        ;
  592. ;
  593.         ENDIF            ;MMIIE
  594. ;
  595.         PUSH    B        ;
  596.         MVI    B,10        ;wait a second
  597.         CALL    TIMER        ;
  598.         POP    B        ;
  599.         RET            ;
  600. ;
  601. ;=================== INITIALIZATION AND APPLE I/O ROUTINES =================
  602. ;
  603. ;.....
  604. ;
  605. INITMOD:    EQU    $        ;locate the routine
  606. ;
  607.         IF    ALSCARD
  608. ;
  609.         LHLD    1        ;pointer to cold boot vector in BIOS
  610.         LXI    D,60H        ;offset to ALS' special vectors
  611.         DAD    D        ;hl => APREAD vector
  612.         SHLD    APREAD+1    ;store address locally so we can use
  613.         INX    H        ;bump hl to point to APWRITE
  614.         INX    H        ;
  615.         INX    H        ;
  616.         SHLD    APWRITE+1    ;
  617. ;
  618.         ENDIF            ;ALSCARD
  619. ;
  620.         MVI    A,INITBITS    ;initialize the ACIA
  621.         CALL    OUT$MODCTL1    ;
  622.         MVI    A,D8NP2SB    ;set default format
  623.         STA    MODCTLB        ;
  624.         CALL    OUT$MODCTL1    ;
  625.         RET            ;from initmod:
  626. ;
  627. ;        Apple I/O subroutines
  628. ;
  629.         IF    CPM2
  630. ;
  631. STADATP:    STA    MODDATP        ;out DATA
  632.         RET            ;
  633. ;
  634. STACTLP:    STA    MODCTL1        ;out CR1
  635.         RET            ;
  636. ;
  637. STACTL2:    STA    MODCTL2        ;out CR2
  638.         RET            ;
  639. ;
  640. LDADATP:    LDA    MODDATP        ;in DATA
  641.         RET            ;
  642. ;
  643. LDACTLP:    LDA    MODCTL1        ;in STATUS
  644.         RET            ;
  645. ;
  646. LDACTL2:    LDA    MODCTL2        ;in RI
  647.         RET            ;
  648. ;
  649.         ENDIF            ;CPM2
  650. ;
  651.         IF    MMIIE AND CPM2
  652. ;
  653. STACTL3:    STA    MODCTL3        ;out CR3
  654.         RET            ;
  655. ;
  656.         ENDIF            ;MMIIE AND CPM2
  657. ;
  658.         IF    ALSCARD
  659. ;
  660. ;        ALS bank select Apple I/O output
  661. ;
  662. STADATP:    PUSH    H        ;save the reg about to be used
  663.         LXI    H,MODDATP    ;point to desired location
  664.         JMP    APWRT        ;go do the action
  665. ;
  666. STACTLP:    PUSH    H        ;
  667.         LXI    H,MODCTL1    ;out CR1
  668.         JMP    APWRT        ;
  669. ;
  670. STACTL2:    PUSH    H        ;
  671.         LXI    H,MODCTL2    ;out CR2
  672. ;
  673.         ENDIF            ;ALSCARD
  674. ;
  675.         IF    ALSCARD AND MMIIE
  676. ;
  677.         JMP    APWRT        ;to give STACTL2 a place to go
  678. STACTL3:    PUSH    H        ;
  679.         LXI    H,MODCTL3    ;out CR3
  680. ;
  681.         ENDIF            ;ALSCARD AND MMIIE
  682. ;
  683.         IF    ALSCARD
  684. ;
  685. APWRT:        PUSH    D        ;save the rest of the registers
  686.         PUSH    B        ;
  687. ;
  688. APWRITE:    CALL    $-$        ;INITMOD inits this CALL
  689. ;
  690.         POP    B        ;
  691.         POP    D        ;
  692.         POP    H        ;
  693.         RET            ;
  694. ;
  695. ;        ALS bank select Apple I/O input
  696. ;
  697. LDADATP:    PUSH    H        ;
  698.         LXI    H,MODDATP    ;
  699.         JMP    APRD        ;
  700. ;
  701. LDACTLP:    PUSH    H        ;
  702.         LXI    H,MODCTL1    ;in STATUS
  703.         JMP    APRD        ;
  704. ;
  705. LDACTL2:    PUSH    H        ;
  706.         LXI    H,MODCTL2    ;
  707. ;
  708. APRD:        PUSH    D        ;save the rest
  709.         PUSH    B        ;
  710. ;
  711. APREAD:        CALL    $-$        ;INITMOD inits this CALL
  712. ;
  713.         POP    B        ;
  714.         POP    D        ;
  715.         POP    H        ;
  716.         RET            ;
  717. ;
  718.         ENDIF            ;ALSCARD
  719. ;
  720. ;========================= DIAL ROUTINES =============================
  721. ;
  722. ;.....
  723. ;
  724. DIAL:        XRA    A        ;reset:
  725.         STA    CRFLAG        ;continuous redial flag
  726.         STA    RINGBKFL    ;ringback flag
  727.         LXI    H,0        ;reset:
  728.         SHLD    DIALCT        ;no. of dial attempts
  729.         LXI    H,CMDBUF+1    ;point to command buffer
  730.         MOV    A,M        ;get no. of char's
  731.         CPI    3+1        ;
  732.         JC    DIAL1        ;< 4?
  733. ;
  734. ; If there were only 3 characters, the CAL<ret> was typed, the user
  735. ; obviously expecting to get a phone number (or letter) from the
  736. ; library file.  If 4 or more, a number (or letter) was typed in from
  737. ; the menu command line, so move the characters down 4 to compensate.
  738. ; Needed for auto-redialing of menu command line entries.
  739. ;
  740.         MOV    C,A        ;
  741.         MVI    B,0        ;bc = num of chars
  742.         SUI    4        ;
  743.         MOV    M,A        ;subtract 4 from cmdbuf+1
  744.         INX    H        ;point to beginning of cmd line
  745.         XCHG            ;switch pointers
  746.         LXI    H,CMDBUF+6    ;
  747.         CALL    MOVER        ;
  748.         JMP    DIAL4        ;
  749. ;
  750. ; Comes here if no phone number was manually entered after "CAL" and if
  751. ; no phone library letter was entered.  Displays the phone number library
  752. ; then asks for an entry.
  753. ;
  754. DIAL1:        MVI    C,13        ;
  755.         LXI    H,NUMBLIB    ;point to library
  756.         LXI    D,BUFFER    ;
  757.         CALL    NEWLINE        ;
  758.         STAX    D        ;
  759.         INX    D        ;
  760. ;
  761. DIAL2:        MVI    B,LIBLEN    ;
  762.         CALL    MOVE        ;
  763.         CALL    SPACES        ;
  764.         MVI    B,LIBLEN    ;
  765.         CALL    MOVE        ;
  766.         CALL    NEWLINE        ;
  767.         DCR    C        ;
  768.         JNZ    DIAL2        ;
  769. ;
  770. DIAL3:        MVI    A,'$'        ;terminate the buffer
  771.         STAX    D        ;
  772.         CALL    CLRTST        ;clear the screen if appropriate
  773.         MVI    C,PRINT        ;
  774.         LXI    D,BUFFER    ;readdress the buffer
  775.         CALL    BDOS        ;print the library
  776.         CALL    JMP$ILPRT    ;
  777.         DB    CR,LF,'Enter library letter or phone number,',CR,LF
  778.         DB    'CTL-X quits while dialing or ringing : ',0
  779.         LXI    D,CMDBUF    ;point to command buffer
  780.         CALL    JMP$INBUF    ;go get user command
  781. ;
  782. ; You now have either a library letter or a manually entered phone number.
  783. ; These either came from the menu command line or from the library command
  784. ; line.  Next we see if a letter, if so, get the corresponding line with
  785. ; phone number from the library.  If a number we ignore the library look-
  786. ; up.  (Ringback numbers are valid in library, but cause a caution message
  787. ; to the user, as this is not possible with Micromodem.)
  788. ;
  789. DIAL4:        LXI    H,CMDBUF+1    ;point to no. of char's
  790.         MOV    A,M        ;
  791.         ORA    A        ;
  792.         JZ    DIALEXIT    ;if none, bomb out
  793.         INX    H        ;point to first char
  794.         PUSH    H        ;save the pointer
  795.         CALL    DIALBGN        ;begin the dialing sequence
  796.         POP    H        ;restore the pointer
  797.         MVI    B,'A'        ;first compare byte
  798.         MVI    E,0        ;corresponding library entry
  799.         MVI    C,26        ;no. of entries to check
  800.         MOV    A,M        ;get the first cmdbuf char
  801. ;
  802. DIAL5:        CMP    B        ;match?
  803.         JZ    DIAL6        ;yes
  804.         INR    B        ;no - increment compare byte
  805.         INR    E        ;and offset
  806.         DCR    C        ;decrement tries
  807.         JZ    DIAL10        ;0 means checked 'Z'
  808.         JMP    DIAL5        ;try again
  809. ;
  810. ; Now have a match between the requested letter and the one in the library.
  811. ; E register has the decimal equivalent (0-25) of the letter (A-Z)
  812. ;
  813. DIAL6:        LXI    H,NUMBLIB    ;point to library
  814.         LXI    B,LIBLEN    ;
  815.         MOV    A,E        ;number of entries to skip
  816.         ORA    A        ;0?
  817.         JZ    DIAL8        ;yes - hl points to selected entry
  818. ;
  819. DIAL7:        MOV    A,M        ;
  820.         ORA    A        ;null phone number?
  821.         JZ    DIALBAD        ;yes - do error routine
  822.         DAD    B        ;no - move to next entry
  823.         DCR    E        ;done skipping?
  824.         JNZ    DIAL7        ;no - do it again
  825. ;
  826. ; Now hl points to the line containing the phone number requested, so
  827. ; store that line at CMDBUF+1
  828. ;
  829. DIAL8:        MVI    B,LIBLEN    ;length of the line
  830.         LXI    D,CMDBUF+1    ;to pointer
  831.         XCHG            ;switch pointers
  832.         MOV    M,B        ;put length of line in cmdbuf+1
  833.         XCHG            ;switch pointers back
  834.         INX    D        ;de -> cmdbuf+2
  835.         CALL    MOVE        ;from hl to de b times
  836. ;
  837. ; Now have the full line including phone number in 'CMDBUF' area.
  838. ;
  839. DIAL10:        LXI    H,CMDBUF+1    ;address the command line
  840.         MOV    E,M        ;put the no. of chars in e
  841.         INX    H        ;point to first char
  842. ;
  843. DIAL11:        MOV    A,M        ;get a char
  844.         ORA    A        ;nulls cause an error
  845.         JZ    DIALBAD        ;
  846. ;
  847. ; Dial a digit, check keyboard for abort
  848. ;
  849.         CALL    DIALA        ;dial the digit in A
  850.         CALL    STAT        ;keyboard hit?
  851.         JZ    DIAL13        ;no - continue
  852.         CALL    KEYIN        ;yes - get the character
  853.         CPI    CANCEL        ;is it the cancel character?
  854.         JZ    DIALEXIT    ;yes - forget the whole idea
  855. DIAL13:        INX    H        ;point to the next digit
  856.         DCR    E        ;decrement char count
  857.         JNZ    DIAL11        ;more to dial
  858. ;
  859. ; Show number of dial attempts
  860. ;
  861.         CALL    JMP$ILPRT    ;
  862.         DB    ' -try #',0    ;
  863.         LHLD    DIALCT        ;get the attempt counter
  864.         INX    H        ;bump it first
  865.         SHLD    DIALCT        ;and update it
  866.         CALL    DECOUT        ;now type it
  867.         MVI    A,' '        ;and then a space
  868.         CALL    TYPE        ;
  869. ;
  870. ; Dialing is done
  871. ;
  872.         MVI    B,WAITCD    ;secs * 10 to wait for carrier
  873.         CALL    CARWT        ;go wait for carrier
  874.         JC    EXMENU        ;cy means operator cancelled
  875.         LDA    UARTCTLB    ;not detected, try answer mode
  876.         XRI    MODBIT        ;flip modem mode...
  877.         ORI    TXEBIT        ;enable the transmitter
  878.         STA    UARTCTLB    ;
  879.         CALL    OUT$MODCTL2    ;set modem
  880.         MVI    B,30        ;now wait for orig tone for 3 seconds
  881.         CALL    CARWT        ;
  882.         JC    EXMENU        ;cy if cancel requested
  883.         LDA    UARTCTLB    ;nope, connection failed
  884.         XRI    MODBIT        ;flip back to originate
  885.         ANI    NOTTXE        ;reset the transmit enable bit
  886.         STA    UARTCTLB    ;
  887.         CALL    OUT$MODCTL2    ;tell modem about it
  888. ;
  889. ; Connection not made, go see if a redial is desired
  890. ;
  891.         CALL    DISCONNT    ;disconnect the modem
  892. DIALAGN:    LDA    CRFLAG        ;continuous redial requested?
  893.         ORA    A        ;
  894.         JNZ    DIALAGN1    ;yes - skip the idle chatter
  895.         CALL    JMP$ILPRT    ;
  896.         DB    CR,LF,LF,'No answer. Redial? (Y,N,C) : ',0
  897.         CALL    KBDCHR        ;get a keyboard character
  898.         CALL    CRLF        ;for neatness
  899.         CPI    'N'        ;(N)o?
  900.         JZ    MENU        ;nope, go back to the menu
  901.         CPI    'Y'        ;(Y)es?
  902.         JZ    DIALAGN1    ;yup, do it again
  903.         CPI    'C'        ;(C)ontinuously redial?
  904.         JNZ    DIALAGN        ;none of these, try again for user
  905.         MVI    A,1        ;set the continuous redial flag
  906.         STA    CRFLAG        ;so we won't do this again
  907. ;
  908. DIALAGN1:    MVI    B,WAITRD    ;secs * 10 to wait until redial
  909.         CALL    TIMER        ;
  910.         CALL    CRLF        ;for display neatness
  911.         JMP    DIAL4        ;
  912. ;
  913. EXMENU:        CALL    DISCONNT    ;disconnect the modem
  914.         CALL    CRLF        ;
  915.         JMP    MENU        ;
  916. ;
  917. ; Come here when the connection has been made
  918. ;
  919. CONMADE:    EQU    $        ;
  920. ;
  921.         IF    MMIIE
  922. ;
  923.         XRA    A        ;turn off speaker now
  924.         CALL    STACTL3        ;
  925. ;
  926.         ENDIF            ;MMIIE
  927. ;
  928.         LDA    UARTCTLB    ;carrier detected ...
  929.         ORI    TXEBIT        ;enable the transmitter, if not already
  930.         STA    UARTCTLB    ;
  931.         CALL    OUT$MODCTL2    ;
  932.         CALL    SETBAUD        ;set the current baud rate
  933.         CALL    JMP$ILPRT    ;
  934.         DB    CR,LF,LF,'Connected.',BELL,0
  935.         LDA    CRFLAG        ;were we continuously redialing?
  936.         ORA    A        ;
  937.         JZ    RETURN        ;no - drop into terminal mode
  938.         CALL    JMP$ILPRT    ;yes - get the user's attention
  939.         DB    ' - hit any key ... ',0
  940. ;
  941. CONMADE2:    CALL    STAT        ;check for user
  942.         JZ    CONMADE3    ;
  943.         CALL    KEYIN        ;get the character typed
  944.         XRA    A        ;
  945.         JMP    RETURN        ;and drop into terminal mode
  946. ;
  947. CONMADE3:    MVI    B,10        ;1 second between bells
  948.         CALL    TIMER        ;
  949.         MVI    A,BELL        ;
  950.         CALL    TYPE        ;send the bell
  951.         CALL    IN$MODCTL1    ;check to see if distant modem gave up
  952.         ANI    CARBIT        ;
  953.         JZ    CONMADE2    ;no - keep trying to signal user
  954.         CALL    DISCONNT    ;disconnect the modem
  955.         CALL    JMP$ILPRT    ;distant modem gave up waiting
  956.         DB    CR,LF,LF,BELL,'++ Carrier lost, hit any key ++ ',0
  957. CONMADE4:    CALL    STAT        ;check for keyboard
  958.         JZ    CONMADE4    ;
  959.         CALL    KEYIN        ;get the character
  960.         XRA    A        ;
  961.         JMP    MENU        ;go back to menu
  962. ;
  963. ; Automatic dialing routine, prints the number being dialed
  964. ;
  965. DIALA:        CALL    TYPE        ;get that out of the way
  966.         CPI    'R'        ;ringback request?
  967.         JNZ    DIALA0        ;no - continue checking
  968.         PUSH    PSW        ;yes - is it really?
  969.         MOV    A,E        ;check character count
  970.         CPI    1        ;last one?
  971.         JZ    RINGBK        ;
  972.         POP    PSW        ;not really, keep checking
  973. DIALA0:        MOV    B,A        ;save char in B
  974.         CALL    DIALAD        ;check for alternate dialing request
  975.         MOV    A,B        ;restore char
  976. DIALADC:    CPI    ','        ;pause request?
  977.         JNZ    DIALA1        ;no - keep going
  978.         MVI    B,20        ;yes - wait 2 seconds and return
  979.         JMP    TIMER        ;this will return
  980. ;
  981. DIALA1:        CPI    '0'        ;check for dialability
  982.         RC            ;less than, so return
  983.         CPI    '9'+1        ;
  984.         RNC            ;greater than, so return
  985.         SUI    '0'        ;kill ascii bias
  986.         JNZ    DIALA2        ;if 1-9, go on
  987.         MVI    A,10        ;convert 0 to 10
  988. ;
  989. ; Dial the digit in the AC, determine the dialing method
  990. ;
  991. DIALA2:        MOV    C,A        ;put digit to be dialed in C
  992. ;
  993.         IF    MMIIE
  994. ;
  995.         LDA    TOUCHPULSE    ;get touch tone flag
  996.         CPI    'T'        ;
  997.         JNZ    DIALA2P        ;not a T, pulse dial
  998. ;
  999. ; Touch tone dialing routine, wait 100 ms, tone for 100 ms
  1000. ;
  1001.         MVI    B,10        ;wait 100 ms
  1002.         CALL    MS10        ;
  1003.         MOV    A,C        ;get the digit to dial (0-10)
  1004.         ORI    TONEBIT+SPKRBIT    ;add speaker and tone bits
  1005.         CALL    STACTL3        ;output to modem
  1006.         MVI    B,10        ;for 100 ms
  1007.         CALL    MS10        ;
  1008.         MVI    A,SPKRBIT    ;turn off tone now
  1009.         JMP    STACTL3        ;digit dialed, STACTL3 will RET
  1010. ;
  1011. DIALA2P:    EQU    $        ;
  1012. ;
  1013.         ENDIF            ;MMIIE
  1014. ;
  1015.         MVI    B,60        ;wait 600 ms
  1016.         CALL    MS10        ;uses the local timing routine
  1017. DIALNXT:    LDA    UARTCTLB    ;get the current make word
  1018.         PUSH    PSW        ;put on the stack
  1019.         ANI    07FH        ;make the break word
  1020.         CALL    OUT$MODCTL2    ;*   break   *
  1021.         MVI    B,5        ;* for 56 ms *
  1022.         CALL    MS10        ;
  1023.         POP    PSW        ;get the make word
  1024.         CALL    OUT$MODCTL2    ;*   make    *
  1025.         MVI    B,4        ;* for 44 ms *
  1026.         CALL    MS10        ;
  1027.         DCR    C        ;done with digit?
  1028.         JNZ    DIALNXT        ;
  1029.         RET            ;digit dialed
  1030. ;
  1031. MS10:        PUSH    B        ;wait 10 ms * b register
  1032.         PUSH    H        ;save used registers
  1033. ;
  1034.         IF    ALSCARD    ;
  1035. ;
  1036.         LXI    H,064H        ;constant to wait
  1037. ;
  1038.         ENDIF            ;ALSCARD
  1039. ;
  1040.         IF    CPM2        ;
  1041. ;
  1042.         LXI    H,032H        ;because I/O faster
  1043. ;
  1044.         ENDIF            ;CPM2
  1045. ;
  1046.         CALL    FIXCNT        ;adjust for clock speed
  1047.         MOV    B,H        ;put in bc
  1048.         MOV    C,L        ;
  1049.         POP    H        ;restore one register
  1050. ;
  1051. MSLP:        DCX    B        ;decrement timeout count
  1052.         MOV    A,B        ;
  1053.         ORA    C        ;done yet?
  1054.         JNZ    MSLP        ;no - keep timing
  1055.         POP    B        ;restore the other register
  1056.         DCR    B        ;debump count
  1057.         JNZ    MS10        ;do it again
  1058.         RET            ;
  1059. ;
  1060. TIMER:        PUSH    B        ;wait 100ms * b register
  1061.         PUSH    H        ;
  1062. ;
  1063.         IF    ALSCARD        ;
  1064. ;
  1065.         LXI    H,03E8H        ;constant to wait
  1066. ;
  1067.         ENDIF            ;ALSCARD
  1068. ;
  1069.         IF    CPM2
  1070. ;
  1071.         LXI    H,01F4H        ;because clock slower
  1072. ;
  1073.         ENDIF            ;
  1074. ;
  1075.         CALL    FIXCNT        ;adjust for clock speed
  1076.         MOV    B,H        ;put in bc
  1077.         MOV    C,L        ;
  1078.         POP    H        ;restore one register
  1079. ;
  1080. MSLP2:        DCX    B        ;decrement timeout count
  1081.         MOV    A,B        ;
  1082.         ORA    C        ;done yet?
  1083.         JNZ    MSLP2        ;no - keep timing
  1084.         POP    B        ;restore the other register
  1085.         DCR    B        ;debump count
  1086.         JNZ    TIMER        ;do it again
  1087.         RET            ;
  1088. ;
  1089. ; Bad library number
  1090. ;
  1091. DIALBAD:    CALL    JMP$ILPRT    ;
  1092.         DB    CR,LF,'++ Bad library number called ++',CR,LF,0
  1093. ;
  1094. DIALEXIT:    CALL    DISCONNT    ;disconnect the modem
  1095.         CALL    CRLF        ;
  1096.         XRA    A        ;clear:
  1097.         STA    CRFLAG        ;the continuous redial flag
  1098.         CALL    JMP$INMODEM    ;clear any garbage
  1099.         JMP    MENU        ;
  1100. ;
  1101. DIALEXT2:    CALL    JMP$INMODEM    ;wait for a clear line
  1102.         JNC    DIALEXT2    ;
  1103.         CALL    JMP$GOODBYE    ;redundancy
  1104.         JMP    MENU        ;
  1105. ;
  1106. ; Disconnect from the line, wait 3 seconds, then pick up again
  1107. ;
  1108. DIALBGN:    CALL    DISCONNT    ;disconnect
  1109.         PUSH    B        ;
  1110.         MVI    B,20        ;because disconnt waits 1
  1111.         CALL    TIMER        ;
  1112.         POP    B        ;
  1113. ;
  1114.         IF    MMIIE
  1115. ;
  1116.         MVI    A,SPKRBIT    ;turn on MM][/e's speaker
  1117.         CALL    STACTL3        ;
  1118. ;
  1119.         ENDIF            ;MMIIE
  1120. ;
  1121.         CALL    OFFHOOK        ;go offhook again
  1122.         PUSH    B        ;
  1123.         MVI    B,20        ;
  1124.         CALL    TIMER        ;wait 2 seconds
  1125.         POP    B        ;
  1126.         RET            ;and return
  1127. ;
  1128. ; If Micromodem ][:
  1129. ;
  1130. ; Check for aternate dialing characters, message the user if detected
  1131. ;
  1132. ; If Micromodem ][/e:
  1133. ;
  1134. ; Does the alternate dialing request, allowing dialing mode switch
  1135. ; with T or P in alternate dialing string.   When done, leaves the modem 
  1136. ; in touch tone mode, as all long distance services require touch tone.
  1137. ;
  1138. DIALAD:        MOV    A,B        ;get the char
  1139.         CPI    '<'        ;altdial1?
  1140.         JZ    DIALAD2        ;
  1141.         CPI    '>'        ;altdial2?
  1142.         RNZ            ;
  1143. ;
  1144.         IF    MMIIE        ;
  1145. ;
  1146. DIALAD2:    LDA    TOUCHPULSE    ;alternate dialing requested
  1147.         CPI    'T'        ;check for touch tone
  1148.         JZ    DIALAD3        ;
  1149.         MVI    A,'T'        ;we're pulse dialing, switch for ad
  1150. DIALAD3:    STA    TOUCHPULSE    ;
  1151.         MOV    A,B        ;restore the char
  1152.         CPI    '>'        ;altdial1?
  1153.         JNZ    ALT2        ;no, must be altdial2
  1154. ;
  1155.         PUSH    H        ;save the used register
  1156.         LXI    H,ALTDIAL1    ;
  1157.         JMP    DIALAD4        ;
  1158. ;
  1159. ALT2:        PUSH    H        ;
  1160.         LXI    H,ALTDIAL2    ;
  1161. ;
  1162. DIALAD4:    CALL    TYPE        ;get that out of the way
  1163. DIALAD5:    MOV    A,M        ;get an alternate dialing char
  1164.         CPI    '$'        ;end of string?
  1165.         JZ    DIALAD6        ;
  1166.         CPI    'P'        ;dialing mode change?
  1167.         JZ    SETIT        ;
  1168.         CPI    'T'        ;
  1169.         JZ    SETIT        ;
  1170.         CALL    DIALADC        ;dial the character, if you can
  1171.         JMP    ADNEXT        ;
  1172. ;
  1173. SETIT:        STA    TOUCHPULSE    ;update the dialing method
  1174. ADNEXT:        INX    H        ;point to the next char
  1175.         JMP    DIALAD5        ;and do it all again
  1176. ;
  1177. DIALAD6:    MVI    A,' '        ;for display neatness
  1178.         CALL    TYPE        ;
  1179.         POP    H        ;remember?
  1180.         RET            ;        
  1181. ;
  1182.         ENDIF            ;MMIIE
  1183. ;
  1184.         IF    NOT MMIIE
  1185. ;
  1186. DIALAD2:    CALL    JMP$ILPRT    ;
  1187.         DB    CR,LF,BELL,'++ Alternate dialing not available for'
  1188.         DB    ' Micromodem ++',CR,LF,LF
  1189.         DB    '   Do you wish to continue ? (Y,N) : ',0
  1190.         CALL    KBDCHR        ;
  1191.         CALL    CRLF        ;
  1192.         CALL    CRLF        ;
  1193.         CPI    'N'        ;
  1194.         JNZ    DIALAD3        ;
  1195.         POP    H        ;justify stack
  1196.         JMP    MENU        ;
  1197. ;
  1198. DIALAD3:    CPI    'Y'        ;
  1199.         JNZ    DIALAD2        ;
  1200.         RET            ;
  1201. ;
  1202.         ENDIF            ;NOT MMIIE
  1203. ;
  1204. ; Ringback not possible, also messages user, but doesn't need ack
  1205. ;
  1206. RINGBK:        POP    PSW        ;justify stack
  1207.         CALL    JMP$ILPRT    ;just message the user
  1208.         DB    BELL,' - (Ringback not available)',0
  1209.         RET            ;from DIALA
  1210. ;
  1211. ; Waits for carrier, performs direct jump to "conmade:" if detected
  1212. ;
  1213. CARWT:        PUSH    B        ;save the count
  1214.         CALL    IN$MODDATP    ;updates status register
  1215.         CALL    IN$MODCTL1    ;check the modem status
  1216.         ANI    CARBIT        ;carrier detected?
  1217.         JNZ    CARWT1        ;no, time out
  1218.         POP    B        ;restore BC
  1219.         POP    PSW        ;get rid of return address
  1220.         JMP    CONMADE        ;and go do connect options
  1221. CARWT1:        CALL    STAT        ;check for keyboard cancel
  1222.         JZ    CARWT2        ;z = no char hit
  1223.         CALL    KEYIN        ;char hit, is it cancel?
  1224.         CPI    CANCEL        ;
  1225.         JNZ    CARWT2        ;no, ignore it
  1226.         STC            ;set cancel flag
  1227.         RET            ;
  1228. ;
  1229. CARWT2:        MVI    B,10        ;wait .1 seconds
  1230.         CALL    MS10        ;
  1231.         POP    B        ;restore the count
  1232.         DCR    B        ;
  1233.         JNZ    CARWT        ;keep waiting
  1234.         XRA    A        ;reset the cy
  1235.         RET            ;
  1236. ;
  1237. ;====================== MICROMODEM SPECIAL MENU ========================
  1238. ;
  1239. SPCLMENU:    CALL    JMP$NXTSCRN    ;
  1240.         CALL    JMP$ILPRT    ;
  1241.         DB    '    Additional commands for Micromodem'
  1242.         DB    CR,LF,LF
  1243.         DB    '  Modem control :',CR,LF,LF
  1244.         DB    '    A - Answer tone for S or R',CR,LF
  1245.         DB    '    O - Originate tone for S or R',CR,LF,LF
  1246.         DB    '  Parity options :',CR,LF,LF
  1247.         DB    '    1 - Set odd parity',CR,LF
  1248.         DB    '    0 - Set even parity',CR,LF,LF
  1249.         DB    '  Both ends must be capable of parity.  Only',CR,LF
  1250.         DB    '  available in R and S modes.  Parity check',CR,LF
  1251.         DB    '  will be part of transfer protocol.',CR,LF,LF
  1252.         DB    '  Note : Data format will be forced to 1 stop',CR,LF
  1253.         DB    '  bit as the Micromodem only supports parity',CR,LF
  1254.         DB    '  in this format.  Data format will be 2 stop',CR,LF
  1255.         DB    '  bits when parity is disabled (default).',CR,LF,LF,0
  1256.         CALL    JMP$NXTSCRN    ;
  1257.         CALL    JMP$ILPRT    ;
  1258.         DB    '    Additional commands for Micromodem'
  1259.         DB    CR,LF,LF
  1260.         DB    '  Speed options :',CR,LF,LF
  1261.         DB    '    Follow primary and secondary options with',CR,LF
  1262.         DB    '    baud rate as ".XXX".',CR,LF,LF
  1263.         DB    '  Speed option example :',CR,LF,LF
  1264.         DB    '    SBOT.110  will set modem for batch mode',CR,LF
  1265.         DB    '    send transfer at 110 baud, then drops',CR,LF
  1266.         DB    '    into terminal mode.',CR,LF,LF
  1267.         DB    '  110 and 300 baud are only rates available,',CR,LF
  1268.         DB    '  default is 300 baud.'
  1269.         DB    CR,LF,LF
  1270. ;
  1271.         IF    MMIIE
  1272. ;
  1273.         DB    '  SET command selects touch-tone or pulse dialing'
  1274.         DB    CR,LF,LF
  1275. ;
  1276.         ENDIF            ;MMIIE
  1277. ;
  1278.         DB    0        ;
  1279.         RET            ;
  1280. ;
  1281. ;=============================================================================
  1282. ;
  1283. SENDBRK:    RET            ;These functions disabled for PMMI
  1284. SETUPR:          EQU    $
  1285. ;
  1286.         IF    MMIIE
  1287. ;
  1288.         CALL    JMP$ILPRT    ;
  1289.         DB    CR,LF,'(T)ouch tone, or (P)ulse dialing ? : ',0
  1290.         CALL    KBDCHR        ;get the response
  1291.         CALL    CRLF        ;for neatness
  1292.         CALL    CRLF        ;
  1293.         CPI    'T'        ;touch tone?
  1294.         JZ    SETMD        ;
  1295.         CPI    'P'        ;pulse?
  1296.         JNZ    SETUPR        ;no, try again
  1297. SETMD:        STA    TOUCHPULSE    ;update flag
  1298. ;
  1299.         ENDIF            ;MMIIE
  1300. ;
  1301.         RET            ;
  1302. ;
  1303. ;-----------------------------------------------------------------------
  1304. ;
  1305. ;.....
  1306. ;
  1307. ; You can put in a message at this location which can be called up with
  1308. ; CTL-O if TRANLOGON has been set TRUE.  You can use several lines if
  1309. ; desired, as long as IGNORE$ERROR evaluates to less than 0B80H
  1310. ; Terminate message with a null.
  1311. ;
  1312. LOGON:        DB    CR,LF,0
  1313. ;
  1314. ;=============================================================================
  1315. ;
  1316. IGNORE$ERROR    EQU    $+1        ;! MUST BE <= 0B80H
  1317. ;
  1318.         ORG    117EH        ;in "optck:"
  1319. ;
  1320.         DB    0,0,0,0,0,0,0,0    ;disable uartctlb modification
  1321.         DB    0,0,0,0,0,0,0,0    ;at this level
  1322.         DB    0,0,0        ;
  1323. ;
  1324.         ORG    1CE9H        ;in "break:"
  1325. ;
  1326.         ORI    BRKBITS        ;
  1327. ;
  1328.         ORG    2733H        ;in "donetcd:"
  1329. ;
  1330.         DB    0,0,0,0,0,0,0    ;zap the multiple goodbye
  1331.         DB    0,0,0,0,0,0,0    ;for pmmi
  1332. ;
  1333.         ORG    3B70H        ;in "nxtopt0:"
  1334. ;
  1335.         JMP    PATCH        ;go do patch
  1336. ;
  1337.         ORG    3BABH        ;in "byebye:"
  1338. ;
  1339.         JMP    3BB9H        ;disable multiple goodbye
  1340. ;
  1341. PATCH        STA    CMDBUF+3    ;disable setting answflg during call
  1342.         JMP    3B7FH        ;now "doopt:"
  1343. ;
  1344.         DB    0,0,0,0,0    ;rest of byebye:
  1345. ;
  1346.         ORG    MODCTLB        ;
  1347. ;
  1348.         DB    D8NP2SB        ;default modem format
  1349. ;
  1350.         ORG    UARTCTLB    ;
  1351. ;
  1352.         DB    ORIGMOD        ;default modem mode word
  1353. ;
  1354.         END
  1355.