home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-MM2.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  19KB  |  766 lines
  1. ; MXMM-2.ASM
  2. ;
  3. REV     EQU     20        ;OVERLAY REVISION LEVEL
  4. ;
  5. ; MEX Micromodem II/IIe overlay for the APPLE II/II+/IIe;
  6. ;    written 09/04/84 by Joe Patterson (70235,460)
  7. ;        adapted from
  8. ;
  9. ; MEX Apple Super Serial Card / Novation J-Cat overlay
  10. ;    written 05/18/84 by D. W. Walker
  11. ;    ALS bank-switching adapted from
  12. ;    an overlay by James M. Scardelis
  13. ;
  14. ; Revn: 1.0  04 Sept 84 -- Modified MXO-AP.21 to produce this
  15. ;                overlay.
  16. ;    2.0  09 SEPT 84 -- ADDED TOUCH-TONE DIALING FOR THE
  17. ;               MICROMODEM IIE (ONLY)
  18. ;            -- RENAMED TO MXMM-2.ASM FROM MXO-MM10.ASM
  19. ;            -- ADDED CONTROL PORT 3 JUMP FOR THE
  20. ;               SOFTCARD (COULD NOT USE MMIIE ON 
  21. ;               SOFTCARD OTHERWISE)
  22. ;
  23. ;
  24. ; This overlay is for the MEX--- series of modem programs. It is
  25. ;   adapted from MXO-AP.21 to work with the APPLE II and the
  26. ;   Hayes Micromodem II and IIe with either the ALS CP/M CARD
  27. ;   or the Microsoft Softcard. Data format is 8 bits, no parity,
  28. ;   1 stop bit. If you have the Micromodem IIe then answer YES
  29. ;   to --BOTH-- equates MM and MM2e to turn the speaker on when
  30. ;   dialing and off when connected. If you have the Micromodem II
  31. ;   then you must --NOT-- answer yes to the MM2e equate as the
  32. ;   program will probably bomb out if you do.
  33. ;
  34. ; Revision 2.0 now supports touch-tone dialing on the Micromodem
  35. ;   IIe (ONLY) if you answer YES to the MM2E equate. When using
  36. ;   touch-tone, the comma (,) feature is supported. Inserting a
  37. ;   comma in the number being dialed, causes a 2 second delay for
  38. ;   each one used. For example, 555-12,34 causes dialing to pause
  39. ;   for 2 seconds between digits 2 and 3. This is especially useful
  40. ;   when waiting for an outside line or a second dial tone. Multiple
  41. ;   commas can be used.
  42. ;
  43. ; I have tested this overlay and it seems to work ok, but, if
  44. ;   anyone finds any let me know and I will try to correct them
  45. ;   as soon as possible.
  46. ;
  47. ;
  48. ; The SET WAIT command adjusts the time that the dialing
  49. ;   routines will wait for a connection (carrier), from
  50. ;   0 to 25 seconds.
  51. ; 
  52. ; NOTE: Most of the comments from Ron Fowler's MXO-PM10.ASM
  53. ;   have been omitted here to save space.  A copy of that file
  54. ;   will be very helpful in understanding what's going on here. 
  55. ;
  56. ;------------------------------------------------------------
  57. ;
  58. ; Misc equates
  59. ;
  60. NO    EQU    0
  61. YES    EQU    0FFH
  62. TPA    EQU    100H
  63. CR    EQU    13
  64. LF    EQU    10
  65. BELL    EQU    7
  66. TAB    EQU    9
  67. ESC    EQU    27
  68. ;      
  69. MM    EQU    YES    ;YES FOR HAYES MICROMODEM II
  70. MM2E    EQU    YES    ;YES FOR MM2E ONLY (FOR TOUCH-TONE & SPEAKER)
  71.             ;MUST BE NO IF YOU HAVE THE MICROMODEM II
  72. SFTCRD    EQU    NO    ;YES for Microsoft Softcard } choose
  73. ALSCRD    EQU    YES    ;YES for ALS CP/M+ card     } one only
  74. ; 
  75.     IF SFTCRD
  76. POFF    EQU    2000H    ;Softcard address offset
  77. RATE    EQU    20
  78.     ENDIF
  79. ;
  80.     IF ALSCRD
  81. POFF    EQU    0
  82. RATE    EQU    60
  83.     ENDIF
  84. ;
  85.     IF    MM
  86. SLOT    EQU    20H        ;SLOT FOR MICROMODEM X 10
  87. PORT    EQU    0C086H+POFF+SLOT  ;BASE CTL/STAT PORT FOR MM
  88. MODDAT    EQU    PORT+1        ;MM DATA PORT
  89. MODSTT    EQU    PORT        ;MM STATUS PORT
  90. MODCTL    EQU    PORT        ;MM CTL PORT 1
  91. BAUDRP    EQU    PORT-1        ;MM CTL PORT 2
  92. MODCTL3:EQU    PORT-3        ;MM2e CONTROL PORT 3
  93. ;
  94. ;
  95. MDRCVB    EQU    01H    ;MM RECIEVE BIT
  96. MDRCVR    EQU    01H    ;MM RECIEVE READY BIT
  97. MDSNDB    EQU    02H    ;MM SEND BIT
  98. MDSNDR    EQU    02H    ;MM SEND READY BIT
  99. ;
  100. DTR     EQU    8FH        ;TRANS ENABLE, ORIG., 300 BAUD
  101. OFFHK    EQU    80H        ;OFF-HOOK
  102. ONHK    EQU    0        ;ON-HOOK
  103. SPKRON    EQU    00100000B    ;MMIIe SPEAKER ON
  104. SPKROFF EQU     00000000B    ;MMIIe SPEAKER OFF
  105. ;
  106. CTSMSK    EQU    00000000B      ;MASK TO TEST FOR CARRIER
  107. BRKMSK    EQU    60H          ;MASK TO SET BREAK
  108. ONHOOK    EQU    0C085H+POFF+SLOT  ;ADDRESS FOR ONHOOK SET
  109. OFFHOOK EQU    ONHOOK            ;OFFHOOK ADDRESS
  110.     ENDIF    ;MM
  111. ;
  112. ;
  113. ;
  114. ; MEX service processor stuff ... See MXO-PM10.ASM
  115. ;
  116. MEX    EQU    0D00H        ;address of the service processor
  117. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  118. TIMER    EQU    254        ;delay 100ms * reg B
  119. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  120. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  121. SNDRDY    EQU    251        ;test for modem-send ready
  122. RCVRDY    EQU    250        ;test for modem-receive ready
  123. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  124. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  125. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  126. PARSFN    EQU    246        ;parse filename from input stream
  127. BDPARS    EQU    245        ;parse baud-rate from input stream
  128. SBLANK    EQU    244        ;scan input stream to next non-blank
  129. EVALA    EQU    243        ;evaluate numeric from input stream
  130. LKAHED    EQU    242        ;get nxt char w/o removing from input
  131. GNC    EQU    241        ;get char from input, cy=1 if none
  132. ILP    EQU    240        ;inline print
  133. DECOUT    EQU    239        ;decimal output
  134. PRBAUD    EQU    238        ;print baud rate
  135. ;
  136. ;
  137. CONOUT    EQU    2        ;simulated BDOS function 2: console char out
  138. PRINT    EQU    9        ;simulated BDOS function 9: print string
  139. INBUF    EQU    10        ;input buffer, same structure as BDOS 10
  140. ;
  141.     ORG    TPA        ;we begin
  142. ;
  143. ;
  144.     DS    3        ;MEX has a JMP START here
  145. ;
  146. ; The following variables are located at the beginning of the program
  147. ; to facilitate modification without the need of re-assembly. They will
  148. ; be moved in MEX 2.0.
  149. ;
  150. PMODEM:    DB    YES        ;yes=PMMI modem \ / These 2 locations are not
  151. SMODEM:    DB    NO        ;yes=Smartmodem / \ referenced by MEX
  152. TPULSE:    DB    'P'        ;T=touch, P=pulse (not referenced by MEX)
  153. CLOCK:    DB    RATE        ;clock speed x .1, up to 25.5 mhz.
  154. MSPEED:    DB    1        ;sets display time for sending a file
  155.                 ;0=110    1=300  2=450  3=600  4=710
  156.                 ;5=1200 6=2400 7=4800 8=9600 9=19200
  157. BYTDLY:    DB    5        ;default time to send character in
  158.                 ;terminal mode file transfer (0-9)
  159.                 ;0=0 delay, 1=10 ms, 5=50 ms, 9=90 ms
  160. CRDLY:    DB    3        ;end-of-line delay after CRLF in terminal
  161.                 ;mode file transfer for slow BBS systems
  162.                 ;0=0 delay, 1=100 ms, 5=500 ms, 9=900 ms
  163. COLUMS:    DB    5        ;number of directory columns
  164. SETFL:    DB    YES        ;yes=user-defined SET command
  165. SCRTST:    DB    YES        ;yes=if home cursor and clear screen
  166.                 ;routine at CLRSCRN
  167.     DB    0        ;was once ACKNAK, now spare
  168. BAKFLG:    DB    NO        ;yes=make .BAK file
  169. CRCDFL:    DB    YES        ;yes=default to CRC checking
  170.                 ;no=default to Checksum checking
  171. TOGCRC:    DB    YES        ;yes=allow toggling of Checksum to CRC
  172. CVTBS:    DB    NO        ;yes=convert backspace to rub
  173. TOGLBK:    DB    YES        ;yes=allow toggling of bksp to rub
  174. ADDLF:    DB    NO        ;no=no LF after CR to send file in
  175.                 ;terminal mode (added by remote echo)
  176. TOGLF:    DB    YES        ;yes=allow toggling of LF after CR
  177. TRNLOG:    DB    NO        ;yes=allow transmission of logon
  178.                 ;write logon sequence at location LOGON
  179. SAVCCP:    DB    YES        ;yes=do not overwrite CCP
  180. LOCNXT:    DB    NO        ;yes=local cmd if EXTCHR precedes
  181.                 ;no=not local cmd if EXTCHR precedes
  182. TOGLOC:    DB    YES        ;yes=allow toggling of LOCNXTCHR
  183. LSTTST:    DB    YES        ;yes=allow toggling of printer on/off
  184.                 ;in terminal mode. Set to no if using
  185.                 ;the printer port for the modem
  186. XOFTST:    DB    NO        ;yes=allow testing of XOFF from remote
  187.                 ;while sending a file in terminal mode
  188. XONWT:    DB    NO        ;yes=wait for XON after sending CR while
  189.                 ;transmitting a file in terminal mode    
  190. TOGXOF:    DB    YES        ;yes=allow toggling of XOFF testing
  191. IGNCTL:    DB    YES        ;yes=do not send control characters
  192.                 ;above CTL-M to CRT in terminal mode
  193.                 ;no=send any incoming CTL-char to CRT
  194. EXTRA1:    DB    0        ;for future expansion
  195. EXTRA2:    DB    0        ;for future expansion
  196. BRKCHR:    DB    '@'-40H        ;^@ = Send a 300 ms. break tone
  197. NOCONN:    DB    'N'-40H        ;^N = Disconnect from phone line
  198. LOGCHR:    DB    'L'-40H        ;^L = Send logon
  199. LSTCHR:    DB    'P'-40H        ;^P = Toggle printer
  200. UNSVCH:    DB    'R'-40H        ;^R = Close input text buffer
  201. TRNCHR:    DB    'T'-40H        ;^T = Transmit file to remote
  202. SAVCHR:    DB    'Y'-40H        ;^Y = Open input text buffer
  203. EXTCHR:    DB    '^'-40H        ;^^ = Send next character
  204. ;
  205.     DS    2
  206. ;
  207. INCTL1:    CALL    XSTTIN        ;in modem status port
  208.     RET
  209.     DB    0,0,0,0,0,0    ;spares if needed
  210. ;            
  211. OTDATA:    CALL    XDATOUT        ;out modem data port
  212.     RET
  213.     DB    0,0,0,0,0,0    ;spares if needed
  214. ;
  215. INPORT:    CALL    XDATIN        ;in modem data port
  216.     RET
  217.     DB    0,0,0,0,0,0    ;spares if needed
  218. ;
  219. MASKR:    ANI MDRCVB ! RET    ;bit to test for receive ready
  220. TESTR:    CPI MDRCVR ! RET    ;value of receive bit when ready
  221. MASKS:    ANI MDSNDB ! RET    ;bit to test for send ready
  222. TESTS:    CPI MDSNDR ! RET    ;value of send bit when ready
  223. ;
  224. ;
  225.     DS    12
  226. ;
  227. ;
  228. LOGON:    DS    2        ;needed for MDM compat, not ref'd by MEX
  229. DIALV:    JMP    PDIAL        ;dial digit in A (see info at PDIAL)
  230. DISCV:    JMP    PDISC        ;disconnect the modem
  231. GOODBV:    JMP    DUMMY        ;called before exit to CP/M
  232. INMODV:    JMP    NITMOD        ;initialization. Called at cold-start
  233. NEWBDV:    JMP    PBAUD        ;set baud rate
  234. NOPARV:    DS    3        ;set modem for no-parity
  235. PARITV:    DS    3        ;set modem parity
  236. SETUPV:    JMP    SETCMD        ;SET cmd: jump to a RET if you don't write SET
  237. SPMENV:    DS    3        ;not used with MEX
  238. VERSNV:    JMP    SYSVER        ;Overlay's voice in the sign-on message
  239. BREAKV:    JMP    PBREAK        ;send a break
  240. ;
  241. ;
  242. ILPRTV:    DS    3        ;replace with MEX function 9
  243. INBUFV:    DS    3        ;replace with MEX function 10
  244. ILCMPV:    DS    3        ;replace with table lookup funct. 247
  245. INMDMV:    DS    3        ;replace with MEX function 255
  246. NXSCRV:    DS    3        ;not supported by MEX (returns w/no action)
  247. TIMERV:    DS    3        ;replace with MEX function 254
  248. ;
  249. CLREOS:    LXI    D,EOSMSG
  250.     MVI    C,PRINT
  251.     CALL    MEX
  252.     RET
  253. ;
  254. CLS:    LXI    D,CLSMSG
  255.     MVI    C,PRINT
  256.     CALL    MEX
  257.     RET
  258. ;
  259. ;------------------------------------------------------------
  260. ;
  261. ;    *** END OF FIXED FORMAT AREA ***
  262. ;
  263. ;------------------------------------------------------------
  264. ;
  265. ; MICROMODEM AND ALS CARD INITIALIZATION
  266. ;
  267. NITMOD:    
  268.     IF ALSCRD
  269.     LHLD    1        ;get WBOOT vector
  270.     LXI    D,60H        ;offset for 32 entries
  271.     DAD    D        ;BIOS "read Apple address"
  272.     SHLD    AR0+1        ;patch read vector
  273.     INX    H
  274.     INX    H
  275.     INX    H        ;BIOS "write Apple address"
  276.     SHLD    AW0+1        ;patch write vector
  277.      ENDIF
  278.  
  279. ;
  280.     IF    MM
  281.     MVI    A,03H
  282.     CALL    XCTLOUT        ;RESET MICROMODEM
  283.     MVI    A,15H        ;8 DATA BITS 1 STOP NO PARITY
  284.     CALL    XCTLOUT
  285.     RET
  286.     ENDIF    ;MM
  287. ;
  288. ; Micromodem send-break routine
  289. ;
  290. PBREAK:    CALL    XCTLIN        ;get control register
  291.     PUSH    PSW        ;save it
  292.     ORI    BRKMSK        ;set break bits
  293.     CALL    XCTLOUT        ;break line
  294.     PUSH    B
  295.     LXI    B,233        ;wait 233 msec
  296.     CALL    DELAY
  297.     POP    B
  298.     POP    PSW
  299.     CALL    XCTLOUT        ;restore control register 
  300.     RET
  301. ;
  302. ; disconnect the Micromodem (and turn off MMIIe speaker)
  303. ;
  304. PDISC:    PUSH    B
  305. ;
  306.     IF    MM2E
  307.     MVI    A,SPKROFF
  308.     CALL    XCTL3        ;SPEAKER OFF
  309.     ENDIF            ;MM2E
  310. ;
  311.     MVI    A,ONHK
  312.     CALL    XONHOOK        ;hang up
  313.     LXI    B,25        ;for 25 msec
  314.     CALL    DELAY
  315.     MVI    A,OFFHK
  316.     CALL    XOFFHK        ;pick up again
  317.     LXI    B,20        ;for 20 msec
  318.     CALL    DELAY
  319.     MVI    A,ONHK
  320.     CALL    XONHOOK        ;hang up for good
  321.     POP    B
  322.     RET
  323. ;
  324. ; wait for BC milliseconds
  325. ;
  326. DELAY:    PUSH    D
  327.     INR    B
  328. DELAY1:    LXI    D,3*RATE    ;count for 1 msec
  329. DELAY2:    DCX    D        ;..may need some tweaking
  330.     MOV    A,E
  331.     ORA    D
  332.     JNZ    DELAY2        ;delay 1 msec
  333.     DCR    C
  334.     JNZ    DELAY1        ;delay another
  335.     DCR    B
  336.     JNZ    DELAY1
  337.     POP    D        ;done, restore DE
  338.     RET
  339. ;
  340. ; exit routine
  341. ;
  342. DUMMY:    RET            ;we don't need one
  343. ;
  344. ;
  345. ;------------------------------------------------------------
  346. ;
  347. ;   MICROMODEM DIALING ROUTINES (PULSE AND TOUCH-TONE)
  348. ;
  349. ;------------------------------------------------------------
  350. ;
  351. PDIAL:    CPI    254        ;start-dial?
  352.     JZ    STDIAL
  353.     CPI    255        ;end-dial
  354.     JZ    ENDIAL
  355. ;
  356.     CPI    ','        ;SEE IF DIGIT IS ','
  357.     JZ    DIALCM        ;YES
  358.     CPI    '9'+1        ;digits are 0-9
  359.     RNC            ;too big...
  360.     SUI    '0'
  361.     RC            ;too small....
  362.     JNZ    DIALIT        ;just right...
  363.     MVI    A,10        ;convert zero to 10 pulses
  364. ;
  365. ; Pulse phone "digit" times
  366. ;
  367.     IF    NOT MM2E
  368. DIALIT:    MOV    E,A        ;save the digit
  369.     PUSH    B
  370. DIGLP:    MVI    A,ONHK
  371.     CALL    XONHOOK
  372.     LXI    B,65        ;for 65 msec
  373.     CALL    DELAY
  374.     MVI    A,OFFHK
  375.     CALL    XOFFHK        ;connect line
  376.     LXI    B,42        ;for 42 msec
  377.     CALL    DELAY
  378.     DCR    E        ;pulse again?
  379.     JNZ    DIGLP        ;yes, do it
  380.     MVI    B,3        ;300 MSEC BETWEEN DIGITS
  381.     MVI    C,TIMER
  382.     CALL    MEX
  383.     POP    B        ;no, exit
  384.     RET
  385.     ENDIF            ;MM
  386. ;
  387. ;
  388.     IF    MM2E
  389. DIALIT: ADI     30H        ;ADD 30H TO DIGIT TO KEEP SPEAKER -
  390.     PUSH    B        ;ON AND SEND TONE
  391. DIGLP:  CALL    XCTL3        ;SEND DIGIT
  392.     LXI    B,120        ;NUMBER OF MSEC FOR EACH TONE
  393.     CALL    DELAY
  394.     MVI    A,20H        ;TURN OFF TONE
  395.     CALL    XCTL3
  396.     MVI    B,1        ;100 MSEC BTWEEN DIGITS
  397.     MVI    C,TIMER
  398.     CALL    MEX
  399.     POP    B
  400.     RET
  401.     ENDIF            ;ENDIF MM2E
  402. ;
  403. ;
  404. ; THIS ROUTINE CONVERTS THE COMMA (,) TO IT'S MICROMODEM DECIMAL
  405. ;   EQUIVALENT. THE COMMA CAUSES A TWO (2) SECOND DELAY IN
  406. ;   DIALING BETWEEN ANY 2 DIGITS.
  407. ;
  408. ;
  409. DIALCM: MVI    B,20        ;DIGIT IS COMMA - SO WAIT 2 SEC.
  410.     MVI    C,TIMER
  411.     CALL    MEX
  412.     RET
  413. ;
  414. ;
  415. ; END OF SPECIAL DIALING CONVERSION ROUTINE
  416. ;
  417. ;
  418. ; Start-dial sequence: connect, wait for dial-tone
  419. ;
  420. STDIAL:    CALL    ILPRT
  421.     DB    'Wait...',0
  422.     MVI    B,25        ;wait 2.5 sec
  423.     MVI    C,TIMER
  424.     CALL    MEX
  425.     MVI    A,DTR        ;enable modem
  426.     CALL    XBDOUT
  427.     ;
  428.     IF    MM2E
  429.     MVI    A,SPKRON
  430.     CALL    XCTL3        ;TURN ON MMIIE SPEAKER
  431.     ENDIF            ;MM2E
  432.     ;
  433.     MVI    A,OFFHK
  434.     CALL    XOFFHK        ;connect phone
  435.     MVI    B,20        ;wait 2 sec
  436.     MVI    C,TIMER
  437.     CALL    MEX        ;for dial tone
  438.     ORA    A
  439.     RET
  440. ;
  441. ; End-dial sequence
  442. ;
  443. ENDIAL: MVI    E,150        ;SET WAIT TIME TO 15 SEC.
  444.     MVI    A,8DH        ;ENABLE MODEM (OFF-HOOK,ORIG.,300 BD)
  445.     CALL    XBDOUT
  446. WAITTM    EQU    $-1        ;patch with SET WAIT command
  447.     CALL    WAIT
  448.     ORA    A        ;successfully connected?
  449.     PUSH    PSW        ;save the error code
  450.     JNZ    NOTCNK        ;no, disconnect
  451.     MVI    A,DTR
  452.     CALL    XBDOUT        ;RE-ENABLE MODEM
  453.     ;
  454.     IF    MM2E
  455.     MVI    A,SPKROFF    ;MMIIE SPEAKER OFF
  456.     CALL    XCTL3
  457.     ENDIF            ;MM2E
  458.     ;
  459.     JMP    DIALXIT    
  460. NOTCNK:    CALL    PDISC        ;shut down the modem
  461. DIALXIT:POP    PSW
  462.     RET
  463. ;
  464. ; Time-out routine.  Must be called with mask in D reg.
  465. ; and number of seconds (times 10) in E reg.
  466. ;
  467. WAIT:    MVI    B,1        ;100 ms
  468.     MVI    C,TIMER    
  469.     CALL    MEX
  470.     CALL    XDATIN        ;READ DATA PORT (SET-UP CARR. DET.)
  471.     CALL    XSTTIN        ;IS CARRIER LOST SINCE LAST DATA READ?
  472.     ANI    4        ;4=NO CARRIER, 0=CARRIER
  473.     RZ            ;active low, so return on 0
  474.     MVI    C,CHEKCC    ;not yet, check for console-abort
  475.     CALL    MEX        ;abort?
  476.     MVI    A,3        ;set error code 3 if abort active
  477.     STC
  478.     RZ            ;return if aborted
  479.     DCR    E        ;nope, downcount
  480.     JNZ    WAIT
  481.     DCR    A        ;set error=2 (timed out); cy already set
  482.     RET
  483.  
  484. ;------------------------------------------------------------
  485. ;    END OF MICROMODEM DIALING ROUTINES
  486. ;------------------------------------------------------------
  487. ;
  488. ; Only 300 baud is supported for the Micromodem
  489. ;
  490. ;
  491.     IF     MM
  492. PBAUD:    RET
  493.     ENDIF    ;MM
  494. ;
  495. ;
  496. ; Control is passed here after MEX parses a SET command.
  497. ;
  498. SETCMD:    MVI    C,SBLANK    ;any arguments?
  499.     CALL    MEX
  500.     JC    SETSHO        ;if not, go print out values
  501.     LXI    D,CMDTBL    ;parse command
  502.     CALL    TSRCH        ;from table
  503.     PUSH    H        ;any address on stack
  504.     RNC            ;if we have one, execute it
  505.     POP    H        ;nope, fix stack
  506. SETERR:    LXI    D,SETEMS    ;print error
  507.     MVI    C,PRINT
  508.     CALL    MEX
  509.     RET
  510. ;
  511. SETEMS:    DB    CR,LF,BELL,'SET command error',CR,LF,'$'
  512. ;
  513. ; SET command table ... note that tables are constructed of command-
  514. ; name (terminated by high bit=1) followed by word-data-value returned
  515. ; in HL by MEX service processor LOOKUP.  Table must be terminated by
  516. ; a binary zero.
  517. ;
  518. ; Note that LOOKUP attempts to find the next item in the input stream
  519. ; in the table passed to it in HL ... if found, the table data item is
  520. ; returned in HL; if not found, LOOKUP returns carry set.
  521. ;
  522. CMDTBL:    DB    '?'+80H            ;"set ?"
  523.     DW    STHELP
  524.     DB    'BAU','D'+80H        ;"set baud"
  525.     DW    STBAUD
  526.     DB    'WAI','T'+80H        ;"set wait time"
  527.     DW    STWAIT
  528.     DB    0        ;<<=== table terminator
  529. ;
  530. ; SET <no-args>: print current statistics
  531. ;
  532. SETSHO:    CALL    CARRSH        ;show carrier present/not present
  533.     LXI    H,SHOTBL    ;get table of SHOW subroutines
  534. SETSLP:    MOV    E,M        ;get table address
  535.     INX    H
  536.     MOV    D,M
  537.     INX    H
  538.     MOV    A,D        ;end of table?
  539.     ORA    E
  540.     RZ            ;exit if so
  541.     PUSH    H        ;save table pointer
  542.     XCHG            ;adrs to HL
  543.     CALL    GOHL        ;do it
  544.     CALL    CRLF        ;print newline
  545.     MVI    C,CHEKCC    ;check for console abort
  546.     CALL    MEX
  547.     POP    H        ;it's done
  548.     JNZ    SETSLP        ;continue if no abort
  549.     RET
  550. ;
  551. GOHL:    PCHL
  552. ;
  553. ; table of SHOW subroutines
  554. ;
  555. SHOTBL:    DW    BDSHOW
  556.     DW    WTSHOW
  557.     DW    0        ;<<== table terminator
  558. ;
  559. ; SET ?  processor
  560. ;
  561. STHELP:    LXI    D,HLPMSG
  562.     MVI    C,PRINT
  563.     CALL    MEX
  564.     RET
  565. ;
  566. ; The help message
  567. ;
  568. HLPMSG:    DB    CR,LF,'SET command, MICROMODEM II/IIE version:',CR,LF
  569.     DB    CR,LF,TAB,'ONLY 300 BAUD SUPPORTED'
  570.     DB    CR,LF,TAB,'SET WAIT 0..25'
  571.     DB    CR,LF,'$'
  572. ;
  573. ; SET BAUD processor
  574. ;
  575. STBAUD:    MVI    C,BDPARS    ;function code
  576.     CALL    MEX        ;let MEX look up code
  577.     JC    SETERR        ;invalid code
  578.     CALL    PBAUD        ;no, try to set it
  579.     JC    SETERR        ;not-supported code
  580. BDSHOW:    CALL    ILPRT        ;display baud
  581.     DB    'Baud rate: ',TAB,0
  582.     LDA    MSPEED
  583.     MVI    C,PRBAUD    ;use MEX routine
  584.     CALL    MEX
  585.     RET          
  586. ;
  587. ; SET WAIT processor
  588. ;
  589. STWAIT:    MVI    C,EVALA        ;get new time from input
  590.     CALL    MEX
  591.     MOV    A,H        ;check for valid input
  592.     ORA    A
  593.     JNZ    SETERR
  594.     MOV    A,L
  595.     CPI    26
  596.     JNC    SETERR        ;25 is maximum wait
  597.     RLC            ;x 2
  598.     MOV    C,A
  599.     RLC            ;x 4
  600.     RLC            ;x 8
  601.     ADD    C        ;x 10
  602.     STA    WAITTM
  603. WTSHOW:    CALL    ILPRT
  604.     DB    'Wait time: ',TAB,0
  605.     MVI    A,0        ;clear HL
  606.     MOV    L,A
  607.     MOV    H,A
  608.     LDA    WAITTM
  609. SBLOOP: SUI    10        ;div. by 10
  610.     JC    WTDSP
  611.     INR    L
  612.     JMP    SBLOOP
  613. WTDSP:    MVI    C,DECOUT
  614.     CALL    MEX
  615.     CALL    ILPRT
  616.     DB    ' seconds',CR,LF,0
  617. ;
  618. ; Compare next input-stream item in table @DE; CY=1
  619. ; if not found, else HL=matched data item
  620. ;
  621. TSRCH:    MVI    C,LOOKUP    ;get function code
  622.     JMP    MEX        ;pass to MEX processor
  623. ;
  624. ; Print in-line message ... blows away C register
  625. ;
  626. ILPRT:    MVI    C,ILP        ;get function code
  627.     JMP    MEX        ;go do it
  628.  
  629. ;
  630. ; Sign-on message
  631. ;
  632. SYSVER:    CALL    NITMOD
  633.     LXI    D,SOMESG
  634.     MVI    C,PRINT
  635.     CALL    MEX
  636. CARRSH:    LXI    D,NOMESG        ;tell about carrier
  637.     CALL    CARRCK            ;check for it
  638.     MVI    C,PRINT
  639.     CNZ    MEX            ;print the "NO" if no carrier
  640.     LXI    D,CARMSG        ;print "carrier present"
  641.     MVI    C,PRINT
  642.     CALL    MEX
  643.     RET
  644. ;
  645. ;
  646.     IF    SFTCRD
  647. SOMESG: DB    'Apple II w/Microsoft Softcard',CR,LF
  648.     ENDIF    ;SFTCRD
  649. ;
  650. ;
  651.     IF    ALSCRD
  652. SOMESG: DB    'Apple II w/ALS CP/M 3.0 Card',CR,LF
  653.     ENDIF    ;ALSCRD
  654. ;
  655.     IF    MM2E
  656.     DB      'and Hayes Micromodem IIe',CR,LF,'$'
  657.     ENDIF   ;MM2E
  658. ;
  659.     IF NOT    MM2E
  660.     DB    'and Hayes Micromodem II',CR,LF,'$'
  661.     ENDIF    ;NOT MM2E
  662. NOMESG:    DB    'no $'
  663. CARMSG:    DB    'carrier present',CR,LF,'$'
  664. ;
  665. ; CHECK THE MICROMODEM FOR CARRIER PRESENT (NZ=NO)
  666. ;
  667. CARRCK:    CALL    XDATIN
  668.     CALL    XSTTIN
  669.     ANI    4
  670.     RET
  671. ;
  672. ; Newline on console
  673. ;
  674. CRLF:    MVI    A,CR
  675.     CALL    TYPE
  676.     MVI    A,LF        ;fall into TYPE
  677. ;
  678. ; type char in A on console
  679. ;
  680. TYPE:    PUSH    H        ;save 'em
  681.     PUSH    D
  682.     PUSH    B
  683.     MOV    E,A        ;align output character
  684.     MVI    C,CONOUT    ;print via MEX
  685.     CALL    MEX
  686.     POP    B
  687.     POP    D
  688.     POP    H
  689.     RET               
  690. ;
  691. ; strings to clear-to-end-of-screen, and clear-screen
  692. ;
  693. EOSMSG:    DB    ESC,'Y$'    ;clear to end-of-screen
  694. CLSMSG:    DB    ESC,'*$'    ;clear whole screen
  695.  
  696. ;-------------------------------------------------------
  697. ; Apple I/O 
  698. ;-------------------------------------------------------
  699.  
  700.     IF    SFTCRD
  701.  
  702. XDATOUT    STA    MODDAT ! RET
  703. XCTLOUT    STA    MODCTL ! RET
  704. XBDOUT    STA    BAUDRP ! RET
  705. XONHOOK    STA    ONHOOK ! RET
  706. XOFFHK    STA    OFFHOOK ! RET
  707.  
  708. XSTTIN    LDA    MODSTT ! RET
  709. XDATIN    LDA    MODDAT ! RET
  710. XCTLIN    LDA    MODCTL ! RET
  711. XBDIN    LDA    BAUDRP ! RET
  712. XCTL3    LDA    MODCTL3 ! RET
  713.  
  714.     ENDIF    
  715.  
  716.     IF ALSCRD
  717. ;
  718. ; ALS card routines require assembly with MAC
  719. ; (supplied with the ALS CP/M card)
  720. ; 
  721. PUT    MACRO    ADDR
  722.     PUSH    H
  723.     LXI    H,ADDR
  724.     JMP    APWRT
  725.     ENDM
  726.        
  727. XDATOUT    PUT    MODDAT
  728. XCTLOUT    PUT    MODCTL
  729. XBDOUT    PUT    BAUDRP
  730. XONHOOK    PUT    ONHOOK
  731. XOFFHK    PUT    OFFHOOK
  732. XCTL3    PUT    MODCTL3
  733.  
  734. APWRT:    PUSH    D
  735.     PUSH    B
  736. AW0:    CALL    $-$    ; patch vector here
  737.     POP    B
  738.     POP    D
  739.     POP    H
  740.     RET
  741.  
  742. GET    MACRO    ADDR
  743.     PUSH    H
  744.     LXI    H,ADDR
  745.     JMP    APRD
  746.     ENDM
  747.  
  748. XSTTIN    GET    MODSTT
  749. XDATIN    GET    MODDAT
  750. XCTLIN    GET    MODCTL
  751. XBDIN    GET    BAUDRP
  752.  
  753. APRD:    PUSH    D
  754.     PUSH    B
  755. AR0:    CALL    $-$    ; patch vector here
  756.     POP    B
  757.     POP    D
  758.     POP    H
  759.     RET
  760.  
  761.     ENDIF
  762. ;
  763. ;------------------------------------------------------------
  764. ;
  765.     END
  766.