home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / MEX / MXO-HU11.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  23KB  |  722 lines
  1. ; MXO-HU11.ASM --  U.S. Robotics S-100 overlay for MEX11.COM adapted for
  2. ; V.86/07/27       Heath/Zenith-100        
  3. ;
  4. ; This overlay follows MEX coventions and is all you need to get MEX running.
  5. ; 
  6. ; Significant quantities of ideas and code for this program have been
  7. ; drawn from M7US-2.ASM, M712US.ASM and MXO-SM13.ASM and I am greatfully
  8. ; taking this opportunity to extend credit to the people involved in
  9. ; the development of these overlays.
  10. ;
  11. ; This version will assemble directly for a Z-100 using the S-100 bus 
  12. ; auto dial/auto answer modem by US Robotics.  The port switches on the
  13. ; modem board should be set to 20h 21h as follows:
  14. ;
  15. ;    DIP SWITCH SEGMENT(S6)        SLIDE SWITCH(J6)
  16. ;       4     3    2    1
  17. ;      OFF    OFF   ON  OFF              UP
  18. ;
  19. ; You will want to look this file over carefully. There are a number of
  20. ; options that you can use to configure the program to suit your taste.
  21. ; This file places particular emphasis on using the Heath/Zenith "100"
  22. ; equipment.  Much of the information contained here is not in the main
  23. ; file.
  24. ;
  25. ; This overlay is capable of setting the baud rate and sending breaks.
  26. ; Although disconnecting the modem is not supported by use of a function to
  27. ; lower DTR. However, the control-N and DSC commands still work, as they use
  28. ; "+++" which causes the U.S.R. S-100 modem to hang up. Some do-nothing time
  29. ; wasting statements have beeen added to the INITMODEM routine to slow the
  30. ; computer down for the modem. The regular U.S.R. S-100 modem initialization
  31. ; routine will not work reliably with computer clock speeds above 4 MHz.
  32. ;
  33. ; Baud rates supported are 150, 300, 600 and 1200. Note that 150 baud has 
  34. ; been included in place of 110 baud which is not supported by the U.S.R.
  35. ; S-100 modem. (The SET command when entered without argument will with
  36. ; 150 baud selected still indicate 110 baud unless MEX.COM is patched. For
  37. ; MEX114.COM this may be done by changing the contents of address 4FF8 from
  38. ; 31H to 35H.)
  39. ;
  40. ;    TO USE: First edit this file filling in answers for your own
  41. ;        equipment.  Then assemble with ASM.COM or equivalent
  42. ;        assembler.  Then use MLOAD.COM to overlay the the results
  43. ;        of this program to the original .COM file:
  44. ;
  45. ;        MLOAD MEX11.COM=MEXHU.COM,MXO-HU11
  46. ; 
  47. ;        Refer to MEX10.INF, MEX10.DOC and updates for complete
  48. ;        instructions.
  49. ;
  50. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  51. ;
  52. ; 86/07/86 - Code added to GOODBYE to warn user if    - Bo Gedda
  53. ;         modem is still on line upon use of
  54. ;         BYE, CPM and SYSTEM commands.
  55. ;      
  56. ; 85/12/26 - Initialization changed to include reset of - Bo Gedda
  57. ;         modem (RESETST and minor code added).
  58. ;
  59. ; 85/08/03 - Dial routine changed to allow conditional    - Bo Gedda
  60. ;         assembly for Swedish pulse dialing which
  61. ;         is different for some crazy reason.
  62. ;         Set SWEPU true to allow this option, which
  63. ;         differs as follows:
  64. ;         
  65. ;        Number        International    Swedish  
  66. ;        of pulses       #           #
  67. ;        ---------------------------------------
  68. ;           1           1           0
  69. ;           2           2           1
  70. ;           3           3           2
  71. ;           4           4           3
  72. ;           5           5           4
  73. ;           6           6           5
  74. ;           7           7           6
  75. ;           8           8           7
  76. ;           9           9           8
  77. ;          10           0           9
  78. ;
  79. ; 84/11/22 - Call in INITMOD modified to follow MEX    - Bo Gedda
  80. ;         conventions. SMANAL modified to exclude
  81. ;         busy and include error code. SMDIAL
  82. ;         modified to add extra 2 second delay
  83. ;         before dialing.
  84. ;
  85. ; 84/09/09 - Initialization modified to allow other    - Bo Gedda
  86. ;         default baud rate then 300 baud
  87. ;
  88. ; 84/08/29 - First version of this file.        - Bo Gedda 
  89. ;
  90. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  91. ;
  92. ; Use the MEX "SET" command to change the baudrate when desired.  Default
  93. ; baud rate may be set to 150, 300, 600 or 1200 by modifying MSPEED below.
  94. ;
  95. ; MEX service processor stuff
  96. ;
  97. MEX    EQU    0D00H        ;address of the service processor
  98. INMDM    EQU    255        ;get char from port to A, CY=no more in 100 ms
  99. TIMER    EQU    254        ;delay 100ms * reg B
  100. TMDINP    EQU    253        ;B=# secs to wait for char, cy=no char
  101. CHEKCC    EQU    252        ;check for ^C from KBD, Z=present
  102. SNDRDY    EQU    251        ;test for modem-send ready
  103. RCVRDY    EQU    250        ;test for modem-receive ready
  104. SNDCHR    EQU    249        ;send a character to the modem (after sndrdy)
  105. RCVCHR    EQU    248        ;recv a char from modem (after rcvrdy)
  106. LOOKUP    EQU    247        ;table search: see CMDTBL comments for info
  107. PARSFN    EQU    246        ;parse filename from input stream
  108. BDPARS    EQU    245        ;parse baud-rate from input stream
  109. SBLANK    EQU    244        ;scan input stream to next non-blank
  110. EVALA    EQU    243        ;evaluate numeric from input stream
  111. LKAHED    EQU    242        ;get nxt char w/o removing from input
  112. GNC    EQU    241        ;get char from input, cy=1 if none
  113. ILP    EQU    240        ;inline print
  114. DECOUT    EQU    239        ;decimal output
  115. PRBAUD    EQU    238        ;print baud rate
  116. PRNTBL    EQU    237        ;get MEX format command table pointer
  117. PRID    EQU    236        ;print MEX ID string on console
  118.  
  119. PRINT    EQU    9        ;MEX/BDOS print-string function call
  120. ;
  121. BELL:        EQU    07H        ;bell
  122. CR:        EQU    0DH        ;carriage return
  123. ESC:        EQU    1BH        ;escape
  124. LF:        EQU    0AH        ;linefeed
  125. ;
  126. YES:        EQU    0FFH
  127. NO:        EQU    0
  128. FALSE        EQU    0    
  129. TRUE        EQU    NOT FALSE
  130. ;
  131. ; SYSTEM CONSTANTS
  132. ;
  133. TPULSE    EQU    0105H        ;TONE/PULSE FLAG IN MODEM OVERLAY
  134. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  135. DISCV    EQU    0165H        ;LOCATION OF DISCONNECT VECTOR IN OVERLAY
  136. ;
  137.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  138.     JMP    DIAL
  139. ;
  140.     ORG    DISCV        ;OVERLAY THE DISCONNECT VECTOR
  141.     JMP    DISCON
  142. ;
  143. ;
  144. ; Change the following information to match your equipment
  145. ;
  146. SWEPU        EQU    FALSE        ;SET TRUE IF SWEDISH TYPE PULSE
  147. ;                     DIALING IS REQUIRED THIS FORCES
  148. ;                     PULSE DIALLING
  149. PORT:        EQU    020H        ;SET TO MATCH MODEM SWITCHES
  150. MODCTL1:    EQU    PORT+1        ;MODEM CONTROL PORT
  151. MODDATP:    EQU    PORT        ;MODEM DATA IN PORT
  152. MODDATO:    EQU    PORT        ;MODEM DATA OUT PORT
  153. MODDCDB:    EQU    080H        ;CARRIER DETECT BIT
  154. MODDCDA:    EQU    080H        ;VALUE WHEN ACTIVE
  155. MODRCVB:    EQU    2        ;BIT TO TEST FOR RECEIVE
  156. MODRCVR:    EQU    2        ;VALUE WHEN READY
  157. MODSNDB:    EQU    1        ;BIT TO TEST FOR SEND
  158. MODSNDR:    EQU    1        ;VALUE WHEN READY
  159. ;
  160. FRMER        EQU    20H        ;FRAMING ERROR
  161. ORUNER        EQU    10H        ;OVERRUN ERROR
  162. PARER        EQU    08H        ;PARITY ERROR
  163. ;
  164.         ORG    100H
  165. ;
  166. ;
  167. ; Change the clock speed to suit your system
  168. ;
  169.         DS    3    ;(for  "JMP   START" instruction)
  170. ;
  171. PMMIMODEM:    DB    NO    ;yes=PMMI S-100 Modem            103H
  172. SMARTMODEM:    DB    YES    ;yes=HAYES Smartmodem, no=non-PMMI    104H
  173. TOUCHPULSE:    DB    'T'    ;T=touch, P=pulse (Smartmodem-only)    105H
  174. CLOCK:        DB    45    ;clock speed in MHz x10, 25.5 MHz max.    106H
  175.                 ;20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  176. MSPEED:     DB    1    ;0=150 1=300 2=450 3=600 4=710 5=1200    107H
  177.                 ;6=2400 7=4800 8=9600 9=19200 default
  178. BYTDLY:     DB    5    ;0=0 delay 1=10 ms  5=50 ms  9=90 ms    108H
  179.                 ;default time to send character in ter-
  180.                 ;minal mode file transfer for slow BBS.
  181. CRDLY:        DB    5    ;0=0 delay 1=100 ms  5=500 ms  9=900 ms 109H
  182.                 ;default time for extra wait after CRLF
  183.                 ;in terminal mode file transfer
  184. NOOFCOL:    DB    5    ;number of DIR columns shown        10AH
  185. SETUPTST:    DB    YES    ;yes=user-added Setup routine        10BH
  186. SCRNTEST:    DB    YES    ;Cursor control routine         10CH
  187. NORETRY     DB    NO    ;yes=DON'T ALLOW RETRY/QUIT OPTION      10DH
  188.                 ;no=ALLOW RETRY/QUIT AFTER 10 TIMEOUTS
  189. BAKUPBYTE:    DB    NO    ;yes=change any file same name to .BAK    10EH
  190. CRCDFLT:    DB    YES    ;yes=default to CRC checking        10FH
  191. TOGGLECRC:    DB    YES    ;yes=allow toggling of CRC to Checksum    110H
  192. CONVBKSP:    DB    NO    ;yes=convert backspace to rub        111H
  193. TOGGLEBK:    DB    YES    ;yes=allow toggling of bksp to rub    112H
  194. ADDLF:        DB    NO    ;no=no LF after CR to send file in    113H
  195.                 ;terminal mode (added by remote echo)
  196. TOGGLELF:    DB    YES    ;yes=allow toggling of LF after CR    114H
  197. TRANLOGON:    DB    NO    ;yes=allow transmission of logon    115H
  198.                 ;write logon sequence at location LOGON
  199. SAVCCP:     DB    YES    ;yes=do not overwrite CCP        116H
  200. LOCONEXTCHR:    DB    NO    ;yes=local command if EXTCHR precedes    117H
  201.                 ;no=external command if EXTCHR precedes
  202. TOGGLELOC:    DB    YES    ;yes=allow toggling of LOCONEXTCHR    118H
  203. LSTTST:     DB    YES    ;yes=printer available on printer port    119H
  204. XOFFTST:    DB    NO    ;yes=checks for XOFF from remote while    11AH
  205.                 ;sending a file in terminal mode
  206. XONWAIT:    DB    NO    ;yes=wait for XON after CR while    11BH
  207.                 ;sending a file in terminal mode
  208. TOGXOFF:    DB    YES    ;yes=allow toggling of XOFF checking    11CH
  209. IGNORCTL:    DB    YES    ;yes=CTL-chars above ^M not displayed    11DH
  210. EXTRA1:     DB    0    ;for future expansion            11EH
  211. EXTRA2:     DB    0    ;for future expansion            11FH
  212. BRKCHR:     DB    '@'-40H ;^@ = Send 300 ms. break tone        120H
  213. NOCONNCT:    DB    'N'-40H ;^N = Disconnect from the phone line    121H
  214. LOGCHR:     DB    'L'-40H ;^L = Send logon            122H
  215. LSTCHR:     DB    'P'-40H ;^P = Toggle printer            123H
  216. UNSAVE:     DB    'R'-40H ;^R = Close input text buffer        124H
  217. TRANCHR:    DB    'T'-40H ;^T = Transmit file to remote        125H
  218. SAVECHR:    DB    'Y'-40H ;^Y = Open input text buffer        126H
  219. EXTCHR:     DB    '^'-40H ;^^ = Send next character        127H
  220. ;
  221. ;
  222.         DS    2        ;                128H
  223. ;
  224. IN$MODCTL1:    IN    MODCTL1 ! RET    ;in modem control port        12AH
  225.         DS    7
  226. OUT$MODDATP:    OUT    MODDATP ! RET    ;out modem data port        134H
  227.         DS    7
  228. IN$MODDATP:    IN    MODDATP ! RET    ;in modem data port        13EH
  229.         DS    7
  230.  
  231. maskr:        ani    2
  232.         ret
  233. testr:        cpi    2
  234.         ret
  235. masks:        ani    1
  236.         ret
  237. tests:        cpi    1
  238.         ret
  239.         ds    12
  240.  
  241.         DS    2        ;                160H
  242.         DS    6        ;                162H
  243. JMP$GOODBYE:    JMP    GOODBYE     ;                168H
  244. JMP$INITMOD:    JMP    INITMOD     ;go to user written routine    16BH
  245. JMP$NEWBAUD:    JMP    NEWBAUD     ;change baudrate        16EH
  246.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    171H
  247.         RET  !    NOP  !    NOP    ;(by-passes PMMI routine)    174H
  248. JMP$SETUPR:    JMP    SETUPR        ;                177H
  249.         DS    3        ;                17AH
  250. JMP$SYSVER:    JMP    SYSVER        ;                17DH
  251. JMP$BREAK:    JMP    SENDBRK     ;                180H
  252. ;
  253. ;
  254. ; Do not change the following six lines.
  255. ;
  256. JMP$ILPRT:    DS    3        ;                183H
  257. JMP$INBUF    DS    3        ;                186H
  258. JMP$INLNCOMP:    DS    3        ;                189H
  259. JMP$INMODEM    DS    3        ;                18CH
  260. JMP$NXTSCRN:    DS    3        ;                18FH
  261. JMP$TIMER    DS    3        ;                192H
  262. ;
  263. ;
  264. ;    routine to clear to end of screen.
  265. ;
  266. CLREOS:     LXI    D,EOSMSG
  267.         MVI    C,PRINT
  268.         CALL    MEX
  269.         RET            
  270. ;
  271. CLRSCRN:    LXI    D,CLSMSG
  272.         MVI    C,PRINT
  273.         CALL    MEX
  274.         RET            
  275. ;
  276. SYSVER:     MVI    C,ILP
  277.         call    mex
  278.         DB    'Version for Heath/ZDS 100 Series Computers'
  279.         DB    CR,LF
  280.         DB    '  with the U.S. Robotics S-100 modem.'
  281. IF SWEPU
  282.         DB    CR,LF
  283.         DB    'Swedish type pulse dialing.'
  284. ENDIF
  285.         DB    CR,LF,0
  286.  
  287.         RET
  288. ;     
  289. ;.....
  290. ;
  291. ;
  292. ; The following routine sends a break "character" to the remote
  293. ; computer for 300 ms.    The "MSPEED" value is needed to decide whether
  294. ; the modem is at 150, 300, 600, or 1200 baud.    The routine must know
  295. ; this because U.S.R. set up the RTS bit of the command resgister as a
  296. ; baud rate selection bit.  Note that the "MVI A, 01FH" does not change
  297. ; any flags.
  298. ;
  299. SENDBRK:    LDA    MSPEED        ; Get speed byte
  300.         CPI    1        ; Are we at 150 baud?
  301.         MVI    A, 01FH     ; Set up for 150/600 (no flag changes)
  302.         JZ    SBRK2        ; And if we are, go do that
  303.         LDA    MSPEED        ; Get speed byte
  304.         CPI    3        ; Are we at 600 baud?
  305.         MVI    A, 01FH     ; Set up for 150/600
  306.         JZ    SBRK2
  307.         MVI    A, 03FH     ; Otherwise, set up for 300/1200
  308. SBRK2:        OUT    MODCTL1     ; Send break
  309.         MVI    B, 3        ; 300 ms delay value
  310.         MVI    C,TIMER
  311.         CALL    MEX        ; Wait that long
  312.         JMP    INITMOD1    ; Restore USRT
  313. ;.....
  314. ;
  315. ;
  316. ; The U.S.R. S-100 does not have a "quick-disconnect" feature like
  317. ; the Hayes does (by lowering DTR).  Therefore, "GOODBYE" is not
  318. ; implemented except to check if modem is connected. Control-N still
  319. ; works to hang up (see note above in introduction)
  320. ;
  321. GOODBYE:    IN    MODCTL1     ;CHECK IF CARRIER
  322.         ANI    MODDCDB
  323.         RZ
  324.         MVI    B,10        ;WAIT 1 SECOND
  325.         MVI    C,TIMER
  326.         CALL    MEX
  327.         IN    MODCTL1     ;CHECK IF STILL CARRIER  
  328.         ANI    MODDCDB
  329.         RZ
  330.         CALL    DISCFAIL
  331.         RET
  332. ;.....
  333. ;
  334. ;
  335. ; You can use this area for any special initialization or setup you may
  336. ; wish to include.  Each must stop with a RET.    This initialization
  337. ; sets up 300 baud, 8 data bits, 1 stop bit, no parity.  Due to a
  338. ; quirk in the U.S.R. S-100 (it seems to have plenty of 'em), after
  339. ; you change baud rates, you should send an "AT" followed by a
  340. ; carriage return.  Therefore, this is done after every initialization
  341. ; when there is no carrier present.
  342. ;
  343. ;
  344. ; NOTE: The U.S.R. S-100 does not operate too well at clock speeds   
  345. ;    over 4 MHz.  As we are running at that speed or higher, the
  346. ;    lines with XCHG have been inserted.  These serve as time wasting
  347. ;    routines to let the U.S.R. S-100 catch up.  This is not a
  348. ;    problem when doing character I/O, as the program checks to see
  349. ;    if the modem is ready to accept a character.
  350. ;
  351. ;
  352. INITMOD:    LDA    MSPEED        ; Get the default baude rate
  353.         CPI    0        ; Is it 150 baud?
  354.         JZ    OK150        ; If so set up for 150 baud
  355.         CPI    1        ; Is it 300 baud?
  356.         JZ    OK300        ; If so set up for 300 baud
  357.         CPI    3        ; Is it 600 baud?
  358.         JZ    OK600
  359.         CPI    5        ; Is it 1200 baud?
  360.         JZ    OK1200
  361.         MVI    C,ILP
  362.         CALL    MEX        ; Tell user if not valid
  363.         DB    '++ Incorrect default baud rate ++',CR,LF,BELL,0
  364. INITMOD1:    XRA    A        ; Zero accumulator
  365.         OUT    MODCTL1     ; Clear 8251A
  366.         XCHG            ; For fast systems
  367.         XCHG            ; For fast systems
  368.         OUT    MODCTL1     ; Twice
  369.         XCHG            ; For fast systems
  370.         XCHG            ; For fast systems
  371.         OUT    MODCTL1     ; Three times, even
  372.         XCHG            ; For fast systems
  373.         XCHG            ; For fast systems
  374.         MVI    A, 040H     ; Reset UART command
  375.         OUT    MODCTL1
  376.         XCHG            ; For fast systems
  377.         XCHG            ; For fast systems
  378. MODEBT:     MVI    A, 04FH     ; 8 bits, 1 stop, no parity
  379.         OUT    MODCTL1
  380.         XCHG            ; For fast systems
  381.         XCHG            ; For fast systems
  382. CMDBT:        MVI    A, 037H     ; On hook, Tx/Rx enable, reset errs
  383.         OUT    MODCTL1
  384.         XCHG            ; For fast systems
  385.         XCHG            ; For fast systems
  386. BDCODE:     MVI    A, 1        ; 300 baud code
  387.         STA    MSPEED
  388.         IN    MODCTL1     ; Get the current status
  389.         ANI    MODDCDB     ; See if there is a carrier
  390.         RNZ            ; If so, don't do AT stuff
  391.         MVI    B, 1        ; 100 ms
  392.         MVI    C,TIMER
  393.         CALL    MEX        ; Wait that long 
  394.         LXI    H,RESETST    ; Point to resetstring
  395.         CALL    SMSEND        ; Reset modem
  396.         MVI    B, 5        ; 500 ms
  397.         MVI    C,TIMER
  398.         CALL    MEX        ; Wait that long
  399.         LXI    H,INITST    ; Point to initstring
  400.         CALL    SMSEND        ; Initialize command status
  401.         RET
  402. ;
  403. RESETST:DB    'ATZ',CR,0        ; Reset modem command status
  404. INITST: DB    'ATS0=0S7=45E1',CR,0    ; Don't answer, wait 45 s for carrier
  405. ;
  406. ; This routine is used to set up for a new baud rate
  407. ; which on the U.S.R. can be 150, 300, 600, or 1200.
  408. ; This modem does not have a provision for the MEX   
  409. ; 110 rate and the U.S.R. 150 baud possibility is
  410. ; therefore utilized. You should not exepect 150 baud
  411. ; to work unless modems at both ends are set up for
  412. ; this same baud rate.
  413. ;
  414. ;
  415. SETUPR:   MVI    C,SBLANK    ;Any arguments?
  416.       CALL    MEX
  417.       JC    TELL        ;If not, go display baud
  418.       LXI    D,CMDTBL
  419.       MVI    C,LOOKUP
  420.       CALL    MEX        ;Parse argument
  421.       PUSH    H        ;Save any parsed argument addrs on stack
  422.       RNC            ;If we have one, return to it
  423.       POP    H        ;Oops, input not found in table
  424.       MVI    C,ILP
  425.       CALL    MEX        ;Tell user input not valid
  426.       DB    CR,LF,'Only 150, 300, 600 or 1200 allowed by SET',CR,LF,0
  427.       RET
  428. ;
  429. CMDTBL:   DB    '15','0'+80H
  430.       DW    OK150
  431.       DB    '30','0'+80H
  432.       DW    OK300
  433.       DB    '60','0'+80H
  434.       DW    OK600
  435.       DB    '120','0'+80H
  436.       DW    OK1200
  437.       DB    0
  438. ;
  439. TELL:      MVI    C,ILP
  440.       CALL    MEX        ;Print current baud rate
  441.       DB    CR,LF,'Baud rate is now: ',0
  442.       LDA    MSPEED
  443.       MVI    C,PRBAUD
  444.       CALL    MEX
  445.       RET
  446. ;
  447. ;
  448. OK150:    MVI    A,0        ;MSPEED 150
  449.     LHLD    BD150        ;Get 150 baud values in (HL)
  450.     JMP    LOADBD        ;Go load them
  451. OK300:    MVI    A,1        ;MSPEED 300
  452.     LHLD    BD300        ;Get 300 baud values in (HL)
  453.     JMP    LOADBD        ;Go load them
  454. OK600:    MVI    A,3        ;MSPEED 600
  455.     LHLD    BD600        ;Get 600 baud values in (HL)
  456.     JMP    LOADBD        ;Go load them
  457. OK1200: MVI    A,5        ;MSPEED 1200
  458.     LHLD    BD1200        ;Get 1200 baud values in (HL)
  459.     JMP    LOADBD        ;Go load them
  460. ;
  461. LOADBD:     STA    BDCODE + 1    ; Change baud rate code value
  462.         MOV    A,L        ; Get mode byte value
  463.         STA    MODEBT + 1    ; Change mode byte
  464.         MOV    A,H        ; Get cmd byte
  465.         STA    CMDBT + 1    ; Change cmd byte
  466.         JMP    INITMOD1    ; (Re)initialize modem
  467. ;
  468. NEWBAUD:  CPI    0
  469.       JZ    OK150
  470.       CPI    1
  471.       JZ    OK300
  472.       CPI    3
  473.       JZ    OK600
  474.       CPI    5
  475.       JZ    OK1200
  476.       RET
  477. ;
  478. ; Baud Rate Table
  479. ;
  480. BD150    DW    274FH        ;150 baud
  481. BD300    DW    374FH        ;300 baud
  482. BD600    DW    274EH        ;600 baud
  483. BD1200    DW    374EH        ;1200 baud
  484. ;        __--
  485. ;         \  \___ Mode Byte to select baud rate (4E or 4F)
  486. ;          \_____ Command Byte to select speed (27 or 37)
  487. ;
  488. BAUDBUF:    DB    10, 0
  489.         DS    10
  490. ;
  491. ;
  492. ;
  493. ;
  494. EOSMSG:   DB    ESC,'J',0,0,0,'$'            
  495. CLSMSG:   DB    ESC,'E',0,0,0,'$'
  496. ;
  497. ;
  498. ;
  499. ;
  500. ; This is the DIAL routine called by MEX to dial a digit. The digit
  501. ; to be dialed is passed in the A register.  Note that two special
  502. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  503. ; and 255 (end-dial sequence).    Mex will always call DIAL with 254
  504. ; in the accumulator prior to dialing a number.  Mex will also call
  505. ; dial with 255 in A as an indication that dialing is complete. Thus,
  506. ; the overlay may use these values to "block" the number, holding it
  507. ; in a buffer until it is completely assembled (in fact, that's the
  508. ; scheme employed here for the Smartmodem).
  509. ;
  510. ; After the 254-start-dial sequence, MEX will call the overlay with
  511. ; digits, one-at-a-time.  Except as noted below, MEX will make no
  512. ; assumptions about the digits, and will send each to the DIAL routine
  513. ; un-inspected (some modems, like the Smartmodem, allow special
  514. ; non-numeric characters in the  phone number, and MEX may make
  515. ; no assumptions about these).
  516. ;
  517. ; If SWEPU is set true MEX will modify numbers (0 to 9) to correct
  518. ; the number of pulses sent to the telephone switching equipment.
  519. ; Note that letters will not be modified and and should not be used
  520. ; with this special type of pulse dialing.
  521. ;
  522. ; After receiving the end-dial sequence (255) the overlay must take
  523. ; whatever end-of-dial actions are necessary *including* waiting for
  524. ; carrier at the distant end.  The overlay should monitor the keyboard
  525. ; during this wait (using the MEX keystat service call), and return
  526. ; an exit code to MEX in the A register, as follows:
  527. ;
  528. ;    0 - Carrier detected, connection established
  529. ;    1 - Far end busy (only for modems that can detect this condition)
  530. ;    2 - No answer (or timed out waiting for modem response)
  531. ;    3 - Keyboard abort (^C only: all others should be ignored)
  532. ;    4 - Error reported by modem
  533. ;    5 - No ring
  534. ;    6 - No dialtone
  535. ;
  536. ; <No other codes should be returned after an end-dial sequence>
  537. ;
  538. ; The overlay should not loop forever in the carrier-wait routine, but
  539. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  540. ; ms character wait) service call routine.
  541. ;
  542. ; The DIAL routine is free to use any of the registers, but must return
  543. ; the above code after an end-dial sequence
  544. ;
  545. ;
  546. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  547.     CPI    254        ;START DIAL?
  548.     JZ    STDIAL        ;JUMP IF SO
  549.     CPI    255        ;END DIAL?
  550.     JZ    ENDIAL        ;JUMP IF SO
  551. ;
  552. ; Not start or end sequence, must be a digit to be sent to the modem
  553. ;
  554. IF    SWEPU
  555.     CALL    CKDIG
  556. NOMOD:    MOV    M,A        ;PUT CHAR IN BUFFER
  557.     INX    H        ;ADVANCE POINTER
  558.     SHLD    DIALPT        ;STUFF PNTR
  559.     RET            ;ALL DONE
  560. CKDIG:    CPI    '9' + 1     ;0 TO 9 IS THE RANGE TO ADJUST
  561.     RNC            ;TOO LARGE
  562.     MOV    C,A        ;SAVE THE NUMBER
  563.     SUI    '0'               
  564.     MOV    A,C        ;RECOVER IT       
  565.     RC            ;TOO SMALL 
  566.     CPI    '9'        ;9 CORRESPONDS TO ZERO
  567.     JZ    ZERO
  568.     ADI    1        ;ADD ONE PULSE TO ALL FROM 0 TO 8
  569.     RET
  570. ZERO:    MVI    A,'0'
  571.     RET
  572. ENDIF
  573. ;
  574. IF NOT SWEPU
  575.     MOV    M,A        ;PUT CHAR IN BUFFER
  576.     INX    H        ;ADVANCE POINTER
  577.     SHLD    DIALPT        ;STUFF PNTR
  578.     RET            ;ALL DONE
  579. ENDIF
  580. ;
  581. ; Here on a start-dial sequence
  582. ;
  583. STDIAL: LXI    H,DIALBF    ;SET UP BUFFER POINTER
  584.     SHLD    DIALPT
  585. IF SWEPU
  586.     MVI    A,'P'        ;FORCE PULSE DIALING
  587.     STA    TPULSE
  588. ENDIF
  589.     RET
  590. ;
  591. ; Here on an end-dial sequence
  592. ;
  593. ENDIAL: MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  594.     INX    H        ;FOLLOWED BY TERMINATOR
  595.     MVI    M,0
  596.     LDA    TPULSE        ;GET OVERLAY'S TOUCH-TONE FLAG
  597.     STA    SMDIAL+3    ;PUT INTO STRING
  598.     LXI    H,SMDIAL    ;POINT TO DIALING STRING
  599.     CALL    SMSEND        ;SEND IT
  600. WAITSM: MVI    C,INMDM
  601.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  602.     JNC    WAITSM        ;LOOP UNTIL NO MORE CHARACTERS
  603. ;
  604. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  605. ; 75 SECONDS. YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  606. ; NOTE THAT THE SMARTMODEM HAS AN INTERNAL 30 SECOND TIMEOUT WHILE
  607. ; FOR A CARRIER ON THE OTHER END.  YOU CAN CHANGE BY PLAYING WITH THE
  608. ; S7 VARIABLE (I.E. SEND THE SMARTMODEM "AT S7=20" TO LOWER THE 30 SECOND
  609. ; WAIT TO 20 SECONDS).
  610. ;
  611. RESULT: MVI    C,75        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  612. SMWLP:    PUSH    B
  613.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  614.     MVI    C,TMDINP    ;DO TIMED INPUT
  615.     CALL    MEX
  616.     POP    B
  617.     JNC    SMTEST        ;JUMP IF MODEM HAD A CHAR
  618.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  619.     MVI    C,CHEKCC
  620.     CALL    MEX
  621.     POP    B
  622.     JNZ    SMNEXT        ;IF NOT, JUMP
  623.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  624.     MVI    C,SNDCHR
  625.     CALL    MEX
  626.     MVI    A,3        ;RETURN ABORT CODE
  627.     RET
  628. SMNEXT: DCR    C        ;NO
  629.     JNZ    SMWLP        ;CONTINUE
  630. ;
  631. ; 75 SECONDS WITH NO MODEM RESPONSE (OR NO CONNECTION)
  632. ;
  633. SMTIMO: MVI    A,2        ;RETURN TIMEOUT CODE
  634.     RET
  635. ;
  636. ; MODEM GAVE US A RESULT, CHECK IT
  637. ;
  638. SMTEST: ANI    7FH        ;IGNORE ANY PARITY
  639.     CALL    SMANAL        ;TEST THE RESULT
  640.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  641.     PUSH    PSW        ;SAVE IT
  642. SMTLP:    MVI    C,INMDM     ;FLUSH ANY REMAINING COMMAND LINE
  643.     CALL    MEX
  644.     JC    SMCHEK        ;JUMP IF NO INPUT
  645.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  646.     JNZ    SMTLP        ;EAT ANY IN-BETWEEN
  647. SMCHEK: POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  648.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  649.     RET
  650. ;
  651. SMANAL: MVI    B,0        ;PREP CONNECT CODE
  652.     CPI    'C'        ;"CONNECT"?
  653.     RZ
  654.  
  655.     MVI    B,2        ;PREP NO CONNECT MSG B=2
  656.     CPI    'N'        ;N=NO CONNECT
  657.     RZ
  658.  
  659.     MVI    B,4        ;PREP ERROR MSG B=4
  660.     CPI    'E'        ;E=ERROR
  661.     RZ
  662.  
  663.     STC            ;UNKNOWN...
  664.     RET
  665. ;
  666. ; FOLLOWING ROUTINE DISCONNECTS THE MODEM USING SMARTMODEM
  667. ; CODES. ALL REGISTERS ARE AVAILABLE FOR THIS FUNCTION.
  668. ; RESULT IS RETURNED TO USER.  
  669. ;
  670. ;
  671. DISCON: MVI    B,10
  672.     MVI    C,TIMER     ;WAIT 1 SECONDS
  673.     CALL    MEX
  674.     LXI    H,SMATN     ;SEND '+++'
  675.     CALL    SMSEND
  676.     MVI    B,30        ;WAIT 3 MORE SECONDS
  677.     MVI    C,TIMER
  678.     CALL    MEX
  679.     IN    MODCTL1     ;CHECK IF CARRIER
  680.     ANI    MODDCDB
  681.     JZ    DISCOK
  682.     MVI    B,30        ;WAIT ANOTHER 3 SECONDS
  683.     MVI    C,TIMER
  684.     CALL    MEX
  685.     IN    MODCTL1     ;CHECK IF STILL CARRIER  
  686.     ANI    MODDCDB
  687.     JNZ    DISCFAIL    ;IF STILL CARRIER TELL USER
  688. DISCOK: MVI    C,ILP
  689.     CALL    MEX
  690.     DB    CR,LF,'++DISCONNECTED++',CR,LF,0
  691.     RET
  692. DISCFAIL:
  693.     MVI    C,ILP
  694.     CALL    MEX
  695.     DB    CR,LF,'+++ WARNING !!!   NOT DISCONNECTED +++',CR,LF,0
  696.     RET
  697.  
  698. ;
  699. SMATN:    DB    '+++',0
  700. ;
  701. ; SMARTMODEM UTILITY ROUTINE: SEND STRING TO MODEM
  702. ;
  703. SMSEND: MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  704.     CALL    MEX
  705.     JNZ    SMSEND
  706.     MOV    A,M        ;FETCH NEXT CHARACTER
  707.     INX    H
  708.     ORA    A        ;END?
  709.     RZ            ;DONE IF SO
  710.     MOV    B,A        ;NO, POSITION FOR SENDING
  711.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  712.     CALL    MEX
  713.     JMP    SMSEND
  714. ;
  715. ; DATA AREA
  716. ;
  717. SMDIAL: DB    'ATDT, '
  718. DIALBF: DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  719. DIALPT: DS    2        ;DIAL POSITION POINTER
  720. ;
  721.     END
  722.