home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-PX8.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  32KB  |  1,232 lines
  1.     Title    'MEX overlay for Epson PX-8 version 1.0'
  2. ;
  3. ;
  4. ; (delete above title line if not assembling with MAC)
  5. ;
  6. ;
  7. REV    EQU    10        ;overlay revision level
  8. ;
  9. ; MEX overlay for Epson PX-8 with MFU, Direct Connect modem, or
  10. ; external modem. Support is provided for an external dialing overlay
  11. ; such as MXO-SM. For details see MXO-PX8.DOC.
  12. ;
  13. ; Written 3/10/85 by David B. Kozinn
  14. ;
  15. ;    Copyright (C) 1985 by David B. Kozinn 
  16. ; 
  17. ; This program (in source or object code form) may be copied and distributed
  18. ; for non-commercial purposes. Sale of this program is forbidden without
  19. ; written consent of the author.
  20. ;
  21. ; The author can be contacted on CompuServe [76703,565] via Easyplex, or
  22. ; (preferably) in CP-MIG (PCS-47) or EpsOnline (PCS-19). 
  23. ;
  24. ; PLEASE READ THE FOLLOWING IF YOU INTEND TO MODIFY THIS OVERLAY:
  25. ; ---------------------------------------------------------------
  26. ; Much of the commentary has been removed in order to save space. For
  27. ; complete documentation of how an overlay is structured, see the original
  28. ; overlay, MXO-PM.ASM, written by Ron Fowler. Please be sure to read the
  29. ; comments in that overlay if you intend to change this one.
  30. ;
  31. ;    Version    Date    Changes
  32. ;    ------- -------    ------- 
  33. ;      1.0    850310    First general release version    
  34. ;------------------------------------------------------------
  35. ;
  36. ; Misc equates
  37. ;
  38. NO    EQU    0
  39. YES    EQU    (NOT NO) AND 0FFH
  40. TPA    EQU    100H
  41. CR    EQU    13
  42. LF    EQU    10
  43. TAB    EQU    9
  44. BELL    EQU    7
  45. ESC    EQU    01BH
  46. CUROFF    EQU    032H
  47. CURON    EQU    033H
  48. XON    EQU    011H
  49. XOFF    EQU    013H
  50. ;
  51. ; PX-8 port definitions
  52. ;
  53. MCTLR2    EQU    002H        ;Misc control signals (output)
  54. CCR    EQU    00DH        ;8251 command port
  55. DCRREG    EQU    084H        ;Modem tone dialer control port (output)
  56. OCR    EQU    085H        ;Modem control register (output)
  57. STR    EQU    086H        ;Modem status register (input)
  58. OMR    EQU    087H        ;Modem port setup (output)
  59. ;
  60. ; PX-8 Special locations (see code for use)
  61. ;
  62. WBLOC    EQU    0EC03H        ;BIOS call Warm Boot location
  63. DRSDAT    EQU    0F00FH        ;Default RS-232 data
  64. CTLR1    EQU    0F0B0H        ;CTLR1 register value
  65. CTLR2    EQU    0F0B2H        ;CTLR2 register value
  66. RSMODE    EQU    0F6D0H        ;8251 Mode byte location
  67. RSCMD    EQU    0F6D1H        ;8251 Command byte location
  68. RSOPN    EQU    0F2C8H        ;RS-232 open flag (00=Open)
  69. SLVFLG    EQU    0F358H        ;Slave cpu (6301) flag
  70. INTBUF    EQU    0FB90H        ;Internal rs232 buffer
  71. INTBUFL    EQU    0160H        ;Internal buffer length
  72. ;
  73. ;  bit definitions
  74. ;
  75. MDMINIT    EQU    089H        ;8251 initialization string
  76. BRKBIT    EQU    008H        ;8251 bit to turn break on
  77. MDRCVB    EQU    001H        ;modem receive bits
  78. MDRCVR    EQU    001H        ;modem recieve ready
  79. MDSNDB    EQU    002H        ;modem send bits
  80. MDSNDR    EQU    002H        ;modem recieve ready
  81. USEINT    EQU    020H        ;set to 0, send this to CTLR2 to use int.
  82. DCD    EQU    008H        ;Use with RSIOX CTLIN
  83. ;
  84. ;  bit definitions for OCR
  85. ;
  86. OHC    EQU    001H        ;off hook
  87. HSC    EQU    002H        ;handset control
  88. MON    EQU    004H        ;enable speaker
  89. TXC    EQU    008H        ;transmit carrier
  90. ANS    EQU    010H        ;Answer mode 
  91. TEST    EQU    020H        ;Test function
  92. PWR    EQU    040H        ;Modem Power
  93. CCT    EQU    080H        ;connect to phone lne
  94. ;
  95. ;  bit definitions for STR
  96. ;
  97. BDS    EQU    001H        ;Bell Detect Signal. 0 if ringing
  98. CTSMSK    EQU    004H        ;Clear to send. (carrier det) =0 if clear
  99. MII    EQU    080H        ;Modem Installation Indicator 0=installed
  100. ;
  101. ;    
  102. ; Special BIOS call locations
  103. ;
  104. CONIN    EQU    WBLOC+006H    ;Direct console input
  105. CONOUT    EQU    WBLOC+009H    ;Direct console output
  106. RSOPEN    EQU    WBLOC+039H    ;Open RS-232 port
  107. RSCLOSE    EQU    WBLOC+03CH    ;Close RS-232  port
  108. RSINST    EQU    WBLOC+03FH    ;Check for input
  109. RSOUTST    EQU    WBLOC+042H    ;Check for output
  110. RSIN    EQU    WBLOC+045H    ;Get a character
  111. RSOUT    EQU    WBLOC+048H    ;Send a character
  112. RSIOX    EQU    WBLOC+051H    ;Special RS-232 calls
  113. SLAVE    EQU    WBLOC+072H    ;Use slave CPU
  114. ;
  115. ; Equates for use with RSIOX
  116. ;
  117. OPNIOX    EQU    010H        ;Open using RSIOX
  118. CLSIOX    EQU    020H        ;Close using RSIOX
  119. INSTS    EQU    030H        ;Check for data in recieve buffer
  120. CTLIN    EQU    070H        ;Check carrier & DSR
  121. ;
  122. ; Mex locations
  123. ;
  124. QUEUE    EQU    00D51H        ;Queued I/O variable
  125. MODE    EQU    00D54H        ;Terminal mode byte (01 = in terminal mode)
  126. SMART    EQU    00B00H        ;Entry point for smart modem overlay
  127. ;
  128. ; Other equates
  129. ;
  130. WTCTS    EQU    150        ;How long to wait for carrier. 150=30 seconds
  131. ;
  132. ; MEX service processor stuff 
  133. ;
  134. MEX    EQU    0D00H        ;address of the service processor
  135. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  136. TIMER    EQU    254        ;delay 100ms * reg B
  137. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  138. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  139. SNDRDY    EQU    251        ;test for modem-send ready
  140. RCVRDY    EQU    250        ;test for modem-receive ready
  141. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  142. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  143. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  144. PARSFN    EQU    246        ;parse filename from input stream
  145. BDPARS    EQU    245        ;parse baud-rate from input stream
  146. SBLANK    EQU    244        ;scan input stream to next non-blank
  147. EVALA    EQU    243        ;evaluate numeric from input stream
  148. LKAHED    EQU    242        ;get nxt char w/o removing from input
  149. GNC    EQU    241        ;get char from input, cy=1 if none
  150. ILP    EQU    240        ;inline print
  151. DECOUT    EQU    239        ;decimal output
  152. PRBAUD    EQU    238        ;print baud rate
  153. ;
  154. ;
  155. PRINT    EQU    9        ;simulated BDOS function 9: print string
  156. INBUF    EQU    10        ;input buffer, same structure as BDOS 10
  157. ;
  158.     ORG    SMART        ;Put code in in case he calls smartmodem
  159.     CPI    255        ;without installing the overlay first
  160.     RNZ            ;Only do it once, at the end
  161.     CALL    ILPRT
  162.     DB    '** You have not installed a dialing overlay **'
  163.     DB    BELL,CR,LF,0
  164.     XRA    A        ;Set zero flag
  165.     MVI    A,3        ;Tell him dialing has been aborted
  166.     RET
  167.  
  168.     ORG    QUEUE        ;Set to Queued I/O flag location
  169.     DB    0        ;Don't allow queued I/O (it interferes
  170.                 ;with the stuff we're doing)
  171.  
  172.     ORG    TPA        ;we begin
  173. ;
  174. ;
  175.     DS    3        ;MEX has a JMP START here
  176. ;
  177. ; The following variables are located at the beginning of the program
  178. ; to facilitate modification without the need of re-assembly. They will
  179. ; be moved in MEX 2.0.
  180. ;
  181. PMODEM:    DB    NO        ;yes=PMMI modem \ / These 2 locations are not
  182. SMODEM:    DB    NO        ;yes=Smartmodem / \ referenced by MEX
  183. TPULSE:    DB    'T'        ;T=touch, P=pulse (not referenced by MEX)
  184. CLOCK:    DB    20        ;clock speed x .1, up to 25.5 mhz.
  185. MSPEED:    DB    1        ;sets display time for sending a file
  186.                 ;0=110    1=300  2=450  3=600  4=710
  187.                 ;5=1200 6=2400 7=4800 8=9600 9=19200
  188. BYTDLY:    DB    0        ;default time to send character in
  189.                 ;terminal mode file transfer (0-9)
  190.                 ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  191. CRDLY:    DB    0        ;end-of-line delay after CRLF in terminal
  192.                 ;mode file transfer for slow BBS systems
  193.                 ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  194. COLUMS:    DB    5        ;number of directory columns
  195. SETFL:    DB    YES        ;yes=user-defined SET command
  196. SCRTST:    DB    YES        ;yes=if home cursor and clear screen
  197.                 ;routine at CLRSCRN
  198.     DB    0        ;was once ACKNAK, now spare
  199. BAKFLG:    DB    NO        ;yes=make .BAK file
  200. CRCDFL:    DB    YES        ;yes=default to CRC checking
  201.                 ;no=default to Checksum checking
  202. TOGCRC:    DB    YES        ;yes=allow toggling of Checksum to CRC
  203. CVTBS:    DB    NO        ;yes=convert backspace to rub
  204. TOGLBK:    DB    YES        ;yes=allow toggling of bksp to rub
  205. ADDLF:    DB    NO        ;no=no LF after CR to send file in
  206.                 ;terminal mode (added by remote echo)
  207. TOGLF:    DB    YES        ;yes=allow toggling of LF after CR
  208. TRNLOG:    DB    NO        ;yes=allow transmission of logon
  209.                 ;write logon sequence at location LOGON
  210. SAVCCP:    DB    YES        ;yes=do not overwrite CCP
  211. LOCNXT:    DB    NO        ;yes=local cmd if EXTCHR precedes
  212.                 ;no=not local cmd if EXTCHR precedes
  213. TOGLOC:    DB    YES        ;yes=allow toggling of LOCNXTCHR
  214. LSTTST:    DB    YES        ;yes=allow toggling of printer on/off
  215.                 ;in terminal mode. Set to no if using
  216.                 ;the printer port for the modem
  217. XOFTST:    DB    YES        ;yes=allow testing of XOFF from remote
  218.                 ;while sending a file in terminal mode
  219. XONWT:    DB    NO        ;yes=wait for XON after sending CR while
  220.                 ;transmitting a file in terminal mode    
  221. TOGXOF:    DB    YES        ;yes=allow toggling of XOFF testing
  222. IGNCTL:    DB    NO        ;yes=do not send control characters
  223.                 ;above CTL-M to CRT in terminal mode
  224.                 ;no=send any incoming CTL-char to CRT
  225. EXTRA1:    DB    0        ;for future expansion
  226. EXTRA2:    DB    0        ;for future expansion
  227. BRKCHR:    DB    '@'-40H        ;^@ = Send a 300 ms. break tone
  228. NOCONN:    DB    'N'-40H        ;^N = Disconnect from phone line
  229. LOGCHR:    DB    'L'-40H        ;^L = Send logon
  230. LSTCHR:    DB    'P'-40H        ;^P = Toggle printer
  231. UNSVCH:    DB    'R'-40H        ;^R = Close input text buffer
  232. TRNCHR:    DB    'T'-40H        ;^T = Transmit file to remote
  233. SAVCHR:    DB    'Y'-40H        ;^Y = Open input text buffer
  234. EXTCHR:    DB    '^'-40H        ;^^ = Send next character
  235. ;
  236. ; The next two are for PMMI, we don't use them, but they have to hang
  237. ; around anyway.
  238. ;
  239.     DB    250
  240.     DB    0
  241. ;
  242. ; Low-level modem I/O routines
  243. ;
  244. INCTL1:    JMP    MODSTAT        ;in modem control port
  245.     DB    0,0,0,0,0,0,0    ;spares
  246. ;
  247. OTDATA:    JMP    MODOUT        ;out modem data port
  248.     DB    0,0,0,0,0,0,0    ;spares
  249. ;
  250. INPORT:    JMP    MODIN        ;in modem data port
  251.     DB    0,0,0,0,0,0,0    ;spares
  252. ;
  253. ; Bit-test routines.  These will be merged with the above
  254. ; routines in MEX 2.0 to provide a more reasonable format
  255. ;
  256. MASKR:    ANI MDRCVB ! RET    ;bit to test for receive ready
  257. TESTR:    CPI MDRCVR ! RET    ;value of receive bit when ready
  258. MASKS:    ANI MDSNDB ! RET    ;bit to test for send ready
  259. TESTS:    CPI MDSNDR ! RET    ;value of send bit when ready
  260. ;
  261. ;
  262. ; Unused area: was once used for special PMMI functions,
  263. ; Now used only to retain compatibility with MDM overlays.
  264. ; You may use this area for any miscellaneous storage you'd
  265. ; like but the length of the area *must* be 12 bytes.
  266. ;
  267.     DS    12
  268. ;
  269. ; Special modem function table
  270. ;
  271. LOGON:    DS    2        ;needed for MDM compat, not ref'd by MEX
  272. DIALV:    JMP    PDIAL        ;dial digit in A (see info at PDIAL)
  273. DISCV:    JMP    PDISC        ;disconnect the modem
  274. GOODBV:    DS    3        ;called before exit to CP/M
  275. INMODV:    JMP    NITMOD        ;initialization. Called at cold-start
  276. NEWBDV:    JMP    PBAUD        ;set baud rate
  277. NOPARV:    DS    3        ;set modem for no-parity
  278. PARITV:    DS    3        ;set modem parity
  279. SETUPV:    JMP    SETCMD        ;SET cmd: jump to a RET if you don't write SET
  280. SPMENV:    DS    3        ;not used with MEX
  281. VERSNV:    JMP    SYSVER        ;Overlay's voice in the sign-on message
  282. BREAKV:    JMP    PBREAK        ;send a break
  283. ;
  284. ; Entry points here are for compatibility with MDM7. They will be gone
  285. ; in MEX 2.0, so avoid using them.
  286. ;
  287. ILPRTV:    DS    3        ;replace with MEX function 9
  288. INBUFV:    DS    3        ;replace with MEX function 10
  289. ILCMPV:    DS    3        ;replace with table lookup funct. 247
  290. INMDMV:    DS    3        ;replace with MEX function 255
  291. NXSCRV:    DS    3        ;not supported by MEX (returns w/no action)
  292. TIMERV:    DS    3        ;replace with MEX function 254
  293. ;
  294. ;
  295. ; Clear/screen and clear/end-of-screen. Each routine must use the
  296. ; full 9 bytes alloted (may be padded with nulls).
  297. ;
  298. CLREOS:    LXI    D,EOSMSG
  299.     MVI    C,PRINT
  300.     CALL    MEX
  301.     RET
  302. ;
  303. ;
  304. CLS:    LXI    D,CLSMSG        ;null unless patched
  305.     MVI    C,PRINT
  306.     CALL    MEX
  307.     RET
  308. ;
  309. ;------------------------------------------------------------
  310. ;
  311. ;    *** END OF FIXED FORMAT AREA ***
  312. ;
  313. ;------------------------------------------------------------
  314. ;
  315. ; Modem initialization. First make sure that the dialing overlay
  316. ; address is correct (some overlays ORG the dial vector and stick a
  317. ; JMP B00 there.) We have to make sure that we get control first.
  318. ; Also, store away the current value in the DISCV address, because it
  319. ; might be the address of the dialing overlay disconnect vector. We'll
  320. ; use this to disconnect along with the regular disconnect code if an
  321. ; external modem is being used. Then, set up the default communications
  322. ; parameters. Then, if the port is already open, just return, else set 
  323. ; up to use the built-in modem.
  324. ;
  325. NITMOD:    LXI    H,PDIAL        ;Get address of our dialing routine
  326.     SHLD    DIALV+1        ;Store it as the address to jump to
  327.     LHLD    DISCV+1        ;Get address of disconnect vector
  328.     SHLD    SMDISCV+1    ;Save it in case it's needed
  329.     LXI    B,PDISC        ;Get our disconnect routine address
  330.     XRA    A        ;Clear carry flag
  331.     DB    0EDH,042H    ;SBC HL,BC If zero, then the same
  332.     JZ    NIT0        ;Don't do anything special
  333.     DCR    A        ;Get 0FFH to store
  334.     STA    GOTDISC        ;Indicate that we've got external disc
  335.     LXI    H,PDISC        ;Get the address of our disconnect routine
  336.     SHLD    DISCV+1        ;Store it in the proper place
  337. NIT0:    LXI    H,DRSDAT    ;Get default rs232 data
  338.     LXI    D,BAUDRATE
  339.     LXI    B,4
  340.     DB    0EDH,0B0H    ;LDIR
  341.     LDA    BAUDRATE    ;Find out what baud we're set to
  342.     LXI    H,BAUDTBL
  343.     MVI    B,0
  344. NIT1:    CMP    M        ;Do we match this table entry?
  345.     JZ    NIT2        ;Yes
  346.     INX    H
  347.     INR    B
  348.     JMP    NIT1
  349. NIT2:    MOV    A,B        ;Store the table entry locally
  350.     STA    MDMSPD
  351.     CALL    SMSPEED        ;Set modem speed for time for xfer
  352.     LDA    RSOPN        ;See if the port is already open
  353.     ORA    A
  354.     RZ            ;Don't do anything if so
  355.     CALL    RSOPEN        ;Turn the port on
  356.     CALL    PWRON        ;Try to turn the modem on
  357.     IN    STR        ;Read status register
  358.     ANI    MII        ;Is modem installed?
  359.     JNZ    OPENIT        ;No, open the RS-232 port normally
  360.     CALL    STPORT        ;Set up to use the direct connect
  361.     LDA    OCRVAL        ;Turn off modem power to conserve
  362.     ANI    (NOT PWR) AND 0FFH
  363.     STA    OCRVAL
  364.     OUT    OCR
  365.     MVI    A,0FFH        ;Indicate we're using the internal modem
  366.     STA    MDMTYPE
  367.     RET
  368. OPENIT:    CALL    RSCLOSE        ;Close the port to clean things up
  369.     CALL    RSOPEN        ;Open it up for the regular port
  370.     RET
  371.  
  372. ;
  373. ;  send-break routine
  374. ;
  375. PBREAK:    LDA    RSCMD        ;Get the current command for the 8251
  376.     ORI    BRKBIT        ;turn break on
  377.     OUT    CCR        ;Send it to the 8251
  378.     MVI    B,3        ;Wait 300 ms.
  379.     MVI    C,TIMER
  380.     CALL    MEX
  381.     LDA    RSCMD        ;Restore the 8251 to normal
  382.     OUT    CCR
  383.     RET
  384. ;
  385. ; disconnect the modem
  386. ;
  387. PDISC:    LDA    MDMTYPE        ;See if we're using an external modem
  388.     ORA    A        ;This will be zero if so
  389.     JNZ    PDISC0        ;If not, don't worry about it
  390.     LDA    GOTDISC        ;See if we had an external routine
  391.     ORA    A        ;This will be non-zero if so
  392.     JNZ    SMDISCV        ;Call it if it's there
  393. PDISC0:    CALL    RSCLOSE
  394.     LDA    OCRVAL        ;get current modem control values
  395.     ANI    0FFH-(CCT+TXC+OHC)    ;On-hook, carrier off,disconnect
  396.     OUT    OCR        ;send it
  397.     ANI    (NOT PWR) AND 0FFH    ;now turn power off too
  398.     OUT    OCR
  399.     STA    OCRVAL        ;Save this as current mod. ctl. value
  400.     CALL    RESPORT        ;Reset to use internal
  401.     CALL    SPKROFF        ;Turn the speaker off
  402.     CALL    RSOPEN
  403.     RET
  404. ;
  405. ; External dialing routine disconnect code is called through here.
  406. ;
  407. SMDISCV:JMP    PDISC        ;<-----This may be modified
  408. ;
  409. ;
  410. ;------------------------------------------------------------
  411. ;
  412. ;        DIALING ROUTINES 
  413. ;    
  414. ;
  415. ; The DIGITS table is a translation for digit to register value for
  416. ; all of the possible legal digits. Not many people will likely have
  417. ; use for A-D, since they are kind of hard to dial on a normal phone,
  418. ; but since the modem supports them, I've included them here. If you do
  419. ; want to use A-D, be sure to specify them as UPPER CASE or they'll be
  420. ; treated as they were one of the non-special characters. The modem
  421. ; also understands that a comma (,) means to wait for n seconds before
  422. ; continuing (for compatability with various intelligent modems.) Any other
  423. ; values (such as -, (, or ) ) are ignored. (Values have been OR'd with
  424. ; the tone-on bit already.)
  425. ;
  426. DIGITS:    DB    1DH,10H,11H,12H    ; 0, 1, 2, 3
  427.     DB    14H,15H,16H,18H    ; 4, 5, 6, 7
  428.     DB    19H,1AH        ; 8, 9
  429. SPLAT:    DB    1CH        ; *
  430. CRUNCH:    DB    1EH        ; #
  431. CHARS:    DB    13H,17H,1BH,1FH    ;A, B, C, D
  432. ;
  433. PDIAL:    MOV    B,A        ;Save the digit
  434.     LDA    MDMTYPE        ;See if we're using an external modem
  435.     ORA    A
  436.     MOV    A,B        ;Restore the digit
  437.     JZ    SMART        ;If so, jump to the Hayes routines
  438.     CPI    254        ;start-dial?
  439.     JZ    STDIAL
  440.     CPI    255        ;end-dial
  441.     JZ    ENDIAL
  442.     CPI    ','        ;smartmodem pause command
  443.     JNZ    CKDIG        ;if not pause, continue
  444.     LDA    COMDLY        ;delay n seconds
  445.     MOV    B,A
  446.     ADD    A        ; x 2
  447.     ADD    A        ; x 4
  448.     ADD    A        ; x 8
  449.     ADD    B        ; x 9
  450.     ADD    B        ; x 10
  451.     MOV    B,A
  452.     MVI    C,TIMER
  453.     CALL    MEX
  454.     RET
  455. ;
  456. CKDIG:    CPI    '9'+1        ;digits are 0-9
  457.     JNC    CKALFA        ;too big...check if it's A-D
  458.     SUI    '0'
  459.     JC    CKSPEC        ;too small....check if it's * or #
  460.     LXI    H,DIGITS    ;get start of digits table
  461.     JMP    DIALIT
  462. ;
  463. CKALFA:    CPI    'D'+1        ;legal alpha are A-D
  464.     RNC            ;too big, ignore it
  465.     SUI    'A'
  466.     RC            ;too small
  467.     LXI    H,CHARS        ;get start of character table
  468.     JMP    DIALIT
  469. ;
  470. CKSPEC:    LXI    H,SPLAT        ;Check for specials
  471.     CPI    ('*'-'0') AND 0FFH    ;..is it *?
  472.     JZ    DIALIT1        ;Yup, go dial
  473.     INX    H        ;point to CRUNCH
  474.     CPI    ('#'-'0') AND 0FFH    ;..is it #?
  475.     RNZ            ;No, forget it
  476.     JMP    DIALIT1        ;Yup, go dial
  477.     
  478. ;
  479. ; First get the value to send to the tone control register. At DIALIT,
  480. ; HL contains the proper table, and A contains the offset into that table.
  481. ;
  482. DIALIT:    MVI    B,0
  483.     MOV    C,A        ;Get offset into BC
  484.     DAD    B        ;Get real byte location into HL
  485. ;
  486. DIALIT1:MOV    A,M        ;Get value to dial into A
  487.     OUT    DCRREG        ;Start sending the tone
  488.     MVI    B,1        ;Send it for 100ms (which is kinda long
  489.     MVI    C,TIMER        ;but it's easier than coding my own timing
  490.     CALL    MEX        ;routine.)
  491.     XRA    A
  492.     OUT    DCRREG        ;Turn tone off
  493.     MVI    B,1        ;Wait for 100ms for the inter-digit delay
  494.     MVI    C,TIMER
  495.     CALL    MEX
  496.     RET
  497. ;
  498. ; Start-dial sequence: Go thru normal init sequence, assuming that
  499. ; the guy is not trying to dial while connected. (This should 
  500. ; disconnect him anyway.
  501. ;
  502.  
  503. STDIAL:    CALL    PDISC        ;Disconnect
  504.     LDA    OCRVAL        ;Turn on monitor soon
  505.     ORI    MON
  506.     STA    OCRVAL
  507.     CALL    RESPORT        ;I don't know why, but I gotta do this
  508.     CALL    PWRON        ;Init modem and ports
  509.     CALL    SPKRON        ;turn power to speaker on
  510.     LDA    OCRVAL        ;Get current value for OCR
  511.     ANI    (NOT ANS) AND 0FFH    ;Set originate mode
  512.     STA    OCRVAL
  513.     OUT    OCR
  514. OFFHK:    LDA    OCRVAL        ;Have to reload 'cause we're called directly
  515.     ORI    CCT        ;Connect to phone
  516.     OUT    OCR
  517.     ORI    OHC        ;go off hook
  518.     OUT    OCR
  519.     STA    OCRVAL
  520.     MVI    B,20        ;Wait 2 seconds for dial tone
  521.     MVI    C,TIMER
  522.     CALL    MEX
  523.     RET            ;dialing init done
  524. ;
  525. ; End-dial sequence: Watch to see if CTS goes on within 30 seconds. If
  526. ; so, turn on carrier, turn speaker off, and connect to the line.
  527. ;
  528. ENDIAL:    LDA    OCRVAL        ;Turn on carrier
  529.     ORI    TXC
  530.     OUT    OCR
  531.     STA    OCRVAL
  532.     CALL    STPORT
  533.     MVI    E,WTCTS        ;# of ms * 5 to wait
  534. LP1:    MVI    B,2        ;200 ms.
  535.     MVI    C,TIMER
  536.     CALL    MEX
  537.     IN    STR        ;Check modem status register
  538.     ANI    CTSMSK        ;See if we've got carrier yet
  539.     JZ    GOTCAR        ;If it's zero, then we've got carrier
  540.     MVI    C,CHEKCC    ;Not yet, see if he hit ctl-c
  541.     CALL    MEX
  542.     MVI    A,3        ;Get ready to return code
  543.     JZ    NOCAR        ;Yup, return
  544.     DCR    E        ;Nope, count down
  545.     JNZ    LP1        ;Keep going if more time
  546.     MVI    A,2        ;Set code in A to 2 (no answer)
  547. NOCAR:    PUSH    PSW        ;Save the return code
  548.     CALL    PDISC        ;Hang up
  549.     POP    PSW        ;Get the return code back
  550.     RET
  551. ;
  552. ; GOTCAR - Come here to go on-line, we've got a carrier from remote
  553. ;
  554. GOTCAR:    CALL    SPKROFF        ;Turn the speaker off
  555.     XRA    A        ;Report that we got carrier
  556.     RET
  557. ;
  558. ;    <end of PX-8 dialing routines>
  559. ;------------------------------------------------------------
  560. ;
  561. PBAUD:    RET            ;use SET COMM for this
  562. ;
  563. ; Sign-on message
  564. ;
  565. SYSVER:    LXI    D,SOMESG
  566.     MVI    C,PRINT
  567.     CALL    MEX
  568.     RET
  569. ;
  570. SOMESG:    DB    'Epson PX-8 overlay V'
  571.     DB    REV/10+'0'
  572.     DB    '.'
  573.     DB    REV MOD 10+'0'
  574.     DB    '$'
  575. ;
  576. ; input from the status port. Since the PX-8 has 2 status ports, and
  577. ; we can't tell why we're being call (for input or output), we have to
  578. ; kludge here. We'll call both in & out status, and fake a 1 byte status
  579. ; word. See the MOD??? bytes for the values. Also, we check here to see
  580. ; if carrier has been lost (only if we were using the modem.) If so, then
  581. ; we'll disconnect from the phone line, reset the port, and tell the user.
  582. ;
  583. ; NOTE: It was observed that there was really no need for output status,
  584. ;    so these routines always return "ready to output". However, the
  585. ;    basic code structure to support both input and output status has
  586. ;    been left in should it ever be necessary.
  587. ;
  588. ; Automatic X-ON/X-OFF flow control is also done from this point.
  589. ;
  590. MODSTAT:
  591.     PUSH    B        ;push all registers (except A)
  592.     PUSH    D
  593.     PUSH    H
  594.     LDA    CTLR2        ;See if we're using an MFU
  595.     ANI    USEINT
  596.     JNZ    MDSTAT1        ;If not, forget about it
  597.     IN    STR        ;Else check modem status register
  598.     ANI    CTSMSK
  599.     JZ    MDSTAT1        ;Everything Ok if it's there
  600.     CALL    PDISC        ;Otherwise hang up
  601.     CALL    ILPRT        ;and say something about it
  602.     DB    CR,LF,'** Carrier Lost **',BELL,CR,LF,0
  603. MDSTAT1:LDA    MODE        ;Get terminal mode
  604.     CPI    1        ;01 means in terminal mode
  605.     JNZ    MDSTAT4        ;If not, then don't worry about it
  606. MDSTAT2:MVI    B,INSTS        ;Check for characters in input buffer
  607.     LXI    H,WIPEOUT    ;Here's where to put the returned info
  608.     CALL    RSIOX
  609.     JNZ    MDSTAT2        ;Wait until we get good status
  610.     XRA    A        ;Clear carry
  611.     LXI    H,264        ;3/4 full buffer
  612.     DB    0EDH,042H    ;SBC HL,BC
  613.     JNC    MDSTAT3        ;Continue if < 264 chars in buffer
  614.     LDA    PENDXOFF    ;is there an XOFF outstanding already?
  615.     ORA    A        ;It'll be 0 if not
  616.     JNZ    MDSTAT4        ;If so, then just go ahead
  617.     MVI    C,XOFF        ;Send out an XOFF
  618.     CALL    RSOUT
  619.     XRA    A
  620.     DCR    A
  621.     STA    PENDXOFF    ;Indicate a pending XOFF
  622.     JMP    MDSTAT4        ;Continue
  623. MDSTAT3:MVI    B,INSTS        ;Check input again, this time we're
  624.     LXI    H,WIPEOUT    ;seeing if it's time to send an XON
  625.     CALL    RSIOX
  626.     JNZ    MDSTAT3
  627.     XRA    A
  628.     LXI    H,50
  629.     DB    0EDH,042H    ;SBC HL,BC
  630.     JC    MDSTAT4        ;Don't send XON until < 50 chars in buffer
  631.     LDA    PENDXOFF    ;Ok, we've got < 50, did we send an XOFF?
  632.     ORA    A
  633.     JZ    MDSTAT4        ;No, so don't do anything
  634.     MVI    C,XON
  635.     CALL    RSOUT        ;Send the XON
  636.     XRA    A
  637.     STA    PENDXOFF
  638. MDSTAT4:CALL    RSINST        ;Now get status
  639.     ANI    MDRCVB        ;Mask off what we don't care about
  640.     ORI    MDSNDB        ;Always say that output is ready
  641. POPEM:    
  642.     POP    H
  643.     POP    D
  644.     POP    B
  645.     RET
  646. ;
  647. ; Get a character
  648. ;
  649. MODIN:    
  650.     PUSH    B
  651.     PUSH    D
  652.     PUSH    H
  653.     MVI    B,INSTS
  654.     LXI    H,STATBLK
  655.     CALL    RSIOX        ;Make sure there is really data so we
  656.     ORA    A        ;don't ever hang waiting
  657.     JZ    MODIN1
  658.     CALL    RSIN
  659. MODIN1:    POP    H
  660.     POP    D
  661.     POP    B
  662.     RET
  663. ;
  664. ; Send a character
  665. ;
  666. MODOUT:    
  667.     PUSH    B
  668.     PUSH    D
  669.     PUSH    H
  670.     MOV    C,A
  671.     CALL    RSOUT
  672.     POP    H
  673.     POP    D
  674.     POP    B
  675.     RET
  676. ;
  677. ; type char in A on console
  678. ;
  679. TYPE:    PUSH    H        ;save 'em
  680.     PUSH    D
  681.     PUSH    B
  682.     MOV    C,A        ;align output character
  683.     CALL    CONOUT
  684.     POP    B
  685.     POP    D
  686.     POP    H
  687.     RET
  688. ;
  689. ; SETPORT - set up to use internal modem
  690. ;
  691. STPORT:    LDA    CTLR2        ;Get current port info
  692.     ANI    (NOT USEINT) AND 0FFH    ;Use internal modem
  693. SPORT:    STA    CTLR2
  694.     OUT    MCTLR2
  695.     RET
  696. ;
  697. ; RESPORT - set up to use external modem
  698. ;
  699. RESPORT:LDA    CTLR2        ;Get current port info
  700.     ORI    USEINT        ;Use external modem
  701.     JMP    SPORT        ;Store & send to modem
  702. ;
  703. ; PWRON - Turn power on to the modem (& some other initialization stuff)
  704. ;
  705. PWRON:     MVI    A,MDMINIT    ;Initialize the 7508
  706.     OUT    OMR
  707.     LDA    OCRVAL        ;Get current parameters
  708.     ORI    PWR        ;Turn the power on
  709.     OUT    OCR
  710.     STA    OCRVAL        ;Save the parameters
  711.     MVI    B,1        ;Wait a while to let things settle
  712.     MVI    C,TIMER
  713.     CALL    MEX
  714.     RET
  715. ;
  716. ; SPKRON - Turn the speaker on
  717. ;
  718. SPKRON:    MVI    A,0FFH
  719.     STA    SLVFLG
  720.     LXI    D,SLVPRAM1
  721.     CALL    SLAVE
  722.     RET
  723. ;
  724. ; SPKROFF - Turn speaker off
  725. ;
  726. SPKROFF:LDA    OCRVAL        ;Get current params
  727.     ANI    (NOT MON) AND 0FFH    ;We're not monitoring anymore
  728.     OUT    OCR
  729.     STA    OCRVAL
  730.     MVI    A,0FFH
  731.     STA    SLVFLG
  732.     LXI    D,SLVPRAM2
  733.     CALL    SLAVE
  734.     RET
  735. ;
  736. ; Print in-line message ... blows away C register
  737. ;
  738. ILPRT:    MVI    C,ILP        ;get function code
  739.     JMP    MEX        ;go do it
  740. ;
  741. ; PLACECUR - Place cursor at row/col specified by BC. 
  742. ;
  743. PLACECUR:
  744.     PUSH    PSW
  745.     MOV    A,B
  746.     ADI    01FH        ;Add in offset
  747.     STA    ROW
  748.     MOV    A,C
  749.     ADI    01FH        ;Add in offset
  750.     STA    COL
  751.     CALL    ILPRT
  752.     DB    ESC,'='
  753. ROW:    DS    1
  754. COL    DS    1
  755.     DB    0
  756.     POP    PSW
  757.     RET
  758. ;
  759. ; Keyin - get a character into A
  760. ;
  761. KEYIN:    PUSH    B
  762.     PUSH    D
  763.     PUSH    H
  764.     CALL    CONIN            ;Direct console input
  765.     POP    H
  766.     POP    D
  767.     POP    B
  768.     RET
  769. ;
  770. ; UCASE - Convert character in A to uppercase
  771. ;
  772. UCASE:    CPI    'a'
  773.     RC            ;Return if not lower case
  774.     CPI    'z'+1
  775.     RNC            ;Return if > lower case z
  776.     ANI    05FH        ;Else change to upper case
  777.     RET
  778. ;
  779. ; SMSPEED - Set time to transfer speed
  780. ;
  781. SMSPEED:LDA    MDMSPD        ;Get locally stored speed value
  782.     MOV    C,A        ;Put in lower half of BC
  783.     MVI    B,0        ;Zap upper half of BC
  784.     LXI    H,XSPDTBL    ;Get address of xfer speed table
  785.     DAD    B        ;Get address of time for xfer byte
  786.     MOV    A,M        ;Get the value
  787.     STA    MSPEED        ;Store it
  788.     RET
  789. ;
  790. ; Data area
  791. ;
  792. ;
  793. ; XSPDTBL - transfer speed table. The number in parenthesis is the value
  794. ;        given to MEX. This differs from the actual baud rate in some
  795. ;        cases due to the baud rates available on the PX-8.
  796. ;
  797. XSPDTBL:DB    0        ;Unused
  798.     DB    0        ;110 Baud    (110)
  799.     DB    0        ;150 Baud    (110)
  800.     DB    1        ;300 Baud    (300)
  801.     DB    3        ;800 Baud    (600)
  802.     DB    5        ;1200 Baud    (1200)
  803.     DB    6        ;2400 Baud    (2400)
  804.     DB    7        ;4800 Baud    (4800)
  805.     DB    8        ;9600 Baud    (9600)
  806.     DB    9        ;19200 Baud    (19200)
  807. EOSMSG:    DB    ESC,'Y','$'    ;clear to end-of-screen
  808. CLSMSG:    DB    ESC,'*','$'    ;clear whole screen
  809. OCRVAL:    DB    0        ;OCR register value
  810. MDMTYPE:DB    0        ;modem type, 0FFH=external, 0=internal
  811. GOTDISC:DB    0        ;got external disconnect routine, FF=Yes
  812. MDMSPD:    DS    1        ;current port speed
  813. COMDLY:    DB    2        ;#secs to wait for , in dial string
  814. PENDXOFF:
  815.     DB    0        ;0FFH if XOFF pending, 0 otherwise
  816. STATBLK:DS    9        ;Returned info from RSIOX INSTS call
  817. ;
  818. ; The following group of data items are for using the slave CPU. 
  819. ; DO NOT ADD OR REMOVE ANYTHING IN THIS AREA!!!
  820. ;---------------Start of slave CPU data------------------
  821. SLVPRAM1:
  822.     DW    ONSNDCMD
  823.     DW    ONSNDLEN
  824.     DW    ONRETVAL
  825.     DW    ONRETLEN
  826. ONSNDCMD:
  827.     DB    072H,080H
  828. ONSNDLEN:
  829.     DB    2
  830. ONRETVAL:
  831.     DB    1
  832. ONRETLEN:
  833.     DB    1
  834. SLVPRAM2:
  835.     DW    OFFSDCMD
  836.     DW    OFFSDLEN
  837.     DW    OFFRTVAL
  838.     DW    OFFRTLEN
  839. OFFSDCMD:
  840.     DB    072H,0
  841. OFFSDLEN:
  842.     DB    2
  843. OFFRTVAL:
  844.     DB    1
  845. OFFRTLEN:
  846.     DB    1
  847. ;
  848. ;-----------------End of Slave CPU data----------------------
  849. ;
  850. ;
  851. ;------------------------------------------------------------
  852. ;
  853. ;
  854. ; Control is passed here after MEX parses a SET command.
  855. ;
  856. SETCMD:    MVI    C,SBLANK    ;any arguments?
  857.     CALL    MEX
  858.     JC    SETSHO        ;if not, go print out values
  859.     LXI    D,CMDTBL    ;parse command
  860.     CALL    TSRCH        ;from table
  861.     PUSH    H        ;any address on stack
  862.     RNC            ;if we have one, execute it
  863.     POP    H        ;nope, fix stack
  864. SETERR:    LXI    D,SETEMS    ;print error
  865.     MVI    C,PRINT
  866.     CALL    MEX
  867.     RET
  868. ;
  869. SETEMS:    DB    CR,LF,'SET command error',CR,LF,'$'
  870. ;
  871. ;
  872. CMDTBL:    DB    '?'+80H            ;"set ?"
  873.     DW    STHELP
  874.     DB    'OFFHOO','K'+80H    ;"set offhook"
  875.     DW    SETOFF
  876.     DB    'COM','M'+80H        ;"set comm"
  877.     DW    SETCOMM
  878.     DB    'DELA','Y'+80H        ;"set delay"
  879.     DW    SETDLY
  880. ;
  881.     DB    0        ;<<=== table terminator
  882. ;
  883. ; SET <no-args>: print current statistics
  884. ;
  885. SETSHO:    CALL    CARRSH        ;show carrier present/not present
  886.     LXI    H,SHOTBL    ;get table of SHOW subroutines
  887. SETSLP:    MOV    E,M        ;get table address
  888.     INX    H
  889.     MOV    D,M
  890.     INX    H
  891.     MOV    A,D        ;end of table?
  892.     ORA    E
  893.     RZ            ;exit if so
  894.     PUSH    H        ;save table pointer
  895.     XCHG            ;adrs to HL
  896.     CALL    GOHL        ;do it
  897.     MVI    C,CHEKCC    ;check for console abort
  898.     CALL    MEX
  899.     POP    H        ;it's done
  900.     JNZ    SETSLP        ;continue if no abort
  901.     RET
  902. ;
  903. GOHL:    PCHL
  904. ;
  905. ; table of SHOW subroutines
  906. ;
  907. SHOTBL:    DW    SHHOOK
  908. ;    DW    SHSTAT
  909.     DW    SHDLY
  910.     DW    0        ;<<== table terminator
  911. ;
  912. ; SET ?  processor
  913. ;
  914. STHELP:    LXI    D,HLPMSG
  915.     MVI    C,PRINT
  916.     CALL    MEX
  917.     RET
  918. ;
  919. ; The help message
  920. ;
  921. HLPMSG:    DB    CR,LF,'SET command, PX-8 version:',CR,LF,LF
  922.     DB    CR,LF,'SET COMM     set/display comm parameters'
  923.     DB    CR,LF,'SET DELAY n  set delay for comma in dial string'
  924.     DB    CR,LF,'             to n seconds'
  925.     DB    CR,LF,'SET OFFHOOK  go offhook'
  926.     DB    CR,LF,'$'
  927. ;
  928. ; Show carrier status
  929. ;
  930. CARRSH:    CALL    CARRCK            ;check for it
  931.     LXI    D,NOMESG        ;tell about carrier
  932.     MVI    C,PRINT
  933.     CZ    MEX            ;print the "NO" if no carrier
  934.     LXI    D,CARMSG        ;print "carrier present"
  935.     MVI    C,PRINT
  936.     CALL    MEX
  937.     RET
  938. ;
  939. NOMESG:    DB    'no $'
  940. CARMSG:    DB    'carrier present',CR,LF,'$'
  941. ;
  942. ; check the PX-8 for carrier-present (Z=no)
  943. ;
  944. CARRCK:    MVI    B,CTLIN        ;get status byte
  945.     CALL    RSIOX
  946.     ANI    DCD        ;Check for carrier detect
  947.     RET
  948.  
  949. ;
  950. ; Set OFFHOOK processor
  951. ;
  952. SETOFF:    CALL    PDISC        ;Disconnect if anything was there
  953.     CALL    PWRON        ;Fire up the modem
  954.     CALL    OFFHK
  955. SHHOOK:    CALL    ILPRT
  956.     DB    'Modem is ',0
  957.     LDA    OCRVAL
  958.     ANI    OHC
  959.     JZ    SHONHK
  960.     CALL    ILPRT
  961.     DB    'off-hook',CR,LF,0
  962.     RET
  963. SHONHK:    CALL    ILPRT
  964.     DB    'on-hook',CR,LF,0
  965.     RET
  966. ;
  967. ; Set delay for comma
  968. ;
  969. SETDLY:    MVI    C,EVALA        ;Get the number
  970.     CALL    MEX
  971.     MOV    A,H        ;Validate
  972.     ORA    A
  973.     JNZ    SETERR
  974.     MOV    A,L
  975.     STA    COMDLY        ;Store new rate
  976.  
  977. ;
  978. ; Show dialing delay
  979. ;
  980. SHDLY:    CALL    ILPRT
  981.     DB    'Delay time for dialing:',0
  982.     LDA    COMDLY
  983.     MOV    L,A
  984.     MVI    H,0
  985.     MVI    C,DECOUT
  986.     CALL    MEX
  987.     CALL    ILPRT
  988.     DB    ' seconds',CR,LF,0
  989.     RET
  990. ;
  991. ; Compare next input-stream item in table @DE; CY=1
  992. ; if not found, else HL=matched data item
  993. ;
  994. TSRCH:    MVI    C,LOOKUP    ;get function code
  995.     JMP    MEX        ;pass to MEX processor
  996. ;
  997. ; SET COMM routines - With thanks to Mike Hoffman and Christopher Rhodes
  998. ;               of Epson. These are from EPPXMDM3.MAC
  999. ;
  1000. SETCOMM:CALL    CLS        ;Clear the screen
  1001.     LXI    D,MENU
  1002.     MVI    C,PRINT
  1003.     CALL    MEX        ;Display the setup menu
  1004.  
  1005. ; DISPLAY CURRENT VALUES ON SETUP SCREEN
  1006.     CALL    DBAUD
  1007.     CALL    DDBITS
  1008.     CALL    DPARITY
  1009.     CALL    DSTP
  1010.     CALL    DMODEM
  1011.  
  1012. ; GET USERS RESPONSE AND SET PARAMITERS
  1013. SETUP0:    CALL    KEYIN
  1014.     CALL    UCASE
  1015.     CPI    ESC
  1016.     JZ    SETUP
  1017.     CPI    '9'+1        ;GREATER THAN BAUD SELECTION
  1018.     JNC    SDBITS        ;CHECK FOR DATA BITS
  1019.     CPI    '1'        ;LESS THAN 1?
  1020.     JC    SETUP0        ;GET ANOTHER RESPONSE
  1021.     ANI    0FH
  1022.     MOV    E,A
  1023.     MVI    A,10
  1024.     SUB    E
  1025.     STA    MDMSPD
  1026.     MOV    C,A
  1027.     MVI    B,0
  1028.     LXI    H,BAUDTBL
  1029.     DAD    B
  1030.     MOV    A,M
  1031.     STA    BAUDRATE
  1032.     CALL    DBAUD
  1033.     JMP    SETUP0
  1034. SDBITS:    CPI    'B'+1        ;GREATER THAN DATA BITS
  1035.     JNC    SPARITY        ;CHECK FOR PARITY
  1036.     CPI    'A'        ;LESS THAN 'A'
  1037.     JC    SETUP0        ;GET ANOTHER RESPONSE
  1038.     SUI    3FH        ;MAKE 2 OR 3
  1039.     STA    DBITS
  1040.     CALL    DDBITS
  1041.     JMP    SETUP0
  1042. SPARITY:CPI    'E'+1        ;GREATER THAN PARITY
  1043.     JNC    SSTOP        ;CHECK FOR STOP BITS
  1044.     SUI    'C'
  1045. SPAR1:    STA    PARBITS
  1046.     CALL    DPARITY
  1047.     JMP    SETUP0
  1048. SSTOP:    CPI    'G'+1        ;GREATER THAN STOP BITS
  1049.     JNC    SMOD        ;CHECK FOR MODEM
  1050.     SUI    'F'-1
  1051.     CPI    1
  1052.     JZ    SSTOP1
  1053.     ADI    2
  1054. SSTOP1:    STA    STP
  1055.     CALL    DSTP
  1056.     JMP    SETUP0
  1057. SMOD:    CPI    'I'+1        ;GREATER THAN BAUD
  1058.     JNC    SETUP0        ;BAD SELECTION GET ANOTHER RESPONSE
  1059.     SUI    'H'
  1060.     JZ    SMOD1
  1061.     CALL    PWRON        ;Try to turn the modem on
  1062.     IN    STR        ;Read status register
  1063.     ANI    MII        ;Is modem installed?
  1064.     JNZ    SMOD2
  1065.     MVI    A,0FFH
  1066. SMOD1:    STA    MDMTYPE
  1067.     CALL    DMODEM
  1068.     JMP    SETUP0
  1069. SMOD2:    MVI    A,BELL
  1070.     CALL    TYPE
  1071. SMOD3:    LXI    B,0201H
  1072.     CALL    PLACECUR
  1073.     CALL    ILPRT
  1074.      DB    TAB,'*** NO MODEM ***',0
  1075.     XRA    A
  1076.     STA    MDMTYPE
  1077.     CALL    DMODEM
  1078.     JMP    SETUP0
  1079. ;
  1080. ; Display baud rate
  1081. ;
  1082. DBAUD:    LXI    B,30DH
  1083.     CALL    PLACECUR
  1084.     LXI    H,BAUDSPD
  1085.     MVI    D,0
  1086.     LDA    MDMSPD        ;get baud rate code
  1087.     CPI    0FFH
  1088.     RZ            ;unknown baud rate
  1089.     MOV    E,A        ;x1
  1090.     ADD    A        ;x2
  1091.     ADD    A        ;x4
  1092.     ADD    E        ;x5
  1093.     ADD    E
  1094.     MOV    E,A
  1095.     DAD    D        ;point to correct rate
  1096.     XCHG
  1097.     MVI    C,PRINT
  1098.     CALL    MEX
  1099.     CALL    ILPRT
  1100.     DB    ' bps ',CR,LF,0
  1101.     RET    
  1102.  
  1103. ;
  1104. ; Display data bits
  1105. ;
  1106. DDBITS:    LXI    B,50DH
  1107.     CALL    PLACECUR
  1108.     LDA    DBITS
  1109.     CPI    2
  1110.     MVI    A,'7'
  1111.     JZ    DDBITS1
  1112.     MVI    A,'8'
  1113. DDBITS1:CALL    TYPE
  1114.     RET
  1115. ;
  1116. ; Display parity
  1117. ;
  1118. DPARITY:LXI    B,60DH
  1119.     CALL    PLACECUR
  1120.     LDA    PARBITS
  1121.     ORA    A
  1122.     JNZ    DPAR1
  1123.     CALL    ILPRT
  1124.     DB    'none',0
  1125.     RET
  1126. DPAR1:    CPI    1
  1127.     JNZ    DPAR2
  1128.     CALL    ILPRT
  1129.     DB    'odd ',0
  1130.     RET
  1131. DPAR2:    CALL    ILPRT
  1132.     DB    'even',0
  1133.     RET
  1134. ;
  1135. ; Display stop bits
  1136. ;
  1137. DSTP:    LXI    B,70DH
  1138.     CALL    PLACECUR
  1139.     LDA    STP
  1140.     CPI    1
  1141.     MVI    A,'1'
  1142.     JZ    DSTP1
  1143.     MVI    A,'2'
  1144. DSTP1:    CALL    TYPE
  1145.     RET
  1146. ;
  1147. ; Display modem type
  1148. ;
  1149. DMODEM:    LXI    B,80DH
  1150.     CALL    PLACECUR
  1151.     LDA    MDMTYPE
  1152.     ORA    A
  1153.     JNZ    DMODEM1
  1154.     CALL    ILPRT
  1155.     DB    'external',0
  1156.     RET
  1157. DMODEM1:CALL    ILPRT
  1158.     DB    'internal',0
  1159.     RET
  1160.  
  1161. SETUP:    CALL    STPORT        ;Set up for internal mode just in case
  1162.     CALL    SMSPEED        ;Set time to xfer speed
  1163.     LDA    MDMTYPE        ;See what kind of modem we're using
  1164.     INR    A        ;If FF, then it's internal
  1165.     JZ    SETUP1        ;yep, it's internal
  1166.     CALL    RESPORT        ;Using external, do setup
  1167. SETUP1:    LXI    H,PARAMS
  1168.     LXI    D,WIPEOUT
  1169.     LXI    B,9
  1170.     DB    0EDH,0B0H    ;LDIR
  1171.     MVI    B,CLSIOX
  1172.     CALL    RSIOX        ; close port first
  1173.     MVI    B,OPNIOX
  1174.     LXI    H,WIPEOUT
  1175.     CALL    RSIOX        ; open with new parameters
  1176.     CALL    CLS
  1177.     CALL    ILPRT
  1178.     DB    ESC,CURON
  1179.      DB    CR,LF,LF,LF
  1180.      DB    TAB,'Communication initialization completed.',CR,LF,0
  1181.     RET
  1182.  
  1183. BAUDSPD: DB    '50   $110  $150  $300  $600  $'
  1184.      DB    '1200 $2400 $4800 $9600 $19200$'
  1185. BAUDTBL:    
  1186.     DB    0FFH    ; 50   baud not supported
  1187.     DB    2    ; 110  baud
  1188.     DB    4    ; 150  baud
  1189.     DB    6    ; 300  baud
  1190.     DB    8    ; 600  baud
  1191.     DB    0AH    ; 1200 baud
  1192.     DB    0CH    ; 2400 baud
  1193.     DB    0DH    ; 4800 baud
  1194.     DB    0EH    ; 9600 baud
  1195.     DB    0FH    ; 19.2 baud
  1196.  
  1197. MENU:    DB    ESC,CUROFF
  1198.  DB    '    Select alphanumeric or ESC to return.',CR,LF,LF
  1199.  DB    'bit rate  :           1=19200    2=9600     3=4800     4=2400'
  1200.  DB    '     5=1200',CR,LF
  1201.  DB    '                      6=600      7=300      8=150      9=110',CR,LF
  1202.  DB    'data bits :           A=7        B=8',CR,LF
  1203.  DB    'parity    :           C=none     D=odd      E=even',CR,LF
  1204.  DB    'stop bits :           F=1        G=2',CR,LF
  1205.  DB    'modem type:           H=external I=internal$'
  1206.  
  1207. PARAMS:    
  1208.     DW    INTBUF
  1209.     DW    INTBUFL
  1210. BAUDRATE:
  1211.     DS    1
  1212. DBITS:
  1213.     DS    1
  1214. PARBITS:
  1215.     DS    1
  1216. STP:
  1217.     DS    1
  1218. SPECIAL:
  1219.     DB    0FFH    ;Not XON/XOFF, not SI/SO, DTR on, RTS on
  1220.  
  1221. WIPEOUT:DS    9    ; this area gets overwritten by BIOS call
  1222. COPYRITE:
  1223.     DB    'Copyright (C) 1985 by David B. Kozinn'
  1224. ;
  1225. ;------------------------------------------------------------
  1226. ;
  1227. ; End of PX-8 MEX modem overlay
  1228. ;
  1229. ;------------------------------------------------------------
  1230. ;
  1231.     END
  1232.