home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-UR13.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  50KB  |  1,168 lines
  1.           Title     'MEX overlay for the U.S. Robotics (S-100) 1.3'
  2. ;
  3. ;
  4. ;
  5. REV       EQU       13                  ;overlay revision level
  6. ;
  7. ; MEX OVERLAY VERSION 1.3: mods by Jesse Eaton on 10/14/84
  8. ;                                Cleaned up break to prevent garbage after brk.
  9. ;                                Fixed bug in parity logic.  The call to
  10. ;                                PARITV: restores parity mode in SIO to its
  11. ;                                value prior to a call to NOPARV:.
  12. ;                                Call to NOPARV: is transparent to SET cmd.
  13. ;         NOTE: If parity is incorrect it can cause no response to initial
  14. ;               NAK for R mode file transfers resulting in timeouts.
  15. ;               Incorrect parity can also cause incorrect header # error.
  16. ;               Normally parity = none should be specified.
  17. ;
  18. ; MEX OVERLAY VERSION 1.2: mods by Jesse Eaton on 10/11/84
  19. ;                                corrected error when dialing from library
  20. ;                                 with auto baud setting.
  21. ;                                corrected bugs in SET command and expanded it's
  22. ;                                 functionality to include auto answer tone and
  23. ;                                 answer on ring #. 
  24. ;                                SET now allows parity bit setting.
  25. ;                                SET now also allows setting full/half duplex.
  26. ;         NOTE: The manual answer logic via "ATA" command and parity setting
  27. ;               from outside the SET command may need additional work.
  28. ;               Also note that you can add the S10 register in INITMSG:
  29. ;               IF your ROM chip set supports it.  Older versions did not.
  30. ;               My USR S-100 modem is connected on a line with "call waiting"
  31. ;               and will drop carrier if an incoming call generates the
  32. ;               call waiting beep tone.  I got a newer ROM (U3 A7.9) and tried
  33. ;               to keep the carrier on by setting S10=255.  It did not help
  34. ;               me but it might help you on a different phone system. Older
  35. ;               ROM versions will not generate a response (0-5 or Verbose) if
  36. ;               any unrecognized "AT" commands sush as "ATH" or "S10" are
  37. ;               are issued to the modem.  You can test them in Terminal mode.
  38. ;               Unknown commands are merely ignored instead of hanging the
  39. ;               modem with newer proms.
  40. ;
  41. ;         REQUEST: If you can shed light on any of the above comments or
  42. ;                    this overlay in general I can be contacted via Arpanet
  43. ;                    mail.  My address is Eaton.HFED @ HI-MULTICS.
  44. ;
  45. ;
  46. ; MEX OVERLAY VERSION 1.1: mods to break routine 10/10/84 by Jesse Eaton
  47. ;                                added help ? msg to SET command
  48. ;
  49. ; MEX OVERLAY VERSION 1.0: written 04/27/84 by Ron Fowler
  50. ; U.S.Robotics Version 1.0: written 08/11/84 by Ray Broz & Mike Smith
  51. ;
  52. ; This overlay is a combination of Ron's PMMI and Smart Modem Overlays
  53. ; with the required changes to make it work with the U.S. Robotics S-100
  54. ; autodial modem.
  55. ; 
  56. ;------------------------------------------------------------
  57. ;
  58. ; Misc equates
  59. ;
  60. NO        EQU       0
  61. YES       EQU       NOT NO
  62. TPA       EQU       100H
  63. NULL      EQU       0
  64. CR        EQU       0DH
  65. LF        EQU       0AH
  66. TAB       EQU       09H
  67. BELL      EQU       07H
  68.  
  69. MAXWAIT EQU         60                  ;maximum time to wait for connection
  70. CLRSCN    EQU       YES                 ;set yes to use clear screen commands
  71. ANSRNG    EQU       '3'                 ;SET RING default 1-9 (answer on ring #)
  72. S10       EQU       YES                 ;S10 can be used with newer model modems
  73.                                         ;see note above. (older ROM versions will
  74.                                         ;hang if this register is used)
  75. ;
  76. ; US Robotics port definitions
  77. ;
  78. PORT      EQU       30H                 ;US Robotics base port 
  79. MDMCOM    EQU       PORT+1              ;modem command port
  80. MDMMOD    EQU       PORT+1              ;modem mode port
  81. MDMSTS    EQU       PORT+1              ;modem status port
  82. MDMDAT    EQU       PORT                ;modem data port
  83. ;
  84. ; US Robotics bit definitions
  85. ;
  86. MDRCVB    EQU       00000010B ;modem receive bit 
  87. MDRCVR    EQU       00000010B ;modem receive ready bit 
  88. MDSNDB    EQU       00000001B ;modem send bit 
  89. MDSNDR    EQU       00000001B ;modem send ready bit 
  90. OPARIT    EQU       00010000B ;odd-parity bits
  91. EPARIT    EQU       00110000B ;even-parity bits
  92. NPARIT    EQU       00000000B ;no-parity bits
  93. ;
  94. ; US Robotics masks (v1.2 je)
  95. ; 
  96. XMITRDY   EQU       00000001B ;mask for transmit ready
  97. BRKMSK    EQU       00001000B ;mask to set break
  98. PARMSK    EQU       11001111B ;mask to remove parity bits
  99. BDMSKL    EQU       01111100B ;mask for baudrate bits in mode (v1.2 je)
  100. BDMSKH    EQU       11011111B ;mask for baudrate bits in command
  101. CARMSK    EQU       10000000B ;carrier present mask         
  102. INMODE    EQU       01001110B ;initial mode word
  103. INCOMM    EQU       00110111B ;initial command word
  104. ;
  105. ;         
  106. ; Modem control command words
  107. ;
  108. CLEAR     EQU       'Z'                 ;idle mode
  109. ANMODE    EQU       'A'                 ;answer mode
  110. ORIGMD    EQU       'Z'                 ;originate mode
  111. RESET     EQU       40H                 ;usart reset
  112. ;
  113. ;
  114. ; MEX service processor stuff 
  115. ;
  116. MEX       EQU       0D00H               ;address of the service processor
  117. INMDM     EQU       255                 ;get char from port to A
  118. TIMER     EQU       254                 ;delay 100ms * reg B
  119. TMDINP    EQU       253                 ;B=# secs to wait for char
  120. CHEKCC    EQU       252                 ;check for ^C from KBD
  121. SNDRDY    EQU       251                 ;test for modem-send ready
  122. RCVRDY    EQU       250                 ;test for modem-receive ready
  123. SNDCHR    EQU       249                 ;send a character to the modem 
  124. RCVCHR    EQU       248                 ;recv a char from modem 
  125. LOOKUP    EQU       247                 ;table search
  126. PARSFN    EQU       246                 ;parse filename from input stream
  127. BDPARS    EQU       245                 ;parse baud-rate from input stream
  128. SBLANK    EQU       244                 ;scan input stream to next non-blank
  129. EVALA     EQU       243                 ;evaluate numeric from input stream
  130. LKAHED    EQU       242                 ;get nxt char w/o removing from input
  131. GNC       EQU       241                 ;get char from input
  132. ILP       EQU       240                 ;inline print
  133. DECOUT    EQU       239                 ;decimal output
  134. PRBAUD    EQU       238                 ;print baud rate
  135. ;
  136. ;
  137. CONOUT    EQU       2                   ;simulated BDOS function 2
  138. PRINT     EQU       9                   ;simulated BDOS function 9
  139. INBUF     EQU       10                  ;simulated BDOS function 10
  140. ;
  141.           ORG       TPA                 ;we begin
  142. ;
  143. ;
  144.           DS        3                   ;MEX has a JMP START here
  145. ;
  146. ; The following variables are located at the beginning of the program
  147. ; to facilitate modification without the need of re-assembly. They will
  148. ; be moved in MEX 2.0.
  149. ; The PMMI DB's are REQUIRED to maintain compatabilty with MEX.
  150. ;
  151. PMODEM:   DB        NO                  ;yes=PMMI modem \ / These 2 locations are 
  152. SMODEM:   DB        YES                 ;yes=Smartmodem / \ not referenced by MEX
  153. TPULSE:   DB        'T'                 ;T=touch, P=pulse (not referenced by MEX)
  154. CLOCK:    DB        40                  ;clock speed x .1, up to 25.5 mhz.
  155. MSPEED:   DB        5                   ;sets display time for sending a file
  156.                                         ;0=110    1=300  2=450  3=600  4=710
  157.                                         ;5=1200 6=2400 7=4800 8=9600 9=19200
  158. BYTDLY:   DB        5                   ;default time to send character in
  159.                                         ;terminal mode file transfer (0-9)
  160.                                         ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  161. CRDLY:    DB        5                   ;end-of-line delay after CRLF in terminal
  162.                                         ;mode file transfer for slow BBS systems
  163.                                         ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  164. COLUMS:   DB        5                   ;number of directory columns
  165. SETFL:    DB        YES                 ;yes=user-defined SET command
  166. SCRTST:   DB        NO                  ;yes=if home cursor and clear screen
  167.                                         ;routine at CLRSCRN
  168.           DB        0                   ;spare
  169. BAKFLG:   DB        YES                 ;yes=make .BAK file
  170. CRCDFL:   DB        NO                  ;yes=default to CRC checking
  171.                                         ;no=default to Checksum checking
  172. TOGCRC:   DB        YES                 ;yes=allow toggling of Checksum to CRC
  173. CVTBS:    DB        NO                  ;yes=convert backspace to rub
  174. TOGLBK:   DB        YES                 ;yes=allow toggling of bksp to rub
  175. ADDLF:    DB        NO                  ;no=no LF after CR to send file in
  176.                                         ;terminal mode (added by remote echo)
  177. TOGLF:    DB        YES                 ;yes=allow toggling of LF after CR
  178. TRNLOG:   DB        NO                  ;yes=allow transmission of logon
  179.                                         ;write logon sequence at location LOGON
  180. SAVCCP:   DB        YES                 ;yes=do not overwrite CCP
  181. LOCNXT:   DB        NO                  ;yes=local cmd if EXTCHR precedes
  182.                                         ;no=not local cmd if EXTCHR precedes
  183. TOGLOC:   DB        YES                 ;yes=allow toggling of LOCNXTCHR
  184. LSTTST:   DB        YES                 ;yes=allow toggling of printer on/off
  185.                                         ;in terminal mode. Set to no if using
  186.                                         ;the printer port for the modem
  187. XOFTST:   DB        NO                  ;yes=allow testing of XOFF from remote
  188.                                         ;while sending a file in terminal mode
  189. XONWT:    DB        NO                  ;yes=wait for XON after sending CR while
  190.                                         ;transmitting a file in terminal mode   
  191. TOGXOF:   DB        YES                 ;yes=allow toggling of XOFF testing
  192. IGNCTL:   DB        YES                 ;yes=do not send control characters
  193.                                         ;above CTL-M to CRT in terminal mode
  194.                                         ;no=send any incoming CTL-char to CRT
  195. EXTRA1:   DB        0                   ;for future expansion
  196. EXTRA2:   DB        0                   ;for future expansion
  197. BRKCHR:   DB        '@'-40H             ;^@ = Send a 300 ms. break tone
  198. NOCONN:   DB        'N'-40H             ;^N = Disconnect from phone line
  199. LOGCHR:   DB        'L'-40H             ;^L = Send logon
  200. LSTCHR:   DB        'P'-40H             ;^P = Toggle printer
  201. UNSVCH:   DB        'R'-40H             ;^R = Close input text buffer
  202. TRNCHR:   DB        'T'-40H             ;^T = Transmit file to remote
  203. SAVCHR:   DB        'Y'-40H             ;^Y = Open input text buffer
  204. EXTCHR:   DB        '^'-40H             ;^^ = Send next character
  205. ;
  206. ; Equates used only by PMMI routines grouped together here.
  207. ;
  208. PRATE:    DB        250
  209.           DB        0
  210. ;
  211. ; Low-level modem I/O routines: this will be replaced with
  212. ; a jump table in MEX 2.0 (you can insert jumps here to longer
  213. ; routines if you'd like ... I'd recommend NOT putting part of
  214. ; a routine in this area, then jumping to the rest of the routine
  215. ; in the non-fixed area; that will complicate the 2.0 conversion)
  216. ;
  217. INCTL1:   IN        MDMSTS              ;in modem control port
  218.           RET
  219.           DB        0,0,0,0,0,0,0       ;spares if needed 
  220. ;
  221. OTDATA:   OUT       MDMDAT              ;out modem data port
  222.           RET
  223.           DB        0,0,0,0,0,0,0       ;spares if needed 
  224. ;
  225. INPORT:   IN        MDMDAT              ;in modem data port
  226.           RET
  227.           DB        0,0,0,0,0,0,0       ;spares if needed 
  228. ;
  229. ; Bit-test routines.  These will be merged with the above
  230. ; routines in MEX 2.0 to provide a more reasonable format
  231. ;
  232. MASKR:    ANI MDRCVB ! RET    ;bit to test for receive ready
  233. TESTR:    CPI MDRCVR ! RET    ;value of receive bit when ready
  234. MASKS:    ANI MDSNDB ! RET    ;bit to test for send ready
  235. TESTS:    CPI MDSNDR ! RET    ;value of send bit when ready
  236. ;
  237. ;
  238. ; Unused area: was once used for special PMMI functions,
  239. ; Now used only to retain compatibility with MDM overlays.
  240. ; You may use this area for any miscellaneous storage you'd
  241. ; like but the length of the area *must* be 12 bytes.
  242. ;
  243.           DS        12
  244. ;
  245. ; Special modem function jump table: 
  246. ;
  247. LOGON:    DS        2                   ;needed for MDM compatability
  248. DIALV:    JMP       PDIAL               ;dial digit in A 
  249. DISCV:    JMP       PDISC               ;disconnect the modem
  250. GOODBV:   JMP       DUMMY               ;called before exit to CP/M
  251. INMODV:   JMP       DUMMY               ;initialization
  252. NEWBDV:   JMP       PBAUD               ;set baud rate
  253. NOPARV:   JMP       NOPAR               ;set modem for no-parity
  254.                                         ;this call is transparent to SET cmd (je)
  255. PARITV:   JMP       PARITY              ;set modem parity
  256.                                         ;to value prior to nopar call (je)
  257. SETUPV:   JMP       SETCMD              ;SET cmd:
  258. SPMENV:   DS        3                   ;not used with MEX
  259. VERSNV:   JMP       SYSVER              ;sign-on message
  260. BREAKV:   JMP       PBREAK              ;send a break
  261. ;
  262. ; For MEX 2.0 compatibility, you should not try to use these
  263. ; routines, since this table will go away with MEX 2.0 (use the MEX
  264. ; service call processor instead).
  265. ;
  266. ILPRTV:   DS        3                   ;replace with MEX function 9 (WHAT IS THIS?)
  267. INBUFV:   DS        3                   ;replace with MEX function 10 (AND THIS?)
  268. ILCMPV:   DS        3                   ;replace with MEX function 247
  269. INMDMV:   DS        3                   ;replace with MEX function 255
  270. NXSCRV:   DS        3                   ;not supported by MEX 
  271. TIMERV:   DS        3                   ;replace with MEX function 254
  272. ;
  273. ;
  274. ; Clear/screen and clear/end-of-screen. Each routine must use the
  275. ; full 9 bytes alloted (may be padded with nulls).
  276. ;
  277. CLREOS:   LXI       D,EOSMSG            ;clear to end of screen
  278.           MVI       C,PRINT
  279.           CALL      MEX
  280.           RET
  281. ;
  282. ;
  283. CLS:      LXI       D,CLSMSG            ;clear screen
  284.           MVI       C,PRINT
  285.           CALL      MEX
  286.           RET
  287. ;
  288. ; strings to clear-to-end-of-screen, and clear-screen (VISUAL 55/VT52)
  289.  
  290. EOSMSG:   DB        1BH,'k','$'         ;clear to end-of-screen (je)
  291. CLSMSG:   DB        1BH,'v','$'         ;clear whole screen (je)
  292.  
  293. ;
  294. ;
  295. ; Modem initialization.  
  296. ;
  297. NOAT:     MVI       A,0FFH                        ;set for 8251 initialization only
  298.           STA       ONLYSIO                       ;"AT" commands are not sent
  299.           CALL      CURRNT
  300.           XRA       A                             ;reset onlysio
  301.           STA       ONLYSIO
  302.           RET
  303.           
  304. NITMOD:   LXI       H,COMMND            ;
  305.           MVI       M,INMODE            ;store modem setup                      
  306.           INX       H                             ;for future reference
  307.           MVI       M,INCOMM
  308.  
  309. CURRNT:   MVI       A,NULL                        ;entry point to resend
  310.           OUT       MDMMOD                        ;modem command and mode
  311.           OUT       MDMCOM                        ;words    
  312.           OUT       MDMMOD                        ;clear command register
  313.           MVI       A,RESET
  314.           OUT       MDMCOM                        ;reset usart
  315.           LDA       COMMND                        ;current modem mode word
  316.           OUT       MDMMOD
  317.           LDA       COMMND+1            ;current modem command word
  318.           OUT       MDMCOM
  319.           LDA       ONLYSIO                       ;get sio only flag
  320.                                                   ;this flag was created because a full
  321.                                                   ;modem init causes interferrence with
  322.                                                   ;automatic dialing from library with
  323.                                                   ;baud rate specified. ONLYSIO is set
  324.                                                   ;and reset in baud and par routine 
  325.           ORA       A                             ;complete modem init=0
  326.           RNZ                                     ;sio only=ff (baud or parity change)
  327.           LXI       H,INITMSG           ;send modem initialization string
  328.           CALL      SMSEND    
  329.           RET
  330. ;
  331. ; US Robotics send-break routine (v1.3 je)
  332. ;
  333. PBREAK:   LDA       COMMND+1  ;get 2nd modem control byte
  334.           ORI       1FH                 ;set break bit (don't change speed)     
  335.           OUT       MDMCOM              ;send it to modem
  336.           MVI       B,3
  337.           MVI       C,TIMER
  338.           CALL      MEX                 ;wait for 300 ms.
  339.           CALL      NOAT                ;reset sio to orig values
  340.           RET
  341. ;
  342. ; The following code disconnects a call in progress.
  343. ; The US Robotics hangs itself up, and returns to
  344. ; command state.
  345. ;
  346. PDISC:    MVI       B,12
  347.           MVI       C,TIMER             ;wait 1.2 seconds
  348.           CALL      MEX
  349.           LXI       H,USESC             ;send '+++'
  350.           CALL      SMSEND
  351.           MVI       B,12                ;wait 1.2 seconds
  352.           MVI       C,TIMER
  353.           CALL      MEX
  354.           RET
  355. ;
  356. USESC     DB        '+++',0             ;disconnect from line
  357. ;
  358. ;
  359. ; exit routine
  360. ;
  361. DUMMY:    RET                           ;we don't need one
  362. ;
  363. ;
  364. ; This is the DIAL routine called by MEX to dial a digit. 
  365. ; 
  366. ;  The following status codes are returned in the A register
  367. ;
  368. ;         0 - Carrier detected, connection established
  369. ;         1 - Far end busy (only for modems that can detect this condition)
  370. ;         2 - No answer (or timed out waiting for modem response)
  371. ;         3 - Keyboard abort (^C only: all others should be ignored)
  372. ;         4 - Error reported by modem
  373. ;
  374. ; <No other codes should be returned after an end-dial sequence>
  375. ;
  376. ;
  377. PDIAL:    LHLD      DIALPT              ;FETCH POINTER
  378.           CPI       254                 ;START DIAL?
  379.           JZ        STDIAL              ;JUMP IF SO
  380.           CPI       255                 ;END DIAL?
  381.           JZ        ENDIAL              ;JUMP IF SO
  382. ;
  383. ; Not start or end sequence, must be a digit to be sent to the modem
  384. ;
  385.           MOV       M,A                 ;PUT CHAR IN BUFFER
  386.           INX       H                   ;ADVANCE POINTER
  387.           SHLD      DIALPT              ;STUFF PNTR
  388.           RET                           ;ALL DONE
  389. ;
  390. ; Here on a start-dial sequence
  391. ;
  392. STDIAL:   LXI       H,DIALBF  ;SET UP BUFFER POINTER
  393.           SHLD      DIALPT
  394.           RET
  395. ;
  396. ; Here on an end-dial sequence
  397. ;
  398. ENDIAL:   MVI       M,CR                ;STUFF END-OF-LINE INTO BUFFER
  399.           INX       H                   ;FOLLOWED BY TERMINATOR
  400.           MVI       M,0
  401.           LDA       TPULSE              ;GET OVERLAY'S TOUCH-TONE FLAG
  402.           STA       SMDIAL+3  ;PUT INTO STRING
  403.           LXI       H,SMDIAL  ;POINT TO DIALING STRING
  404.           CALL      SMSEND              ;SEND IT
  405.           MVI       C,INMDM
  406.           CALL      MEX                 ;CATCH ANY OUTPUT FROM THE MODEM
  407. ;
  408. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM FOR UP TO
  409. ; 60 SECONDS: YOU MAY CHANGE THE EQUATE VALUE FOR THE FOLLOWING LINE
  410. ; "MODE ANS" WILL (TEMP) SET IT TO 20 SECONDS DUE TO THE MODEM'S RESTRICTION
  411. ;
  412. RESULT:   MVI       C,MAXWAIT ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  413. SMWLP:    PUSH      B
  414.           MVI       B,1                 ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  415.           MVI       C,TMDINP  ;DO TIMED INPUT
  416.           CALL      MEX
  417.           POP       B
  418.           JNC       SMTEST              ;JUMP IF MODEM HAD A CHAR
  419.           PUSH      B                   ;NO, TEST FOR CONTROL-C FROM CONSOLE
  420.           MVI       C,CHEKCC
  421.           CALL      MEX
  422.           POP       B
  423.           JNZ       SMNEXT              ;IF NOT, JUMP
  424.           MVI       B,CR                ;YES, SHUT DOWN THE MODEM
  425.           MVI       C,SNDCHR
  426.           CALL      MEX
  427.           MVI       A,3                 ;RETURN ABORT CODE
  428.           RET
  429. SMNEXT:   DCR       C                   ;NO
  430.           JNZ       SMWLP               ;CONTINUE
  431. ;
  432. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  433. ;
  434. SMTIMO:   MVI       A,2                 ;RETURN TIMEOUT CODE
  435.           RET
  436. ;
  437. ; MODEM GAVE US A RESULT, CHECK IT
  438. ;
  439. SMTEST:   ANI       7FH                 ;IGNORE ANY PARITY
  440.           CALL      SMANAL              ;TEST THE RESULT
  441.           JC        RESULT              ;GO TRY AGAIN IF UNKNOWN RESPONSE
  442.           MOV       A,B                 ;A=RESULT 
  443.           PUSH      PSW                 ;SAVE IT
  444. SMTLP:    MVI       C,INMDM             ;EAT ANY ADDITIONAL CHARS FROM SMARTMODEM
  445.           CALL      MEX
  446.           JNC       SMTLP               ;UNTIL 100MS OF QUIET TIME
  447.           POP       PSW                 ;RETURN THE CODE
  448.           RET
  449. ;
  450. SMANAL:   STA       ANSBD               ;store baud rate for "MODE ANS" (v1.3 je) 
  451.           MVI       B,0                 ;prep connect code
  452.           CPI       '1'                 ;numeric version of "CONNECT"
  453.           RZ
  454.           CPI       '5'                 ;numeric version of "CONNECT 1200"
  455.           RZ
  456.           INR       B                   ;US Robotics can't do busy
  457.           INR       B                   ;prep no connect code B=2
  458.           CPI       '3'                 ;numeric version of "NO CONNECT"
  459.           RZ
  460.           INR       B                   ;we already checked for ^C
  461.           INR       B                   ;prep modem error B=4
  462.           CPI       '4'                 ;numeric version of "ERROR"
  463.           RZ
  464.  
  465. ANSBD:    DB        0                   ;1=300, 5=1200 baud for "MODE ANS" (v1.3 je)
  466.  
  467. ;
  468. ; UNKNOWN RESPONSE, RETURN CARRY TO CALLER. BUT FIRST,
  469. ; FLUSH THE UNKNOWN RESPONSE LINE FROM THE MODEM.
  470. ;
  471. WTLF:     CPI       LF                  ;LINEFEED?
  472.           STC
  473.           RZ                            ;END IF SO
  474.           MVI       C,INMDM             ;NO. GET NEXT CHAR
  475.           CALL      MEX
  476.           JNC       WTLF                ;UNLESS BUSY, LOOP
  477.           RET
  478. ;
  479. ; SMARTMODEM UTILITY ROUTINE: SEND STRING TO MODEM
  480. ;
  481. SMSEND:   MVI       C,SNDRDY  ;WAIT FOR MODEM READY
  482.           CALL      MEX
  483.           JNZ       SMSEND
  484.           MOV       A,M                 ;FETCH NEXT CHARACTER
  485.           INX       H
  486.           ORA       A                   ;END?
  487.           RZ                            ;DONE IF SO
  488.           MOV       B,A                 ;NO, POSITION FOR SENDING
  489.           MVI       C,SNDCHR  ;NOPE, SEND THE CHARACTER
  490.           CALL      MEX
  491.           JMP       SMSEND
  492. ;
  493. ; DATA AREA
  494. ;
  495.  
  496. INITMSG:DB          'AT'                ;modem attention (carrier must be off)
  497.           DB        'V'                 ;verbosity
  498.           DB        '0'                 ;verbose=1, terse=0
  499.           DB        'X'                 ;extended result to be sent?
  500.           DB        '1'                 ;yes=1 (0-5), no=0 (0-4)
  501. ;
  502. ; *** DO NOT CHANGE THE ABOVE SETTINGS
  503. ;
  504.           DB        'M'                 ;monitor speaker
  505. SPKFLG:   DB        '1'                 ;on=2, until carrier=1, off=0
  506.           DB        'F'                 ;duplex
  507. DUPFLG: DB          '1'                 ;full=1, half=0
  508.           DB        'S0='               ;answer on ring
  509. ONRING:   DB        '0'                 ;#=1-9 (usr max=255), no ans=0
  510.                                         ;modified by ANSRNG equate
  511.                                         ;SET ORIG resets this byte to '0'
  512.           DB        'S7='               ;carrier wait time
  513. TIMFLG:   DB        '15'                ;15, 20, 30 or 60 seconds
  514.  
  515.           IF        S10                 ;use only with newer modems ***********
  516.           DB        'S10=255' ;(see change notes)
  517.           ENDIF     ;S10                ;used to determine carrier dropout time
  518.  
  519.           DB        CR                  ;usr command mode terminator
  520.           DB        0                   ;initmsg stopper
  521.  
  522. ANSNOW:   DB        'ATA',CR,0          ;enter answer mode (send ans tone)
  523.                                         ;(wait for carrier from orig modem)
  524.  
  525. SMDIAL:   DB        'ATD'               ;dial attention
  526.           DB        'T'                 ;tone=T, pulse=P, ","=2 sec delay (in dialbf)
  527. DIALBF:   DS        52                  ;2* 24 CHAR MAX, + CR + NULL + SLOP
  528. DIALPT:   DS        2                   ;DIAL POSITION POINTER
  529. ;
  530. ; Set baud-rate code in A . US Robotics supports only four rates, 
  531. ; which are validated here. 
  532. ;
  533. PBAUD:    PUSH      H                   ;don't alter anybody
  534.           PUSH      D
  535.           PUSH      B
  536.           MOV       E,A                 ;code to DE
  537.           MVI       D,0
  538.           LXI       H,BAUDTB  ;offset into table
  539.           DAD       D
  540.           MOV       A,M                 ;fetch code
  541.           ORA       A                   ;0? (means unsupported code)
  542.           STC                           ;return error for STBAUD caller
  543.           JZ        PBEXIT              ;exit if so
  544.           MOV       B,A
  545.           LXI       H,MSPEED
  546.           MOV       M,E
  547.           LXI       H,BAUDCD
  548.           DAD       D
  549.           MOV       C,M
  550.           LXI       H,COMMND
  551.           MOV       A,M
  552.           ANI       BDMSKL              ;modified 110 baud for 2 stop bits (v1.2 je)
  553.           ORA       B
  554.           MOV       M,A
  555.           INX       H
  556.           MOV       A,M
  557.           ANI       BDMSKH
  558.           ORA       C
  559.           MOV       M,A
  560.           CALL      NOAT                ;init 8251 sio only
  561. PBEXIT:   POP       B                   ;all done
  562.           POP       D
  563.           POP       H
  564.           RET
  565. ;
  566. ; table of baud rate divisors for supported rates
  567. ; modified 110 for 2 stop bits.  (v1.2 je)
  568. ;
  569. BAUDTB:   DB        83H,3,0,2,0                   ;110,300,450,610,710 (v1.2 je)
  570.           DB        2,0,0,0,0           ;1200,2400,4800,9600,19200
  571. BAUDCD: DB          0,20H,0,0,0
  572.           DB        20H,0,0,0,0
  573. ;
  574. ; Sign-on message
  575. ;
  576.  
  577. SYSVER:   CALL      NITMOD              ;init modem with defaults
  578.           LXI       D,SOMESG
  579.           MVI       C,PRINT
  580.           CALL      MEX
  581. CARRSH:   CALL      CRLF
  582.           LXI       D,NOMESG
  583.           CALL      CARRCK
  584.           MVI       C,PRINT
  585.           CNZ       MEX
  586.           LXI       D,CARMSG
  587.           MVI       C,PRINT
  588.           CALL      MEX
  589.           RET
  590. ;
  591. SOMESG:   DB        'U.S. Robotics (S-100) overlay V. '
  592.           DB        REV/10+'0'
  593.           DB        '.'
  594.           DB        REV MOD 10+'0'
  595.           DB        ':',CR,LF,'$'
  596. ;
  597. NOMESG:   DB        'NO $'
  598. CARMSG:   DB        'CARRIER PRESENT',CR,LF,LF,'$'
  599. ;
  600. ;   Check US Robotics for carrier present  (Z=yes)
  601. ;
  602. CARRCK:   IN        MDMSTS
  603.           CMA
  604.           ANI       CARMSK
  605.           RET
  606. ;
  607. ; Newline on console
  608. ;
  609. CRLF:     MVI       A,CR
  610.           CALL      TYPE
  611.           MVI       A,LF                ;fall into TYPE
  612. ;
  613. ; type char in A on console
  614. ;
  615. TYPE:     PUSH      H                   ;save 'em
  616.           PUSH      D
  617.           PUSH      B
  618.           MOV       E,A                 ;align output character
  619.           MVI       C,CONOUT  ;print via MEX
  620.           CALL      MEX
  621.           POP       B
  622.           POP       D
  623.           POP       H
  624.           RET
  625. ;
  626. ; Data area
  627. ;
  628. ERRFLG:    DB       0                   ;connection error code
  629. COMMND:    DS       2                   ;current modem status storage
  630. ORGFLG:    DB       '0'                 ;initiate to "normal"(originate) 
  631.                                         ;'0'=orig,'1'-'9'=ring,ffh='ATA'
  632. ONLYSIO: DB         0                   ;ff=don't send "AT" commands to modem
  633. ;
  634. ;------------------------------------------------------------
  635. ;
  636. ; The remainder of this overlay implements a very versatile
  637. ; SET command (v1.2 je) 
  638. ;
  639. ; Control is passed here after MEX parses a SET command.
  640. ;
  641. SETCMD:   MVI       C,SBLANK  ;any arguments?
  642.           CALL      MEX
  643.           JC        SETSHO              ;if not, go print out values
  644.           LXI       D,CMDTBL  ;parse command
  645.           CALL      TSRCH               ;from table
  646.           PUSH      H                   ;any address on stack
  647.           RNC                           ;if we have one, execute it
  648.           POP       H                   ;nope, fix stack
  649. SETERR:   LXI       D,SETEMS  ;print error
  650.           MVI       C,PRINT
  651.           CALL      MEX
  652.           RET
  653. ;
  654. ; SET with parameters is not allowed if carrier is present (v1.2 je)
  655. ;
  656.  
  657. SETNOK:
  658.           IF        CLRSCN              ;clear screen cmds
  659.           CALL      CLS
  660.           ENDIF     ;CLRSCN
  661.  
  662.           LXI       D,SETNOM  ;set not allowed with carrier present
  663.           MVI       C,PRINT
  664.           CALL      MEX
  665.           MVI       A,0FFH              ;prevent clearing screen at setsho
  666.           STA       NOCLR
  667.           CALL      SETSHO              ;display current parameters
  668.           XRA       A                   ;reset flag
  669.           STA       NOCLR
  670.           RET
  671.  
  672. NOCLR:    DB        0                   ;prevents clearing screen in setsho if=ff
  673.  
  674. SETNOM:   DB        CR,LF,'The requested SET command is not allowed',CR,LF
  675.           DB        'when a carrier is present.  The connection',CR,LF
  676.           DB        'must be broken first.',CR,LF,LF,'$'
  677.  
  678. ;
  679. SETEMS:   DB        CR,LF,'SET command error',CR,LF,'$'
  680. ;
  681. ; SET command table ... note that tables are constructed of command-
  682. ; name (terminated by high bit=1) followed by word-data-value returned
  683. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  684. ; a binary zero.
  685. ;
  686. ; Note that LOOKUP attempts to find the next item in the input stream
  687. ; in the table passed to it in HL ... if found, the table data item is
  688. ; returned in HL; if not found, LOOKUP returns carry set.
  689. ;
  690. CMDTBL:   DB        '?'+80H                       ;"set ?"
  691.           DW        STHELP
  692.           DB        'BAU','D'+80H                 ;"set baud"
  693.           DW        STBAUD
  694.           DB        'MOD','E'+80H                 ;"set mode"
  695.           DW        STMODE
  696.           DB        'SPEA','K'+80H                ;"set speaker on/off"
  697.           DW        STSPKR
  698.           DB        'WAI','T'+80H                 ;"set time"
  699.           DW        STTIME
  700.           DB        'PA','R'+80H                  ;"set parity"
  701.           DW        STPAR
  702.           DB        'DUPL','X'+80H                ;"set full/half duplex"
  703.           DW        STDUP     
  704. ;
  705.           DB        0                   ;<<=== table terminator
  706. ;
  707. ; SET <no-args>: print current statistics
  708. ;
  709. SETSHO:
  710.           IF        CLRSCN              ;clear screen cmds
  711.           LDA       NOCLR               ;see if we already have an err msg on screen
  712.           ORA       A
  713.           JNZ       STSHO               ;yes, don't clear screen
  714.           CALL      CLS                 ;clear screen
  715.           ENDIF     ;CLRSCN
  716.  
  717. STSHO:    CALL      CARRSH              ;show carrier present/not present
  718.           LXI       H,SHOTBL  ;get table of SHOW subroutines
  719. SETSLP:   MOV       E,M                 ;get table address
  720.           INX       H
  721.           MOV       D,M
  722.           INX       H
  723.           MOV       A,D                 ;end of table?
  724.           ORA       E
  725.           RZ                            ;exit if so
  726.           PUSH      H                   ;save table pointer
  727.           XCHG                          ;adrs to HL
  728.           CALL      GOHL                ;do it
  729.           CALL      CRLF                ;print newline
  730.           MVI       C,CHEKCC  ;check for console abort
  731.           CALL      MEX
  732.           POP       H                   ;it's done
  733.           JNZ       SETSLP              ;continue if no abort
  734.           RET
  735. ;
  736. GOHL:     PCHL
  737. ;
  738. ; table of SHOW subroutines
  739. ;
  740. SHOTBL:   DW        BDSHOW              ;baud rate
  741.           DW        MDSHOW              ;mode
  742.           DW        SPSHOW              ;speaker
  743.           DW        TMSHOW              ;wait time
  744.           DW        PSHOW               ;parity
  745.           DW        DSHOW               ;duplex
  746.           DW        HLSHOW              ;v1.1 je
  747.           DW        0                   ;<<== table terminator
  748. ;
  749. ; SET ?  processor
  750. ;
  751. STHELP:
  752.           IF        CLRSCN              ;clear screen
  753.           CALL      CLS
  754.           ENDIF     ;CLRSCN
  755.  
  756.           LDA       RINGNO              ;get number of rings
  757.           STA       HLRING              ;set it in help message
  758.           LXI       D,HLPMSG
  759.           MVI       C,PRINT
  760.           CALL      MEX
  761.           RET
  762. ;
  763. ; Display SET ? message (v1.1 je)
  764. ;
  765. HLSHOW:   LXI       D,HLQMSG
  766.           MVI       C,PRINT
  767.           CALL      MEX
  768.           RET
  769.  
  770. HLQMSG:   DB        CR,LF,'Type SET ? for help.',CR,LF,'$'
  771.  
  772. ;
  773. ; The help message
  774. ;
  775. HLPMSG:
  776.           IF        NOT CLRSCN
  777.           DB        CR,LF
  778.           ENDIF     ;NOT CLRSCN
  779.  
  780.           DB        'SET COMMAND (recommended defaults first)  '
  781.           DB        '"U.S. ROBOTICS VERSION"',CR
  782.           DB        LF,LF,'SET BAUD  1200   (1200 baud + 1 stop bit)'
  783.           DB        CR,LF,'          600    (600 baud + 1 stop bit)'
  784.           DB        CR,LF,'          300    (300 baud + 1 stop bit)'
  785.           DB        CR,LF,'          110    (110 baud + 2 stop bits)'
  786.           DB        CR,LF,'SET MODE  ORIG   (orignate mode) *'
  787.           DB        CR,LF,'          ANS    (answer tone sent immediately) *'
  788.           DB        CR,LF,'          RING   (answer on ring #'
  789. HLRING:   DB        '3'
  790.           DB        ') *'
  791.           DB        CR,LF,'SET SPEAK TEMP   (speaker on until carrier) *'
  792.           DB        CR,LF,'          ON     (speaker always on) *'
  793.           DB        CR,LF,'          OFF    (speaker always off) *'
  794.           DB        CR,LF,'SET WAIT  15     (15 seconds) *'
  795.           DB        CR,LF,'          20     (20 seconds) *'
  796.           DB        CR,LF,'          30     (30 seconds) *'
  797.           DB        CR,LF,'          60     (60 seconds) *'
  798.           DB        CR,LF,'SET PAR   NO     (no parity + 8 data bits)'
  799.           DB        CR,LF,'          ODD    (odd parity + 7 data bits)'
  800.           DB        CR,LF,'          EVEN   (even parity + 7 data bits)'
  801.           DB        CR,LF,'SET DUPLX FULL   (full duplex) *'          
  802.           DB        CR,LF,'          HALF   (half duplex) *',CR,LF
  803.           DB        CR,LF,'* = CARRIER CANNOT BE PRESENT FOR THESE COMMANDS'
  804.           DB        CR,LF,'$'
  805. ;
  806. ; SET BAUD processor (v1.2 je)
  807. ; carrier may be on or off
  808. ;
  809. STBAUD:   MVI       C,BDPARS  ;function code
  810.           CALL      MEX                 ;let MEX look up code
  811.           JC        SETERR              ;invalid code?
  812.           CALL      PBAUD               ;no, try to set it
  813.           JC        SETERR              ;not-supported code
  814. BDSHOW:   CALL      ILPRT               ;display baud
  815.           DB        'BAUD RATE:   ',0
  816.           LDA       MSPEED
  817.           MVI       C,PRBAUD  ;use MEX routine
  818.           CALL      MEX
  819.           RET
  820. ;
  821. ; SET MODE processor (v1.2 je)
  822. ; carrier must be off
  823. ;
  824. STMODE:   CALL      CARRCK              ;is carrier present?
  825.           JZ        SETNOK              ;z=yes, SET MODE not allowed with carrier
  826.           LXI       D,MODTBL  ;lookup next input item in table
  827.           CALL      TSRCH
  828.           JC        SETERR              ;if not found, error
  829.           MOV       A,L                 ;L='0' orig, L=ff ans, L='1'-'9' ring #
  830.           STA       ORGFLG
  831.           CPI       '0'                 ;orgflg contains ascii 0-9 or ffh
  832.           JZ        MDORIG              ;originate
  833.           JM        MDANS               ;answer
  834. MDRING:   LDA       RINGNO              ;get ring # to answer on
  835.           STA       ONRING              ;store in modem init string
  836.           STA       RINGNB              ;store in display string
  837.           CALL      CURRNT              ;send modem init string
  838.           JMP       MDSHOW              ;display mode
  839. MDORIG:   MVI       A,'0'               ;set for no ans in init string
  840.           STA       ONRING
  841.           CALL      CURRNT              ;send modem init string
  842. MDSHOW:   CALL      ILPRT               ;show mode
  843.           DB        'MODE:        ',0
  844.           LDA       ORGFLG              ;orig='0', ans=ff, ring='1'-'9'
  845.           CPI       '0'                 ;orgflg contains ascii 0-9 or ffh
  846.           JZ        ORIGP               ;display orig
  847.           CALL      ILPRT
  848.           DB        'Answer on Ring #'
  849. RINGNB:   DB        '3'                 ;default is 3 rings
  850.           DB        0                   ;stopper
  851.           RET
  852. ORIGP:    CALL      ILPRT
  853.           DB        'Originate'
  854.           DB        0
  855.           RET
  856. ;
  857. ; This routine is used primarily for remote ends which have
  858. ; originate only modems without autodialing. You must issue
  859. ; the "ATA" command before the carrier is detected from remote.
  860. ; It is temporary in nature and will revert to RING or ORIGINATE
  861. ; the next time an "AT" command other than "ATA" is sent to the
  862. ; modem, depending on mode prior to last "ATA".
  863. ;         NOTE: THE BAUD RATE MAY CHANGE UPON CONNECTION (v1.3 je)
  864. ;
  865. MDANS:    CALL      ILPRT               ;answer mode
  866.           DB        'MODE:        '
  867.           DB        'Sending Answer Tone "Now"',CR,LF
  868.           DB        '             '
  869.           DB        'Remote Modem must send Originate',CR,LF
  870.           DB        '             '
  871.           DB        'tone within '
  872. MDTIME:   DB        '15'                          ;modifying S7 in modem had no effect
  873.                                                   ;on the "ATA" cmd so I removed the
  874.                                                   ;logic to change this value (je)
  875.           DB        ' seconds!',CR,LF
  876.           DB        '             '
  877.           DB        'Originator Determines Baud Rate.'
  878.           DB        CR,LF,0
  879.  
  880.           LXI       H,ANSNOW  ;send answer tone now
  881.           CALL      SMSEND              ;send "ATA" to modem
  882. ;
  883. ; This logic reset the orgflg back to orig or ring since the
  884. ; manual answer mode is a one shot operation.
  885. ; Then the result of the ANS command is reported and baud rate
  886. ; switching is done if required. (v1.3 je)
  887. ;
  888.           LDA       ONRING              ;get init string rings
  889.           STA       ORGFLG              ;set orgflg to orig or ring (not ans)
  890.           MVI       A,20                ;set max time for connection
  891.           STA       RESULT+1
  892.           CALL      RESULT              ;wait for modem response
  893.           PUSH      PSW                 ;save return code
  894.           MVI       A,MAXWAIT ;reset to max of 60 sec
  895.           STA       RESULT+1
  896.           POP       PSW                 ;retrieve return code
  897.           CPI       0                   ;connection?
  898.           JZ        ACNCT               ;yes
  899.           CPI       2                   ;timeout?
  900.           JZ        ANCNCT              ;yes
  901.           CPI       3                   ;ctl-c abort?
  902.           JZ        KABORT              ;yes
  903.           CALL      ILPRT               ;modem reported error
  904.           DB        CR,LF,BELL
  905.           DB        'USR Modem Returned "FAILED" Status',CR,LF,LF,0
  906.           RET
  907. ACNCT:    LDA       ANSBD               ;get connected baud rate
  908.           SBI       30H                 ;convert from dec to hex
  909.           STA       MSPEED              ;set speed byte
  910.           CPI       1                   ;300 baud?
  911.           JNZ       A1200               ;no, must be 1200
  912.           CALL      ILPRT
  913.           DB        CR,LF,BELL,'300',0
  914.           JMP       ACOM
  915. A1200:    CALL      ILPRT
  916.           DB        CR,LF,BELL,'1200',0
  917. ACOM:     CALL      ILPRT
  918.           DB        ' BAUD CONNECTION DETECTED',CR,LF
  919.           DB        'You may enter Terminal (T/L/E) Mode.',CR,LF,LF,0
  920.           CALL      PBAUD               ;change baud rate in sio
  921.           RET
  922. ANCNCT:   CALL      ILPRT               ;no connection
  923.           DB        CR,LF,BELL,'TIMEOUT -'
  924.           DB        ' No Orignate Tone Received.',CR,LF,LF,0
  925.           RET
  926. KABORT:   CALL      ILPRT               ;ctl-c abort by user
  927.           DB        CR,LF,'ABORTED',CR,LF,LF,0
  928.           RET
  929.  
  930. ;
  931. ; MODE argument table
  932. ;
  933. MODTBL:   DB        'ORI','G'+80H       ;"set mode orig"
  934.           DB        '0',0
  935.           DB        'AN','S'+80H        ;"set mode ans"
  936.           DB        0FFH,0
  937.           DB        'RIN','G'+80H       ;"answer on ring #"
  938. RINGNO:   DB        ANSRNG              ;default is set for you taste at equate
  939.           DB        0
  940. ;
  941.           DB        0                   ;<<=== table terminator
  942. ;
  943. ; The speaker on the US Robotics board can get annoying
  944. ; so we included this routine to turn it off. If you
  945. ; are truly masochistic you can turn it on all the time.
  946. ; Carrier must be off.
  947. ;
  948. STSPKR:   CALL      CARRCK              ;check for carrier
  949.           JZ        SETNOK              ;z=yes, command not allowed
  950.           LXI       D,SPKTBL  ;lookup next input item in table
  951.           CALL      TSRCH
  952.           JC        SETERR              ;if not found, error
  953.           MOV       A,L
  954.           STA       SPKFLG
  955.           CALL      CURRNT              ;send init buff
  956. SPSHOW:   CALL      ILPRT               ;show speaker setting
  957.           DB        'SPEAKER:     ',0
  958.           LDA       SPKFLG
  959.           CPI       '0'
  960.           JZ        SDOFF
  961.           CPI       '2'
  962.           JZ        SDON
  963.           CALL      ILPRT
  964.           DB        'On Until Carrier Detected',0
  965.           RET
  966. SDOFF:    CALL      ILPRT
  967.           DB        'Always Off',0
  968.           RET
  969. SDON:     CALL      ILPRT
  970.           DB        'Always On',0       
  971.           RET
  972. ;
  973. ; SPEAKER argument table
  974. ;
  975. SPKTBL:   DB        'OF','F'+80H                  ;"set sound off"
  976.           DB        '0',0
  977.           DB        'O','N'+80H                   ;"set sound on"
  978.           DB        '1',0
  979.           DB        'TEM','P'+80H                 ;"set sound on until carrier"
  980.           DB        '2',0     
  981. ;
  982.           DB        0                   ;<<=== table terminator
  983. ;
  984. ;
  985. ;  The US Robotics allows for soft setting of the time to
  986. ;  wait for answer from the other end. It can be anywhere
  987. ;  in the range of 0 to 255 seconds. We have arbitrarily
  988. ;  chosen 15, 20, 30 and 60 seconds... If you don't like 
  989. ;  these times... change them.
  990. ;  Carrier must be off.
  991. ;  
  992. STTIME:   CALL      CARRCK              ;is carrier on?
  993.           JZ        SETNOK              ;z=yes, SET WAIT not allowed if carrier
  994.           LXI       D,TIMETBL ;lookup next input item in table
  995.           CALL      TSRCH
  996.           JC        SETERR              ;if not found, error
  997.           SHLD      TIMFLG
  998.           CALL      CURRNT              ;send modem init string
  999. TMSHOW:   CALL      ILPRT               ;show time setting
  1000.           DB        'WAIT TIME:   ',0
  1001.           LDA       TIMFLG
  1002.           CPI       '1'
  1003.           JZ        TM15
  1004.           CPI       '2'
  1005.           JZ        TM20
  1006.           CPI       '3'
  1007.           JZ        TM30
  1008.           CALL      ILPRT
  1009.           DB        '60 Seconds',0
  1010.           RET
  1011. TM30:     CALL      ILPRT
  1012.           DB        '30 Seconds',0
  1013.           RET
  1014. TM20:     CALL      ILPRT
  1015.           DB        '20 Seconds',0      
  1016.           RET
  1017. TM15:     CALL      ILPRT
  1018.           DB        '15 Seconds',0
  1019.           RET
  1020. ;
  1021. ; TIME argument table
  1022. ;
  1023. TIMETBL:  DB        '1','5'+80H         ;"set time 15"
  1024.           DB        '15'
  1025.           DB        '2','0'+80H                   ;"set time 20"
  1026.           DB        '20'
  1027.           DB        '3','0'+80H                   ;"set time 30"
  1028.           DB        '30'      
  1029.           DB        '6','0'+80H                   ;"set time 60"
  1030.           DB        '60'
  1031. ;
  1032.           DB        0                   ;<<=== table terminator
  1033.  
  1034. ;
  1035. ; Parity setting logic.  Even and Odd parity setting requires
  1036. ; 7 data bits.  No parity requires 8 data bits. The number
  1037. ; of stop bits is determined by baud rate.
  1038. ; As of version 1.2 I don't know if there is outside entry other
  1039. ; than through the SET command.  If there is a need to come in
  1040. ; externally entry can be made at PARITY: and NOPAR:.
  1041. ; An assumption is being made at the PARITY: entry. (see comments there)
  1042. ; Carrier may be on or off.
  1043. ;
  1044. ; CAUTION: NO PARITY MUST BE SPECIFIED IF OBJECT FILES ARE TO BE TRANSFERRED
  1045. ;
  1046. STPAR:    LXI       D,PARTBL  ;lookup next input item in table
  1047.           CALL      TSRCH
  1048.           JC        SETERR              ;if not found, error
  1049.           MOV       A,L
  1050.           STA       PARFLG
  1051.           CPI       '0'
  1052.           JZ        NONE8               ;no parity
  1053.           CPI       '1'
  1054.           JZ        ODD7                ;odd parity
  1055. EVEN7:    LDA       COMMND              ;get mode byte
  1056.           ORI       38H                 ;send even parity with 7 data bits
  1057.           ANI       0FBH
  1058.           JMP       PARCOM              ;go to common routine
  1059. NONE8:    LDA       COMMND              ;get mode byte      
  1060.           ORI       0CH                 ;send no parity with 8 data bits
  1061.           ANI       0CFH
  1062.           JMP       PARCOM              ;go to common routine
  1063. ODD7:     LDA       COMMND              ;get mode byte
  1064.           ORI       18H                 ;send odd parity with 7 data bits
  1065.           ANI       0DBH
  1066. PARCOM:   STA       COMMND              ;resave mode byte
  1067.           CALL      NOAT                ;init of 8251 only
  1068. PSHOW:    CALL      ILPRT               ;show parity setting
  1069.           DB        'PARITY:      ',0
  1070.           LDA       PARFLG
  1071.           CPI       '0'
  1072.           JZ        PARNO
  1073.           CPI       '1'
  1074.           JZ        PARODD
  1075. PAREVN:   CALL      ILPRT
  1076.           DB        'Even',0
  1077.           RET
  1078. PARNO:    CALL      ILPRT
  1079.           DB        'None',0
  1080.           RET
  1081. PARODD:   CALL      ILPRT
  1082.           DB        'Odd',0
  1083.           RET
  1084.  
  1085. ;
  1086. ; Set parity to its original value after call to nopar (v1.3 je)
  1087. ; Called by MEX (transparent to SET cmd)
  1088. ;
  1089. PARITY:   CALL      NOAT                ;init sio only (no AT cmd)
  1090.           RET
  1091. ;
  1092. ; MEX calls this routine to set modem for no parity.
  1093. ; This is transparent to the SET command (v1.3 je)
  1094. ;
  1095. NOPAR:    LDA       COMMND              ;get current parity setting
  1096.           PUSH      PSW                 ;save it
  1097.           ANI       PARMSK              ;clear parity enable bit
  1098.           ORI       NPARIT              ;set for no parity
  1099.           STA       COMMND              ;this is temporary in sio until set parity
  1100.                                         ;changes it to its previous value (je)
  1101.           CALL      NOAT                ;init sio only (no AT cmd)
  1102.           POP       PSW                 ;get original sio mode byte
  1103.           LXI       H,COMMND  ;hl = mode byte upon return
  1104.           MOV       M,A                 ;restore mode byte
  1105.           RET
  1106.  
  1107. PARFLG:   DB        '0'                 ;default to no parity
  1108.  
  1109. ;
  1110. ; PARITY argument table
  1111. ;
  1112. PARTBL:   DB        'NON','E'+80H                 ;"set no parity"
  1113.           DB        '0',0
  1114.           DB        'OD','D'+80H                  ;"set odd parity"
  1115.           DB        '1',0
  1116.           DB        'EVE','N'+80H                 ;"set even parity"
  1117.           DB        '2',0     
  1118. ;
  1119.           DB        0                   ;<<=== table terminator
  1120. ;
  1121. ; Full or Half Duplex setting (v1.2 je)
  1122. ; Normally Full duplex is all that is required but in
  1123. ; case there is a need to change it you can.
  1124. ; Carrier must not be present.
  1125. ;
  1126. STDUP:    CALL      CARRCK              ;check for carrier present
  1127.           JZ        SETNOK              ;z=yes, SET DUPLX is not allowe
  1128.           LXI       D,DUPTBL  ;lookup next input item in table
  1129.           CALL      TSRCH
  1130.           JC        SETERR              ;if not found, error
  1131.           MOV       A,L
  1132.           STA       DUPFLG
  1133.           CALL      CURRNT              ;send init buff including "AT" cmd
  1134. DSHOW:    CALL      ILPRT               ;show duplex setting
  1135.           DB        'DUPLEX:      ',0
  1136.           LDA       DUPFLG
  1137.           CPI       '0'
  1138.           JZ        HDPLX               ;half duplex
  1139.           CALL      ILPRT
  1140.           DB        'Full',0
  1141.           RET
  1142. HDPLX:    CALL      ILPRT
  1143.           DB        'Half',0
  1144.           RET
  1145. ;
  1146. ; DUPLEX argument table
  1147. ;
  1148. DUPTBL:   DB        'FUL','L'+80H                 ;"set full duplex"
  1149.           DB        '1',0
  1150.           DB        'HAL','F'+80H                 ;"set half duplex"
  1151.           DB        '0',0
  1152. ;
  1153.           DB        0                   ;<<=== table terminator
  1154. ;
  1155. ; Compare next input-stream item in table @DE; CY=1
  1156. ; if not found, else HL=matched data item
  1157. ;
  1158. TSRCH:    MVI       C,LOOKUP  ;get function code
  1159.           JMP       MEX                 ;pass to MEX processor
  1160. ;
  1161. ; Print in-line message ... blows away C register
  1162. ;
  1163. ILPRT:    MVI       C,ILP               ;get function code
  1164.           JMP       MEX                 ;go do it
  1165. ;
  1166. ;
  1167.           END
  1168.