home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-P1-1.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  12KB  |  402 lines
  1. ; MEXP1-1.ASM - MEX OVERLAY FOR PMC MICROMATE 101
  2. ;   Version 1.0
  3. ;
  4. ; History:
  5. ;
  6. ; 84/11/02 Created from M7P1-1.ASM
  7. ;       Ian Cottrell, Dept Energy, Mines and Resources, Ottawa, Canada
  8. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  9. ;    /////////////////////////////////////////
  10. ;    /                    /
  11. ;    /    - - W A R N I N G - -        /
  12. ;    /                    /
  13. ;    /    This code uses CP/M 3 dependent    /
  14. ;    /    stuff.                /
  15. ;    /                    /
  16. ;    /////////////////////////////////////////
  17. ;
  18. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  19. ;
  20. ; Use the "SET" command to change the baudrate when desired. 
  21. ;
  22. ;    To use:    First edit this file, filling in answers for your own
  23. ;        equipment. Then assemble with MAC.COM or equivalent
  24. ;        assembler. Use MLOAD21 to overlay the results of this
  25. ;        program on the original .COM file:
  26. ;
  27. ;        MLOAD21 MEX.COM=MEX112.COM,MXO-P1-1.HEX
  28. ;
  29. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  30. ;
  31. ; 
  32. BELL:        EQU    07H        ;bell
  33. CR:        EQU    0DH        ;carriage return
  34. ESC:        EQU    1BH        ;escape
  35. LF:        EQU    0AH        ;linefeed
  36. ;
  37. YES:        EQU    0FFH
  38. NO:        EQU    0
  39. ;
  40. ; PMC Micromate Model 101 dependant stuff 
  41. ;
  42. PORT:        EQU    89H    ;PMC SERIAL MODEM PORT
  43. MODCTL1:    EQU    PORT+2    ;Modem control port             gts
  44. MODCTL2:    EQU    PORT+2    ;Modem control port             gts
  45. MODDATP:    EQU    PORT    ;Modem data port
  46. MODRCVB:    EQU    01H    ;Your bit to test for receive
  47. MODRCVR:    EQU    01H    ;Your value when receive ready.
  48. MODSNDB:    EQU    04H    ;Your bit to test for send.
  49. MODSNDR:    EQU    04H    ;Your value when xmitter available.
  50. ;
  51. P$BAUD        EQU    93H    ;Upper nibble = TERMNL
  52. P$GETBAUD    EQU    95H    ;Lower nibble = MODEM
  53. ;
  54. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  55. ; MEX Service Processor
  56. ;
  57. MEX    EQU    0D00H        ;address of the service processor
  58. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  59. TIMER    EQU    254        ;delay 100ms * reg B
  60. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  61. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  62. SNDRDY    EQU    251        ;test for modem-send ready
  63. RCVRDY    EQU    250        ;test for modem-receive ready
  64. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  65. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  66. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  67. PARSFN    EQU    246        ;parse filename from input stream
  68. BDPARS    EQU    245        ;parse baud-rate from input stream
  69. SBLANK    EQU    244        ;scan input stream to next non-blank
  70. EVALA    EQU    243        ;evaluate numeric from input stream
  71. LKAHED    EQU    242        ;get nxt char w/o removing from input
  72. GNC    EQU    241        ;get char from input, cy=1 if none
  73. ILP    EQU    240        ;inline print
  74. DECOUT    EQU    239        ;decimal output
  75. PRBAUD    EQU    238        ;print baud rate
  76. ;
  77. CONOUT    EQU    2        ;simulated BDOS function 2: console char out
  78. PRINT    EQU    9        ;simulated BDOS function 9: print string
  79. INBUF    EQU    10        ;input buffer, same structure as BDOS 10
  80. ;
  81.         ORG    100H
  82. ;
  83. ;
  84. ; Change the clock speed to suit your system
  85. ;
  86.         DS    3    ;(for  "JMP   START" instruction)
  87. ;
  88. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  89. SMARTMODEM:    DB    YES    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  90. TOUCHPULSE:    DB    'P'    ;T=touch, P=pulse (Smartmodem-only)    105H
  91. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  92.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  93. MSPEED:        DB    1    ;0=110 1=300 2=450 3=600 4=710 5=1200    107H
  94.                 ;6=2400 7=4800 8=9600 9=19200 default
  95. BYTDLY:        DB    5    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms    108H
  96.                 ;default time to send character in ter-
  97.                 ;minal mode file transfer for slow BBS.
  98. CRDLY:        DB    5    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  99.                 ;default time for extra wait after CRLF
  100.                 ;in terminal mode file transfer
  101. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  102. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH jw
  103. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  104. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  105.                 ;no=resend a record after a valid-NAK
  106. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  107. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH wcw
  108. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  109. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  110. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  111. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  112.                 ;terminal mode (added by remote echo)
  113. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  114. TRANLOGON:    DB    YES    ;yes=allow transmission of logon    115H
  115.                 ;write logon sequence at location LOGON
  116. SAVCCP:        DB    YES    ;yes=do not overwrite CCP        116H
  117. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  118.                 ;no=external command if EXTCHR precedes
  119. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  120. LSTTST:        DB    NO    ;yes=printer available on printer port    119H
  121. XOFFTST:    DB    YES    ;yes=checks for XOFF from remote while    11AH wcw
  122.                 ;sending a file in terminal mode
  123. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  124.                 ;sending a file in terminal mode
  125. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  126. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH wcw
  127. EXTRA1:        DB    0    ;for future expansion            11EH
  128. EXTRA2:        DB    0    ;for future expansion            11FH
  129. BRKCHR:        DB    '@'-40H    ;^@ = Send 300 ms. break tone        120H
  130. NOCONNCT:    DB    'D'-40H    ;^D = Disconnect from the phone line    121H
  131. LOGCHR:        DB    'L'-40H    ;^L = Send logon            122H
  132. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  133. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  134. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  135. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  136. EXTCHR:        DB    '^'-40H    ;^^ = Send next character        127H
  137. ;
  138. ;
  139.         DS    2        ;                128H
  140. ;
  141. ; IN$MODCTL1:    IN    MODCTL1     ;in modem control port        12AH
  142. ;        RET    
  143. ;        DS    7
  144. ;
  145. IN$MODCTL1:    XRA    A        ;Output 00H to command port    12AH wcw
  146.         OUT    MODCTL1         ;                               12BH wcw
  147.         MVI    A,10H        ;Output 10H to command port     12DH jw
  148.         OUT    MODCTL1         ;                               12FH jw
  149.         IN    MODCTL1        ;Get status bits.               131H jw
  150.         RET                     ;                               133H
  151. ;
  152. OUT$MODDATP:    OUT    MODDATP     ;out modem data port        134H
  153.         RET    
  154.         DS    7               ;                               137H
  155. IN$MODDATP:    IN    MODDATP     ;in modem data port        13EH
  156.         RET    
  157.         DS    7               ;                               141H
  158. ANI$MODRCVB:    ANI    MODRCVB        ;bit to test for receive ready    148H
  159.         RET    
  160.  
  161. CPI$MODRCVR:    CPI    MODRCVR        ;value of rcv. bit when ready    14BH
  162.         RET
  163. ANI$MODSNDB:    ANI    MODSNDB        ;bit to test for send ready    14EH
  164.         RET
  165. CPI$MODSNDR:    CPI    MODSNDR        ;value of send bit when ready    151H
  166.         RET    
  167.         DS    6        ;                154H
  168. ;
  169. OUT$MODCTL1:    OUT    MODCTL1        ;out modem control port #2    15AH
  170.         RET
  171. OUT$MODCTL2:    OUT    MODCTL2        ;out modem control port #1    15DH
  172.         RET
  173. ;
  174.         DS    2        ;not used by MEX        160H
  175.         DS    6        ;                162H
  176. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  177. JMP$INITMOD:    JMP    INITMOD        ;go to user written routine    16BH
  178. JMP$NEWBAUD:    JMP    NEWBAUD        ;change baud rate
  179.         RET            ;(by-passes PMMI routine)    171H
  180.         NOP
  181.         NOP
  182.         RET            ;(by-passes PMMI routine)    174H
  183.         NOP
  184.         NOP
  185. JMP$SETUPR:    JMP    SETUPR        ;                177H
  186.         DS    3        ;not used by MEX        17AH
  187. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  188. JMP$BREAK:    JMP    SENDBRK        ;                180H
  189. ;
  190. ;
  191. ; Do not change the following six lines.
  192. ;
  193. JMP$ILPRT:    DS    3        ;                183H
  194. JMP$INBUF    DS    3        ;                186H
  195. JMP$INLNCOMP:    DS    3        ;                189H
  196. JMP$INMODEM    DS    3        ;                18CH
  197. JMP$NXTSCRN:    DS    3        ;                18FH
  198. JMP$TIMER    DS    3        ;                192H
  199. ;
  200. ;
  201. ; Routine to clear to end of screen.  If using CLREOS and CLRSCRN, set
  202. ; SCRNTEST to YES at 010AH (above).
  203. ;
  204. CLREOS:        LXI    D,EOSMSG
  205.         MVI    C,PRINT
  206.         CALL    MEX
  207.         RET
  208. ;
  209. CLRSCRN:    LXI    D,CLSMSG
  210.         MVI    C,PRINT
  211.         CALL    MEX
  212.         RET
  213.     
  214. ;
  215. ;
  216. SYSVER:        MVI    C,ILP        ;                1A7H
  217.         CALL    MEX
  218.         DB    'Version for PMC Micromate Model 101 - '
  219.         DB    CR,LF
  220.         DB    'With external Hayes Smartmodem 1200'
  221.         DB    CR,LF,0
  222.         RET
  223. ;-----------------------------------------------------------------------
  224. ;
  225. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  226. ;     end of your last routine should terminate by 0400H (601 bytes
  227. ;     available after start of SYSVER) if using the Hayes Smartmodem
  228. ;     or by address 0C00H (2659 bytes) otherwise.
  229. ;
  230. ;-----------------------------------------------------------------------
  231. ;
  232. ; Add your own routine here to send a break tone to reset some time-sharing
  233. ; computers, if desired.
  234. ; 
  235. SENDBRK:    RET
  236. ;.....
  237. ;
  238. ;
  239. ; Add your own routine here to put DTR low and/or send a break tone.
  240. ; Check other routines such as MDM709DP.ASM (M7DP-1.ASM) which is
  241. ;    using this feature.
  242. ;
  243. GOODBYE:    RET
  244. ;.....
  245. ;
  246. ;
  247. ; You can use this area for any special initialization or setup you may
  248. ; wish to include.  Each must stop with a RET. You can check the other
  249. ; available overlays for ideas how to write your own routines if that
  250. ; may be of some help.
  251. ;
  252. INITMOD:MVI    L,8            ;set baud rate to 1200
  253.     CALL    BAUDMCH
  254.     MVI    A,5
  255.     STA    MSPEED            ;set MSPEED to match
  256.     RET
  257. ;
  258. ;Allow baud rate change w SET cmd
  259. SETUPR:    MVI    C,SBLANK        ;any arguments
  260.     CALL    MEX
  261.     JC    TELL            ;if not, go display baud
  262.     LXI    D,CMDTBL
  263.     MVI    C,LOOKUP
  264.     CALL    MEX            ;parse argument
  265.     PUSH    H            ;save any arg addrs on stack
  266.     RNC                ;if we have one, return to it
  267.     POP    H            ;oops, input not found in table
  268.     MVI    C,ILP
  269.     CALL    MEX            ;tell user input not valid
  270.     DB    '++ Incorrect Entry ++',CR,LF,BELL,0
  271.     RET
  272.  
  273. CMDTBL:    DB    '30','0'+80H
  274.     DW    OK300
  275.     DB    '60','0'+80H
  276.     DW    OK600
  277.     DB    '120','0'+80H
  278.     DW    OK1200
  279.     DB    '240','0'+80H
  280.     DW    OK2400
  281.     DB    '480','0'+80H
  282.     DW    OK4800
  283.     DB    '960','0'+80H
  284.     DW    OK9600
  285.     DB    '1920','0'+80H
  286.     DW    OK1920
  287. ;
  288. TELL    MVI    C,ILP
  289.     CALL    MEX            ;print current baud rate
  290.     DB    CR,LF,'Baud rate is now: ',0
  291.     LDA    MSPEED
  292.     MVI    C,PRBAUD
  293.     CALL    MEX
  294.     RET
  295.  
  296. OK300:    MVI    A,1            ;MSPEED 300 baud value
  297.     LHLD    BD300            ;300 baud value in 'HL'
  298.     JMP    BAUDMCH            ;go do it
  299.  
  300. OK600:    MVI    A,3
  301.     LHLD    BD600
  302.     JMP    BAUDMCH
  303.  
  304. OK1200:    MVI    A,5
  305.     LHLD    BD1200
  306.     JMP    BAUDMCH
  307.  
  308. OK2400:    MVI    A,6
  309.     LHLD    BD2400
  310.     JMP    BAUDMCH
  311.  
  312. OK4800:    MVI    A,7
  313.     LHLD    BD4800
  314.     JMP    BAUDMCH
  315.  
  316. OK9600:    MVI    A,8
  317.     LHLD    BD9600
  318.     JMP    BAUDMCH
  319.  
  320. OK1920:    MVI    A,9
  321.     LHLD    BD1920
  322.     JMP    BAUDMCH
  323.  
  324. BAUDMCH:PUSH    PSW        ;save MSPEED value
  325.     PUSH    H        ;Save baud code
  326.     MVI    C,32H        ;Function: direct bios call.
  327.     LXI    D,BIOSPB    ;BIOS parameter block
  328.     CALL    5
  329.     LXI    D,8+7        ;Index to BAUD rate in 2nd
  330.     DAD    D        ; entry. (i.e. MODEM)
  331.     POP    D        ;Get new code back.
  332.     MOV    A,M        ;Best not to change high
  333.     ANI    0F0H        ; nibble, whatever it is.
  334.     ORA    E        ;Put new code in table.
  335.     MOV    M,A
  336. ;
  337.     MVI    C,32H        ;Function: direct bios call.
  338.     LXI    D,BIOSPB1    ;Initialize device means to
  339.     CALL    5        ; set BAUD rate to PMC.
  340.     POP    PSW        ;restore MSPEED value
  341.     STA    MSPEED        ;set it
  342.     RET
  343.  
  344. NEWBAUD:CPI    1
  345.     JZ    OK300
  346.     CPI    3
  347.     JZ    OK600
  348.     CPI    5
  349.     JZ    OK1200
  350.     CPI    6
  351.     JZ    OK2400
  352.     CPI    7
  353.     JZ    OK4800
  354.     CPI    8
  355.     JZ    OK9600
  356.     CPI    9
  357.     JZ    OK1920
  358.     RET
  359. ;
  360. ; Table of Baud Rate Parameters
  361. ;
  362. BD300    DW    0006H
  363. BD600    DW    0007H
  364. BD1200    DW    0008H
  365. BD2400    DW    000AH
  366. BD4800    DW    000CH
  367. BD9600    DW    000EH
  368. BD1920    DW    000FH
  369. ;
  370. BIOSPB        DB    20    ;BIOS fcn: return devtbl address
  371.         DB    0    ;A-reg contents
  372.         DW    0    ;BC-reg contents
  373.         DW    0    ;DE-reg contents
  374.         DW    0    ;HL-reg contents
  375. ;
  376. BIOSPB1        DB    21    ;BIOS fcn: initialize device in c-reg
  377.         DB    0    ;A-reg contents
  378.         DB    1    ;C-reg=1 for MODEM
  379.         DB    0    ;B-reg
  380.         DW    0    ;DE-reg
  381.         DW    0    ;HL-reg
  382. ;
  383. SPCLMENU:    RET
  384. ;.....
  385. ;
  386. ;    
  387. ;
  388. BAUDBUF:    DB    10,0
  389.         DS    10
  390.  
  391. EOSMSG:    DB    23,0,0,0,0,'$'    ;clear to eos for Cybernex XL-87
  392. CLSMSG:    DB    24,0,0,0,0,'$'    ;clear screen for Cybernex XL-87
  393.  
  394. ;-----------------------------------------------------------------------
  395. ;
  396. ; NOTE:  MUST TERMINATE PRIOR TO 0B00H (with Smartmodem)
  397. ;                 0D00H (without Smartmodem)
  398. ;.....
  399. ;
  400.       END
  401. ;
  402.