home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / IMP / I2MO-3.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  11KB  |  337 lines
  1.  
  2. ; I2MO-3.ASM - IMP overlay for older Morrow MD-3 computers - 06/17/88
  3. ;
  4. ;       USES 8251A I/O and no baudrate generator
  5. ;
  6. ; You will want to look this file over carefully. There are a number of
  7. ; options that you can use to configure the program to suit your taste.
  8. ; This file adapts the Sayno computer to the IMP modem program.  This
  9. ; model has no baudrate generator and changes the 8251 from "x16" for
  10. ; 1200 bps to "x64" for 300 bps.  The Sayno must be jumpered for 1200
  11. ; bps for this method to work.
  12. ;
  13. ; Edit this file for your preferences then follow the "TO USE:" example
  14. ; shown below.
  15. ;
  16. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  17. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  18. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  19. ; (The ESC will automatically be typed with no CTL-character present.)
  20. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
  21. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  22. ; looking at the function key table, typing CTL-Z in command mode, etc.
  23. ;
  24. ; Use the "SET" command to change the baudrate when desired.  The value
  25. ; at MSPEED controls the baudrate when the program is first called up.
  26. ;
  27. ;    TO USE: First edit this file filling in answers for your own
  28. ;        equipment.  Then assemble with ASM.COM or equivalent
  29. ;        assembler.  Then use MLOAD to merge into the main file:
  30. ;
  31. ;        MLOAD IMP.COM=IMP.COM,I2S2-x.HEX
  32. ;
  33. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  34. ;
  35. ; 06/17/88  With help of Ilbert Butler and Bill Smith, fixed the over-
  36. ;    v3     lay to not check the printer port for status, since the MD3
  37. ;        computer already uses the printer port as the modem port.
  38. ;                        - Irv Hoff
  39. ;
  40. ; 06/01/87  Improved the GOODBYE routine, added BREAK routine, needs
  41. ;    v2     IMP245 to use it.            - Irv Hoff
  42. ;
  43. ; 10/27/85  Initial IMP version         - Irv Hoff
  44. ;    v1
  45. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  46. ;
  47. ;
  48. YES    EQU    0FFH
  49. NO    EQU    0
  50. ;
  51. ;
  52. ; Values shown are for a 8251A
  53. ;
  54. GOLIST    EQU    20E3H    ; Address of IMP routine to check printer status
  55. ;            ;    used in INITMOD to bypass the status check
  56. ;
  57. PORT    EQU    0FEH    ; Your base port (data or status)
  58. MDCTL1    EQU    PORT+1    ; Modem control port
  59. MDDATP    EQU    PORT    ; Modem data port
  60. MDRCV    EQU    02H    ; Modem receive ready
  61. MDSND    EQU    01H    ; Modem send ready bit
  62. MDTXE    EQU    05H    ; Modem send buffer empty, holding buffer empty
  63. ;
  64. MDMODE    EQU    82H    ; Insures 8251 is out of mode with DTR high
  65. MDRSET    EQU    42H    ; Resets USART for additional commands
  66. MDSET0    EQU    4FH    ; 1 stop bit, no parity, 8 bits, x64
  67. MDSET1    EQU    4EH    ; 1 stop bit, no parity, 8 bits, x16
  68. MDSET2    EQU    4CH    ; 2 stop bits, no parity, 8 bits, x16
  69. MDCOM    EQU    37H    ; Reset RTS, error flags, RCV, DTR, TX ready
  70. ;
  71. ;-----------------------------------------------------------------------
  72. ;
  73. ESC    EQU    '['-40H    ; ^[ = Escape
  74. BELL    EQU    'G'-40H    ; ^G = Bell character
  75. LF    EQU    'J'-40H    ; ^J = Linefeed
  76. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  77. CR    EQU    'M'-40H    ; ^M = Carriage return
  78. CLEARSC    EQU    'Z'-40H    ; ^Z = Clears screen, command mode only
  79. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  80. ;
  81. ;-----------------------------------------------------------------------
  82. ;
  83. ;
  84.     ORG    0100H
  85. ;
  86. ;
  87.     DS    3        ; Skip the data area below
  88. ;
  89. ;
  90. ; These routines and equates are at the beginning of the program so
  91. ; they can be patched by a monitor or overlay file without re-assembling
  92. ; the program.
  93. ;
  94. MSPEED:     DB    5    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  95.             ; 6=2400 7=4800 8=9600 9=19200 default
  96. HS2400:     DB    NO    ; Yes=2400 bps highest speed            104H
  97. HS1200:     DB    YES    ; Yes=1200 bps highest speed            105H
  98. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  99. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  100. RESVD1:     DB    NO    ; Reserved for special modems            108H
  101. RESVD2:     DB    NO    ; Reserved for special modems            109H
  102. ;
  103. ;
  104. CLEAR:     DB    '*'    ; Clear screen character (ESC not needed)    10AH
  105. CLOCK:     DB    40    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  106.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  107. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  108.             ;   default time to send character in ter-
  109.             ;   minal mode file transfer for slow BBS
  110. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  111.             ;   default time for extra wait after CRLF
  112.             ;   in terminal mode file transfer
  113. NOFCOL:     DB    5    ; Number of directory columns shown        10EH
  114. TCHPUL:     DB    'T'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  115. ;.....
  116. ;
  117. ;
  118. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  119.             ;   mode (normally added by remote echo)
  120. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  121. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  122. IGNRCTL: DB    YES    ; Yes=CTL-chars above ^M not displayed        113H
  123. ;.....
  124. ;
  125. ;
  126. EXTCHR:     DB    '['-40H    ; ESC = preceeds local control character    114H
  127. EXITCHR: DB    'E'    ; Exit character                115H
  128. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  129. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  130. LOGCHR:     DB    'L'    ; Send logon                    118H
  131. LSTCHR:     DB    'P'    ; Toggle printer                119H
  132. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  133. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  134. CLEARS:     DB    'Z'    ; Clears screen, terminal mode            11CH
  135. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  136. NODTR:     DB    NO    ; YES if no DTR and need ATH0 to disconnect    11EH
  137. ;.....
  138. ;
  139. ; Handles in/out ports for data and status
  140. ;
  141. I$MDCTL1: IN    MDCTL1        ;                    11FH
  142.       RET            ; IN modem control port         121H
  143.       DB    0,0,0,0,0,0,0    ; Spares if needed            122H
  144. ;
  145. I$MDTXE:  IN    MDCTL1        ; (Needed for SIO or DART register 1    129H
  146.       RET            ;                    12BH
  147.       DB    0,0,0,0,0,0,0    ;                    12CH
  148. ;
  149. I$MDDATP: MVI    A,37H        ;                    133H
  150.       OUT    MDCTL1        ;                    135H
  151.       IN    MDDATP        ;                    137H
  152.       RET            ;                    139H
  153.       DB    0,0,0        ; Spares if needed            13AH
  154. ;
  155. O$MDDATP: OUT    MDDATP        ;                    13DH
  156.       RET            ; OUT modem data port            13FH
  157.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  158. ;.....
  159. ;
  160. A$MDRCV:  ANI    MDRCV        ;                    147H
  161.       RET            ;                    149H
  162. ;
  163. C$MDRCV:  CPI    MDRCV        ;                    14AH
  164.       RET            ;                    14CH
  165. ;
  166. A$MDSND:  ANI    MDSND        ;                    14DH
  167.       RET            ;                    14FH
  168. ;
  169. C$MDSND:  CPI    MDSND        ;                    150H
  170.       RET            ;                    152H
  171. ;
  172. A$MDTXE:  ANI    MDTXE        ;                    153H
  173.       RET            ;                    155H
  174. ;
  175. C$MDTXE:  CPI    MDTXE        ;                    156H
  176.       RET            ;                    158H
  177. ;.....
  178. ;
  179. ; Special exit vector, used by some computers to reset interrupt vectors
  180. ;
  181. J$EXITVEC:RET            ;                    159H
  182.       DB    0,0        ;                    15AH
  183. ;.....
  184. ;
  185. ; Jump vectors needed by each overlay
  186. ;
  187. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  188. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  189. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  190. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  191. ;.....
  192. ;
  193. ; "AT" command strings, can be replaced in individual overlay if needed
  194. ;
  195. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  196. J$STRNG1: DS    3        ; 2400 bps "AT" string            16BH
  197. ;
  198. ; Next fourteen lines should not be changed by user overlay as these go
  199. ; to specific locations in the main program, not in the overlay.
  200. ;
  201. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  202. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  203. J$DIAL:      DS    3        ; Start of dialing routine        174H
  204. J$DSCONT: DS    3        ; Terminates modem use            177H
  205. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  206. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  207. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  208. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  209. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  210. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  211. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  212. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  213. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  214. J$BREAK:  JMP    SENDBRK        ; Break routine             195H
  215. J$NEW2:      DB    0,0,0        ; For future needs            198H
  216. ;.....
  217. ;
  218. ; For 2400 bps auto-stepdown units
  219. ;
  220. MANUAL:      DB    0        ; For manual selection flag        19BH
  221. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  222. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  223. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  224. ;.....
  225. ;
  226. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  227. ;
  228. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  229.       DB    'Version for Morrow MD3 modem port 0FEH' ;        1AAH
  230.       DB    CR,LF,0
  231.       RET
  232. ;.....
  233. ;
  234. ;-----------------------------------------------------------------------
  235. ;
  236. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  237. ;     end of your last routine should terminate by 0400H (601 bytes
  238. ;     available after start of SYSVER).
  239. ;
  240. ;-----------------------------------------------------------------------
  241. ;
  242. ; You can put in a message at this location which can be called up with
  243. ; (special character-L).  You can put in several lines.  End with a 0.
  244. ;
  245. LOGON:    DB    'Hello from a happy Morrow MD3 user...',CR,LF,0
  246. ;
  247. ;-----------------------------------------------------------------------
  248. ;
  249. ; This routine sets a 300 ms break tone
  250. ;
  251. SENDBRK:MVI    A,3FH        ; DTR normal, send break tone
  252.     JMP    GOODBYE+2
  253. ;.....
  254. ;
  255. ; This routine sets DTR low for 300 ms to disonnect the phone
  256. ;
  257. GOODBYE:MVI    A,3DH        ; Send break, turn off DTR
  258.     OUT    MDCTL1        ; Send to status port
  259.     MVI    B,3        ; Delay 300 ms to hang up phone
  260.     CALL    J$TIMER
  261.     MVI    A,37H        ; Normal send/receive with DTR
  262.     OUT    MDCTL1        ; Send to status port
  263.     RET
  264. ;.....
  265. ;
  266. ; Sets 8251 to 8 bits, DTR, RCV and TX ready
  267. ;
  268. INITMOD:MVI    A,0C9H        ; "Return" value
  269.     STA    GOLIST        ; Bypass checking printer status
  270.     LDA    MSPEED        ; Get the selected value
  271.     CPI    1        ; 300 bps
  272.     JZ    OK300
  273.     CPI    5        ; 1200 bps
  274.     JZ    OK1200
  275.     JMP    STUPR1        ; Else ask what is wanted
  276. ;.....
  277. ;
  278. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  279.     JNC    STUPR2
  280. ;
  281. STUPR1:    CALL    J$ILPRT
  282.     DB    'Input Baud Rate (300, 1200): ',0
  283.     LXI    D,BAUDBUF    ; Point to new input buffer
  284.     CALL    J$INBUF
  285.     CALL    J$CRLF
  286.     LXI    D,BAUDBUF+2
  287. ;
  288. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  289.     DB    '300',0
  290.     JNC    OK300        ; Go if got match
  291.     CALL    J$INLNCP
  292.     DB    '1200',0
  293.     JNC    OK1200
  294.     CALL    J$ILPRT        ; All matches failed, tell operator
  295.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  296.     JMP    STUPR1        ; Try again
  297. ;
  298. OK300:    MVI    A,1        ; MSPEED 300 baud value
  299.     MVI    B,MDSET0    ; Divide by 64 for 300 baud
  300.     JMP    LOADBD        ; Go set the baudrate
  301. ;
  302. OK1200:    MVI    A,5
  303.     MVI    B,MDSET1    ; Divide by 16 for 1200 bps
  304.     JMP    LOADBD        ; Go set the baudrate
  305. ;
  306. OK2400:    JMP    OK1200        ; (Does not support 1200 bps)
  307. ;
  308. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  309.     MVI    A,MDMODE    ; Insure 8251 is out of mode
  310.     OUT    MDCTL1
  311.     XTHL            ; Small delay to complete command
  312.     XTHL
  313.     MVI    A,MDRSET    ; Reset the 8251A for new command
  314.     OUT    MDCTL1
  315.     XTHL            ; Small delay to complete command
  316.     XTHL
  317.     MOV    A,B        ; Set speed
  318.     OUT    MDCTL1
  319.     XTHL            ; Small delay to complete command
  320.     XTHL
  321.     MVI    A,MDCOM        ; Error reset, RCV, DTR, TX ready
  322.     OUT    MDCTL1
  323.     XTHL            ; Small delay to complete command
  324.     XTHL
  325.     RET
  326. ;.....
  327. ;
  328. BAUDBUF:DB    10,0,0,0,0,0
  329.     DB    0,0,0,0,0,0
  330. ;
  331. ;                   end
  332. ;-----------------------------------------------------------------------
  333. ;
  334. ; NOTE: Must terminate by 0400H
  335. ;
  336.     END
  337.