home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
CPM
/
IMP
/
I2H8-5.AZM
/
I2H8-5.ASM
Wrap
Assembly Source File
|
2000-06-30
|
12KB
|
407 lines
; I2H8-5.ASM - Heath/Zenith H89 overlay file for IMP - 06/01/87
;
; 8250 with built-in baudrate generator
;
; You will want to look this file over carefully. There are a number of
; options that you can use to configure the program to suit your taste.
; This file adapts the Heath/Zenith 89/90 series computers to IMP.COM.
;
; Edit this file for your preferences then follow the "TO USE:" example
; shown below.
;
; Many terminals will clear the screen with a CTL-Z. If yours does, put
; a 1AH at CLEAR: (010AH). Many terminals use two characters, the first
; normally an ESC. For example, ESC *. In this case put '*' at CLEAR:
; (The ESC will automatically be typed with no CTL-character present.)
; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
; will scroll up 24 blank lines to clear the CRT for things like MENU,
; looking at the function key table, typing CTL-Z in command mode, etc.
;
; Use the "SET" command to change the baudrate when desired. The value
; at MSPEED controls the baudrate when the program is first called up.
;
; TO USE: First edit this file filling in answers for your own
; equipment. Then assemble with ASM.COM or equivalent
; assembler. Then use MLOAD to merge into the main file:
;
; MLOAD IMP.COM=IMP.COM,I2H8-x.HEX
;
;----------------------------------------------------------------------
;
; USING 5-1/4" DRIVES? You may experience problems with slow access
; times. Symptoms of the problem are: If you get a timeout when it
; stops each 128 records to dump to disk, this sometimes causes things
; to get out of synch and the program eventually aborts.
;
; SOLUTION: Change byte 0BFFh from 80h (128 decimal for 16k disk dumps)
; to 40h (64 decimal for 8k disk dumps). You can do this with either
; DDT or easier with the telephone overlay library which has this byte
; prominently displayed so it can be readily changed. (Then use DDT or
; MLOAD to install the revised telephone library.)
;
; This allows the disk dump to terminate in less than 10 seconds and the
; file transfer can then proceed normally.
;
; NOTE: do not use 19200 if you have the slow disk drives
; like the SSSD hard-sectored (40 track) drives.
;
; = = = = = = = = = = = = = = = = = =
;
; 06/01/87 Improved the GOODBYE routine, added BREAK routine, needs
; IMP245 to use it. - Irv Hoff
;
; 10/27/85 Restored baud rates to those normally used with this equip-
; ment. If others are needed, install those on an individual
; basis, please. Other incidental changes.
; - Irv Hoff
; 10/24/85 Added more baud rates - Fred Townsend
; 09/08/85 Added 19200 Baud - Fred Townsend
; 07/17/85 Written to work with IMP - Irv Hoff
;
; = = = = = = = = = = = = = = = = =
;
;
YES EQU 0FFH
NO EQU 0
;
;
; Values shown are for a 8250
;
PORT EQU 0D8H ; Your base port (data or status)
MDCTL1 EQU PORT+5 ; Modem control port
MDDATP EQU PORT ; Modem data port
MDRCV EQU 01H ; Modem receive ready
MDSND EQU 20H ; Modem send ready bit
MDTXE EQU 60H ; Modem send buffer empty, holding buffer empty
;
;
;-----------------------------------------------------------------------
;
ESC EQU '['-40H ; ^[ = Escape
BELL EQU 'G'-40H ; ^G = Bell character
LF EQU 'J'-40H ; ^J = Linefeed
NEXTRY EQU 'K'-40H ; ^K = Try next phone number, abort this try
CR EQU 'M'-40H ; ^M = Carriage return
CLEARSC EQU 'Z'-40H ; ^Z = Clears screen, command mode only
EOFCHAR EQU 'Z'-40H ; ^Z = End of file
;
;
;-----------------------------------------------------------------------
;
;
ORG 0100H
;
;
DS 3 ; Skip the data area below
;
;
; These routines and equates are at the beginning of the program so
; they can be patched by a monitor or overlay file without re-assembling
; the program.
;
MSPEED: DB 5 ; 0=110 1=300 2=450 3=600 4=710 5=1200 103H
; 6=2400 7=4800 8=9600 9=19200
HS2400: DB NO ; Yes=2400 bps highest speed 104H
HS1200: DB YES ; Yes=1200 bps highest speed 105H
RACAL: DB NO ; Yes=Racal-Vadic 1200V or 2400V or 2400PA 106H
PROMODM: DB NO ; Yes=Prometheus ProModem 1200 bps 107H
RESVD1: DB NO ; Reserved for special modems 108H
RESVD2: DB NO ; Reserved for special modems 109H
;
;
CLEAR: DB 'E' ; Clear screen character (ESC not needed) 10AH
CLOCK: DB 20 ; Clock speed in MHz x10, 25.5 MHz max. 10BH
; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
BYTDLY: DB 2 ; 0=0 delay 1=10ms 5=50 ms - 9=90 ms 10CH
; default time to send character in ter-
; minal mode file transfer for slow BBS
CRDLY: DB 2 ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms 10DH
; default time for extra wait after CRLF
; in terminal mode file transfer
NOFCOL: DB 5 ; Number of directory columns shown 10EH
TCHPUL: DB 'T' ; T=tone, P=Pulse (Hayes 2400 modems) 10FH
;.....
;
;
ADDLFD: DB NO ; Yes=add LF after CR to send file in terminal 110H
; mode (normally added by remote echo)
CONVRUB: DB YES ; Yes=convert rub to backspace 111H
CRCDFLT: DB YES ; Yes=default to CRC checking 112H
IGNRCTL: DB YES ; Yes=CTL-chars above ^M not displayed 113H
;.....
;
;
EXTCHR: DB '['-40H ; ESC = precedes local control character 114H
EXITCHR: DB 'E' ; Exit character 115H
FILESND: DB 'F' ; Send file when in terminal mode 116H
NOCONCT: DB 'N' ; Disconnect from phone line 117H
LOGCHR: DB 'L' ; Send logon 118H
LSTCHR: DB 'P' ; Toggle printer 119H
UNSAVCH: DB 'R' ; Close input text buffer 11AH
SAVECHR: DB 'Y' ; Open input text buffer 11BH
CLEARS: DB 'Z' ; Clears screen, terminal mode 11CH
BRKCHR: DB 'Q' ; Send a break tone 11DH
NODTR: DB NO ; Yes if no DTR and need +++ to disconnect 11EH
;.....
;
;
; Handles in/out ports for data and status
;
I$MDCTL1: IN MDCTL1 ; Modem control port 11FH
RET ; 121H
DB 0,0,0,0,0,0,0 ; Spares if needed 122H
;
I$MDTXE: IN MDCTL1 ; 129H
RET ; 12BH
DB 0,0,0,0,0,0,0 ; 12CH
;
I$MDDATP: IN MDDATP ; 133H
RET ; 135H
DB 0,0,0,0,0,0,0 ; 136H
;
O$MDDATP: OUT MDDATP ; 13DH
RET ; 13FH
DB 0,0,0,0,0,0,0 ; Spares if needed 140H
;.....
;
;
A$MDRCV: ANI MDRCV ; 147H
RET ; 149H
;
C$MDRCV: CPI MDRCV ; 14AH
RET ; 14CH
;
A$MDSND: ANI MDSND ; 14DH
RET ; 14FH
;
C$MDSND: CPI MDSND ; 150H
RET ; 152H
;
A$MDTXE: ANI MDTXE ; 153H
RET ; 155H
;
C$MDTXE: CPI MDTXE ; 156H
RET ; 158H
;.....
;
;
; Special exit vector, used by some computers to reset interrupt vectors
;
J$EXITVEC:RET ; 159H
DB 0,0 ; 15AH
;.....
;
;
; Jump vectors needed by each overlay
;
J$GOODBYE:JMP GOODBYE ; Disconnects modem by dropping DTR 15CH
J$INITMOD:JMP INITMOD ; Initializes modem, autosets baudrate 15FH
J$STUPR: JMP STUPR ; SET routine to change baudrate 162H
J$SYSVR: JMP SYSVR ; Signon message 165H
;.....
;
;
; "AT" command strings, can be replaced in individual overlay if needed
;
J$STRNGA: DS 3 ; 1200 bps "AT" string 168H
J$STRNG1: DS 3 ; 2400 bps "AT" string 16BH
;
;
; Next fourteen lines should not be changed by user overlay as these go
; to specific locations in the main program, not in the overlay.
;
;
J$CMDSPL: DS 3 ; Allows entry of baudrate on CMD line 16EH
J$CRLF: DS 3 ; Turns up one new line on display 171H
J$DIAL: DS 3 ; Start of dialing routine 174H
J$DSCONT: DS 3 ; Terminates modem use 177H
J$GOLST: DS 3 ; Printer routine, needed by Apple //e 17AH
J$ILPRT: DS 3 ; Prints an inline string, 0 to end 17DH
J$INBUF: DS 3 ; Stores a keybd string for comparison 180H
J$INLNCP: DS 3 ; Inline "compare strings" routine 183H
J$INMDM: DS 3 ; Max .1 sec wait for modem character 186H
J$RCVRSP: DS 3 ; For 3801 I/O use (TV-803) 189H
J$SNDCHR: DS 3 ; Sends a character to the modem 18CH
J$SNDSTR: DS 3 ; Sends a string to the modem, $ to end 18FH
J$TIMER: DS 3 ; .1 second timer (amount in 'B' reg.) 192H
J$BREAK: JMP SENDBRK ; Break routine 195H
J$NEW2: DB 0,0,0 ; For future needs 198H
;.....
;
;
; For 2400 bps auto-stepdown units
;
MANUAL: DB 0 ; For manual selection flag 19BH
J$300: JMP OK300 ; Sets baudrate to 300 baud 19CH
J$1200: JMP OK1200 ; Sets baudrate to 1200 bps 19FH
J$2400: JMP OK2400 ; Sets baudrate to 2400 bps 1A2H
;.....
;
;
LOGPTR: DW LOGON ; Pointer to display LOGON message 1A5H
;
SYSVR: CALL J$ILPRT ; Display the following line 1A7H
DB 'Version for Heath H89 with HAYES or dumb modem, ' ; 1AAH
DB 'port 0D8H',CR,LF,0
RET
;.....
;
;
;-----------------------------------------------------------------------
;
; NOTE: You can change the SYSVR message to be longer or shorter. The
; end of your last routine should terminate by 0400H (601 bytes
; available after start of SYSVR).
;
;-----------------------------------------------------------------------
;
; You can put in a message at this location which can be called up with
; (special character-L). You can put in several lines. End with a 0.
;
LOGON: DB 'Hello from an Heath H89 user',CR,0
;
;-----------------------------------------------------------------------
;
; This routine sets a 300 ms break tone
;
SENDBRK:
JMP GOODBYE1
;.....
;
;
; This routine sets DTR low for 300 ms to disconnect the phone
;
GOODBYE:
XRA A
OUT PORT+4 ; Set DTR and RTS low
GOODBYE1:
MVI A,40H ; Set break tone
OUT PORT+3
MVI B,3 ; Wait 300 ms
CALL J$TIMER
MVI A,03H ; Reset to normal 8 bits
OUT PORT+3
MVI A,01H
OUT PORT+4 ; Reset DTR high
RET
;.....
;
;
INITMOD:LDA MSPEED ; Get the selected value
CPI 1 ; 300 bps
JZ OK300
CPI 5 ; 1200 bps
JZ OK1200
CPI 6 ; 2400 bps
JZ OK2400
CPI 8 ; 9600 bps
JZ OK9600
CPI 9 ; 19200 bps
JZ OK19200
JMP STUPR1 ; Else ask what is wanted
;
INITMOD1:
DI ; Turn off interrupts for initialization
XRA A
OUT PORT+1 ; Interrupt enable register
MVI A,80H ; Insure out of mode to set baud rate
OUT PORT+3 ; Line control register
OUT PORT+3
;
INITMOD2:
MVI A,60H ; Default 'LSP' speed for 1200 bps
OUT PORT ; Register for 'LSP' speed if enabled
;
INITMOD3:
MVI A,00H ; Default 'MSP' speed for 1200 bps
OUT PORT+1 ; Register for 'MSP' speed if enabled
MVI A,03H ; 8-level, 1 stop bit, no parity
OUT PORT+3 ; Line control register (03=1, 07=2)
MVI A,01H ; Set 'DTR' normal
OUT PORT+4 ; Modem control register
EI ; Restore interrupts to normal
RET
;.....
;
;
; The following routine changes the baud rate for the H89 with the SET
; command.
;
STUPR: CALL J$CMDSPL ; Gives us CMDBUF+6
JNC STUPR2
;
STUPR1: CALL J$ILPRT
DB 'Input Baud Rate (300, 1200, 2400, 9600, 19200): ',0
LXI D,BAUDBUF ; Point to new input buffer
CALL J$INBUF
CALL J$CRLF
LXI D,BAUDBUF+2
;
STUPR2: CALL J$INLNCP ; Compare BAUDBUF+2 with chars. below
DB '300',0
JNC OK300 ; Go if got match
CALL J$INLNCP
DB '1200',0
JNC OK1200
CALL J$INLNCP
DB '2400',0
JNC OK2400
CALL J$INLNCP
DB '9600',0
JNC OK9600
CALL J$INLNCP
DB '19200',0
JNC OK19200
CALL J$ILPRT ; All matches failed, tell operator
DB '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
JMP STUPR1 ; Try again
;
OK300: MVI A,1 ; MSPEED 300 baud value
LXI H,BD300 ; Get 300 baud parameters in HL
JMP LOADBD ; Go load them
;
OK1200: MVI A,5
LXI H,BD1200
JMP LOADBD
;
OK2400: XRA A
STA MANUAL
MVI A,6
LXI H,BD2400
JMP LOADBD
;
OK9600: MVI A,8
LXI H,BD9600
JMP LOADBD
;
OK19200:MVI A,9
LXI H,BD19200
;
LOADBD: STA MSPEED ; Store speed to show transfer time
MOV A,L ; Get least significant baud rate byte
STA INITMOD2+1 ; Store in INITMOD
MOV A,H ; Get most significant baud rate byte
STA INITMOD3+1 ; Store in INITMOD
JMP INITMOD1 ; Reinitialize to new baudrate, done
;.....
;
;
; Table of baud rate parameters
;
BD300 EQU 0180H
BD1200 EQU 0060H
BD2400 EQU 0030H
BD9600 EQU 000CH
BD19200 EQU 0006H
;
BAUDBUF:DB 10,0,0,0,0,0
DB 0,0,0,0,0,0
;
; end
;-----------------------------------------------------------------------
;
; NOTE: Must terminate prior to 0400H
;
END