home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / IMP / I2SS-3.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  11KB  |  363 lines
  1.  
  2. ; I2SS-3.ASM - IMP overlay for the CompuPro System Support 1 - 06/01/87
  3. ;
  4. ;        2651 I/O with built-in baudrate generator
  5. ;
  6. ; This overlay adapts IMP.COM to the CompuPro System Support 1 serial
  7. ; card using the 2651 USART.  If using a 6 MHz clock 1-2 wait states may
  8. ; be needed to keep from dropping characters.
  9. ;
  10. ; You will want to look this file over carefully.  There are a number of
  11. ; options that you can use to configure the program to suit your taste.
  12. ;
  13. ; Edit this file for your preferences then follow the "TO USE:" example
  14. ; shown below.
  15. ;
  16. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  17. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  18. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  19. ; (The ESC will automatically be typed with no CTL-character present.)
  20. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
  21. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  22. ; looking at the function key table, typing CTL-Z in command mode, etc.
  23. ;
  24. ; Use the "SET" command to change the baudrate when desired.  The value
  25. ; at MSPEED controls the baudrate when the program is first called up.
  26. ;
  27. ;    TO USE: First edit this file filling in answers for your own
  28. ;        equipment.  Then assemble with ASM.COM or equivalent
  29. ;        assembler.  Then use MLOAD to merge into the main file:
  30. ;
  31. ;        MLOAD IMP.COM=IMP.COM,I2SS-x.HEX
  32. ;
  33. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  34. ;
  35. ; 06/01/87  Improved the GOODBYE routine, added BREAK routine, needs
  36. ;        IMP245 to use it.                - Irv Hoff
  37. ;
  38. ; 07/17/86  Fixed a "MVI  A,B" error in INITMOD1:    - Irv Hoff
  39. ; 07/17/85  Written to work with IMP            - Irv Hoff
  40. ;
  41. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  42. ;
  43. ;
  44. YES    EQU    0FFH
  45. NO    EQU    0
  46. ;
  47. ;
  48. PORT    EQU    05CH    ; Your base port (data or status)
  49. MDCTL1    EQU    PORT+1    ; Modem control port
  50. MDDATP    EQU    PORT    ; Modem data port
  51. MDRCV    EQU    02H    ; Modem receive ready
  52. MDSND    EQU    01H    ; Modem send ready bit
  53. MDTXE    EQU    05H    ; Modem send buffer empty, holding buffer empty
  54. ;
  55. ;
  56. ;-----------------------------------------------------------------------
  57. ;
  58. ESC    EQU    '['-40H    ; ^[ = Escape
  59. BELL    EQU    'G'-40H    ; ^G = Bell character
  60. LF    EQU    'J'-40H    ; ^J = Linefeed
  61. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  62. CR    EQU    'M'-40H    ; ^M = Carriage return
  63. CLEARSC    EQU    'Z'-40H    ; ^Z = Clears screen, command mode only
  64. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  65. ;
  66. ;
  67. ;-----------------------------------------------------------------------
  68. ;
  69. ;
  70.     ORG    0100H
  71. ;
  72. ;
  73.     DS    3    ; Skip the data area below
  74. ;
  75. ;
  76. ; These routines and equates are at the beginning of the program so
  77. ; they can be patched by a monitor or overlay file without re-assembling
  78. ; the program.
  79. ;
  80. MSPEED:     DB    6    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  81.             ; 6=2400 7=4800 8=9600 9=19200 default
  82. HS2400:     DB    YES    ; Yes=2400 bps highest speed            104H
  83. HS1200:     DB    NO    ; Yes=1200 bps highest speed            105H
  84. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  85. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  86. RESVD1:     DB    NO    ; Reserved for special modems            108H
  87. RESVD2:     DB    NO    ; Reserved for special modems            109H
  88. ;
  89. ;
  90. CLEAR:     DB    1AH    ; Clear screen character (ESC not needed)    10AH
  91. CLOCK:     DB    40    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  92.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  93. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  94.             ;   default time to send character in ter-
  95.             ;   minal mode file transfer for slow BBS
  96. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  97.             ;   default time for extra wait after CRLF
  98.             ;   in terminal mode file transfer
  99. NOFCOL:     DB    5    ; Number of directory columns shown        10EH
  100. TCHPUL:     DB    'T'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  101. ;.....
  102. ;
  103. ;
  104. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  105.             ;   mode (normally added by remote echo)
  106. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  107. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  108. IGNRCTL: DB    YES    ; Yes=CTL-chars above ^M not displayed        113H
  109. ;.....
  110. ;
  111. ;
  112. EXTCHR:     DB    '['-40H    ; ESC = preceeds local control character    114H
  113. EXITCHR: DB    'E'    ; Exit character                115H
  114. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  115. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  116. LOGCHR:     DB    'L'    ; Send logon                    118H
  117. LSTCHR:     DB    'P'    ; Toggle printer                119H
  118. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  119. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  120. CLEARS:     DB    'Z'    ; Clears screen, terminal mode            11CH
  121. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  122. NODTR:     DB    NO    ; YES if no DTR and need ATH0 to disconnect    11EH
  123. ;.....
  124. ;
  125. ;
  126. ; Handles in/out ports for data and status
  127. ;
  128. I$MDCTL1: IN    MDCTL1        ;                    11FH
  129.       RET            ;                    121H
  130.       DB    0,0,0,0,0,0,0    ;                    122H
  131. ;
  132. I$MDTXE:  IN    MDCTL1        ;                    129H
  133.       RET            ;                    12BH
  134.       DB    0,0,0,0,0,0,0    ;                    12CH
  135. ;
  136. I$MDDATP: IN    MDDATP        ;                    133H
  137.       RET            ;                    135H
  138.       DB    0,0,0,0,0,0,0    ;                    136H
  139. ;
  140. O$MDDATP: OUT    MDDATP        ; Out modem data port            13DH
  141.       RET            ;                    13FH
  142.       DB    0,0,0,0,0,0,0    ;                    140H
  143. ;.....
  144. ;
  145. ;
  146. A$MDRCV:  ANI    MDRCV        ;                    147H
  147.       RET            ;                    149H
  148. ;
  149. C$MDRCV:  CPI    MDRCV        ;                    14AH
  150.       RET            ;                    14CH
  151. ;
  152. A$MDSND:  ANI    MDSND        ;                    14DH
  153.       RET            ;                    14FH
  154. ;
  155. C$MDSND:  CPI    MDSND        ;                    150H
  156.       RET            ;                    152H
  157. ;
  158. A$MDTXE:  ANI    MDTXE        ;                    153H
  159.       RET            ;                    155H
  160. ;
  161. C$MDTXE:  CPI    MDTXE        ;                    156H
  162.       RET            ;                    158H
  163. ;.....
  164. ;
  165. ;
  166. ; Special exit vector, used by some computers to reset interrupt vectors
  167. ;
  168. J$EXITVEC:RET            ;                    159H
  169.       DB    0,0        ;                    15AH
  170. ;.....
  171. ;
  172. ;
  173. ; Jump vectors needed by each overlay
  174. ;
  175. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  176. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  177. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  178. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  179. ;.....
  180. ;
  181. ;
  182. ; "AT" command strings, can be replaced in individual overlay if needed
  183. ;
  184. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  185. J$STRNG1: DS    3        ; 2400 bps "AT" string            16BH
  186. ;
  187. ;
  188. ; Next fourteen lines should not be changed by user overlay as these go
  189. ; to specific locations in the main program, not in the overlay.
  190. ;
  191. ;
  192. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  193. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  194. J$DIAL:      DS    3        ; Start of dialing routine        174H
  195. J$DSCONT: DS    3        ; Terminates modem use            177H
  196. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  197. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  198. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  199. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  200. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  201. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  202. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  203. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  204. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  205. J$BREAK:  JMP    SENDBRK        ; Break routine             195H
  206. J$NEW2:      DB    0,0,0        ; For future needs            198H
  207. ;.....
  208. ;
  209. ;
  210. ; For 2400 bps auto-stepdown units
  211. ;
  212. MANUAL:      DB    0        ; For manual selection flag        19BH
  213. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  214. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  215. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  216. ;.....
  217. ;
  218. ;
  219. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  220. ;
  221. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  222.       DB    'Version for CompuPro System Support-1'    ;        1AAH
  223.       DB    CR,LF,0
  224.       RET
  225. ;.....
  226. ;
  227. ;
  228. ;-----------------------------------------------------------------------
  229. ;
  230. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  231. ;     end of your last routine should terminate by 0400H (601 bytes
  232. ;     available after start of SYSVER).
  233. ;
  234. ;-----------------------------------------------------------------------
  235. ;
  236. ; You can put in a message at this location which can be called up with
  237. ; (special character-L).  You can put in several lines.  End with a 0.
  238. ;
  239. LOGON:      DB    'Nice chatting with you, bye for now.',CR,LF,0
  240. ;
  241. ;-----------------------------------------------------------------------
  242. ;
  243. ; This routine sets a 300 ms break tone
  244. ;
  245. SENDBRK:
  246.     MVI    A,1FH        ; DTR normal, send break tone
  247.     JMP    GOODBYE+2    ; Send the break tone
  248. ;.....
  249. ;
  250. ;
  251. ; This routine sets DTR low for 300 ms to disconnect the phone
  252. ;
  253. GOODBYE:
  254.     MVI    A,1DH        ; Set RTS, flags, DTR, break
  255.     OUT    PORT+3        ; Put command register out of mode
  256.     IN    PORT+3        ; Make sure it is now clear
  257.     IN    PORT+3        ; Try once more
  258.     MVI    B,3        ; Turn off DTR for 300 ms
  259.     CALL    J$TIMER
  260.     MVI    A,37H        ; Turn DTR back on
  261.     OUT    PORT+3        ; Send to command register
  262.     IN    PORT+3        ; Clear any incoming characters
  263.     IN    PORT+3        ; Try once more
  264.     XRA    A        ; Clear the 'A' register
  265.     RET
  266. ;.....
  267. ;
  268. ;
  269. ; Initializes the 2561 I/O for selected baudrate
  270. ;
  271. INITMOD:
  272.     LDA    MSPEED        ; Get the selected value
  273.     CPI    1        ; 300 bps
  274.     JZ    OK300
  275.     CPI    5        ; 1200 bps
  276.     JZ    OK1200
  277.     CPI    6        ; 2400 bps
  278.     JZ    OK2400
  279.     CPI    8        ; 9600 bps
  280.     JZ    OK9600
  281.     JMP    STUPR1        ; Else ask what is wanted
  282. ;
  283. INITMOD1:
  284.     MVI    A,4EH        ; Select 8 data bits no parity 1 stop
  285.     OUT    PORT+2        ; Send to mode register 1
  286.     MOV    A,B        ; Get the baudrate back
  287.     OUT    PORT+2        ; Send to mode register 2
  288.     MVI    A,37H        ; Turn on DTR etc, reset any error flags
  289.     OUT    PORT+3        ; Send to command register
  290.     IN    PORT+3        ; Clear any incoming characters
  291.     IN    PORT+3        ; Try once more
  292.     RET
  293. ;.....
  294. ;
  295. ;
  296. ; Use the 'SET' command to select a desired baud rate
  297. ;
  298. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  299.     JNC    STUPR2
  300. ;
  301. STUPR1:    CALL    J$ILPRT
  302.     DB    'Input Baud Rate (300, 1200, 2400, 9600): ',0
  303.     LXI    D,BAUDBUF    ; Point to new input buffer
  304.     CALL    J$INBUF
  305.     CALL    J$CRLF
  306.     LXI    D,BAUDBUF+2
  307. ;
  308. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  309.     DB    '300',0
  310.     JNC    OK300        ; Go if got match
  311.     CALL    J$INLNCP
  312.     DB    '1200',0
  313.     JNC    OK1200
  314.     CALL    J$INLNCP
  315.     DB    '2400',0
  316.     JNC    OK2400
  317.     CALL    J$INLNCP
  318.     DB    '9600',0
  319.     JNC    OK9600
  320.     CALL    J$ILPRT        ; All matches failed, tell operator
  321.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  322.     JMP    STUPR1        ; Try again
  323. ;
  324. OK300:    MVI    A,1        ; MSPEED 300 baud value
  325.     MVI    B,BD300        ; Get 300 baud value for 2651 in 'B'
  326.     JMP    LOADBD        ; Go load everything
  327. ;
  328. OK1200:    MVI    A,5
  329.     MVI    B,BD1200
  330.     JMP    LOADBD
  331. ;
  332. OK2400:    XRA    A
  333.     STA    MANUAL
  334.     MVI    A,6
  335.     MVI    B,BD2400
  336.     JMP    LOADBD
  337. ;
  338. OK9600:    MVI    A,8
  339.     MVI    B,BD9600
  340. ;
  341. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  342.     JMP    INITMOD1    ; Reset to new baudrate
  343. ;.....
  344. ;
  345. ;
  346. ; Baudrate table
  347. ;
  348. BD300    EQU    35H        ; 300 baud
  349. BD1200    EQU    37H        ; 1200 bps
  350. BD2400    EQU    3AH        ; 2400 bps
  351. BD9600    EQU    3EH        ; 9600 bps
  352. BD19200    EQU    3FH        ; 19200 bps
  353. ;
  354. BAUDBUF:DB    10,0,0,0,0,0
  355.     DB    0,0,0,0,0,0
  356. ;
  357. ;                   end
  358. ;-----------------------------------------------------------------------
  359. ;
  360. ; NOTE: Must terminate prior to 0400H
  361. ;
  362.     END
  363.