home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-SX10.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  29KB  |  823 lines
  1. ;
  2. ;
  3. ;
  4. ;
  5. REV     EQU     10              ;overlay revision level
  6. ;
  7. ; MEX STARPLEX OVERLAY VERSION 1.0: written 07/16/84 by Bill Meahan
  8. ;                                                       1951 S. Globe
  9. ;                                                       Westland, MI 48185
  10. ; I can also be contacted through MICROLINK-820 at:
  11. ;                 (313)487-0070 (24 hrs 300/1200 baud)
  12. ;
  13. ;
  14. ; This is a MEX overlay file for the National Semiconductor STARPLEX.
  15. ; Derived from the PMMI overlay by Ronald G. Fowler.
  16. ;
  17. ; This overlay should also work (except for the serial printer support) with
  18. ; systems based on the following single-board computers:
  19. ;                Intel          National
  20. ;                SBC80/20       BLC80/204
  21. ;                SBC80/20-4     BLC80/24
  22. ;                SBC80/24       BLC80/316
  23. ;                SBC80/30
  24. ;
  25. ; Intel development systems may have different addresses for the ports, but
  26. ; use the same arrangement of 8253 baud rate generators and 8251 USART's so
  27. ; this overlay should be EASILY adaptible to those systems as well.
  28. ;
  29. ;------------------------------------------------------------
  30. ;
  31. ; Misc equates
  32. ;
  33. NO    EQU    0
  34. YES     EQU     0FFH  
  35. TPA    EQU    100H
  36. CR    EQU    13
  37. LF    EQU    10
  38. TAB    EQU    9
  39. XON     EQU     011H
  40. XOFF    EQU     013H
  41. ;
  42. ; STARPLEX port definitions  (serial port 1)
  43. ;
  44. PORT    EQU     0ECH            ;STARPLEX base port (data or status)
  45. MODCT1  EQU     PORT+1          ;modem control port
  46. MODDAT  EQU     PORT            ;modem data port
  47. MODCT2  EQU     PORT+1          ;modem status port
  48. BAUDRP  EQU     0DDH            ;modem baud rate port
  49. BAUDMD  EQU     0DFH            ;modem baud rate mode control port
  50. ;
  51. ; STARPLEX bit definitions
  52. ;
  53. MDRCVB    EQU    02H        ;modem receive bit (DAV)
  54. MDRCVR    EQU    02H        ;modem receive ready
  55. MDSNDB    EQU    01H        ;modem send bit
  56. MDSNDR    EQU    01H        ;modem send ready bit
  57. ;
  58. ; 
  59. CTSMSK    EQU    4        ;mask for CTS bit
  60. BRKMSK  EQU     8               ;mask to set break
  61. PARMSK    EQU    0CFH        ;mask to remove parity bits
  62. OPARIT  EQU     10H             ;odd-parity bits
  63. EPARIT  EQU     30H             ;even-parity bits
  64. NPARIT  EQU     00H             ;no-parity bits
  65. PARTST  EQU     10H             ;mask to test parity enabled bit
  66. EVNTST  EQU     20H             ;mask to test even parity bit
  67. MODEMK  EQU     06EH            ;mode mask
  68. MODEGO  EQU     027H            ;default control command
  69. RSTCTL  EQU     040H            ;reset USART command
  70. BITS7   EQU     08H             ;mask for 7 bit characters
  71. BITS8   EQU     0CH             ;mask for 8 bit characters
  72. BITS8T  EQU     04H             ;mask to test for 8 bit characters
  73. STBIT1  EQU     040H            ;mask to set 1 stop bit
  74. STBI15  EQU     080H            ;mask to set 1.5 stop bits   
  75. STBIT2  EQU     0C0H            ;mask to set 2 stop bits
  76. ;
  77. ;
  78. ; MEX service processor stuff ... MEX supports an overlay service
  79. ; processor, located at 0D00H (and maintained at this address from
  80. ; version to version).  If your overlay needs to call BDOS for any
  81. ; reason, it should call MEX instead; function calls below about
  82. ; 240 are simply passed on to the BDOS (console and list I/O calls
  83. ; are specially handled to allow modem port queueing, which is why
  84. ; you should call MEX instead of BDOS).  MEX uses function calls
  85. ; above about 244 for special overlay services (described below).
  86. ;
  87. ; Some sophisticated overlays may need to do file I/O; if so, use
  88. ; the PARSFN MEX call with a pointer to the FCB in DE to parse out
  89. ; the name.  This FCB should support a spare byte immediately pre-
  90. ; ceeding the actual FCB (to contain user # information).  If you've
  91. ; used MEX-10 for input instead of BDOS-10 (or you're parsing part
  92. ; of a SET command line that's already been input), then MEX will
  93. ; take care of DU specs, and set up the FCB accordingly.  There-
  94. ; after all file I/O calls done through the MEX service processor
  95. ; will handle drive and user with no further effort necessary on
  96. ; the part of the programmer.
  97. ;
  98. MEX    EQU    0D00H        ;address of the service processor
  99. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  100. TIMER    EQU    254        ;delay 100ms * reg B
  101. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  102. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  103. SNDRDY    EQU    251        ;test for modem-send ready
  104. RCVRDY    EQU    250        ;test for modem-receive ready
  105. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  106. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  107. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  108. PARSFN    EQU    246        ;parse filename from input stream
  109. BDPARS    EQU    245        ;parse baud-rate from input stream
  110. SBLANK    EQU    244        ;scan input stream to next non-blank
  111. EVALA    EQU    243        ;evaluate numeric from input stream
  112. LKAHED    EQU    242        ;get nxt char w/o removing from input
  113. GNC    EQU    241        ;get char from input, cy=1 if none
  114. ILP    EQU    240        ;inline print
  115. DECOUT    EQU    239        ;decimal output
  116. PRBAUD    EQU    238        ;print baud rate
  117. ;
  118. ;
  119. CONOUT    EQU    2        ;simulated BDOS function 2: console char out
  120. PRINT    EQU    9        ;simulated BDOS function 9: print string
  121. INBUF    EQU    10        ;input buffer, same structure as BDOS 10
  122. ;
  123.     ORG    TPA        ;we begin
  124. ;
  125. ;
  126.     DS    3        ;MEX has a JMP START here
  127. ;
  128. ; The following variables are located at the beginning of the program
  129. ; to facilitate modification without the need of re-assembly. They will
  130. ; be moved in MEX 2.0.
  131. ;
  132. STRPLX: DB      YES             ;yes=STARPLEX modem \ / These 2 locations are not
  133. SMODEM: DB      NO              ;yes=Smartmodem     / \ referenced by MEX
  134.         DB      0               ;spare
  135. CLOCK:  DB      38              ;clock speed x .1, up to 25.5 mhz.
  136. MSPEED:    DB    1        ;sets display time for sending a file
  137.                 ;0=110    1=300  2=450  3=600  4=710
  138.                 ;5=1200 6=2400 7=4800 8=9600 9=19200
  139. BYTDLY:    DB    5        ;default time to send character in
  140.                 ;terminal mode file transfer (0-9)
  141.                 ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  142. CRDLY:    DB    5        ;end-of-line delay after CRLF in terminal
  143.                 ;mode file transfer for slow BBS systems
  144.                 ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  145. COLUMS:    DB    5        ;number of directory columns
  146. SETFL:    DB    YES        ;yes=user-defined SET command
  147. SCRTST: DB      YES             ;yes=if home cursor and clear screen
  148.                 ;routine at CLRSCRN
  149.     DB    0        ;was once ACKNAK, now spare
  150. BAKFLG:    DB    NO        ;yes=make .BAK file
  151. CRCDFL:    DB    YES        ;yes=default to CRC checking
  152.                 ;no=default to Checksum checking
  153. TOGCRC:    DB    YES        ;yes=allow toggling of Checksum to CRC
  154. CVTBS:    DB    NO        ;yes=convert backspace to rub
  155. TOGLBK:    DB    YES        ;yes=allow toggling of bksp to rub
  156. ADDLF:    DB    NO        ;no=no LF after CR to send file in
  157.                 ;terminal mode (added by remote echo)
  158. TOGLF:    DB    YES        ;yes=allow toggling of LF after CR
  159. TRNLOG:    DB    NO        ;yes=allow transmission of logon
  160.                 ;write logon sequence at location LOGON
  161. SAVCCP:    DB    YES        ;yes=do not overwrite CCP
  162. LOCNXT:    DB    NO        ;yes=local cmd if EXTCHR precedes
  163.                 ;no=not local cmd if EXTCHR precedes
  164. TOGLOC:    DB    YES        ;yes=allow toggling of LOCNXTCHR
  165. LSTTST:    DB    YES        ;yes=allow toggling of printer on/off
  166.                 ;in terminal mode. Set to no if using
  167.                 ;the printer port for the modem
  168. XOFTST:    DB    NO        ;yes=allow testing of XOFF from remote
  169.                 ;while sending a file in terminal mode
  170. XONWT:    DB    NO        ;yes=wait for XON after sending CR while
  171.                 ;transmitting a file in terminal mode    
  172. TOGXOF:    DB    YES        ;yes=allow toggling of XOFF testing
  173. IGNCTL:    DB    NO        ;yes=do not send control characters
  174.                 ;above CTL-M to CRT in terminal mode
  175.                 ;no=send any incoming CTL-char to CRT
  176. EXTRA1:    DB    0        ;for future expansion
  177. EXTRA2:    DB    0        ;for future expansion
  178. BRKCHR:    DB    '@'-40H        ;^@ = Send a 300 ms. break tone
  179. NOCONN:    DB    'N'-40H        ;^N = Disconnect from phone line
  180. LOGCHR:    DB    'L'-40H        ;^L = Send logon
  181. LSTCHR:    DB    'P'-40H        ;^P = Toggle printer
  182. UNSVCH:    DB    'R'-40H        ;^R = Close input text buffer
  183. TRNCHR:    DB    'T'-40H        ;^T = Transmit file to remote
  184. SAVCHR:    DB    'Y'-40H        ;^Y = Open input text buffer
  185. EXTCHR:    DB    '^'-40H        ;^^ = Send next character
  186. ;
  187. ; Equates used only by STARPLEX routines grouped together here.
  188. ;
  189.         DB      0               ;not used
  190.     DB    0        ;not used
  191. ;
  192. ; Low-level modem I/O routines: this will be replaced with
  193. ; a jump table in MEX 2.0 (you can insert jumps here to longer
  194. ; routines if you'd like ... I'd recommend NOT putting part of
  195. ; a routine in this area, then jumping to the rest of the routine
  196. ; in the non-fixed area; that will complicate the 2.0 conversion)
  197. ;
  198. INCTL1:    IN    MODCT1        ;in modem control port
  199.     RET
  200.         DB      0,0,0,0,0,0,0   ;spares if needed for non-STARPLEX
  201. ;
  202. OTDATA:    OUT    MODDAT        ;out modem data port
  203.     RET
  204.         DB      0,0,0,0,0,0,0   ;spares if needed for non=STARPLEX
  205. ;
  206. INPORT:    IN    MODDAT        ;in modem data port
  207.     RET
  208.         DB      0,0,0,0,0,0,0   ;spares if needed for non-STARPLEX
  209. ;
  210. ; Bit-test routines.  These will be merged with the above
  211. ; routines in MEX 2.0 to provide a more reasonable format
  212. ;
  213. MASKR:    ANI MDRCVB ! RET    ;bit to test for receive ready
  214. TESTR:    CPI MDRCVR ! RET    ;value of receive bit when ready
  215. MASKS:    ANI MDSNDB ! RET    ;bit to test for send ready
  216. TESTS:    CPI MDSNDR ! RET    ;value of send bit when ready
  217. ;
  218. ;
  219. ; Unused area: was once used for special STARPLEX functions,
  220. ; Now used only to retain compatibility with MDM overlays.
  221. ; You may use this area for any miscellaneous storage you'd
  222. ; like but the length of the area *must* be 12 bytes.
  223. ;
  224.     DS    12
  225. ;
  226. ; Special modem function jump table: 
  227. ;
  228. LOGON:    DS    2        ;needed for MDM compat, not ref'd by MEX
  229. DIALV:  DS      3               ;dial digit in A (see info at PDIAL)
  230. DISCV:  DS      3               ;disconnect the modem
  231. GOODBV:    JMP    DUMMY        ;called before exit to CP/M
  232. INMODV:    JMP    NITMOD        ;initialization. Called at cold-start
  233. NEWBDV:    JMP    PBAUD        ;set baud rate
  234. NOPARV: JMP     DUMMY           ;set modem for no-parity
  235. PARITV: JMP     DUMMY           ;set modem parity
  236. SETUPV:    JMP    SETCMD        ;SET cmd: jump to a RET if you don't write SET
  237. SPMENV:    DS    3        ;not used with MEX
  238. VERSNV:    JMP    SYSVER        ;Overlay's voice in the sign-on message
  239. BREAKV:    JMP    PBREAK        ;send a break
  240. ;
  241. ; The following jump vector provides the overlay with access to special
  242. ; routines in the main program (retained and supported in the main pro-
  243. ; gram for MDM overlay compatibility). These should not be modified by
  244. ; the overlay.
  245. ;
  246. ; Note that for MEX 2.0 compatibility, you should not try to use these
  247. ; routines, since this table will go away with MEX 2.0 (use the MEX
  248. ; service call processor instead).
  249. ;
  250. ILPRTV:    DS    3        ;replace with MEX function 9
  251. INBUFV:    DS    3        ;replace with MEX function 10
  252. ILCMPV:    DS    3        ;replace with table lookup funct. 247
  253. INMDMV:    DS    3        ;replace with MEX function 255
  254. NXSCRV:    DS    3        ;not supported by MEX (returns w/no action)
  255. TIMERV:    DS    3        ;replace with MEX function 254
  256. ;
  257. ;
  258. ; Clear/screen and clear/end-of-screen. Each routine must use the
  259. ; full 9 bytes alloted (may be padded with nulls).
  260. ;
  261. ; These routines (and other screen routines that MEX 2.0 will sup-
  262. ; port) will be accessed through a jump table in 2.0, and will be
  263. ; located in an area that won't tie the screen functions to the
  264. ; modem overlay (as the MDM format does).
  265. ;
  266. CLREOS:    LXI    D,EOSMSG
  267.     MVI    C,PRINT
  268.     CALL    MEX
  269.     RET
  270. ;
  271. ;
  272. CLS:    LXI    D,CLSMSG        ;null unless patched
  273.     MVI    C,PRINT
  274.     CALL    MEX
  275.     RET
  276. ;
  277. ;------------------------------------------------------------
  278. ;
  279. ;       *** END OF FIXED FORMAT AREA ***
  280. ;
  281. ;------------------------------------------------------------
  282. ;
  283. ; Modem initialization.
  284. ;
  285. NITMOD:    
  286.         MVI     A,1             ;default to 300 baud on start-up
  287.         CALL    PBAUD
  288.         LDA     MODMOD          ;default mode command in A
  289. ALTINI:                         ;alternate entry point for mode change routines
  290.         PUSH    PSW             ;save mode command on stack
  291.         XRA     A               ;force 8251 USART to look for reset command
  292.         OUT     MODCT2
  293.         OUT     MODCT2
  294.         OUT     MODCT2
  295.         MVI     A,RSTCTL        ;reset USART
  296.         OUT     MODCT2
  297.         POP     PSW             ;retreive mode command
  298.         STA     MODMOD          ;save copy for future use
  299.         OUT     MODCT2          ;set USART mode
  300.         MVI     A,MODEGO        ;enable transmitter and receiver
  301.         OUT     MODCT2
  302.         RET
  303. ;
  304. ; STARPLEX send-break routine
  305. ;
  306. PBREAK: LDA     MODCTB          ;get the last modem control byte
  307.         ORI     BRKMSK          ;set the transmit break bit low
  308.     OUT    MODCT2        ;send it to the modem
  309.         LXI     B,02FEH         ;B=2, C=254 
  310.         CALL    MEX             ;send a space tone for 200 ms.
  311.     LDA    MODCTB        ;get the last modem control byte
  312.     OUT    MODCT2        ;restore to normal
  313. ;
  314. ; exit routine
  315. ;
  316. DUMMY:    RET            ;we don't need one
  317. ;
  318. ;
  319. ;
  320. ; Set baud-rate code in A 
  321. ;
  322. PBAUD:    PUSH    H        ;don't alter anybody
  323.     PUSH    D
  324.     PUSH    B
  325.         STA     MSPEED
  326.         ADD     A               ;double value to get word address
  327.     MOV    E,A        ;code to DE
  328.     MVI    D,0
  329.     LXI    H,BAUDTB    ;offset into table
  330.     DAD    D
  331.         MOV     C,M             ;fetch code
  332.         INX     H
  333.         MOV     B,M
  334.         MVI     A,076H
  335.         OUT     BAUDMD          ;control counter
  336.         MOV     A,C
  337.         OUT     BAUDRP
  338.         MOV     A,B
  339.         OUT     BAUDRP          ;good rate, set it
  340. PBEXIT: POP     B               ;all done
  341.     POP    D
  342.     POP    H
  343.     RET
  344. ;
  345. ; table of baud rate divisors for supported rates
  346. ;
  347. BAUDTB: DW      1048,384,256,192,162    ;110,300,450,610,710
  348.         DW      96,48,24,12,6           ;1200,2400,4800,9600,19200
  349. ;
  350. ; Sign-on message
  351. ;
  352. SYSVER:    LXI    D,SOMESG
  353.     MVI    C,PRINT
  354.     CALL    MEX
  355.         RET
  356. ;
  357. SOMESG: DB      'STARPLEX overlay By Bill Meahan V. '
  358.         DB      REV/10+'0'
  359.     DB    '.'
  360.     DB    REV MOD 10+'0'
  361.     DB    ': $'
  362. ;
  363. ;
  364. ;
  365. ;
  366. ; Newline on console
  367. ;
  368. CRLF:    MVI    A,CR
  369.     CALL    TYPE
  370.     MVI    A,LF        ;fall into TYPE
  371. ;
  372. ; type char in A on console
  373. ;
  374. TYPE:    PUSH    H        ;save 'em
  375.     PUSH    D
  376.     PUSH    B
  377.     MOV    E,A        ;align output character
  378.     MVI    C,CONOUT    ;print via MEX
  379.     CALL    MEX
  380.     POP    B
  381.     POP    D
  382.     POP    H
  383.     RET
  384. ;
  385. ; strings to clear-to-end-of-screen, and clear-screen
  386. ;
  387. EOSMSG: DB      09BH,'$'        ;clear to end-of-screen
  388. CLSMSG: DB      09AH,'$'        ;clear whole screen
  389. ;
  390. ; Data area
  391. ;
  392. ERRFLG:    DB    0        ;connection error code
  393. MODMOD  DB      MODEMK          ;uart-control byte image
  394. BAUDSV: DB      01              ;current baud rate (dflt 300)
  395. MODCTB: DB      MODEGO          ;modem control byte
  396. ;
  397. ;------------------------------------------------------------
  398. ;
  399. ; The remainder of this overlay implements a very versatile
  400. ; SET command -- 
  401. ;
  402. ;
  403. ; Control is passed here after MEX parses a SET command.
  404. ;
  405. SETCMD:    MVI    C,SBLANK    ;any arguments?
  406.     CALL    MEX
  407.     JC    SETSHO        ;if not, go print out values
  408.     LXI    D,CMDTBL    ;parse command
  409.     CALL    TSRCH        ;from table
  410.     PUSH    H        ;any address on stack
  411.     RNC            ;if we have one, execute it
  412.     POP    H        ;nope, fix stack
  413. SETERR:    LXI    D,SETEMS    ;print error
  414.     MVI    C,PRINT
  415.     CALL    MEX
  416.     RET
  417. ;
  418. SETEMS:    DB    CR,LF,'SET command error',CR,LF,'$'
  419. ;
  420. ; SET command table ... note that tables are constructed of command-
  421. ; name (terminated by high bit=1) followed by word-data-value returned
  422. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  423. ; a binary zero.
  424. ;
  425. ; Note that LOOKUP attempts to find the next item in the input stream
  426. ; in the table passed to it in HL ... if found, the table data item is
  427. ; returned in HL; if not found, LOOKUP returns carry set.
  428. ;
  429. CMDTBL:    DB    '?'+80H            ;"set ?"
  430.     DW    STHELP
  431.     DB    'BAU','D'+80H        ;"set baud"
  432.     DW    STBAUD
  433.         DB      'PARIT','Y'+80H         ;"set parity"
  434.         DW      SETPAR
  435.         DB      'BIT','S'+80H           ;"set bits"
  436.         DW      SETBIT
  437.         DB      'STO','P'+80H           ;"set stop"
  438.         DW      SETSTO
  439. ;
  440.     DB    0        ;<<=== table terminator
  441. ;
  442. ; SET <no-args>: print current statistics
  443. ;
  444. SETSHO: 
  445.     LXI    H,SHOTBL    ;get table of SHOW subroutines
  446. SETSLP:    MOV    E,M        ;get table address
  447.     INX    H
  448.     MOV    D,M
  449.     INX    H
  450.     MOV    A,D        ;end of table?
  451.     ORA    E
  452.     RZ            ;exit if so
  453.     PUSH    H        ;save table pointer
  454.     XCHG            ;adrs to HL
  455.     CALL    GOHL        ;do it
  456.     CALL    CRLF        ;print newline
  457.     MVI    C,CHEKCC    ;check for console abort
  458.     CALL    MEX
  459.     POP    H        ;it's done
  460.     JNZ    SETSLP        ;continue if no abort
  461.     RET
  462. ;
  463. GOHL:    PCHL
  464. ;
  465. ; table of SHOW subroutines
  466. ;
  467. SHOTBL:    DW    BDSHOW
  468.         DW      PARSHO
  469.         DW      BITSHO
  470.         DW      STOSHO
  471.         DW      0               ;<<== table terminator
  472. ;
  473. ; SET ?  processor
  474. ;
  475. STHELP:    LXI    D,HLPMSG
  476.     MVI    C,PRINT
  477.     CALL    MEX
  478.     RET
  479. ;
  480. ; The help message
  481. ;
  482. HLPMSG: DB      CR,LF,'SET command, STARPLEX version:',CR,LF,LF
  483.         DB      CR,LF,'SET BAUD 150 <or> 300 <or> 600 <or> 1200 <or> 2400'
  484.         DB      CR,LF,'    <or> 4800 <or> 9600'
  485.         DB      CR,LF,'SET PARITY ODD <or> EVEN <or> OFF'
  486.         DB      CR,LF,'SET BITS 7 <or> 8'
  487.         DB      CR,LF,'SET STOP 1 <or> 1.5 <or> 2'
  488.         DB      CR,LF,'$'
  489. ;
  490. ; SET BAUD processor
  491. ;
  492. STBAUD:    MVI    C,BDPARS    ;function code
  493.     CALL    MEX        ;let MEX look up code
  494.     JC    SETERR        ;invalid code
  495.     CALL    PBAUD        ;no, try to set it
  496.     JC    SETERR        ;not-supported code
  497. BDSHOW:    CALL    ILPRT        ;display baud
  498.     DB    'Baud rate:',TAB,' ',0
  499.     LDA    MSPEED
  500.     MVI    C,PRBAUD    ;use MEX routine
  501.     CALL    MEX
  502.     RET
  503. ;
  504. ; SET PARITY processor
  505. ;
  506. SETPAR:
  507.         LXI     D,PARTBL        ;point to argument table
  508.         CALL    TSRCH           ;look for match with allowed arguments
  509.         JC      SETERR          ;process error if found
  510.         LDA     MODMOD          ;get current mode byte
  511.         ANI     PARMSK          ;mask away current parity bits
  512.         ORA     L               ;add new parity bits
  513.         CALL    ALTINI
  514. PARSHO:
  515.         CALL    ILPRT           ;show current status
  516.         DB      'Parity:',TAB,' ',0
  517.         LDA     MODMOD          ;get current mode word
  518.         ANI     PARTST          ;test for parity enabled
  519.         JNZ     PAR             ;skip if it is
  520.         CALL    ILPRT
  521.         DB      'Off',0
  522.         RET
  523. PAR:
  524.         LDA     MODMOD
  525.         ANI     EVNTST          ;test mode byte for even parity
  526.         JNZ     PAREVN          ;skip if it is
  527.         CALL    ILPRT
  528.         DB      'Odd',0
  529.         RET
  530. PAREVN:
  531.         CALL    ILPRT
  532.         DB      'Even',0
  533.         RET
  534. ;
  535. ;PARITY argument table
  536. ;
  537. PARTBL: DB      'OD','D'+80H
  538.         DB      OPARIT,0
  539.         DB      'EVE','N'+80H
  540.         DB      EPARIT,0
  541.         DB      'OF','F'+80H
  542.         DB      NPARIT,0
  543.         DB      0
  544. ;
  545. ;SET BITS processor
  546. ;
  547. SETBIT:
  548.         LXI     D,BITTBL        ;point to argument table
  549.         CALL    TSRCH           ;look for match with allowed arguments
  550.         JC      SETERR          ;process error if found
  551.         LDA     MODMOD          ;get current mode command
  552.         ANI     (NOT BITS8) AND 255     ;mask away current bits
  553.         ORA     L               ;set new bits
  554.         CALL    ALTINI          ;change mode
  555. BITSHO:
  556.         CALL    ILPRT           ;show current status
  557.         DB      'Bits:',TAB,' ',0
  558.         LDA     MODMOD          ;get current mode word
  559.         ANI     BITS8           ;test for number of bits
  560.         JZ      SETERR
  561.         ANI     BITS8T           
  562.         JNZ     B8              ;skip if it is
  563.         CALL    ILPRT
  564.         DB      '7',0
  565.         RET
  566. B8:
  567.         CALL    ILPRT
  568.         DB      '8',0
  569.         RET
  570. ;
  571. ;BITS argument table
  572. ;
  573. BITTBL: DB      '8'+80H
  574.         DB      BITS8,0
  575.         DB      '7'+80H
  576.         DB      BITS7,0
  577.         DB      0
  578. ;
  579. ;SET STOP processor
  580. ;
  581. SETSTO:
  582.         LXI     D,STPTBL        ;point to argument table
  583.         CALL    TSRCH           ;look for match with allowed arguments
  584.         JC      SETERR          ;process error if found
  585.         LDA     MODMOD          ;get current mode command
  586.         ANI     (NOT STBIT2) AND 255     ;mask away current bits
  587.         ORA     L               ;set new bits
  588.         CALL    ALTINI          ;change mode
  589. STOSHO:
  590.         CALL    ILPRT           ;show current status
  591.         DB      'Stop Bits:',TAB,' ',0
  592.         LDA     MODMOD          ;get current mode word
  593.         ANI     STBIT2          ;test for number of bits
  594.         JZ      SETERR
  595.         RLC
  596.         RLC
  597.         ADD     A               ;form word table index
  598.         LXI     H,STJTBL        ;get address of jump table
  599.         ADD     L               ;point to address of proper routine
  600.         MOV     L,A
  601.         MVI     A,0
  602.         ADC     H
  603.         MOV     H,A
  604.         MOV     A,M             ;get address of proper routine
  605.         INX     H
  606.         MOV     H,M
  607.         MOV     L,A
  608.         PCHL                    ;branch to proper routine
  609. PRT1:
  610.         CALL    ILPRT
  611.         DB      '1',0
  612.         RET
  613. PRT2:
  614.         CALL    ILPRT
  615.         DB      '2',0
  616.         RET
  617. PRT15:
  618.         CALL    ILPRT
  619.         DB      '1.5',0
  620.         RET
  621. ;
  622. STJTBL:                         ;jump table for stop bit show routines
  623.         DW      SETERR
  624.         DW      PRT1
  625.         DW      PRT15
  626.         DW      PRT2
  627. ;
  628. ;STOP argument table
  629. ;
  630. STPTBL: DB      '1'+80H
  631.         DB      STBIT1,0
  632.         DB      '1.','5'+80H
  633.         DB      STBI15,0
  634.         DB      '2'+80H
  635.         DB      STBIT2,0
  636.         DB      0
  637. ;
  638. ; Compare next input-stream item in table @DE; CY=1
  639. ; if not found, else HL=matched data item
  640. ;
  641. TSRCH:    MVI    C,LOOKUP    ;get function code
  642.     JMP    MEX        ;pass to MEX processor
  643. ;
  644. ; Print in-line message ... blows away C register
  645. ;
  646. ILPRT:    MVI    C,ILP        ;get function code
  647.     JMP    MEX        ;go do it
  648. ;------------------------------------------------------------------------------
  649. ;
  650. ;The following routines are provided to support a printer
  651. ;on the second serial port of the STARPLEX II which is not
  652. ;supported (except for USART initialization at 1200 baud)
  653. ;by the STARPLEX CP/M BIOS. The routine here also implements
  654. ;XON-XOFF support which is provided by many printers.
  655. ;(e.g. LA100, TI820, etc.)
  656. ;
  657. ;At my installation, there is no need to change baud rates, parity, etc
  658. ;but if you need to do so, just duplicate the appropriate routines
  659. ;from the SET command. I'd suggest then using SET PRINTER BAUD or equal
  660. ;to go to the proper routines. The baud rate counter for port 2 is 
  661. ;counter 2 of the 8253 rather than counter 1. (Code 0B6H instead of 076H
  662. ;in PBAUD). Port addresses shown below.
  663. ;
  664. ;You do not need anything from here to the END statement UNLESS you DO want
  665. ;to support a serial printer on port 2 of a STARPLEX II. For systems other
  666. ;than STARPLEX II, (i.e. one built upon one of the SBC or BLC series boards)
  667. ;delete this stuff!
  668. ;
  669. PTRSTP  EQU     0EFH            ;USART status port address
  670. PTRDTP  EQU     0EEH            ;  "    data   "    "
  671. PTROKP  EQU     001H            ;mask for transmit busy status bit
  672. PTRINC  EQU     002H            ;mask for receiver ready status bit
  673. ;
  674. OKPRNT: DB      0FFH            ;OK to PRiNT flag. OK=0FFH Hold=0
  675. ;
  676. PTRTST:                         ;printer  status routine
  677.         PUSH    B               ;save b-c registers for MEX
  678.         IN      PTRSTP          ;get USART status
  679.         MOV     B,A             ;save a copy in b register
  680.         ANI     PTRINC          ;character in?
  681.         JZ      TSTPST          ;just skip and test status if not
  682.         IN      PTRDTP          ;get character
  683.         CPI     XON             ;XON character
  684.         JNZ     ISXOFF          ;skip if not
  685.         MVI     A,0FFH          ;set OK flag
  686.         STA     OKPRNT
  687.         JMP     PSTTST          ;skip to status test
  688. ISXOFF: CPI     XOFF            ;XOFF character?
  689.         JNZ     TSTPST          ;skip to status test if not (ignore)
  690.         XRA     A               ;reset flag
  691.         STA     OKPRNT
  692.         JMP     PSEXIT          ;then exit- a is already zero indicating hold
  693. TSTPST:  
  694.         LDA     OKPRNT          ;get hold flag
  695. PSTTST:  
  696.         ORA     A               ;test for hold
  697.         JZ      PSEXIT          ;exit if OK flag false (0)
  698.         MOV     A,B             ;test actual USART transmitter status
  699.         ANI     PTROKP
  700.         JZ      PSEXIT          ;exit if not ready
  701.         MVI     A,0FFH          ;MEX wants to see an FF if ok to print
  702. PSEXIT: POP     B               ;restore saved registers
  703.         RET                     ;return to MEX
  704. ;
  705. PTROUT: OUT     PTRDTP          ;shove character out to printer
  706.         RET
  707. ;
  708. ;
  709. ; Patches to MEX for STARPLEX system. (primarily adds vectors for serial
  710. ;                                      printer support)
  711. ;
  712.     ORG    0D00H        ;location of patch variables
  713. ;
  714. ;
  715. ;
  716. ; The following line defines the MEX service call entry point, and
  717. ; is not meant to be changed by the user
  718. ;
  719.         DS      3               ;MEX service call processor
  720.         DS      3               ;reserved
  721.         DS      1               ;reserved
  722. ;
  723. ; The following line contains the initial free-memory pointer for
  724. ; MEX.  Sophisticated modem overlays requiring additional space may change
  725. ; this pointer (ie, move it higher), and thus "protect" an area of RAM.
  726. ;
  727.         DS      2               ;first free memory pointer
  728. ;
  729. ; Following are the lowest-level vectors for console and list I/O used
  730. ; by MEX.  These normally point to routines that save the registers and
  731. ; vector to the appropriate BIOS routines.  Complex applications may
  732. ; need to intercept (or even replace) these routines.  If you do this,
  733. ; be sure to preserve DE, HL and BC.
  734. ;
  735.         DS      2               ;console status vector
  736.         DS      2               ;console input vector
  737.         DS      2               ;console output vector
  738.         DW      PTROUT          ;list output vector  (points to local routine)
  739.         DW      PTRTST          ;list status vector  (points to local routine)
  740. ;
  741. ; The following line defines the location of the default MEX prompt.
  742. ; If you'd like to provide your own initial prompt, add a DW statement
  743. ; pointing to a prompt buffer structured as follows:
  744. ;
  745. ;        DB <max size of buffer>
  746. ;        DB <length of actual prompt>
  747. ;        DB <prompt string>
  748. ;
  749. ; <maxsize> and <length> may be equal (especially if you disable the
  750. ; ID command by setting CHGPMT, below to 0); the ID command will, if
  751. ; left enabled, be limited to the <max size> value.
  752. ;
  753.         DS      2               ;prompt location
  754.         DS      1               ;reserved
  755.         DB      24              ;for TYPE command: # lines/screen
  756.         DB      1               ;for TYPE cmd: 1=pause 0=no pause
  757.         DB      ';'             ;multiple command-line separator
  758. ;
  759. ; following five for SENDOUT command
  760. ;
  761.         DB      4               ;# seconds waiting for a sendout echo
  762.         DB      8               ;# seconds waiting for initial reply
  763.         DB      '>'             ;sendout trigger char from remote
  764.         DB      'U'-64          ;sendout char to cancel line to remote
  765.         DB      6               ;sendout # retries
  766. ;
  767. ;
  768.         DB      0               ;hex/decimal mode
  769.         DB      01BH            ;terminal mode escape char (01BH = ESC)
  770.         DB      0               ;set to 1 to disable bell
  771. ;
  772. ; Buffer variables.  See BUFFERS.DOC for setup information
  773. ;
  774.         DB      2               ;default=2k
  775.         DB      255             ;"big" capture buffer
  776.         DB      16              ;16K transfer buffer
  777.         DB      1               ;1k for 85 batch files
  778.         DB      40              ;maximum length of PREFIX string
  779.         DB      40              ;maximum length of SUFFIX string
  780. ;
  781. ; Misc. stuff
  782. ;
  783.         DB      0               ;non-zero for CDOS
  784.         DB      0               ;non-zero sets "wait-for-echo"
  785.         DW      400             ;size of keystring area, in bytes
  786.         DB      1               ;non-zero allows CIS file transfers
  787.         DB      1               ;non zero allows STAT CIS ON or OFF
  788.         DB      1               ;non-zero allows ID (prompt chg) command
  789.         DB      1               ;non-zero prints ID msg in err msgs
  790. ;
  791. ; by setting the following DB to 0, you can disable the HELP
  792. ; command, freeing up space used by the help file index.
  793. ;
  794.         DB      1               ;non-zero allows HELP command
  795.         DB      0               ;user \/  alternate area for READ,LOAD,INI.MEX
  796.     DB    0        ;drive/\  & HELP.MEX (if SEARCH <>0)
  797.         DB      0               ;debugging in term-mode if non-zero
  798.         DB      1               ;non-0 excludes $SYS from batchsend, dir
  799.         DB      0               ;non-zero runs INI.MEX (if present) at startup
  800.         DB      1               ;receiver wait: # seconds [Plouff patch]
  801.         DW      150             ;size of the modem-port queue
  802.         DB      30              ;phone library size (# entries)
  803.         DB      0FFH            ;0=silence multi-line & READ cmd echo
  804.         DB      255             ;alert-bell count on CALL complete
  805.         DB      0               ;non-zero: unknown commands goto READ processor
  806.         DB      0               ;non-zero: splits phonelib printout, shows baud
  807.         DB      0               ;search mode 0,1,2,3
  808. ;
  809. ; Following is the GLOBAL secondary options table.  To
  810. ; set an option to global, change its ASCII character to a 0.
  811. ;
  812.         DB      'BDLQRSTVX'
  813. ;
  814. ;
  815. ;
  816. ;------------------------------------------------------------
  817. ;
  818. ; End of STARPLEX MEX modem overlay and patches
  819. ;
  820. ;------------------------------------------------------------
  821. ;
  822.         END
  823.