home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-SM13.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  9KB  |  285 lines
  1.     TITLE    'MEX SMARTMODEM OVERLAY V1.3'
  2. ;
  3. ; (DELETE ABOVE TITLE LINE IF ASSEMBLING WITH ASM)
  4. ;
  5. ; Smartmodem overlay for MEX: revision 1.3
  6. ; Written 04/16/84 by Ronald G. Fowler (V1.0)
  7. ;
  8. ; 07/16/84: Added equate NUMRES to enable/disable numeric result code 
  9. ;        interpretation.  Under TurboDos, the first digit of the 
  10. ;        phone number was being interpreted as a result code as it 
  11. ;        was echoed by the Anchor modem as it dialed.  Set NUMRES false
  12. ;        to disable numeric results. (Bob Puckett)
  13. ;
  14. ; 06/06/84: Fixed problem for Anchor users, where, when the modem returned
  15. ;        "DIAL TONE", the "N" in "TONE" was being regarded as a NO-CONNECT
  16. ;        code.  Now we flush the entire result line before reading another.
  17. ;        Also added code for numeric version of "CONNECT 1200".  --RGF
  18. ;
  19. ; Small bug repaired: (V1.1) 05/14/84 (Steve Grandi): Smartmodem was not being 
  20. ;    flushed after a dial string so that last digit of the phone number 
  21. ;    was being interpreted as a numeric result code causing the program, 
  22. ;    for certain numbers, to give up even as the modem merrily dialed away.
  23. ;
  24. ; This modules adapts MEX for the DC Hayes Smartmodem (as well
  25. ; as many others -- including US Robotics -- that use a similar
  26. ; command language). The main function of this module is to pro-
  27. ; vide dialing capability; the disconnect vector is ancillary.
  28. ; You may use this module as a model to develop dialing routines
  29. ; for non-standard modems (e.g., the Racal-Vadic).  The only
  30. ; pertinent entry point is the DIAL routine; you'll find entry
  31. ; specs for that below.
  32. ;
  33. ; The only conditional you might want to change in this
  34. ; module is the DISC equate below -- if left on, MEX will
  35. ; use the Smartmodem's disconnect code.  If you prefer to
  36. ; provide your own in your overlay's DISCV vector (e.g.,
  37. ; by dropping DTR), then set DISC to FALSE and re-assemble.
  38. ; (If you don't understand this, then play it safe, and
  39. ; leave the equate set as it is).
  40. ;
  41. ; This overlay will work with any modem overlay that terminates
  42. ; prior to 0B00H
  43. ;
  44. FALSE    EQU    0
  45. TRUE    EQU    NOT FALSE
  46. ;
  47. ;
  48. NUMRES    EQU    FALSE        ; TRUE = INTERPRET NUMERIC RESULT CODES
  49.                 ; FALSE = IGNORE NUMERIC RESULT CODES
  50. ;
  51. DISC    EQU    TRUE        ;<<== CHANGE TO FALSE IF YOU DISC. WITH DTR
  52. ;
  53. ; SYSTEM CONSTANTS
  54. ;
  55. TPULSE    EQU    0105H        ;TONE/PULSE FLAG IN MODEM OVERLAY
  56. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  57. DISCV    EQU    0165H        ;LOCATION OF DISCONNECT VECTOR IN OVERLAY
  58. DIALOC    EQU    0B00H        ;DIALING CODE GOES HERE
  59. MEX    EQU    0D00H        ;"CALL MEX"
  60. ;
  61. ; FOLLOWING ARE FUNCTION CODES FOR THE MEX SERVICE CALL PROCESSOR
  62. ;
  63. INMDM    EQU    255        ;RETURN CHAR FROM MDM IN A, CY=NO CHR IN 100MS
  64. TIMER    EQU    254
  65. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  66. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  67. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  68. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  69. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  70. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  71. ;
  72. CR    EQU    13
  73. LF    EQU    10
  74. ;
  75. ;
  76. ;
  77.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  78.     JMP    DIAL
  79. ;    
  80.     IF    DISC        ;IF PROVIDING DISCONNECT CODE
  81.     ORG    DISCV        ;OVERLAY THE VECTOR
  82.     JMP    DISCON
  83.     ENDIF
  84. ;
  85. ; This is the DIAL routine called by MEX to dial a digit. The digit
  86. ; to be dialed is passed in the A register.  Note that two special
  87. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  88. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  89. ; in the accumulator prior to dialing a number.  Mex will also call
  90. ; dial with 255 in A as an indication that dialing is complete. Thus,
  91. ; the overlay may use these values to "block" the number, holding it
  92. ; in a buffer until it is completely assembled (in fact, that's the
  93. ; scheme employed here for the Smartmodem).
  94. ;
  95. ; After the 254-start-dial sequence, MEX will call the overlay with
  96. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  97. ; its, and will send each to the DIAL routine un-inspected (some modems,
  98. ; like the Smartmodem, allow special non-numeric characters in the
  99. ; phone number, and MEX may make no assumptions about these).
  100. ;
  101. ; After receiving the end-dial sequence (255) the overlay must take
  102. ; whatever end-of-dial actions are necessary *including* waiting for
  103. ; carrier at the distant end.  The overlay should monitor the keyboard
  104. ; during this wait (using the MEX keystat service call), and return
  105. ; an exit code to MEX in the A register, as follows:
  106. ;
  107. ;    0 - Carrier detected, connection established
  108. ;    1 - Far end busy (only for modems that can detect this condition)
  109. ;    2 - No answer (or timed out waiting for modem response)
  110. ;    3 - Keyboard abort (^C only: all others should be ignored)
  111. ;    4 - Error reported by modem
  112. ;
  113. ; <No other codes should be returned after an end-dial sequence>
  114. ;
  115. ; The overlay should not loop forever in the carrier-wait routine, but
  116. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  117. ; ms character wait) service call routine.
  118. ;
  119. ; The DIAL routine is free to use any of the registers, but must return
  120. ; the above code after an end-dial sequence
  121. ;
  122.     ORG    DIALOC
  123. ;
  124. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  125.     CPI    254        ;START DIAL?
  126.     JZ    STDIAL        ;JUMP IF SO
  127.     CPI    255        ;END DIAL?
  128.     JZ    ENDIAL        ;JUMP IF SO
  129. ;
  130. ; Not start or end sequence, must be a digit to be sent to the modem
  131. ;
  132.     MOV    M,A        ;PUT CHAR IN BUFFER
  133.     INX    H        ;ADVANCE POINTER
  134.     SHLD    DIALPT        ;STUFF PNTR
  135.     RET            ;ALL DONE
  136. ;
  137. ; Here on a start-dial sequence
  138. ;
  139. STDIAL:    LXI    H,DIALBF    ;SET UP BUFFER POINTER
  140.     SHLD    DIALPT
  141.     RET
  142. ;
  143. ; Here on an end-dial sequence
  144. ;
  145. ENDIAL:    MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  146.     INX    H        ;FOLLOWED BY TERMINATOR
  147.     MVI    M,0
  148.     LDA    TPULSE        ;GET OVERLAY'S TOUCH-TONE FLAG
  149.     STA    SMDIAL+3    ;PUT INTO STRING
  150.     LXI    H,SMDIAL    ;POINT TO DIALING STRING
  151.     CALL    SMSEND        ;SEND IT
  152. WAITSM:    MVI    C,INMDM
  153.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  154.     JNC    WAITSM        ;LOOP UNTIL NO MORE CHARACTERS
  155. ;
  156. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  157. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  158. ; NOTE THAT THE SMARTMODEM HAS AN INTERNAL 30 SECOND TIMEOUT WHILE
  159. ; FOR A CARRIER ON THE OTHER END.  YOU CAN CHANGE BY PLAYING WITH THE
  160. ; S7 VARIABLE (I.E. SEND THE SMARTMODEM "AT S7=20" TO LOWER THE 30 SECOND
  161. ; WAIT TO 20 SECONDS).
  162. ;
  163. RESULT:    MVI    C,60        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  164. SMWLP:    PUSH    B
  165.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  166.     MVI    C,TMDINP    ;DO TIMED INPUT
  167.     CALL    MEX
  168.     POP    B
  169.     JNC    SMTEST        ;JUMP IF MODEM HAD A CHAR
  170.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  171.     MVI    C,CHEKCC
  172.     CALL    MEX
  173.     POP    B
  174.     JNZ    SMNEXT        ;IF NOT, JUMP
  175.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  176.     MVI    C,SNDCHR
  177.     CALL    MEX
  178.     MVI    A,3        ;RETURN ABORT CODE
  179.     RET
  180. SMNEXT:    DCR    C        ;NO
  181.     JNZ    SMWLP        ;CONTINUE
  182. ;
  183. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  184. ;
  185. SMTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  186.     RET
  187. ;
  188. ; MODEM GAVE US A RESULT, CHECK IT
  189. ;
  190. SMTEST:    ANI    7FH        ;IGNORE ANY PARITY
  191.     CALL    SMANAL        ;TEST THE RESULT
  192.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  193.     PUSH    PSW        ;SAVE IT
  194. SMTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  195.     CALL    MEX
  196.     JC    SMCHEK        ;JUMP IF NO INPUT
  197.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  198.     JNZ    SMTLP        ;EAT ANY IN-BETWEEN
  199. SMCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  200.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  201.     RET
  202. ;
  203. SMANAL:    MVI    B,0        ;PREP CONNECT CODE
  204.     CPI    'C'        ;"CONNECT"?
  205.     RZ
  206.  
  207.     IF     NUMRES
  208.     CPI    '1'        ;NUMERIC VERSION OF "CONNECT"
  209.     RZ
  210.     CPI    '5'        ;NUMERIC VERSION OF "CONNECT 1200"
  211.     RZ
  212.     ENDIF
  213.  
  214.     INR    B        ;PREP BUSY CODE B=1
  215.     CPI    'B'
  216.     RZ
  217.     INR    B        ;PREP NO CONNECT MSG B=2
  218.     CPI    'N'        ;N=NO CONNECT
  219.     RZ
  220.  
  221.     IF     NUMRES
  222.     CPI    '3'        ;NUMERIC VERSION OF "NO CONNECT"
  223.     RZ
  224.     ENDIF
  225.  
  226.     MVI    B,4        ;PREP MODEM ERROR
  227.     CPI    'E'        ;E=ERROR
  228.     RZ
  229.  
  230.     IF    NUMRES
  231.     CPI    '4'        ;NUMERIC VERSION OF "ERROR"
  232.     RZ
  233.     ENDIF
  234.  
  235.     STC            ;UNKNOWN...
  236.     RET
  237. ;
  238. ; FOLLOWING ROUTINE DISCONNECTS THE MODEM USING SMARTMODEM
  239. ; CODES. ALL REGISTERS ARE AVAILABLE FOR THIS FUNCTION.
  240. ; NOTHING RETURNED TO CALLER.
  241. ;
  242.     IF    DISC
  243. ;
  244. DISCON:    MVI    B,20
  245.     MVI    C,TIMER        ;WAIT 2 SECONDS
  246.     CALL    MEX
  247.     LXI    H,SMATN        ;SEND '+++'
  248.     CALL    SMSEND
  249.     MVI    B,20        ;WAIT 2 MORE SECONDS
  250.     MVI    C,TIMER
  251.     CALL    MEX
  252.     LXI    H,SMDISC    ;SEND 'ATH'
  253.     CALL    SMSEND
  254.     MVI    B,1        ;WAIT 1 SECOND
  255.     MVI    C,TIMER
  256.     CALL    MEX
  257.     RET
  258. ;
  259. SMATN:    DB    '+++',0
  260. SMDISC:    DB    'ATH',CR,0
  261. ;
  262.     ENDIF
  263. ;
  264. ; SMARTMODEM UTILITY ROUTINE: SEND STRING TO MODEM
  265. ;
  266. SMSEND:    MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  267.     CALL    MEX
  268.     JNZ    SMSEND
  269.     MOV    A,M        ;FETCH NEXT CHARACTER
  270.     INX    H
  271.     ORA    A        ;END?
  272.     RZ            ;DONE IF SO
  273.     MOV    B,A        ;NO, POSITION FOR SENDING
  274.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  275.     CALL    MEX
  276.     JMP    SMSEND
  277. ;
  278. ; DATA AREA
  279. ;
  280. SMDIAL:    DB    'ATDT '
  281. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  282. DIALPT:    DS    2        ;DIAL POSITION POINTER
  283. ;
  284.     END
  285.