home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / IMP / I2DM-2.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  11KB  |  376 lines
  1.  
  2. ; I2DM-2.ASM - Dynabyte Monarch computer overlay file for IMP - 06/01/87
  3. ;
  4. ;        Z80 SIO and 8116 baudrate generator
  5. ;
  6. ; You will want to look this file over carefully. There are a number of
  7. ; options that you can use to configure the program to suit your taste.
  8. ; This file adapts Dynabye Monarch computer to IMP.COM.
  9. ;
  10. ; Edit this file for your preferences then follow the "TO USE:" example
  11. ; shown below.
  12. ;
  13. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  14. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  15. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  16. ; (The ESC will automatically be typed with no CTL-character present.)
  17. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
  18. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  19. ; looking at the function key table, typing CTL-Z in command mode, etc.
  20. ;
  21. ; Use the "SET" command to change the baudrate when desired.  The value
  22. ; at MSPEED controls the baudrate when the program is first called up.
  23. ;
  24. ;    TO USE: First edit this file filling in answers for your own
  25. ;        equipment.  Then assemble with ASM.COM or equivalent
  26. ;        assembler.  Then use MLOAD to merge into the main file:
  27. ;
  28. ;        MLOAD IMP.COM=IMP.COM,I2DM-x.HEX
  29. ;
  30. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  31. ;
  32. ; 06/01/87  Improved the GOODBYE routine, added BREAK routine, needs
  33. ;        IMP245 to use it.            - Irv Hoff
  34. ; 10/27/85  Written to work with IMP        - Irv Hoff
  35. ;
  36. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  37. ;
  38. ;
  39. YES    EQU    0FFH
  40. NO    EQU    0
  41. ;
  42. ;
  43. PORT    EQU    0BDH    ; Your base port (data or status)
  44. MDCTL1    EQU    PORT+2    ; Modem control port
  45. MDDATP    EQU    PORT    ; Modem data port
  46. MDRCV    EQU    01H    ; Modem receive ready
  47. MDSND    EQU    04H    ; Modem send ready bit
  48. MDTXE    EQU    01H    ; Modem send buffer empty, holding buffer empty
  49. ;
  50. BRPORT    EQU    83H    ; Baud rate generator port
  51. ;
  52. ;
  53. ;-----------------------------------------------------------------------
  54. ;
  55. ESC    EQU    '['-40H    ; ^[ = Escape
  56. BELL    EQU    'G'-40H    ; ^G = Bell character
  57. LF    EQU    'J'-40H    ; ^J = Linefeed
  58. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  59. CR    EQU    'M'-40H    ; ^M = Carriage return
  60. CLEARSC    EQU    'Z'-40H    ; ^Z = Clears screen, command mode only
  61. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  62. ;
  63. ;
  64. ;-----------------------------------------------------------------------
  65. ;
  66. ;
  67.     ORG    0100H
  68. ;
  69. ;
  70.     DS    3    ; Skip the data area below
  71. ;
  72. ;
  73. ; These routines and equates are at the beginning of the program so
  74. ; they can be patched by a monitor or overlay file without re-assembling
  75. ; the program.
  76. ;
  77. MSPEED:     DB    5    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  78.             ; 6=2400 7=4800 8=9600 9=19200 default
  79. HS2400:     DB    NO    ; Yes=2400 bps highest speed            104H
  80. HS1200:     DB    YES    ; Yes=1200 bps highest speed            105H
  81. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  82. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  83. RESVD1:     DB    NO    ; Reserved for special modems            108H
  84. RESVD2:     DB    NO    ; Reserved for special modems            109H
  85. ;
  86. ;
  87. CLEAR:     DB    '*'    ; Clear screen character (ESC not needed)    10AH
  88. CLOCK:     DB    60    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  89.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  90. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  91.             ;   default time to send character in ter-
  92.             ;   minal mode file transfer for slow BBS
  93. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  94.             ;   default time for extra wait after CRLF
  95.             ;   in terminal mode file transfer
  96. NOFCOL:     DB    5    ; Number of directory columns shown        10EH
  97. TCHPUL:     DB    'T'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  98. ;.....
  99. ;
  100. ;
  101. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  102.             ;   mode (normally added by remote echo)
  103. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  104. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  105. IGNRCTL: DB    YES    ; Yes=CTL-chars above ^M not displayed        113H
  106. ;.....
  107. ;
  108. ;
  109. EXTCHR:     DB    '['-40H    ; ESC = preceeds local control character    114H
  110. EXITCHR: DB    'E'    ; Exit character                115H
  111. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  112. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  113. LOGCHR:     DB    'L'    ; Send logon                    118H
  114. LSTCHR:     DB    'P'    ; Toggle printer                119H
  115. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  116. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  117. CLEARS:     DB    'Z'    ; Clears screen, terminal mode            11CH
  118. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  119. NODTR:     DB    NO    ; YES if no DTR and need ATH0 to disconnect    11EH
  120. ;.....
  121. ;
  122. ;
  123. ; Handles in/out ports for data and status
  124. ;
  125. I$MDCTL1: MVI    A,10H        ; Register 0, reset interrupts        11FH
  126.       OUT    MDCTL1        ;                    121H
  127.       IN    MDCTL1        ; Get the status            123H
  128.       RET            ;                    125H
  129.       DB    0,0,0        ; Spares if needed            126H
  130. ;
  131. I$MDTXE:  MVI    A,11H        ; For read register 1            129H
  132.       OUT    MDCTL1        ;                    12BH
  133.       IN    MDCTL1        ; Get status of read register 1     12DH
  134.       RET            ;                    12FH
  135.       DB    0,0,0        ;                    130H
  136. ;
  137. I$MDDATP: IN    MDDATP        ;                    133H
  138.       RET            ;                    135H
  139.       DB    0,0,0,0,0,0,0    ; Spares if needed            136H
  140. ;
  141. O$MDDATP: OUT    MDDATP        ;                    13DH
  142.       RET            ; OUT modem data port            13FH
  143.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  144. ;.....
  145. ;
  146. ;
  147. A$MDRCV:  ANI    MDRCV        ;                    147H
  148.       RET            ;                    149H
  149. ;
  150. C$MDRCV:  CPI    MDRCV        ;                    14AH
  151.       RET            ;                    14CH
  152. ;
  153. A$MDSND:  ANI    MDSND        ;                    14DH
  154.       RET            ;                    14FH
  155. ;
  156. C$MDSND:  CPI    MDSND        ;                    150H
  157.       RET            ;                    152H
  158. ;
  159. A$MDTXE:  ANI    MDTXE        ;                    153H
  160.       RET            ;                    155H
  161. ;
  162. C$MDTXE:  CPI    MDTXE        ;                    156H
  163.       RET            ;                    158H
  164. ;.....
  165. ;
  166. ;
  167. ; Special exit vector, used by some computers to reset interrupt vectors
  168. ;
  169. J$EXITVEC:RET            ;                    159H
  170.       DB    0,0        ;                    15AH
  171. ;.....
  172. ;
  173. ;
  174. ; Jump vectors needed by each overlay
  175. ;
  176. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  177. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  178. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  179. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  180. ;.....
  181. ;
  182. ;
  183. ; "AT" command strings, can be replaced in individual overlay if needed
  184. ;
  185. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  186. J$STRNG1: DS    3        ; 2400 bps "AT" string            16BH
  187. ;
  188. ;
  189. ; Next fourteen lines should not be changed by user overlay as these go
  190. ; to specific locations in the main program, not in the overlay.
  191. ;
  192. ;
  193. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  194. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  195. J$DIAL:      DS    3        ; Start of dialing routine        174H
  196. J$DSCONT: DS    3        ; Terminates modem use            177H
  197. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  198. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  199. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  200. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  201. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  202. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  203. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  204. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  205. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  206. J$BREAK:  JMP    SENDBRK        ; Break routine             195H
  207. J$NEW2:      DB    0,0,0        ; For future needs            198H
  208. ;.....
  209. ;
  210. ;
  211. ; For 2400 bps auto-stepdown units
  212. ;
  213. MANUAL:      DB    0        ; For manual selection flag        19BH
  214. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  215. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  216. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  217. ;.....
  218. ;
  219. ;
  220. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  221. ;
  222. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  223.       DB    'Version for Dynabyte Monarch, modem port 0BDH'    ;    1AAH
  224.       DB    '04H',CR,LF,0
  225.       RET
  226. ;.....
  227. ;
  228. ;
  229. ;-----------------------------------------------------------------------
  230. ;
  231. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  232. ;     end of your last routine should terminate by 0400H (601 bytes
  233. ;     available after start of SYSVER).
  234. ;
  235. ;-----------------------------------------------------------------------
  236. ;
  237. ; You can put in a message at this location which can be called up with
  238. ; (special character-L).  You can put in several lines.  End with a 0.
  239. ;
  240. LOGON:    DB    'Greetings from a Dynabylt user...',CR,LF,0
  241. ;
  242. ;-----------------------------------------------------------------------
  243. ;
  244. ; This routine sets a 300 ms break tone
  245. ;
  246. SENDBRK:
  247.     MVI    A,5
  248.     OUT    MDCTL1        ; Send to the status port
  249.     MVI    A,0F8H        ; DTR normal, send break tone
  250.     JMP    GOODBYE1    ; Go send the break tone
  251. ;.....
  252. ;
  253. ;
  254. ; This routine sets DTR low for 300 ms to disconnect the modem.
  255. ;
  256. GOODBYE:
  257.     MVI    A,5
  258.     OUT    MDCTL1        ; Send to the status port
  259.     MVI    A,78H        ; Turn off DTR and send break tone
  260. ;
  261. GOODBYE1:
  262.     OUT    MDCTL1
  263.     MVI    B,3        ; Delay 300 ms
  264.     CALL    J$TIMER
  265.     MVI    A,5
  266.     OUT    MDCTL1
  267.     MVI    A,0E8H        ; Restore normal, 8 bits, DTR on, etc.
  268.     OUT    MDCTL1
  269.     RET
  270. ;.....
  271. ;
  272. ;
  273. ; Dynabye initialization -- sets CTC timer 83H for send and receive
  274. ; baudrate.
  275. ;
  276. INITMOD:
  277.     MVI    A,00H        ; Select register
  278.     OUT    MDCTL1
  279.     MVI    A,18H        ; Throw out of mode
  280.     OUT    MDCTL1
  281.     MVI    A,04H        ; Select register
  282.     OUT    MDCTL1
  283.     MVI    A,44H        ; Set ASCII parameters (44=1, 4C=2)
  284.     OUT    MDCTL1
  285.     MVI    A,03H        ; Select register
  286.     OUT    MDCTL1
  287.     MVI    A,0C1H        ; Enable receive
  288.     OUT    MDCTL1
  289.     MVI    A,05H        ; Select register
  290.     OUT    MDCTL1
  291.     MVI    A,0EAH        ; Enable send, DTR, RTS
  292.     OUT    MDCTL1
  293. ;
  294.     LDA    MSPEED        ; Get the selected value
  295.     CPI    1        ; 300 bps
  296.     JZ    OK300
  297.     CPI    5        ; 1200 bps
  298.     JZ    OK1200
  299.     CPI    6        ; 2400 bps
  300.     JZ    OK2400
  301.     CPI    8        ; 9600 bps
  302.     JZ    OK9600
  303.     JMP    STUPR1        ; Else ask what is wanted
  304. ;.....
  305. ;
  306. ;
  307. ; Sets the modem speed via the SET command.
  308. ;
  309. ;
  310. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  311.     JNC    STUPR2
  312. ;
  313. STUPR1:    CALL    J$ILPRT
  314.     DB    'Input Baud Rate (300, 1200, 2400, 9600): ',0
  315.     LXI    D,BAUDBUF    ; Point to new input buffer
  316.     CALL    J$INBUF
  317.     CALL    J$CRLF
  318.     LXI    D,BAUDBUF+2
  319. ;
  320. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  321.     DB    '300',0
  322.     JNC    OK300        ; Go if got match
  323.     CALL    J$INLNCP
  324.     DB    '1200',0
  325.     JNC    OK1200
  326.     CALL    J$INLNCP
  327.     DB    '2400',0
  328.     JNC    OK2400
  329.     CALL    J$INLNCP
  330.     DB    '9600',0
  331.     JNC    OK9600
  332.     CALL    J$ILPRT        ; All matches failed, tell operator
  333.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  334.     JMP    STUPR1        ; Try again
  335. ;
  336. OK300:    MVI    A,1        ; MSPEED 300 baud value
  337.     MVI    B,BD300
  338.     JMP    LOADBD
  339. ;
  340. OK1200:    MVI    A,5
  341.     MVI    B,BD1200
  342.     JMP    LOADBD
  343. ;
  344. OK2400:    XRA    A
  345.     STA    MANUAL        ; Reset to maximum auto-speed
  346.     MVI    A,6
  347.     MVI    B,BD2400
  348.     JMP    LOADBD
  349. ;
  350. OK9600:    MVI    A,8
  351.     MVI    B,BD9600
  352. ;
  353. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  354.     MOV    A,B        ; Get baudrate byte
  355.     OUT    BRPORT        ; Send to 'ctc' for new baudrate
  356.     RET
  357. ;.....
  358. ;
  359. ;
  360. ; TABLE OF BAUDRATE PARAMETERS
  361. ;
  362. BD300    EQU    5
  363. BD1200    EQU    7
  364. BD2400    EQU    10
  365. BD9600    EQU    14
  366. ;
  367. BAUDBUF:DB    10,0,0,0,0,0
  368.     DB    0,0,0,0,0,0
  369. ;
  370. ;                   end
  371. ;-----------------------------------------------------------------------
  372. ;
  373. ; NOTE: Must terminate prior to 0400H
  374. ;
  375.     END
  376.