home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / IMP / I2MT-2.AZM / I2MT-2.ASM
Assembly Source File  |  2000-06-30  |  12KB  |  400 lines
  1.  
  2. ; I2MT-2.ASM - Memotech SDX-512 computer overlay file for IMP - 06/01/87
  3. ;
  4. ;        DART I/O and CTC timer 4.000 MHz
  5. ;
  6. ; This overlay adapts the IMP modem program to the Memotech SDX-512
  7. ; computer with the Z80 DART serial port "B" and the Z80 CTC baud rate
  8. ; generator.
  9. ;
  10. ;     Make up a RS232 cable per the instructions below:
  11. ;
  12. ;            Modem      Memotech
  13. ;            -----      --------
  14. ;            pin 2    -  pin 2
  15. ;            pin 3    -  pin 3
  16. ;            pin 7    -  pin 7
  17. ;            pin 8    -  pin 8    (not needed for IMP)
  18. ;            pin 20    -  pin 20
  19. ;
  20. ;
  21. ; Edit this file for your preferences then follow the "TO USE:" example
  22. ; shown below.
  23. ;
  24. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  25. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  26. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  27. ; (The ESC will automatically be typed with no CTL-character present.)
  28. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
  29. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  30. ; looking at the function key table, typing CTL-Z in command mode, etc.
  31. ;
  32. ; Use the "SET" command to change the baudrate when desired.  The value
  33. ; at MSPEED controls the baudrate when the program is first called up.
  34. ;
  35. ;    TO USE: First edit this file filling in answers for your own
  36. ;        equipment.  Then assemble with ASM.COM or equivalent
  37. ;        assembler.  Then use MLOAD to merge into the main file:
  38. ;
  39. ;        MLOAD IMP.COM=IMP.COM,I2MT-x.HEX
  40. ;
  41. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  42. ;
  43. ; 06/01/87  Improved the GOODBYE routine, added BREAK routine, needs
  44. ;        IMP245 to use it.            - Irv Hoff
  45. ;
  46. ; 02/11/86  Initial Version            - Irv Hoff
  47. ;
  48. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  49. ;
  50. ;
  51. YES    EQU    0FFH
  52. NO    EQU    0
  53. ;
  54. ;
  55. ; Values shown are for a Z80 DART, using Memotech port 'B'
  56. ;
  57. PORT    EQU    0DH    ; Your base data port
  58. MDCTL1    EQU    PORT+2    ; Modem control port
  59. MDDATP    EQU    PORT    ; Modem data port
  60. MDRCV    EQU    01H    ; Modem receive ready
  61. MDSND    EQU    04H    ; Modem send ready bit
  62. MDTXE    EQU    01H    ; Modem send buffer empty, holding buffer empty
  63. ;
  64. BRPORT    EQU    0AH    ; Baud rate generator port (CTC)
  65. ;
  66. ;
  67. ;-----------------------------------------------------------------------
  68. ;
  69. ESC    EQU    '['-40H    ; ^[ = Escape
  70. BELL    EQU    'G'-40H    ; ^G = Bell character
  71. LF    EQU    'J'-40H    ; ^J = Linefeed
  72. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  73. CR    EQU    'M'-40H    ; ^M = Carriage return
  74. CLEARSC    EQU    'Z'-40H    ; ^Z = Clear screen, command mode only
  75. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  76. ;
  77. ;
  78. ;-----------------------------------------------------------------------
  79. ;
  80. ;
  81.     ORG    0100H
  82. ;
  83. ;
  84.     DS    3    ; Skip the data area below
  85. ;
  86. ;
  87. ; These routines and equates are at the beginning of the program so
  88. ; they can be patched by a monitor or overlay file without re-assembling
  89. ; the program.
  90. ;
  91. MSPEED:     DB    1    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  92.             ; 6=2400 7=4800 8=9600 9=19200 default
  93. HS2400:     DB    NO    ; Yes=2400 bps highest speed            104H
  94. HS1200:     DB    YES    ; Yes=1200 bps highest speed            105H
  95. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  96. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  97. RESVD1:     DB    NO    ; Reserved for special modems            108H
  98. RESVD2:     DB    NO    ; Reserved for special modems            109H
  99. ;
  100. ;
  101. CLEAR:     DB    '*'    ; Clear screen character (ESC not needed)    10AH
  102. CLOCK:     DB    40    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  103.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  104. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  105.             ;   default time to send character in ter-
  106.             ;   minal mode file transfer for slow BBS
  107. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  108.             ;   default time for extra wait after CRLF
  109.             ;   in terminal mode file transfer
  110. NOFCOL:     DB    5    ; Number of directory columns shown        10EH
  111. TCHPUL:     DB    'T'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  112. ;.....
  113. ;
  114. ;
  115. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  116.             ;   mode (normally added by remote echo)
  117. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  118. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  119. IGNRCTL: DB    YES    ; Yes=CTL-chars above ^M not displayed        113H
  120. ;.....
  121. ;
  122. ;
  123. EXTCHR:     DB    '['-40H    ; ESC = preceeds local control character    114H
  124. EXITCHR: DB    'E'    ; Exit character                115H
  125. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  126. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  127. LOGCHR:     DB    'L'    ; Send logon                    118H
  128. LSTCHR:     DB    'P'    ; Toggle printer                119H
  129. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  130. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  131. CLEARS:     DB    'Z'    ; Clears screen, terminal mode            11CH
  132. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  133. NODTR:     DB    NO    ; YES if no DTR and need ATH0 to disconnect    11EH
  134. ;.....
  135. ;
  136. ;
  137. ; Handles in/out ports for data and status
  138. ;
  139. I$MDCTL1: MVI    A,10H        ; Register 0, reset interrupts        11FH
  140.       OUT    MDCTL1        ;                    121H
  141.       IN    MDCTL1        ;                    123H
  142.       RET            ; IN modem control port         125H
  143.       DB    0,0,0        ; Spares if needed            126H
  144. ;
  145. I$MDTXE:  MVI    A,11H        ; Select read register 1        129H
  146.       OUT    MDCTL1        ;                    12BH
  147.       IN    MDCTL1        ;                    12DH
  148.       RET            ;                    12FH
  149.       DB    0,0,0        ;                    130H
  150. ;
  151. I$MDDATP: MVI    A,37H        ;                    133H
  152.       OUT    MDCTL1        ;                    135H
  153.       IN    MDDATP        ;                    137H
  154.       RET            ;                    139H
  155.       DB    0,0,0        ; Spares if needed            13AH
  156. ;
  157. O$MDDATP: OUT    MDDATP        ;                    13DH
  158.       RET            ; OUT modem data port            13FH
  159.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  160. ;.....
  161. ;
  162. ;
  163. A$MDRCV:  ANI    MDRCV        ;                    147H
  164.       RET            ;                    149H
  165. ;
  166. C$MDRCV:  CPI    MDRCV        ;                    14AH
  167.       RET            ;                    14CH
  168. ;
  169. A$MDSND:  ANI    MDSND        ;                    14DH
  170.       RET            ;                    14FH
  171. ;
  172. C$MDSND:  CPI    MDSND        ;                    150H
  173.       RET            ;                    152H
  174. ;
  175. A$MDTXE:  ANI    MDTXE        ;                    153H
  176.       RET            ;                    155H
  177. ;
  178. C$MDTXE:  CPI    MDTXE        ;                    156H
  179.       RET            ;                    158H
  180. ;.....
  181. ;
  182. ;
  183. ; Special exit vector, used by some computers to reset interrupt vectors
  184. ;
  185. J$EXITVEC:RET            ;                    159H
  186.       DB    0,0        ;                    15AH
  187. ;.....
  188. ;
  189. ;
  190. ; Jump vectors needed by each overlay
  191. ;
  192. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  193. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  194. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  195. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  196. ;.....
  197. ;
  198. ;
  199. ; "AT" command strings, can be replaced in individual overlay if needed
  200. ;
  201. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  202. J$STRNG1: DS    3        ; 2400 bps "AT" string            16BH
  203. ;
  204. ;
  205. ; Next fourteen lines should not be changed by user overlay as these go
  206. ; to specific locations in the main program, not in the overlay.
  207. ;
  208. ;
  209. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  210. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  211. J$DIAL:      DS    3        ; Start of dialing routine        174H
  212. J$DSCONT: DS    3        ; Terminates modem use            177H
  213. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  214. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  215. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  216. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  217. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  218. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  219. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  220. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  221. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  222. J$BREAK:  JMP    SENDBRK        ; Break routine             195H
  223. J$NEW2:      DB    0,0,0        ; For future needs            198H
  224. ;.....
  225. ;
  226. ;
  227. ; For 2400 bps auto-stepdown units
  228. ;
  229. MANUAL:      DB    0        ; For manual selection flag        19BH
  230. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  231. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  232. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  233. ;.....
  234. ;
  235. ;
  236. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  237. ;
  238. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  239.       DB    'Version for the Memotech computer' ;            1AAH
  240.       DB    CR,LF,0
  241.       RET
  242. ;.....
  243. ;
  244. ;
  245. ;-----------------------------------------------------------------------
  246. ;
  247. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  248. ;     end of your last routine should terminate by 0400H (601 bytes
  249. ;     available after start of SYSVER).
  250. ;
  251. ;-----------------------------------------------------------------------
  252. ;
  253. ; You can put in a message at this location which can be called up with
  254. ; (special character-L).  You can put in several lines.  End with a 0.
  255. ;
  256. LOGON:    DB    'This is a Memotech computer. ',CR,LF,0
  257. ;
  258. ;-----------------------------------------------------------------------
  259. ;
  260. ; This routine sets a 300 ms break tone
  261. ;
  262. SENDBRK:
  263.     MVI    A,5
  264.     OUT    MDCTL1        ; Send to the status port
  265.     MVI    A,0F8H        ; DTR normal, send break tone
  266.     JMP    GOODBYE1    ; Go send the break tone
  267. ;.....
  268. ;
  269. ;
  270. ; This routine sets DTR low for 300 ms to disconnect the modem.
  271. ;
  272. GOODBYE:
  273.     MVI    A,5
  274.     OUT    MDCTL1        ; Send to the status port
  275.     MVI    A,78H        ; Turn off DTR and send break tone
  276. ;
  277. GOODBYE1:
  278.     OUT    MDCTL1
  279.     MVI    B,3        ; Delay 300 ms
  280.     CALL    J$TIMER
  281.     MVI    A,5
  282.     OUT    MDCTL1
  283.     MVI    A,0E8H        ; Restore normal, 8 bits, DTR on, etc.
  284.     OUT    MDCTL1
  285.     RET
  286. ;.....
  287. ;
  288. ;
  289. ; Sets CTC for baud rate.
  290. ;
  291. INITMOD:
  292.     MVI    A,0        ; Select register
  293.     OUT    MDCTL1        ; Send to the status port
  294.     MVI    A,18H        ; Reset the Z8SIO chip
  295.     OUT    MDCTL1        ; Send to the status port
  296.     MVI    A,4        ; Select register
  297.     OUT    MDCTL1        ; Send to the status port
  298.     MVI    A,44H        ; 16x, 2-stop, no parity  (84=1, 8C=2)
  299.     OUT    MDCTL1        ; Send to the status port
  300.     MVI    A,3        ; Select register
  301.     OUT    MDCTL1        ; Send to the status port
  302.     MVI    A,0C1H        ; Enable receive section
  303.     OUT    MDCTL1        ; Send to the status port
  304.     MVI    A,5        ; Select register
  305.     OUT    MDCTL1        ; Send to the status port
  306.     MVI    A,0EAH        ; DTR, RTS, 8-bits, enable send section
  307.     OUT    MDCTL1        ; Send to the status port
  308. ;
  309.     LDA    MSPEED        ; Get the selected value
  310.     CPI    1        ; 300 baud
  311.     JZ    OK300
  312.     CPI    5        ; 1200 bps
  313.     JZ    OK1200
  314.     CPI    6        ; 2400 bps
  315.     JZ    OK2400
  316.     CPI    8        ; 9600 bps
  317.     JZ    OK9600
  318.     CPI    9        ; 19200 bps
  319.     JZ    OK19200
  320.     JMP    STUPR1        ; Else ask what is wanted
  321. ;.....
  322. ;
  323. ;
  324. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  325.     JNC    STUPR2
  326. ;
  327. STUPR1:    CALL    J$ILPRT
  328.     DB    'Input Baud Rate (300, 1200, 2400, 9600, 19200): ',0
  329.     LXI    D,BAUDBUF    ; Point to new input buffer
  330.     CALL    J$INBUF
  331.     CALL    J$CRLF
  332.     LXI    D,BAUDBUF+2
  333. ;
  334. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  335.     DB    '300',0
  336.     JNC    OK300        ; Go if got match
  337.     CALL    J$INLNCP
  338.     DB    '1200',0
  339.     JNC    OK1200
  340.     CALL    J$INLNCP
  341.     DB    '2400',0
  342.     JNC    OK2400
  343.     CALL    J$INLNCP
  344.     DB    '9600',0
  345.     JNC    OK9600
  346.     CALL    J$INLNCP
  347.     DB    '19200',0
  348.     JNC    OK19200
  349.     CALL    J$ILPRT        ; All matches failed, tell operator
  350.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  351.     JMP    STUPR1        ; Try again
  352. ;
  353. OK300:    MVI    A,1        ; MSPEED 300 baud value
  354.     MVI    B,BD300        ; Get 300 bps parameters in 'HL'
  355.     JMP    LOADBD        ; Go load them
  356. ;
  357. OK1200:    MVI    A,5
  358.     MVI    B,BD1200
  359.     JMP    LOADBD
  360. ;
  361. OK2400:    XRA    A
  362.     STA    MANUAL        ; Reset to maximum auto-speed
  363.     MVI    A,6
  364.     MVI    B,BD2400
  365.     JMP    LOADBD
  366. ;
  367. OK9600:    MVI    A,8
  368.     MVI    B,BD9600
  369.     JMP    LOADBD
  370. ;
  371. OK19200:MVI    A,9
  372.     MVI    B,BD19200
  373. ;
  374. LOADBD:    STA    MSPEED        ; Change time-to-send to match baud rate
  375.     MVI    A,47H        ; Command word
  376.     OUT    BRPORT
  377.     MOV    A,B        ; Baudrate
  378.     OUT    BRPORT
  379.     RET
  380. ;.....
  381. ;
  382. ;
  383. ; Table of baud rate parameters
  384. ;
  385. BD300    EQU    64        ; 19200/300  (first half is CTC command)
  386. BD1200    EQU    16        ; 19200/1200
  387. BD2400    EQU    8        ; 19200/2400
  388. BD9600    EQU    2        ; 19200/9600
  389. BD19200    EQU    1        ; 19200/19200
  390. ;
  391. BAUDBUF:DB    10,0,0,0,0,0
  392.     DB    0,0,0,0,0,0
  393. ;
  394. ;                   end
  395. ;-----------------------------------------------------------------------
  396. ;
  397. ; NOTE: Must terminate prior to 0400H
  398. ;
  399.     END
  400.