home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / IMP / I2SV-2.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  11KB  |  373 lines
  1.  
  2. ; I2SVI-1.ASM - Renamed and remodeled for the SVI-328  06/01/87
  3. ;
  4. ;        8250 with built-in baudrate generator
  5. ;
  6. ; You will want to look this file over carefully. There are a number of
  7. ; options that you can use to configure the program to suit your taste.
  8. ; This file adapts the Heath/Zenith 89/90 series computers to IMP.COM.
  9. ;
  10. ; Edit this file for your preferences then follow the "TO USE:" example
  11. ; shown below.
  12. ;
  13. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  14. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  15. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  16. ; (The ESC will automatically be typed with no CTL-character present.)
  17. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
  18. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  19. ; looking at the function key table, typing CTL-Z in command mode, etc.
  20. ;
  21. ; Use the "SET" command to change the baudrate when desired.  The value
  22. ; at MSPEED controls the baudrate when the program is first called up.
  23. ;
  24. ;    TO USE: First edit this file filling in answers for your own
  25. ;        equipment.  Then assemble with ASM.COM or equivalent
  26. ;        assembler.  Then use MLOAD to merge into the main file:
  27. ;
  28. ;        MLOAD IMP.COM=IMP.COM,I2SVI-x.HEX
  29. ;
  30. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  31. ;
  32. ; 06/01/87  Improved the GOODBYE routine, added BREAK routine, needs
  33. ;        IMP245 to use it.            - Irv Hoff
  34. ; 07/17/85 - Written to work with IMP        - Irv Hoff
  35. ;
  36. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  37. ;
  38. ;
  39. YES    EQU    0FFH
  40. NO    EQU    0
  41. ;
  42. ;
  43. ; Values shown are for a 8250
  44. ;
  45. PORT    EQU    028H    ; Your base port (data or status)
  46. MDCTL1    EQU    PORT+5    ; Modem control port
  47. MDDATP    EQU    PORT    ; Modem data port
  48. MDRCV    EQU    01H    ; Modem receive ready
  49. MDSND    EQU    20H    ; Modem send ready bit
  50. MDTXE    EQU    60H    ; Modem send buffer empty, holding buffer empty
  51. ;
  52. ;
  53. ;-----------------------------------------------------------------------
  54. ;
  55. ESC    EQU    '['-40H    ; ^[ = Escape
  56. BELL    EQU    'G'-40H    ; ^G = Bell character
  57. LF    EQU    'J'-40H    ; ^J = Linefeed
  58. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  59. CR    EQU    'M'-40H    ; ^M = Carriage return
  60. CLEARSC    EQU    'L'-40H    ; ^L = Clears screen, command mode only
  61. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  62. ;
  63. ;
  64. ;-----------------------------------------------------------------------
  65. ;
  66. ;
  67.     ORG    0100H
  68. ;
  69. ;
  70.     DS    3        ; Skip the data area below
  71. ;
  72. ;
  73. ; These routines and equates are at the beginning of the program so
  74. ; they can be patched by a monitor or overlay file without re-assembling
  75. ; the program.
  76. ;
  77. MSPEED:     DB    1    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  78.             ; 6=2400 7=4800 8=9600 9=19200 default
  79. HS2400:     DB    YES    ; Yes=2400 bps highest speed            104H
  80. HS1200:     DB    NO    ; Yes=1200 bps highest speed            105H
  81. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  82. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  83. RESVD1:     DB    NO    ; Reserved for special modems            108H
  84. RESVD2:     DB    NO    ; Reserved for special modems            109H
  85. ;
  86. ;
  87. CLEAR:     DB    'E'    ; Clear screen character (ESC not needed)    10AH
  88. CLOCK:     DB    37    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  89.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  90. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  91.             ;   default time to send character in ter-
  92.             ;   minal mode file transfer for slow BBS
  93. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  94.             ;   default time for extra wait after CRLF
  95.             ;   in terminal mode file transfer
  96. NOFCOL:    DB    2    ; Number of directory columns shown        10EH
  97. TCHPUL:     DB    'P'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  98. ;.....
  99. ;
  100. ;
  101. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  102.             ;   mode (normally added by remote echo)
  103. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  104. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  105. IGNRCTL: DB    YES    ; Yes=CTL-chars above ^M not displayed        113H
  106. ;.....
  107. ;
  108. ;
  109. EXTCHR:     DB    '['-40H    ; ESC = preceeds local control character    114H
  110. EXITCHR: DB    'E'    ; Exit character                115H
  111. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  112. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  113. LOGCHR:     DB    'L'    ; Send logon                    118H
  114. LSTCHR:     DB    'P'    ; Toggle printer                119H
  115. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  116. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  117. CLEARS:     DB    'Z'    ; Clears screen, terminal mode            11CH
  118. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  119. NODTR:     DB    NO    ; YES if no DTR and need ATH0 to disconnect    11EH
  120. ;.....
  121. ;
  122. ;
  123. ; Handles in/out ports for data and status
  124. ;
  125. I$MDCTL1: IN    MDCTL1        ; Modem control port            11FH
  126.       RET            ;                    121H
  127.       DB    0,0,0,0,0,0,0    ; Spares if needed            122H
  128. ;
  129. I$MDTXE:  IN    MDCTL1        ;                    129H
  130.       RET            ;                    12BH
  131.       DB    0,0,0,0,0,0,0    ;                    12CH
  132. ;
  133. I$MDDATP: IN    MDDATP        ;                    133H
  134.       RET            ;                    135H
  135.       DB    0,0,0,0,0,0,0    ;                    136H
  136. ;
  137. O$MDDATP: OUT    MDDATP        ;                    13DH
  138.       RET            ;                    13FH
  139.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  140. ;.....
  141. ;
  142. ;
  143. A$MDRCV:  ANI    MDRCV        ;                    147H
  144.       RET            ;                    149H
  145. ;
  146. C$MDRCV:  CPI    MDRCV        ;                    14AH
  147.       RET            ;                    14CH
  148. ;
  149. A$MDSND:  ANI    MDSND        ;                    14DH
  150.       RET            ;                    14FH
  151. ;
  152. C$MDSND:  CPI    MDSND        ;                    150H
  153.       RET            ;                    152H
  154. ;
  155. A$MDTXE:  ANI    MDTXE        ;                    153H
  156.       RET            ;                    155H
  157. ;
  158. C$MDTXE:  CPI    MDTXE        ;                    156H
  159.       RET            ;                    158H
  160. ;.....
  161. ;
  162. ;
  163. ; Special exit vector, used by some computers to reset interrupt vectors
  164. ;
  165. J$EXITVEC:RET            ;                    159H
  166.       DB    0,0        ;                    15AH
  167. ;.....
  168. ;
  169. ;
  170. ; Jump vectors needed by each overlay
  171. ;
  172. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  173. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  174. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  175. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  176. ;.....
  177. ;
  178. ;
  179. ; "AT" command strings, can be replaced in individual overlay if needed
  180. ;
  181. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  182. J$STRNG1: DS    3        ; 2400 bps "AT" string            16B:IMP
  183. ;
  184. ;
  185. ; Next fourteen lines should not be changed by user overlay as these go
  186. ; to specific locations in the main program, not in the overlay.
  187. ;
  188. ;
  189. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  190. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  191. J$DIAL:      DS    3        ; Start of dialing routine        174H
  192. J$DSCONT: DS    3        ; Terminates modem use            177H
  193. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  194. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  195. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  196. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  197. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  198. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  199. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  200. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  201. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  202. J$BREAK:  JMP    SENDBRK        ; Break routine             195H
  203. J$NEW2:      DB    0,0,0        ; For future needs            198H
  204. ;.....
  205. ;
  206. ;
  207. ; For 2400 bps auto-stepdown units
  208. ;
  209. MANUAL:      DB    0        ; For manual selection flag        19BH
  210. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  211. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  212. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  213. ;.....
  214. ;
  215. ;
  216. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  217. ;
  218. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  219.       DB    'Version for SVI-328 with RS-232 card, ' ;        1AAH
  220.       DB    'and ext. modem port 028H',CR,LF,0
  221.       RET
  222. ;.....
  223. ;
  224. ;
  225. ;-----------------------------------------------------------------------
  226. ;
  227. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  228. ;     end of your last routine should terminate by 0400H (601 bytes
  229. ;     available after start of SYSVER).
  230. ;
  231. ;-----------------------------------------------------------------------
  232. ;
  233. ; You can put in a message at this location which can be called up with
  234. ; (special character-L).  You can put in several lines.  End with a 0.
  235. ;
  236. LOGON:    DB    'Hello from an SVI-328 user',CR,0
  237. ;
  238. ;-----------------------------------------------------------------------
  239. ;
  240. ; This routine sets a 300 ms break tone
  241. ;
  242. SENDBRK:
  243.     JMP    GOODBYE1
  244. ;.....
  245. ;
  246. ;
  247. ; This routine sets DTR low for 300 ms to disconnect the phone
  248. ;
  249. GOODBYE:
  250.     XRA    A
  251.     OUT    PORT+4        ; Set DTR and RTS low
  252. ;
  253. GOODBYE1:
  254.     MVI    A,40H        ; Set break tone
  255.     OUT    PORT+3
  256.     MVI    B,3        ; Wait 300 ms
  257.     CALL    J$TIMER
  258.     MVI    A,03H        ; Reset to normal 8 bits
  259.     OUT    PORT+3
  260.     MVI    A,01H
  261.     OUT    PORT+4        ; Reset DTR high
  262.     RET
  263. ;.....
  264. ;
  265. ;
  266. INITMOD:
  267.     LDA    MSPEED        ; Get the selected value
  268.     CPI    1        ; 300 bps
  269.     JZ    OK300
  270.     CPI    5        ; 1200 bps
  271.     JZ    OK1200
  272.     CPI    6        ; 2400 bps
  273.     JZ    OK2400
  274.     CPI    8        ; 9600 bps
  275.     JZ    OK9600
  276.     JMP    STUPR1        ; Else ask what is wanted
  277. ;
  278. INITMOD1:
  279.     DI            ; Turn off interrupts for initialization
  280.     XRA    A
  281.     OUT    PORT+1        ; Interrupt enable register
  282.     MVI    A,80H        ; Insure out of mode to set baud rate
  283.     OUT    PORT+3        ; Line control register
  284.     OUT    PORT+3
  285. ;
  286. INITMOD2:
  287.     MVI    A,08AH        ; Default 'LSP' speed for 300 bps
  288.     OUT    PORT        ; Register for 'LSP' speed if enabled
  289. ;
  290. INITMOD3:
  291.     MVI    A,02H        ; Default 'MSP' speed for 300 bps
  292.     OUT    PORT+1        ; Register for 'MSP' speed if enabled
  293.     MVI    A,03H        ; 8-level, 1 stop bit, no parity
  294.     OUT    PORT+3        ; Line control register (03=1, 07=2)
  295.     MVI    A,01H        ; Set 'DTR' nromal
  296.     OUT    PORT+4        ; Modem control register
  297.     EI            ; Restore interrupts to normal
  298.     RET
  299. ;.....
  300. ;
  301. ;
  302. ; The following routine changes the baud rate for the SVI-328 with the SET
  303. ; command.
  304. ;
  305. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  306.     JNC    STUPR2
  307. ;
  308. STUPR1:    CALL    J$ILPRT
  309.     DB    'Input Baud Rate (300, 1200, 2400, 9600): ',0
  310.     LXI    D,BAUDBUF    ; Point to new input buffer
  311.     CALL    J$INBUF
  312.     CALL    J$CRLF
  313.     LXI    D,BAUDBUF+2
  314. ;
  315. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  316.     DB    '300',0
  317.     JNC    OK300        ; Go if got match
  318.     CALL    J$INLNCP
  319.     DB    '1200',0
  320.     JNC    OK1200
  321.     CALL    J$INLNCP
  322.     DB    '2400',0
  323.     JNC    OK2400
  324.     CALL    J$INLNCP
  325.     DB    '9600',0
  326.     JNC    OK9600
  327.     CALL    J$ILPRT        ; All matches failed, tell operator
  328.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  329.     JMP    STUPR1        ; Try again
  330. ;
  331. OK300:    MVI    A,1        ; MSPEED 300 baud value
  332.     LXI    H,BD300        ; Get 300 baud parameters in HL
  333.     JMP    LOADBD        ; Go load them
  334. ;
  335. OK1200:    MVI    A,5
  336.     LXI    H,BD1200
  337.     JMP    LOADBD
  338. ;
  339. OK2400:    XRA    A
  340.     STA    MANUAL
  341.     MVI    A,6
  342.     LXI    H,BD2400
  343.     JMP    LOADBD
  344. ;
  345. OK9600:    MVI    A,8
  346.     LXI    H,BD9600
  347. ;
  348. LOADBD:    STA    MSPEED        ; Store speed to show transfer time
  349.     MOV    A,L        ; Get least significant baud rate byte
  350.     STA    INITMOD2+1    ; Store in INITMOD
  351.     MOV    A,H        ; Get most signifcant baud rate byte
  352.     STA    INITMOD3+1    ; Store in INITMOD
  353.     JMP    INITMOD1    ; Reinitialize to new baudrate, done
  354. ;.....
  355. ;
  356. ;
  357. ; Table of baud rate parameters
  358. ;
  359. BD300    EQU    640
  360. BD1200    EQU    160
  361. BD2400    EQU     80
  362. BD9600    EQU     20
  363. ;
  364. BAUDBUF:DB    10,0,0,0,0,0
  365.     DB    0,0,0,0,0,0
  366. ;
  367. ;                   end
  368. ;-----------------------------------------------------------------------
  369. ;
  370. ; NOTE: Must terminate prior to 0400H
  371. ;
  372.     END
  373.