home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / MODEM7 / M7HZ-1.AQM / M7HZ-1.ASM
Assembly Source File  |  2000-06-30  |  10KB  |  311 lines
  1.  
  2. ; M7HZ-1.ASM -- Heath/Zenith - 100 overlay for MDM7xx.    11/11/83
  3. ;
  4. ; You will want to look this file over carefully. There are a number of
  5. ; options that you can use to configure the program to suit your taste.
  6. ; This file places particular emphasis on using the Heath/Zenith "100"
  7. ; equipment.  Much of the information contained here is not in the main
  8. ; file.
  9. ;
  10. ; Edit this file for your preferences then follow the "TO USE:" example
  11. ; shown below.
  12. ;
  13. ; Use the MDM7xx "SET" command to change the baudrate when desired.  It
  14. ; starts out at 300 baud when the program is first called up.
  15. ;
  16. ;
  17. ;    TO USE: First edit this file filling in answers for your own
  18. ;        equipment.  Then assemble with ASM.COM or equivalent
  19. ;        assembler.  Then use DDT to overlay the the results
  20. ;        of this program to the original .COM file:
  21. ;
  22. ;        A>DDT MDM7xx.COM
  23. ;        DDT VERS 2.2
  24. ;        NEXT  PC
  25. ;        4300 0100
  26. ;        -IM7HZ-1.HEX        (note the "I" command)
  27. ;        -R            ("R" loads in the .HEX file)
  28. ;        NEXT  PC
  29. ;        4300 0000
  30. ;        -G0            (return to CP/M)
  31. ;        A>SAVE 66 MDM7xx.COM    (now have a modified .COM file)
  32. ;
  33. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  34. ;
  35. ; 11/11/83 - Renamed to M7HZ-1.ASM, no changes    - Irv Hoff    
  36. ; 07/27/83 - Renamed to work with MDM712    - Irv Hoff
  37. ; 07/01/83 - Revised to work with MDM711    - Irv Hoff
  38. ; 06/22/83 - Revised to work with MDM710    - Irv Hoff
  39. ; 05/27/83 - Revised to work with MDM709    - Irv Hoff
  40. ; 05/15/83 - Revised to work with MDM708    - Irv Hoff
  41. ; 04/11/83 - Updated to work with MDM707    - Irv Hoff
  42. ; 04/04/83 - Updated to work with MDM706    - Irv Hoff
  43. ; 02/27/83 - Updated to work with MDM705    - Irv Hoff
  44. ; 02/17/83 - Modified MDM703CF to work with
  45. ;         Heath/Zenith -100 series com-
  46. ;         puters with 2661B I/O        - Irv Hoff
  47. ;
  48. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  49. ;
  50. BELL:        EQU    07H        ;bell
  51. CR:        EQU    0DH        ;carriage return
  52. ESC:        EQU    1BH        ;escape
  53. LF:        EQU    0AH        ;linefeed
  54. ;
  55. YES:        EQU    0FFH
  56. NO:        EQU    0
  57. ;
  58. ;
  59. MODDATP:    EQU    0ECH        ;data port for Z-100
  60. MODCTL1:    EQU    MODDATP+1    ;status port for Z-100
  61. MODRCVB:    EQU    2        ;bit to test for received data
  62. MODRCVR:    EQU    2        ;modem receive ready
  63. MODSNDB:    EQU    1        ;bit to test for ready to send
  64. MODSNDR:    EQU    1        ;modem send ready bit
  65. ;
  66. ;
  67. ; Change the clock speed if needed, to match your system.  The 2661B
  68. ; normally runs 4.9152 MHz.
  69. ;
  70. ;
  71.         ORG    100H
  72. ;
  73.         DS    3    ;(for  "JMP   START" instruction)
  74. ;
  75. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  76. SMARTMODEM:    DB    NO    ;yes=HAYES Smartmodem, no=non-Hayes    104H
  77. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  78. CLOCK:        DB    49    ;clock speed in MHz x10, 25.5 MHz max.    106H
  79.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  80. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  81.                 ;6=2400 7=4800 8=9600 9=19200 default
  82. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  83.                 ;default time to send character in ter-
  84.                 ;minal mode file transfer for slow BBS.
  85. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  86.                 ;default time for extra wait after CRLF
  87.                 ;in terminal mode file transfer
  88. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  89. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  90. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  91. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  92.                 ;no=resend a record after a valid NAK
  93. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  94. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  95. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  96. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  97. TOGGLEBK:    DB    NO    ;yes=allow toggling of bksp to rub    112H
  98. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  99.                 ;terminal mode (added by remote echo)
  100. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  101. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  102.                 ;write logon sequence at location LOGON
  103. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  104. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  105.                 ;no=external command if EXTCHR precedes
  106. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  107. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  108. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  109.                 ;sending a file in terminal mode
  110. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  111.                 ;sending a file in terminal mode
  112. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  113. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  114. EXTRA1:        DB    0    ;for future expansion            11EH
  115. EXTRA2:        DB    0    ;for future expansion            11FH
  116. BRKCHR:        DB    '@'-40H    ;^@ = Send a 300 ms. break tone        120H
  117. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  118. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  119. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  120. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  121. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  122. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        125H
  123. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        126H
  124. ;
  125. ;
  126.         DS    2        ;                128H
  127. ;
  128. IN$MODCTL1:    IN    MODCTL1 ! RET    ;in modem control port        12AH
  129.         DS    7
  130. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  131.         DS    7
  132. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  133.         DS    31
  134. ;
  135. LOGONPTR:    DW    LOGON        ;for user message.        160H
  136.         DS    6        ;                162H
  137. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  138. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  139.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    16EH
  140.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    171H
  141.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    174H
  142. JMP$SETUPR:    JMP    SETUPR        ;                177H
  143. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  144. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  145. JMP$BREAK:    JMP    SENDBRK        ;                180H
  146. ;
  147. ;
  148. ; Do not change the following six lines.
  149. ;
  150. JMP$ILPRT:    DS    3        ;                183H
  151. JMP$INBUF    DS    3        ;                186H
  152. JMP$INLNCOMP:    DS    3        ;                189H
  153. JMP$INMODEM    DS    3        ;                18CH
  154. JMP$NXTSCRN:    DS    3        ;                18FH
  155. JMP$TIMER:    DS    3        ;                192H
  156. ;
  157. ;
  158. CLREOS:        CALL    JMP$ILPRT    ;                195H
  159.         DB    ESC,'J',0,0,0    ;                198H
  160.         RET            ;                19DH
  161. ;
  162. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  163.         DB    ESC,'E',0,0,0    ;CLEAR ENTIRE SCREEN        1A1H
  164.         RET            ;                1A6H
  165. ;
  166. ;
  167. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  168.         DB    'Version for Zenith Z-120 modem port J2'
  169.         DB    CR,LF,0
  170.         DB    RET
  171. ;.....
  172. ;
  173. ;
  174. ;-----------------------------------------------------------------------
  175. ;
  176. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  177. ;     end of your last routine should terminate by 0400H (601 bytes
  178. ;     available after start of SYSVER) if using the Hayes Smartmodem
  179. ;     or by address 0C00H (2659 bytes available) otherwise.
  180. ;
  181. ;-----------------------------------------------------------------------
  182. ;
  183. ; You can put in a message at this location which can be called up with
  184. ; CTL-O if TRANLOGON has been set YES.    You can put in several lines if
  185. ; desired.  End with a 0.
  186. ;
  187. LOGON:      DB    'Hello from a Zenith Z-120 computer',CR,LF,0
  188. ;.....
  189. ;    
  190. ;
  191. ; This routine allows a 300 ms. break tone to be send to reset some
  192. ; time-share computers.
  193. ;
  194. SENDBRK:  MVI    A,1DH        ;SEND A BREAK TONE FOR 300 MS.
  195.       JMP    GOODBYE1
  196. ;.....
  197. ;
  198. ;
  199. ; This routine sends a 300 ms. break tone and sets DTR low for the same
  200. ; length of time to disconnect some modems such as the Bell 212A, etc.
  201. ;
  202. GOODBYE:  MVI    A,05H        ;SET BREAK, DTR LOW
  203. ;
  204. GOODBYE1: OUT    MODDATP+3    ;PUT COMMAND REGISTER OUT OF MODE
  205.       IN    MODDATP+3    ;MAKE SURE IT IS NOW CLEAR
  206.       IN    MODDATP+3    ;TRY ONCE MORE
  207.       MVI    B,3        ;DELAY FOR 300 MS.
  208.       CALL    JMP$TIMER
  209.       MVI    A,37H        ;RESET RTS, FLAGS, DTR LOW, ENABLE R/T
  210.       OUT    MODDATP+3    ;SEND TO COMMAND REGISTER
  211.       IN    MODDATP+3    ;CLEAR ANY INCOMING CHARS.
  212.       IN    MODDATP+3    ;TRY ONCE MORE
  213.       XRA    A        ;CLEAR THE 'A' REG.
  214.       RET
  215. ;.....
  216. ;
  217. ;
  218. ; The following are used in setting up the 2661B I/O port.
  219. ;
  220. INITMOD:  MVI    A,1        ;DEFAULT TRANSFER TIME TO 300 BAUD
  221.       STA    MSPEED
  222.       XRA    A        ;SET RTS, FLAGS, DTR, DISABLE R/T
  223.       OUT    MODDATP+3    ;PUT COMMAND REGISTER OUT OF MODE
  224.       IN    MODDATP+3    ;MAKE SURE IT IS NOW CLEAR
  225.       IN    MODDATP+3    ;TRY ONCE MORE
  226.       MVI    A,4EH        ;1 STOP, NO PARITY, 8 BITS, 16X ASYNCH
  227.       OUT    MODDATP+2    ;SEND TO MODE REGISTER 1
  228. ;
  229. INITMOD1: MVI    A,0F6H        ;START WITH 300 BAUD, INTERNAL 4.9 CLOCK
  230.       OUT    MODDATP+2    ;SEND TO MODE REGISTER 2
  231.       MVI    A,37H        ;RESET RTS, FLAGS, DTR LOW, ENABLE R/T
  232.       OUT    MODDATP+3    ;SEND TO COMMAND REGISTER
  233.       IN    MODDATP+3    ;CLEAR ANY INCOMING CHARS.
  234.       IN    MODDATP+3    ;TRY ONCE MORE
  235.       XRA    A        ;CLEAR THE 'A' REG.
  236.       RET
  237. ;.....
  238. ;
  239. ;
  240. ; The following changes the baud rate with the SET command.
  241. ;
  242. SETUPR:      LXI    D,BAUDBUF
  243.       CALL    JMP$ILPRT
  244.       DB    'Input Baud Rate (110, 300, 1200, 9600): ',0
  245.       CALL    JMP$INBUF
  246.       LXI    D,BAUDBUF+2
  247.       CALL    JMP$INLNCOMP
  248.       DB    '110',0
  249.       JNC    OK110
  250.       CALL    JMP$INLNCOMP    ;COMPARE BAUDBUF+2 WITH CHARACTERS BELOW
  251.       DB    '300',0
  252.       JNC    OK300        ;GO IF GOT MATCH
  253.       CALL    JMP$INLNCOMP
  254.       DB    '1200',0
  255.       JNC    OK1200
  256.       CALL    JMP$INLNCOMP
  257.       DB    '9600',0
  258.       JNC    OK9600
  259.       CALL    JMP$ILPRT    ;ALL MATCHES FAILED, ASK AGAIN
  260.       DB    '++ Incorrect entry ++',CR,LF,BELL,0
  261.       JMP    SETUPR        ;TRY AGAIN
  262. ;
  263. OK110:      MVI    A,0        ;MSPEED 110 BAUD VALUE
  264.       LHLD    BD110        ;GET 110 BAUD PARAMETERS IN 'HL'
  265.       JMP    LOADBD        ;GO LOAD THEM
  266. ;
  267. OK300:      MVI    A,1
  268.       LHLD    BD300
  269.       JMP    LOADBD
  270. ;
  271. OK1200:      MVI    A,5
  272.       LHLD    BD1200
  273.       JMP    LOADBD
  274. ;
  275. OK9600:      MVI    A,8
  276.       LHLD    BD9600
  277. ;
  278. LOADBD:      STA    INITMOD+1
  279.       MOV    A,L        ;get least significant baud rate byte
  280.       STA    INITMOD1+1    ;store in INITMOD1
  281.       JMP    INITMOD        ;reset Z-100 2661
  282. ;.....
  283. ;
  284. ;
  285. ; TABLE OF BAUDRATE PARAMETERS FOR 2661 I/O
  286. ;
  287. BD110:      DW    00F3H
  288. BD300:      DW    00F6H
  289. BD1200:      DW    00F8H
  290. BD9600:      DW    00FDH
  291. ;
  292. BAUDBUF:  DB    10,0
  293.       DS    10
  294. ;
  295. ;-----------------------------------------------------------------------
  296. ;
  297. ; The following routine could be used to display selections of interest
  298. ; to owners of this computer.  If using the Hayes Smartmodem this is
  299. ; unavailable without a special change.
  300. ;
  301. SPCLMENU: RET
  302. ;
  303. ;-----------------------------------------------------------------------
  304. ;
  305. ;
  306. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  307. ;                 0C00H (without Smartmodem)
  308. ;
  309.       END
  310. ;
  311.