home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / IMP / I2VG-2.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  13KB  |  449 lines
  1.  
  2. ; I2VG-2.ASM - Vector Graphics 3/4 overlay for IMP - 06/01/87
  3. ;
  4. ;     Uses 8251 I/O and 8253 baudrate generator (Vector 4 only)
  5. ;
  6. ;
  7. ; You will want to look this file over carefully. There are a number of
  8. ; options that you can use to configure the program to suit your taste.
  9. ; This adpats the Vector Graphics 3 or 4 to the IMP modem program.
  10. ;
  11. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  12. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  13. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  14. ; (The ESC will automatically be typed with no CTL-character present.)
  15. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
  16. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  17. ; looking at the function key table, typing CTL-Z in command mode, etc.
  18. ;
  19. ; Use the "SET" command to change the baudrate while program is running.
  20. ; Use INITBAUD to set the baudrate when the program is first called up.
  21. ;
  22. ;    TO USE: First edit this file filling in answers for your own
  23. ;        equipment.  Then assemble with ASM.COM or equivalent
  24. ;        assembler.  Then use MLOAD to merge into the main file:
  25. ;
  26. ;        MLOAD IMP.COM=IMP.COM,I2VG-x.HEX
  27. ;
  28. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  29. ;
  30. ; 06/01/87  Improved the GOODBYE routine, added BREAK routine, needs
  31. ;        IMP245 to use it.        - Irv Hoff
  32. ;
  33. ; 02/11/86  Written to work with IMP    - Irv Hoff
  34. ;
  35. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  36. ;
  37. ;
  38. YES    EQU    0FFH
  39. NO    EQU    0
  40. ;
  41. ;
  42. VECTOR3    EQU    NO
  43. VECTOR4    EQU    YES
  44. ;
  45. ;
  46. PORT    EQU    04H
  47. MDDATP    EQU    PORT    ; Modem data port
  48. MDCTL1    EQU    PORT+1    ; Modem control port
  49. CTCCMD    EQU    13H    ; 8253 Timer control/status port
  50. CTC1    EQU    11H    ; Timer (1) port 011H
  51.  
  52. MDRCV    EQU    02H    ; Modem receive ready mask (bit 2)
  53. MDSND    EQU    01H    ; Modem send ready bit mask (bit 1)
  54. MDTXE    EQU    05H    ; Modem send buffer empty, holding buffer empty
  55. ;
  56. ;
  57. MDMODE    EQU    82H    ; Insures 8251 is out of mode with DTR high
  58. MDRSET    EQU    42H    ; Resets USART for additional commands
  59. MDSET0    EQU    4FH    ; 1 stop bit, no parity, 8 bits, x64
  60. MDSET1    EQU    4EH    ; 1 stop bit, no parity, 8 bits, x16
  61. MDSET2    EQU    4CH    ; 2 stop bits, no parity, 8 bits, x16
  62. MDCOM    EQU    37H    ; Reset RTS, error flags, RCV, DTR, TX ready
  63. ;
  64. ;
  65. ;-----------------------------------------------------------------------
  66. ;
  67. ESC    EQU    '['-40H    ; ^[ = Escape
  68. BELL    EQU    'G'-40H    ; ^G = Bell character
  69. LF    EQU    'J'-40H    ; ^J = Linefeed
  70. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  71. CR    EQU    'M'-40H    ; ^M = Carriage return
  72. CLEARSC    EQU    'Z'-40H    ; ^Z = Clears screen, command mode only
  73. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  74. ;
  75. ;
  76. ;-----------------------------------------------------------------------
  77. ;
  78. ;
  79.     ORG    0100H
  80. ;
  81. ;
  82.     DS    3        ; Skip the data area below
  83. ;
  84. ;
  85. ; These routines and equates are at the beginning of the program so
  86. ; they can be patched by a monitor or overlay file without re-assembling
  87. ; the program.
  88. ;
  89. MSPEED:     DB    5    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  90.             ; 6=2400 7=4800 8=9600 9=19200 default
  91. HS2400:     DB    NO    ; Yes=2400 bps highest speed            104H
  92. HS1200:     DB    YES    ; Yes=1200 bps highest speed            105H
  93. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  94. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  95. RESVD1:     DB    NO    ; Reserved for special modems            108H
  96. RESVD2:     DB    NO    ; Reserved for special modems            109H
  97. ;
  98. ;
  99. CLEAR:     DB    04H    ; Clear screen character (ESC not needed)    10AH
  100. CLOCK:     DB    51    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  101.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  102. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  103.             ;   default time to send character in ter-
  104.             ;   minal mode file transfer for slow BBS
  105. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  106.             ;   default time for extra wait after CRLF
  107.             ;   in terminal mode file transfer
  108. NOFCOL:     DB    4    ; Number of directory columns shown        10EH
  109. TCHPUL:     DB    'T'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  110. ;.....
  111. ;
  112. ;
  113. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  114.             ;   mode (normally added by remote echo)
  115. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  116. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  117. IGNRCTL: DB    YES    ; Yes=CTL-chars above ^M not displayed        113H
  118. ;.....
  119. ;
  120. ;
  121. EXTCHR:     DB    '['-40H    ; "ESC" preceeds local control character    114H
  122. EXITCHR: DB    'E'    ; Exit character  ("ESC E" to ret to COMMAND)    115H
  123. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  124. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  125. LOGCHR:     DB    'L'    ; Send logon                    118H
  126. LSTCHR:     DB    'P'    ; Toggle printer                119H
  127. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  128. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  129. CLEARS:     DB    'Z'    ; Clears screen, terminal mode            11CH
  130. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  131. NODTR:     DB    NO    ; YES if no DTR and need ATH0 to disconnect    11EH
  132. ;.....
  133. ;
  134. ;
  135. ; Handles in/out ports for data and status
  136. ;
  137. I$MDCTL1: IN    MDCTL1        ;                    11FH
  138.       RET            ; IN modem control port         121H
  139.       DB    0,0,0,0,0,0,0    ; Spares if needed            122H
  140. ;
  141. I$MDTXE:  IN    MDCTL1        ; (Needed for SIO or DART register 1    129H
  142.       RET            ;                    12BH
  143.       DB    0,0,0,0,0,0,0    ;                    12CH
  144. ;
  145. I$MDDATP: MVI    A,37H        ;                    133H
  146.       OUT    MDCTL1        ;                    135H
  147.       IN    MDDATP        ;                    137H
  148.       RET            ;                    139H
  149.       DB    0,0,0        ; Spares if needed            13AH
  150. ;
  151. O$MDDATP: OUT    MDDATP        ;                    13DH
  152.       RET            ; OUT modem data port            13FH
  153.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  154. ;.....
  155. ;
  156. ;
  157. A$MDRCV:  ANI    MDRCV        ;                    147H
  158.       RET            ;                    149H
  159. ;
  160. C$MDRCV:  CPI    MDRCV        ;                    14AH
  161.       RET            ;                    14CH
  162. ;
  163. A$MDSND:  ANI    MDSND        ;                    14DH
  164.       RET            ;                    14FH
  165. ;
  166. C$MDSND:  CPI    MDSND        ;                    150H
  167.       RET            ;                    152H
  168. ;
  169. A$MDTXE:  ANI    MDTXE        ;                    153H
  170.       RET            ;                    155H
  171. ;
  172. C$MDTXE:  CPI    MDTXE        ;                    156H
  173.       RET            ;                    158H
  174. ;.....
  175. ;
  176. ;
  177. ; Special exit vector, used by some computers to reset interrupt vectors
  178. ;
  179. J$EXITVEC:RET            ;                    159H
  180.       DB    0,0        ;                    15AH
  181. ;.....
  182. ;
  183. ;
  184. ; Jump vectors needed by each overlay
  185. ;
  186. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  187. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  188. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  189. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  190. ;.....
  191. ;
  192. ;
  193. ; "AT" command strings, can be replaced in individual overlay if needed
  194. ;
  195. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  196. J$STRNG1: DS    3        ; 2400 bps "AT" string            16BH
  197. ;
  198. ;
  199. ; Next fourteen lines should not be changed by user overlay as these go
  200. ; to specific locations in the main program, not in the overlay.
  201. ;
  202. ;
  203. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  204. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  205. J$DIAL:      DS    3        ; Start of dialing routine        174H
  206. J$DSCONT: DS    3        ; Terminates modem use            177H
  207. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  208. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  209. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  210. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  211. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  212. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  213. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  214. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  215. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  216. J$BREAK:  JMP    SENDBRK        ; Break routine             195H
  217. J$NEW2:      DB    0,0,0        ; For future needs            198H
  218. ;.....
  219. ;
  220. ;
  221. ; For 2400 bps auto-stepdown units
  222. ;
  223. MANUAL:      DB    0        ; For manual selection flag        19BH
  224. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  225. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  226. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  227. ;.....
  228. ;
  229. ;
  230. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  231. ;
  232. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  233. ;
  234.        IF    VECTOR4
  235.       DB    'Version for Vector 4 '    ;                1AAH
  236.        ENDIF
  237. ;
  238.        IF    NOT VECTOR4
  239.       DB    'Version for Vector 3 '    ;                1AAH
  240.        ENDIF
  241. ;
  242.       DB    CR,LF,0
  243.       RET
  244. ;.....
  245. ;
  246. ;
  247. ;-----------------------------------------------------------------------
  248. ;
  249. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  250. ;     end of your last routine should terminate by 0400H (601 bytes
  251. ;     available after start of SYSVER).
  252. ;
  253. ;
  254. ;-----------------------------------------------------------------------
  255. ;
  256. ; You can put in a message at this location which can be called up with
  257. ; (special character-L).  You can put in several lines.  End with a 0.
  258. ;
  259. LOGON:    DB    'This is a North Star Advantage computer...',CR,LF,0
  260. ;
  261. ;
  262. ;-----------------------------------------------------------------------
  263. ;
  264. ; This routine sets a 300 ms break tone
  265. ;
  266. SENDBRK:
  267.     MVI    A,3FH        ; DTR normal, send break tone
  268.     JMP    GOODBYE+2
  269. ;.....
  270. ;
  271. ;
  272. ; This routine sets DTR low for 300 ms to disonnect the phone
  273. ;
  274. GOODBYE:
  275.     MVI    A,3DH        ; Send break, turn off DTR
  276.     OUT    MDCTL1        ; Send to status port
  277.     MVI    B,3        ; Delay 300 ms to hang up phone
  278.     CALL    J$TIMER
  279.     MVI    A,37H        ; Normal send/receive with DTR
  280.     OUT    MDCTL1        ; Send to status port
  281.     RET
  282. ;.....
  283. ;
  284. ;
  285. ; Complete initialization of 8251 - sets 8251 to 8 bits, DTR, RCV and
  286. ; TX ready
  287. ;
  288.      IF    VECTOR3
  289. INITMOD:
  290.     LDA    MSPEED        ; Get the selected value
  291.     CPI    1        ; 300 bps
  292.     JZ    OK300
  293.     CPI    5        ; 1200 bps
  294.     JZ    OK1200
  295.     JMP    STUPR1        ; Else ask what is wanted
  296. ;.....
  297. ;
  298. ;
  299. ;
  300. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  301.     JNC    STUPR2
  302. ;
  303. STUPR1:    CALL    J$ILPRT
  304.     DB    'Input Baud Rate (300, 1200): ',0
  305.     LXI    D,BAUDBUF    ; Point to new input buffer
  306.     CALL    J$INBUF
  307.     CALL    J$CRLF
  308.     LXI    D,BAUDBUF+2
  309. ;
  310. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  311.     DB    '300',0
  312.     JNC    OK300        ; Go if got match
  313.     CALL    J$INLNCP
  314.     DB    '1200',0
  315.     JNC    OK1200
  316.     CALL    J$ILPRT        ; All matches failed, tell operator
  317.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  318.     JMP    STUPR1        ; Try again
  319. ;
  320. OK300:    MVI    A,1        ; MSPEED 300 baud value
  321.     MVI    B,MDSET0    ; Divide by 64 for 300 baud
  322.     JMP    LOADBD        ; Go set the baudrate
  323. ;
  324. OK1200:    MVI    A,5
  325.     MVI    B,MDSET1    ; Divide by 16 for 1200 bps
  326.     JMP    LOADBD        ; Go set the baudrate
  327. ;
  328. OK2400:    JMP    OK1200        ; (Does not support 1200 bps)
  329. ;
  330. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  331.     MVI    A,MDMODE    ; Insure 8251 is out of mode
  332.     OUT    MDCTL1
  333.     XTHL            ; Small delay to complete command
  334.     XTHL
  335.     MVI    A,MDRSET    ; Reset the 8251A for new command
  336.     OUT    MDCTL1
  337.     XTHL            ; Small delay to complete command
  338.     XTHL
  339.     MOV    A,B        ; Set speed
  340.     OUT    MDCTL1
  341.     XTHL            ; Small delay to complete command
  342.     XTHL
  343.     MVI    A,MDCOM        ; Error reset, RCV, DTR, TX ready
  344.     OUT    MDCTL1
  345.     XTHL            ; Small delay to complete command
  346.     XTHL
  347.     RET
  348.      ENDIF            ; VECTOR3
  349. ;.....
  350. ;
  351. ;
  352.      IF    VECTOR4
  353. INITMOD:
  354.     MVI    A,MDMODE    ; Insure 8251 is out of mode
  355.     OUT    MDCTL1
  356.     XTHL            ; Small delay to complete command
  357.     XTHL
  358.     MVI    A,MDRSET
  359.     OUT    MDCTL1
  360.     XCHG            ; Waste a bit of time
  361.     MVI    A,MDSET1    ; Mode is asynch, 16X, 1 stop bit,
  362.     OUT    MDCTL1        ;   ...8 data bits, no parity
  363.     XCHG            ; Waste a bit of time
  364.     LDA    MSPEED        ; Get the selected value
  365.     CPI    1        ; 300 bps
  366.     JZ    OK300
  367.     CPI    5        ; 1200 bps
  368.     JZ    OK1200
  369.     CPI    6        ; 2400 bps
  370.     JZ    OK2400
  371.     CPI    8        ; 9600 bps
  372.     JZ    OK9600
  373.     JMP    STUPR1        ; Else ask what is wanted
  374.  
  375. ;.....
  376. ;
  377. ;
  378. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  379.     JNC    STUPR2
  380. ;
  381. STUPR1:    CALL    J$ILPRT
  382.     DB    'Input Baud Rate (300, 1200, 2400, 9600): ',0
  383.     LXI    D,BAUDBUF    ; Point to new input buffer
  384.     CALL    J$INBUF
  385.     CALL    J$CRLF
  386.     LXI    D,BAUDBUF+2
  387. ;
  388. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  389.     DB    '300',0
  390.     JNC    OK300        ; Go if got match
  391.     CALL    J$INLNCP
  392.     DB    '1200',0
  393.     JNC    OK1200
  394.     CALL    J$INLNCP
  395.     DB    '2400',0
  396.     JNC    OK2400
  397.     CALL    J$INLNCP
  398.     DB    '9600',0
  399.     JNC    OK9600
  400.     CALL    J$ILPRT        ; All matches failed, tell operator
  401.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  402.     JMP    STUPR1        ; Try again
  403. ;
  404. OK300:    MVI    A,1        ; MSPEED 300 baud value
  405.     LXI    H,BD300        ; Get 300 baud parameters in 'HL'
  406.     JMP    LOADBD        ; Go load them
  407. ;
  408. OK1200:    MVI    A,5
  409.     LXI    H,BD1200
  410.     JMP    LOADBD
  411. ;
  412. OK2400:    XRA    A
  413.     STA    MANUAL        ; Reset to maximum auto-speed
  414.     MVI    A,6
  415.     LXI    H,BD2400
  416.     JMP    LOADBD
  417. ;
  418. OK9600:    MVI    A,8
  419.     LXI    H,BD9600
  420. ;
  421. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  422.     MVI    A,76H        ; Select Timer (1)
  423.     OUT    CTCCMD
  424.     MOV    A,L        ; Get least significant baudrate byte
  425.     OUT    CTC1
  426.     MOV    A,H        ; Get most significant baudrate byte
  427.     OUT    CTC1
  428.     RET
  429. ;.....
  430. ;
  431. ;
  432. ; Table of baudrate parameters
  433. ;
  434. BD300    EQU    01A1H        ; 300 bps
  435. BD1200    EQU    0068H        ; 1200 bps
  436. BD2400    EQU    0034H        ; 2400 bsp
  437. BD9600    EQU    000DH        ; 9600 bps
  438.      ENDIF            ; VECTOR4
  439. ;
  440. BAUDBUF:DB    10,0,0,0,0,0
  441.     DB    0,0,0,0,0,0
  442. ;
  443. ;                   end
  444. ;----------------------------------------------------------------------
  445. ;
  446. ; NOTE: Must terminate by 0400H
  447. ;
  448.     END
  449.