home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / MODEM7 / M7C3-1.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  9KB  |  338 lines
  1.  
  2. ; M7C3-1.ASM -- CP/M Plus overlay file for MODEM7.  11/19/83
  3. ;
  4. ; This overlay adapts the MODEM7 program to use the auxiliary device
  5. ; in CP/M Version 3.
  6. ;
  7. ; You will want to look this file over carefully. There are a number of
  8. ; options that you can use to configure the program to suit your taste.
  9. ; This file places particular emphasis on using the Auxiliary device
  10. ; properly configured under CP/M 3.
  11. ;
  12. ;
  13. ; Edit this file for your preferences then follow the "TO USE:" example
  14. ; shown below.
  15. ;
  16. ;    TO USE: First edit this file filling in answers for your own
  17. ;        equipment.  Then assemble with MAC.COM or equivalent
  18. ;        assembler.  Then use SID to overlay the the results
  19. ;        of this program to the original .COM file:
  20. ;
  21. ;        A>SID MDM712
  22. ;        CP/M 3 SID - Version 3.0
  23. ;        NEXT MSZE  PC  END
  24. ;        4300 4300 0100 D3FF
  25. ;        #E M7C3-1.HEX        ("E" loads in the .HEX file)
  26. ;        NEXT MSZE  PC  END
  27. ;        031E 4300 0100 D3FF
  28. ;        #W MDM712.COM,100,42FF    ("W" writes the modified .COM file)
  29. ;        0084h record(s) written
  30. ;        #G0            (return to CP/M)
  31. ;
  32. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  33. ;
  34. ; 11/19/83 - Edited M712GP.ASM for this file    - Jim Lopushinsky
  35. ;
  36. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  37. ;
  38. BELL:        EQU    07H        ;bell
  39. CR:        EQU    0DH        ;carriage return
  40. ESC:        EQU    1BH        ;escape
  41. LF:        EQU    0AH        ;linefeed
  42. ;
  43. YES:        EQU    0FFH
  44. NO:        EQU    0
  45. ;
  46. ;
  47. ; Change the following information to match your equipment
  48. ;
  49. BDOS:        EQU    5
  50. DEVICE:        EQU    1    ;CP/M's MODEM device number
  51. ;
  52.         ORG    100H
  53. ;
  54. ;
  55. ; Change the clock speed to suit your system
  56. ;
  57.         DS    3    ;(for  "JMP   START" instruction)
  58. ;
  59. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  60. SMARTMODEM:    DB    YES    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  61. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  62. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  63.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  64. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200   107H
  65.                 ;6=2400 7=4800 8=9600 9=19200 default
  66. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
  67.                 ;default time to send character in ter-
  68.                 ;minal mode file transfer for slow BBS.
  69. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  70.                 ;default time for extra wait after CRLF
  71.                 ;in terminal mode file transfer
  72. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  73. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  74. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  75. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  76.                 ;no=resend a record after a valid-NAK
  77. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  78. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  79. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  80. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  81. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  82. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  83.                 ;terminal mode (added by remote echo)
  84. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  85. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  86.                 ;write logon sequence at location LOGON
  87. SAVCCP:        DB    NO    ;yes=do not overwrite CCP        116H
  88. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  89.                 ;no=external command if EXTCHR precedes
  90. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  91. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  92. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  93.                 ;sending a file in terminal mode
  94. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  95.                 ;sending a file in terminal mode
  96. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  97. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  98. EXTRA1:        DB    0    ;for future expansion            11EH
  99. EXTRA2:        DB    0    ;for future expansion            11FH
  100. BRKCHR:        DB    '@'-40H    ;^@ = Send 300 ms. break tone        120H
  101. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  102. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  103. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  104. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  105. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  106. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  107. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        127H
  108. ;
  109. ;
  110.         DS    2        ;                128H
  111. ;
  112. IN$MODCTL1:    RET            ;                     12AH
  113.         DS    9
  114. OUT$MODDATP:    JMP    AUXOUT        ;out modem data port        134H
  115.         DS    7
  116. IN$MODDATP:    JMP    AUXIN        ;in modem data port        13EH
  117.         DS    7
  118. ANI$MODRCVB:    RET            ;                148H
  119.         DS    2
  120. CPI$MODRCVR:    JMP    AUXINST        ;value of rcv. bit when ready    14BH
  121. ANI$MODSNDB:    RET            ;                14EH
  122.         DS    2
  123. CPI$MODSNDR:    JMP    AUXOUTST    ;value of send bit when ready    151H
  124.         DS    6        ;                156H
  125. ;
  126. OUT$MODCTL1:    RET            ;                15AH
  127.         DS    2
  128. OUT$MODCTL2:    RET            ;                15DH
  129.         DS    2
  130. ;
  131. LOGONPTR:    DW    LOGON        ;for user message.        160H
  132.         DS    6        ;                162H
  133. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  134. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  135.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    16EH
  136.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    171H
  137.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    174H
  138. JMP$SETUPR:    JMP    SETUPR        ;                177H
  139. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  140. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  141. JMP$BREAK:    JMP    SENDBRK        ;                180H
  142. ;
  143. ;
  144. ; Do not change the following six lines.
  145. ;
  146. JMP$ILPRT:    DS    3        ;                183H
  147. JMP$INBUF    DS    3        ;                186H
  148. JMP$INLNCOMP:    DS    3        ;                189H
  149. JMP$INMODEM    DS    3        ;                18CH
  150. JMP$NXTSCRN:    DS    3        ;                18FH
  151. JMP$TIMER    DS    3        ;                192H
  152. ;
  153. ; 
  154. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  155. ; SCRNTEST to YES at 010AH (above).
  156. ;
  157. CLREOS:        CALL    JMP$ILPRT    ;                195H
  158.         DB    ESC,'k',0,0,0    ;Setup for Adds Viewpoint    198H
  159.         RET            ;                19DH
  160. ;
  161. CLRSCRN:    CALL    JMP$ILPRT    ;                19EH
  162.         DB    12,0,0,0,0    ;Setup for Adds Viewpoint    1A1H
  163.         RET            ;                1A6H
  164.     
  165. ;
  166. SYSVER:        CALL    JMP$ILPRT    ;                1A7H
  167.         DB    'Version for CP/M Plus (Device '
  168.         DB    DEVICE+'0',')'
  169.         DB    CR,LF,0
  170.         RET
  171. ;.....
  172. ;
  173. ;
  174. ;-----------------------------------------------------------------------
  175. ;
  176. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  177. ;     end of your last routine should terminate by 0400H (601 bytes
  178. ;     available after start of SYSVER) if using the Hayes Smartmodem
  179. ;     or by address 0C00H (2659 bytes) otherwise.
  180. ;
  181. ;-----------------------------------------------------------------------
  182. ;
  183. ; You can put in a message at this location which can be called up with
  184. ; CTL-O if TRANLOGON has been set TRUE.  You can use several lines if
  185. ; desired.  End with a 0.
  186. ;
  187. LOGON:        DB    'The cow jumped over the moon',CR,0
  188. ;.....
  189. ;
  190. ;
  191. ; Add your own routine here to send a break tone to reset some time-share
  192. ; computers, if desired.
  193. ;
  194. SENDBRK:    RET
  195. ;.....
  196. ;
  197. ;
  198. ; Add your own routine here to put DTR low and/or send a break tone.
  199. ; Check other routines such as MDM709DP.ASM which is using this feature.
  200. ;
  201. GOODBYE:    RET
  202. ;.....
  203. ;
  204. ;
  205. ; You can use this area for any special initialization or setup you may
  206. ; wish to include.  Each must stop with a RET.  You can check the other
  207. ; available overlays for ideas how to write your own routines if that
  208. ; may be of some help.
  209. ;
  210. INITMOD:      MVI    C,12
  211.         CALL    BDOS    ;Get version #
  212.         CPI    30H
  213.         JNC    ISCPM3
  214.         CALL    JMP$ILPRT
  215.         DB    'Requires CP/M Version 3',CR,LF,0
  216.         RST    0
  217.  
  218. ISCPM3:        MVI    A,20    ;BIOS return character I/O table function
  219.         STA    FUNC
  220.         MVI    C,50
  221.         LXI    D,FUNC
  222.         CALL    BDOS
  223.         PUSH    H    ;Save the table address for later
  224.         LXI    H,7    ;Offset to baud rate
  225.         MVI    A,DEVICE
  226.         ORA    A
  227.         JZ    ISZERO
  228.         LXI    D,8
  229.  
  230. DEVLP:        DAD    D
  231.         DCR    A
  232.         JNZ    DEVLP
  233.  
  234. ISZERO:        POP    D    ;Get Table address
  235.         DAD    D    ;Form baud rate address
  236.         SHLD    BAUDAD
  237.         RET
  238. ;
  239. SETUPR:          CALL    JMP$ILPRT
  240.         DB    'Input Baud Rate (300, 1200, 9600 ,19200): ',0
  241.         LXI    D,BAUDBUF
  242.         CALL    JMP$INBUF
  243.         LXI    D,BAUDBUF+2
  244.         CALL    JMP$INLNCOMP
  245.         DB    '300',0
  246.         JNC    OK300
  247.         CALL    JMP$INLNCOMP
  248.         DB    '1200',0
  249.         JNC    OK1200
  250.         CALL    JMP$INLNCOMP
  251.         DB    '9600',0
  252.         JNC    OK9600
  253.         CALL    JMP$INLNCOMP
  254.         DB    '19200',0
  255.         JNC    OK19200
  256.         CALL    JMP$ILPRT
  257.         DB    '++ Incorrect entry ++',CR,LF,BELL,0
  258.         JMP    SETUPR
  259.  
  260. OK300:        MVI    A,1
  261.         MVI    B,6
  262.         JMP    LOADBD
  263.  
  264. OK1200:        MVI    A,5
  265.         MVI    B,8
  266.         JMP    LOADBD
  267.  
  268. OK9600:        MVI    A,8
  269.         MVI    B,14
  270.         JMP    LOADBD
  271.  
  272. OK19200:    MVI    A,9
  273.         MVI    B,15
  274.  
  275. LOADBD:        STA    MSPEED
  276.         LHLD    BAUDAD
  277.         MOV    M,B
  278.         LXI    H,DEVICE
  279.         SHLD    BCREG
  280.         MVI    A,21
  281.         STA    FUNC
  282.         MVI    C,50
  283.         LXI    D,FUNC
  284.         JMP    BDOS
  285.  
  286. AUXIN:        DB    0D9H    ;EXX
  287.         MVI    C,3
  288.         CALL    BDOS
  289.         DB    0D9H    ;EXX
  290.         RET
  291.  
  292. AUXOUT:        DB    0D9H    ;EXX
  293.         MVI    C,4
  294.         MOV    E,A
  295.         PUSH    PSW
  296.         CALL    BDOS
  297.         POP    PSW
  298.         DB    0D9H    ;EXX
  299.         RET
  300.  
  301. AUXINST:    DB    0D9H    ;EXX
  302.         MVI    C,7
  303.         CALL    BDOS
  304.         DB    0D9H    ;EXX
  305.         INR    A    ;Reverse sense
  306.         RET
  307.  
  308. AUXOUTST:    DB    0D9H    ;EXX
  309.         MVI    C,8
  310.         CALL    BDOS
  311.         DB    0D9H    ;EXX
  312.         INR    A    ;Reverse sense
  313.         RET
  314.  
  315. BAUDBUF:    DB    10,0
  316.         DS    2
  317.  
  318. FUNC:        DS    1
  319. AREG:        DS    1
  320. BCREG:        DS    2
  321. DEREG:        DS    2
  322. HLREG:        DS    2
  323. BAUDAD:        DS    2
  324. ;
  325. ;
  326. ; If using the Hayes Smartmodem this is unavailable without a special
  327. ; change.
  328. ;
  329. SPCLMENU:  RET
  330. ;
  331. ;
  332. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  333. ;                 0C00H (without Smartmodem)
  334. ;.....
  335. ;
  336.       END
  337. ;
  338.