home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-TSA.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  34KB  |  1,270 lines
  1. ;//////////////////////////////////////////////////////////////////////////////
  2. ;
  3.      TITLE  'MEX Overlay for Toshiba T100 and Serial Interface Adapter '
  4. ;
  5. ;    NOTE - this overlay is designed to be specific for a Toshiba T00
  6. ;    together with a Hayes Smartmodem 300/1200 driven in conjunction with
  7. ;    a Toshiba Support Group Serial Async Interface Adapter. 
  8. ;
  9. ;    --- A very good starting point for ANY 2651 usart IO device, however.
  10. ;     
  11. ;//////////////////////////////////////////////////////////////////////////////
  12. ;
  13. REV    EQU    10        ; revision number * 10
  14. ;
  15. ;******************************************************************************
  16. ;
  17. ;    One problem with the Toshiba T100 is the inabillity to do 1200
  18. ;    bps. This is due to the fact that Toshiba, for some reason - which is
  19. ;    completely beyond comprehension of civilized man - had decided to 
  20. ;    implement a software usart on an 8255 PIA. It is impossible to get 
  21. ;    1200 bps out of the infernal thing. Need I say that 300 bps gets
  22. ;    a bit frustrating to sysops, including myself. Well, to solve the
  23. ;    problem, I've designed a serial interface with a National INS2651 
  24. ;    usart to get up to 19.2K baud out of the Tosh. (I don't own a Tosh, 
  25. ;    but I got tired of all of the bitching about not being able to do 
  26. ;    1200 with the thing). Tha adapter plugs into the rampack 2 expansion 
  27. ;    slot. You still can use slot 1 for the prom expansion. 
  28. ;
  29. ;    Tosh does furnish a serial port adapter - matter of fact, they are 
  30. ;    glad to sell you one. So would I at $400.00+ - arrghhhh ... gag me with
  31. ;    a microchip.... whats that old saying coined by Ward.....
  32. ;
  33. ;               Sempus Non Rippus Offis
  34. ;
  35. ;    My adapter goes for about 40 bucks (+/-) in small quanity. If there 
  36. ;    is a demand for it, this will be reduced as it costs a lot less to 
  37. ;    build 100 of 'em than it does 10. If you are 1) a poor soul with a 
  38. ;    Tosh, 2) are tired of paying Ma Bell and 3) would really like to do 
  39. ;    1200/2400 all the way up to 19,200 (dream on, we all wish...) baud on 
  40. ;    dialups, then contact me, the Sysop at Smokin Silicon RCP/M to leave 
  41. ;    a private message in 'TOS' - Ill get back to you. Smokin Silicon is 
  42. ;    the central point for the Toshiba Support group. If Toshiba won't 
  43. ;    support it at a reasonable price, We will. I'll be happy to fill yall 
  44. ;    in on the details. Flawless performance in computer <=> computer batch 
  45. ;    xfers with MEX at 9600 bps. This is the first in a series of RCPM 
  46. ;    overlays to support the serial adapter and the machine. 
  47. ;
  48. ;                        modem to the max / happy hacking
  49. ;            
  50. ;                            JP Sojak - sysop -
  51. ;                               Smokin Silicon RCP/M
  52. ;                               (312)941-0049 24 hrs 
  53. ;
  54. ;  ps - if you have a special problem with your machine, Ill try to help out.
  55. ;       By helping you out, many benifit. (Sempus Non Rippus Offis - FIGHT
  56. ;    BACK - don't put up with the garbage many manufactures try to feed 
  57. ;    you) 
  58. ;    
  59. ;******************************************************************************
  60. ;
  61. ;  02/24/84 ... mxo-tsa.asm   (for TS A-dapter)
  62. ;
  63. ;        Base version for a Toshiba T100 and a serial adapter. Roots
  64. ;        are everywhere by a cast of thousands. Thanks all... 
  65. ;        - Especially Ron Fowler for doing the single most important
  66. ;        public domain work since the original Modem7
  67. ;        
  68. ;                                    JP Sojak 
  69. ;
  70. ;//////////////////////////////////////////////////////////////////////////////
  71. ;
  72. ;    There is a Zilog SIO style full featured SET command implemented on
  73. ;    the INS2651 USART device ... The SET is specific to Smartmodem 
  74. ;    compatables. The available commands are:
  75. ;
  76. ;    delay <n> (seconds) .... SET the delay between dial and "NO CARRIER"
  77. ;    baud <rate> 110-19.2k .. SET the baud rate 110-19.2K, no 450 and 710
  78. ;    orig (originate mode) .. SET the modem originate (callout) carrier 
  79. ;    answer    (answer mode) .. SET the modem answer (callin) carrier 
  80. ;    tone ................... SET touch tone dialing
  81. ;    pulse .................. SET pulse dialing
  82. ;       monitor ................ SET the speaker ON
  83. ;    quiet .................. SET the speaker OFF
  84. ;    parity ................. SET the parity to odd, even, or none
  85. ;    stop ................... SET 1, 1.5, or 2 stopbits
  86. ;    bits ................... SET 5, 6, 7, or 8 bit data word length
  87. ;    digit .................. SET the interdigit dial time in mS 
  88. ;
  89. ;    "SET" <cr> will bring up the current settings.
  90. ;    "SET ?"<cr> will bring up the syntax for the SET commands available. 
  91. ;    And additionally, all 'SET'tings are 100% cloneable to new defaults.
  92. ;
  93. ;//////////////////////////////////////////////////////////////////////////////
  94. ;
  95. ; adapter port definitions
  96. ;
  97. BASEP    EQU    018H        ; port base address
  98. DATAPT    EQU    BASEP        ; serial data port
  99. SPORT    EQU    BASEP+1        ; status register
  100. MODE1    EQU    BASEP+2        ; first mode register
  101. MODE2    EQU    BASEP+2        ; second mode register
  102. CPORT    EQU    BASEP+3        ; command register
  103. ;    
  104. ;
  105. ; 2651 usart bit definitions
  106. ;
  107. MDRCVB    EQU    00000010B    ; modem receive bit (dav)
  108. MDRCVR    EQU    00000010B    ; modem receive ready
  109. MDSNDB    EQU    00000001B    ; modem send bit
  110. MDSNDR    EQU    00000001B    ; modem send ready bit
  111. MDMDTR    EQU    00000010B    ; modem data trm ready bit
  112. ;
  113. ; PLEASE NOTE ... The use of DCD (Data Carrier Detect) status register bit
  114. ; within the USART should be avoided. It is actually a Tx enable for the
  115. ; hardware. It MUST be pulled high on the EIA cable or the USART will seem
  116. ; to "hang". When it is active, the initialization routine thinks there 
  117. ; is returning from CP/M with a carrier present even when there isnt - 
  118. ; improper switch settings could unconditionally force an active (HIGH) state 
  119. ; - and abort the routine. The adapter has been defaulted with a pullup to 
  120. ; avoid "hanging" the hardware if the DCD #8 is left unconnected. It is 
  121. ; desirable to redefine the carrier sence bit to DSR #6 (Data Set Ready). It 
  122. ; is customary to leave DCD #8 open on the interface side and connect DCD #8 
  123. ; from the modem to DSR #6 (Data Set Ready) on the interface side. In this 
  124. ; way, the USART will never "hang". If you wish to use DCD then by all means 
  125. ; do so. As a matter of fact, ANY rcpm work REQUIRES it, but if you do not
  126. ; follow what all of this is about, then it is best to leave the equate as 
  127. ; is and prepare a cable as follows.... 
  128. ;
  129. ;    MODEM             INTERFACE
  130. ;    (DCE)               (DTE)
  131. ;
  132. ;    #1 <------------------------> #1  water pipe ground (optional)
  133. ;    #2 <------------------------> #2  \
  134. ;                       (Tx and Rx data)
  135. ;    #3 <------------------------> #3  / 
  136. ;
  137. ;    #7 <------------------------> #7  Signal Ground
  138. ; (DCD)    #8 <------------------------> #6  Data Set Ready
  139. ;      #20 <------------------------> #20 Data Terminal Ready
  140. ;
  141. ;
  142. ;MDMDCD    EQU    01000000B    ; DCD used to sence carrier present 
  143. ;
  144. MDMDCD    EQU    10000000B    ; DSR used to sence a carrier present     
  145. ;
  146. ;
  147. ;******************************************************************************
  148. ;
  149. ; Status register definitions within the 8251 USART device:
  150. ;
  151. ;    MODE 0 REGISTER (base + 2)
  152. ;  +--------+--------+--------+--------+--------+--------+--------+--------+
  153. ;  | 00 - invalid    | X0 - no parity  | 00 - 5 bits     |     must be     |
  154. ;  | 01 - 1 stop     | 01 - odd        | 01 - 6 bits     |   1    |   0    |
  155. ;  | 10 - 1.5 stop   | 10 - no parity  | 10 - 7 bits     | for the adapter |
  156. ;  | 11 - 2 stops    | 11 - even       | 11 - 8 bits     |        |        |
  157. ;  +--------+--------+--------+--------+--------+--------+--------+--------+
  158. ;
  159. ;    MODE 1 REGISTER (base + 2)
  160. ;  +--------+--------+--------+--------+--------+--------+--------+--------+
  161. ;  |        |        |     must be     | internal baud rate select register|
  162. ;  |   X    |   X    |   1    |   1    |        +        +        +        |
  163. ;  |        |        |  for the adapter|   B3   |   B2   |   B1   |   B0   |
  164. ;  +--------+--------+--------+--------+--------+--------+--------+--------+
  165. ;
  166. ; Where the internal generator is selected and is represented by:
  167. ;
  168. ;    NOTE - some of these are NOT supported by MEX - the USART does em,
  169. ;        but MEX has no idea they exist.
  170. ;    
  171. ;   Bx=    3 2 1 0            |  3 2 1 0
  172. ;   ----------------------------+-------------------------------
  173. ;    0 0 0 0 .... 50 baud    |  0 0 0 1 .... 75 baud
  174. ;    0 0 1 0 .... 110 baud    |  0 0 1 1 .... 134.5 baud
  175. ;    0 1 0 0 .... 150 baud    |  0 0 0 1 .... 300 baud
  176. ;    0 1 1 0 .... 600 baud    |  0 1 1 1 .... 1200 baud
  177. ;    1 0 0 0 .... 1800 baud    |  1 0 0 1 .... 2000 baud
  178. ;    1 0 1 0 .... 2400 baud    |  1 0 1 1 .... 3600 baud
  179. ;    1 1 0 0 .... 4800 baud  |  1 1 0 1 .... 7200 baud
  180. ;    1 1 1 0 .... 9600 baud    |  1 1 1 1 .... 19.2K baud
  181. ;     
  182. ;    COMMAND    REGISTER (base + 3)
  183. ;  +--------+--------+--------+--------+--------+--------+--------+--------+
  184. ;  | 00 - normal     | RTS    | ERROR  | FORCE  | RECV   | DTR    | TRNSMT |
  185. ;  | 01 - auto echo  | CTRL   | RESET  | BREAK  | CTRL   | CTRL   | CTRL   |
  186. ;  | 10 - lcl lopbak | 0 - hi | 0 -norm| 0 -norm| 0 -dsbl| 0 -hi  | 0 -dsbl|
  187. ;  | 11 - rmt lopbak | 1 - lo | 1 -rst | 1 -brk | 1 -enbl| 1 -lo  | 1 -enbl|
  188. ;  +--------+--------+--------+--------+--------+--------+--------+--------+
  189. ;
  190. ;    STATUS REGISTER (base + 1)
  191. ;  +--------+--------+--------+--------+--------+--------+--------+--------+
  192. ;  |        |        | FRAME  | OVERRUN| PARITY |Tx SHIFT| Rx CHAR| Tx BUFR|
  193. ;  | DSR lo | DCD lo | ERROR  | ERROR  | ERRORY |REGISTER| READY  |  EMPTY |
  194. ;  |        |        |        |        |        | EMPTY  |        |        |
  195. ;  +--------+--------+--------+--------+--------+--------+--------+--------+
  196. ;
  197. ;    MODE 1 register must be written into before MODE 2 - it is a toggle 
  198. ;    type operation. a COMMAND register <read> operation will reset the
  199. ;    toggle so the next MODE operation will be performed on the first 
  200. ;    register - REGISTER 1.
  201. ;
  202. ;******************************************************************************
  203. ;
  204. ; standard mex service processor hooks
  205. ;
  206. MEX    EQU    0D00H        ;address of the service processor
  207. INMDM    EQU    255        ;get char from port to a, cy=no more in 100 ms
  208. TIMER    EQU    254        ;delay 100ms * reg b
  209. TMDINP    EQU    253        ;b=# secs to wait for char, cy=no char
  210. CHEKCC    EQU    252        ;check for ^c from kbd, z=present
  211. SNDRDY    EQU    251        ;test for modem-send ready
  212. RCVRDY    EQU    250        ;test for modem-receive ready
  213. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  214. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  215. LOOKUP    EQU    247        ;table search: see cmdtbl comments for info
  216. PARSFN    EQU    246        ;parse filename from input stream
  217. BDPARS    EQU    245        ;parse baud-rate from input stream
  218. SBLANK    EQU    244        ;scan input stream to next non-blank
  219. EVALA    EQU    243        ;evaluate numeric from input stream
  220. LKAHED    EQU    242        ;get nxt char w/o removing from input
  221. GNC    EQU    241        ;get char from input, cy=1 if none
  222. ILP    EQU    240        ;inline print
  223. DECOUT    EQU    239        ;decimal output
  224. PRBAUD    EQU    238        ;print baud rate
  225. ;
  226. CONOUT    EQU    2        ;simulated bdos function 2: console char out
  227. PRINT    EQU    9        ;simulated bdos function 9: print string
  228. INBUF    EQU    10        ;input buffer, same structure as bdos 10
  229. ;
  230. ; msc crud
  231. ;
  232. TPA    EQU    100H
  233. CR    EQU    13
  234. LF    EQU    10
  235. TAB    EQU    9
  236. DING    EQU    'G'-40H
  237. ;
  238. YES    EQU    0FFFFH        ;it is so
  239. NO    EQU    NOT YES     ;it is not so
  240. ;
  241. ;//////////////////////////////////////////////////////////////////////////////
  242. ;
  243.     ORG    TPA
  244. ;
  245. ;//////////////////////////////////////////////////////////////////////////////
  246. ;
  247.     DS    3        ;mex has a jmp start here
  248.     DS    2        ;not used by mex
  249. TPULSE:    DB    'T'        ;t=touch, p=pulse (used by this overlay)
  250. CLOCK:    DB    40        ;clock speed x 10 (up to 25.5 mhz.)
  251. MSPEED:    DB    5        ;sets display time for sending a file
  252.                 ;0=110    1=300  2=450  3=600  4=710
  253.                 ;5=1200 6=2400 7=4800 8=9600 9=19200
  254. BYTDLY:    DB    5        ;default time to send character in
  255.                 ;terminal mode file transfer (0-9)
  256.                 ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  257. CRDLY:    DB    5        ;end-of-line delay after crlf in terminal
  258.                 ;mode file transfer for slow bbs systems
  259.                 ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  260. COLUMS:    DB    5        ;number of directory columns
  261. SETFL:    DB    YES        ;yes=user-defined set command
  262. SCRTST:    DB    YES        ;yes=if home cursor and clear screen
  263.                 ;routine at clrscrn
  264.     DB    0        ;was once acknak, now spare
  265. BAKFLG:    DB    YES        ;yes=make .bak file
  266. CRCDFL:    DB    YES        ;yes=default to crc checking
  267.                 ;no=default to checksum checking
  268. TOGCRC:    DB    YES        ;yes=allow toggling of checksum to crc
  269. CVTBS:    DB    NO        ;yes=convert backspace to rub
  270. TOGLBK:    DB    YES        ;yes=allow toggling of bksp to rub
  271. ADDLF:    DB    NO        ;no=no lf after cr to send file in
  272.                 ;terminal mode (added by remote echo)
  273. TOGLF:    DB    YES        ;yes=allow toggling of lf after cr
  274. TRNLOG:    DB    NO        ;yes=allow transmission of logon
  275.                 ;write logon sequence at location logon
  276. SAVCCP:    DB    YES        ;yes=do not overwrite ccp
  277. LOCNXT:    DB    NO        ;yes=local cmd if extchr precedes
  278.                 ;no=not local cmd if extchr precedes
  279. TOGLOC:    DB    YES        ;yes=allow toggling of locnxtchr
  280. LSTTST:    DB    YES        ;yes=allow toggling of printer on/off
  281.                 ;in terminal mode. set to no if using
  282.                 ;the printer port for the modem
  283. XOFTST:    DB    NO        ;yes=allow testing of xoff from remote
  284.                 ;while sending a file in terminal mode
  285. XONWT:    DB    NO        ;yes=wait for xon after sending cr while
  286.                 ;transmitting a file in terminal mode    
  287. TOGXOF:    DB    YES        ;yes=allow toggling of xoff testing
  288. IGNCTL:    DB    NO         ;yes=do not send control characters
  289.                 ;above ctl-m to crt in terminal mode
  290.                 ;no=send any incoming ctl-char to crt
  291. EXTRA1:    DB    0        ;for future expansion
  292. EXTRA2:    DB    0        ;for future expansion
  293. BRKCHR:    DB    '@'-40H        ;^@ = send a 300 ms. break tone
  294. NOCONN:    DB    'N'-40H        ;^n = disconnect from phone line
  295. LOGCHR:    DB    'L'-40H        ;^l = send logon
  296. LSTCHR:    DB    'P'-40H        ;^p = toggle printer
  297. UNSVCH:    DB    'R'-40H        ;^r = close input text buffer
  298. TRNCHR:    DB    'T'-40H        ;^t = transmit file to remote
  299. SAVCHR:    DB    'Y'-40H        ;^y = open input text buffer
  300. EXTCHR:    DB    '^'-40H        ;^^ = send next character
  301. ;
  302.     DS    2        ;not used
  303. ;
  304. ; low-level modem i/o routines.
  305. ;
  306. INCTL1:    JMP    INC        ;in modem control port
  307.     DB    0,0,0,0,0,0,0    ;spares if needed for non-pmmi
  308. ;
  309. OTDATA:    JMP    OUTD        ;out modem data port
  310.     DB    0,0,0,0,0,0,0    ;spares if needed for non=pmmi
  311. ;
  312. INPORT: JMP    IND        ;in modem data port
  313.     DB    0,0,0,0,0,0,0    ;spares if needed for non-pmmi
  314. ;
  315. ; bit-test routines. 
  316. ;
  317. MASKR:    ANI MDRCVB ! RET    ;bit to test for receive ready
  318. TESTR:    CPI MDRCVR ! RET    ;value of receive bit when ready
  319. MASKS:    ANI MDSNDB ! RET    ;bit to test for send ready
  320. TESTS:    CPI MDSNDR ! RET    ;value of send bit when ready
  321. ;
  322.     DS    12
  323. ;
  324. LOGON:    DS    2        ;needed for mdm compat, not ref'D BY MEX
  325. DIALV:    JMP    DIAL
  326. DISCV:    JMP    DISCON
  327. GOODBV:    JMP    GOODBYE        ;called before exit to cp/m
  328. INMODV:    JMP    NITMOD        ;initialization. called at cold-start
  329. NEWBDV:    JMP    PBAUD        ;set baud rate
  330. NOPARV:    RET!NOP!NOP        ;set modem for no-parity
  331. PARITV:    RET!NOP!NOP        ;set modem parity
  332. SETUPV:    JMP    SETCMD        ;set cmd: jump to a ret if you don'T WRITE SET
  333. SPMENV:    RET!NOP!NOP        ;not used with mex
  334. VERSNV:    JMP    SYSVER        ;overlay'S VOICE IN THE SIGN-ON MESSAGE
  335. BREAKV:    JMP    SBREAK        ;send a break
  336. ;
  337. ; mdm calls supported in mex 1.0 but not recommended for use.
  338. ;
  339. ILPRTV:    DS    3        ;replace with mex function 9
  340. INBUFV:    DS    3        ;replace with mex function 10
  341. ILCMPV:    DS    3        ;replace with table lookup funct. 247
  342. INMDMV:    DS    3        ;replace with mex function 255
  343. NXSCRV:    DS    3        ;not supported by mex (returns w/no action)
  344. TIMERV:    DS    3        ;replace with mex function 254
  345. ;
  346. ; terminal specific control sequences
  347. ;
  348. ; if you wish to use the terminal screen operations, uncomment the code below 
  349. ; and insert your terminal specific routines at the clsmsg and eosmsg string 
  350. ; areas.
  351. ;    
  352. CLREOS:        
  353. ;    lxi    d,eosmsg
  354. ;    mvi    c,print
  355. ;    call    mex
  356.     RET
  357. ;
  358. CLS:    
  359. ;    lxi    d,clsmsg
  360. ;    mvi    c,print
  361. ;    call    mex
  362.     RET
  363. ;
  364. ; put your terminal specific strings here ... (I don't know what they are) 
  365. ;    ... dont forget the '$'
  366. ;
  367. EOSMSG:      DB    17H,'$'        ;clear to end-of-screen
  368. CLSMSG:      DB    1AH,'$'        ;clear whole screen
  369. ;
  370. ;------------------------------------------------------------
  371. ;
  372. ; input control/status port
  373. ;
  374. INC:    IN    SPORT        ; get the status bits
  375.     RET
  376. ;
  377. ; input data port
  378. ;
  379. IND:    IN    DATAPT        
  380.     RET
  381. ;
  382. ; output data port
  383. ;
  384. OUTD:    OUT    DATAPT
  385.     RET
  386. ;
  387. ; print out the overlay version
  388. ;
  389. SYSVER:      CALL    MILP
  390.       DB    'Toshiba Support Group Serial Interface',CR,LF
  391. ;      DB    'Trashiba T100 - V'     ;he.. he.. he...
  392.       DB    'Toshiba T100 - V'    
  393.       DB    REV/10+'0'
  394.       DB    '.'
  395.       DB    REV MOD 10+'0'
  396.       DB    CR,LF
  397.       DB    0
  398.       RET
  399. ;
  400. ; send break routine
  401. ;
  402. SBREAK: 
  403. ;
  404. ; disconnect routine
  405. ;
  406. DISCON:   
  407. ;
  408. ; goodbye routines are called by mex prior to exit to cp/m
  409. ;
  410. GOODBYE:MVI    A,00011101B    ; drop cts, dtr and force break a
  411.     OUT    CPORT
  412.     MVI    B,3        ; 300 ms
  413.     CALL    MTIME
  414.     MVI    A,00100111B    ; initial default
  415.     OUT    CPORT
  416.     RET
  417. ;
  418. ; initialize rs-232 to default modes.
  419. ;
  420. NITMOD: CALL    INC        ;see if carrier ie returning to mex with
  421.     ANI    MDMDCD        ;a call active 
  422.     RNZ            ;skip if connected
  423.  
  424.     LDA    SPEED        ; load default ascii baud rate 
  425.     STA    MSPEED        ;and keep it current
  426.     CALL    PBAUD        ;set the baud rate
  427. ;
  428. ; default the modem to either speaker ON or OFF - as CLONED
  429. ;
  430.     LDA    MONFLG        ;get monitor default
  431.     ORA    A
  432.     MVI    A,'0'        ;speaker off
  433.     JZ    NIT4
  434.     MVI    A,'1'        ;speaker on
  435.  
  436. NIT4:      STA    SMINIT+3    ;put it in sminit string
  437. ;
  438. ; default the modem mode to either answer or originate - as CLONED
  439. ; 
  440.     LDA    ANSFLG        ;get mode default
  441.     ORA    A
  442.     MVI    A,'0'        ;originate
  443.     JZ    NIT5
  444.     MVI    A,'1'        ;answer
  445.  
  446. NIT5:      STA    S0NIT+3        ;put it in sminit string
  447. ;
  448. ; set up the modem with the initial string 
  449. ;    
  450.     LXI    H,SMINIT
  451. SINIT:    CALL    SMSEND        ;send the init string
  452. SMTLP1:    MVI    C,INMDM        ;wait for modem response
  453.     CALL    MEX
  454.     JNC    SMTLP1        ;eat everything until silence for
  455.     RET            ; 100 msec
  456. ;
  457. ; set command processor
  458. ;
  459. SETCMD:      MVI    C,SBLANK    ;any arguments?
  460.       CALL  MEX
  461.       JC    SETSHO        ;if not, display default(s)
  462.       LXI    D,CMDTBL
  463.           MVI    C,LOOKUP
  464.       CALL  MEX        ;parse the argument
  465.       PUSH    H        ;save any parsed arguments on stack
  466.       RNC            ;if we have one, return to it
  467.       POP    H        ;oops, input not found in table
  468. SETERR:      LXI    D,SETEMS
  469.       MVI    C,PRINT
  470.       CALL    MEX
  471.       CALL  CRLF
  472.       RET
  473. SETEMS:      DB    CR,LF,'Unrecognized SET command',DING,CR,LF,'$'
  474. ;
  475. SETBAD:      LXI    D,SETBMS
  476.       MVI    C,PRINT
  477.       CALL    MEX
  478.       RET
  479. SETBMS:      DB    CR,LF,'Invalid SET parameter',DING,CR,LF,'$'
  480. ;
  481. ; argument table
  482. ;
  483. CMDTBL:   DB    '?'+80H            ; help
  484.       DW    SETHELP
  485.       DB    'ORI','G'+80H        ; originate mode
  486.       DW    ORIG
  487.       DB    'ANSWE','R'+80H        ; answer mode
  488.       DW    ANS
  489.       DB    'TON','E'+80H        ; tone dialing
  490.       DW    STTONE
  491.       DB    'PULS','E'+80H        ; pulse dialing
  492.       DW    STPULSE
  493.       DB    'MONITO','R'+80H    ; monitor on
  494.       DW    MONIT
  495.       DB    'QUIE','T'+80H        ; monitor off
  496.       DW    QUIET
  497.       DB    'BAU','D'+80H        ; set baud
  498.       DW    STBAUD
  499.       DB    'DELA','Y'+80H        ; set delay
  500.       DW    DELAY
  501.       DB    'PARIT','Y'+80H        ; set parity
  502.       DW    STPRTY
  503.       DB    'STO','P'+80H        ; set stopbits
  504.       DW    STSTOP
  505.       DB    'BIT','S'+80H        ; set length
  506.       DW    STBITS
  507.       DB    'DIGI','T'+80H        ; set inter-digit delay
  508.       DW    SDIGIT
  509.       DB    0            ;table terminator
  510. ;
  511. ;  "set (no args): print current statistics
  512. ;
  513. SETSHO:      CALL  MILP
  514.       DB    CR,LF
  515.       DB    'Current settings:',CR,LF,0
  516.       CALL    CRLF
  517.       CALL    TPSHOW
  518.       CALL    CRLF
  519.       CALL    BDSHOW
  520.       CALL  CRLF
  521.       CALL    MONSHO
  522.       CALL    CRLF
  523.       CALL  SHOWP
  524.       CALL    CRLF
  525.       CALL    SHOWS
  526.       CALL    CRLF
  527.       CALL  SHOWBT
  528.       CALL  CRLF
  529.       CALL    DLSHOW
  530.       CALL    CRLF
  531.       CALL    DDSHOW
  532.       CALL  CRLF
  533.       CALL  CRLF
  534.       RET
  535. ;
  536. ; "set ?" processor
  537. ;
  538. SETHELP:  CALL    MILP
  539.       DB    CR,LF,'SET ORIG      - Modem Originate mode'
  540.       DB    CR,LF,'SET ANSWER    - Modem Answer mode'
  541.       DB    CR,LF,'SET TONE      - Touch Tone dial'
  542.       DB    CR,LF,'SET PULSE     - Dial Pulse dial'
  543.       DB    CR,LF,'SET PARITY    - None, Even or Odd'
  544.       DB    CR,LF,'SET STOP      - 1, 1.5 or 2'
  545.       DB    CR,LF,'SET BITS      - 5, 6, 7 or 8'
  546.       DB    CR,LF,'SET QUIET     - Speaker Off'
  547.       DB    CR,LF,'SET MONITOR   - Speaker On'
  548.       DB    CR,LF,'SET BAUD <X>  - <X> = 110, 300, 600, 1200, 2400, '
  549.       DB    '4800, 9600, 19200'
  550.       DB    CR,LF,'SET DELAY <X> - <X> seconds'
  551.       DB    CR,LF,'SET DIGIT <X> - <X> 0-99 mS'    
  552.       DB    CR,LF,CR,LF,0
  553.       RET
  554. ;
  555. ; "set baud" processor
  556. ;
  557. STBAUD:          MVI    C,BDPARS    ;function code: parse a baudrate
  558.           CALL    MEX        ;let mex look up code
  559.           JC    SETERR        ;jump if invalid code
  560.           CALL    PBAUD        ;no, try to set it
  561.           JC    SETERR        ;if not one of ours, bomb out
  562. ;
  563. ; let MEX print the baud rate
  564. ;
  565. BDSHOW:          LDA    MSPEED        ;get current baud rate
  566.           MVI    C,PRBAUD    ;let mex print it
  567.           CALL    MEX
  568.           RET 
  569. ;
  570. ; this routine sets baud rate passed as mspeed code in a.
  571. ; returns cy=1 if baud rate not supported.
  572. ;
  573. PBAUD:          PUSH    H        ;don't alter anyboby
  574.           PUSH    D
  575.           PUSH     B
  576. ;
  577.         LXI    H,BAUDS        ; get the table base
  578.         MOV    E,A
  579.         MVI    D,00
  580.         DAD    D        ; offset it
  581.         MOV    A,M
  582.         CPI    11111111B    ; is it bad ?
  583.         STC
  584.         JZ    BADEX        ; yup - quit now
  585. ;
  586. ; selected rate is good ... save parameters
  587. ;
  588.         STA    DFTBAUD        ; setup for reinitialization
  589.         MOV    A,E
  590.         STA    SPEED        ; save it in case of CLONE command
  591.         STA    MSPEED
  592.         CALL    SINITL        ; reinitialize the usart
  593.         STC        
  594.         CMC            ; no error here
  595. BADEX:        POP    B
  596.           POP    D
  597.           POP    H
  598.         RET
  599. ;
  600. ; lookup table for all of the valid bit rates 
  601. ;
  602. BAUDS:        DB    00000010B    ; 110 baud
  603.         DB    00000101B    ; 300 baud
  604.         DB    11111111B    ; 450 baud    
  605.         DB    00000110B    ; 600 baud
  606.         DB    11111111B    ; 710 baud
  607.         DB    00000111B    ; 1200 baud
  608.         DB    00001010B    ; 2400 baud
  609.         DB    00001100B    ; 4800 baud
  610.         DB    00001110B    ; 9600 baud
  611.         DB    00001111B    ; 19.2k baud
  612. ;
  613. ; "set mode" processor
  614. ;
  615. ORIG:    XRA    A
  616.     STA    ANSFLG        ;set orig flag
  617.     LXI    H,SMO        ;send out ats0=0
  618.     CALL    SINIT
  619.     CALL    MILP
  620.     DB    'Originate mode',0
  621.     RET
  622. ;
  623. ANS:    MVI    A,0FFH
  624.     STA    ANSFLG        ;set ans flag
  625.     LXI    H,SMA        ;send out ats0=1
  626.     CALL    SINIT
  627.     CALL    MILP
  628.     DB    'Answer mode',0
  629.     RET
  630. ;
  631. SMO:    DB    'ATS0=0',CR,0
  632. SMA:    DB    'ATS0=1',CR,0
  633. ;
  634. ;
  635. ; "monitor" processor
  636. ;
  637. QUIET:    XRA    A
  638.     STA    MONFLG
  639.     LXI    H,SMQT
  640.     CALL    SINIT
  641.     JMP    MONSHO
  642.  
  643. MONIT:    MVI    A,0FFH
  644.     STA    MONFLG
  645.     LXI    H,SMMON
  646.     CALL    SINIT
  647.  
  648. MONSHO:    LDA    MONFLG
  649.     ORA    A
  650.     JZ    MONOFF
  651.     CALL    MILP
  652.     DB    'Speaker On',0
  653.     RET
  654.  
  655. MONOFF:    CALL    MILP
  656.     DB    'Speaker Off',0
  657.     RET
  658.  
  659. SMQT:    DB    'ATM0',CR,0
  660. SMMON:    DB    'ATM1',CR,0
  661. ;
  662. ; "dial" processor
  663. ;
  664. STTONE:    MVI    B,'T'
  665.     JMP    SDIAL1
  666. STPULSE:MVI    B,'P'
  667.  
  668. SDIAL1: LDA    TPULSE
  669.     CPI    B
  670.     JZ    TPSHOW
  671.     MOV    A,B
  672.     STA    TPULSE
  673.     CPI    'P'
  674.     MVI    A,01010000B    ;pulse dial
  675.     JZ    SDIAL2
  676.     MVI    A,01000000B    ;tone dial
  677. SDIAL2: STA    DIALWD
  678.  
  679. TPSHOW:    LDA    DIALWD
  680.     ANI    00010000B
  681.     JZ    TPTONE
  682.  
  683.     CALL    MILP
  684.     DB    'Pulse Dial',0
  685.     RET
  686.  
  687. TPTONE:    CALL    MILP
  688.     DB    'Tone Dial',0      
  689.     RET
  690. ;
  691. ; "delay" processor
  692. ;
  693. DELAY:    MVI    C,EVALA
  694.     CALL    MEX
  695.     MOV    A,H
  696.     ORA    A
  697.     JNZ    SETERR
  698.     MOV    A,L
  699.     CPI    100        ;too big ?
  700.     JNC    SETERR
  701.  
  702.     PUSH    D        ; convert binary to ascii
  703.     CALL    CVDCML
  704.     MOV    A,D
  705.     STA    S7NIT+3        ; 10's digit
  706.     STA    LDSTR+5
  707.     MOV    A,E
  708.     STA    S7NIT+4        ; 1's digit
  709.     STA    LDSTR+6
  710.     POP    D
  711.  
  712.     LXI    H,LDSTR        ; send the local string to the modem
  713.     CALL    SMSEND
  714.  
  715. DLSHOW:    CALL    MILP        ;finally tell the user about it
  716.     DB    'Answer delay is ',0
  717. ;
  718.     LDA    S7NIT+3        ;print 10'S DIGIT
  719.     MOV    E,A    
  720.     MVI    C,CONOUT
  721.     CALL    MEX
  722. ;
  723.     LDA    S7NIT+4        ;print 1'S DIGIT
  724.     MOV    E,A    
  725.     MVI    C,CONOUT    
  726.     CALL    MEX
  727. ;
  728.     CALL    MILP        ;print units
  729.     DB    ' Seconds.',0
  730.     RET
  731.  
  732. LDSTR:    DB    'ATS7=30',CR,0
  733.  
  734. ;
  735. ; "digit" processor - interdigit time 
  736.  
  737. SDIGIT:    MVI    C,EVALA
  738.     CALL    MEX
  739.     MOV    A,H
  740.     ORA    A
  741.     JNZ    SETERR
  742.     MOV    A,L
  743.     CPI    100        ;too big ?
  744.     JNC    SETERR
  745. ;
  746.     PUSH    D        ; convert binary to ascii
  747.     CALL    CVDCML
  748.     MOV    A,D
  749.     STA    S11NIT+4    ; 10's digit
  750.     STA    LSTR+6
  751.     MOV    A,E
  752.     STA    S11NIT+5    ; 1's digit
  753.     STA    LSTR+7
  754.     POP    D
  755. ;
  756.     LXI    H,LSTR        ; send the local string to the modem
  757.     CALL    SMSEND
  758.  
  759. DDSHOW:    CALL    MILP        ;finally tell the user about it
  760.     DB    'Dial digit time is ',0
  761. ;
  762.     LDA    S11NIT+4        ;print 10'S DIGIT
  763.     MOV    E,A    
  764.     MVI    C,CONOUT
  765.     CALL    MEX
  766. ;
  767.     LDA    S11NIT+5        ;print 1'S DIGIT
  768.     MOV    E,A    
  769.     MVI    C,CONOUT    
  770.     CALL    MEX
  771. ;
  772.     CALL    MILP        ;print units
  773.     DB    ' Ms.',0
  774.     RET
  775.  
  776. LSTR:    DB    'ATS11=40',CR,0
  777. ;
  778. ; convert to ascii the hard way
  779. ;
  780. CVDCML:    MVI    B,0        ; make ascii out of 7 bit binary 
  781. TENS:    SUI    10
  782.     JC    ONES        ; gone negative yet ?
  783.     INR    B
  784.     JMP    TENS        ; nope... keep bumping the 10'S DIGIT
  785. ;
  786. ONES:    ADI    10        ; fix it
  787.     PUSH    PSW        ; save the number for a sec
  788.     MOV    A,B
  789.     ADI    '0'        ; add in the ascii bias
  790.     MOV    D,A
  791.     POP    PSW
  792.      ADI    '0'        ; add in the ascii bias - must be 0-9
  793.     MOV    E,A
  794.     RET
  795.  
  796. ;
  797. ;    set parity command: reset transmit/receive parity
  798. ;
  799. ;        parity is controlled by bits 4 and 5 of mode register 1
  800. ;        for the 2651 
  801. ;
  802. ;           parity    bit 5       bit 4
  803. ;                 off          -          0
  804. ;              odd      0         1
  805. ;             even      1         1
  806. ;
  807. STPRTY:    MVI    C,SBLANK    ;check for parity code
  808.     CALL    MEX        ;
  809.     JC    SETERR        ;if none, print error
  810.     LXI    D,PARTBL    ;check for proper syntax
  811.     MVI    C,LOOKUP
  812.     CALL    MEX
  813.     PUSH    H        ;match found, go do it!
  814.     RNC            ;
  815.     POP    H        ;no match: fix stack and
  816.     JMP    SETERR        ;  print error
  817. ;
  818. PROFF:    MVI    A,00000000B
  819.     STA    DFTPAR
  820.     JMP    SHOWP1
  821.  
  822. PREVEN:    MVI    A,00110000B
  823.     STA    DFTPAR
  824.     JMP    SHOWP1
  825.  
  826. PRODD:    MVI    A,00010000B
  827.     STA    DFTPAR
  828.  
  829. SHOWP1:    CALL    SINITL
  830.  
  831. SHOWP:    LDA    DFTPAR
  832.     RRC
  833.     RRC    
  834.     RRC
  835.     RRC
  836.     ANI    00000011B
  837.     ADD    A
  838.     MOV    E,A
  839.     MVI    D,00
  840.     PUSH    D
  841.     CALL    MILP        ;display parity
  842.     DB    'Parity is ',0
  843.     POP    D
  844.     LXI    H,PVECT
  845.     DAD    D
  846.     MOV    A,M
  847.     INX    H
  848.     MOV    H,M
  849.     MOV    L,A
  850.     PCHL
  851.  
  852. PVECT:    DW    OFFMSG
  853.     DW    ODDMSG
  854.     DW    OFFMSG        
  855.     DW    EVNMSG
  856.     
  857. OFFMSG:    CALL    MILP        ;
  858.     DB    '(None)',0    ;
  859.     RET
  860.  
  861. ODDMSG:    CALL    MILP        ;
  862.     DB    'Odd',0        ;
  863.     RET            ;
  864.  
  865. EVNMSG:    CALL    MILP        ;
  866.     DB    'Even',0    ;
  867.     RET
  868. ;
  869. ;    set parity command table
  870. ;
  871. PARTBL:      DB    'NON','E'+80H    ;"set parity off"
  872.       DW    PROFF
  873.       DB    'EVE','N'+80H    ;"set parity even"
  874.       DW    PREVEN
  875.       DB    'OD','D'+80H    ;"set parity odd"
  876.       DW    PRODD
  877.       DB    0        ;<<== end of parity table
  878. ;
  879. ;    set stopbits command: reset number of stop bits
  880. ;
  881. ;        the stop bits are controlled by bits 7 and 8 of mode register 
  882. ;        1 for the 2651 
  883. ;
  884. ;            stop bits       bit 7    bit 8
  885. ;            1         0            1
  886. ;               1.5         1          0
  887. ;            2         1          1
  888. ;
  889. ;
  890. STSTOP:      MVI    C,SBLANK    ;check for stop bits
  891.       CALL    MEX
  892.       JC    SETERR        ;if none, print error
  893.       LXI    D,STPTBL    ;check syntax
  894.       MVI   C,LOOKUP
  895.       CALL    MEX
  896.       PUSH    H        ;match found, go do it!
  897.       RNC    
  898.       POP    H        ;no match: fix stack and
  899.       JMP    SETERR        ;print error
  900. ;
  901. STOP01:    MVI    A,01000000B    ; 1 stop bit
  902.     STA    DFTSTP
  903.     JMP    SHOWS
  904. ;
  905. STOP02:    MVI    A,11000000B    ; 2 stop bits
  906.     STA    DFTSTP
  907.     JMP    SHOWS
  908. ;
  909. STOP15:    MVI    A,10000000B    ; 1 1/2 stop bits
  910.     STA    DFTSTP
  911. ;
  912. SHOWS:    LDA    DFTSTP        ; print the current setting
  913.     RRC
  914.     RRC
  915.     RRC
  916.     RRC
  917.     RRC
  918.     RRC
  919.     ANI    00000011B    ; mask any possible crap    
  920.     ADD    A        ; <a> * 2
  921.     MOV    E,A
  922.     MVI    D,00
  923.     PUSH    D
  924.     CALL    SINITL        ; reinit the usart
  925.     CALL    MILP
  926.     DB    'There ',0
  927.     POP    D
  928.     LXI    H,SVECT
  929.     DAD    D
  930.     MOV    A,M        ; dispatch
  931.     INX    H
  932.     MOV    H,M
  933.     MOV    L,A
  934.     PCHL
  935.  
  936. SVECT:    DW    MSG0
  937.     DW    MSG1
  938.     DW    MSG15
  939.     DW    MSG2
  940.  
  941. MSG0:    CALL    MILP
  942.     DB    'is an INVALID MODE COMMAND - UNKNOWN ERROR in MEX'
  943.     DB    DING,CR,LF,0
  944.     RET
  945.  
  946. MSG1:    CALL    MILP        ; display '1'    
  947.     DB    'is 1 stop bit',0        ;
  948.     RET
  949.  
  950. MSG2:     CALL    MILP        ; display '2' 
  951.      DB    'are 2 stop bits',0        ;
  952.      RET
  953.  
  954. MSG15:    CALL    MILP        ; display '1.5'
  955.     DB    'are 1.5 stop bits',0
  956.     RET
  957.  
  958. ;    set stopbits command table
  959. ;
  960. STPTBL:      DB    '1'+80H        ;"set stop 1"
  961.       DW    STOP01
  962.       DB    '2'+80H        ;"set stop 2"
  963.       DW    STOP02
  964.       DB    '1.','5'+80H    ;"set stop 1.5"
  965.       DW    STOP15
  966.       DB    0        ;<<== end of stop-bits table
  967. ;
  968. ;    set length command: set bits per character
  969. ;
  970. ;        the number of bits per character is controlled by 
  971. ;        bits 3 and 2 of mode register 1 for the 2651
  972. ;        3 only, but are the same for register 5:
  973. ;
  974. ;            bpc        bit 3        bit 2
  975. ;             5          0          0
  976. ;             6          0             1
  977. ;             7          1          0
  978. ;             8          1          1
  979. ;
  980. STBITS:      MVI    C,SBLANK    ;check for bits/char
  981.       CALL    MEX
  982.       JC    SETERR        ;if none, print error
  983.       LXI    D,BITTBL    ;check syntax
  984.       MVI    C,LOOKUP
  985.       CALL    MEX
  986.       PUSH    H        ;match found, go do it!
  987.       RNC    
  988.       POP    H        ;no match: fix stack and
  989.       JMP    SETERR        ;print error
  990. ;
  991. BIT5:    MVI    A,00000000B
  992.     STA    DFTBITS
  993.     JMP    SHOWBT
  994.  
  995. BIT6:    MVI    A,00000100B
  996.     STA    DFTBITS
  997.     JMP    SHOWBT
  998.  
  999. BIT7:    MVI    A,00001000B
  1000.     STA    DFTBITS
  1001.     JMP    SHOWBT
  1002.  
  1003. BIT8:    MVI    A,00001100B
  1004.     STA    DFTBITS
  1005.  
  1006. SHOWBT:    LDA    DFTBITS        ; get default setting
  1007.     RRC
  1008.     RRC
  1009.     ANI    00000011B    ; mask garbage if any
  1010.     ADD    A        ; <a> * 2
  1011.     MOV    E,A
  1012.     MVI    D,00
  1013.     PUSH    D
  1014.     CALL    SINITL        ; reinit the usart
  1015.     CALL    MILP
  1016.     DB    'There are ',0
  1017.     POP    D
  1018.     LXI    H,BVECT
  1019.     DAD    D
  1020.     MOV    A,M
  1021.     INX    H
  1022.     MOV    H,M
  1023.     MOV    L,A
  1024.     PCHL
  1025.  
  1026. BVECT:    DW    BITS5
  1027.     DW    BITS6
  1028.     DW    BITS7
  1029.     DW    BITS8
  1030.  
  1031. BITS5:      CALL    MILP        ; display '5'
  1032.       DB    '5 bits/char',0        
  1033.       RET            
  1034. BITS6:      CALL    MILP        ; display '6'
  1035.       DB    '6 bits/char',0        
  1036.       RET            
  1037. BITS7:      CALL    MILP        ; display '7'
  1038.       DB    '7 bits/char',0        
  1039.       RET            
  1040. BITS8:      CALL    MILP        ; display '8'
  1041.       DB    '8 bits/char',0        
  1042.       RET            
  1043. ;
  1044. ;    set length command table
  1045. ;
  1046. BITTBL:      DB    '5'+80H        ;"set bits 5"
  1047.       DW    BIT5
  1048.       DB    '6'+80H        ;"set bits 6"
  1049.       DW    BIT6
  1050.       DB    '7'+80H        ;"set bits 7"
  1051.       DW    BIT7
  1052.       DB    '8'+80H        ;"set bits 8"
  1053.       DW    BIT8
  1054.       DB    0        ;<<== end of bpc table
  1055. ;
  1056. ;
  1057. ; build the default initialization from ram so as to be cloneable
  1058. ;
  1059. SINITL:    IN    CPORT        ; reset the mode registers    
  1060.     LDA    DFTSTP        ; get default stop bits
  1061.     MOV    B,A
  1062.     LDA    DFTPAR        ; get default parity
  1063.     ORA    B
  1064.     MOV    B,A
  1065.     LDA    DFTBITS        ; get default character length
  1066.     ORA    B
  1067.     ORI    00000010B    ; force divide by 16 - use internal baud gen
  1068.     OUT    MODE1        ; set the register
  1069.  
  1070.     LDA    DFTBAUD        ; get the default baud rate
  1071.     ORI    00110000B    ; force internal clocks
  1072.     OUT    MODE2        ; set the register
  1073.  
  1074.     MVI    A,00100111B    ; force dtr, cts, async, txe, rxe, no loopbak
  1075.     OUT     CPORT
  1076.     RET
  1077. ;
  1078. ;
  1079. ; smartmodem dialing routine ... by a "cast of thousands"
  1080. ;
  1081. DIAL:      LHLD    DIALPT        ;fetch pointer
  1082.       CPI    254        ;start dial?
  1083.       JZ    STDIAL1        ;jump if so
  1084.       CPI    255        ;end dial?
  1085.       JZ    ENDIAL1        ;jump if so
  1086. ;
  1087. ; not start or end sequence, must be a digit to be sent to the modem
  1088. ;
  1089.       MOV    M,A        ;put char in buffer
  1090.       INX    H        ;advance pointer
  1091.       SHLD    DIALPT        ;stuff pntr
  1092.       RET            ;all done
  1093. ;
  1094. ; here on a start-dial sequence
  1095. ;
  1096. STDIAL1:  LXI    H,DIALBF    ;set up buffer pointer
  1097.       SHLD    DIALPT
  1098.       RET
  1099. ;
  1100. ; here on an end-dial sequence
  1101. ;
  1102. ENDIAL1:  MVI    M,CR        ;stuff end-of-line into buffer
  1103.       INX    H        ;followed by terminator
  1104.       MVI    M,0
  1105.       LDA    TPULSE        ;get overlay'S TOUCH-TONE FLAG
  1106.       STA    SMDIAL+3    ;put into string
  1107.       LXI    H,SMDIAL    ;point to dialing string
  1108.       CALL    SMSEND        ;send it
  1109. WAITSM:      MVI    C,INMDM
  1110.       CALL    MEX        ;catch any output from the modem
  1111.       JNC    WAITSM        ;loop until no more characters
  1112. ;
  1113. ; the following loop waits for a result from the modem.
  1114. ;
  1115. RESULT:      MVI    A,60        ; dont hang longer than a minute
  1116.       MOV    C,A
  1117.  
  1118. SMWLP:      PUSH    B
  1119.       MVI    B,1        ;check for a char, up to 1 sec wait
  1120.       MVI    C,TMDINP    ;do timed input
  1121.       CALL    MEX
  1122.       POP    B
  1123.       JNC    SMTEST        ;jump if modem had a char
  1124.       PUSH    B        ;no, test for control-c from console
  1125.       MVI    C,CHEKCC
  1126.       CALL    MEX
  1127.       POP    B
  1128.       JNZ    SMNEXT        ;if not, jump
  1129.       CALL    SMDMOFF        ;yes, shut down the modem
  1130.       MVI    A,3        ;return abort code
  1131.       RET
  1132. SMNEXT:      DCR    C        ;no
  1133.       JNZ    SMWLP        ;continue
  1134. ;
  1135. ; no modem response within the time specified in set delay command
  1136. ;
  1137. SMTIMO:    CALL    SMDMOFF
  1138.     MVI    A,2        ;return timeout code
  1139.     RET
  1140. ;
  1141. ; modem gave us a result, check it
  1142. ;
  1143. SMTEST:      ANI    7FH        ;ignore any parity
  1144.       CALL    SMANAL        ;test the result
  1145.       JC    RESULT        ;go try again if unknown response
  1146.       MOV    A,B        ;a=result 
  1147.       PUSH    PSW        ;save it
  1148. SMTLP:      MVI    C,INMDM        ;eat any additional chars from smartmodem
  1149.       CALL    MEX
  1150.       JNC    SMTLP        ;until 100ms of quiet time
  1151.       POP    PSW        ;return the code
  1152.       RET
  1153. ;
  1154. ; analyze character returned from modem
  1155. ;
  1156. SMANAL:      MVI    B,0        ;prep connect code
  1157.       CPI    'C'        ;"connect"?
  1158.       RZ
  1159.       CPI    '1'        ;numeric version of "connect"
  1160.       RZ
  1161.       CPI    '5'        ;numeric version of "connect 1200"
  1162.       RZ
  1163.       INR    B        ;prep busy code b=1
  1164.       CPI    'B'
  1165.       RZ
  1166.       INR    B        ;prep no connect msg b=2
  1167.       CPI    'N'        ;n=no connect
  1168.       RZ
  1169.       CPI    '3'        ;numeric version of "no connect"
  1170.       RZ
  1171.       MVI    B,4        ;prep modem error
  1172.       CPI    'E'        ;e=error
  1173.       RZ
  1174.       CPI    '4'        ;numeric version of "error"
  1175.       RZ
  1176. ;
  1177. ; unknown response, return carry to caller. but first,
  1178. ; flush the unknown response line from the modem.
  1179. ;
  1180. WTLF:      CPI    LF        ;linefeed?
  1181.       STC
  1182.       RZ            ;end if so
  1183.       MVI    C,INMDM        ;no. get next char
  1184.       CALL    MEX
  1185.       JNC    WTLF        ;unless busy, loop
  1186.       RET
  1187. ;
  1188. ; send string to the external modem
  1189. ;
  1190. SMSEND:      MVI    C,SNDRDY    ;wait for modem ready
  1191.       CALL    MEX
  1192.       JNZ    SMSEND
  1193.       MOV    A,M        ;fetch next character
  1194.       INX    H
  1195.       ORA    A        ;end?
  1196.       RZ            ;done if so
  1197.       MOV    B,A        ;no, position for sending
  1198.       MVI    C,SNDCHR    ;nope, send the character
  1199.       CALL    MEX
  1200.       JMP    SMSEND
  1201. ;
  1202. ; disconnect smodem - if DTR didnt, this will...
  1203. ;
  1204. SMDMOFF:  MVI    B,CR
  1205.       MVI    C,SNDCHR
  1206.       CALL    MEX
  1207.       MVI    B,10        ;one second wait for hayes, etc
  1208.            CALL    MTIME
  1209.       JMP    DISCON        ;make sure it is off
  1210. ;
  1211. ; general utility routines
  1212. ;
  1213. MILP:      MVI    C,ILP        ;in-line print
  1214.       JMP    MEX
  1215.       RET
  1216. ;
  1217. MTIME:      MVI    C,TIMER        ; mex timer
  1218.       JMP    MEX
  1219.       RET
  1220. ;
  1221. CRLF:      CALL    MILP        ; print carriage return, line feed
  1222.       DB    CR,LF,0
  1223.       RET
  1224.  
  1225. DONEW:      PUSH    H        ; save the new command string fro a sec 
  1226.       LXI    H,ATNSTR
  1227.       CALL    SMSEND        ; wake up the modem with 'AT'
  1228.       POP    H
  1229.       JMP    SINIT        ; now send the new parameter
  1230.  
  1231. ATNSTR:      DB    'AT',0
  1232. ;
  1233. ;==========================================================================
  1234. ;                            data area
  1235. ;==========================================================================
  1236. ;
  1237. ; default uart parameters 
  1238. ;
  1239. DFTSTP:       DB     01000000B    ; default stop bits - 1
  1240. DFTPAR:       DB     00000000B    ; default parity - none
  1241. DFTBITS:   DB     00001100B    ; default character length - 8 bits
  1242. DFTBAUD:   DB    00000000B    ; default baud rate scratch area 
  1243. ;
  1244. SMDIAL:      DB    'ATDT '        ; smartmodem dial prefix
  1245. DIALBF:      DS    52        ; 2* 24 char max, + cr + null + slop
  1246. DIALPT:      DS    2        ; dial position pointer
  1247. DIALWD:      DB    01000000B    ; pulse/tone dial word
  1248. DIGIT      DB    0        ; save dialed digit
  1249. SPEED:      DB    5        ; default baud rate 
  1250.                 ; 0=110,1=300,3=600,5=1200,6=2400
  1251.                 ; 7=4800,8=9600,9=19200 
  1252. MONFLG:      DB    0FFH        ; 0: monitor off - 0ffh: monitor on
  1253. ANSFLG:      DB    0        ; 0: originate   - 0ffh: ans
  1254. ;
  1255. SMATN:    DB    '+++',0        ; smartmodem online 'ATTENTION'
  1256. SMDISC:      DB    'ATH',CR,0    ; smartmodem disconnect 
  1257. SMINIT:   DB    'ATM1 '        ; speaker
  1258. S0NIT:      DB    'S0=0 '        ; answer ring counter
  1259. S7NIT:      DB    'S7=30'        ; carrier wait delay seconds
  1260. XNIT:      DB    'X1'        ; result code mode 
  1261. S11NIT:      DB    'S11=40 '    ; interdigit delay in ms
  1262.       DB    CR,0        ; modem init string
  1263.  
  1264. ;
  1265. ;******************************************************************************
  1266. ;
  1267.                   END
  1268. ;
  1269. ;******************************************************************************
  1270.