home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / IMP / I2FT-2.AZM / I2FT-2.ASM
Assembly Source File  |  2000-06-30  |  11KB  |  383 lines
  1.  
  2. ; I2FT-2.ASM - Facit DTC overlay file for IMP2 - 06/01/87
  3. ;
  4. ;        (Z80 SIO) and (8430 CTC 4.000 MHz)
  5. ;
  6. ; You will want to look this file over carefully. There are a number of
  7. ; options that you can use to configure the program to suit your taste.
  8. ; This file adapts the Facit DTC computer to IMP2xx.COM.
  9. ;
  10. ; Edit this file for your preferences then follow the "TO USE:" example
  11. ; shown below.
  12. ;
  13. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  14. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  15. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  16. ; (The ESC will automatically be typed with no CTL-character present.)
  17. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP2
  18. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  19. ; looking at the function key table, typing CTL-Z in command mode, etc.
  20. ;
  21. ; Use the "SET" command to change the baudrate when desired.  The value
  22. ; at MSPEED controls the baudrate when the program is first called up.
  23. ;
  24. ;    TO USE: First edit this file filling in answers for your own
  25. ;        equipment.  Then assemble with ASM.COM or equivalent
  26. ;        assembler.  Then use MLOAD to merge into the main file:
  27. ;
  28. ;        MLOAD IMP.COM=IMP2xx.COM,I2EP-x.HEX
  29. ;
  30. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  31. ;
  32. ; 06/01/87  Improved the GOODBYE routine, added BREAK routine, needs
  33. ;        IMP245 to use it.            - Irv Hoff
  34. ;
  35. ; 09/22/85  Modified for Facit DTC        - Harlan Gustafson
  36. ; 07/29/85  Modified for Datavue 3000        - Jim Gooch
  37. ; 07/17/85  Written to work with IMP2        - Irv Hoff
  38. ;
  39. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  40. ;
  41. ;
  42. YES    EQU    0FFH
  43. NO    EQU    0
  44. ;
  45. ;
  46. ; Values shown are for a Z80 SIO
  47. ;
  48. PORT    EQU    040H    ; Your base port (data or status)
  49. MDCTL1    EQU    PORT+1    ; Modem control port
  50. MDDATP    EQU    PORT    ; Modem data port
  51. MDRCV    EQU    01H    ; Modem receive ready
  52. MDSND    EQU    04H    ; Modem send ready bit
  53. MDTXE    EQU    01H    ; Modem send buffer empty, holding buffer empty
  54. ;
  55. BRPORT    EQU    60H    ; Timer port for baudrate generator
  56. CTPORT    EQU    62H    ; CTC control port
  57. ;
  58. ;
  59. ;-----------------------------------------------------------------------
  60. ;
  61. ESC    EQU    '\'    ; \ = Escape
  62. BELL    EQU    'G'-40H    ; ^G = Bell character
  63. LF    EQU    'J'-40H    ; ^J = Linefeed
  64. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  65. CR    EQU    'M'-40H    ; ^M = Carriage return
  66. CLEARSC    EQU    'W'-40H    ; ^W = Clears screen, command mode only
  67. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  68. ;
  69. ;
  70. ;-----------------------------------------------------------------------
  71. ;
  72. ;
  73.     ORG    0100H
  74. ;
  75. ;
  76.     DS    3    ; Skip the data area below
  77. ;
  78. ;
  79. ; These routines and equates are at the beginning of the program so
  80. ; they can be patched by a monitor or overlay file without re-assembling
  81. ; the program.
  82. ;
  83. MSPEED:     DB    5    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  84.             ; 6=2400 7=4800 8=9600 9=19200 default
  85. HS2400:     DB    NO    ; Yes=2400 bps highest speed            104H
  86. HS1200:     DB    YES    ; Yes=1200 bps highest speed            105H
  87. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  88. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  89. RESVD1:     DB    NO    ; Reserved for special modems            108H
  90. RESVD2:     DB    NO    ; Reserved for special modems            109H
  91. ;
  92. ;
  93. CLEAR:     DB    0CH    ; Clear screen character (ESC not needed)    10AH
  94. CLOCK:     DB    40    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  95.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  96. BYTDLY:     DB    5    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  97.             ;   default time to send character in ter-
  98.             ;   minal mode file transfer for slow BBS
  99. CRDLY:     DB    5    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  100.             ;   default time for extra wait after CRLF
  101.             ;   in terminal mode file transfer
  102. NOFCOL:     DB    5    ; Number of directory columns shown        10EH
  103. TCHPUL:     DB    'T'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  104. ;.....
  105. ;
  106. ;
  107. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  108.             ;   mode (normally added by remote echo)
  109. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  110. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  111. IGNRCTL: DB    YES    ; Yes=CTL-chars above ^M not displayed        113H
  112. ;.....
  113. ;
  114. ;
  115. EXTCHR:     DB    '\'    ; \ = preceeds local control character    114H
  116. EXITCHR: DB    'E'    ; Exit character                115H
  117. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  118. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  119. LOGCHR:     DB    'L'    ; Send logon                    118H
  120. LSTCHR:     DB    'P'    ; Toggle printer                119H
  121. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  122. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  123. CLEARS:     DB    'W'    ; Clears screen, terminal mode            11CH
  124. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  125. NODTR:     DB    NO    ; YES if no DTR and need ATH0 to disconnect    11EH
  126. ;.....
  127. ;
  128. ;
  129. ; Handles in/out ports for data and status
  130. ;
  131. I$MDCTL1: MVI    A,10H        ; Register 0, reset interrupts        11FH
  132.       OUT    MDCTL1        ;                    121H
  133.       IN    MDCTL1        ;                    123H
  134.       RET            ;                    125H
  135.       DB    0,0,0        ; Spares if needed            126H
  136. ;
  137. I$MDTXE:  MVI    A,11H        ; Read register 1 for "all sent"    129H
  138.       OUT    MDCTL1        ;                    12BH
  139.       IN    MDCTL1        ;                    12DH
  140.       RET            ;                    12FH
  141.       DB    0,0,0        ;                    130H
  142. ;
  143. I$MDDATP: IN    MDDATP        ;                    133H
  144.       RET            ;                    135H
  145.       DB    0,0,0,0,0,0,0    ;                    136H
  146. ;
  147. O$MDDATP: OUT    MDDATP        ;                    13DH
  148.       RET            ; OUT modem data port            13FH
  149.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  150. ;.....
  151. ;
  152. ;
  153. A$MDRCV:  ANI    MDRCV        ;                    147H
  154.       RET            ;                    149H
  155. ;
  156. C$MDRCV:  CPI    MDRCV        ;                    14AH
  157.       RET            ;                    14CH
  158. ;
  159. A$MDSND:  ANI    MDSND        ;                    14DH
  160.       RET            ;                    14FH
  161. ;
  162. C$MDSND:  CPI    MDSND        ;                    150H
  163.       RET            ;                    152H
  164. ;
  165. A$MDTXE:  ANI    MDTXE        ;                    153H
  166.       RET            ;                    155H
  167. ;
  168. C$MDTXE:  CPI    MDTXE        ;                    156H
  169.       RET            ;                    158H
  170. ;.....
  171. ;
  172. ;
  173. ; Special exit vector, used by some computers to reset interrupt vectors
  174. ;
  175. J$EXITVEC:RET            ;                    159H
  176.       DB    0,0        ;                    15AH
  177. ;.....
  178. ;
  179. ;
  180. ; Jump vectors needed by each overlay
  181. ;
  182. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  183. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  184. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  185. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  186. ;.....
  187. ;
  188. ;
  189. ; "AT" command strings, can be replaced in individual overlay if needed
  190. ;
  191. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  192. J$STRNG1: DS    3        ; 2400 bps "AT" string            16BH
  193. ;
  194. ;
  195. ; Next fourteen lines should not be changed by user overlay as these go
  196. ; to specific locations in the main program, not in the overlay.
  197. ;
  198. ;
  199. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  200. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  201. J$DIAL:      DS    3        ; Start of dialing routine        174H
  202. J$DSCONT: DS    3        ; Terminates modem use            177H
  203. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  204. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  205. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  206. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  207. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  208. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  209. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  210. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  211. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  212. J$BREAK:  JMP    SENDBRK        ; Break routine             195H
  213. J$NEW2:      DB    0,0,0        ; For future needs            198H
  214. ;.....
  215. ;
  216. ;
  217. ; For 2400 bps auto-stepdown units
  218. ;
  219. MANUAL:      DB    0        ; For manual selection flag        19BH
  220. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  221. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  222. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  223. ;.....
  224. ;
  225. ;
  226. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  227. ;
  228. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  229.       DB    'Version for Facit DTC computers'    ;        1AAH
  230.       DB    CR,LF
  231.       DB    'Modified by Harlan Gustafson - 1985'
  232.       DB    CR,LF,0
  233.       RET
  234. ;.....
  235. ;
  236. ;
  237. ;-----------------------------------------------------------------------
  238. ;
  239. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  240. ;     end of your last routine should terminate by 0400H (601 bytes
  241. ;     available after start of SYSVER).
  242. ;
  243. ;-----------------------------------------------------------------------
  244. ;
  245. ; You can put in a message at this location which can be called up with
  246. ; (special character-L).  You can put in several lines.  End with a 0.
  247. ;
  248. LOGON:      DB    '75046,2700',CR,0
  249. ;
  250. ;-----------------------------------------------------------------------
  251. ;
  252. ; This routine sets a 300 ms break tone
  253. ;
  254. SENDBRK:
  255.     MVI    A,5
  256.     OUT    MDCTL1        ; Send to the status port
  257.     MVI    A,0F8H        ; DTR normal, send break tone
  258.     JMP    GOODBYE1    ; Go send the break tone
  259. ;.....
  260. ;
  261. ;
  262. ; This routine sets DTR low for 300 ms to disconnect the modem.
  263. ;
  264. GOODBYE:
  265.     MVI    A,5
  266.     OUT    MDCTL1        ; Send to the status port
  267.     MVI    A,78H        ; Turn off DTR and send break tone
  268. ;
  269. GOODBYE1:
  270.     OUT    MDCTL1
  271.     MVI    B,3        ; Delay 300 ms
  272.     CALL    J$TIMER
  273.     MVI    A,5
  274.     OUT    MDCTL1
  275.     MVI    A,0E8H        ; Restore normal, 8 bits, DTR on, etc.
  276.     OUT    MDCTL1
  277.     RET
  278. ;.....
  279. ;
  280. ;
  281. ; Facit DTC initialization -- sets CTC timer for send and receive
  282. ; baudrate.
  283. ;
  284. INITMOD:MVI    A,00H        ; Select register
  285.     OUT    MDCTL1
  286.     MVI    A,18H        ; Throw out of mode
  287.     OUT    MDCTL1
  288.     MVI    A,04H        ; Select register
  289.     OUT    MDCTL1
  290.     MVI    A,044H        ; Set ASCII parameters (44=1, 4C=2)
  291.     OUT    MDCTL1
  292.     MVI    A,03H        ; Select register
  293.     OUT    MDCTL1
  294.     MVI    A,0C1H        ; Enable receive
  295.     OUT    MDCTL1
  296.     MVI    A,05H        ; Select register
  297.     OUT    MDCTL1
  298.     MVI    A,0EAH        ; Enable send, DTR, RTS
  299.     OUT    MDCTL1
  300. ;
  301.     LDA    MSPEED        ; Get the selected value
  302.     CPI    1        ; 300 bps
  303.     JZ    OK300
  304.     CPI    5        ; 1200 bps
  305.     JZ    OK1200
  306.     CPI    6        ; 2400 bps
  307.     JZ    OK2400
  308.     CPI    8        ; 9600 bps
  309.     JZ    OK9600
  310.     JMP    STUPR1        ; Else ask what is wanted
  311. ;.....
  312. ;
  313. ;
  314. ; Sets the modem speed via the SET command.
  315. ;
  316. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  317.     JNC    STUPR2
  318. ;
  319. STUPR1:    CALL    J$ILPRT
  320.     DB    'Input Baud Rate (300, 1200, 2400, 9600): ',0
  321.     LXI    D,BAUDBUF    ; Point to new input buffer
  322.     CALL    J$INBUF
  323.     CALL    J$CRLF
  324.     LXI    D,BAUDBUF+2
  325. ;
  326. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  327.     DB    '300',0
  328.     JNC    OK300        ; Go if got match
  329.     CALL    J$INLNCP
  330.     DB    '1200',0
  331.     JNC    OK1200
  332.     CALL    J$INLNCP
  333.     DB    '2400',0
  334.     JNC    OK2400
  335.     CALL    J$INLNCP
  336.     DB    '9600',0
  337.     JNC    OK9600
  338.     CALL    J$ILPRT        ; All matches failed, tell operator
  339.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  340.     JMP    STUPR1        ; Try again
  341. ;
  342. OK300:    MVI    A,1        ; MSPEED 300 baud value
  343.     LXI    H,BD300
  344.     JMP    LOADBD
  345. ;
  346. OK1200:    MVI    A,5        ;MSPEED
  347.     LXI    H,BD1200
  348.     JMP    LOADBD
  349. ;
  350. OK2400:    MVI    A,6
  351.     LXI    H,BD2400
  352.     JMP    LOADBD
  353. ;
  354. OK9600:    MVI    A,8
  355.     LXI    H,BD9600
  356. ;
  357. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  358.  
  359.     MOV    A,H        ; MSP of baudrate (timer mode)
  360.     OUT    BRPORT        ; prescaler= 256
  361.     MOV    A,L        ; LSP of baudrate
  362.     OUT    BRPORT        ; count value
  363.     RET
  364. ;.....
  365. ;
  366. ;
  367. ; Table of baudrate parameters
  368. ;
  369. BD300    EQU    04780H        ; 300 baud
  370. BD1200    EQU    04720H        ; 1200 bps
  371. BD2400    EQU    04710H        ; 2400 bps
  372. BD9600    EQU    04704H        ; 9600 bps
  373. ;
  374. BAUDBUF:DB    10,0,0,0,0,0
  375.     DB    0,0,0,0,0,0
  376. ;
  377. ;                   end
  378. ;-----------------------------------------------------------------------
  379. ;
  380. ; NOTE: Must terminate prior to 0400H
  381. ;
  382.     END
  383.