home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / MODEM7 / M7IN-3.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  13KB  |  436 lines
  1.  
  2. ; M7IN-3.ASM -- Overlay file for the CompuPro I3/I4/SS1.  4/26/84
  3. ;
  4. ; This overlay adapts the MDM7xx program to the CompuPro Interfacer 3 or
  5. ; Interfacer 4 or System Support 1 serial cards using the 2651 USART chip.
  6. ; (Note:  It is very easy to modify this file to work with the Apple CPS
  7. ; Multifunction card too.)
  8. ;
  9. ; NOTE TO INTERFACER 4 USERS:
  10. ; The 'MIDDLE' serial port and the Centronics port can have their addresses
  11. ; changed using a hardware option.  Godbout did this to maintain software
  12. ; compatibility with their bios.  In order to prevent problems, use the
  13. ; 'RIGHT' serial port (RELATIVE USER 5) instead of the center serial
  14. ; port (RELATIVE USER 6).  Also, read page 19 of the manual, the modem
  15. ; port will probably have to be set up in the 'MASTER MODE'.  While 
  16. ; you're reading the manual, read the section on 'WAIT STATE LOGIC'.
  17. ; I'm using a CPU-Z running at 6Mhz, with a 300 baud modem and two wait
  18. ; states (jumper at J7).  Without them, I get 'o's for 'n's and 'g's
  19. ; for 'f's, and the checksums are never right.  (AWW 12/20/83)
  20. ;
  21. ; You will want to look this file over carefully. There are a number of
  22. ; options that you can use to configure the program to suit your taste.
  23. ; This file places particular emphasis on using an external modem that
  24. ; is connected to a serial port.  This includes acoustic modems as well
  25. ; as "intelligent" modems such as the Hayes Smartmodem, Racal-Vadic, Bell
  26. ; Dataphone 212A, etc.
  27. ;
  28. ; This overlay is capable of changing the UART port number, setting the
  29. ; baud rate and parameters, disconnecting the  modem, and sending breaks.
  30. ;
  31. ;
  32. ;    TO USE: First edit this file filling in answers for your own
  33. ;        equipment.  Then assemble with ASM.COM or equivalent
  34. ;        assembler.  Then use DDT to overlay the the results
  35. ;        of this program to the original .COM file:
  36. ;
  37. ;        A>DDT MDM7xx.COM
  38. ;        DDT VERS 2.2
  39. ;        NEXT  PC
  40. ;        4B00 0100
  41. ;        -IM7IN-2.HEX        (note the "I" command)
  42. ;        -R            ("R" loads in the .HEX file)
  43. ;        NEXT  PC
  44. ;        4B00 0000
  45. ;        -G0            (return to CP/M)
  46. ;        A>SAVE 74 MDM7xx.COM    (now have a modified .COM file)
  47. ;
  48. ; =   =      =   =      =   =      =   =      =   =      =   =      =   =      =   =      =   =
  49. ;
  50. ; 04/26/84 - Modified to take further advantage of the software selectable
  51. ;         features provided by CompuPro    - Chuck Rider
  52. ; 11/20/83 - Interfacer 4 Note Added            - A.W. Warren
  53. ; 11/11/83 - Renamed to M7IN-1.ASM, no changes    - Irv Hoff
  54. ; 07/27/83 - Renamed to work with MDM712    - Irv Hoff
  55. ; 07/11/83 - Modifed somewhat for MDM711    - Irv Hoff
  56. ; 07/08/83 - Adapted from MDM711GP.ASM        - Paul Traina
  57. ;
  58. ; =   =      =   =      =   =      =   =      =   =      =   =      =   =      =   =      =
  59. ;
  60. BELL:    EQU    07H        ;bell
  61. CR:    EQU    0DH        ;carriage return
  62. ESC:    EQU    1BH        ;escape
  63. LF:    EQU    0AH        ;linefeed
  64. ;
  65. YES:    EQU    0FFH
  66. NO:    EQU    0
  67. ;
  68. ; Change the following to match your equipment
  69. ;
  70. GBCI3:    EQU    YES        ;yes= Godbout Interfacer 3
  71. GBCI4:    EQU    NO        ;yes= Godbout Interfacer 4
  72. GBCSS1: EQU    NO        ;yes= Godbout SS1 board
  73. UARTOP: EQU    YES        ;yes= allow user to change UART number
  74. BAUDOP: EQU    YES        ;yes= allow user to change baud rate
  75. PARMOP: EQU    YES        ;yes= allow user to change bits and parity
  76. ;
  77. ; =   =      =   =      =   =      =   =      =   =      =   =      =   =      =   =      =
  78. ;
  79.     IF     GBCI3 OR GBCI4
  80. BASE:    EQU    010H        ;base port of CompuPro I3 or I4 cards
  81. UPORT:    EQU    BASE+7        ;user (UART select) port
  82. MDM:    EQU    5        ;default UART that controls modem port
  83.     ENDIF
  84. ;
  85.     IF     GBCSS1
  86. BASE:    EQU    05CH        ;base of serial section of CompuPro SS1
  87. UPORT:    EQU    0EFH        ;this should be some UNUSED port on...
  88. MDM:    EQU    0        ;...system - MDM7 will OUT the value...
  89.     ENDIF               ;...MDM to it.
  90. ;
  91. ;
  92. DPORT:    EQU    BASE        ;data port
  93. SPORT:    EQU    BASE+1        ;status port
  94. MPORT:    EQU    BASE+2        ;mode port
  95. CPORT:    EQU    BASE+3        ;control port
  96. ;
  97. TBMT:    EQU    01H        ;transmit buffer empty
  98. DAV:    EQU    02H        ;data available
  99. ;
  100.         ORG    100H
  101. ;
  102. ; Change the clock speed to suit your system
  103. ;
  104.         DS    3    ;(for  "JMP   START" instruction)
  105. ;
  106. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  107. SMARTMODEM:    DB    NO    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  108. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  109. CLOCK:        DB    80    ;clock speed in MHz x10, 25.5 MHz max.    106H
  110.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  111. MSPEED:        DB    5    ;0=110 1=300 3=600 5=1200 6=2400    107H
  112.                 ;7=4800 8=9600 9=19200 default
  113. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  114.                 ;default time to send character in ter-
  115.                 ;minal mode file transfer for slow BBS.
  116. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  117.                 ;default time for extra wait after CRLF
  118.                 ;in terminal mode file transfer
  119. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  120. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  121. SCRNTEST:    DB    YES    ;Cursor control routine            10CH
  122. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  123.                 ;no=resend a record after a valid-NAK
  124. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  125. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  126. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  127. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  128. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  129. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  130.                 ;terminal mode (added by remote echo)
  131. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  132. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  133.                 ;write logon sequence at location LOGON
  134. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  135. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  136.                 ;no=external command if EXTCHR precedes
  137. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  138. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  139. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  140.                 ;sending a file in terminal mode
  141. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  142.                 ;sending a file in terminal mode
  143. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  144. IGNORCTL:    DB    NO    ;yes=CTL-chars above ^M not displayed    11DH
  145. PARM:        DB    06EH    ;6E=8N1 EE=8N2 7E=8E1 FE=8E2 6A=7N1    11EH
  146.                 ;EA=7N2 7A=7E1 FA=7E2
  147.                 ;default data bits, parity, and stop bits
  148. EXITCHR        DB    'E'-40H ;^E = Exit to main menu            11FH
  149. BRKCHR:        DB    '@'-40H ;^@ = Send 300 ms. break tone        120H
  150. NOCONNCT:    DB    'N'-40H ;^N = Disconnect from the phone line    121H
  151. LOGCHR:        DB    'L'-40H ;^L = Send logon            122H
  152. LSTCHR:        DB    'P'-40H ;^P = Toggle printer            123H
  153. UNSAVE:        DB    'R'-40H ;^R = Close input text buffer        124H
  154. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  155. SAVECHR:    DB    'Y'-40H ;^Y = Open input text buffer        126H
  156. EXTCHR:        DB    '^'-40H ;^^ = Send next character        127H
  157. ;
  158. ;
  159.         DS    2        ;                128H
  160. ;
  161. IN$MODCTL1:    LDA    UART        ;in modem control port        12AH
  162.         OUT    UPORT
  163.         IN    SPORT
  164.         RET
  165.         DS    2
  166.  
  167. OUT$MODDATP:    PUSH    PSW        ;out modem data port        134H
  168.         LDA    UART
  169.         OUT    UPORT
  170.         POP    PSW
  171.         OUT    DPORT
  172.         RET
  173.  
  174. IN$MODDATP:    LDA    UART        ;in modem data port        13EH
  175.         OUT    UPORT
  176.         IN    DPORT
  177.         RET
  178.         DS    2
  179.  
  180. ANI$MODRCVB:    ANI    DAV    ! RET    ;bit to test for receive ready    148H
  181. CPI$MODRCVR:    CPI    DAV    ! RET    ;value of rcv. bit when ready    14BH
  182. ANI$MODSNDB:    ANI    TBMT    ! RET    ;bit to test for send ready    14EH
  183. CPI$MODSNDR:    CPI    TBMT    ! RET    ;value of send bit when ready    151H
  184.         DS    6        ;                156H
  185. ;
  186. OUT$MODCTL1:    RET    ! DS 2        ;out modem control port #1    15AH
  187. OUT$MODCTL2:    RET    ! DS 2        ;out modem control port #2    15DH
  188. ;
  189. LOGONPTR:    DW    LOGON        ;for user message.        160H
  190.         DS    6        ;                162H
  191. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  192. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  193.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    16EH
  194.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    171H
  195.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    174H
  196. JMP$SETUPR:    JMP    SETUPR        ;                177H
  197. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  198. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  199. JMP$BREAK:    JMP    SENDBRK        ;                180H
  200. ;
  201. ;
  202. ; Do not change the following six lines.
  203. ;
  204. JMP$ILPRT:    DS    3        ;                183H
  205. JMP$INBUF    DS    3        ;                186H
  206. JMP$INLNCOMP:    DS    3        ;                189H
  207. JMP$INMODEM    DS    3        ;                18CH
  208. JMP$NXTSCRN:    DS    3        ;                18FH
  209. JMP$TIMER    DS    3        ;                192H
  210. ;
  211. ;
  212. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  213. ; SCRNTEST to YES at 010AH (above). TV-920
  214. ;
  215. CLREOS:        CALL    JMP$ILPRT    ;                195H
  216.         DB    ESC,'Y',0,0,0    ;                198H
  217.         RET            ;                19DH
  218. ;
  219. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  220.         DB    ESC,'*',0,0,0    ;                1A1H
  221.         RET            ;                1A6H
  222.     
  223. ;
  224. SYSVER:        CALL    JMP$ILPRT
  225.         DB    'Version for CompuPro '
  226.  
  227.         IF    GBCSS1
  228.         DB    'System Support-1'
  229.         ENDIF
  230.  
  231.         IF    GBCI3
  232.         DB    'Interfacer-3 (port ',MDM+'0',')'
  233.         ENDIF
  234.  
  235.         IF    GBCI4
  236.         DB    'Interfacer-4 (port ',MDM+'0',')'
  237.         ENDIF
  238.  
  239.         DB    CR,LF,0
  240.         RET
  241.  
  242. ;.....
  243. ;
  244. ;
  245. ;-----------------------------------------------------------------------
  246. ;
  247. ; NOTE:     You can change the SYSVER message to be longer or shorter.  The
  248. ;     end of your last routine should terminate by 0400H (601 bytes
  249. ;     available after start of SYSVER) if using the Hayes Smartmodem
  250. ;     or by address 0C00H (2659 bytes) otherwise.
  251. ;
  252. ;-----------------------------------------------------------------------
  253. ;
  254. ; You can put in a message at this location which can be called up with
  255. ; CTL-O if TRANLOGON has been set TRUE.     You can use several lines if
  256. ; desired.  End with a 0.
  257. ;
  258. LOGON:      DB    'AT S7=20 S11=50',CR,0
  259. ;.....
  260. ;
  261. ;
  262. ; Add your own routine here to send a break tone to reset some time-
  263. ; share computers, if desired.
  264. ;
  265. UART:      DB    MDM        ;current UART number
  266. ;
  267. SENDBRK:  LDA    UART        ;select chip
  268.       OUT    UPORT
  269.       MVI    A,2FH        ;send break for 300ms
  270.       JMP    GOODBYE1
  271. ;.....
  272. ;
  273. ;
  274. ; Add your own routine here to put DTR low and/or send a break tone.
  275. ; Check other routines such as M7DP-x.ASM which uses this feature.
  276. ;
  277. GOODBYE:  LDA    UART        ;select chip
  278.       OUT    UPORT
  279.       XRA    A        ;turn off DTR
  280. ;
  281. GOODBYE1: OUT    CPORT
  282.       MVI    B,3        ;turn off DTR for 300 ms.
  283.       CALL    JMP$TIMER
  284.       MVI    A,27H        ;turn DTR back on
  285.       OUT    CPORT
  286.       RET
  287. ;.....
  288. ;
  289. ;
  290. ; You can use this area for any special initialization or setup you may
  291. ; wish to include.  Each must stop with a RET.    You can check the other
  292. ; available overlays for ideas how to write your own routines if that
  293. ; may be of some help.
  294. ;
  295. BDOS:      EQU    5
  296. READCNSL: EQU    1
  297. ;
  298.       IF UARTOP OR BAUDOP OR PARMOP
  299. INVSEL:      CALL    JMP$ILPRT
  300.       DB    CR,LF,LF,BELL,'Invalid selection.',0
  301.       RET
  302. ;
  303. SETUPR:      IF    (GBCI3 OR GBCI4) AND UARTOP
  304.       LDA    UART
  305.       ADI    '0'
  306.       STA    UARTDISP
  307.       CALL    JMP$ILPRT
  308.       DB    CR,LF,'Current UART number is '
  309. UARTDISP: DB    ' .  Do you wish to change it? (Y/N) ',0
  310.       MVI    C,READCNSL
  311.       CALL    BDOS
  312.       CPI    'Y'
  313.       JZ    UARTSEL
  314.       CPI    'y'
  315.       JNZ    SPEEDSEL
  316. ;
  317. UARTSEL:  CALL    JMP$ILPRT
  318.       DB    CR,LF,'Enter new UART number (0-7) ',0
  319.       MVI    C,READCNSL
  320.       CALL    BDOS
  321.       SBI    '0'
  322.       JM    UARTINV
  323.       CPI    8
  324.       JM    UARTOK
  325. UARTINV:  CALL    INVSEL
  326.       JMP    UARTSEL
  327. UARTOK:      STA    UART        ;save new UART number
  328.       ENDIF
  329. ;
  330.       IF    BAUDOP
  331. SPEEDSEL: CALL    JMP$ILPRT
  332.       DB    CR,LF,'Select baud rate (0=110 1=300 2=600 3=1200 '
  333.       DB    '4=2400 5=4800 6=9600 7=19.2k) ',0
  334.       MVI    C,READCNSL
  335.       CALL    BDOS
  336.       SBI    '0'
  337.       JM    SPEEDINV
  338.       CPI    8
  339.       JM    SPEEDOK
  340. SPEEDINV: CALL    INVSEL
  341.       JMP    SPEEDSEL
  342. SPEEDOK:  LXI    H,MSPEDTAB
  343.       MVI    B,0
  344.       MOV    C,A
  345.       DAD    B
  346.       MOV    A,M        ;get new value
  347.       STA    MSPEED        ;and save it
  348.       ENDIF
  349. ;
  350.       IF    PARMOP
  351. PARMSEL:  CALL    JMP$ILPRT
  352.       DB    CR,LF,'Select parameter (0=8N1 1=8N2 2=8E1 3=8E2 4=7N1 '
  353.       DB    '5=7N2 6=7E1 7=7E2) ',0
  354.       MVI    C,READCNSL
  355.       CALL    BDOS
  356.       SBI    '0'
  357.       JM    PARMINV
  358.       CPI    8
  359.       JM    PARMOK
  360. PARMINV:  CALL    INVSEL
  361.       JMP    PARMSEL
  362. PARMOK:      LXI    H,PARMTAB
  363.       MVI    B,0
  364.       MOV    C,A
  365.       DAD    B
  366.       MOV    A,M        ;get new parameter
  367.       STA    PARM        ;and save it
  368.       ENDIF
  369. ;
  370.       CALL    JMP$ILPRT
  371.       DB    CR,LF,LF,'Modem setup completed.',CR,LF,0
  372. ;
  373. INITMOD:  LDA    UART        ;select UART
  374.       OUT    UPORT
  375.       LDA    PARM        ;select data bits, parity, stop bits
  376.       OUT    MPORT
  377.       LDA    MSPEED        ;select baud rate
  378.       LXI    H,SPEEDTAB
  379.       MVI    B,0
  380.       MOV    C,A
  381.       DAD    B
  382.       MOV    A,M
  383.       OUT    MPORT
  384.       MVI    A,27H        ;turn on DTR, etc.
  385.       OUT    CPORT
  386.       RET
  387. ;
  388.       IF    BAUDOP
  389. SPEEDTAB: DB    72H        ;  110 bps
  390.       DB    75H        ;  300 bps
  391.       DB    75H        ;  300 bps
  392.       DB    76H        ;  600 bps
  393.       DB    76H        ;  600 bps
  394.       DB    77H        ; 1200 bps
  395.       DB    7AH        ; 2400 bps
  396.       DB    7CH        ; 4800 bps
  397.       DB    7EH        ; 9600 bps
  398.       DB    7FH        ;19200 bps
  399. ;
  400. MSPEDTAB: DB    0        ;  110 bps
  401.       DB    1        ;  300 bps
  402.       DB    3        ;  600 bps
  403.       DB    5        ; 1200 bps
  404.       DB    6        ; 2400 bps
  405.       DB    7        ; 4800 bps
  406.       DB    8        ; 9600 bps
  407.       DB    9        ;19200 bps
  408.       ENDIF
  409. ;
  410.       IF    PARMOP
  411. PARMTAB:  DB    06EH        ;8N1
  412.       DB    0EEH        ;8N2
  413.       DB    07EH        ;8E1
  414.       DB    0FEH        ;8E2
  415.       DB    06AH        ;7N1
  416.       DB    0EAH        ;7N2
  417.       DB    07AH        ;7E1
  418.       DB    0FAH        ;7E2
  419.       ENDIF
  420. ;
  421. ;           (END OF INITMOD AND SETUP ROUTINES)
  422. ;=======================================================================
  423. ;
  424. ;
  425. ; If using the Hayes Smartmodem this is unavailable without a special
  426. ; change.
  427. ;
  428. SPCLMENU:  RET
  429. ;
  430. ;
  431. ; NOTE:     MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  432. ;                 0C00H (without Smartmodem)
  433. ;.....
  434. ;
  435.       END
  436.