home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-OS22.AQM / MXO-OS22.ASM
Assembly Source File  |  2000-06-30  |  15KB  |  451 lines
  1. ; MXO-OS22.ASM - OSBORNE 1 OVERLAY                                  24 AUG 84
  2. ; for MEX11.COM - Changed START location to 0EB9H
  3. ; Mark S. Stein, Morton Grove RBBS RCP/M (312) 470-0017
  4. ;
  5. ; MXO-OS21.ASM - Osborne I Overlay                      10JULY84
  6. ; for MEX10.COM & MDM7xx.COM file - 10 JULY 84                 10JULY84
  7. ;
  8. ; This version is a synthesis of MXO-OS01, MXO-OS12.  The primary    10JULY84
  9. ; change from Bob Schultz's MXO-OS01 version is implementation of    10JULY84
  10. ; the  NEWBD  vector, allowing support of the optional baud  rate    10JULY84 
  11. ; entry for phone numbers.
  12. ; 
  13. ;    -- Howard Gerber, WB5YWS                     10JULY84
  14. ;       contact me through the OZZ-HAM RCP/M (713) 893-0424         10JULY84
  15. ;       or The Weekender (713) 492-8700                 10JULY84
  16.  
  17. ; Bob Schultz's notes follow:                         10JULY84
  18.  
  19. ; This file is derived from MDM711OS.ASM by Irv Hoff and Paul Kelly.
  20. ; It was necessary to put in some kludges to make it work with MEX10.
  21. ; The problem was that MEX10 called the modem routines before it called
  22. ; the modem initialization routine.  Since the modem routines MUST be
  23. ; above 4000H, ozy wasn't very happy.  While I was at it, I cleaned up
  24. ; the baud rate routines so that the default baud rate can be set by
  25. ; setting MSPEED to the desired value.  I also added a send break routine
  26. ; and a disconnect routine.  Unfortunately, these routines will work only
  27. ; if you use the modem connector rather than the RS-232 connector.  It
  28. ; seems that ozy was designed to use the RS-232 connector to be able to
  29. ; drive a printer at the same time that the modem connector is being used.
  30. ; I don't know why anyone would want a serial printer when a parallel
  31. ; printer is cheaper, but that's the way OCC did it.  The problem with
  32. ; sending a break through the serial port is the MC6850 ACIA can only send
  33. ; a break when RTS is ON.  This is quite reasonable, but the hardware
  34. ; design of the Osborne I clamps the transmitted data from the RS-232
  35. ; connector to a MARK when RTS is on.  Since a break is a SPACE, this
  36. ; doesn't work very well.  The only solutions are: 1) Build an interface
  37. ; to convert the modem connector signals to proper RS-232 signals
  38. ; 2) Modify the main logic board.  This looks like it would be very
  39. ; easy to do, but I haven't tried it.  Just lift the ends of the resistors
  40. ; R20 (10K) and R35 (1.0K) that are connected together and connect the
  41. ; ends off the board with a wire.  I don't know if the resistors are
  42. ; labeled, or even if the mod will work.  It should, but there are as
  43. ; many gotcha's in hardware as there are in software.  Good luck.  If you
  44. ; do make the mod, set the RS232 EQU to NO.
  45.  
  46. ; This file should also work with MDM730 -- I mean MDM740 or perhaps it's
  47. ; now MDM750.  Just set MEX to off.  But if you can get MEX, why bother
  48. ; with MDM?
  49.  
  50. ; A few helpful hints for MEX10.  When MEX starts up, it tries to READ 
  51. ; INI.MEX.  You can create the INI file with an editor and put any MEX
  52. ; commands that you want into it.  Or else you can disable the feature
  53. ; with STAT INITFILE OFF and then clone it.  When you get sick of the
  54. ; prompt that you get when entering terminal mode type POKE $40A0 $C9
  55. ; and then clone it.  The clone number is two bytes at 5335H with the
  56. ; low order byte first.
  57.  
  58. ; I'm releasing this file as version 0.1 without as much testing as I'd
  59. ; like to do only because I can hear the anguished cries of Osborne owners
  60. ; who are faced with yet another version of MDM and can't get MEX running.
  61. ; When I have more time, I'll release an upgraded version 1.0.
  62.  
  63. ; You can contact me through just about any RCPM system in Toronto.
  64.  
  65. ;    Bob Schultz
  66.  
  67. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  68.  
  69. BELL:    EQU    07H        ;bell
  70. CR:    EQU    0DH        ;carriage return
  71. ESC:    EQU    1BH        ;escape
  72. LF:    EQU    0AH        ;linefeed
  73.  
  74. YES:    EQU    0FFH
  75. NO:    EQU    0
  76.  
  77. START:    EQU    0EB9H    ;location MEX10 jumps to -- for kludge
  78.  
  79. RS232:    EQU    YES    ;set this to YES if you're
  80.                 ;   using the RS232 connector
  81.                 ;and to NO if you're using the modem connector
  82. MEX:    EQU    YES    ;set this to YES for MEX10
  83.                 ;and to NO for MDM7
  84.  
  85. ; values to send to 6850 control register for
  86. ; 8 bits, no parity, 1 stop bit
  87. IF    RS232            ;RTS MUST be off
  88. BAUD3:        EQU    56H        ;300 baud 8-bit no parity
  89. BAUD12:        EQU    55H        ;1200 baud 8-bit no parity
  90. ENDIF
  91. IF NOT    RS232            ;RTS on seems reasonable
  92. BAUD3:        EQU    16H        ;300 baud 8-bit no parity
  93. BAUD12:        EQU    15H        ;1200 baud 8-bit no parity
  94. BRKBIT:        EQU    60H        ;bits to set to send break
  95. RTSBIT:        EQU    40H        ;bit to turn off RTS
  96. ENDIF
  97.  
  98. MODCTLP:    EQU    2A00H    ;status register for RS232
  99. MODDATP:    EQU    MODCTLP+1 ;data resister for RS232
  100. MODSNDB:    EQU    2    ;bit to test for ready to send
  101. MODSNDR:    EQU    2    ;modem send ready when high
  102. MODRCVB:    EQU    1    ;bit to test for received data
  103. MODRCVR:    EQU    1    ;modem receive ready when high
  104.  
  105.     ORG    100H
  106.  
  107. IF    MEX
  108.     JMP    INITMOD    ;I hate this kludge
  109. ENDIF
  110. IF NOT    MEX
  111.     DS    3
  112. ENDIF
  113.  
  114. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  115. SMARTMODEM:    DB    YES    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  116. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  117. CLOCK:        DB    40    ;clock speed in MHz x10, 25.5 MHz max.    106H
  118.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  119. MSPEED:        DB    5    ;0=110 1=300 2=450 3=600 4=710 5=1200   107H
  120.                 ;6=2400 7=4800 8=9600 9=19200 default
  121. BYTDLY:        DB    9    ;0=0 delay  1=10ms  5=50 ms - 9=90 ms   108H
  122.                 ;default time to send character in ter-
  123.                 ;minal mode file transfer for slow BBS.
  124. CRDLY:        DB    9    ;0=0 delay 1=100 ms 5=500 ms - 9=900 ms 109H
  125.                 ;default time for extra wait after CRLF
  126.                 ;in terminal mode file transfer
  127. NOOFCOL:    DB    4    ;number of DIR columns shown        10AH
  128. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  129. SCRNTEST:    DB    YES    ;cursor control routine         10CH
  130. ACKNAK:        DB    YES    ;yes=resend a record after any non-ACK    10DH
  131.                 ;no=resend a record after a valid NAK
  132. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  133. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  134. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  135. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  136. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  137. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  138.                 ;terminal mode (added by remote echo)
  139. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  140. TRANLOGON:    DB    NO    ;yes=allow transmission of logon    115H
  141.                 ;write logon sequence at location LOGON
  142. SAVCCP:        DB    NO    ;no=do not save CCP, may be overwritten 116H
  143. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  144.                 ;no=external command if EXTCHR precedes
  145. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  146. LSTTST:        DB    YES    ;yes=printer available on printer port    119H
  147. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  148.                 ;sending a file in terminal mode
  149. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  150.                 ;sending a file in terminal mode
  151. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  152. IGNORCTL:    DB    NO     ;yes=CTL-chars above ^M not displayed    11DH
  153. EXTRA1:        DB    0    ;for future expansion            11EH
  154. EXTRA2:        DB    0    ;for future expansion            11FH
  155. BRKCHR:        DB    'B'-40H    ;^B = Send a 300 ma. break tone        120H
  156. NOCONNCT:    DB    'N'-40H    ;^N = Disconnect from the phone line    121H
  157. LOGCHR:        DB    'W'-40H    ;^W = Send logon            122H
  158. LSTCHR:        DB    'P'-40H    ;^P = Toggle printer            123H
  159. UNSAVE:        DB    'R'-40H    ;^R = Close input text buffer        124H
  160. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  161. SAVECHR:    DB    'Y'-40H    ;^Y = Open input text buffer        126H
  162. EXTCHR:        DB    '\'-40H    ;^\ = Send next character        127H
  163.         DS    2        ;                128H
  164.  
  165. IN$MODCTLP:    CALL    $-$    ! RET    ;get the I/O status        12AH
  166.         DS    6        ;patched to OSTAT by INITMOD
  167.  
  168. OUT$MODDATP:    CALL    $-$    ! RET    ;send a character to the I/O    134H
  169.         DS    6        ;patched to OSOUT by INITMOD 
  170.  
  171. IN$MODDATP:    CALL    $-$    ! RET    ;get a character from the I/O    13EH
  172.         DS    6        ;patched to OSIN by INITMOD
  173.  
  174. ANI$MODRCVB:    ANI    MODRCVB ! RET    ;bit to test for receive ready    148H
  175. CPI$MODRCVR:    CPI    MODRCVR ! RET    ;value of rcv. bit when ready    14BH
  176. ANI$MODSNDB:    ANI    MODSNDB ! RET    ;bit to test for send ready    14EH
  177. CPI$MODSNDR:    CPI    MODSNDR ! RET    ;value of send bit when ready    151H
  178.         DS    12        ;                156H
  179. LOGONPTR:    DW    LOGON        ;for user message.        160H
  180.         DS    3        ;                162H
  181. JMP$DISCON    JMP    DISCON        ;                165h
  182. JMP$GOODBYE:    JMP    GOODBYE        ;                168H
  183. JMP$INITMOD:
  184. IF    MEX
  185.         RET  !  NOP  !  NOP    ;already initialized by kludge    16BH
  186. ENDIF
  187. IF NOT    MEX
  188.         JMP    INITMOD        ;initialize modem code and 6850
  189. ENDIF
  190.  
  191. IF    MEX
  192.         JMP  NEWBD    ; support optional NEWBD    10JULY84    16EH
  193. ENDIF
  194. IF NOT    MEX
  195.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    16EH
  196. ENDIF
  197.  
  198.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    171H
  199.         RET  !  NOP  !  NOP    ;(by-passes PMMI routine)    174H
  200. JMP$SETUPR:    JMP    SETUPR        ;                177H
  201. JMP$SPCLMENU:    JMP    SPCLMENU    ;                17AH
  202. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  203. JMP$BREAK:    JMP    SENDBRK        ;                180H
  204.  
  205. ; Do not change the following six lines.
  206.  
  207. JMP$ILPRT:    DS    3        ;                183H
  208. JMP$INBUF    DS    3        ;                186H
  209. JMP$INLNCOMP:    DS    3        ;                189H
  210. JMP$INMODEM    DS    3        ;                18CH
  211. JMP$NXTSCRN:    DS    3        ;                18FH
  212. JMP$TIMER:    DS    3        ;                192H
  213.  
  214. CLREOS:        CALL    JMP$ILPRT    ;                195H
  215.         DB    0,0,0,0,0    ;O-1 has no clear EOS.        198H
  216.         RET            ;                19DH
  217.  
  218. CLRSCRN:    CALL JMP$ILPRT        ;                19EH
  219.         DB    1AH,0,0,0,0    ;O-1 clear screen, home cursor  1A1H
  220.         RET            ;                1A6H
  221.  
  222. SYSVER:    CALL    JMP$ILPRT    ;                1A7H
  223.             
  224.     DB    CR,LF
  225.     DB    01BH,')'    ;into half intensity
  226.     DB    'For the Osborne 1: '
  227.     DB    01BH,'('    ;out of half intensity
  228.     DB    'Revised by M. Stein - 08/24/84'
  229.     DB      CR,LF,LF,0
  230.     RET
  231.  
  232. ;-----------------------------------------------------------------------
  233. ;
  234. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  235. ;     end of your last routine should terminate by 0400H (601 bytes
  236. ;     available after start of SYSVER) if using the Hayes Smartmodem
  237. ;     or by address 0C00H (2659 bytes) otherwise.
  238. ;
  239. ;-----------------------------------------------------------------------
  240.  
  241. ; You can put in a message at this location which can be called up with
  242. ; CTL-W if TRANLOGON has been set TRUE.  You can put in several lines if
  243. ; desired.  End with a 0.
  244.  
  245. LOGON:        DB    0
  246.  
  247.  
  248. ; Sends a 300 msec break.  Will work only with the modem connector. 
  249.  
  250. SENDBRK:
  251. IF NOT    RS232
  252.         PUSH    H
  253.         LDA    BAUD        ;turn on break
  254.         ORI    BRKBIT
  255.         CALL    OSET
  256.         MVI    B,3        ;wait for 300 ms
  257.         CALL    JMP$TIMER
  258.         LDA    BAUD        ;turn off break 
  259.         CALL    OSET
  260.         POP    H
  261. ENDIF
  262.         RET
  263.  
  264.  
  265. ;  Drops RTS for 3 sec.  RTS is not available on the RS232 connector. 
  266.  
  267. DISCON:
  268. IF NOT    RS232
  269.         PUSH    H
  270.         LDA    BAUD        ;drop RTS
  271.         ORI    RTSBIT
  272.         CALL    OSET
  273.         MVI    B,30        ;wait for 3 sec
  274.         CALL    JMP$TIMER
  275.         LDA    BAUD        ;restore RTS
  276.         CALL    OSET
  277.         POP    H
  278. ENDIF
  279.         RET
  280.  
  281.  
  282. ; if you put a routine in here, it should NOT do a disconnect when
  283. ; using MEX.  That's handled by the DISCON routine above
  284.  
  285. GOODBYE:    RET
  286.  
  287. ; You can put any items in this area you wish to display that are of in-
  288. ; terest to those using this equipment.  If using the Hayes Smartmodem
  289. ; this is unavailable without a special address change.  End the routine
  290. ; with a RET.
  291.  
  292. SPCLMENU:    RET
  293.  
  294.  
  295. ; This is the Osborne initialization routine.
  296.  
  297. INITMOD:
  298. IF NOT    MEX            ;MEX could not be cloned if this code was in
  299.     LDA    FINITFLG    ;flag set yet?
  300.     ORA    A
  301.     RNZ            ;return if have already been here
  302.     INR    A
  303.     STA    FINITFLG    ;set flag
  304. ENDIF
  305.     LHLD    0005H+1        ;FIND START OF BDOS
  306.     LXI    D,-0100H    ;GO TO FIRST PAGE AHEAD OF BDOS
  307.     DAD    D        ;HL NOW POSITIONED ONE PAGE BELOW BDOS
  308.     PUSH    H        ;SAVE THE ADDRESS
  309.     LXI    D,BDJ        ;POINT TO OUR ROUTINE TO PUT THERE
  310.     LXI    B,CDLEN+2    ;SET LENGTH OF CODE
  311.     XCHG
  312.     DB    0EDH,0B0H    ;Z80 LDIR
  313.  
  314.     LHLD    0005H+1        ;GET BDOS ADDRESS BACK ONCE MORE
  315.     POP    D        ;GET THE STARTING ADDRESS OFF STACK
  316.     PUSH    D        ;PUT IT BACK ON THE STACK
  317.     INX    D        ;POINT TO ADDRESS POSITION
  318.     XCHG            ;PUT INTO 'HL'
  319.     MOV    M,E        ;STORE 'LSP' ADDRESS
  320.     INX    H        ;GET 'LSP' LOCATION
  321.     MOV    M,D        ;STORE 'MSP' ADDRESS
  322.     POP    H        ;GET THE ADDRESS BACK ONCE MORE
  323.     SHLD    0005H+1        ;NEW ADDRESS TO PROTECT FOR OVERWRITE
  324.  
  325.     LXI    D,OSIN-BDJ    ;GET THE LENGTH OF ROUTINE TO MOVE
  326.     DAD    D        ;COMUTE ADDRESS OF THE 'OSIN' ROUTINE
  327.     SHLD    IN$MODDATP+1        ;PATCH CALL FOR "GET CHAR." ROUTINE
  328.     LXI    D,OSOUT-OSIN
  329.     DAD    D
  330.     SHLD    OUT$MODDATP+1    ;PATCH CALL FOR "SEND CHAR." ROUTINE
  331.     LXI    D,OSTAT-OSOUT
  332.     DAD    D
  333.     SHLD    IN$MODCTLP+1    ;PATCH CALL FOR "GET STATUS" ROUTINE
  334.     MVI    C,BAUD3        ;300 baud for 6850
  335.     LDA    MSPEED
  336.     CALL    NEWBD        ; set baud rate            10JULY84
  337. IF    MEX
  338.     JMP    START        ;more kludge
  339. ENDIF
  340. IF NOT    MEX
  341.     RET
  342. ENDIF
  343.  
  344.  
  345. NEWBD:    CPI    1        ;                10JULY84
  346.     JZ    OK300        ;                10JULY84
  347.     CPI    5        ;                10JULY84
  348.     JZ    OK1200        ;                10JULY84
  349.     RET            ;                10JULY84
  350.  
  351. OK300:    MVI    A,1        ; MSPEED 300 bps        10JULY84
  352.     MVI    C,BAUD3        ; 01 300 bps            10JULY84
  353.     STA    MSPEED        ;                10JULY84
  354.     JMP    STBAUD        ;                10JULY84
  355.  
  356. OK1200:    MVI    A,5        ; MSPEED 1200 bps        10JULY84
  357.     MVI    C,BAUD12    ; 01 1200 bps            10JULY84
  358.     STA    MSPEED        ;                10JULY84
  359. STBAUD:    PUSH    H        ;                10JULY84
  360.     CALL    OSET1        ; set baud rate            10JULY84
  361.     POP    H        ;                10JULY84
  362.     XRA    A        ; clear carry            10JULY84
  363.     RET            ;                10JULY84
  364.  
  365. ; stuff the control register on the 6850
  366.  
  367. OSET:    MOV    C,A
  368. OSET1:    LHLD    1        ;GET BIOS+3 ADDRESS
  369.     MVI    L,3CH        ;SPECIAL OSBORNE ROUTINE
  370.     PCHL            ;BRANCH TO IT
  371.  
  372.  
  373. ; Change the baud rate with the SET command
  374.  
  375. SETUPR:      PUSH    H
  376.  
  377. AGAIN:    LXI    D,BAUDBUF    ;POINT TO INPUT BUFFER
  378.     CALL    JMP$ILPRT
  379.     DB    'Input Baud Rate (300, 1200): ',0
  380.     CALL    JMP$INBUF
  381.     LXI    D,BAUDBUF+2
  382.  
  383.     CALL    JMP$INLNCOMP    ;COMPARE BAUDBUF+2 WITH CHARACTERS BELOW
  384.     DB    '300',0
  385.     MVI    A,1        ;MSPEED 300 BAUD
  386.     MVI    C,BAUD3        ;OSBORNE 300 BAUD
  387.     JNC    OK        ;GO IF GOT MATCH
  388.  
  389.     CALL    JMP$INLNCOMP
  390.     DB    '1200',0
  391.     MVI    A,5        ;MSPEED 1200 BAUD
  392.     MVI    C,BAUD12    ;OSBORNE 1200 BAUD
  393.     JNC    OK
  394.  
  395.     CALL    JMP$ILPRT    ;ALL MATCHES FAILED - TELL OPERATOR
  396.     DB    '++ Incorrect entry ++',CR,LF,BELL,0
  397.     JMP    AGAIN        ;TRY AGAIN
  398.  
  399. OK:    STA    MSPEED        ;SET MSPEED
  400.     MOV    A,C
  401.     STA    BAUD        ;save 6850 control register image
  402.     CALL    OSET
  403.     POP    H
  404.     XRA    A        ;CLEAR CARRY
  405.     RET
  406.  
  407. BAUDBUF:  DB    10,0
  408.       DS    10
  409. BAUD:      DS    1
  410. IF NOT    MEX
  411. FINITFLG: DB    0
  412. ENDIF
  413.  
  414.  
  415. ; --- ROUTINES THAT GET PLACED JUST UNDER 'BDOS' OVERLAYING 'CCP'
  416.  
  417. BDJ:    JMP    $-$        ;THIS GETS PATCHED TO JUMP TO BDOS ENTRY
  418.  
  419. OSIN:    DI            ;DISABLE INTERRUPTS
  420.     OUT    0        ;SWITCH TO ALTERNATE PAGE
  421.     LDA    MODDATP        ;GET DATA BYTE
  422.     OUT    1        ;SWITCH PAGES BACK
  423.     EI            ;RE-ENABLE INTERRUPTS
  424.     RET
  425.  
  426.  
  427. OSOUT:    DI            ;DISABLE INTERRUPTS
  428.     OUT    0        ;SWITDH TO ALTERNATE PAGE
  429.     STA    MODDATP        ;SEND DATA BYTE
  430.     OUT    1        ;SWITCH PAGES BACK
  431.     EI            ;RE-ENABLE INTERRUPTS
  432.     RET
  433.  
  434.  
  435. OSTAT:    DI            ;DISABLE INTERRUPTS
  436.     OUT    0        ;SWITCH TO ALTERNATE PAGE
  437.     LDA    MODCTLP        ;GET STATUS BYTE
  438.     OUT    1        ;SWITCH PAGES BACK
  439.     EI            ;RE-ENABLE INTERRUPTS
  440.     RET
  441.  
  442.  
  443. CDLEN:    EQU    $-BDJ        ;LENGTH OF CODE TO COPY
  444.  
  445. ;-----------------------------------------------------------------------
  446. ;
  447. ; NOTE:  MUST TERMINATE PRIOR TO 0400H (with Smartmodem)
  448. ;                 0C00H (without Smartmodem)
  449. ;
  450.     END
  451.