home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MODEMS / MODEM / CP405SRC.ARK / CP4PKT.ASM < prev    next >
Assembly Source File  |  1986-12-25  |  64KB  |  2,210 lines
  1. ; CP4PKT.ASM
  2. ;    KERMIT - (Celtic for "FREE")
  3. ;
  4. ;    This is the CP/M-80 implementation of the Columbia University
  5. ;    KERMIT file transfer protocol.
  6. ;
  7. ;    Version 4.0
  8. ;
  9. ;    Copyright June 1981,1982,1983,1984
  10. ;    Columbia University
  11. ;
  12. ; Originally written by Bill Catchings of the Columbia University Center for
  13. ; Computing Activities, 612 W. 115th St., New York, NY 10025.
  14. ;
  15. ; Contributions by Frank da Cruz, Daphne Tzoar, Bernie Eiben,
  16. ; Bruce Tanner, Nick Bush, Greg Small, Kimmo Laaksonen, Jeff Damens, and many
  17. ; others. 
  18. ;
  19. ;    This file contains the (system-independent) routines that implement
  20. ;    the KERMIT protocol, and the commands that use them:
  21. ;    RECEIVE, SEND, FINISH, and LOGOUT.
  22. ;
  23. ; revision history:
  24. ; edir 6: November 22, 1984
  25. ;    Change SEND's 'Unable to find file' error exit from calling
  26. ;    error3 to calling prtstr instead.  I don't know about you, but
  27. ;    I greatly dislike having messages dumped into pre-existing
  28. ;    junk on the screen where I have to spend lots of time hunting
  29. ;    for them.  [Hal Hostetler]
  30. ;
  31. ; edit 5: September 9, 1984
  32. ;    Call flsmdm in init to flush old input when starting transfers.
  33. ;    Select console before returning from inpkt.
  34. ;    Replace inline code with calls to makfil/clofil to set up for
  35. ;    multisector buffering on output.
  36. ;    Remove superfluous call to clrlin in error3.
  37. ;
  38. ; edit 4: August 21, 1984 (CJC)
  39. ;    Fix comment in inpkt: packet is terminated by NUL on return, not CR.
  40. ;    If debugging, display the outgoing packet before putting the EOL
  41. ;    character on, so the dumped packet doesn't get overwritten.
  42. ;
  43. ; edit 3: July 27, 1984
  44. ;    add link directive for LASM.  CP4PKT is linked by CP4MIT, and links
  45. ;    to CP4TT.  Add Toad Hall TACtrap to permit operations through a TAC.
  46. ;
  47. ; edit 2: June 8, 1984
  48. ;    formatting and documentation; remove some unused labels; move setpar
  49. ;    to cp4mit.m80; add module version string; make all arithmetic on
  50. ;    'pktnum' modulo 64; apply defaults correctly for missing parameters
  51. ;    in send-init packet (and corresponding ack).
  52. ;
  53. ; edit 1: May, 1984
  54. ;    extracted from CPMBASE.M80 version 3.9; modifications are described
  55. ;    in the accompanying .UPD file.
  56. ;
  57. pktver:    db    'CP4PKT.ASM (6)  22-Nov-84$'    ; name, edit number, date
  58.  
  59. ;    RECEIVE command
  60. ;    here from: kermit
  61.  
  62. read:    lxi    d,data        ;Where to put the text (if any.)
  63.     mvi    a,cmtxt
  64.     call    comnd        ;Get either some text or a confirm.
  65.      jmp    kermt3        ; Didn't get anything.
  66.     ora    a        ;Get any chars?
  67.     jz    read1        ;Nope, just a regular send.
  68.     sta    argblk+1    ;Store the number of chars.
  69.     xchg            ;Get pointer into HL.
  70.     mvi    m,'$'        ;Put in a dollar sign for printing.
  71.     call    init        ;Clear the line and initialize the buffers.
  72.     call    scrfln        ;Position cursor
  73.     lxi    d,data        ;Print the file name
  74.     call    prtstr
  75.     mvi    a,'1'        ;Start with single character checksum
  76.     sta    curchk        ;Save the type
  77.     xra    a        ;Start a packet zero.
  78.     sta    argblk
  79.     mvi    a,'R'        ;Receive init packet.
  80.     call    spack        ;Send the packet.
  81.      jmp    kermt3        ; Die!
  82.     jmp    read12
  83.  
  84. read1:    call    init        ;Clear the line and initialize the buffers.
  85. read12:    xra    a
  86.     sta    czseen        ;Clear the ^X/^Z flag initially.
  87.     lxi    h,0
  88.     shld    numpkt        ;Set the number of packets to zero.
  89.     shld    numrtr        ;Set the number of retries to zero.
  90.     sta    pktnum        ;Set the packet number to zero.
  91.     sta    numtry        ;Set the number of tries to zero.
  92.     call    scrnrt        ;Position cursor
  93.     lxi    h,0
  94.     call    nout        ;Write the number of retries.
  95.     mvi    a,'R'
  96.     sta    state        ;Set the state to receive initiate.
  97.     ;...
  98. ;
  99. ;RECEIVE state table switcher.
  100.  
  101. read2:    call    scrnp        ;Position cursor
  102.     lhld    numpkt
  103.     call    nout        ;Write the current packet number.
  104.     lda    state        ;Get the state.
  105.     cpi    'D'        ;Are we in the DATA receive state?
  106.     jnz    read3
  107.     call    rdata
  108.     jmp    read2
  109.  
  110. read3:    cpi    'F'        ;Are we in the FILE receive state?
  111.     jnz    read4
  112.     call    rfile        ;Call receive file.
  113.     jmp    read2
  114.  
  115. read4:    cpi    'R'        ;Are we in the Receive-Initiate state?
  116.     jnz    read5
  117.     call    rinit
  118.     lda    state        ;[jd] get new state
  119.     cpi    'F'        ;[jd] went into receive state?
  120.     jnz    read2        ;[jd] no
  121.     lxi    d,inms24    ;[jd] yes, get receiving... message
  122.     call    finmes        ;[jd] go print it
  123.     jmp    read2
  124.  
  125. read5:    cpi    'C'        ;Are we in the Receive-Complete state?
  126.     jnz    read6
  127.     lxi    d,infms3    ;Put in "Complete" message.
  128.     lda    czseen        ;Or was it interrupted?
  129.     ora    a        ; .  .  .
  130.     jz    read5a        ;No.
  131.     xra    a        ;Yes, clear flag.
  132.     sta    czseen        ; ...
  133.     lxi    d,inms13    ;Issue "interrupted" message.
  134. read5a:    call    finmes        ;Print completion message in right place.
  135.     jmp    kermit
  136.  
  137. read6:    cpi    'A'        ;Are we in the Receive-"Abort" state?
  138.     jnz    read7
  139. read7:    lxi    d,infms4    ;Anything else is equivalent to "abort".
  140.     call    finmes
  141.     jmp    kermit
  142. ;
  143. ;    Receive routines
  144.  
  145. ;    Receive init
  146. ;    called by: read
  147.  
  148. rinit:    lda    numtry        ;Get the number of tries.
  149.     cpi    imxtry        ;Have we reached the maximum number of tries?
  150.     jm    rinit2
  151.     lxi    d,ermes4
  152.     call    error3        ;Move cursor and print an error message.
  153.     jmp    abort        ;Change the state to abort.
  154.  
  155. rinit2:    inr    a        ;Increment it.
  156.     sta    numtry        ;Save the updated number of tries.
  157.     mvi    a,'1'        ;Reset block check type to single character
  158.     sta    curchk        ;Store as current type for initialization
  159.     call    rpack        ;Get a packet.
  160.      jmp    nak        ; Trashed packet: nak, retry.
  161.     cpi    'S'        ;Is it a send initiate packet?
  162.     jnz    rinit3        ;If not see if its an error.
  163.     lda    numtry        ;Get the number of tries.
  164.     sta    oldtry        ;Save it.
  165.     xra    a
  166.     sta    numtry        ;Reset the number of tries.
  167.     lda    argblk        ;Returned packet number.  (Synchronize them.)
  168.     call    countp
  169.     lda    argblk+1    ;Get the number of arguments received.
  170.     lxi    h,data        ;Get a pointer to the data.
  171.     call    spar        ;Get the data into the proper variables.
  172.     lxi    h,data        ;Get a pointer to our data block.
  173.     call    rpar        ;Set up the receive parameters.
  174.     sta    argblk+1    ;Store the returned number of arguments.
  175.     mvi    a,'Y'        ;Acknowledge packet.
  176.     call    spack        ;Send the packet.
  177.      jmp    abort        ; Failed, abort.
  178.     lda    inichk        ;Now switch to agreed upon check-type
  179.     sta    curchk        ;For all future packets
  180.     mvi    a,'F'        ;Set the state to file send.
  181.     sta    state
  182.     ret
  183.  
  184. rinit3:    cpi    'E'        ;Is it an error packet.
  185.     jnz    nak0        ;If not NAK whatever it is.
  186.     call    error
  187.     jmp    abort
  188. ;
  189. ;    Receive file
  190. ;    called by: read
  191.  
  192. rfile:    lda    numtry        ;Get the number of tries.
  193.     cpi    maxtry        ;Have we reached the maximum number of tries?
  194.     jm    rfile1
  195.     lxi    d,ermes5
  196.     call    error3        ;Move cursor and print an error message.
  197.     jmp    abort        ;Change the state to abort.
  198.  
  199. rfile1:    inr    a        ;Increment it.
  200.     sta    numtry        ;Save the updated number of tries.
  201.     call    rpack        ;Get a packet.
  202.      jmp    nak        ; Trashed packet: nak, retry.
  203.     cpi    'S'        ;Is it a send initiate packet?
  204.     jnz    rfile2        ; No, try next type.
  205.     lda    oldtry        ;Get the number of tries.
  206.     cpi    imxtry        ;Have we reached the maximum number of tries?
  207.     jm    rfil12        ;If not proceed.
  208.     lxi    d,ermes4
  209.     call    error3        ;Move cursor and print an error message.
  210.     jmp    abort        ;Change the state to abort.
  211.  
  212. rfil12:    inr    a        ;Increment it.
  213.     sta    oldtry        ;Save the updated number of tries.
  214.     lda    pktnum        ;Get the present packet number.
  215.     dcr    a        ;Decrement
  216.     ani    3FH        ; modulo 64
  217.     mov    b,a
  218.     lda    argblk        ;Get the packet's number
  219.     cmp    b        ;Is the packet's number one less than now?
  220.     jnz    nak0        ;No, NAK and try again.
  221.     call    updrtr        ;Update the retry count.
  222.     xra    a
  223.     sta    numtry        ;Reset the number of tries.
  224.     lxi    h,data        ;Get a pointer to our data block.
  225.     call    rpar        ;Set up the parameter information.
  226.     sta    argblk+1    ;Save the number of arguments.
  227.     mvi    a,'Y'        ;Acknowledge packet.
  228.     call    spack        ;Send the packet.
  229.      jmp    abort        ; Failed, abort.
  230.     ret
  231.  
  232. rfile2:    cpi    'Z'        ;Is it an EOF packet?
  233.     jnz    rfile3        ; No, try next type.
  234.     lda    oldtry        ;Get the number of tries.
  235.     cpi    maxtry        ;Have we reached the maximum number of tries?
  236.     jm    rfil21        ;If not proceed.
  237.     lxi    d,ermes6
  238.     call    error3        ;Move cursor and print an error message.
  239.     jmp    abort        ;Change the state to abort.
  240.  
  241. rfil21:    call    tryagn
  242.     ret
  243.  
  244. rfile3:    cpi    'F'        ;Start of file?
  245.     jnz    rfile4
  246.     call    compp
  247.     jnz    nak0        ;No, NAK it and try again.
  248.     call    countp
  249.     call    gofil        ;Get a file to write to, and init output buffer.
  250.      jmp    abort
  251.     lda    numtry        ;Get the number of tries.
  252.     sta    oldtry        ;Save it.
  253.     call    ackp
  254.     mvi    a,'D'        ;Set the state to data receive.
  255.     sta    state
  256.     lda    czseen        ;Check if we punted a file
  257.     cpi    'Z'        ;and didn't want any more
  258.     rz            ;If that was the request, keep telling other end
  259.     xra    a        ;Otherwise, clear flag (^X is only for one file)
  260.     sta    czseen        ;And store the flag back
  261.     ret
  262.  
  263. rfile4:    cpi    'B'        ;End of transmission.
  264.     jnz    rfile5
  265.     call    compp
  266.     jnz    nak0        ;No, NAK it and try again.
  267.     xra    a        ;No data.  (Packet number already in argblk).
  268.     sta    argblk+1
  269.     mvi    a,'Y'        ;Acknowledge packet.
  270.     call    spack        ;Send the packet.
  271.      jmp    abort
  272.     mvi    a,'C'        ;Set the state to complete.
  273.     sta    state
  274.     ret
  275.  
  276. rfile5:    cpi    'E'        ;Is it an error packet.
  277.     jnz    abort
  278.     call    error
  279.     jmp    abort
  280. ;
  281. ;    Receive data
  282. ;    called by: read
  283.  
  284. rdata:    lda    numtry        ;Get the number of tries.
  285.     cpi    maxtry        ;Have we reached the maximum number of tries?
  286.     jm    rdata1
  287.     lxi    d,erms10
  288.     call    error3        ;Display error message.
  289.     jmp    abort        ;Change the state to abort.
  290.  
  291. rdata1:    inr    a        ;Increment it.
  292.     sta    numtry        ;Save the updated number of tries.
  293.     call    rpack        ;Get a packet.
  294.      jmp    nak        ; Trashed packet: nak, retry.
  295.     cpi    'D'        ;Is it a data packet?
  296.     jnz    rdata2        ; No, try next type.
  297.     call    compp
  298.     jz    rdat14
  299.     lda    oldtry        ;Get the number of tries.
  300.     cpi    maxtry        ;Have we reached the maximum number of tries?
  301.     jm    rdat12        ;If not proceed.
  302.     lxi    d,erms10
  303.     call    error3        ;Display err msg.
  304.     jmp    abort        ;Change the state to abort.
  305.  
  306. rdat12:    call    tryagn
  307.     ret
  308.  
  309. rdat14:    call    countp
  310.     lda    numtry        ;Get the number of tries.
  311.     sta    oldtry        ;Save it.
  312.     lda    argblk+1    ;Get the length of the data.
  313.     call    ptchr
  314.      jmp    abort        ; Unable to write out chars;abort.
  315.     xra    a
  316.     sta    numtry        ;Reset the number of tries.
  317.     sta    argblk+1    ;No data.  (Packet number still in argblk.)
  318.     mov    c,a        ;Assume no data
  319.     lda    czseen        ;Check if control-X typed
  320.     ora    a        ; .  .  .
  321.     jz    rdat15        ;Zero if not typed
  322.     mov    c,a        ;Get the type of character typed
  323.     mvi    a,1        ;One data character
  324.     sta    argblk+1    ;Save the count
  325.     mov    a,c        ;Get the possible data character
  326.     sta    data        ;Store in data area
  327. rdat15:    mvi    a,'Y'        ;Acknowledge packet.
  328.     call    spack        ;Send the packet.
  329.      jmp    abort
  330.     ret
  331.  
  332. rdata2:    cpi    'F'        ;Start of file?
  333.     jnz    rdata3        ; No, try next type.
  334.     lda    oldtry        ;Get the number of tries.
  335.     cpi    maxtry        ;Have we reached the maximum number of tries?
  336.     jm    rdat21        ;If not proceed.
  337.     lxi    d,ermes5
  338.     call    error3        ;Display err msg.
  339.     jmp    abort        ;Change the state to abort.
  340.  
  341. rdat21:    call    tryagn
  342.     ret
  343.  
  344. rdata3:    cpi    'Z'        ;Is it a EOF packet?
  345.     jnz    rdata4        ;Try and see if its an error.
  346.     call    compp
  347.     jnz    nak0        ;No, NAK it and try again.
  348.     call    countp
  349.     lda    argblk+1    ;Get the data length
  350.     cpi    1        ;Have one item?
  351.     jnz    rdat33        ;If not, ignore data
  352.     lda    data        ;Yes, get the character
  353.     cpi    'D'        ;Is it a 'D' for discard?
  354.     jz    rdat36        ;If so, punt file
  355. rdat33:    call    clofil        ;Finish off the file.
  356.      jmp    rdat37        ; Give up if the disk is full.
  357.     xra    a        ;Since we kept the file,
  358.     sta    czseen        ;don't say it was discarded.
  359. rdat36:    lda    numtry        ;Get the number of tries.
  360.     sta    oldtry        ;Save it.
  361.     call    ackp
  362.     mvi    a,'F'
  363.     sta    state
  364.     ret
  365.  
  366. rdat37:    lxi    d,erms11    ; "?Disk full"
  367.     call    error3        ; put it on the error line
  368.     jmp    abort        ; abort transfer
  369.  
  370. rdata4:    cpi    'E'        ;Is it an error packet.
  371.     jnz    abort
  372.     call    error
  373.     jmp    abort
  374. ;
  375. ;    SEND command
  376. ;    here from: kermit
  377.  
  378. send:    mvi    a,cmifi        ;Parse an input file spec.
  379.     lxi    d,fcb        ;Give the address for the FCB.
  380.     call    comnd
  381.      jmp    kermit        ; Give up on bad parse.
  382.     call    cfmcmd
  383.     call    mfname        ;handle (multi) files
  384.     jnc    send14        ;got a valid file-name
  385.     lxi    d,erms15
  386.     call    prtstr        ;Display error msg. ([hh] where it's visible)
  387.     jmp    kermit
  388.  
  389. send14:    call    init        ;Clear the line and initialize the buffers.
  390.     xra    a
  391.     sta    pktnum        ;Set the packet number to zero.
  392.     sta    numtry        ;Set the number of tries to zero.
  393.     sta    wrn8        ;[jd] we haven't sent the 8-bit-lost warning
  394.     lxi    h,0
  395.     shld    numpkt        ;Set the number of packets to zero.
  396.     shld    numrtr        ;Set the number of retries to zero.
  397.     call    scrnrt        ;Position cursor
  398.     lxi    h,0
  399.     call    nout        ;Write the number of retries.
  400.     mvi    a,'1'        ;Reset to use single character checksum
  401.     sta    curchk        ;For startup
  402.     mvi    a,'S'
  403.     sta    state        ;Set the state to receive initiate.
  404.     ;...
  405. ;
  406. ;SEND state table switcher
  407.  
  408. send2:    call    scrnp        ;Position cursor
  409.     lhld    numpkt
  410.     call    nout        ;Write the packet number.
  411.     lda    state        ;Get the state.
  412.     cpi    'D'        ;Are we in the data send state?
  413.     jnz    send3
  414.     call    sdata
  415.     jmp    send2
  416.  
  417. send3:    cpi    'F'        ;Are we in the file send state?
  418.     jnz    send4
  419.     call    sfile        ;Call send file.
  420.     jmp    send2
  421.  
  422. send4:    cpi    'Z'        ;Are we in the EOF state?
  423.     jnz    send5
  424.     call    seof
  425.     jmp    send2
  426.  
  427. send5:    cpi    'S'        ;Are we in the send initiate state?
  428.     jnz    send6
  429.     call    sinit
  430.     lda    state        ;[jd] get state back
  431.     cpi    'F'        ;[jd] into file send state yet?
  432.     jnz    send2        ;[jd] no
  433.     lxi    d,inms23    ;[jd] yes, print sending...
  434.     call    finmes        ;[jd] 
  435.     jmp    send2
  436.  
  437. send6:    cpi    'B'        ;Are we in the eot state?
  438.     jnz    send7
  439.     call    seot
  440.     jmp    send2
  441.  
  442. send7:    cpi    'C'        ;Are we in the send complete state?
  443.     jnz    send8        ;No...
  444.     lxi    d,infms3    ;Yes, write "Complete" message.
  445.     lda    czseen        ;Or was it interrupted?
  446.     ora    a        ; .  .  .
  447.     jz    send7a        ;No.
  448.     lxi    d,inms13    ;Yes, then say "Interrupted" instead.
  449. send7a:    call    finmes
  450.     jmp    kermit
  451.  
  452. send8:    cpi    'A'        ;Are we in the send "abort" state?
  453.     jnz    send9
  454.     lxi    d,infms4    ;Print    message.
  455.     call    finmes
  456.     jmp    kermit
  457.  
  458. send9:    lxi    d,infms4    ;Anything else is equivalent to "abort".
  459.     call    finmes
  460.     jmp    kermit
  461. ;
  462. ;    Send routines
  463.  
  464. ;    Send initiate
  465. ;    called by: send
  466.  
  467. sinit:    lda    numtry        ;Get the number of tries.
  468.     cpi    imxtry        ;Have we reached the maximum number of tries?
  469.     jm    sinit2
  470.     lxi    d,erms14
  471.     call    error3        ;Display ermsg
  472.     jmp    abort        ;Change the state to abort.
  473.  
  474. sinit2:    inr    a        ;Increment it.
  475.     sta    numtry        ;Save the updated number of tries.
  476.     mvi    a,'1'        ;Reset to use single character checksum
  477.     sta    curchk        ;For startup
  478.     lda    chktyp        ;Get our desired block check type
  479.     sta    inichk        ;Store so we tell other end
  480.     lxi    h,data        ;Get a pointer to our data block.
  481.     call    rpar        ;Set up the parameter information.
  482.     sta    argblk+1    ;Save the number of arguments.
  483.     lda    numpkt        ;Get the packet number.
  484.     sta    argblk
  485.     mvi    a,'S'        ;Send initiate packet.
  486.     call    spack        ;Send the packet.
  487.      jmp    abort        ; Failed, abort.
  488.     call    rpack        ;Get a packet.
  489.      jmp    r        ; Trashed packet don't change state, retry.
  490.     cpi    'Y'        ;ACK?
  491.     jnz    sinit3        ;If not try next.
  492.     call    compp
  493.     rnz            ;If not try again.
  494.     call    countp
  495.     lda    argblk+1    ;Get the number of pieces of data.
  496.     lxi    h,data        ;Pointer to the data.
  497.     call    spar        ;Read in the data.
  498.     lda    numtry        ;Get the number of tries.
  499.     sta    oldtry        ;Save it.
  500.     xra    a
  501.     sta    numtry        ;Reset the number of tries.
  502.     lda    inichk        ;Get the agreed upon block check type
  503.     sta    curchk        ;Store as type to use for packets now
  504.     mvi    a,'F'        ;Set the state to file send.
  505.     sta    state
  506.     call    getfil        ;Open the file.
  507.     ret            ; assume success; mfname thinks the file exists.
  508.  
  509. sinit3:    cpi    'N'        ;NAK?
  510.     jnz    sinit4        ;If not see if its an error.
  511.     call    updrtr        ;Update the number of retries.
  512.     lda    pktnum        ;Get the present packet number.
  513.     inr    a        ;Increment
  514.     ani    3FH        ; modulo 64
  515.     mov    b,a
  516.     lda    argblk        ;Get the packet's number.
  517.     cmp    b        ;Is the packet's number one more than now?
  518.     rnz            ;If not assume its for this packet, go again.
  519.     xra    a
  520.     sta    numtry        ;Reset number of tries.
  521.     mvi    a,'F'        ;Set the state to file send.
  522.     sta    state
  523.     ret
  524.  
  525. sinit4:    cpi    'E'        ;Is it an error packet.
  526.     jnz    abort
  527.     call    error
  528.     jmp    abort
  529. ;
  530. ;    Send file header
  531. ;    called by: send
  532.  
  533. sfile:    lda    numtry        ;Get the number of tries.
  534.     cpi    maxtry        ;Have we reached the maximum number of tries?
  535.     jm    sfile1
  536.     lxi    d,erms14
  537.     call    error3
  538.     jmp    abort        ;Change the state to abort.
  539.  
  540. sfile1:    inr    a        ;Increment it.
  541.     sta    numtry        ;Save the updated number of tries.
  542.     xra    a        ;Clear A
  543.     sta    czseen        ;No control-Z or X seen
  544.     lxi    h,data        ;Get a pointer to our data block.
  545.     shld    datptr        ;Save it.
  546.     lxi    h,fcb+1        ;Pointer to the file name in the FCB.
  547.     shld    fcbptr        ;Save position in FCB.
  548.     mvi    b,0        ;No chars yet.
  549.     mvi    c,0
  550. sfil11:    mov    a,b
  551.     cpi    8H        ;Is this the ninth char?
  552.     jnz    sfil12        ;If not proceed.
  553.     mvi    a,'.'        ;Get a dot.
  554.     lhld    datptr
  555.     mov    m,a        ;Put the char in the data packet.
  556.     inx    h
  557.     shld    datptr        ;Save position in data packet.
  558.     inr    c
  559. sfil12:    inr    b        ;Increment the count.
  560.     mov    a,b
  561.     cpi    0CH        ;Twelve?
  562.     jp    sfil13
  563.     lhld    fcbptr
  564.     mov    a,m
  565.     ani    7fH        ;Turn off CP/M 2 or 3's high bits.
  566.     inx    h
  567.     shld    fcbptr        ;Save position in FCB.
  568.     cpi    '!'        ;Is it a good character?
  569.     jm    sfil11        ;If not get the next.
  570.     lhld    datptr
  571.     mov    m,a        ;Put the char in the data packet.
  572.     inx    h
  573.     shld    datptr        ;Save position in data packet.
  574.     inr    c
  575.     jmp    sfil11        ;Get another.
  576.  
  577. sfil13:    mov    a,c        ;Number of char in file name.
  578.     sta    argblk+1
  579.     lhld    datptr
  580.     mvi    a,'$'
  581.     mov    m,a        ;Put in a dollar sign for printing.
  582.     call    scrfln        ;Position cursor
  583.     lxi    d,data        ;Print the file name
  584.     call    prtstr
  585.     lda    pktnum        ;Get the packet number.
  586.     sta    argblk
  587.     mvi    a,'F'        ;File header packet.
  588.     call    spack        ;Send the packet.
  589.      jmp    abort        ; Failed, abort.
  590.     call    rpack        ;Get a packet.
  591.      jmp    r        ; Trashed packet don't change state, retry.
  592.     cpi    'Y'        ;ACK?
  593.     jnz    sfile2        ;If not try next.
  594.     call    compp
  595.     rnz            ;If not hold out for the right one.
  596. sfil14:    call    countp
  597.     lda    numtry        ;Get the number of tries.
  598.     sta    oldtry        ;Save it.
  599.     xra    a
  600.     sta    numtry        ;Reset the number of tries.
  601.     call    gtchr        ;Fill the first data packet
  602.      jmp    sfil16        ;Error go see if its EOF.
  603. ;                ;Got the chars, proceed.
  604.     sta    size        ;Save the size of the data gotten.
  605.     mvi    a,'D'        ;Set the state to data send.
  606.     sta    state
  607.     ret
  608.  
  609. sfil16:    cpi    0FFH        ;Is it EOF?
  610.     jnz    abort        ;If not give up.
  611.     mvi    a,'Z'        ;Set the state to EOF.
  612.     sta    state
  613.     ret
  614.  
  615. sfile2:    cpi    'N'        ;NAK?
  616.     jnz    sfile3        ;Try if error packet.
  617.     call    updrtr        ;Update the number of retries.
  618.     lda    pktnum        ;Get the present packet number.
  619.     inr    a        ;Increment
  620.     ani    3FH        ; modulo 64
  621.     mov    b,a
  622.     lda    argblk        ;Get the packet's number.
  623.     cmp    b        ;Is the packet's number one more than now?
  624.     rnz            ;If not go try again.
  625.     jmp    sfil14        ;Just as good as a ACK;go to the ACK code.
  626.  
  627. sfile3:    cpi    'E'        ;Is it an error packet.
  628.     jnz    abort
  629.     call    error
  630.     jmp    abort
  631. ;
  632. ;    Send data
  633. ;    called by: send
  634.  
  635. sdata:    lda    numtry        ;Get the number of tries.
  636.     cpi    maxtry        ;Have we reached the maximum number of tries?
  637.     jm    sdata1
  638.     lxi    d,erms14
  639.     call    error3
  640.     jmp    abort        ;Change the state to abort.
  641.  
  642. sdata1:    inr    a        ;Increment it.
  643.     sta    numtry        ;Save the updated number of tries.
  644.     lxi    h, data        ;Get a pointer to our data block.
  645.     shld    datptr        ;Save it.
  646.     lxi    h,filbuf    ;Pointer to chars to be sent.
  647.     shld    cbfptr        ;Save position in char buffer.
  648.     mvi    b,1        ;First char.
  649. sdat11:    lhld    cbfptr
  650.     mov    a,m
  651.     inx    h
  652.     shld    cbfptr        ;Save position in char buffer.
  653.     mov    c,a        ;[jd] preserve character temporarily
  654.     lda    quot8        ;[jd] doing eighth-bit quoting?
  655.     ora    a        ;[jd] 
  656.     mov    a,c        ;[jd] restore char
  657.     jnz    sdat4        ;[jd] using eighth-bit quoting, no warning
  658.     lda    parity        ;[jd] get parity
  659.     cpi    parnon        ;[jd] none?
  660.     mov    a,c        ;[jd] restore character
  661.     jz    sdat4        ;[jd] no parity, leave char alone
  662.     lda    wrn8        ;[jd] look at warning flag
  663.     ora    a        ;[jd] have we already given the warning?
  664.     jnz    sdat5        ;[jd] yes, skip this
  665.     mov    a,c        ;[jd] restore character...
  666.     ani    80h        ;[jd] examine parity
  667.     jz    sdat5        ;[jd] no parity, no warning.
  668.     call    parwrn        ;[jd] ...print warning - parity lost
  669.     mvi    a,0ffh        ;[jd] remember that we sent the message
  670.     sta    wrn8        ;[jd]
  671. sdat5:    mov    a,c        ;[jd] restore character again
  672.     ani    7fh        ;[jd] strip parity so not checksummed
  673. sdat4:    lhld    datptr
  674.     mov    m,a        ;Put the char in the data packet.
  675.     inx    h
  676.     shld    datptr        ;Save position in data packet.
  677.     inr    b        ;Increment the count.
  678.     lda    size        ;Get the number of chars in char buffer.
  679.     cmp    b        ;Have we transfered that many?
  680.     jp    sdat11        ;If not get another.
  681.     lda    size        ;Number of char in char buffer.
  682.     sta    argblk+1
  683.     lda    pktnum        ;Get the packet number.
  684.     sta    argblk
  685.     mvi    a,'D'        ;Data packet.
  686.     call    spack        ;Send the packet.
  687.      jmp    abort        ; Failed, abort.
  688.     call    rpack        ;Get a packet.
  689.      jmp    r        ; Trashed packet don't change state, retry.
  690.     cpi    'Y'        ;ACK?
  691.     jnz    sdata2        ;If not try next.
  692.     call    compp
  693.     rnz            ;If not hold out for the right one.
  694.     lda    argblk        ;Get the packet number back
  695.     call    countp
  696.     lda    numtry        ;Get the number of tries.
  697.     sta    oldtry        ;Save it.
  698.     xra    a
  699.     sta    numtry        ;Reset the number of tries.
  700.     lda    argblk+1    ;Get the data length
  701.     cpi    1        ;Check if only 1 character?
  702.     jnz    sdat15        ;If not, just continue
  703.     lda    data        ;Got one character, get it from data
  704.     cpi    'Z'        ;Want to abort entire stream?
  705.     jnz    sdat14        ;If not, check for just this file
  706.     sta    czseen        ;Yes, remember it
  707. sdat14:    cpi    'X'        ;Desire abort of current file?
  708.     jnz    sdat15        ;If not, just continue
  709.     sta    czseen        ;Yes, remember that
  710. sdat15:    lda    czseen        ;Also get control-Z flag
  711.     ora    a        ;Check if either given
  712.     jz    sdat12        ;If neither given, continue
  713.     mvi    a,'Z'        ;Change state to EOF
  714.     sta    state        ; .  .  .
  715.     ret            ;And return
  716.  
  717. sdat12:    call    gtchr
  718.      jmp    sdat13        ;Error go see if its EOF.
  719.     sta    size        ;Save the size of the data gotten.
  720.     ret
  721.  
  722. sdat13:    cpi    0FFH        ;Is it EOF?
  723.     jnz    abort        ;If not give up.
  724.     mvi    a,'Z'        ;Set the state to EOF.
  725.     sta    state
  726.     ret
  727.  
  728. sdata2:    cpi    'N'        ;NAK?
  729.     jnz    sdata3        ;See if is an error packet.
  730.     call    updrtr        ;Update the number of retries.
  731.     lda    pktnum        ;Get the present packet number.
  732.     inr    a        ;Increment
  733.     ani    3FH        ; modulo 64
  734.     mov    b,a
  735.     lda    argblk        ;Get the packet's number.
  736.     cmp    b        ;Is the packet's number one more than now?
  737.     rnz            ;If not go try again.
  738.     jmp    sdat12        ;Just as good as a ACK;go to the ACK code.
  739.  
  740. sdata3:    cpi    'E'        ;Is it an error packet.
  741.     jnz    abort
  742.     call    error
  743.     jmp    abort
  744. ;
  745. ;    Send EOF
  746. ;    called by: send
  747.  
  748. seof:    lda    numtry        ;Get the number of tries.
  749.     cpi    maxtry        ;Have we reached the maximum number of tries?
  750.     jm    seof1
  751.     lxi    d,erms14
  752.     call    error3
  753.     jmp    abort        ;Change the state to abort.
  754.  
  755. seof1:    inr    a        ;Increment it.
  756.     sta    numtry        ;Save the updated number of tries.
  757.     lda    pktnum        ;Get the packet number.
  758.     sta    argblk
  759.     xra    a
  760.     sta    argblk+1    ;No data.
  761.     lda    czseen        ;Check if C-Z or C-X typed
  762.     ora    a        ; .  .  .
  763.     jz    seof14        ;If not aborted, just keep going
  764.     mvi    a,'D'        ;Tell other end to discard packet
  765.     sta    data        ;Store in data portion
  766.     mvi    a,1        ;One character
  767.     sta    argblk+1    ;Store the length
  768. seof14:    mvi    a,'Z'        ;EOF packet.
  769.     call    spack        ;Send the packet.
  770.      jmp    abort        ; Failed, abort.
  771.     call    rpack        ;Get a packet.
  772.      jmp    r        ; Trashed packet don't change state, retry.
  773.     cpi    'Y'        ;ACK?
  774.     jnz    seof2        ;If not try next.
  775.     call    compp
  776.     rnz            ;If not hold out for the right one.
  777. seof12:    call    countp
  778.     lda    numtry        ;Get the number of tries.
  779.     sta    oldtry        ;Save it.
  780.     xra    a
  781.     sta    numtry        ;Reset the number of tries.
  782.     mvi    c,closf        ;Close the file.
  783.     lxi    d,fcb
  784.     call    bdos
  785. ;* Check if successful
  786.     lda    czseen        ;Desire abort of entire stream?
  787.     cpi    'Z'        ;Desire abort of entire stream?
  788.     jz    seof13        ;If so, just give up now
  789.     call    mfname        ;Get the next file.
  790.      jc    seof13        ; No more.
  791.     call    getfil        ;and open it (assume success)
  792.     xra    a        ;Clear A
  793.     sta    czseen        ;Since we have not aborted this file
  794.     mvi    a,'F'        ;Set the state to file send.
  795.     sta    state
  796.     ret
  797.  
  798. seof13:    mvi    a,'B'        ;Set the state to EOT.
  799.     sta    state
  800.     ret
  801.  
  802. seof2:    cpi    'N'        ;NAK?
  803.     jnz    seof3        ;Try and see if its an error packet.
  804.     call    updrtr        ;Update the number of retries.
  805.     lda    pktnum        ;Get the present packet number.
  806.     inr    a        ;Increment
  807.     ani    3FH        ; modulo 64
  808.     mov    b,a
  809.     lda    argblk        ;Get the packet's number.
  810.     cmp    b        ;Is the packet's number one more than now?
  811.     rnz            ;If not go try again.
  812.     jmp    seof12        ;Just as good as a ACK;go to the ACK code.
  813.  
  814. seof3:    cpi    'E'        ;Is it an error packet.
  815.     jnz    abort
  816.     call    error
  817.     jmp    abort
  818. ;
  819. ;    Send EOT
  820. ;    called by: send
  821.  
  822. seot:    lda    numtry        ;Get the number of tries.
  823.     cpi    maxtry        ;Have we reached the maximum number of tries?
  824.     jm    seot1
  825.     lxi    d,erms14
  826.     call    error3
  827.     jmp    abort        ;Change the state to abort.
  828.  
  829. seot1:    inr    a        ;Increment it.
  830.     sta    numtry        ;Save the updated number of tries.
  831.     lda    pktnum        ;Get the packet number.
  832.     sta    argblk
  833.     xra    a
  834.     sta    argblk+1    ;No data.
  835.     mvi    a,'B'        ;EOF packet.
  836.     call    spack        ;Send the packet.
  837.      jmp    abort        ; Failed, abort.
  838.     call    rpack        ;Get a packet.
  839.      jmp    r        ; Trashed packet don't change state, retry.
  840.     cpi    'Y'        ;ACK?
  841.     jnz    seot2        ;If not try next.
  842.     call    compp
  843.     rnz            ;If not hold out for the right one.
  844. seot12:    call    countp
  845.     lda    numtry        ;Get the number of tries.
  846.     sta    oldtry        ;Save it.
  847.     xra    a
  848.     sta    numtry        ;Reset the number of tries.
  849.     mvi    a,'C'        ;Set the state to file send.
  850.     sta    state
  851.     ret
  852.  
  853. seot2:    cpi    'N'        ;NAK?
  854.     jnz    seot3        ;Is it error.
  855.     call    updrtr        ;Update the number of retries.
  856.     lda    pktnum        ;Get the present packet number.
  857.     inr    a        ;Increment
  858.     ani    3FH        ; modulo 64
  859.     mov    b,a
  860.     lda    argblk        ;Get the packet's number.
  861.     cmp    b        ;Is the packet's number one more than now?
  862.     rnz            ;If not go try again.
  863.     jmp    seot12        ;Just as good as a ACK;go to the ACK code.
  864.  
  865. seot3:    cpi    'E'        ;Is it an error packet.
  866.     jnz    abort
  867.     call    error
  868.     jmp    abort
  869. ;
  870. ;    This routine sets up the data for init packet (either the
  871. ;    Send_init or ACK packet).
  872. ;    called by: rinit, rfile, sinit
  873.  
  874. rpar:    lda    rpsiz        ;Get the receive packet size.
  875.     adi    ' '        ;Add a space to make it printable.
  876.     mov    m,a        ;Put it in the packet.
  877.     inx    h        ;Point to the next char.
  878.     lda    rtime        ;Get the receive packet time out.
  879.     adi    ' '        ;Add a space.
  880.     mov    m,a        ;Put it in the packet.
  881.     inx    h
  882.     lda    rpad        ;Get the number of padding chars.
  883.     adi    ' '
  884.     mov    m,a
  885.     inx    h
  886.     lda    rpadch        ;Get the padding char.
  887.     adi    100O        ;Uncontrol it.
  888.     ani    7FH
  889.     mov    m,a
  890.     inx    h
  891.     lda    reol        ;Get the EOL char.
  892.     adi    ' '
  893.     mov    m,a
  894.     inx    h
  895.     lda    rquote        ;Get the quote char.
  896.     mov    m,a
  897.     inx    h
  898.     mvi    m,'Y'        ;[jd] we know how to do 8-bit quoting
  899.     lda    parity        ;[jd]
  900.     cpi    parnon        ;[jd] parity none?
  901.     jz    rpar1        ;[jd] yes, keep going
  902.     lda    qbchr        ;[jd] no, better request 8-bit quoting
  903.     mov    m,a
  904.  
  905. rpar1:
  906.     inx    h        ;Advance to next
  907.     lda    chktyp        ;Get desired block check type
  908.     mov    m,a        ;Store it
  909.     inx    h        ;Advance pointer
  910.     mvi    a,08H        ;Six pieces of data.
  911.     ret
  912. ;
  913. ;    This routine reads in all the send_init packet information.
  914. ;    called by: rinit, sinit
  915.  
  916. spar:    sta    temp4        ;Save the number of arguments.
  917. ; Initialize some variables to their required default values, so we use
  918. ; the right values even if the remote Kermit doesn't send the full packet:
  919. ;                ; we don't do anything with timeout values yet.
  920. ;                ; no default pad count/pad character?
  921.     mvi    a,cr        ; EOL character = carriage-return
  922.     sta    seol
  923.     mvi    a,'#'        ; quote character = '#'
  924.     sta    squote
  925.     mvi    a,'&'        ; eighth-bit quote character = '&'
  926.     sta    qbchr
  927.     mvi    a,'1'        ; block-check = 1-character-checksum
  928.     sta    inichk
  929. ; 
  930.     mov    a,m        ;Get the max packet size.
  931.     sbi    ' '        ;Subtract a space.
  932.     sta    spsiz        ;Save it.
  933.     lda    temp4
  934.     cpi    3        ;Fewer than three pieces?
  935.     rm            ;If so we are done.
  936.     inx    h
  937.     inx    h        ;Increment past the time out info.
  938.     mov    a,m        ;Get the number of padding chars.
  939.     sbi    ' '
  940.     sta    spad
  941.     lda    temp4
  942.     cpi    4        ;Fewer than four pieces?
  943.     rm            ;If so we are done.
  944.     inx    h
  945.     mov    a,m        ;Get the padding char.
  946.     adi    100O        ;Re-controlify it.
  947.     ani    7FH
  948.     sta    spadch
  949.     lda    temp4
  950.     cpi    5        ;Fewer than five pieces?
  951.     rm            ;If so we are done.
  952.     inx    h
  953.     mov    a,m        ;Get the EOL char.
  954.     sbi    ' '
  955.     sta    seol
  956.     lda    temp4
  957.     cpi    6        ;Fewer than six pieces?
  958.     rm            ;If so we are done.
  959.     inx    h
  960.     mov    a,m        ;Get the quote char.
  961.     sta    squote
  962.     lda    temp4        ;Get the amount of data supplied
  963.     cpi    7        ;Have an 8-bit quote?
  964.     rm            ;If not there, all done
  965.     inx    h        ;Yes, get the character
  966.     mvi    a,0        ;[jd] 
  967.     sta    quot8        ;[jd] assume not quoting
  968.     mov    a,m        ;Get the supplied character
  969.     cpi    'N'        ;[jd] No?
  970.     jz    spar1        ;[jd] then don't try to do it
  971.     cpi    ' '        ;[jd] maybe they don't know about it...
  972.     jz    spar1        ;[jd] then don't try to do it.
  973.     cpi    'Y'        ;[jd] Yes?
  974.     jnz    spar2        ;[jd] if not 'Y', assume it's a quote char.
  975.     lda    parity        ;[jd] using parity?
  976.     cpi    parnon        ;[jd] no, don't need quoting...
  977.     jz    spar1        ;[jd] 
  978.     mvi    a,0ffh        ;[jd] else turn on...
  979.     sta    quot8        ;[jd] ...quote flag
  980.     jmp    spar1
  981.  
  982. spar2:    sta    qbchr        ;[jd] use their quote char (should validate)
  983.     mvi    a,0ffh
  984.     sta    quot8        ;[jd] turn quote flag and fall thru...
  985.  
  986. spar1:    lda    temp4        ;Determine if block check type given
  987.     cpi    8        ;Is the field there?
  988.     rm            ;If not, all done
  989.     inx    h        ;Point to the character
  990.     mov    a,m        ;Get the value
  991.     mov    b,a        ;Copy value
  992.     lda    chktyp        ;Get our type
  993.     cmp    b        ;Is it our desired type?
  994.     rnz            ; If not, use default (1-character-checksum)
  995.     sta    inichk        ; Match, store as type to use after init
  996.     ret            ; and return
  997. ;
  998.  
  999. ;    Copy characters from packet to disk
  1000. ;    called by: rdata
  1001.  
  1002. ptchr:    sta    temp1        ;Save the size.
  1003.     lxi    h,data        ;Beginning of received packet data.
  1004.     shld    outpnt        ;Remember where we are.
  1005.     lda    rquote
  1006.     mov    b,a        ;Keep the quote char in b.
  1007.     mvi    c,0        ;[jd] assume no 8-bit quote char
  1008.     lda    quot8        ;[jd] doing 8-bit quoting?
  1009.     ora    a
  1010.     jz    ptchr1        ;[jd] no, keep going
  1011.     lda    qbchr        ;[jd] else get 8-bit quote char
  1012.     mov    c,a        ;[jd] keep this in c
  1013. ptchr1:    lxi    h,temp1
  1014.     dcr    m        ;Decrement # of chars in packet.
  1015.     jm    rskp        ;Return successfully if done.
  1016.     lxi    h,chrcnt    ;Number of chars remaining in dma.
  1017.     dcr    m        ;Decrement.
  1018.     jp    ptchr2        ;Continue if space left.
  1019.     call    outbuf        ;Output it if full.
  1020.      jmp    ptchr9        ; Error return if disk is full.
  1021. ptchr2:    lhld    outpnt        ;Get position in output buffer.
  1022.     mov    a,m        ;Grab a char.
  1023.     inx    h
  1024.     shld    outpnt        ;and bump pointer.
  1025.     mvi    e,0        ;[jd] assume nothing to OR in.
  1026.     cmp    c        ;[jd] is it the binary quote char?
  1027.     jnz    ptch2a        ;[jd] no, keep going
  1028.     mvi    e,80h        ;[jd] include parity bit
  1029.     lda    temp1
  1030.     dcr    a
  1031.     sta    temp1        ;[jd] decrement character count
  1032.     mov    a,m        ;[jd] get next character
  1033.     inx    h
  1034.     shld    outpnt
  1035. ptch2a:    cmp    b        ;Is it the quote char?
  1036.     jnz    ptchr3        ;[jd] changed to ptchr3 so includes parity
  1037.     mov    a,m        ;Get the quoted character
  1038.     inx    h
  1039.     shld    outpnt        ;and bump pointer.
  1040.     lxi    h,temp1
  1041.     dcr    m        ;Decrement # of chars in packet.
  1042.     mov    d,a        ;Save the char.
  1043.     ani    80H        ;Turn off all but the parity bit.
  1044.     ora    e        ;[jd] let parity come from either (???)
  1045.     mov    e,a        ;Save the parity bit.
  1046.     mov    a,d        ;Get the char.
  1047.     ani    7FH        ;Turn off the parity bit.
  1048.     cmp    b        ;Is it the quote char?
  1049.     jz    ptchr3        ;If so just go write it out.
  1050.     cmp    c        ;[jd] maybe it's the 8-bit prefix character?
  1051.     jz    ptchr3        ;[jd] then don't controllify.
  1052.     mov    a,d        ;Get the char.
  1053.     adi    40H        ;Make the character a control char again.
  1054.     ani    7FH        ;Modulo 128.
  1055. ptchr3:    ora    e        ;Or in the parity bit.
  1056.     lhld    bufpnt        ;Destination buffer.
  1057.     mov    m,a        ;Store it.
  1058.     inx    h
  1059.     shld    bufpnt        ;Update the pointer
  1060.     jmp    ptchr1        ;and loop to next char.
  1061.  
  1062. ptchr9:    lxi    d,erms11    ; "?Disk full"
  1063.     call    error3        ; put it on the error line
  1064.     ret            ; take error return.
  1065. ;
  1066. ;    Fill a data packet from file
  1067. ;    called by: sfile, sdata
  1068.  
  1069. gtchr:    lda    squote        ;Get the quote char.
  1070.     mov    c,a        ;Keep quote char in c.
  1071.     lda    curchk        ;Get current block check type
  1072.     sui    '1'        ;Get the extra overhead
  1073.     mov    b,a        ;Get a copy
  1074.     lda    spsiz        ;Get the maximum packet size.
  1075.     sui    5        ;Subtract the overhead.
  1076.     sub    b        ;Determine max packet length
  1077.     sta    temp1        ;This is the number of chars we are to get.
  1078.     lxi    h,filbuf    ;Where to put the data.
  1079.     shld    cbfptr        ;Remember where we are.
  1080.     mvi    b,0        ;No chars.
  1081. gtchr1:    lda    temp1
  1082.     dcr    a        ;Decrement the number of chars left.
  1083.     jp    gtchr2        ;Go on if there is more than one left.
  1084.     mov    a,b        ;Return the count in A.
  1085.     jmp    rskp
  1086.  
  1087. gtchr2:    sta    temp1
  1088.     lda    chrcnt        ;Space left in the DMA.
  1089.     dcr    a
  1090. ;* Can improve order here.
  1091.     jm    gtchr3
  1092.     sta    chrcnt
  1093.     jmp    gtchr4
  1094.  
  1095. gtchr3:    call    inbuf        ;Get another buffer full.
  1096.      jmp    gtch30        ; If no more return what we got.
  1097.     jmp    gtchr4        ;If we got some, proceed.
  1098.  
  1099. gtch30:    mov    a,b        ;Return the count in A.
  1100.     ora    a        ;Get any chars?
  1101.     jnz    rskp        ;If so return them.
  1102.     jmp    gtceof        ;If not, say we found the end of the file.
  1103.  
  1104. gtchr4:    lhld    bufpnt        ;Position in DMA.
  1105.     mov    a,m        ;Get a char from the file.
  1106.     inx    h
  1107.     shld    bufpnt
  1108.     mov    d,a        ;Save the char.
  1109.     ani    80H        ;Turn off all but parity.
  1110.     mov    e,a        ;Save the parity bit.
  1111.     jz    gtch4a        ;[jd] no parity, skip this check...
  1112.     lda    quot8        ;[jd] doing eighth-bit quoting?
  1113.     ora    a
  1114.     jz    gtch4a        ;[jd] no, just proceed normally
  1115.     lda    temp1        ;[jd] get space remaining
  1116.     cpi    2        ;[jd] 3 chrs left (one cnted already)?
  1117.     jm    gtchr9        ;[jd] no, skip this
  1118.     dcr    a        ;[jd] decrement space remaining
  1119.     sta    temp1        ;[jd] put back.
  1120.     lhld    cbfptr        ;[jd] Position in character buffer.
  1121.     lda    qbchr        ;[jd] get quote character
  1122.     mov    m,a        ;]jd] Put the quote char in the buffer.
  1123.     inx    h        ;[jd] increment destination buffer pointer
  1124.     shld    cbfptr        ;[jd] store the pointer back
  1125.     inr    b        ;[jd] Increment the char count.
  1126.     mvi    e,0        ;[jd] no parity bit to OR in.
  1127. ;[jd] fall thru...
  1128.  
  1129. gtch4a:    mov    a,d        ;Restore the char.
  1130.     ani    7FH        ;Turn off the parity.
  1131.     mov    d,a        ;[jd] save here for later...
  1132.     cpi    ' '        ;Compare to a space.
  1133.     jm    gtchr5        ;If less then its a control char, handle it.
  1134.     cpi    del        ;Is the char a delete?
  1135.     jz    gtchr5        ;Go quote it.
  1136.     lda    quot8        ; Are we doing 8th-bit quoting?
  1137.     ora    a
  1138.     jz    gtch4c        ; if not, skip this test and restore character.
  1139.     lda    qbchr        ; get 8th-bit quote character
  1140.     cmp    d        ; same as current character?
  1141.     jz    gtch4b        ; yes, have to quote it...
  1142. gtch4c:    mov    a,d        ; no. get character back again.
  1143.     cmp    c        ;Is it the quote char?
  1144.     jnz    gtchr8        ;If not proceed.
  1145. gtch4b:    lxi    h,temp1        ;[jd] point to char count
  1146.     dcr    m        ;[jd] decrement (know room for at least one)
  1147.     lhld    cbfptr        ;Position in character buffer.
  1148.     mov    m,c        ;Put the (quote) char in the buffer.
  1149.     inx    h
  1150.     shld    cbfptr
  1151.     inr    b        ;Increment the char count.
  1152.     mov    a,d        ;[jd] restore character again
  1153.     jmp    gtchr8
  1154.  
  1155. gtchr5:    ora    e        ;Turn on the parity bit.
  1156.     cpi    ('Z'-100O)    ;Is it a ^Z?
  1157.     jnz    gtchr7        ;If not just proceed.
  1158.     lda    cpmflg        ;Was the file created by CPM...
  1159.     cpi    1        ;in ASCII-mode ?
  1160.     jz    gtch52        ;Control-Z stops text
  1161.     cpi    2        ;in BINARY mode?
  1162.     jz    gtchr6        ;Yes, pass the ^Z
  1163. ;At this point file-mode is DEFAULT.
  1164. ;If the rest of the record is filled with ^Zs, we're at EOF, otherwise
  1165. ;its a regular character.
  1166.     lhld    bufpnt        ;since CHRCNT is ZERO at EOF-time
  1167.     lda    chrcnt        ;(set by INBUF5 B.G.E)
  1168.     mov    d,a        ;Get the number of chars left in the DMA.
  1169. gtch51:    dcr    d
  1170.     mov    a,d
  1171.     jp    gtch53        ;Any chars left?
  1172. gtch52:    xra    a        ;If not, get a zero.
  1173.     sta    chrcnt        ;Say no more chars in buffer.
  1174.     mov    a,b        ;Return the count in A.
  1175.     jmp    rskp
  1176.  
  1177. ;Scan rest of buffer for non ^Z -- If we find a non ^Z, fall into gtchr6.
  1178. ;If we get to the end of the buffer before finding a non ^Z, fall into gtch52.
  1179. gtch53:    mov    a,m        ;Get the next char.
  1180.     inx    h        ;Move the pointer.
  1181.     cpi    ('Z'-100O)    ;Is it a ^Z?
  1182.     jz    gtch51        ;If so see if the rest are.
  1183.  
  1184. gtchr6:    mvi    a,('Z'-100O)    ;Restore the ^Z.
  1185. gtchr7:    sta    temp2        ;Save the char.
  1186.     lxi    h,temp1        ;Point to the char total remaining.
  1187.     dcr    m        ;Decrement it.
  1188.     lhld    cbfptr        ;Position in character buffer.
  1189.     mov    m,c        ;Put the quote in the buffer.
  1190.     inx    h
  1191.     shld    cbfptr
  1192.     inr    b        ;Increment the char count.
  1193.     lda    temp2        ;Get the control char back.
  1194.     adi    40H        ;Make the non-control.
  1195.     ani    7fH        ;Modulo 200 octal.
  1196. gtchr8:    lhld    cbfptr        ;Position in character buffer.
  1197.     ora    e        ;Or in the parity bit.
  1198.     mov    m,a        ;Put the char in the buffer.
  1199.     inx    h
  1200.     shld    cbfptr
  1201.     inr    b        ;Increment the char count.
  1202.     jmp    gtchr1        ;Go around again.
  1203.  
  1204. gtchr9:    ;[jd] not enough room left in buffer...
  1205.     lhld    bufpnt
  1206.     dcx    h
  1207.     shld    bufpnt        ;[jd] back up over last character
  1208.     lxi    h,chrcnt    ;[jd] point to character count
  1209.     inr    m        ;[jd] increment it
  1210.     mov    a,b        ;[jd] count of chars transferred
  1211.     jmp    rskp        ;[jd] return it
  1212.  
  1213. gtceof:    mvi    a,0FFH        ;Get a minus one.
  1214.     ret
  1215. ;
  1216. ;    Get the file name (including host to micro translation)
  1217. ;    called by: rfile
  1218.  
  1219. gofil:    lxi    h,data        ;Get the address of the file name.
  1220.     shld    datptr        ;Store the address.
  1221.     lxi    h,fcb+1        ;Address of the FCB.
  1222.     shld    fcbptr        ;Save it.
  1223.     xra    a
  1224.     sta    temp1        ;Initialize the char count.
  1225.     sta    temp2
  1226.     sta    fcb        ;Set the drive to default to current.
  1227.     mvi    b,' '
  1228. gofil1:    mov    m,b        ;Blank the FCB.
  1229.     inx    h
  1230.     inr    a
  1231.     cpi    0CH        ;Twelve?
  1232.     jm    gofil1
  1233. gofil2:    lhld    datptr        ;Get the NAME field.
  1234.     mov    a,m
  1235.     cpi    'a'        ;Force upper case
  1236.     jm    gofl2a        ;
  1237.     ani    5FH        ;
  1238. gofl2a:    inx    h
  1239.     cpi    '.'        ;Seperator?
  1240.     jnz    gofil3
  1241.     shld    datptr        ;[jd] update ptr (moved from above)
  1242.     lxi    h,fcb+9H
  1243.     shld    fcbptr
  1244.     lda    temp1
  1245.     sta    temp2
  1246.     mvi    a,9H
  1247.     sta    temp1
  1248.     jmp    gofil6
  1249.  
  1250. gofil3:    ora    a        ;Trailing null?
  1251.     jz    gofil7        ;Then we're done.
  1252.     shld    datptr        ;[jd] no, can update ptr now.
  1253.     lhld    fcbptr
  1254.     mov    m,a
  1255.     inx    h
  1256.     shld    fcbptr
  1257.     lda    temp1        ;Get the char count.
  1258.     inr    a
  1259.     sta    temp1
  1260.     cpi    8H        ;Are we finished with this field?
  1261.     jm    gofil2
  1262. gofil4:    sta    temp2
  1263.     lhld    datptr
  1264.     mov    a,m
  1265.     inx    h
  1266.     shld    datptr
  1267.     ora    a
  1268.     jz    gofil7
  1269.     cpi    '.'        ;Is this the terminator?
  1270.     jnz    gofil4        ;Go until we find it.
  1271. gofil6:    lhld    datptr        ;Get the TYPE field.
  1272.     mov    a,m
  1273.     cpi    'a'        ;Force upper case
  1274.     jm    gofl6a        ;
  1275.     ani    5FH        ;
  1276. gofl6a:    ora    a        ;Trailing null?
  1277.     jz    gofil7        ;Then we're done.
  1278. ;[jd] move above two lines so we don't increment pointer if char is null
  1279.     inx    h
  1280.     shld    datptr
  1281.     lhld    fcbptr
  1282.     mov    m,a
  1283.     inx    h
  1284.     shld    fcbptr
  1285.     lda    temp1        ;Get the char count.
  1286.     inr    a
  1287.     sta    temp1
  1288.     cpi    0CH        ;Are we finished with this field?
  1289.     jm    gofil6
  1290. gofil7:    lhld    datptr
  1291.     mvi    m,'$'        ;Put in a dollar sign for printing.
  1292.     call    scrfln        ;Position cursor
  1293.     lxi    d,data        ;Print the file name
  1294.     call    prtstr
  1295.     lda    flwflg        ;Is file warning on?
  1296.     ora    a
  1297.     jz    gofil9        ;If not, just proceed.
  1298.     mvi    c,openf        ;See if the file exists.
  1299.     lxi    d,fcb
  1300.     call    bdos
  1301.     cpi    0FFH        ;Does it exist?
  1302.     jz    gofil9        ;If not create it.
  1303.     lxi    d,infms5
  1304.     call    error3
  1305.     lda    temp2        ;Get the number of chars in the file name.
  1306.     ora    a
  1307.     jnz    gofil8
  1308.     lda    temp1
  1309.     sta    temp2
  1310. gofil8:    mvi    b,0
  1311.     mov    d,b        ;Zero d for dad index into filename
  1312.     inr    a        ;Replace next character after filename
  1313.     cpi    9H        ;Is the first field full?
  1314.     jnz    gofl80
  1315.     mvi    b,0FFH        ;Set a flag saying so.
  1316.     dcr    a
  1317. gofl80:    mov    e,a        ;Keep current, replace index in d,e.
  1318. gofl81:    lxi    h,fcb        ;Get the FCB.
  1319.     dad    d        ;Add in the character number.
  1320.     mvi    m,'&'        ;Replace the char with an ampersand.
  1321.     push    b
  1322.     push    d
  1323.     lxi    h,fcb        ;Trim off any CP/M 2.2 attribute bits
  1324.     mvi    c,1+8+3        ;so they do not affect the new file
  1325. gofl82:    mov    a,m        ;
  1326.     ani    7FH        ;
  1327.     mov    m,a        ;
  1328.     inx    h        ;
  1329.     dcr    c        ;
  1330.     jnz    gofl82        ;
  1331.     mvi    c,openf        ;See if the file exists.
  1332.     lxi    d,fcb
  1333.     call    bdos
  1334.     pop    d
  1335.     pop    b
  1336.     cpi    0FFH        ;Does it exist?
  1337.     jz    gofl89        ;If not create it.
  1338.     mov    a,b        ;Get the field-full flag.
  1339.     ora    a        ;Incr. or decr. ?
  1340.     jz    gofl83        ;Jump if increment
  1341.     dcr    e        ;Decrement the number of chars.
  1342.     mov    a,e
  1343.     ora    a
  1344.     jz    gofl88        ;If no more, die.
  1345.     jmp    gofl81
  1346.  
  1347. gofl83:    inr    e        ;Increment the number of chars.
  1348.     mov    a,e
  1349.     cpi    9H        ;Are we to the end?
  1350.     jm    gofl81        ;If not try again.
  1351.     lda    temp2        ;Get the original size.
  1352.     mov    e,a
  1353.     mvi    b,0FFH        ;Set flag saying field-full, decrement
  1354.     jmp    gofl81
  1355.  
  1356. gofl88:    lxi    d,erms16    ;Tell user that we can't rename it.
  1357.     call    prtstr
  1358.     ret
  1359.  
  1360. gofl89: mvi    c,8        ;[jd] # of chars in name
  1361.     lxi    d,fnbuf        ;[jd] point to destination
  1362.     lxi    h,fcb+1        ;[jd] source of name
  1363.     mvi    b,0        ;[jd] first-time-thru flag
  1364. gof89a:    mov    a,m        ;[jd] get a char from the name
  1365.     inx    h        ;[jd] pass it
  1366.     cpi    ' '        ;[jd] end of this part of name?
  1367.     jz    gof89b        ;[jd] yes, skip rest...
  1368.     stax    d        ;[jd] else drop char off
  1369.     inx    d        ;[jd] increment dest ptr
  1370.     dcr    c        ;[jd] decrement count
  1371.     jnz    gof89a        ;[jd] and continue if more to go
  1372. gof89b:    mov    a,b        ;[jd]
  1373.     ora    a        ;[jd] first time thru?
  1374.     jnz    gof89c        ;[jd] no, no period
  1375.     mvi    a,'.'        ;[jd] period between parts
  1376.     stax    d        ;[jd] 
  1377.     inx    d        ;[jd] 
  1378.     mvi    b,0ffh        ;[jd] not first time thru anymore
  1379.     mvi    c,3        ;[jd] length of this part
  1380.     lxi    h,fcb+9        ;[jd] start of extension
  1381.     jmp    gof89a        ;[jd] keep copying
  1382.  
  1383. gof89c:    mvi    a,'$'
  1384.     stax    d        ;[jd] end the name string
  1385.     lxi    d,fnbuf        ;[jd] Print the file name
  1386.     call    prtstr
  1387. gofil9: call    makfil        ; Create the file.
  1388.      jmp    gofl91        ; Disk was full.
  1389.     jmp    rskp        ; Success.
  1390.     
  1391. gofl91:    lxi    d,erms11
  1392.     call    error3
  1393.     ret
  1394. ;
  1395. ;    This is the FINISH command.  It tells the remote KERSRV to exit.
  1396. ;    here from kermit
  1397.  
  1398. finish:    call    cfmcmd
  1399.     xra    a
  1400.     sta    numtry        ;Inititialize count.
  1401.     mvi    a,'1'        ;Reset block check type to single character
  1402.     sta    curchk        ; .  .  .
  1403.  
  1404. finsh1:    lda    numtry        ;How many times have we tried?
  1405.     cpi    maxtry        ;Too many times?
  1406.     jm    finsh3        ;No, try it.
  1407. finsh2:    lxi    d,erms18    ;Say we couldn't do it.
  1408.     call    prtstr
  1409.     jmp    kermit        ;Go home.
  1410.  
  1411. finsh3:    inr    a        ;Increment the number of tries.
  1412.     sta    numtry
  1413.     xra    a
  1414.     sta    argblk        ;Make it packet number zero.
  1415.     mvi    a,1
  1416.     sta    argblk+1    ;One piece of data.
  1417.     lxi    h,data
  1418.     mvi    m,'F'        ;Finish running Kermit.
  1419.     mvi    a,'G'        ;Generic command packet.
  1420.     call    spack
  1421.      jmp    finsh2        ; Tell the user and die.
  1422.     call    rpack        ;Get an acknowledgement.
  1423.      jmp    finsh1        ; Go try again.
  1424.     cpi    'Y'        ;ACK?
  1425.     jz    kermit        ;Yes, we are done.
  1426.     cpi    'E'        ;Is it an error packet?
  1427.     jnz    finsh1        ;Try sending the packet again.
  1428.     call    error1        ;Print the error message.
  1429.     jmp    kermit
  1430. ;
  1431. ;    This is the LOGOUT command.  It tells the remote KERSRV to logout.
  1432. ;    here from: kermit
  1433.  
  1434. logout:    call    cfmcmd
  1435.     call    logo        ;Send the logout packet.
  1436.      jmp    kermit        ;Go get another command
  1437.     jmp    kermit        ; whether we succeed or not.
  1438.  
  1439. ;    do logout processing.
  1440. ;    called by: bye, logout
  1441.  
  1442. logo:    xra    a
  1443.     sta    numtry        ;Inititialize count.
  1444.     mvi    a,'1'        ;Reset block check type to single character
  1445.     sta    curchk        ; .  .  .
  1446.  
  1447. logo1:    lda    numtry        ;How many times have we tried?
  1448.     cpi    maxtry        ;Too many times?
  1449.     jm    logo3        ;No, try it.
  1450. logo2:    lxi    d,erms19    ;Say we couldn't do it.
  1451.     call    prtstr
  1452.     ret            ;Finished.
  1453.  
  1454. logo3:    inr    a        ;Increment the number of tries.
  1455.     sta    numtry
  1456.     xra    a
  1457.     sta    argblk        ;Make it packet number zero.
  1458.     mvi    a,1
  1459.     sta    argblk+1    ;One piece of data.
  1460.     lxi    h,data
  1461.     mvi    m,'L'        ;Logout the remote host.
  1462.     mvi    a,'G'        ;Generic command packet.
  1463.     call    spack
  1464.      jmp    logo2        ; Tell the user and die.
  1465.     call    rpack        ;Get an acknowledgement
  1466.      jmp    logo1        ; Go try again.
  1467.     cpi    'Y'        ;ACK?
  1468.     jz    rskp        ;Yes, we are done.
  1469.     cpi    'E'        ;Is it an error packet?
  1470.     jnz    logo1        ;Try sending the packet again.
  1471.     call    error1        ;Print the error message.
  1472.     ret            ;All done.
  1473. ;
  1474. ;    Packet routines
  1475.  
  1476. ;    Send_Packet
  1477. ;    This routine assembles a packet from the arguments given and sends it
  1478. ;    to the host.
  1479. ;
  1480. ;    Expects the following:
  1481. ;        A     - Type of packet (D,Y,N,S,R,E,F,Z,T)
  1482. ;        ARGBLK     - Packet sequence number
  1483. ;        ARGBLK+1 - Number of data characters
  1484. ;    Returns: nonskip if failure
  1485. ;         skip if success
  1486. ;    called by: read, rinit, rfile, rdata, sinit, sfile, sdata, seof, seot,
  1487. ;           finish, logout, nak, ackp
  1488.  
  1489. spack:    sta    argblk+2
  1490.     lxi    h,packet    ;Get address of the send packet.
  1491.     mvi    a,soh        ;Get the start of header char.
  1492.     mov    m,a        ;Put in the packet.
  1493.     inx    h        ;Point to next char.
  1494.     lda    curchk        ;Get current checksum type
  1495.     sui    '1'        ;Determine extra length of checksum
  1496.     mov    b,a        ;Copy length
  1497.     lda    argblk+1    ;Get the number of data chars.
  1498.     adi    ' '+3        ;Real packet character count made printable.
  1499.     add    b        ;Determine overall length
  1500.     mov    m,a        ;Put in the packet.
  1501.     inx    h        ;Point to next char.
  1502.     lxi    b,0        ;Zero the checksum AC.
  1503.     mov    c,a        ;Start the checksum.
  1504.     lda    argblk        ;Get the packet number.
  1505.     adi    ' '        ;Add a space so the number is printable.
  1506.     mov    m,a        ;Put in the packet.
  1507.     inx    h        ;Point to next char.
  1508.     add    c
  1509.     mov    c,a        ;Add the packet number to the checksum.
  1510.     mvi    a,0        ;Clear A (Cannot be XRA A, since we can't
  1511.                 ; touch carry flag)
  1512.     adc    b        ;Get high order portion of checksum
  1513.     mov    b,a        ;Copy back to B
  1514.     lda    argblk+2    ;Get the packet type.
  1515.     mov    m,a        ;Put in the packet.
  1516.     inx    h        ;Point to next char.
  1517.     add    c
  1518.     mov    c,a        ;Add the packet number to the checksum.
  1519.     mvi    a,0        ;Clear A
  1520.     adc    b        ;Get high order portion of checksum
  1521.     mov    b,a        ;Copy back to B
  1522. spack2:    lda    argblk+1    ;Get the packet size.
  1523.     ora    a        ;Are there any chars of data?
  1524.     jz    spack3        ; No, finish up.
  1525.     dcr    a        ;Decrement the char count.
  1526.     sta    argblk+1    ;Put it back.
  1527.     mov    a,m        ;Get the next char.
  1528.     inx    h        ;Point to next char.
  1529.     add    c
  1530.     mov    c,a        ;Add the packet number to the checksum.
  1531.     mvi    a,0        ;Clear A
  1532.     adc    b        ;Get high order portion of checksum
  1533.     mov    b,a        ;Copy back to B
  1534.     jmp    spack2        ;Go try again.
  1535.  
  1536. spack3:    lda    curchk        ;Get the current checksum type
  1537.     cpi    '2'        ;Two character?
  1538.     jz    spack4        ;Yes, go handle it
  1539.     jnc    spack5        ;No, go handle CRC if '3'
  1540.     mov    a,c        ;Get the character total.
  1541.     ani    0C0H        ;Turn off all but the two high order bits.
  1542.                 ;Shift them into the low order position.
  1543.     rlc            ;Two left rotates same as 6 rights
  1544.     rlc            ; .  .  .
  1545.     add    c        ;Add it to the old bits.
  1546.     ani    3FH        ;Turn off the two high order bits.  (MOD 64)
  1547.     adi    ' '        ;Add a space so the number is printable.
  1548.     mov    m,a        ;Put in the packet.
  1549.     inx    h        ;Point to next char.
  1550.     jmp    spack7        ;Go store eol character
  1551.  
  1552. ;Here for 3 character CRC-CCITT
  1553.  
  1554. spack5:    mvi    m,0        ;Store a null for current end
  1555.     push    h        ;Save H
  1556.     lxi    h,packet+1    ;Point to first checksumed character
  1557.     call    crcclc        ;Calculate the CRC
  1558.     pop    h        ;Restore the pointer
  1559.     mov    c,e        ;Get low order half for later
  1560.     mov    b,d        ;Copy the high order
  1561.     mov    a,d        ;Get the high order portion
  1562.     rlc            ;Shift off low 4 bits
  1563.     rlc            ; .  .  .
  1564.     rlc            ; .  .  .
  1565.     rlc            ; .  .  .
  1566.     ani    0FH        ;Keep only low 4 bits
  1567.     adi    ' '        ;Put into printing range
  1568.     mov    m,a        ;Store the character
  1569.     inx    h        ;Point to next position
  1570.  
  1571. ;Here for two character checksum
  1572.  
  1573. spack4:    mov    a,b        ;Get high order portion
  1574.     ani    0FH        ;Only keep last four bits
  1575.     rlc            ;Shift up two bits
  1576.     rlc            ; . .  .
  1577.     mov    b,a        ;Copy back into safe place
  1578.     mov    a,c        ;Get low order half
  1579.     rlc            ;Shift    high two bits
  1580.     rlc            ;to low two bits
  1581.     ani    03H        ;Keep only two low bits
  1582.     ora    b        ;Get high order portion in
  1583.     adi    ' '        ;Convert to printing character range
  1584.     mov    m,a        ;Store the character
  1585.     inx    h        ;Point to next character
  1586.     mov    a,c        ;get low order portion
  1587.     ani    3FH        ;Keep only six bits
  1588.     adi    ' '        ;Convert to printing range
  1589.     mov    m,a        ;Store it
  1590.     inx    h        ;Bump the pointer
  1591.  
  1592. spack7:    lda    dbgflg
  1593.     ora    a        ; is debugging enabled?
  1594.     jz    spack8
  1595.     push    h        ; yes. save address of end of packet
  1596.     mvi    m,0        ; null-terminate the packet for display
  1597.     call    sppos        ; position cursor
  1598.     lxi    h,packet+1    ; print the packet
  1599.     call    dmptxt
  1600.     pop    h        ; restore address of end of packet
  1601. spack8:    lda    seol        ;Get the EOL the other host wants.
  1602.     mov    m,a        ;Put in the packet.
  1603.     inx    h        ;Point to next char.
  1604.     xra    a        ;Get a null.
  1605.     mov    m,a        ;Put in the packet.
  1606. ;    Write out the packet.
  1607. outpkt:    call    selmdm        ; Set up for output to comm port if iobyt
  1608.     lda    spad        ;Get the number of padding chars.
  1609.     sta    temp1
  1610. outpk2:    lda    temp1        ;Get the count.
  1611.     dcr    a
  1612.     ora    a
  1613.     jm    outpk6        ;If none left proceed.
  1614.     sta    temp1
  1615.     lda    spadch        ;Get the padding char.
  1616.     call    setpar        ;Set parity appropriately
  1617.     mov    e,a        ;Put the char in right AC.
  1618.     call    outmdm        ;Output it.
  1619.     jmp    outpk2
  1620.  
  1621. outpk6:    lxi    h,packet    ; Point to the packet.
  1622. outlup:    mov    a,m        ; Get the next character.
  1623.     ora    a        ; Is it a null?
  1624.     jz    outlud        ; If so return success.
  1625.     call    setpar        ; Set parity for the character
  1626.     mov    e,a        ; Put it in right AC
  1627.     call    outmdm        ; and output it.
  1628. ; TAC trap: If this character is the TAC intercept character, and the TAC
  1629. ; trap is enabled, we have to output it twice.  If the TAC trap is enabled,
  1630. ; tacflg contains the intercept character.  (The current character cannot
  1631. ; be NUL, so we don't have to worry about doubling nulls in the message)
  1632.     lda    tacflg        ; get current intercept character, or zero.
  1633.     cmp    m        ; compare against current data character.
  1634.     jnz    outpk8        ; if different, do nothing.
  1635.     call    setpar        ; match. set appropriate parity,
  1636.     mov    e,a        ;  put it in the right register,
  1637.     call    outmdm        ;  and output it a second time.
  1638. outpk8:
  1639.     inx    h        ; Increment the char pointer.
  1640.     jmp    outlup
  1641.  
  1642. outlud:    call    selcon        ; select console
  1643.     jmp    rskp        ; and return success
  1644. ;
  1645. ;    Receive_Packet
  1646. ;    This routine waits for a packet to arrive from the host.  It reads
  1647. ;    characters until it finds a SOH.  It then reads the packet into packet.
  1648. ;
  1649. ;    Returns:  nonskip if failure (checksum wrong or packet trashed)
  1650. ;       skip if success, with
  1651. ;        A     - message type
  1652. ;        ARGBLK     - message number
  1653. ;        ARGBLK+1 - length of data
  1654. ;    called by: rinit, rfile, rdata,
  1655. ;           sinit, sfile, sdata, seof, seot, finish, logout
  1656.  
  1657. rpack:    call    inpkt        ;Read up to the end-of-line character
  1658.      jmp    r        ; Return bad.
  1659. rpack0:    call    getchr        ;Get a character.
  1660.      jmp    rpack        ; Hit eol;null line;just start over.
  1661.     cpi    soh        ;Is the char the start of header char?
  1662.     jnz    rpack0        ; No, go until it is.
  1663. rpack1:    call    getchr        ;Get a character.
  1664.      jmp    r        ; Hit end of line, return bad.
  1665.     cpi    soh        ;Is the char the start of header char?
  1666.     jz    rpack1        ; Yes, then go start over.
  1667.     sta    packet+1    ;Store in packet also
  1668.     mov    c,a        ;Start the checksum.
  1669.     lda    curchk        ;Get block check type
  1670.     sui    '1'        ;Determine extra length of block check
  1671.     mov    b,a        ;Get a copy
  1672.     mov    a,c        ;Get back length character
  1673.     sui    ' '+3        ;Get the real data count.
  1674.     sub    b        ;Get total length
  1675.     sta    argblk+1
  1676.     mvi    b,0        ;Clear high order half of checksum
  1677.     call    getchr        ;Get a character.
  1678.      jmp    r        ; Hit end of line, return bad.
  1679.     cpi    soh        ;Is the char the start of header char?
  1680.     jz    rpack1        ; Yes, then go start over.
  1681.     sta    argblk
  1682.     sta    packet+2    ;Save also in packet
  1683.     add    c
  1684.     mov    c,a        ;Add the character to the checksum.
  1685.     mvi    a,0        ;Clear A
  1686.     adc    b        ;Get high order portion of checksum
  1687.     mov    b,a        ;Copy back to B
  1688.     lda    argblk
  1689.     sui    ' '        ;Get the real packet number.
  1690.     sta    argblk
  1691.     call    getchr        ;Get a character.
  1692.      jmp    r        ; Hit end of line, return bad.
  1693.     cpi    soh        ;Is the char the start of header char?
  1694.     jz    rpack1        ; Yes, then go start over.
  1695.     sta    temp1        ;Save the message type.
  1696.     sta    packet+3    ;Save in packet
  1697.     add    c
  1698.     mov    c,a        ;Add the character to the checksum.
  1699.     mvi    a,0        ;Clear A
  1700.     adc    b        ;Get high order portion of checksum
  1701.     mov    b,a        ;Copy back to B
  1702.     lda    argblk+1    ;Get the number of data characters.
  1703.     sta    temp2
  1704.     lxi    h,data        ;Point to the data buffer.
  1705.     shld    datptr
  1706. rpack2:    lda    temp2
  1707.     sui    1        ;Any data characters?
  1708.     jm    rpack3        ; If not go get the checksum.
  1709.     sta    temp2
  1710.     call    getchr        ;Get a character.
  1711.      jmp    r        ; Hit end of line, return bad.
  1712.     cpi    soh        ;Is the char the start of header char?
  1713.     jz    rpack1        ; Yes, then go start over.
  1714.     lhld    datptr
  1715.     mov    m,a        ;Put the char into the packet.
  1716.     inx    h        ;Point to the next character.
  1717.     shld    datptr
  1718.     add    c
  1719.     mov    c,a        ;Add the character to the checksum.
  1720.     mvi    a,0        ;Clear A
  1721.     adc    b        ;Get high order portion of checksum
  1722.     mov    b,a        ;Copy back to B
  1723.     jmp    rpack2        ;Go get another.
  1724.  
  1725. rpack3:    call    getchr        ;Get a character.
  1726.      jmp    r        ; Hit end of line, return bad.
  1727.     cpi    soh        ;Is the char the start of header char?
  1728.     jz    rpack1        ; Yes, then go start over.
  1729.     sui    ' '        ;Turn the char back into a number.
  1730.     sta    temp3
  1731. ;Determine type of checksum
  1732.  
  1733.     lda    curchk        ;Get the current checksum type
  1734.     cpi    '2'        ;1, 2 or 3 character?
  1735.     jz    rpack4        ;If zero, 2 character
  1736.     jnc    rpack5        ;Go handle 3 character
  1737.     mov    a,c        ;Get the character total.
  1738.     ani    0C0H        ;Turn off all but the two high order bits.
  1739.                 ;Shift them into the low order position.
  1740.     rlc            ;Two left rotates same as six rights
  1741.     rlc            ; .  .  .
  1742.     add    c        ;Add it to the old bits.
  1743.     ani    3FH        ;Turn off the two high order bits.  (MOD 64)
  1744.     mov    b,a
  1745.     lda    temp3        ;Get the real received checksum.
  1746.     cmp    b        ;Are they equal?
  1747.     jz    rpack7        ;If so, proceed.
  1748. rpack9:    call    updrtr        ;If not, update the number of retries.
  1749.     ret            ;Return error.
  1750.  
  1751. ;Here for three character CRC-CCITT
  1752.  
  1753. rpack5:    lhld    datptr        ;Get the address of the data
  1754.     mvi    m,0        ;Store a zero in the buffer to terminate packet
  1755.     lxi    h,packet+1    ;Point at start of checksummed region
  1756.     call    crcclc        ;Calculate the CRC
  1757.     mov    c,e        ;Save low order half for later
  1758.     mov    b,d        ;Also copy high order
  1759.     mov    a,d        ;Get high byte
  1760.     rlc            ;Want high four bits
  1761.     rlc            ; .  .  .
  1762.     rlc            ;And shift two more
  1763.     rlc            ; .  .  .
  1764.     ani    0FH        ;Keep only 4 bits
  1765.     mov    d,a        ;Back into D
  1766.     lda    temp3        ;Get first value back
  1767.     cmp    d        ;Correct?
  1768.     jnz    rpack9        ;No, punt
  1769.     call    getchr        ;Get a character.
  1770.      jmp    r        ; Hit end of line, return bad.
  1771.     cpi    soh        ;Is the char the start of header char?
  1772.     jz    rpack1        ; Yes, then go start over.
  1773.     sui    ' '        ;Remove space offset
  1774.     sta    temp3        ;Store for later check
  1775.     ;...
  1776.  
  1777. ;Here for a two character checksum and last two characters of CRC
  1778.  
  1779. rpack4:    mov    a,b        ;Get high order portion
  1780.     ani    0FH        ;Only four bits
  1781.     rlc            ;Shift up two bits
  1782.     rlc            ; .  .  .
  1783.     mov    b,a        ;Save back in B
  1784.     mov    a,c        ;Get low order
  1785.     rlc            ;move two high bits to low bits
  1786.     rlc            ; .  .  .
  1787.     ani    03H        ;Save only low two bits
  1788.     ora    b        ;Get other 4 bits
  1789.     mov    b,a        ;Save back in B
  1790.     lda    temp3        ;Get this portion of checksum
  1791.     cmp    b        ;Check first half
  1792.     jnz    rpack9        ;If bad, go give up
  1793.     call    getchr        ;Get a character.
  1794.      jmp    r        ; Hit end of line, return bad.
  1795.     cpi    soh        ;Is the char the start of header char?
  1796.     jz    rpack1        ; Yes, then go start over.
  1797.     sui    ' '        ;Remove space offset
  1798.     mov    b,a        ;Save in safe place
  1799.     mov    a,c        ;Get low 8 bits of checksum
  1800.     ani    3FH        ;Keep only 6 bits
  1801.     cmp    b        ;Correct value
  1802.     jnz    rpack9        ;Bad, give up
  1803. rpack7:    lhld    datptr
  1804.     mvi    m,0        ;Put a null at the end of the data.
  1805.     lda    temp1        ;Get the type.
  1806.     jmp    rskp
  1807. ;
  1808. ;    inpkt - receive and buffer packet
  1809. ;    returns: nonskip if error (timeout)
  1810. ;        skip if success; packet starts at recpkt (which holds the SOH)
  1811. ;          and is terminated by a null.
  1812. ;        console is selected in either case.
  1813. ;    called by: rpack
  1814.  
  1815. inpkt:    lxi    h,recpkt    ;Point to the beginning of the packet.
  1816.     shld    pktptr
  1817. inpkt1:    call    inchr        ;Get first character
  1818.     jmp    r        ;Return failure
  1819.     cpi    soh        ;is it the beginning of a packet?
  1820.     jnz    inpkt1        ;if not, ignore leading junk
  1821.     jmp    inpkt3        ;else go put it in packet
  1822.  
  1823. inpkt2:    call    inchr        ;Get a character.
  1824.      jmp    r        ; Return failure.
  1825.     cpi    soh        ;is it a new beginning of packet?
  1826.     jnz    inpkt3        ;if not continue
  1827.     lxi    h,recpkt    ;else throw away what we've got so far
  1828.     shld    pktptr        ;
  1829. inpkt3:    lhld    pktptr        ;
  1830.     mov    m,a        ;Put the char in the packet.
  1831.     inx    h
  1832.     shld    pktptr
  1833.     mov    b,a
  1834.     lxi    d,-recpkx    ;Start over if packet buffer overflow
  1835.     dad    d        ;
  1836.     jc    inpkt        ;
  1837.     lda    reol        ;Get the EOL char.
  1838.     cmp    b
  1839.     jnz    inpkt2        ;If not loop for another.
  1840.     ;...
  1841.  
  1842. ;Begin IBM change/fdc
  1843. ;This moved from OUTPK7 -- it appears that waiting until we're
  1844. ;ready to send a packet before looking for turnaround character
  1845. ;is long enough for it to get lost.  Better to look now.
  1846.  
  1847.     lda    ibmflg        ;Is this the IBM?
  1848.     ora    a
  1849.     jz    inpkt6        ;If not then proceed.
  1850.     lda    state        ;Check if this is the Send-Init packet.
  1851.     cpi    'S'
  1852.     jz    inpkt6        ;If so don't wait for the XON.
  1853. inpkt5:    call    inchr        ;Wait for the turn around char.
  1854.      jmp    inpkt6
  1855.     cpi    xon        ;Is it the IBM turn around character?
  1856.     jnz    inpkt5        ;If not, go until it is.
  1857. inpkt6:    lhld    pktptr        ;Reload packet pointer
  1858. ;End IBM change/fdc.
  1859.     dcx    h        ;Back up to end of line character
  1860.     mvi    m,0        ;Replace it with a null to stop rpack:
  1861.     call    selcon        ;We've got the packet. Return to console.
  1862.  
  1863.     lda    dbgflg        ; Is debugging enabled?
  1864.     ora    a
  1865.     jz    inpkt7
  1866.     inx    h        ; Point to next char.
  1867.     call    rppos        ; position cursor
  1868.     lxi    h,recpkt+1    ; print the packet
  1869.     call    dmptxt
  1870. inpkt7:    lxi    h,recpkt
  1871.     shld    pktptr        ;Save the packet pointer.
  1872.     jmp    rskp        ;If so we are done.
  1873.  
  1874. ;    getchr - get next character from buffered packet.
  1875. ;    returns nonskip at end of packet.
  1876. ;    called by: rpack
  1877.  
  1878. getchr:    lhld    pktptr        ;Get the packet pointer.
  1879.     mov    a,m        ;Get the char.
  1880.     inx    h
  1881.     shld    pktptr
  1882.     ora    a        ;Is it the null we put at the end of the packet?
  1883.     jnz    rskp        ;If not return retskp.
  1884.     ret            ;If so return failure.
  1885. ;
  1886. ;
  1887. ;    inchr - character input loop for file transfer
  1888. ;    returns: nonskip if timeout or character typed on console
  1889. ;            (console selected)
  1890. ;        skip with character from modem in A (parity stripped
  1891. ;            if necessary; modem selected)
  1892. ;        preserves bc, de, hl in either case.
  1893. ;    called by: inpkt
  1894.  
  1895. inchr:    push    h        ; save hl and bc
  1896.     push    b
  1897.     lhld    timout        ;Get initial value for timeout
  1898.     shld    timval        ;[jd] 
  1899. inchr0:    call    selmdm        ;select modem
  1900.     call    inpmdm        ;Try to get a character from the modem
  1901.     ora    a
  1902.     jz    inchr2        ;if zero, nothing there.
  1903.     mov    b,a
  1904.     lda    parity        ;Is the parity none?
  1905.     cpi    parnon
  1906.     mov    a,b
  1907.     jz    inchr1        ;If so just return.
  1908.     ani    7FH        ;Turn off the parity bit.
  1909. inchr1:    pop    b        ;restore registers
  1910.     pop    h
  1911.     jmp    rskp        ;take skip return, character in A
  1912.  
  1913. inchr2:    call    selcon        ;select console
  1914.     call    inpcon        ; Try to get a character from the console
  1915.     ora    a
  1916.     jz    inchr6        ;If not go do timer thing
  1917.     cpi    cr        ;Is it a carriage return?
  1918.     jz    inchr4        ;If so return
  1919.     cpi    ('Z'-100O)    ;Control-Z?
  1920.     jz    inchr5        ;Yes, go flag it
  1921.     cpi    ('C'-100O)    ;Control-C?
  1922.     jz    inchr7        ;re-enter, he wants to get out
  1923.     cpi    ('X'-100O)    ;Control-X?
  1924.     jnz    inchr6        ;No, ignore it. do timer thing.
  1925. inchr5:    adi    100O        ;Convert to printing range
  1926.     sta    czseen        ;Flag we saw a control-Z
  1927. inchr4:    pop    b        ; restore registers
  1928.     pop    h
  1929.     ret            ;And return
  1930.  
  1931. inchr6:    lda    timflg        ;[jd] pick up timer flag
  1932.     ora    a        ;[jd] are we allowed to use timer?
  1933.     jz    inchr0        ;[jd] no, don't time out
  1934.     lhld    timval        ; decrement fuzzy time-out
  1935.     dcx    h        ;
  1936.     shld    timval        ;((timout-1) * loop time)
  1937.     mov    a,h        ;(Retry if not time-out)
  1938.     ora    l        ;
  1939.     jnz    inchr0        ;
  1940.     call    updrtr        ;Count as retry (?)
  1941.     pop    b        ;restore registers
  1942.     pop    h
  1943.     ret            ;and return to do retry
  1944.  
  1945. inchr7:    call    clrtop        ;[hh] clear screen and home cursor
  1946.     jmp    kermit        ;[hh] then re-enter kermit
  1947.  
  1948. ;
  1949. ;    CRCCLC - Routine to calculate a CRC-CCITT for a string.
  1950. ;
  1951. ;    This routine will calculate a CRC using the CCITT polynomial for
  1952. ;    a string.
  1953. ;
  1954. ;    call with: HL/ Address of null-terminated string
  1955. ;    16-bit CRC value is returned in DE.
  1956. ;    Registers BC and HL are preserved.
  1957. ;
  1958. ;    called by: spack, rpack
  1959.  
  1960. crcclc:    push    h        ;Save HL
  1961.     push    b        ;And BC
  1962.     lxi    d,0        ;Initial CRC value is 0
  1963.  
  1964. crccl0:    mov    a,m        ;Get a character
  1965.     ora    a        ;Check if zero
  1966.     jz    crccl1        ;If so, all done
  1967.     push    h        ;Save the pointer
  1968.     xra    e        ;Add in with previous value
  1969.     mov    e,a        ;Get a copy
  1970.     ani    0FH        ;Get last 4 bits of combined value
  1971.     mov    c,a        ;Get into C
  1972.     mvi    b,0        ;And make high order zero
  1973.     lxi    h,crctb2    ;Point at low order table
  1974.     dad    b        ;Point to correct entry
  1975.     dad    b        ; .  .  .
  1976.     push    h        ;Save the address
  1977.     mov    a,e        ;Get combined value back again
  1978.     rrc            ;Shift over to make index
  1979.     rrc            ; .  .  .
  1980.     rrc            ; .  .  .
  1981.     ani    1EH        ;Keep only 4 bits
  1982.     mov    c,a        ;Set up to offset table
  1983.     lxi    h,crctab    ;Point at high order table
  1984.     dad    b        ;Correct entry
  1985.     mov    a,m        ;Get low order portion of entry
  1986.     xra    d        ;XOR with previous high order half
  1987.     inx    h        ;Point to high order byte
  1988.     mov    d,m        ;Get into D
  1989.     pop    h        ;Get back pointer to other table entry
  1990.     xra    m        ;Include with new high order half
  1991.     mov    e,a        ;Copy new low order portion
  1992.     inx    h        ;Point to other portion
  1993.     mov    a,m        ;Get the other portion of the table entry
  1994.     xra    d        ;Include with other high order portion
  1995.     mov    d,a        ;Move back into D
  1996.  
  1997.     pop    h        ;And H
  1998.     inx    h        ;Point to next character
  1999.     jmp    crccl0        ;Go get next character
  2000.  
  2001. crccl1:    pop    b        ;Restore B
  2002.     pop    h        ;And HL
  2003.  
  2004.     ret            ;And return, DE=CRC-CCITT
  2005.  
  2006. CRCTAB:    DW    00000H
  2007.     DW    01081H
  2008.     DW    02102H
  2009.     DW    03183H
  2010.     DW    04204H
  2011.     DW    05285H
  2012.     DW    06306H
  2013.     DW    07387H
  2014.     DW    08408H
  2015.     DW    09489H
  2016.     DW    0A50AH
  2017.     DW    0B58BH
  2018.     DW    0C60CH
  2019.     DW    0D68DH
  2020.     DW    0E70EH
  2021.     DW    0F78FH
  2022.  
  2023. CRCTB2:    DW    00000H
  2024.     DW    01189H
  2025.     DW    02312H
  2026.     DW    0329BH
  2027.     DW    04624H
  2028.     DW    057ADH
  2029.     DW    06536H
  2030.     DW    074BFH
  2031.     DW    08C48H
  2032.     DW    09DC1H
  2033.     DW    0AF5AH
  2034.     DW    0BED3H
  2035.     DW    0CA6CH
  2036.     DW    0DBE5H
  2037.     DW    0E97EH
  2038.     DW    0F8F7H
  2039. ;
  2040. ;    This is where we go if we get an error during a protocol communication.
  2041. ;    error prints the error packet on line 6 or so, and aborts the
  2042. ;    transfer.
  2043. ;      called by: rinit, rfile, rdata, sinit, sfile, sdata, seof, seot
  2044. ;    error1 print CRLF followed by the error packet.
  2045. ;      called by: finish, logout
  2046. ;    error2 just prints the error packet.
  2047. ;    error3 positions cursor and prints error message specified in DE.
  2048. ;      called by: rinit, rfile, rdata, sinit, sfile, sdata, seof,
  2049. ;             seot, parwrn, gofil, outbuf
  2050.  
  2051. error:    call    screrr        ;Position the cursor.
  2052.     mvi    a,'A'        ;Set the state to abort.
  2053.     sta    state
  2054.     jmp    error2
  2055.  
  2056. error1:    lxi    d,crlf        ;Print a CRLF.
  2057.     call    prtstr
  2058. error2:    lda    argblk+1    ;Get the length of the data.
  2059.     mov    c,a
  2060.     mvi    b,0        ;Put it into BC
  2061.     lxi    h,data        ;Get the address of the data.
  2062.     dad    b        ;Get to the end of the string.
  2063.     mvi    a,'$'        ;Put a dollar sign at the end.
  2064.     mov    m,a
  2065.     lxi    d,data        ;Print error message
  2066.     call    prtstr
  2067.     ret
  2068.  
  2069. error3:    push    d        ;Save the pointer to the message.
  2070.     call    screrr        ;Position the cursor.
  2071.     pop    d        ;Get the pointer back.
  2072.     call    prtstr        ;Print error message
  2073.     ret
  2074. ;
  2075. ;    Set up for file transfer.
  2076. ;    called by read, send.
  2077.  
  2078. init:    lxi    d,version    ; point at Kermit's version string
  2079.     call    sysscr        ; fix up screen
  2080.     call    selmdm        ; select modem
  2081.     call    flsmdm        ; purge any pending data
  2082.     call    selcon        ; select console again.
  2083.     ret
  2084.  
  2085. ;    Set state to ABORT
  2086. ;    called by: rinit, rfile, rdata, sinit, sfile, sdata, seof, seot,
  2087. ;           nak, ackp
  2088.  
  2089. abort:    mvi    a,'A'        ;Otherwise abort.
  2090.     sta    state
  2091.     ret
  2092.  
  2093. ;    nak - send NAK packet
  2094. ;    here from: rinit, rfile, rdata
  2095. ;    nak0 - update retry count and send NAK packet
  2096. ;    here from: rinit, rfile, rdata, tryagn
  2097.  
  2098. nak0:    call    updrtr        ;Update number of retries.
  2099. nak:    lda    pktnum        ;Get the packet number we're waiting for.
  2100.     sta    argblk
  2101.     xra    a        ;No data.
  2102.     sta    argblk+1
  2103.     mvi    a,'N'        ;NAK that packet.
  2104.     call    spack
  2105.      jmp    abort        ; Give up.
  2106.     ret            ;Go around again.
  2107.  
  2108. ;    increment and display retry count
  2109. ;    called by: rfile, sinit, sfile, sdata, seof, seot,
  2110. ;           nak, rpack, inchr, tryagn
  2111.  
  2112. updrtr:    call    scrnrt        ;Position cursor
  2113.     lhld    numrtr
  2114.     inx    h        ;Increment the number of retries
  2115.     shld    numrtr
  2116.     call    nout        ;Write the number of retries.
  2117.     ret
  2118.  
  2119. ;    [jd] this routine prints parity warnings.  All registers are
  2120. ;    saved except for a.
  2121. ;    called by: sdata
  2122.  
  2123. parwrn:    push    b
  2124.     push    d
  2125.     push    h
  2126.     lxi    d,inms25
  2127.     call    error3
  2128.     pop    h
  2129.     pop    d
  2130.     pop    b
  2131.     ret
  2132. ;[jd] end of addition
  2133.  
  2134. ;    print message in status field.  address of message is in DE.
  2135. ;    called by: read, send
  2136.  
  2137. finmes:    push    d        ;Save message.
  2138.     call    scrst        ;Position cursor
  2139.     pop    d        ;Print the termination message
  2140.     call    prtstr
  2141.     call    scrend        ;Position cursor for prompt
  2142.     ret
  2143.  
  2144. ;    Compare expected packet number against received packet number.
  2145. ;    return with flags set (Z = packet number valid)
  2146. ;    called by: rfile, rdata, sinit, sfile, sdata, seof, seot
  2147.  
  2148. compp:    lda    pktnum        ;Get the packet Nr.
  2149.     mov    b,a
  2150.     lda    argblk
  2151.     cmp    b
  2152.     ret
  2153.  
  2154. ;    Increment the packet number, modulo 64.
  2155. ;    called by: rinit, rfile, rdata, sinit, sfile, sdata, seof, seot
  2156.  
  2157. countp:    inr    a        ;Increment packet Nr.
  2158.     ani    3FH        ;Turn off the two high order bits
  2159.     sta    pktnum        ;Save modulo 64 of number
  2160.     lhld    numpkt
  2161.     inx    h        ;Increment Nr. of packets
  2162.     shld    numpkt
  2163.     ret
  2164.  
  2165. ;    Send an ACK-packet
  2166. ;    called by: rfile, rdata, tryagn
  2167.  
  2168. ackp:    xra    a
  2169.     sta    numtry        ;Reset number of retries
  2170.     sta    argblk+1    ;No data. (The packet number is in argblk)
  2171.     mvi    a,'Y'        ;Acknowledge packet
  2172.     call    spack        ;Send packet
  2173.      jmp    abort
  2174.     ret
  2175.  
  2176. ;    ?
  2177. ;    called with A/ current retry count
  2178. ;    called by: rfile, rdata
  2179.  
  2180. tryagn:    inr    a        ;Increment it.
  2181.     sta    oldtry        ;Save the updated number of tries.
  2182.     lda    pktnum        ;Get the present packet number.
  2183.     dcr    a        ;Decrement
  2184.     ani    3FH        ; modulo 64
  2185.     mov    b,a
  2186.     lda    argblk        ;Get the packet's number
  2187.     cmp    b        ;Is the packet's number one less than now?
  2188.     jnz    nak0        ;No, NAK it and try again.
  2189.     call    updrtr        ;Update the number of retries.
  2190.     call    ackp
  2191.     ret
  2192.  
  2193. ;    Output a null-terminated string to the console.  We assume that the
  2194. ;    console has been selected.  Called with HL = address of string.
  2195. ;    called by: spack, inpkt
  2196.  
  2197. dmptxt:    mov    a,m        ; get character from string
  2198.     ora    a
  2199.     rz            ; done if null
  2200.     push    h        ; save string address
  2201.     mov    e,a        ; move character to E for outcon
  2202.     call    outcon        ; output character to console
  2203.     pop    h        ; restore string address
  2204.     inx    h        ; point past printed character
  2205.     jmp    dmptxt        ; go output rest of string
  2206. ;
  2207. IF lasm
  2208.     LINK    CP4TT
  2209. ENDIF;lasm
  2210.