home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / MODEM / DIAL3.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  23KB  |  917 lines
  1. ;DIAL.ASM  V3.0   BY JEFF HAMMERSLEY
  2. ;
  3. ;CP/M - PMMI CONSOLE, STORED, AND PRESET AUTODIALING
  4. ;PROGRAM.
  5. ;
  6. ;  THIS PROGRAM CONTAINS MANY FEATURES FOUND IN WARD
  7. ;CHRISTENSEN'S MODEM PROGRAM 8/6/79 AND THE ORIGINATE-
  8. ;ANSWER DEMO. PROGRAM DISTRIBUTED BY PMMI FOR THEIR
  9. ;MM103 MODEM (4/2/79). FULL CREDIT MUST BE GIVEN TO
  10. ;THESE INDIVIDUALS FOR THEIR GROUND WORK.
  11. ;
  12. ;MODIFICATION HISTORY:
  13. ;
  14. ;07/31/81 ENTERED NEW TABLE OF NUMBERS TO DIAL
  15. ;      ENTERED COMMAND '?' TO PRINT TABLE. (JCG)
  16. ;
  17. ;06/23/80 CORRECTED EDITING ERRORS IN COMMENTS AND
  18. ;      SET MODEM PORT NUMBERS TO PMMI STANDARD. (KBP)
  19. ;
  20. ;06/22/80 CORRECTED ERROR IN SELECTING 'A' (REQUIRES NO OFFSET) 
  21. ;      ALSO CLEANED UP PHONELIST, NOLONGER LEAVES 'GARBAGE' IN AREA.
  22. ;      AND IT IS EASIER TO KEEP TRACK OF DATA AREA. BY HANK SZYSZKA
  23. ;
  24. ;03/08/80 RINGBACK REWRITTEN.  (BY COMMITTEE DECISION, THE FANCY
  25. ;      FOOTWORK PREVIOUSLY DONE TO IDENTIFY BUSY AND FAR END
  26. ;      RINGING HAS BEEN REMOVED IN FAVOR OF A MORE RELIABLE,
  27. ;      SIMPLE CARRIER OR TONE IDENTIFICATION).  (JH)
  28. ;
  29. ;12/16/79 EXTENDED NUMBER LIST ASCII INFO.  (JH)
  30. ;
  31. ;11/21/79 BASIC TIMING MODS.  (JH)
  32. ;
  33. ;12/04/79 EQUATE AND LABEL FOR 20PPS DIALING (JH)
  34. ;
  35. ;09/21/79 ORIGINALLY WRITTEN BY JEFF HAMMERSLEY
  36. ;
  37. ;***********************************************************
  38. ;   EQUATES
  39. ;
  40. MCTLP     EQU    0C0H    ;PMMI VALUES
  41. MSNDB    EQU    1    ;BIT TO TEST FOR SEND
  42. MSNDR     EQU    1    ;VALUE WHEN READY
  43. MRCVB    EQU    2    ;BIT TO TEST FOR RECEIVE
  44. MRCVR     EQU    2    ;VALUE WHEN READY
  45. MDATP    EQU    0C1H    ;DATA PORT
  46. BAUDRP     EQU    0C2H    ;BAUD RATE OUTPUT
  47. MCTL2     EQU    0C3H    ;SECOND CTL PORT
  48. ;
  49. ORIGM     EQU    1DH    ;8 DATA, NO PARITY, ORIG
  50. ;
  51. NUMPPS     EQU    125    ;125=20PPS, 250=10PPS
  52. PULSE     EQU    80H    ;TIMER PULSE MASK
  53. MAKE     EQU    01H    ;TEL LINE MAKE (OFF HOOK)
  54. BRK     EQU    00H    ;TEL LINE BREAK (ON HOOK)
  55. INTER     EQU    7    ;INTERDIGIT TIME
  56. CLEAR     EQU    3FH    ;CLEAR MODEM TO IDLE
  57. DTDET     EQU    2FH    ;SWITCH ON DIAL TONE DETECT
  58. DTMSK     EQU    01H    ;DIAL TONE MASK
  59. DTR3     EQU    07FH    ;DATA TERMINAL READY (300 baud)
  60. CTSBT     EQU    04H    ;CLEAR TO SEND BIT
  61. BAUDRT     EQU    52    ;BAUD RATE = 300
  62. TRATE     EQU    255    ;TIMER RATE = 0.1 SEC/PULSE
  63. ;
  64. ;** RINGBACK TIMING EQUATES **
  65. ;(MAY REQUIRE OPTIMIZATION TO YOUR LOCAL OR LONG DISTANCE SITUATION)
  66. ;
  67. ;ROUTINE DIALING
  68. NATOUT     EQU    200    ;# OF SEC*10 TO WAIT BEFORE GIVING NO ANSWER MESSAGE
  69. ;
  70. ;RINGBACK
  71. RBLMT     EQU    70    ;# OF SEC*10 TO WAIT BEFORE GIVING NO RING HEARD MESS.
  72. RBWAIT     EQU    50    ;# OF SEC*10 DELAY BEFORE REDIALING NUMBER
  73. ;
  74. ;
  75. DISCCH     EQU    'D'-40H    ;CTL-D DISCONNECTS MODEM RTN TO CP/M
  76. RESTAR   EQU    'C'-40H    ;CTL-C ABORT TO CONSOLE PHONE # ENTRY
  77. ESCTCP   EQU    'E'-40H    ;CTL-E RTN TO CPM WITHOUT DISCONNECT
  78. LSTCHR     EQU    'P'-40H    ;CTL-P TURN ON/OFF LIST DEVICE (SPEED >300 BAUD)
  79. RBKCHA     EQU    'R'    ;RINGBACK SEQUENCE
  80. ;
  81. TIMESH     EQU    0    ;PUT 1 HERE TO PULL BIT 7 HIGH
  82. LSTDEV     EQU    1    ;PUT 1 HERE IF YOU HAVE A LIST DEVICE CAPABLE
  83.             ; OF SPEED >300 BAUD
  84. ;
  85. ;DEFINE ASCII CHARACTERS USED
  86. ;
  87. LF       EQU    10    ;LINEFEED
  88. CR     EQU    13    ;CARRIAGE RETURN
  89. BELL     EQU    07    ;BELL
  90. ; 
  91. ;*********************************************************
  92. ;
  93.     ORG    100H
  94. ;
  95. ;INIT PRIVATE STACK
  96.     LXI    H,0    ;HL=0
  97.     DAD    SP    ;HL=STACK FROM CP/M
  98.     SHLD    STACK    ;..SAVE IT
  99. ;
  100. RESTRT    LXI    SP,STACK ;SP=MY STACK
  101.     CALL    START    ;GO PRINT ID
  102.     DB    1AH,0,0,0,0,0 ;ADM-3 SCREEN CLEAR 
  103.     DB    0,0,0,0,0,0    ;NULLS FOR SCREEN CLEAR
  104.     DB    'DIAL PROGRAM ver 3.0'
  105.     DB    CR,LF,'$'
  106. ;
  107. START    POP    D    ;GET ID MESSAGE
  108.     CALL    PRTMSG    ;PRINT IT
  109. ;
  110. ;INITIALIZE JUMPS TO CP/M CBIOS
  111. ;
  112.     CALL    INITAD
  113. ;
  114. ;CHECK FOR PRIMARY OPTIONS OF EITHER X OR #
  115.     LXI    D,FCB+1    ;GET FIRST OPTION
  116.     LDAX    D
  117.     CPI    'X'    ;IS IT 'X' ?
  118.     JZ    EXAM    ;YES, EXAMPLE PRINT
  119.     CPI    '#'    ;IS IT '#' ?
  120.     JZ    DISCON    ;YES, DISCONNECT
  121.     CPI    '?'    ;IS IT '?'
  122.     JZ    PRTLST    ;YES, PRINT PHONE LIST
  123. ;
  124. ;CLEAR MODEM TO IDLE
  125.     MVI    A,CLEAR
  126.     OUT    MCTL2
  127.     MVI    A,BRK    ;GO ON HOOK IF NOT ALREADY THERE
  128.     OUT    MCTLP
  129.     MVI    B,25    ;SET UP TIMER
  130.     CALL    TIMER
  131. ;
  132. ;HELP PRINT
  133.     LXI    D,MENU    ;PRINT CTRL-CHAR. CODES
  134.     CALL    PRTMSG
  135. ;
  136. ;EVALUATE OPTION SELECTED
  137. ;
  138. PRIOPT:    XRA    A
  139.     STA    NFLAG    ;ZERO NUMBER FLAG
  140.     LXI    D,FCB+1    ;GET 1ST OPTION CHAR.
  141.     LDAX    D    ; FOUND IN FCB
  142.     STA    OPTION    ;SAVE IT
  143.     CPI    40H    ;IS IT >= A
  144.     JNC    GTHAN    ;YES (IT MAY BE A LETTER)
  145.     JMP    CKNUM    ;NO, SEE IF A NUMBER
  146. ;
  147. GTHAN    CPI    5BH    ;IF <= Z THEN IT IS A LETTER
  148.     JC    LETTER
  149.     JMP    CKNUM    ;SEE IF IT IS ANOTHER CHAR. > Z
  150. ;
  151. LETTER    CALL    ORIGMD    ;GO OFF HOOK, IDENT. DIAL TONE
  152.     LXI    H,00    ;LOAD H-L RESET TO ZERO
  153.     LDA    OPTION    ;GET OPTION CHAR.
  154.     CPI    'A'    ;IS IT AN 'A' (NO  OFFSET REQ)
  155.     JZ    NOFFS    ;YES, THE BYPASS OFFSET.
  156.     LXI    D,30    ;SET D-E TO OFFSET VALUE
  157.     SUI    41H    ;SUBTRACT 41H FROM LETTER TO GET #
  158.             ; OF 30 BYTE BLOCKS TO SKIP
  159.     MOV    B,A    ;MOVE TO B
  160. ;
  161. LOOP    DAD    D    ;ADD OFFSET
  162.     DCR    B
  163.     JNZ    LOOP    ;ADD APPROPRIATE # UNTIL DONE
  164. ;
  165. NOFFS    LXI    D,NUMLST ;GET PHONE NUMBER LIST ORIGIN
  166.     DAD    D    ;ADD TO OFFSET IN H-L
  167.     XCHG        ;MOVE RESULT TO D-E
  168.     JMP    PROCS    ;READ AND DIAL PRESET NUMBER
  169. ;
  170. CKNUM    CALL    ORIGMD    ;GO OFF HOOK, IDENT. DIAL TONE
  171.     LXI    H,NUMBR    ;LOAD H-L WITH LOCATION OF CURRENT # BUFF
  172.     SHLD    NBP    ;SAVE IN BUFF POINTER
  173.     LDA    FCB+1    ;GET FIRST CHARACTER AGAIN
  174.     LXI    D,DBUF+2
  175. ;
  176. CKNM    CPI    'R'    ;IS IT RINGBACK?
  177.     JZ    RINGBK    ;YES
  178.     CPI    2FH    ;IF CHAR. >='0'
  179.     JNC    GT0    ;YES
  180.     CPI    ' '    ;IS IT A SPACE?
  181.     JZ    QDONE    ;YES, CK IF DONE OR CONSOLE ENTRY
  182.     ORA    A    ;IS IT BINARY 0? (END OF DBUF)
  183.     JZ    QDONE    ;YES, DONE
  184.     CPI    '-'    ;IS IT DASH?
  185.     JZ    IGN    ;IGNORE
  186.     JMP    BDCHR    ;NO, MUST BE A BAD CHAR.
  187. ;
  188. GT0    CPI    3AH    ;IS IT <= 9 ?
  189.     JC    NUM    ;YES
  190.     JMP    BDCHR    ;MUST BE A BAD CHAR.
  191. ;
  192. NUM    CALL    TYPE    ;PRINT DIGIT
  193.     CALL    DIAL    ;DIAL THE DIGIT
  194.     MVI    A,0FFH    ; FLIP NUMBER FLAG (NOTES IF ANY # DIALED)
  195.     STA    NFLAG    ;
  196. ;
  197. IGNRE    INX    D    ;GET ANOTHER CHAR. FROM DBUF
  198.     LDAX     D    ;
  199.     JMP    CKNM    ;IF FIRST CHARACTER IS A NUMBER ASSUME THAT THE REST
  200.             ;ARE AND SO GO GET ANOTHER.
  201. IGN    CALL    TYPE    ;PRINT '-'
  202.     JMP    IGNRE
  203. ;
  204. QDONE    LDA    NFLAG    ;IS THIS THE FIRST CHAR. POSITION?
  205.     ORA    A    ; IF SO, AND IT IS A BLANK, ASSUME
  206.     JZ    CNSLE    ; THAT WE WANT CONSOLE INPUT
  207.     JMP    DIALE    ;NO, IT ISN'T- SO STORE AN EOF CHAR. IN
  208.             ; CURRENT NUMBER BUFFER
  209.             ;DIALING ENDED WAIT FOR ANSWER
  210. ;
  211. CNSLE:    LXI    D,PMESS    ;ENTER PHONE NUMBER MESSAGE
  212.     CALL    PRTMSG
  213.     MVI    D,255    ;25 SECONDS - TOTAL DIALING TIME ALLOWED
  214. ;
  215. CNSL1    CALL    STAT    ;CHAR. ENTERED?
  216.     JNZ    CNSL2    ;YES
  217. ;
  218. ;ALLOW ONLY 255 TIME ELEMENTS TO DIAL
  219.     MVI    B,1
  220.     CALL    TIMER
  221.     DCR    D
  222.     JZ    HEXIT    ;ABORT- TAKING TOO LONG TO DIAL
  223.     JMP    CNSL1
  224. ;
  225. CNSL2    CALL    KEYIN    ; GET IT
  226.     CALL    SPECL    ;ABORT?, REDIAL? etc.
  227.     CALL    TYPE    ; PRINT IT ON TERMINAL
  228.     CPI    2FH    ; >=0 ?
  229.     JNC    NM0    ;YES
  230.     CPI    ' '    ;IGNORE SPACES
  231.     JZ    CNSL1    ;
  232.     CPI    '-'    ;IGNORE DASHES
  233.     JZ    CNSL1    ;
  234.     CPI    CR    ;IF 'CR', THEN END OF NUMBER
  235.     JZ    NEND    ;
  236.     JMP    BDCHR    ;MUST BE A BAD CHAR.
  237. ;
  238. NEND    CALL    CRLF    ;PRINT A CRLF
  239.     JMP    DIALE    ;END OF DIALING
  240. ;
  241. NM0    CPI    3AH    ; <= 9 ?
  242.     JC    CSLE    ;FOUND A NUM. 0-9
  243.     CPI    'R'    ;RINGBACK MODE
  244.     JZ    RINGBK    ;
  245.     JMP    BDCHR    ;MUST BE A BAD CHAR.
  246. ;
  247. CSLE    CALL    DIAL    ;DIAL DIGIT
  248.     JMP    CNSL1    ;GET ANOTHER
  249. ;
  250. ;  DIAL STORED NUMBER REFERENCED BY D-E, THEN
  251. ;   PRINT TRAILING INFO.
  252. PROCS:    XRA    A    ;ZERO    ACC.
  253.     STA    PFLAG    ;ZERO PRINT FLAG
  254.     LXI    H,NUMBR    ;GET NUM BUFF START
  255.     SHLD    NBP    ;SAVE IN POINTER
  256. ;
  257. PRCS1    LDA    PFLAG    ;IS PRINT FLAG ON ?(=FFH)
  258.     CPI    0FFH
  259.     LDAX    D    ;LOAD ACC WITH 1ST CHARACTER REF. BY D-E
  260.     JZ    INCR    ;IF PFLAG ON THEN PRINT ONLY
  261.     CPI    '*'    ;EMPTY NUMBER SLOT
  262.     JZ    NONUM
  263.     CPI    ' '    ;BLANK?
  264.     JZ    INCR    ;PRINT AND ADVANCE
  265.     CPI    '-'    ;DASH?
  266.     JZ    INCR    ;PRINT AND ADVANCE
  267.     CPI    '"'    ;REST TO BE PRINT ONLY?
  268.     JZ    PSET    ;YES
  269.     CPI    2FH    ; >=0
  270.     JNC    GTH    ;YES
  271.     CPI    '$'    ;EOF ?
  272.     JZ    DIALE    ;END OF DIALING
  273.     JMP    BDCHR    ;MUST BE A BAD CHAR.
  274. ;
  275. DIGIT    CALL    TYPE    ;PRINT DIGIT
  276.     CALL    DIAL    ;DIAL IT
  277.     JMP    INCR1
  278. ;
  279. GTH    CPI    3AH    ;<=9 ?
  280.     JC    DIGIT    ;DIAL THE NUMBER
  281.     DCX    D    ;ADJUST POINTER TO 1 LESS
  282.             ; THAN LOC. OF 'R'
  283.     CPI    'R'    ;RINGBACK?
  284.     JZ    RBPRT    ;YES
  285.     JMP    BDCHR    ;BAD CHARACTER
  286. ;
  287. RBPRT    INX    D    ;RINGBACK PRINT SEQ.
  288.     LDAX    D    ;GET CHAR.
  289.     CPI    '"'    ;NON-PRINTING
  290.     JZ    RBPRT
  291.     CPI    '$'    ;END?
  292.     JZ    RBPR1    ;YES
  293.     CALL    TYPE    ;PRINT IT
  294.     JMP    RBPRT    ;GET ANOTHER
  295. ;
  296. RBPR1    MVI    A,LF    ;
  297.     CALL    TYPE
  298.     JMP    RINGBK    ;TO RINGBACK ROUTINE
  299. ;
  300. INCR    CPI    '$'    ;EOF CHAR.?
  301.     JZ    DIALE    ;DIALEND
  302.     CALL    TYPE
  303. ;
  304. INCR1    INX    D
  305.     JMP    PRCS1
  306. ;
  307. NONUM    LXI    D,NMESS    ;NO NUMBER LISTED MESSAGE
  308.     CALL    PRTMSG
  309.     JMP    HEXIT    
  310. ;
  311. PSET    MVI    A,0FFH    ;LOAD PRINT ONLY FLAG
  312.     STA    PFLAG
  313.     JMP    INCR1    ;GET NEXT CHAR.(DON'T PRINT  ")
  314. ;
  315. ;  GO TO ORIGINATE MODE AND IDENTIFY THE DIAL TONE
  316. ;***********************************************************
  317. ;
  318. ORIGMD:    MVI    A,MAKE    ;GO OFF HOOK IN ORGINATE MODE
  319.     OUT    MCTLP    ;
  320.     MVI    A,DTDET    ;SWITCH IN DIAL TONE DETECT FILTERS
  321.     OUT    MCTL2
  322. ; WAIT FOR DIAL TONE (TIME OUT)
  323.     MVI    D,DTMSK    ;LOAD MASK FOR DIAL TONE PRESENCE
  324.     CALL    WAT15
  325.     LXI    D,DMESS    ;DIAL TONE DETECTED MESSAGE
  326.     CALL    PRTMSG    ;PRINT ROUTINE
  327.     RET
  328. ;
  329. ;  AUTO-DIAL ROUTINE
  330. ;*********************************************************
  331. ;
  332. DIAL    ANI    0FH    ;CONVERT TO BINARY
  333.     LHLD    NBP    ;GET BUFF POINTER
  334.     MOV    M,A    ;SAVE DIGIT IN BUFF
  335.     INX    H    ;INCRE. BUFF POINTER
  336.     SHLD    NBP    ;SAVE BUFF. POINTER
  337. ;
  338. DIALR    CPI    0    ;IF 0 CONVERT TO 10
  339.     JNZ    DIALS
  340.     MVI    A,10
  341. ;
  342. DIALS    MOV    C,A    ;LOAD C WITH #
  343.     MVI    A,NUMPPS ;SET UP TIMER PULSE RATE
  344.     OUT    BAUDRP
  345. ;
  346. DIALC    IN    BAUDRP    ;WAIT IF TIMER PULSE NOT = 0
  347.     ANI    PULSE
  348.     JNZ    DIALC
  349. ;
  350. DIALB    IN    BAUDRP    ;WAIT UNTIL TRANSITION TO 1 FOR SYNC
  351.     ANI    PULSE
  352.     JZ    DIALB
  353. ;
  354. MKPLSE    MVI    A,MAKE    ;START WITH A MAKE
  355.     OUT    MCTLP
  356. ;
  357. TIMEM    IN    BAUDRP    ;WAIT FOR MAKE INTERVAL TO END
  358.     ANI    PULSE
  359.     JNZ    TIMEM
  360.     MVI    A,BRK    ;BREAK
  361.     OUT    MCTLP
  362. ;
  363. TIMEB    IN    BAUDRP    ;WAIT FOR BREAK PULSE INTERVAL
  364.     ANI    PULSE
  365.     JZ    TIMEB
  366.     DCR    C    ;MORE PULSES FOR THIS DIGIT?
  367.     JNZ    MKPLSE    ;YES
  368. ; LAST PULSE WAIT FOR INTERDIGIT TIME
  369.     MVI    A,MAKE
  370.     OUT    MCTLP
  371.     MVI    A,NUMPPS
  372.     MVI    B,INTER    ;INTERDIGIT INTERVAL = 7 GEN.
  373.     CALL    TIMER2
  374.     RET
  375. ;
  376. BUSY:    LXI    D,BMESS    ;PHONE BUSY MESSAGE
  377.     CALL    PRTMSG
  378.     LXI    D,NAMES2
  379.     JMP    ABORT2
  380. ;
  381. DIALE:    MVI    A,'$'    ;PUT INTO CURRENT NUMBER BUFF.
  382.     LHLD    NBP    ;GET BUFF POINTER
  383.     MOV    M,A    ;SAVE EOF CHAR.
  384. ;
  385. DTRON:    CALL    CRLF    ;PRINT A CRLF
  386.     MVI    A,DTR3    ;TURN ON DTR AT APPROPRIATE BAUD RATE
  387.     OUT    MCTL2
  388.     MVI    B,1    ;WAIT FOR MODEM TO TURN ON DTR
  389.     CALL    TIMER
  390. ;SET UP UART
  391.     MVI    A,ORIGM    ;8bits, No parity, orig 
  392.     OUT    MCTLP
  393. ;
  394. ;WAIT FOR CLEAR TO SEND OR RINGTONE
  395.     MVI    C,NATOUT ;SET FOR X SEC
  396.     MVI    D,CTSBT    ;CARRRIER MASK BIT
  397. ;
  398. DZ1    MVI    B,1    ;SET TIMER FOR 0.1 SEC
  399.     CALL    TIMER
  400.     IN    BAUDRP    ;GET STATUS
  401.     STA    MSTAT    ;SAVE STATUS
  402.     ANA    D    ;CARRIER ?
  403.     JZ    CARRIER    ;YES
  404.     CALL    STAT    ;KEYBOARD INPUT?
  405.     JZ    DZZ    ;NO
  406.     CALL    KEYIN    ;YES,GET IT
  407.     CALL    SPECL    ;ABORT CHAR.?
  408. ;
  409. DZZ    DCR    C    ;GET NEXT INTERVAL
  410.     JNZ    DZ1    ;
  411.     JMP    ABORT    ;TIME EXPIRED, NO ANSWER
  412.             ; OR BUSY
  413. ;
  414. CARRIER:
  415.     CALL    WAT15    ;ALLOW 15 SECONDS FOR CTS
  416.     IN    MDATP    ;CLEAR OUT DATA GARBAGE
  417. ;PRINT CARRIER RECEIVED MESSAGE
  418.     LXI    D,CMESS
  419.     CALL    PRTMSG
  420. ;
  421. ;SET BAUD RATE (USUALLY 300)
  422.     MVI    A,BAUDRT
  423.     OUT    BAUDRP
  424. ;
  425. ;**********************************************************
  426. ; MAIN COMMUNICATION SECTION
  427. ;**********************************************************
  428. ;
  429. TERM    CALL    LOSS    ;CK FOR CARRIER LOSS
  430.     CALL    STAT    ;LOCAL CHAR KEYED?
  431.     JZ    TERML    ;..NO, CHECK LINE
  432.     CALL    KEYIN    ;GET CHAR
  433.     CPI    ESCTCP    ;TIME TO END?
  434.     JZ    NDIS    ;YES, NO DISCON
  435.     CPI    DISCCH    ;DISCONNECT REQUEST?
  436.     JZ    DISCON    ;YES, DO IT
  437.     CPI    LSTCHR    ;PRINT ON LIST DEVICE ?
  438.     JNZ    NCHG    ;NO CHANGE, CONTINUE
  439.     LDA    LFLAG    ;YES, FLIP FLAG
  440.     CMA
  441.     STA    LFLAG    ; & SAVE IT
  442.     XRA    A    ;CLEAR ACCUM.
  443. ;
  444. NCHG:
  445.     IF    TIMESH
  446.     ORI    80H    ;FORCE BIT 7 TO HIGH
  447.     ENDIF        ;TIMESH
  448. ;
  449.     OUT    MDATP    ;SEND THE CHAR
  450. ;
  451. ;SEE IF CHAR FROM LINE
  452. ;
  453. TERML    IN    MCTLP    ;READ STATUS
  454.     ANI    MRCVB    ;ISOLATE BIT
  455.     CPI    MRCVR    ;READY?
  456.     JNZ    TERM    ;..NO, LOOP
  457.     IN    MDATP    ;READ DATA
  458.     CALL    TYPE    ;TYPE IT
  459. ;
  460.     IF    LSTDEV
  461.     CALL    LIST    ;IF LIST DEVICE PRESENT (SPEED >300 BAUD)
  462.     ENDIF
  463. ;
  464.     JMP    TERM    ;LOOP
  465. ;
  466. ;---->    DISCON: DISCONNECT THE PHONE
  467. ;
  468. DISCON    XRA    A    ;GET DISCON VALUE
  469.     OUT    MCTLP    ;RESET ORIG/ANSW
  470.     OUT    MCTL2    ;TURN OFF DTR, DO BREAK
  471.     CALL    ILPRT    ;PRINT:
  472.     DB    CR,LF,'++ DISCONNECTED ++',CR,LF,0
  473.     JMP    EXIT
  474. ;
  475. ;NO DISCONNECT, TYPE MSG AS REMINDER THAT PHONE'S
  476. ;OFF HOOK
  477. ;
  478. NDIS    CALL    ILPRT
  479.     DB    CR,LF,'++ DON''T FORGET - THE MODEM IS '
  480.     DB    'NOT DISCONNECTED ++',CR,LF
  481.     DB    'Use "DIAL #" to Disconnect',CR,LF,0
  482.     JMP    EXIT
  483. ;
  484. ;*********************************************************
  485. ;
  486. LOSS    IN    BAUDRP
  487.     ANI    CTSBT    ;MASK FOR CARRIER LOSS
  488.     RZ        ;STILL PRESENT
  489.     LXI    D,CLMES    ;TYPE CARRIER LOST MESSAGE
  490.     CALL    PRTMSG
  491.     JMP    HEXIT    ;GO TO ABORT
  492. ;
  493. HANGP:    XRA    A    ;GET DISCONNECT VALUE
  494.     OUT    MCTL2    ;TURN OFF DTR, DO BREAK
  495.     OUT    MCTLP    ;GO ON HOOK
  496.     RET
  497. ;
  498. ABORT:    LXI    D,NAMES    ;NO ANSWER MESSAGE
  499.             ; DO YOU WISH TO REDIAL?
  500. ;
  501. ABORT2    CALL    HANGP
  502.     MVI    B,25    ;LOAD TIMER
  503.     CALL    TIMER    ; WITH LONG PAUSE
  504.     CALL    PRTMSG    ;PRINT THE MSG
  505.     CALL    KEYIN    ;GET REPLY
  506.     CALL    TYPE
  507.     CPI    'D'    ;WAS A 'D' HIT?
  508.     JZ    REDIAL    ;YES
  509.     JMP    EXIT    ;NO,GO TO CP/M
  510. ;
  511. SPECL    CPI    ESCTCP    ;CTL-E JMP TO CPM
  512.     JZ    EXIT
  513.     CPI    DISCCH    ;CTL-D DISCONNECT,TO CPM
  514.     JZ    HEXIT
  515.     CPI    RESTAR    ;CTL-C ABORT,RESTAR
  516.     JZ    RESTRT
  517.     CPI    RBKCHA    ;IF R
  518.     JZ    RINGBK    ;SET UP RINGBACK SEQUENCE
  519.     CPI    LSTCHR    ;CTL-P CONCURRENT LIST (DEVICE SPEED >300 BAUD)
  520.     RNZ        ;RETURN, NO SPECIAL CHARACTER IDENTIFIED
  521.     LDA    LFLAG
  522.     CMA        ;UPDATE LIST FLAG
  523.     STA    LFLAG
  524.     RET
  525. ;
  526. RINGBK:    MVI    A,'$'    ;PUT INTO CURRENT # BUFFER
  527.     LHLD    NBP    ;GET BUFF POINTER
  528.     MOV    M,A    ;SAVE EOF CHAR.
  529.     MVI    D,DTMSK    ;LOAD IN TONE DETECT MASK
  530.     MVI    C,RBLMT    ;SET TIMER FOR RBLIMIT # OF SEC.
  531.     CALL    RBTIME    ;  ABORTS IF IT TAKES LONGER
  532.     MVI    B,25    ;WAIT 2.5 SEC
  533.     CALL    TIMER    ;
  534.     IN    BAUDRP    ;IS TONE STILL PRESENT ?
  535.     ANA    D    ;
  536.     JNZ    RNGBK1    ;
  537.     JMP    BUSY    ;YES, MUST BE BUSY
  538. ;
  539. RNGBK1    CALL    HANGP    ;HANGUP PHONE
  540.     MVI    B,RBWAIT    ;WAIT X SEC.
  541.     CALL    TIMER    ;
  542.     JMP    REDIAL    ;REDIAL NUMBER
  543. ;
  544. RBTIME:    MVI    B,1    ; 0.1SEC TIME OUT
  545.     CALL    TIMER
  546.     IN    BAUDRP    ;GET STATUS
  547.     ANA    D    ;IS TONE PRESENT ?
  548.     RZ        ;YES
  549.     DCR    C    ;GET NEXT 0.1 SEC INTERVAL
  550.     JNZ    RBTIME
  551.     LXI    D,RBMES    ;NO TONE IDENTIFIED IN TIME LIMIT
  552.     CALL    PRTMSG    ;  BUT WILL CONTINUE
  553.     POP    D    ;GET RID OF SUBROUTINE RETURN
  554.     JMP    RNGBK1    ;HANGUP, REDIAL, & LISTEN FOR CARRIER
  555. ;
  556. REDIAL:    CALL    CRLF    ;PRINT A CRLF
  557.      CALL    ORIGMD    ;LOOK FOR DIAL TONE
  558.     LXI    H,NUMBR    ;GET START OF 'LAST' NUMBER BUFF.
  559. ;
  560. RDIAL    MOV    A,M    ;GET DIGIT
  561.     CPI    '$'    ;EOF CHAR. ?
  562.     JZ    DTRON    ;DONE DIALING
  563.     ADI    '0'    ;MAKE IT PRINTABLE
  564.     CALL    TYPE
  565.     MOV    A,M    ;GET DIGIT AGAIN
  566.     CALL    DIALR    ;DIAL DIGIT
  567.     INX    H    ;NEXT ONE
  568.     JMP    RDIAL
  569. ;
  570. ; SUBROUTINE- TIMER
  571. ;    reg B = # time periods to count
  572. ;***********************************************************
  573. ;
  574. TIMER    MVI    A,TRATE    ;RESET TO .1 SEC
  575. ;
  576. TIMER2    OUT    BAUDRP
  577. ;
  578. TIMES    IN    BAUDRP    ;CK TO SEE IF TIMER BIT IS LOW
  579.     ANI    PULSE
  580.     JNZ    TIMES
  581. ;
  582. TIMEE    IN    BAUDRP    ;CK TO SEE IF BIT IS HIGH
  583.     ANI    PULSE
  584.     JZ    TIMEE
  585.     DCR    B    ;ONE PERIOD DONE
  586.     JNZ    TIMES
  587.     RET        ;TOTAL TIME EXPIRED
  588. ;
  589. ;
  590. ;   DIALING ENDED:  CARRIER DETECT ROUTINES
  591. ;********************************************************************
  592. ;
  593. ; TIME OUT ROUTINE (CK OF BITS vs MASK IN  D )
  594. ;
  595. WAT15:    MVI    C,150    ;TIMER SET FOR 15 SEC. INTERVALS
  596. ;
  597. T15    MVI    B,1    ; .1 SEC TIMEOUT
  598.     CALL    TIMER    ;TIMER WAITS .1 SEC
  599.     IN    BAUDRP    ;TEST STATUS
  600.     ANA    D    ;MASK WITH TEST BIT IN D
  601.     RZ        ;RETURN IF OFF
  602.     CALL    STAT
  603.     JZ    TS15    ;WAIT FOR INPUT
  604.     CALL    KEYIN
  605.     CALL    SPECL    ;CK FOR ABORT
  606. ;
  607. TS15    DCR    C    ;GET NEXT .1 SEC INTERVAL
  608.     JNZ    T15
  609.     JMP    ABORT
  610. ;
  611. ;---->    INITAD: INIT'S CP/M CBIOS ADDRESSES
  612. ;
  613. ;THIS ROUTINE FILLS IN THE ADDRESSES OF VARIOUS
  614. ;JMP AND CALL INSTRUCTIONS, SO THAT CP/M BDOS
  615. ;IS BYPASSED WHILE ACCESSING THE CONSOLE.  THIS
  616. ;IS DONE TO ALLOW CHARACTERS SUCH AS CONTROL-C
  617. ;AND CONTROL-S TO BE KEYED WHILE IN TERMINAL
  618. ;MODE, WITHOUT CP/M INTERPRETING THEM.
  619. ;
  620. INITAD    LHLD    1    ;GET WARM BOOT ADDR
  621.     LXI    D,3    ;LENGTH OF A 'JMP'
  622.     DAD    D    ;TO CONSOLE STAT
  623.     SHLD    VSTAT+1    ;MODIFY CALL
  624.     DAD    D    ;TO CONSOLE IN
  625.     SHLD    VKEYIN+1 ;MODIFY CALL
  626.     DAD    D    ;TO CONSOLE OUT
  627.     SHLD    VTYPE+1    ;MODIFY CALL
  628.     IF    LSTDEV
  629.     DAD    D    ;TO LIST DEVICE
  630.     SHLD    VLIST+1    ;MODIFY    CALL
  631.     ENDIF
  632.     RET
  633. ;
  634. CRLF    MVI    A,CR
  635.     CALL    TYPE
  636.     MVI    A,LF    ;FALL INTO TYPE
  637. ;
  638. ;---->    TYPE: TYPE VIA DIRECT CBIOS ACCESS
  639. ;WE ASSUME CBIOS MAY DESTROY SOME REGISTERS,
  640. ;SO SAVE THEM ALL.
  641. ;
  642. ;THIS ROUTINE BYPASSES CP/M'S CTL-S, CTL-C
  643. ;TESTS.
  644. ;
  645. TYPE    PUSH    PSW    ;SAVE CHAR
  646.     PUSH    B    ;AND OTHER REGISTERS
  647.     PUSH    D
  648.     PUSH    H
  649.     MOV    C,A    ;FOR BIOS
  650. VTYPE    CALL    $-$    ;ADDR SET AT INIT
  651.     POP    H    ;RESTORE REGISTERS
  652.     POP    D
  653.     POP    B
  654.     POP    PSW    ;..AND CHAR
  655.     RET        ;FROM "TYPE"
  656. ;
  657. ;PRINT ON LIST DEVICE ROUTINE
  658.     IF    LSTDEV    ;IF LIST DEVICE IS PRESENT >300 BAUD
  659. LIST    MOV    C,A    ;SAVE CHAR.
  660.     LDA    LFLAG    ;GET LIST FLAG
  661.     ORA    A
  662.     RZ        ;RETURN IF OFF
  663.     PUSH    PSW    ;SAVE CHAR.
  664.     PUSH    B    ;AND OTHER REGISTERS
  665.     PUSH    D
  666.     PUSH    H
  667. VLIST    CALL    $-$    ;ADDR SET AT INIT
  668.     POP    H    ;RESTORE REGISTERS
  669.     POP    D
  670.     POP    B
  671.     POP    PSW    ;..AND CHAR
  672.     RET        ;FROM    "LIST"
  673.     ENDIF
  674. ;
  675. ;---->  STAT: KEYBOARD STATUS
  676. ;
  677. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  678. ;CBIOS CLOBBERS THEM.
  679. ;
  680. STAT    PUSH    B
  681.     PUSH    D
  682.     PUSH    H
  683. VSTAT    CALL    $-$    ;ADDR SET AT INIT
  684.     POP    H
  685.     POP    D
  686.     POP    B
  687.     ORA    A    ;0 => NOT READY
  688.     RET
  689. ;
  690. ;---->  KEYIN: KEYBOARD INPUT
  691. ;
  692. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  693. ;CBIOS CLOBBERS THEM.
  694. ;
  695. KEYIN    PUSH    B
  696.     PUSH    D
  697.     PUSH    H
  698. VKEYIN    CALL    $-$    ;ADDR SET AT INIT
  699.     POP    H
  700.     POP    D
  701.     POP    B
  702.     ANI    7FH    ;STRIP PARITY IF THERE
  703.     RET        ;FROM KEYIN
  704. ;
  705. ;---->    ILPRT: INLINE PRINT OF MSG
  706. ;
  707. ;THE CALL TO ILPRT IS FOLLOWED BY A MESSAGE,
  708. ;BINARY 0 AS THE END.  BINARY 1 MAY BE USED TO
  709. ;PAUSE (MESSAGE 'PRESS RETURN TO CONTINUE')
  710. ;
  711. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  712. ;
  713. ILPLP    MOV    A,M    ;GET CHAR
  714.     ORA    A    ;END OF MSG?
  715.     JZ    ILPRET    ;..YES, RETURN
  716.     CPI    1    ;PAUSE?
  717.     JZ    ILPAUS    ;..YES
  718.     CALL    TYPE    ;TYPE THE MSG
  719. ;
  720. ILPNEX    INX    H    ;TO NEXT CHAR
  721.     JMP    ILPLP    ;LOOP
  722. ;
  723. ;PAUSE WHILE TYPING HELP SO INFO DOESN'T
  724. ;SCROLL OFF OF VIDEO SCREENS
  725. ILPAUS    CALL    ILPRT    ;PRINT:
  726.     DB    CR,LF,'PRESS RETURN TO CONTINUE'
  727.     DB    CR,LF,0
  728.     CALL    KEYIN    ;GET ANY CHAR
  729.     CPI    'C'-40H    ;REBOOT?
  730.     JZ    EXIT    ;YES.
  731.     JMP    ILPNEX    ;LOOP
  732. ;
  733. ILPRET    XTHL        ;RESTORE HL
  734.     RET        ;PAST MSG
  735. ;
  736. ;---->  PRTLST:  PRINTS THE PHONE LIST & GETS INPUT
  737. ;
  738. PRTLST    PUSH    D    ;STORE REGISTERS
  739.     PUSH    H
  740.     MVI    D,0    ;STORE SKIP INCR IN D-E
  741.     MVI    E,31
  742.     LXI    H,NUMLST;1ST CHAR OF PHONE LIST
  743. ;
  744. ;    Move past phone number or skip * entry
  745. ;
  746. PRTLP1    MOV    A,M    ;GET CHAR FROM PHONE LIST
  747.     INX    H    ;BUMP H-L BEFORE CHECKING
  748.     CPI    '@'    ;IS IT EO LIST
  749.     JZ    PLSTX    ;YES, GO TO END
  750.     CPI    '*'    ;IS IT A BLANK
  751.     JZ    PRTSKP    ;YES, SKIP TO NEXT LINE
  752.     CPI    '"'    ;IS IT EO NUM
  753.     JNZ    PRTLP1    ;NO, GET ANOTHER CHAR
  754. ;
  755. ;    Print Rest of line
  756. ;
  757. PRTLP2    MOV    A,M    ;GET A CHAR (BUMPED ALREADY)
  758.     CPI    '$'    ;IS IT EO LINE
  759.     JZ    PRTEOL    ;YES, BYPASS LAST CHAR.
  760.     CALL    TYPE    ;PRINT IT OUT
  761.     INX    H
  762.     JMP    PRTLP2    ;GET ANOTHER CHAR.
  763. ;
  764. PRTEOL    INX    H    ;GET READY FOR ANOTHER CHAR
  765.     CALL    CRLF    ;EO LINE
  766.     JMP    PRTLP1    ;NO, GET ANOTHER LINE
  767. ;
  768. ;    Handle End of List
  769. ;
  770. PLSTX:    POP     H    ;RESTORE REGS
  771.     POP    D
  772.     CALL    ILPRT    ;PRINT THIS MESSAGE
  773.     DB    'Type the letter before name ',0
  774.     CALL    KEYIN    ;GET INPUT
  775.     STA    OPTION    ;STORE AS FROM FCB+1
  776.     CALL    CRLF    ;MAKE IT NEAT
  777.     JMP    LETTER    ;DIAL BASED ON KEYIN
  778. ;
  779. ;    Skip unused line
  780. ;
  781. PRTSKP    DAD    D    ;ADD NEXT LINE INCR
  782.     JMP    PRTLP1    ;GO FOR ANOTHER LINE
  783. ;
  784. ;---->    PRTMSG: PRINTS MSG POINTED TO BY (DE)
  785. ;
  786. ;A '$' IS THE ENDING DELIMITER FOR THE PRINT.
  787. ;NO REGISTERS SAVED.
  788. ;
  789. PRTMSG    MVI    C,PRINT    ;GET BDOS FNC
  790.     JMP    BDOS    ;PRINT MESSAGE, RETURN
  791. ;
  792. HEXIT    CALL    HANGP    ;DISCONNECT
  793. ;
  794. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  795.     SPHL        ;RESTORE IT
  796.     RET        ;--EXIT-- TO CP/M (WARM BOOT)
  797. ;
  798. BDCHR    CALL    TYPE    ;PRINT CHAR.
  799.     CALL    HANGP    ;DISCONNECT
  800.     CALL    ILPRT    ;PRINT EXIT MESSAGE
  801.     DB    ' :INVALID CHARACTER',CR,LF
  802.     DB    'Press Return for Help, Ctrl-c if not.',cr,lf,1,0
  803. ;
  804. EXAM    MVI    B,1    ;WAIT
  805.     CALL    TIMER
  806.     CALL    ILPRT
  807.  DB  cr,lf
  808.  DB 'Commands:',cr,lf,cr,lf
  809.  DB '   DIAL ',cr,lf
  810.  DB '        if phone number is to be input from console',cr,lf,cr,lf
  811.  DB '   DIAL ?',cr,lf
  812.  DB '        for a phone listing from which you can choose',cr,lf,cr,lf
  813.  DB '   DIAL 756-5553',cr,lf
  814.  DB '        if the trailing number is to be dialed (spaces and',cr,lf
  815.  DB '        dashes are ignored)',cr,lf,cr,lf
  816.  DB '   DIAL C',cr,lf
  817.  DB '        if one of 25 preset numbers is to be dialed (preset',cr,lf
  818.  DB '        at time of assembly)',cr,lf,cr,lf
  819.  DB '   An  R  which follows any number indicates that it is',cr,lf
  820.  DB '    to be dialed as a ringback sequence.'
  821.  DB '(One ring then dial back)',cr,lf
  822.  DB '    (For preset numbers this must be entered before assembly)'
  823.  DB cr,lf,cr,lf,0
  824.     JMP    EXIT
  825. ;
  826. MENU:
  827.  DB '                      NOTE',cr,lf
  828.  DB '                     ======',cr,lf
  829.  DB '   ctrl- D  causes a disconnect and return to CP/M',cr,lf
  830.  DB '   ctrl- E  causes a return to CP/M without a disconnect',cr,lf
  831.  DB '   ctrl- C  aborts current dialing and restarts program',cr,lf
  832.     IF    LSTDEV
  833.  DB '   ctrl- P  turns list device on and off',cr,lf
  834.     ENDIF
  835.  DB cr,lf,cr,lf,'$'
  836. ;
  837. ;
  838. NUMLST:
  839. ;  Phone Number list (capacity 25 numbers)
  840. ;Format    '############"acaaaaaaaaaaaaaa$'
  841. ;CAUTION:   ^----from here to here-------^
  842. ;    **MUST NOT EXCEED 30 CHARACTERS**
  843. ;    (the actual # of #'s or a's doesn't matter if <30)
  844. ;
  845. ;    where  # = a digit, space or dash
  846. ;           " = separator between number and info
  847. ;           a = ascii info
  848. ;           c = a char corresponding to the second
  849. ;               char of tag. It should follow the "
  850. ;           by one space since it prints with
  851. ;           the name
  852. ;           $ = eof
  853. ;           * = no number character
  854. ;
  855. NA    DB    '304-555-1212" A:L.A. INFO    $'
  856. NB    DB    '*                            $'
  857. NC    DB    '*                            $'
  858. ND    DB    '*                            $'
  859. NE    DB    '*                            $'
  860. NF    DB    '*                            $'
  861. NG    DB    '4517840" G:GILBERTS, THE     $'
  862. NH    DB    '*                            $'
  863. NI    DB    '*                            $'
  864. NJ    DB    '*                            $'
  865. NK    DB    '*                            $'
  866. NL    DB    '936-1212" L:WEATHER          $'
  867. NM    DB    '*                            $'
  868. NN    DB    '*                            $'
  869. NO    DB    '*                            $'
  870. NP    DB    '*                            $'
  871. NQ    DB    '3135887054" Q:PETERSEN, K    $'
  872. NR    DB    '*                            $'
  873. NS    DB    '*                            $'
  874. NT    DB    '*                            $'
  875. NU    DB    '*                            $'
  876. NV    DB    '844-2525" V:LOCAL TIME       $'
  877. ;    The following exceed a 24 line display
  878. ;    if all preceding entries are full
  879. NW    DB    '*                            $'
  880. NX    DB    '*                            $'
  881. NY    DB    '*                            $'
  882. NZ    DB    '*                            $'
  883. ;    The following is the list terminator
  884.     DB    '@'
  885. ;
  886. DMESS    DB    'Phone is off cradle  ',cr,lf,'$'
  887. CMESS    DB    'DATA CARRIER Received',cr,lf,bell,'$'
  888. BMESS    DB    bell,cr,lf,'BUSY Signal',bell,cr,lf,'$'
  889. RBMES    DB    bell,lf,'No Ringing Tone Detected',cr,lf,'$'
  890. NAMES    DB    'NO ANSWER',cr,lf
  891. NAMES2    DB    '   If you wish to redial PRESS  D',cr,lf
  892.     DB    '$'
  893. CLMES    DB    cr,lf,'DATA CARRIER LOST',cr,lf,bell,'$'
  894. NMESS    DB    'NO NUMBER STORED',cr,lf,'$'
  895. PMESS    DB    'ENTER PHONE # (terminate with  RETURN )  ',cr,lf,'$'
  896. ;
  897. ;
  898. NUMBR    DB    '$$$$$$$$$$$$$$$$'    ;16 DIGIT BUFFER
  899. ;
  900. PFLAG    DB    0    ;PRINT FLAG
  901. NFLAG    DB    0
  902. LFLAG    DB    0    ;LIST FLAG
  903. MSTAT    DB    0    ;MODEM STATUS
  904. OPTION    DB    0
  905. NBP    DS    2    ;NUM BUFF POINTER
  906.     DS    60    ;STACK AREA
  907. STACK    DS    2    ;STACK POINTER
  908. ;
  909. ;  BDOS EQUATES
  910. ;
  911. PRINT    EQU    9    ;PRINT ROUTINE
  912. BDOS    EQU    5
  913. FCB    EQU    5CH    ;SYSTEM FCB
  914. DBUF    EQU    80H    ;CP/M DEFAULT BUFFER
  915. ;
  916.     END
  917.