home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-PR10.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  7KB  |  227 lines
  1.     TITLE    'MEX PENRIL 300/1200 AD MODEM OVERLAY V1.0'
  2. ;
  3. ; (DELETE ABOVE TITLE LINE IF ASSEMBLING WITH ASM)
  4. ;
  5. ; used smartmodem overlay for MEX: revision 1.2
  6. ; Written 04/16/84 by Ronald G. Fowler (V1.2) as an outline.
  7. ; This overlay is a modified MXO-VPxx for the Penril.
  8. ;
  9. ;            Written by:
  10. ;        Bruce Childers & Jon Albers
  11. ;        Data - 202-633-0804, 0805, 0806
  12. ;               703-281-7907
  13. ;
  14. ; This overlay will allow a user to use the Penril 300/1200 AD
  15. ; modem and its compatibles (Rixon) with Mex.  This overlay does
  16. ; support auto-dial.  You should set the DISC equatte to FALSE
  17. ; if you wish to disconnect with DTR.
  18. ;
  19. ;
  20. ; This overlay will work with any modem overlay that terminates
  21. ; prior to 0B00H
  22. ;
  23. FALSE    EQU    0
  24. TRUE    EQU    NOT FALSE
  25. ;
  26. ;
  27. DISC    EQU    FALSE        ;<<== CHANGE TO FALSE IF YOU DISC. WITH DTR
  28. ;
  29. ; SYSTEM CONSTANTS
  30. ;
  31. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  32. DISCV    EQU    0165H        ;LOCATION OF DISCONNECT VECTOR IN OVERLAY
  33. DIALOC    EQU    0B00H        ;DIALING CODE GOES HERE
  34. MEX    EQU    0D00H        ;"CALL MEX"
  35. ;
  36. ; FOLLOWING ARE FUNCTION CODES FOR THE MEX SERVICE CALL PROCESSOR
  37. ;
  38. INMDM    EQU    255        ;RETURN CHAR FROM MDM IN A, CY=NO CHR IN 100MS
  39. TIMER    EQU    254
  40. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  41. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  42. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  43. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  44. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  45. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  46. ;
  47. CR    EQU    13
  48. LF    EQU    10
  49. ;
  50. ;
  51. ;
  52.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  53.     JMP    DIAL
  54. ;    
  55.     IF    DISC        ;IF PROVIDING DISCONNECT CODE
  56.     ORG    DISCV        ;OVERLAY THE VECTOR
  57.     JMP    DISCON
  58.     ENDIF
  59. ;
  60. ; This is the DIAL routine called by MEX to dial a digit. The digit
  61. ; to be dialed is passed in the A register.  Note that two special
  62. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  63. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  64. ; in the accumulator prior to dialing a number.  Mex will also call
  65. ; dial with 255 in A as an indication that dialing is complete. Thus,
  66. ; the overlay may use these values to "block" the number, holding it
  67. ; in a buffer until it is completely assembled.
  68. ; After the 254-start-dial sequence, MEX will call the overlay with
  69. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  70. ; its, and will send each to the DIAL routine un-inspected (some modems,
  71. ; like the Smartmodem, allow special non-numeric characters in the
  72. ; phone number, and MEX may make no assumptions about these).
  73. ;
  74. ; After receiving the end-dial sequence (255) the overlay must take
  75. ; whatever end-of-dial actions are necessary *including* waiting for
  76. ; carrier at the distant end.  The overlay should monitor the keyboard
  77. ; during this wait (using the MEX keystat service call), and return
  78. ; an exit code to MEX in the A register, as follows:
  79. ;
  80. ;    0 - Carrier detected, connection established
  81. ;    1 - Far end busy (only for modems that can detect this condition)
  82. ;    2 - No answer (or timed out waiting for modem response)
  83. ;    3 - Keyboard abort (^C only: all others should be ignored)
  84. ;    4 - Error reported by modem
  85. ;
  86. ; <No other codes should be returned after an end-dial sequence>
  87. ;
  88. ; The overlay should not loop forever in the carrier-wait routine, but
  89. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  90. ; ms character wait) service call routine.
  91. ;
  92. ; The DIAL routine is free to use any of the registers, but must return
  93. ; the above code after an end-dial sequence
  94. ;
  95.     ORG    DIALOC
  96. ;
  97. DIAL:    CPI    254        ;START DIAL?
  98.     JZ    STDIAL        ;JUMP IF SO
  99.     CPI    255        ;END DIAL?
  100.     JZ    ENDIAL        ;JUMP IF SO
  101. ;
  102. ; Not start or end sequence, must be a digit to be sent to the modem
  103. ;
  104.     CALL    SEND        ;SEND CHARACTER TO MODEM
  105.     CALL    DELAY1
  106.     RET            ;ALL DONE
  107. ;
  108. ; Here on a start-dial sequence
  109. ;
  110. STDIAL:    CALL     SETUP        ;WAKE UP THE VENTEL
  111.     RET
  112. ;
  113. ; Here on an end-dial sequence
  114. ;
  115. ENDIAL: MVI    A,CR        ;PUT A CR AT THE END
  116.     CALL    SEND        ;SEND CR TO MODEM
  117.  
  118. WAITPR: MVI    C,INMDM
  119.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  120.     JNC    WAITPR        ;LOOP UNTIL NO MORE CHARACTERS
  121. ;
  122. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  123. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  124. ;
  125. RESULT:    MVI    C,60        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  126. PRWLP:    PUSH    B
  127.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  128.     MVI    C,TMDINP    ;DO TIMED INPUT
  129.     CALL    MEX
  130.     POP    B
  131.     JNC    PRTEST        ;JUMP IF MODEM HAD A CHAR
  132.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  133.     MVI    C,CHEKCC
  134.     CALL    MEX
  135.     POP    B
  136.     JNZ    PRNEXT        ;IF NOT, JUMP
  137.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  138.     MVI    C,SNDCHR
  139.     CALL    MEX
  140.     MVI    A,3        ;RETURN ABORT CODE
  141.     RET
  142. PRNEXT:    DCR    C        ;NO
  143.     JNZ    PRWLP        ;CONTINUE
  144. ;
  145. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  146. ;
  147. PRTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  148.     RET
  149. ;
  150. ; MODEM GAVE US A RESULT, CHECK IT
  151. ;
  152. PRTEST:    ANI    7FH        ;IGNORE ANY PARITY
  153.     CALL    PRANAL        ;TEST THE RESULT
  154.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  155.     PUSH    PSW        ;SAVE IT
  156. PRTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  157.     CALL    MEX
  158.     JC    PRCHEK        ;JUMP IF NO INPUT
  159.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  160.     JNZ    PRTLP        ;EAT ANY IN-BETWEEN
  161. PRCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  162.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  163.     RET
  164. ;
  165. PRANAL:    MVI    B,0        ;PREP CONNECT CODE
  166.     CPI    'O'        ;"CONNECT"?
  167.     RZ
  168.     INR    B        ;PREP BUSY CODE B=1
  169.     CPI    'B'
  170.     RZ
  171.     INR    B        ;PREP NO CONNECT MSG B=2
  172.     CPI    'N'        ;N=NO CONNECT
  173.     RZ
  174.     MVI    B,4        ;PREP MODEM ERROR
  175.     CPI    'E'        ;E=ERROR
  176.     RZ
  177.     STC            ;UNKNOWN...
  178.     RET
  179.  
  180. ; FOLLOWING ROUTINE DISCONNECTS THE MODEM USING THE PENRIL
  181. ; CTRL-@. ALL REGISTERS ARE AVAILABLE FOR THIS FUNCTION.
  182. ; NOTHING RETURNED TO CALLER.
  183.  
  184.      IF DISC
  185. CTRL@:    EQU    '@'-40H
  186.  
  187. DISCON:    MVI    B,CTRL@
  188.     CALL    SEND
  189.     MVI    B,20        ;Wait 2 secs to let modem recover
  190.     MVI    C,TIMER
  191.     CALL    MEX
  192.     RET
  193.      ENDIF
  194. ;
  195. ;    SET UP ROUTINE TO WAKE VEN-TEL UP
  196. ;
  197. SETUP:    MVI    C,SNDRDY    ;CHECK TO SEE IF MODEM IS ALIVE
  198.     CALL     MEX
  199.     JNZ    SETUP
  200.     MVI    A,CR        ;send first cr of 3
  201.     CALL    SEND
  202.     MVI    B,30        ;Wait to get past banner
  203.     MVI    C,TIMER
  204.     CALL    MEX
  205. KOUT:    MVI    C,SNDRDY
  206.     CALL    MEX
  207.     JNZ    KOUT
  208.     MVI    B,'K'    ;GET READY TO DIAL
  209.     MVI    C,SNDCHR
  210.     CALL    MEX
  211.     CALL    DELAY1
  212.     RET
  213. ; 
  214. DELAY1:    MVI    B,5        ;Delay routine
  215.     MVI    C,TIMER
  216.     CALL    MEX
  217.     RET
  218.  
  219. ;    SEND A CHARACTER TO THE MODEM
  220. ;
  221. SEND:    MOV    B,A        ;WHEN CALLING HERE, THE CHAR IS IN A
  222.     MVI    C,SNDCHR
  223.     CALL    MEX
  224.     RET
  225. ;                End of  Overlay
  226.     END
  227.