home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / HAMRADIO / MORSETXT.LBR / MORSETXT.AZM / MORSETXT.ASM
Assembly Source File  |  2000-06-30  |  51KB  |  2,365 lines
  1. .he MORSETXT.* v1.0     de WB1HKU/6 --CHR$(13)24AUG85         -#-
  2. .po2
  3. ;
  4. ;Assemble with ASM.
  5. ;
  6. BDOS    equ    5
  7. LF    equ    10
  8. CR    equ    13
  9. FCB    equ    5Ch
  10. DMA    equ    80h
  11. FX    equ    0FFh
  12. FOXES    equ    0FFFFh
  13. ;
  14. CLOCK    equ    40    ;CPU clockspeed in hundreds of kilohertz
  15. ;
  16. FALSE    equ    0
  17. TRUE    equ    NOT FALSE
  18. ;
  19. ;
  20. CONDBUG    equ    FALSE    ;assembles in debugging tracers for
  21.             ;console interactions if true, 
  22.             ;including all ditrate controls
  23. BIGDBUG    equ    FALSE    ;assembles in debugging tracers for
  24.             ;wildcard filename expansions and 
  25.             ;command-line controls if true
  26. DEBUG    equ    FALSE    ;assembles in debugging tracers for
  27.             ;single-file buffer refresh if true
  28. ;
  29. NODBUG    equ    NOT (CONDBUG OR BIGDBUG OR DEBUG)
  30. ;
  31. ;tracing messages mess up your screen, but I needed 'em...
  32. ;
  33. ;
  34. PORTAS    equ    84h    ;console status and control port
  35. PORTAD    equ    80h    ;console data port
  36. CINMSK    equ    1    ;character-is-input mask
  37. CINMCH    equ    1    ;character-is-input match
  38. PORTBS    equ    8Ch    ;port B status and control port
  39. PORTBD    equ    88h    ;port B data port (not presently used)
  40. ;
  41. RECORD    equ    4000h    ;start-point of read-in records
  42.             ;--must be on a page boundary
  43. ;
  44. ;
  45.     org    100h
  46. ;
  47.     call    ILPRT
  48. ;
  49. ;Sign on at the console. 
  50. ;
  51. ;             0123456789012345678901234567890123
  52. ;
  53.     db    CR,LF,9,'***----MORSETXT.COM v1.0-----***'
  54.     db    CR,LF,9,'*                              *'
  55.     db    CR,LF,9,'*   International Morse Code   *'
  56.     db    CR,LF,9,'*  transmitter for text files  *'
  57.     db    CR,LF,9,'*  Ampro Little Board version  *'
  58.     db    CR,LF,9,'*    via Port B''s HSO line     *'
  59.     db    CR,LF,9,'*                              *'
  60.     db    CR,LF,9,'***-- --CHR$(13)23AUG85------***'
  61.     db    CR,LF,LF,0,1Ah
  62. ;
  63. ;
  64.     lxi    h,0
  65.     dad    sp
  66.     shld    STAKS
  67.     lxi    sp,STAKS
  68.     call    MULTD    ;Correct delay constant for clockrate.
  69.     call    START    ;Now earn your disk space.
  70. EXIT:    lhld    STAKS
  71.     sphl
  72.     ret
  73. ;
  74. ;These storage cells are down here where it's easy to get to
  75. ;them with DDT. For ROMming, copy 'em up back, in RAM, and
  76. ;work on 'em there.
  77. ;
  78. DELCON:    db    0,0    ;32-bit value stored in byte-serial
  79.     db    4,0A6h    ;form. Delay constant for 0.1 wpm
  80.             ;when running a Z80 at 0.1 MHz. This
  81.             ;value is adjusted for declared
  82.             ;clockrate in the first routine 
  83.             ;called.
  84. DITCNT:    ds    2    ;the key delay variable.
  85. ;
  86. DAHCNT:    ds    2    ;no longer directly used by program.
  87. ;
  88. CLKBYT:    db    CLOCK    ;clock frequency in 100 KHz increments
  89. WSPACE:    db    0    ;if true, space out the characters.
  90. XTNFLG:    db    0    ;if true, only ARRL characters. 
  91. PRETTY:    db    0    ;if 0, excess period becomes <bt>, and
  92.             ;only one <space> in a row is sent.
  93. ;
  94. ;WSPACE, XTNFLG and PRETTY are copied into WSPBYT, XTNBYT and
  95. ; PRYBYT just before each command line's arguments are brought
  96. ; down. Thus (last-minute change) the defaults may be set by
  97. ; overlay.
  98. ;
  99. KEY:    jmp    KEYR
  100. UNKEY:    jmp    UNKEYR     ;Hooks for the three hardware-dependent
  101. CONSEN:    jmp    CSEN    ;routines, allowing for overlays.
  102. SEIKON:    jmp    CONSAY
  103. ;
  104. ;These are the hardware-specific sending routines.
  105. ;As written, KEYSTB works with the Ampro's DART.
  106. ;The callers, KEY and UNKEY, differ in that KEY
  107. ;calls with A=0FFh, while UNKEY calls with A=0.
  108. ;The Ampro initialization routines set the HSO line
  109. ; on serial-B, so this routine-set resets that line
  110. ;in order to key the oscillator.
  111. ;Don't trash anything but A, and be as quick as you
  112. ;can. The massive delays in KEY and UNKEY will mask
  113. ;a lot of fixed delay, but you want to be able to 
  114. ;really hear an honest 45 wpm, don't you?  
  115. ;
  116. ;
  117. KEYR:    mvi    a,FX    ;delay-count is in hl
  118.     call    KEYSTB
  119. KELP:    nop! nop! nop! nop! nop    ;If you mess with these
  120.     nop! nop! nop! nop! nop    ;delays, you'll have to
  121.     nop! nop! nop! nop! nop    ;retune the master delay
  122.     nop! nop! nop! nop! nop    ;count. Try to put it in
  123.     nop! nop! nop! nop! nop    ;the same general range.
  124.     nop! nop         ;Otherwise, you'll run
  125.     mov    a,a        ;out of arithmetic range
  126.     dcx    h        ;one way or the other.
  127.     mov    a,l
  128.     ora    h
  129.     jnz    KELP
  130.     ret
  131. ;
  132. UNKEYR:    xra    a    ;ditto
  133.     call    KEYSTB
  134. UKELP:    nop! nop! nop! nop! nop
  135.     nop! nop! nop! nop! nop
  136.     nop! nop! nop! nop! nop
  137.     nop! nop! nop! nop! nop
  138.     nop! nop! nop! nop! nop
  139.     nop! nop
  140.     mov    a,a
  141.     dcx    h
  142.     mov    a,l
  143.     ora    h
  144.     jnz    UKELP
  145.     ret
  146. ;
  147. KEYSTB:    cma
  148.     push    psw
  149.     mvi    a,5
  150.     out    PORTBS
  151.     pop    psw
  152.     push    b
  153.     mvi    b,68h
  154.     ani    2
  155.     add    b
  156.     out    PORTBS
  157.     pop    b
  158.     ret
  159. ;
  160. ;This is the direct port status call. It is called by
  161. ; ILMORS and GOCHAR on their way back from sending a
  162. ; character. If CON: has a freshly typed character,
  163. ; go play with it. Otherwise, as you were.   
  164. ;
  165. CSEN:    in    PORTAS    ;console port
  166.     ani    CINMSK
  167.     cpi    CINMCH    ;Here's where we break off if
  168.     cz    SEIKON    ;CON: is sending.
  169.     ret
  170. ;
  171. ;
  172. ;I trust this is enough room for whatever you have to do.
  173. ; 
  174.     org    400h
  175. ;
  176. START:    lxi    h,200    ;wpm * 10
  177.     shld    RESULT
  178.     call    CONVRT    ;set up a 20 wpm coderate
  179. ;
  180.     IF    DEBUG
  181.     ;
  182.     call    ILPRT
  183.     db    CR,LF,'default baudrate set.',0
  184.     ;
  185.     ENDIF    ;DEBUG
  186. ;
  187. ;
  188. ;Copy the single filename, if there is one, into NAMBUF
  189. ;and cap it with a <crlf> and an EOF, so we've got 
  190. ;someplace to go if we get ^X'd out of the test string.
  191. ;
  192. COPYUP:    lxi    h,DMA
  193.     mvi    b,0    ;pick up the extended-argument
  194.     mov    c,m    ;bytecount left by CCP
  195.     inx    h
  196.     inx    h    ;skip over the inevitable space
  197.     dcr    c    ;...and knock it off the count.
  198.     lxi    d,NAMBUF
  199.     call    M2D4B
  200.     mvi    a,CR
  201.     stax    d
  202.     inx    d
  203.     mvi    a,LF
  204.     stax    d
  205.     inx    d
  206.     mvi    a,1Ah
  207.     stax    d
  208. ;
  209.     IF    DEBUG
  210.     ;
  211.     call    ILPRT
  212.     db    CR,LF,'Entry string copied up.',0
  213.     ;
  214.     ENDIF    ;DEBUG
  215. ;
  216. ;
  217. ;Send 'test' out at the morse line. With no sending-rate yet
  218. ; sought, that'll be at the default rate. 
  219. ;
  220.     lhld    DITCNT    ;DAHCNT = 3 * DITCNT
  221.     push    h
  222.     pop    b
  223.     dad    h
  224.     dad    b
  225.     shld    DAHCNT
  226. ;
  227.     IF    DEBUG
  228.     ;
  229.     call    ILPRT
  230.     db    CR,LF,'DAHCNT expanded.',0
  231.     ;
  232.     ENDIF    ;DEBUG
  233. ;
  234.     lda    FCB+1
  235.     cpi    '$'
  236.     jz    INLIST
  237. ;
  238.     IF    DEBUG
  239.     ;
  240.     call    ILPRT
  241.     db    CR,LF,'call ILMORS',0
  242.     ;
  243.     ENDIF    ;DEBUG
  244. ;
  245.     call    ILMORS
  246.     db    'TEST DE WB1HKU/6 @',0
  247. ;
  248.     IF    DEBUG
  249.     ;
  250.     call    ILPRT
  251.     db    CR,LF,'TEST de WB1HKU/6 *',CR,LF,0
  252.     ;
  253.     ENDIF    ;DEBUG
  254. ;
  255. ;Empty argument string, or just hashes or query? Then the user
  256. ; was just kerchunking. Go home.
  257. ;
  258.     lda    FCB+1    ;all the well-known ways to
  259.     cpi    ' '    ;tell a program "just kidding".
  260.     rz
  261.     cpi    '/'
  262.     rz
  263.     cpi    '?'
  264.     jnz    BIZNES
  265.     lda    FCB+2
  266.     cpi    ' '
  267.     rz
  268.     cpi    '/'
  269.     jnz    BIZNES
  270.     lda    FCB+3
  271.     cpi    ' '
  272.     rz
  273. ;
  274.     IF    DEBUG
  275.     ;
  276.     call    ILPRT
  277.     db    CR,LF,'BIZNESS',0
  278.     ;
  279.     ENDIF    ;DEBUG
  280. ;
  281. ;
  282. ;Nope, the user means  business.  Get to work.  First,  we've
  283. ;already gotten the opening parameters  up out of harm's way.
  284. ;Now copy it right back down, but formatted. Clumsy, you say?
  285. ;Maybe, but it lets you use (rather than send) a SUBfile from
  286. ;the console, without restart.
  287. ;
  288. BIZNES:    mvi    a,0h        ;the filename isn't preformatted...
  289.     sta    USEMOV        ;use M2D4BF to move it down again.
  290.  
  291. ;
  292. ;At this point  there is a list  of one or more filenames  in
  293. ;the names buffer at NAMBUF, perhaps with trailing arguments,
  294. ;each line demarcated by <crlf>, the list terminated with ^Z. 
  295. ;Now,  one at a time,  those filenames  are brought down into
  296. ;the FCB at 5Ch,  brought in and sent.  Any  command switches
  297. ;in the line  are asserted.  Any not present  are deasserted.
  298. ;The ditrate  remains  the same  unless  there is  a  numeric
  299. ;argument in the line.
  300. ;
  301. ;Go get the first filename. 
  302. ;
  303. SETUP:    lhld    NAMPTR    ;if that's a control Z you've got
  304. UPEND:    mov    a,m    ;there, I'm going home.
  305.     ani    7Fh
  306.     cpi    1Ah    ;(Will never be seen if '&' switch
  307.     rz        ;is used.)
  308.     cpi    CR
  309.     jz    UPSET
  310.     cpi    ' '
  311.     jz    UPSET
  312.     cpi    LF
  313.     jz    UPSET
  314.     cpi    '$'
  315.     jz    INLIST
  316.     cpi    '!'
  317.     jnz    NOKEY
  318.     inx    h
  319.     shld    NAMPTR
  320.     call    MORKY
  321.     jmp    SETUP
  322. NOKEY:    cpi    '&'    ;Ampersand means, loop forever.
  323.     jnz    NOTUPS    ;Sorry, you can't use that as the
  324.             ;first character in a filename.
  325.     lxi    h,NAMBUF
  326.     shld    NAMPTR
  327.     call    CONSEN    ;Lockup-proofing for the idiots.
  328.     jmp    SETUP
  329. UPSET:    inx    h
  330.     jmp    UPEND
  331. ;
  332. NOTUPS:    inx    h    ;If that's a letter between A and P
  333.     mov    a,m    ;inclusive, and what follows it is
  334.     dcx    h    ;a colon, it's a drive spec. Put it
  335.     cpi    ':'    ;in and pray.
  336.     jnz    NOTSPE    ;Either way, HL ends up pointing at
  337.     mov    a,m    ;the first letter of the filename.
  338.     inx    h
  339.     inx    h
  340.     ani    5Fh
  341.     sui    40h
  342.     jc    NOTSPE
  343.     cpi    17
  344.     jnc    NOTSPE
  345.     sta    FCB    ;Never mind that null, son, we've
  346.     jmp    SPECD    ;already got our drivespec.
  347. ;
  348. NOTSPE:    xra    a    ;No? Okay, then, go ahead and 
  349.     sta    FCB    ;zero out the drivespec.
  350. ;
  351. ; +++ COPY DOWN THE FIRST LINE'S FILENAME.TYP +++
  352. ;
  353. SPECD:    lxi    d,FCB+1
  354.     mvi    c,11
  355.     lda    USEMOV
  356.     ora    a
  357.     jz    OTHRMV    ;If USEMOV is NOT ZERO, use the
  358.     call    M2D4B    ;regular filename mover, well-behaved 
  359.     jmp    M2OVDN    ;If USEMOV is ZERO, use the
  360. OTHRMV:    call    M2D4BF    ;special filename mover, pads names
  361.             ;and ambiguities (frightening thought,
  362.             ;eh? They call that "fashion".)
  363. M2OVDN:    shld    NAMPTR    ;Now store the pointer for next time,
  364.             ;suitably advanced.
  365.  
  366. ;
  367. ;First, arguments are brought down from NAMBUF and plugged
  368. ; in as initial parameters. We'll stop trying when we hit
  369. ; the <crlf>.
  370. ;
  371. GETARG:    lda    WSPACE    ;Turn 'em to default. This way, if we
  372.     sta    WSPBYT    ;toggle, MAYBE it's to assert.
  373.     lda    XTNFLG
  374.     sta    XTNBYT
  375.     lda    PRETTY
  376.     sta    PRYBYT
  377.     lhld    NAMPTR
  378. GARGLP:    mov    a,m
  379.     ani    7Fh
  380.     cpi    1Ah
  381.     rz
  382.     cpi    ' '
  383.     jz    GARGSP
  384. ;
  385. ;Inspect argument for numbers.
  386. ;
  387.     cpi    '0'    ;This means '$', bang will be
  388.     jc    GARGDN    ;noticed as soon as the file is
  389.             ;sent.
  390.     cpi    ':'
  391.     jc    GARGNM
  392. ;
  393.     ani    5Fh    ;No numbers? Mask for letters.
  394.     cpi    'W'    ;Any letter switches not found
  395.     cz    WTOG    ;on a submitted line are presumed
  396.     cpi    'X'    ;deasserted.
  397.     cz    XTOG
  398.     cpi    'P'
  399.     cz    PTOG
  400.     jmp    GARGSP
  401. ;
  402. ;Found any? Then pointer is at the most-significant one.
  403. ; Beginning there, convert into hex. The numbers are the
  404. ; nominal desired words-per-minute rate times 10. Put 'em
  405. ; into the furnace for CONVRT and DIVI to work on.
  406. ;
  407. ;These subsidiary labels sure read like Orkish, don't they?
  408. ; Or R'Lyehn...
  409. ;
  410. GARGNM:    call    ILPRT
  411.     db    CR,LF,'[No','w'+80h,0
  412.     lxi    b,0        ;prepare count
  413.     lxi    d,CONBUF+2    ;point for copying
  414. GRGNLP:    mov    a,m    ;hl points into NAMBUF
  415.     push    psw
  416.     call    PCHAR
  417.     pop    psw
  418.     stax    d    ;de points into CONBUF
  419.     inr    c    ;count the passed byte
  420.     mov    a,c    ;...but don't allow more
  421.     cpi    16    ;than 16. You don't have to
  422.     jz    GRGNDN    ;type silly. BDOS'll getcha.
  423.     inx    d    ;Bump the pointers and check
  424. GRS:    inx    h     ;the next byte: number?
  425.     mov    a,m    ;I'll do you a favor: any
  426.     cpi    '.'    ;dots, we'll simply skip.
  427.     jz    GRS    ;Anything else, though, and
  428.     cpi    '0'    ;that's it for the number.  
  429.     jc    GRGNDN
  430.     cpi    ':'
  431.     jc    GRGNLP
  432. GRGNDN:    mov    a,c
  433.     sta    CONBUF+1
  434.     push    h    
  435.     call    ASDEC
  436.     call    CONVRT
  437.     pop    h
  438.     call    ILPRT
  439.     db    '/1','0'+80h,'wpm.]',0
  440.     jmp    GARGLP
  441. ;
  442. GARGSP:    inx    h
  443.     jmp    GARGLP
  444. GARGDN:    shld    NAMPTR
  445.  
  446. ;
  447. ;Inspect filename for *.SUB. If so, pull it in, record
  448. ;by record, verbatim into NAMBUF.  If not, go test for
  449. ;wildcards.
  450. ;
  451. ISSUB:    lxi    h,FCB+9    
  452.     mov    a,m
  453.     cpi    'S'
  454.     jnz    NOTSUB    ;wildcard test next.
  455.     inx    h
  456.     mov    a,m
  457.     cpi    'U'
  458.     jnz    NOTSUB
  459.     inx    h
  460.     mov    a,m
  461.     cpi    'B'
  462.     jnz    NOTSUB
  463. ;
  464. ;It's a SUB file.
  465. ;
  466.     xra    a        ;We'll use M2D4BF to bring down
  467.     sta    USEMOV        ;virtual (unformatted) console
  468.                 ;input at SETUP. SUBfiles aren't
  469.                 ;formatted by CCP.
  470.     lxi    d,NAMBUF
  471.     mvi    c,1Ah    ;set DMA
  472.     call    BDOS
  473. ;
  474.     mvi    a,1Ah    ;Insert an end-of-list marker.
  475.     sta    NAMBUF    ;if nothing gets copied (empty
  476.             ;directory entry), we'll just
  477.             ;shut down on finding it. 
  478.     xra    a
  479.     sta    FCB+32
  480.     sta    FCB+12
  481.     lxi    d,FCB
  482.     mvi    c,0Fh    ;open file
  483.     call    BDOS
  484.     inr    a
  485.     jnz    SUBOPN
  486.     call    ILPRT
  487.     db    'BDOS can''t find that SUB file.',0
  488.     ret
  489. ;
  490. SUBOPN:    lxi    d,NAMBUF
  491.     shld    DMADR
  492. SBOPLP:    lxi    d,FCB
  493.     mvi    c,14h    ;read sequential
  494.     call    BDOS
  495.     ora    a
  496.     jz    SBOPDN
  497.     lhld    DMADR
  498.     lxi    b,80h
  499.     dad    b
  500.     shld    DMADR
  501.     xchg
  502.     mvi    c,1Ah    ;set DMA (80h up)
  503.     call    BDOS
  504.     jmp    SBOPLP
  505. ;
  506. SBOPDN:    lxi    h,NAMBUF
  507.     shld    NAMPTR    ;Reset the pointer to Go.
  508.     jmp    SETUP    ;go pull down the first line for use.
  509.             ;If you're clever, the first filetype
  510.             ;in your SUB file isn't SUB or some-
  511.             ;thing ambiguous... otherwise, we'll
  512.             ;just go around again until we do get
  513.             ;a file we can send.
  514. ;
  515. ;Inspect filename for '?'. Any? Then do search-for-first, then
  516. ; search-for-next, to collect all the filenames that match into
  517. ; a names buffer. The buffer will be capped with ^Z; when all
  518. ; the names are serviced, there'll be ^Z instead of a name, the 
  519. ; signal to go home.
  520. ;Of course, any ambiguous filename.typ will be expanded out right
  521. ; on top of anything you might have had in NAMBUF...
  522. ;
  523. ;If no '?', use the lone filename.typ into the filenames
  524. ; buffer and proceed.
  525. ;
  526. NOTSUB:    call    ISAMBG
  527.     jz    ISNOT    ;go open and send the file.
  528. ;
  529.     IF    BIGDBUG
  530.     ;
  531.     call    ILPRT
  532.     db    CR,LF,'Enter EXPAN.',0
  533.     ;
  534.     ENDIF    ;BIGDBUG
  535. ;
  536.     lxi    d,DMA
  537.     mvi    c,1Ah    ;set DMA address to 80h
  538.     call    BDOS
  539.     lxi    h,NAMBUF    ;reset the NAMBUF pointer here
  540.     shld    NAMPTR
  541. ;
  542. ;
  543. ;
  544. ;-------<EXPANSION MODULE>--------START
  545. ;
  546. EXPAN:    mvi    a,0FFh    ;pop the MOV flag --this stuff'll
  547.     sta    USEMOV    ;be preformatted when it's used.
  548.     xra    a
  549.     sta    FIRSTM    ;set the FIRST TIME flag
  550. ;
  551.     IF    BIGDBUG
  552.     ;
  553.     call    ILPRT
  554.     db    CR,LF,'FCB: ',CR,LF,0
  555.     mvi    a,8
  556.     sta    DMPCTR
  557.     lxi    h,FCB
  558.     call    DUMPR
  559.     call    ILPRT
  560.     db    CR,LF,'DRIVE CODE: ',0
  561.     lda    USRDRV
  562.     call    PHEX
  563.     call    ILPRT
  564.     db    CR,LF,'[SEARCH FOR FIRST] ',0
  565.     ;
  566.     ENDIF    ;BIGDBUG
  567. ;
  568.     lxi    d,FCB
  569.     mvi    c,11h    ;search for first
  570.     call    BDOS
  571. EXPLP:
  572. ;
  573.     IF    BIGDBUG
  574.     ;
  575.     sta    STASH
  576.     call    ILPRT
  577.     db    'result code: ',0
  578.     lda    STASH
  579.     call    PHEX
  580.     call    ILPRT
  581.     db    CR,LF,0
  582.     lda    STASH
  583.     ;
  584.     ENDIF    ;BIGDBUF
  585. ;
  586.     cpi    0FFh    ;FF? No more matches. We're done.
  587.     jz    EXPDUN
  588.     add    a    ;rotate returned code
  589.     add    a    ;to be an offset
  590.     add    a
  591.     add    a
  592.     add    a
  593.     mvi    d,0
  594.     mov    e,a
  595.     lxi    h,DMA+1    ;step across user number
  596.     dad    d    ;now points to directory entry
  597.     shld    STASHW    ;save a pointer copy for later
  598. ;
  599.     IF    BIGDBUG
  600.     ;
  601.     push h! push d! push b
  602.     push psw
  603.     mvi    a,0Eh
  604.     sta    DMPCTR
  605.     call    DUMPR
  606.     pop psw
  607.     pop b! pop d! pop h
  608.     ;
  609.     ENDIF    ;BIGDBUG
  610. ;
  611.     xchg
  612.     lhld    NAMPTR    ;first time, @ NAMBUF.
  613.     xchg        ;hl @ 80h+, de @ NAMBUF+
  614.     lda    FIRSTM    ;If this is the first time
  615.     ora    a    ;through, don't preface new
  616.     jz    SKIPCR    ;name with <crlf> or look 
  617.             ;for duplication of entry.
  618.     call    CHEK11    ;test for redundance
  619.     mov    a,b    ;Zero? Matches previous entry.
  620.     ora    a
  621.     jz    REDUND
  622. ;
  623.     IF    BIGDBUG
  624.     ;
  625.     call    ILPRT
  626.     db    '(not redundant) ',0
  627.     ;
  628.     ENDIF    ;BIGDBUG
  629. ;
  630.     xchg        ;hl @ last NAMBUF entry +1
  631.     mvi    m,CR    ;put in EOL marker
  632.     inx    h
  633.     mvi    m,LF
  634.     inx    h
  635.     shld    NAMPTR    ;advance the stored pointer now
  636.     xchg        ;put it back into de
  637. SKIPCR:    lhld    STASHW    ;rewind input pointer to start of name
  638.     lxi    b,11
  639.     call    M2D4B    ;NOW copy the filename up.
  640.     mvi    a,0FFh    ;And reset the flag: we're in
  641.     sta    FIRSTM    ;and running.
  642. ;
  643.     IF    BIGDBUG
  644.     ;
  645.     call    ILPRT
  646.     db    9,7,'-------<<<<< COPY >>>>-------',CR,LF,0
  647.     mvi    a,0Eh
  648.     sta    DMPCTR
  649.     lhld    NAMPTR
  650.     call    DUMPR    
  651.     call    BDWAIT
  652.     call    BDWAIT
  653.     ;
  654.     ENDIF    ;BIGDBUG
  655. ;
  656. REDUND:    lxi    d,FCB
  657.     mvi    c,12h    ;search for next
  658.     call    BDOS
  659. ;
  660.     IF    BIGDBUG
  661.     ;
  662.     call    ILPRT
  663.     db    CR,LF,'[SEARCH FOR NEXT]',0
  664.     ;
  665.     ENDIF    ;BIGDBUG
  666. ;
  667.     jmp    EXPLP
  668. ;
  669. EXPDUN:    lhld    NAMPTR    ;BDOS can't find any more matches.
  670.     lxi    d,11    ;Put a line-end <crlf> after the
  671.     dad    d    ;last entry and go on.
  672.     mvi    m,CR
  673.     inx    h
  674.     mvi    m,LF
  675.     inx    h
  676.     mvi    m,1Ah    ;cap it with EOF
  677.     lxi    h,NAMBUF
  678.     shld    NAMPTR    ;Reset the pointer to Go.
  679. ;
  680.     IF    BIGDBUG
  681.     ;
  682.     call    ILPRT
  683.     db    CR,LF,'EXPDUN. Now jmp SETUP.',CR,LF,0
  684.     ;
  685.     ENDIF    ;BIGDBUG
  686. ;
  687.     jmp    SETUP    ;Still inline. A return here would
  688.             ;be to EXIT. 'Course, it IS a
  689.             ;back-jump... Go pull down the first
  690.             ;line for use.
  691. ;
  692. ;11-character filenam.typ ambiguity test for 
  693. ;initial argument
  694. ;
  695. AMBIG:    lxi    b,11    ;c is counter, b is flag
  696.     mvi    a,'?'    ;Assuming that CCP put together
  697. AMBGLP:    cmp    m    ;this filename.typ, the only
  698.             ;ambiguous character is '?'.
  699.             ;If it came out of a console
  700.     jnz    NOAM    ;string or a SUBfile, though,
  701.     mov    b,a    ;the string may include '*'.
  702. NOAM:    inx    h    ;That'll have to be handled
  703.     dcr    c    ;gently, since it'll throw
  704.     jnz    AMBGLP    ;off the character count.
  705.     ret            
  706. ;
  707. ;Check two eleven character strings for duplication.
  708. ;On return, b = 0 if they match.
  709. ;On return, hl and de point once beyond their strings.
  710. ;
  711. CHEK11:    lxi    b,11    ;set up loop-counter and flag.
  712. CHK11L:    ldax    d    ;get byte from NAMBUF.
  713.     cmp    m    ;Match? Fall out if not: the name
  714.     jnz    CHKOUT    ;is not redundant.
  715.     inx    h    ;Keep looping. When c = 0, we'll
  716.     inx    d    ;blindly copy it into b, indicating
  717.     dcr    c    ;a true compare. If we fall out,
  718.     jnz    CHK11L    ;though, that'll be a nonzero
  719. CHKOUT:    mov    b,c    ;loopcount we copy into b.
  720.     xra    a
  721.     cmp    c
  722.     rz
  723. CHKOLP:    inx    h
  724.     inx    d
  725.     dcr    c
  726.     jnz    CHKOLP
  727.     ret
  728. ;
  729.     IF    BIGDBUG
  730.     ;
  731. BDWAIT:    push    h    ;This waitloop gives me time
  732.     push    psw    ;to see what the filename lines
  733.     lxi    h,0    ;are up to, without sending CQ
  734. BDWALP:    dcx    h    ;on the ^S key.
  735.     mov    a,l
  736.     ora    h
  737.     jnz    BDWALP
  738.     pop    psw
  739.     pop    h
  740.     ret
  741.     ;
  742.     ENDIF    ;BIGDBUG
  743. ;
  744. ;
  745. ;-------<EXPANSION MODULE>--------END
  746. ;
  747. ISNOT:
  748. ;
  749.     IF    BIGDBUG
  750.     ;
  751.     call    ILPRT
  752.     db    CR,LF,'Next file, according to NAMPTR: ',CR,LF,0
  753.     lhld    NAMPTR
  754.     lxi    b,-16    ;back it off to include present line
  755.     dad    b
  756.     mvi    a,0Eh    ;two lines, please.
  757.     sta    DMPCTR
  758.     call    DUMPR
  759.     ;
  760.     ENDIF    ;DEBUG
  761. ;
  762.     xra    a
  763.     sta    FCB+12    ;and et cetera
  764.     sta    FCB+32    ;and et cetera.
  765. ;
  766.     IF    BIGDBUG
  767.     ;
  768.     call    ILPRT
  769.     db    CR,LF,'Check this out. Did I fill out the '
  770.     db    'FCB okay?',CR,LF,7,0
  771.     mvi    a,8
  772.     sta    DMPCTR    ;I only wanna see one record, honest.
  773.     lxi    h,FCB
  774.     call    DUMPR
  775.     ;
  776.     ENDIF    ;BIGDBUG
  777. ;
  778.     lxi    d,FCB
  779.     mvi    c,0Fh    ;open file
  780.     call    BDOS
  781.     inr    a
  782.     jnz    ISOPEN
  783.     call    ILPRT
  784.     db    CR,LF,9,'BDO','S'+80h,'can''','t'+80h
  785.     db    'fin','d'+80h,'m','y'+80h,'file',':'+80h,0
  786.     jmp    WIMPER
  787. ;
  788. ;Pull the first two records of the file into the file buffer.
  789. ;From here until file end, program flow should be relatively
  790. ;linear unless pestered. At file end, it'll pull down the next
  791. ;line in NAMBUF and play with that.
  792. ;
  793. ISOPEN:    lxi    d,RECORD
  794.     mvi    c,1Ah    ;set DMA address
  795.     call    BDOS
  796.     lxi    d,FCB
  797.     mvi    c,14h    ;read sequential
  798.     call    BDOS
  799.     lxi    d,RECORD+80h
  800.     mvi    c,1Ah    ;set DMA up a record
  801.     call    BDOS
  802.     lxi    d,FCB
  803.     mvi    c,14h    ;read sequential
  804.     call    BDOS
  805. ;
  806. ; Set the record toggle, indicating that the second record was
  807. ; the last one loaded. Set the record pointer to the byte previous 
  808. ; to the first byte of the first record. Because of how we
  809. ; increment the pointer, that means setting it to the last byte
  810. ; of the records page.
  811. ;
  812.     mvi    a,FX
  813.     sta    RECTGL
  814.     lxi    h,RECORD+255
  815.     shld    RECPTR
  816.     xra    a    ;Reset the EXHAUST flag too.
  817.     sta    XHAUST
  818.     call    CRLF    ;Start a new screen line
  819. ;
  820.     call    LOOP    ;Now send the file.
  821.     jmp    SETUP    
  822. ;
  823. ;Loop.
  824. ;Advance the pointer. Ani 7Fh. Zero? Reset the high byte to 
  825. ; wrap around. Then test the record pointer.
  826. ;For this to work as is, the record buffers must be on even
  827. ; page boundaries. That's why I put 'em someplace up high,
  828. ; where I could define the edges in isolation.
  829. ;
  830. LOOP:    lhld    RECPTR    ;advance the character pointer here...
  831.     inr    l    ;but don't let it out of the page.
  832.     shld    RECPTR    ;store it immediately.
  833.     mov    a,l
  834.     ani    7Fh    ;Did we just walk across the border
  835.     jnz    INREC    ;into another record?
  836. ;
  837.     IF    DEBUG
  838.     ;
  839.     call    ILPRT
  840.     db    '7Fh hit.',8,8,8,8,8,8,8,8,LF,0
  841.     ;
  842.     ENDIF    ;DEBUG
  843. ;
  844. ;
  845. ;Ani 80h. Are the exposed bit and the record toggle now
  846. ; in the same state? Then set the record-exhausted flag, so
  847. ; it'll be noticed next time there's a sentence end.
  848. ;
  849.     lda    RECPTR    ;pick up lobyte of record pointer,
  850.     ani    80h    ; and mask. Now it's either 80h 
  851.     jz    NOFF    ; or 00. If it's 00, leave it. If
  852.     mvi    a,FX    ; it's 80h, turn it into 0FFh.
  853. NOFF:    lxi    h,RECTGL    ;repoint to the record-toggle
  854.     cmp    m    ;...and compare. Match? Then we just
  855.     jnz    INREC    ;walked into the last record loaded.
  856.     mvi    a,FX    ;That means the one we left is 
  857.     sta    XHAUST    ;exhausted. Flag for a refresher.
  858. ;
  859.     IF    DEBUG
  860.     ;
  861.     call    ILPRT
  862.     db    'XHAUST set.',8,8,8,8,8,8,8,8,8,8,8,LF,0
  863.     ;
  864.     ENDIF    ;DEBUG
  865. ;
  866. ;Get the character. EOF? We done.
  867. ;
  868. INREC:    lda    RECPTR
  869.     ani    7Fh
  870.     cpi    7Fh
  871.     jnz    SOKAY
  872. ;
  873. ;Test for emergency fetch. Pointer at end of record? 
  874. ; Record-exhausted flag raised? Then Thomas Hardy has struck. 
  875. ;Obtrusive or not, fetch the next record NOW.
  876. ;
  877. MRGNC:    lda    XHAUST
  878.     ora    a
  879.     jz    SOKAY
  880.     call    GETIT
  881. ;
  882. SOKAY:    lhld    RECPTR
  883.     mov    a,m
  884.     ani    7Fh    ;WS top bits drive it crazy.
  885.     sta    STASH
  886.     cpi    1Ah
  887.     rz
  888. ;
  889. ;Show it at the console.
  890. ;
  891.     mov    e,a
  892.     mvi    c,6
  893.     call    BDOS
  894. ;
  895. ; Is it a period? Then increment the period-count.
  896. ; Query? Ditto, then send.
  897. ; Bang? Ditto. 
  898. ; Semicolon? Ditto.
  899. ; Comma? Ditto. (I hate to do it, but it seems I write
  900. ; longer sentences than I thought. Even this might not
  901. ; be enough for Thomas Hardy texts.)
  902. ;
  903.     lda    STASH
  904.     cpi    '.'
  905.     jz    PERIOD
  906.     cpi    '?'
  907.     jz    PERIOD
  908.     cpi    '!'
  909.     jz    PERIOD
  910.     cpi    ';'
  911.     jz    PERIOD
  912.     cpi    ','
  913.     jnz    CNTPER
  914. PERIOD:    lda    PERCNT
  915.     inr    a
  916.     sta    PERCNT
  917. ;
  918.     IF    DEBUG
  919.     ;
  920.     call    ILPRT
  921.     db    'up PERCNT.',8,8,8,8,8,8,8,8,8,8,LF,0
  922.     ;
  923.     ENDIF    ;DEBUG
  924. ;
  925. ;
  926. ;  Then test the period count... two or more? Then reset
  927. ;   the period count to one, change the character-to-send
  928. ;   to double-dash (three periods sent as: . = =). If that
  929. ;   default flag is reset. (0=pretty it up. Else, don't get
  930. ;   cute.)
  931. ;
  932. CNTPER:    lda    PRYBYT
  933.     ora    a
  934.     lda    STASH
  935.     jnz    NOPER
  936. ;
  937.     lda    PERCNT
  938.     cpi    2
  939.     lda    STASH
  940.     jc    NOPER
  941.     cpi    '.'
  942.     jnz    NOPER
  943.     mvi    a,'='
  944.     sta    STASH
  945.     mvi    a,1
  946.     sta    PERCNT
  947.     lda    STASH
  948. ;
  949. ; Is it <lf>? Throw it away. <cr>? Turn it into a space.
  950. ;
  951. NOPER:    cpi    LF
  952.     jz    LOOP
  953.     cpi    CR
  954.     jnz    NOTCR
  955.     mvi    a,' '
  956.     sta    STASH
  957. ;
  958. ; Is it none of the above? Then reset the period-count.
  959. ;
  960. NOTCR:    lda    STASH
  961.     cpi    '.'
  962.     jz    NORST
  963.     cpi    '?'
  964.     jz    NORST
  965.     cpi    '!'
  966.     jz    NORST
  967.     cpi    '='
  968.     jz    NORST
  969.     xra    a
  970.     sta    PERCNT
  971.     lda    STASH
  972. ;
  973. ; Is it <space>?  Test the space-count. Zero? Then 
  974. ; send  a  seven-dit  period  of rest.  Otherwise,
  975. ; throw it away. This checking is to eliminate the
  976. ; lumpiness of word-spacing that otherwise results
  977. ; from sending a WordStar document-mode file.  The 
  978. ; spaces  still show up  on the screen,  they just 
  979. ; don't occupy time now.  Turning a  <cr> into one
  980. ; nominally guarantees an  interword space  in  WS
  981. ; wordwraps.
  982. ; Tabs get the same treatment.
  983. ; 
  984. NORST:    cpi    ' '
  985.     jz    ISP
  986.     cpi    9    ;tab
  987.     jnz    NSP
  988. ISP:    lda    PRYBYT
  989.     ora    a
  990.     jnz    NOPRET
  991.     lda    SPACNT
  992.     ora    a
  993.     jnz    LOOP
  994.     inr    a
  995.     sta    SPACNT
  996. NOPRET:    call    SPACE
  997.     jmp    LOOP
  998. ;
  999. ;Ampsersand, <es>, is handled as a special case,  because
  1000. ; of the timing. It is the only prosign that requires it.
  1001. ; This character is a holdout from Telegraph Morse. 
  1002. ;
  1003. NSP:    mov    e,a    ;stash it quick
  1004.     xra    a    ;reset space-count
  1005.     sta    SPACNT
  1006.     mov    a,e    ;get it back
  1007.     cpi    '&'    ;NOW the ampsersand...
  1008.     jnz    NES
  1009.     call    ES    ;jumps through to MORSER
  1010.     jmp    LOOP
  1011. ;
  1012. ;Here's the ARRL/full International Morse filter.
  1013. ;First, test: if XTNFLG = 0, we're running wide open.
  1014. ;No?  Then we gotta slog.  We gotta find out if  the character
  1015. ;is on the short list, and there's no simple mathematic test I
  1016. ;know for that.
  1017. ;
  1018. ;
  1019. NES:    sta    STASH    ;put character someplace safe
  1020.     lda    XTNBYT    ;now, about that flag...
  1021.     ora    a
  1022.     jz    GOCHAR    ;Zero? Never mind long involved test, then.
  1023.     lda    STASH    ;No? Okay, slog time. First, split things
  1024.     sui    41h    ;down the middle. No jump if it might be a
  1025.     jc    ISANUM    ;letter. Now mask off uppercasing. Z or
  1026.     ani    1Fh    ;below? Then it is a letter, otherwise it's
  1027.     cpi    1Ah    ;extended-set punctuation, which we don't
  1028.     jc    GOCHAR    ;want to send just now.
  1029.     jmp    OGO
  1030. ;
  1031. ISANUM:    lda    STASH    
  1032.     cpi    '?'    
  1033.     jz    GOCHAR    
  1034.     cpi    '='    
  1035.     jz    GOCHAR
  1036.     cpi    ':'
  1037.     jnc    OGO
  1038.     cpi    '+'    ;<ar>?
  1039.     jz    GOCHAR    
  1040.     cpi    '#'    ;<sk>?
  1041.     jz    GOCHAR
  1042.     cpi    ','    
  1043.     jz    GOCHAR    
  1044.     cpi    '.'    
  1045.     jz    GOCHAR    
  1046.     cpi    '/'
  1047.     jz    GOCHAR
  1048.     cpi    '0'
  1049.     jc    OGO
  1050. ;
  1051. GOCHAR:    lda    STASH    ;pick up the character...
  1052.     call    MORSER    ;send it out...
  1053.     call    CONSEN    ;now see if CON: said anything.
  1054. ;
  1055. OGO:    lda    PERCNT
  1056.     ora    a
  1057.     jz    LOOP
  1058.     lda    XHAUST
  1059.     ora    a
  1060.     jz    LOOP
  1061. ;
  1062.     IF    DEBUG
  1063.     ;
  1064.     call    ILPRT
  1065.     db    'found XHAUST.',8,8,8,8,8,8,8,8,8,8,8,8,8,LF,0
  1066.     ;
  1067.     ENDIF    ;DEBUG
  1068. ;
  1069.     call    GETIT
  1070. ;
  1071.     jmp    LOOP
  1072. ;
  1073. ;Look up the character in the table. Each table entry is
  1074. ; two bytes, a baud-count nibble plus up to the remainder
  1075. ; of two bytes to be shifted rightwards out the door. 
  1076. ; The character symbols algorithm is from a message keyer
  1077. ; program in 73 by VE3CWY, originally written for the 
  1078. ; CDP1802, which I used in the Morse-code readout for TSCRT.
  1079. ;
  1080. MORSER:    lxi    d,TABLE    ;character brought in in a
  1081.     mvi    h,0
  1082.     mov    l,a    ;character into hl
  1083.     dad    h    ;shift it left
  1084.     dad    d    ;add in the table base
  1085.     mov    e,m    ;pick up lobyte
  1086.     inx    h
  1087.     mov    d,m    ;pick up hibyte
  1088.     mvi    a,FX
  1089.     cmp    d
  1090.     jnz    OK    ;empty entry = foxes, 0FFFFh . 
  1091.     cmp    e
  1092.     jnz    OK
  1093.     ret
  1094. OK:    call    IAMBIC
  1095.     ret
  1096. ;
  1097. SPACE:    lda    SPACNT
  1098.     dcr    a    ;Including what DIT or DAH and IAMB
  1099.     jz    NUTHRS    ;have already provided, provide        
  1100.     call    DAHSP    ;seven dit-counts of unkeyed time
  1101.             ;between words. If WSPACE is true,
  1102. NUTHRS:    call    DAHSP    ;twice that. It's handled this
  1103.     lhld    DITCNT    ;way because 16 bits of delay can     
  1104.     call    UNKEY   ;only be so long, and there might 
  1105.     lda    WSPBYT  ;otherwise be rollover irregularities 
  1106.     ora    a         ;at slow speeds. If this is an
  1107.     rz        ;additional space, send the whole
  1108.     lda    SPACNT    ;thing from here... nobody began it
  1109.     dcr    a    ;for us.
  1110.     jz    NUTHRW
  1111.     call    DAHSP
  1112. NUTHRW:    call    DAHSP
  1113.     lhld    DITCNT
  1114.     call    UNKEY
  1115.     ret
  1116. ;
  1117. DAHSP:    lhld    DITCNT
  1118.     call    UNKEY
  1119.     lhld    DITCNT
  1120.     call    UNKEY
  1121.     lhld    DITCNT
  1122.     call    UNKEY
  1123.     ret
  1124. ;
  1125. ES:    lhld    DITCNT
  1126.     call    KEY
  1127.     lhld    DITCNT
  1128.     call    UNKEY
  1129.     lhld    DITCNT
  1130.     call    UNKEY
  1131.     mvi    a,'S'
  1132.     sta    STASH
  1133.     jmp    MORSER
  1134. ;
  1135. ;One element at a time, shift the bits right and out.
  1136. ; A hi is a dah, a lo is a dit. Each is followed by
  1137. ; a dit of quiet. The character is followed by a dah
  1138. ; of quiet, double that if WhiteSPACE is set.
  1139. ;
  1140. IAMBIC:    mov    a,d
  1141.     cpi    FX
  1142.     jnz    BIGGIE
  1143.     mov    a,e
  1144. BIGGIE:    rrc    ;highest nibl is the length-count
  1145.     rrc    ;isolate it and stash it in counter.
  1146.     rrc
  1147.     rrc
  1148.     ani    0Fh
  1149.     mov    b,a
  1150. IAMLUP:    mov    a,e    ;now rightshift-with-carry loop...
  1151.     rrc        ;if cy=0, DIT. if cy=1, DAH.
  1152.     mov    e,a
  1153.     jnc    DODIT
  1154. DODAH:    call    DAH
  1155.     jmp    IAMDEC
  1156. DODIT:    call    DIT
  1157. IAMDEC:    dcr    b    ;countdown: done?
  1158.     jnz    IAMLUP
  1159.     lhld    DITCNT    ;two dits of additional space.
  1160.     call    UNKEY    ;the third, DIT or DAH provided.
  1161.     lhld    DITCNT
  1162.     call    UNKEY
  1163.     lda    WSPBYT
  1164.     ora    a
  1165.     rz    
  1166.     call    DAHSP
  1167.     ret
  1168. ;
  1169. DIT:    lhld    DITCNT    ;ditcount
  1170.     call    KEY
  1171.     lhld    DITCNT
  1172.     call    UNKEY
  1173.     ret
  1174. ;
  1175. DAH:    lhld    DITCNT
  1176.     call    KEY    ;All of this boring duplication,
  1177.     lhld    DITCNT
  1178.     call    KEY    ;just to allow for a large DITCNT... 
  1179.     lhld    DITCNT
  1180.     call    KEY    ;
  1181.     lhld    DITCNT
  1182.     call    UNKEY
  1183.     ret
  1184. ;-----------------------------
  1185. ;
  1186. ; filename ambiguity test.
  1187. ; On return, zero flag is SET if there are no question-
  1188. ; marks or asterisks in the filename.
  1189. ; Uses all but de.
  1190. ;
  1191. ISAMBG:    lxi    h,FCB+1
  1192.     mvi    b,11
  1193.     mvi    c,0
  1194. ISALP:    mov    a,m
  1195.     cpi    '*'
  1196.     jz    YESAM
  1197.     cpi    '?'
  1198.     jnz    NOISA
  1199. YESAM:    inr    c
  1200. NOISA:    inx    h
  1201.     dcr    b
  1202.     jnz    ISALP
  1203.     xra    a
  1204.     cmp    c
  1205.     ret
  1206. ;
  1207. ;Go find out what CON: has to say.
  1208. ;
  1209. CONSAY:    push h! push d! push b
  1210.     call    CMENU
  1211.     call    FLOOSH
  1212.     pop b! pop d! pop h
  1213.     ret
  1214. ;
  1215. FLOOSH:    mvi    c,6    ;use direct console calls to
  1216.     mvi    e,FX    ;flush the CON: port of any
  1217.     call    BDOS    ;backed-up characters
  1218.     ani    7Fh
  1219.     ora    a
  1220.     jnz    FLOOSH
  1221.     ret
  1222. ;
  1223. CRLF:    push h! push d! push b
  1224.     push    psw
  1225.     mvi    e,CR
  1226.     mvi    c,6
  1227.     call    BDOS
  1228.     mvi    e,LF
  1229.     mvi    c,6
  1230.     call    BDOS
  1231.     pop    psw
  1232.     pop b! pop d! pop h
  1233.     ret
  1234. ;
  1235. CMENU:    mvi    c,6    ;direct-console-input BDOS call.
  1236.     mvi    e,FX
  1237.     call    BDOS
  1238.     ani    7Fh
  1239.     cpi    '!'
  1240.     jz    MORKY
  1241.     cpi    '&'
  1242.     jz    LOOPME    ;Convert to continuous operation.
  1243.     cpi    '$'
  1244.     jz    INLIST    ;Flush old list, get new one. Start over.
  1245.     cpi    'C'-40h    ;Go home. Right now.
  1246.     jz    EXIT
  1247.     cpi    'X'-40h    ;go play with next file, or leave.
  1248.     jz    INSHIN
  1249.     cpi    'T'-40h    ;go send dits until asked to <esc>.
  1250.     jz    DITEST
  1251.     ani    5Fh
  1252.     cpi    'W'
  1253.     jz    WTOG
  1254.     cpi    'X'
  1255.     jz    XTOG
  1256.     cpi    'P'
  1257.     jz    PTOG
  1258. ;
  1259.     call    FLOOSH
  1260.     call    ILPRT
  1261.     db    CR,LF,LF
  1262.     db    9,'***------CONSOL'
  1263.     db    'E'+80h,'COMMAND------***',CR,LF
  1264.     db    9,'*'+80h,'Optio','n'+80h,'Switche','s'+80h
  1265.     db    'supported:',1Fh,4,'*',CR,LF
  1266.     db    9,'*',1Fh,3,'X'+80h,'='+80h
  1267.     db    'Extende','d'+80h
  1268.     db    'Internationa','l'+80h,' *',CR,LF
  1269.     db    9,'*',1Fh,8,'Mors','e'+80h
  1270.     db    'Alphabe','t'+80h
  1271.     db    'on/of','f'+80h,' *',CR,LF
  1272.     db    9,'*',1Fh,3,'W'+80h,'='+80h
  1273.     db    'Extende','d'+80h,'intercharacte'
  1274.     db    'r'+80h,'*',CR,LF
  1275.     db    9,'*',1Fh,8,'(white',')'+80h,'spac','e'+80h
  1276.     db    'on/off',1Fh,3,'*',CR,LF
  1277.     db    9,'*',1Fh,3,'P'+80h,'='+80h
  1278.     db    'Multiple-spac','e'+80h
  1279.     db    'and',1Fh,6,'*',CR,LF
  1280.     db    9,'*',1Fh,8,'ellipsi','s'+80h
  1281.     db    'mask','s'+80h,'on/of','f'+80h,' *',CR,LF
  1282.     db    9,'*',1Fh,3,'!'+80h,'='+80h,'Ente'
  1283.     db    'r'+80h,'Mors','e'+80h
  1284.     db    'keyboard',1Fh,4,'*',CR,LF
  1285.     db    9,'*',1Fh,8,'loop',1Fh,19,'*',CR,LF
  1286.     db    9,'*',1Fh,3,'&'+80h,'='+80h
  1287.     db    'Loo','p'+80h,'o','n'+80h
  1288.     db    'presen','t'+80h,'list',1Fh,4,'*',CR,LF
  1289.     db    9,'*',1Fh,8,'unti','l'+80h
  1290.     db    'interrupted',1Fh,6,'*',CR,LF
  1291.     db    9,'*',1Fh,3,'$'+80h,'='+80h
  1292.     db    'Loa','d'+80h,'ne','w'+80h,'lis'
  1293.     db    't'+80h,'from',1Fh,6,'*',CR,LF
  1294.     db    9,'*',1Fh,8,'console',1Fh,16,'*',CR,LF
  1295.     db    9,'***-------MORSETX','T'+80h
  1296.     db    'v1.0-------***',CR,LF,LF
  1297.     db    9,'Ente','r'+80h,'eithe','r'+80h
  1298.     db    'ne','w'+80h 
  1299.     db    'coderate-times-te','n'+80h
  1300.     db    'o','r'+80h,'optio','n'+80h
  1301.     db    'switch:___',8,8,8,0
  1302. ;
  1303.     lxi    d,CONBUF
  1304.     call    LINEUP
  1305.     call    CRLF
  1306. ;
  1307.     lda    CONBUF+2
  1308.     cpi    '!'
  1309.     jz    MORKY
  1310.     cpi    '$'
  1311.     jz    INLIST
  1312.     cpi    '&'
  1313.     jz    LOOPME    ;Convert to continuous operation.
  1314.     ani    5Fh
  1315.     cpi    'W'
  1316.     jz    WTOG
  1317.     cpi    'X'
  1318.     jz    XTOG
  1319.     cpi    'P'
  1320.     jz    PTOG
  1321. ;
  1322.     IF    CONDBUG
  1323.     ;
  1324.     lxi    h,CONBUF
  1325.     call    DUMPR
  1326.     ;
  1327.     ENDIF    ;CONDBUG
  1328. ;
  1329.     call    ASDEC    ;ASCII-decimal conversion
  1330.     jnz    PUI    ;lousy input? Punk typists...
  1331.     call    CONVRT
  1332. ;
  1333.     IF    CONDBUG
  1334.     ;
  1335.     call    ILPRT
  1336.     db    CR,LF,'DITCNT now is: ',0
  1337.     lhld    DITCNT
  1338.     call    PHL
  1339.     call    ILPRT
  1340.     db    ',',CR,LF,'DAHCNT now is: ',0
  1341.     lhld    DAHCNT
  1342.     call    PHL
  1343.     call    ILPRT
  1344.     db    '.',CR,LF,0
  1345.     ;
  1346.     ENDIF    ;CONDBUG
  1347. ;
  1348. PUI:    call    CRLF
  1349.     ret
  1350. ;
  1351. DITEST:    call    ILPRT
  1352.     db    CR,LF
  1353.     db    9,'***----DITRAT','E'+80h,'TES','T'+80h
  1354.     db    'MODE-----***',CR,LF
  1355.     db    9,'*'+80h,'Cleartex','t'+80h
  1356.     db    'Words-Per-Minute',':'+80h,' *',CR,LF
  1357.     db    9,'*'+80h,' dit','s'+80h,'pe','r'+80h
  1358.     db    'mi','n'+80h,'/'+80h
  1359.     db    '25','.'+80h,'(PARIS',')'+80h,' *',CR,LF
  1360.     db    9,'* Rando','m'+80h,'group','s'+80h
  1361.     db    'abou','t'+80h,'5/','6'+80h,'tha'
  1362.     db    't'+80h,'*',CR,LF
  1363.     db    9,'*',1Fh,3,'rat','e'+80h,'(o','r'+80h
  1364.     db    'us','e'+80h,'CODE','X'+80h,'test)'
  1365.     db    '.'+80h,' *',CR,LF
  1366.     db    9,'*'+80h,'T','o'+80h,'exit',','+80h
  1367.     db    'hi','t'+80h
  1368.     db    '<escape>.',1Fh,7,'*',CR,LF
  1369.     db    9,'***-------MORSETX'
  1370.     db    'T'+80h,'v1.0------***',CR,LF,0
  1371.     call    FLOOSH
  1372. ;
  1373. DTESTD:    call    DIT
  1374.     mvi    c,6
  1375.     mvi    e,FX
  1376.     call    BDOS
  1377.     ora    a
  1378.     jz    DTESTD
  1379.     ani    7Fh
  1380.     cpi    'C'-40h
  1381.     jz    EXIT
  1382.     cpi    'X'-40h
  1383.     jz    INSHIN
  1384.     cpi    1Bh    ;<escape>
  1385.     cnz    CONSAY
  1386.     xra    a
  1387.     ret
  1388.  
  1389. ;
  1390. LOOPME:    call    ILPRT
  1391.     db    '-<&>-',8,8,8,8,8,LF,0
  1392.     lxi    h,NAMBUF
  1393.     mvi    a,1Ah    ;^Z
  1394. LOPLUP:    inx    h
  1395.     cmp    m
  1396.     jnz    LOPLUP
  1397.     mvi    m,'&'
  1398.     inx    h
  1399.     mvi    m,1Ah
  1400.     ret
  1401.     
  1402. ;
  1403. MORKY:    call    FLOOSH
  1404.     call    ILPRT
  1405.     db    CR,LF,9,'***---MORS','E'+80h
  1406.     db    'KEYBOAR','D'+80h,' LOOP---***'
  1407.     db    9,'PROSIGNS:',9,'[ar]',9,'@'+80h,'+'
  1408.     db    CR,LF,9,'*'+80h,' N','o'+80h
  1409.     db    'softwar','e'+80h
  1410.     db    ' type-ahea','d'+80h,'i','s'+80h,' *'
  1411.     db    9,9,9,'[bt]',9,'='
  1412.     db    CR,LF,9,'*'+80h,' provided','.'+80h
  1413.     db    'Hi','t'+80h,'<esc','>'+80h
  1414.     db    '(^[',')'+80h,'t','o'+80h,'*'
  1415.     db    9,9,9,'[bk]',9,'\'
  1416.     db    CR,LF,9,'*'+80h,' retur','n'+80h,' t'
  1417.     db    'o'+80h,' file-sending.',1Fh,3,'*'
  1418.     db    9,9,9,'[kn]',9,'('+80h,'~'
  1419.     db    CR,LF,9,'***------MORSETX'
  1420.     db    'T'+80h,'v1.0-------***'
  1421.     db    9,9,9,'[sk]',9,'#'
  1422.     db    CR,LF,1Fh,64,'[as]',9,'*'+80h,'!'
  1423.     db    CR,LF,1Fh,64,'[hh]',9,'<bs>'
  1424.     db    CR,LF,1Fh,64,'[sn]',9,'{'+80h,'^'
  1425.     db    CR,LF,0
  1426. MORKLP:    mvi    c,6
  1427.     mvi    e,FX
  1428.     call    BDOS
  1429.     sta    STASH
  1430.     ora    a
  1431.     jz    MORKLP
  1432.     cpi    CR
  1433.     jnz    ICTL
  1434.     call    CRLF
  1435.     jmp    MORKLP
  1436. ICTL:    cpi    20h
  1437.     jnc    EKO
  1438.     mvi    e,'^'
  1439.     mvi    c,6
  1440.     call    BDOS
  1441.     lda    STASH
  1442.     adi    40h    
  1443. EKO:    mov    e,a
  1444.     mvi    c,6
  1445.     call    BDOS
  1446.     lda    STASH
  1447.     cpi    'X'-40h
  1448.     jz    INSHIN
  1449.     cpi    'C'-40h
  1450.     jz    EXIT
  1451.     cpi    'T'-40h
  1452.     cz    DITEST
  1453.     cpi    1Bh    ;esc
  1454.     rz
  1455.     lxi    h,MORKLP
  1456.     push    h
  1457.     lxi    h,SPACE
  1458.     cpi    ' '
  1459.     jz    JOUT
  1460.     cpi    9
  1461.     jz    JOUT
  1462.     lxi    h,ES
  1463.     cpi    '&'
  1464.     jz    JOUT
  1465.     jmp    MORSER
  1466. JOUT:    pchl
  1467. ;
  1468. ;The following is a buffered-console routine that doesn't
  1469. ; use the BDOS call. The buffer it uses must look like 
  1470. ; the one in function 10, though, with:
  1471. ; CONBUF:     db     MAX ;where MAX is the maximum 
  1472. ;                ;character count the buffer
  1473. ;                ;can hold
  1474. ;        ds    1   ;byte counter
  1475. ;        ds    MAX
  1476. ;call with de-->CONBUF
  1477. ;
  1478. LINEUP:    push d! pop h    ;now hl points there too.
  1479.     shld    STASHW    ;save me one. Other user of this is DIV.
  1480.     mov    c,m
  1481.     inx h! inx h    ;repoint to first storage byte
  1482.     mvi    b,0    ;set up the counter
  1483. LINLUP:    call    GETCHR    ;stack-shielded conin call
  1484.     cpi    20h
  1485.     jc    DCIN
  1486.     mov    m,a
  1487.     inx    h
  1488.     inr    b
  1489.     mov    a,c
  1490.     cmp    b
  1491.     jnz    LINLUP
  1492. LINDUN:    lhld    STASHW    ;CONBUF...
  1493.     inx    h    ;+1.
  1494.     mov    m,b
  1495.     ret
  1496. ;
  1497. DCIN:    cpi    CR
  1498.     jz    LINDUN
  1499.     cpi    LF
  1500.     jz    LINDUN
  1501.     cpi    'C'-40h
  1502.     jz    EXIT
  1503.     cpi    'T'-40h
  1504.     jz    DITEST
  1505.     cpi    'X'-40h
  1506.     jz    INSHIN
  1507.     cpi    'H'-40h
  1508.     jnz    FLUSH        ;match? backspace.
  1509.     push h! push d! push b
  1510.     call    ILPRT
  1511.     db    ' ',8,0        ;first bs already echoed by BDOS
  1512.     pop b! pop d! pop h
  1513.     mov    a,b
  1514.     ora    a
  1515.     jz    FLUSH
  1516.     dcx    h
  1517.     mvi    m,0
  1518.     dcr    b
  1519.     jnz    LINLUP
  1520. FLUSH:    cpi    'U'-40h
  1521.     jnz    LINLUP
  1522.     call    ILPRT
  1523.     db    CR,LF,'# ',0
  1524.     jmp    LINEUP
  1525. ;
  1526. GETCHR:    push h! push d! push b    ;uses direct-console call.
  1527. GCRL:    mvi    e,FX
  1528.     mvi    c,6
  1529.     call    BDOS
  1530.     ora    a
  1531.     jz    GCRL
  1532.     push    psw
  1533.     cpi    20h
  1534.     jnc    GCROK
  1535.     cpi    CR
  1536.     jz    GCROK
  1537.     cpi    LF
  1538.     jz    GCROK
  1539.     cpi    8
  1540.     jz    GCROK
  1541.     mvi    e,'^'
  1542.     mvi    c,6
  1543.     call    BDOS
  1544.     pop psw! push psw
  1545.     adi    40h
  1546. GCROK:    mov    e,a
  1547.     mvi    c,6
  1548.     call    BDOS
  1549.     pop    psw
  1550.     pop b! pop d! pop h
  1551.     ret
  1552. ;
  1553. ;The following converts up to the last four decimal digit (0-9)
  1554. ;characters typed to a console-buffer line into an absolute
  1555. ;binary value. On return, the zero flag is set if there's a
  1556. ;worthwhile value stored in RESULT. If the buffer contains no
  1557. ;ASCII numeric bytes, the zero flag is reset and a = 0FFh.
  1558. ;
  1559. ASDEC:    lda    CONBUF+1
  1560.     ora    a
  1561.     jz    NOBUF
  1562.     mvi    d,0
  1563.     lxi    h,0
  1564.     shld    RESULT
  1565.     lxi    h,CONBUF+2
  1566.     lda    CONBUF+1
  1567.     mov    c,a
  1568.     mvi    b,0
  1569. ASDLP:    mov    a,m
  1570.     sui    30h
  1571.     jc    NODEC
  1572.     cpi    0Ah
  1573.     jnc    NODEC
  1574.     mov    e,a
  1575.     push    h
  1576.     lhld    RESULT
  1577.     call    MULTEN
  1578.     dad    d
  1579.     shld    RESULT
  1580.     pop    h
  1581.     inr    b
  1582. NODEC:    inx    h
  1583.     dcr    c
  1584.     jnz    ASDLP
  1585.     mov    a,b
  1586.     ora    a
  1587.     jz    NOBUF
  1588.     xra    a
  1589.     ret
  1590. ;
  1591. MULTEN:    push    d
  1592.     push    h
  1593.     pop    d
  1594.     dad    h
  1595.     dad    h
  1596.     dad    d
  1597.     dad    h
  1598.     pop    d
  1599.     ret
  1600. ;
  1601. NOBUF:    mvi    a,0FFh
  1602.     ora    a
  1603.     ret
  1604. ;
  1605. ;
  1606. CONVRT:    lhld    DELCON+2    ;bring in a fresh copy of
  1607.     shld    DIV+4        ;the (clockrate-corrected)
  1608.     lhld    DELCON        ;0.1 wpm delay constant.
  1609.     shld    DIV+2
  1610.     xra    a
  1611.     sta    DIV+1
  1612.     sta    DIV
  1613. ;
  1614.     IF    CONDBUG
  1615.     ;
  1616.     call    ILPRT
  1617.     db    CR,LF,'Binary equivalent of that:',9,0
  1618.     lhld    RESULT    ;
  1619.     call    PHL
  1620.     call    ILPRT
  1621.     db    CR,LF,'Starting delay constant'
  1622.     db    CR,LF,'  (32-bit value)--',9,0
  1623.     call    SHOW32
  1624.     ;
  1625.     ENDIF    ;CONDBUG
  1626. ;
  1627.     call    DIVI
  1628. ;
  1629.     IF    CONDBUG
  1630.     ;
  1631.     call    ILPRT            
  1632.     db    CR,LF,'Division results:',9,0
  1633.     call    SHOW32
  1634.     call    ILPRT
  1635.     db    CR,LF,'Remainder:',9,9,0
  1636.     lda    DIV
  1637.     call    PHEX
  1638.     lda    DIV+1
  1639.     call    PHEX
  1640.     db    CR,LF,LF,0
  1641.     ;
  1642.     ENDIF    ;CONDBUG
  1643. ;
  1644.     lhld    DIV+2
  1645.     mov    a,l
  1646.     ora    h
  1647.     jz    SMALL
  1648. ;
  1649.     IF    CONDBUG
  1650.     ;
  1651.     call    ILPRT
  1652.     db    CR,LF,'Ditdelay too big: 0FFFFh substituted.',CR,LF,0
  1653.     ;
  1654.     ENDIF    ;CONDBUG
  1655. ;
  1656.     lxi    h,FOXES
  1657.     shld    DIV+4
  1658. SMALL:    lxi    h,DIV+5
  1659.     mov    e,m
  1660.     dcx    h
  1661.     mov    d,m
  1662.     xchg
  1663.     shld    DITCNT
  1664.     push    h
  1665.     pop    b
  1666.     dad    h
  1667.     dad    b
  1668.     shld    DAHCNT
  1669.     ret
  1670. ;
  1671.     IF    CONDBUG
  1672.     ;
  1673. SHOW32:    lda    DIV+2
  1674.     call    PHEX
  1675.     lda    DIV+3
  1676.     call    PHEX
  1677.     lda    DIV+4
  1678.     call    PHEX
  1679.     lda    DIV+5
  1680.     call    PHEX
  1681.     ret
  1682.     ;
  1683.     ENDIF    ;CONDBUG
  1684. ;
  1685. DIVI:    mvi    a,33
  1686.     sta    SHCNT
  1687.     xra    a
  1688.     jmp    SHIN
  1689. DIVLP:    sta    SHCNT    ;shift count. 
  1690.     call    SUBT    ;
  1691. SHIN:    call    SHIFT    ;48-bit leftshift, carry-in.
  1692.     lda    SHCNT
  1693.     dcr    a
  1694.     jnz    DIVLP
  1695.     ret
  1696. ;
  1697. SUBT:    lhld    DIV    ;keep a copy for the restore
  1698.     shld    STASHW    ;(need not be saved in order)
  1699.     lhld    RESULT    ;16-bit divisor stored as a word
  1700.     xchg
  1701.     lxi    h,DIV+1    ;to 32-bit dividend stored byte-serial
  1702.     mov    a,m
  1703.     sub    e
  1704.     mov    m,a
  1705.     dcx    h    ;go down
  1706.     mov    a,m
  1707.     sbb    d
  1708.     mov    m,a    ;Now. Carry? Undo the subtract.
  1709.     cmc        ;SHIFT will need the carry the other
  1710.     rc        ;way, so react based on that.
  1711.     lhld    STASHW
  1712.     shld    DIV
  1713.     ret
  1714. ;
  1715. ;++ CARRY BIT AT ENTRY WILL BE SHIFTED INTO LSB ++
  1716. ;
  1717. SHIFT:    mvi    b,6    ;bytes to be rotated
  1718.     lxi    h,DIV+5    ;start at the least byte
  1719. SHILUP:    mov    a,m    ;get it...
  1720.     ral        ;roll it left. Hibit into carry, 
  1721.     mov    m,a    ;carry into lobit. Store it.
  1722.     push    psw    ;Save the flags (especially carry) 
  1723.     dcx    h    ;repoint to more significant byte
  1724.     dcr    b    ;tick off one pass. Done?
  1725.     jz    SHIDUN
  1726.     pop    psw    ;Nope. Gimme back my flags.
  1727.     jmp    SHILUP
  1728. ;
  1729. SHIDUN:    pop    psw    ;Done. Unplug the stack and leave.
  1730.     ret        ;Anybody want a used carry flag?
  1731. ;
  1732. ;
  1733. ;
  1734. WTOG:    call    ILPRT
  1735.     db    '-<W>-',8,8,8,8,8,LF,0
  1736.     lda    WSPBYT
  1737.     cma
  1738.     sta    WSPBYT
  1739.     ret
  1740. ;
  1741. XTOG:    call    ILPRT
  1742.     db    '-<X>-',8,8,8,8,8,LF,0
  1743.     lda    XTNBYT
  1744.     cma
  1745.     sta    XTNBYT
  1746.     ret
  1747. ;
  1748. PTOG:    call    ILPRT
  1749.     db    '-<P>-',8,8,8,8,8,LF,0
  1750.     lda    PRYBYT
  1751.     cma
  1752.     sta    PRYBYT
  1753.     ret
  1754. ;
  1755. ;Bring in a list of files to send from the console. Use the
  1756. ;buffered console function for each line. Stop looping when
  1757. ;the linebuffer's character count reads zero.
  1758. ;
  1759. ;1. Sign on, announce the game rules.
  1760. ;2. Point to beginning of NAMBUF. Set up controls in NAMBEL.
  1761. ;3. Bring in a line using the BDOS buffered line function.
  1762. ;4. Test: line had zero characters? Then wrap it up.
  1763. ;5. Repoint to next free space.
  1764. ;6. Convert previous line's control bytes to <crlf>.
  1765. ;7. Goto 3.
  1766. ;
  1767. ;The input line will be evaluated when it's acted upon. 
  1768. ;
  1769. INLIST:    call    FLOOSH
  1770.     call    ILPRT
  1771.     db    CR,LF,LF,LF
  1772.     db    9,'***--CONSOL','E'+80h
  1773.     db    'FILENAM','E'+80h,'ENTRY--***',CR,LF
  1774.     db    9,'*'+80h,'Ente','r'+80h,'on','e'+80h
  1775.     db    'dr:filename.ty','p'+80h,'o'
  1776.     db    'n'+80h,'*',CR,LF
  1777.     db    9,'*'+80h,' eac','h'+80h,'line',','+80h
  1778.     db    'followe','d'+80h,'b','y'+80h
  1779.     db    'an','y'+80h,' *',CR,LF
  1780.     db    9,'*'+80h,'optio','n'+80h
  1781.     db    'switche','s'+80h,'o','r'+80h,'ne'
  1782.     db    'w'+80h,'spee','d'+80h,'*',CR,LF
  1783.     db    9,'*'+80h,'a','s'+80h,'wp'
  1784.     db    'm'+80h,'time','s'+80h
  1785.     db    'ten','.'+80h,' N','o'+80h
  1786.     db    '*.SUB','s'+80h,'*',CR,LF
  1787.     db    9,'*'+80h,'o','r'+80h,'ambiguou','s'+80h
  1788.     db    'filenames',':'+80h,'the','y'+80h,'*',CR,LF
  1789.     db    9,'*'+80h,'overwrit','e'+80h,'followin'
  1790.     db    'g'+80h,' entrie','s'+80h,'*',CR,LF
  1791.     db    9,'*'+80h,'a','t'+80h,'expansion','.'+80h
  1792.     db    'A','n'+80h,'extr','a'+80h,'<cr'
  1793.     db    '>'+80h,' *',CR,LF
  1794.     db    9,'*  end','s'+80h,'entry.',1Fh,17,'*',CR,LF
  1795.     db    9,'***-------MORSETX'
  1796.     db    'T'+80h,'v1.0------***',CR,LF,LF,0
  1797.     lxi    h,NAMBEL
  1798.     shld    NAMPTR
  1799.     xra    a    ;Console (unformatted) entries---
  1800.     sta    USEMOV    ;use M2D4BF to move 'em down.
  1801. ;
  1802.     lxi    h,32h
  1803.     shld    NAMBEL
  1804. INLILP:    lhld    NAMPTR    ;first time, this points to NAMBEL.
  1805.     xchg        ;After that, we move it up.
  1806.             ;buffered console string
  1807.     call    LINEUP    ;homebrew function 10
  1808.     mvi    e,LF
  1809.     mvi    c,6    ;BDOS echos only what it gets. That
  1810.     call    BDOS    ;means, send your own linefeed.
  1811. ;
  1812.     lhld    NAMPTR    ;Point to the maximum-count byte.
  1813.     inx    h    ;Now point to character count. Is it
  1814.     xra    a    ;zero? Then that's it for the console
  1815.     ora    m    ;entry schtick. Go cap off the list
  1816.     dcx    h    ;and get busy. No? Continue.
  1817.     jz    SHINIT    ;Back to the maximum-count byte.
  1818.     mvi    m,CR    ;Convert the 32h we wrote to <cr>.
  1819.     inx    h    ;This is the character count. That we
  1820.     mov    e,m    ;want. Put it in de. Replace it with 
  1821.     mvi    d,0    ;<lf>. Bump. Now we point at the first
  1822.     mvi    m,LF    ;string byte. Add the bytecount, and we
  1823.     inx    h    ;point to the first free location past
  1824.     dad    d    ;the string. This is where the new
  1825.     shld    NAMPTR    ;string will go. Set up control bytes.
  1826.     mvi    m,32h
  1827.     inx    h    ;I don't know that this pre-nulling is
  1828.     mvi    m,0    ;really necessary, but...
  1829. ;
  1830.     jmp    INLILP    ;one more time, with feeling...    
  1831. ;
  1832. SHINIT:    mvi    m,CR    ;Back to our max-count. One more <crlf>
  1833.     inx    h    ;to keep the list handler happy, then
  1834.     mvi    m,LF    ;put a ^Z where the list handler will
  1835.     inx    h    ;find it instead of a name, to tell it  
  1836.     mvi    m,1Ah    ;to go home.
  1837. ;
  1838.     lxi    h,NAMBUF    ;repoint to the beginning
  1839.     shld    NAMPTR        ;of the list...
  1840. INSHIN:    lxi    sp,STAKS
  1841.     lxi    h,EXIT    ;This bit restarts the whole program,
  1842.     push    h    ;flushing the stack of old (dead)
  1843.     jmp    SETUP    ;saves and returns. The other visitor
  1844.             ;here is the ^X response at CONSAY.
  1845.             ;You think this is dirty? I'd rather
  1846.             ;design this for humans to use. 
  1847. ;
  1848. ;
  1849. ILPRT:    xthl        ;In-Line Printer, as kind to
  1850.     push    psw    ;registers as I could make it.
  1851. ILLUP:    mov    a,m    ;I've commented out the copy
  1852.     inx    h    ;in TRACEPKG, while preserving
  1853.     ora    a    ;TRACEPKG as a transplant 
  1854.     jz    ILDUN    ;module, because of the filler.
  1855.     cpi    1Fh    ;^_, record separator. In MONITOR,
  1856.     jz    FILTHM    ;I use TAB the same way.
  1857.     call    PCHAR
  1858.     jmp    ILLUP
  1859. ILDUN:    pop    psw
  1860.     xthl
  1861.     ret
  1862. ;
  1863. FILTHM:            ;We've bumped across the 1Fh,
  1864.     mov    a,m    ;the process flag. Now pick up the
  1865.     inx    h    ;space count that follows, and
  1866. FLTHLP:    push    psw    ;step over that too. Save the
  1867.     mvi    a,' '    ;count. Now, until it drops to
  1868.     call    PCHAR    ;zero, send out spaces. Then
  1869.     pop    psw    ;jump back into action, pointing
  1870.     dcr    a    ;at the next printable byte.
  1871.     jnz    FLTHLP
  1872.     jmp    ILLUP
  1873.  
  1874. ;
  1875. ;
  1876. ;This inline Morse string-sender also has machine-specific
  1877. ; details, though not so rigorously defined. If you can
  1878. ; adapt the program by merely changing the equates, you
  1879. ; can use the routine as-is.
  1880. ;
  1881. ILMORS:    pop    h    ;Get the pointer...
  1882.     mov    a,m    ;get the byte... 
  1883.     inx    h    ;bump the pointer...
  1884.     ora    a
  1885.     jz    MORDUN    ;...and, assuming we're not done,
  1886.     push    h    ;put the pointer away.
  1887.     cpi    ' '
  1888.     jz    MOSP
  1889.     cpi    '&'
  1890.     jz    MOES
  1891.     call    MORSER
  1892.     call    CONSEN    ;CON: sensing. Calls CONSAY if true.
  1893.     in    PORTAS    ;console port
  1894.     ani    CINMSK
  1895.     cpi    CINMCH    ;Here's where we break off if
  1896.     cz    CONSAY    ;CON: is sending.
  1897.     jmp    ILMORS
  1898. MOSP:    call    SPACE    ;7 dits of silence.
  1899.     jmp    ILMORS
  1900. MOES:    call    ES    ;'&'
  1901.     jmp    ILMORS
  1902. MORDUN:    pchl        ;We're done? Oh. Bye.
  1903. ;
  1904. ;
  1905. ;Short-haul (256 bytes) 8080 equivalent to LDIR.
  1906. ;
  1907. M2D4B:    mov    a,m
  1908.     inx    h
  1909.     stax    d
  1910.     inx    d
  1911.     dcr    c
  1912.     jnz    M2D4B
  1913.     ret
  1914. ;
  1915. ;The following is designed to do what CCP does to
  1916. ;a filename.typ, in copying a virtual line of
  1917. ;console input into an FCB. 
  1918. ;
  1919. M2D4BF:    mov    a,m    ;until c decrements to 0, copy @ hl
  1920.     cpi    '.'    ;to @ de. BUT:
  1921.     jz    DOTTY    ;--if the source byte is a period,
  1922.     cpi    '*'    ;pad out the target subsection
  1923.     jz    FILAMB    ;(name, type) with spaces. 
  1924.     cpi    CR    ;--Space? Pad with spaces all the way.
  1925.     jz    PADIT    ;--if it's an asterisk, pad out the
  1926.     cpi    ' '    ;section with '?'.
  1927.     jz    PADIT    ;--if it's a space, go pad with spaces.
  1928.     cpi    'a'    ;'a'-'z'? Uppercase 'em.
  1929.     jc    UPPRC
  1930.     cpi    '{'
  1931.     jnc    UPPRC
  1932.     ani    5Fh
  1933. UPPRC:    stax    d
  1934.     inx    h
  1935.     inx    d
  1936.     dcr    c
  1937.     jnz    M2D4BF
  1938.     ret
  1939. ;
  1940. FILAMB:    inx    h    ;step across the *.
  1941. FLAMBP:    mvi    a,'?'    ;Now fill out whichever slot
  1942.     stax    d    ;we're in (filename or .typ)
  1943.     inx    d    ;with '?'.
  1944.     dcr    c
  1945.     mov    a,c
  1946.     cpi    3    ;Dot's right---
  1947.     jz    M2D4BF    ;Let DOTTY handle the dot. 
  1948.     ora    a    ;If the party's over, though,
  1949.     rz        ;go home.
  1950.     jmp    FLAMBP
  1951. ;
  1952. DOTTLE:    mvi    a,' '    ;We found a dot, but the count 
  1953.     stax    d    ;wasn't down to 3. Until it is,
  1954.     inx    d    ;pad out the target with spaces.
  1955.     dcr    c
  1956. DOTTY:    mov    a,c    ;If the dot in 'FILENAME.TYP' is 
  1957.     cpi    4    ;what we found, we should jump
  1958.     jnc    DOTTLE    ;across it and continue, ending
  1959.     ora    a    ;up with 'FILENAMETYP'.
  1960.     rz        ;...and this here is partial 
  1961.     inx    h    ;idiotproofing, to deal with
  1962.     jmp    M2D4BF    ;multiple dots. Let the caller
  1963.             ;complain-- at least we don't
  1964.             ;lock up.
  1965. ;
  1966. PADIT:    mvi    a,' '
  1967.     stax    d
  1968.     inx    d
  1969.     dcr    c
  1970.     jnz    PADIT
  1971.     ret
  1972. ;
  1973. PCHAR:    push h! push d! push b! push psw
  1974.     push    psw
  1975.     cpi    CR
  1976.     jz    NULCRL
  1977.     cpi    LF
  1978.     jz    NULCRL
  1979.     cpi    9
  1980.     jnz    OUTPCR
  1981.     jmp    MAKTAB    
  1982. NULCRL:    push    psw
  1983.     mvi    a,FX
  1984.     sta    CRLIN
  1985.     pop    psw    
  1986. OUTPCR:    ani    7Fh
  1987.     mov    e,a
  1988.     mvi    c,6
  1989.     call    BDOS
  1990.     pop    psw
  1991.     ani    80h
  1992.     jz    PCRDUN
  1993.     lda    CRLIN
  1994.     inr    a
  1995.     sta    CRLIN
  1996. DNTB:    mvi    a,' '
  1997.     push    psw
  1998.     jmp    OUTPCR
  1999. PCRDUN:    lda    CRLIN
  2000.     inr    a
  2001.     sta    CRLIN
  2002.     pop psw! pop b! pop d! pop h
  2003.     ret
  2004. ;
  2005. MAKTAB:    pop    psw
  2006. MKTB:    mvi    e,' '
  2007.     mvi    c,6
  2008.     call    BDOS
  2009.     lda    CRLIN
  2010.     inr    a
  2011.     sta    CRLIN
  2012.     ani    7
  2013.     cpi    7
  2014.     jnz    MKTB
  2015.     jmp    DNTB    
  2016. ;
  2017. ;This routine's  only purpose in life is to show
  2018. ; you what  weird filename.typ you typed in when
  2019. ; you thought were naming something. Perhaps you
  2020. ; put in a user code...  V1.0 doesn't understand
  2021. ; such things.  I'm not really up on  writing it
  2022. ; yet either,  since  I  keep everything down at
  2023. ; 0: where  I can keep an eye on who's eating up
  2024. ; all my disk space.
  2025. ;
  2026. WIMPER:    lxi    h,0C900h    ;when stored, that'll be
  2027.                 ;<null>, ret.
  2028.     shld    FCB+12
  2029.     lxi    h,FCB+1
  2030.     push    h
  2031.     jmp    ILPRT
  2032. ;
  2033. GETIT:    lda    RECTGL
  2034.     ora    a
  2035.     lxi    d,RECORD+80h
  2036.     jz    DOTOP
  2037.     lxi    d,RECORD
  2038. DOTOP:    mvi    c,1Ah    ;set DMA
  2039.     call    BDOS
  2040.     lxi    d,FCB
  2041.     mvi    c,14h    ;read sequential
  2042.     call    BDOS
  2043.     ora    a
  2044.     jnz    INSHIN    ;if he's had us reading a file without
  2045.     sta    XHAUST    ;a ^Z, this could be EOF. Go reloop to
  2046.             ;SETUP via a stack flush... let him
  2047.             ;handle it.
  2048.     lda    RECTGL
  2049.     cma
  2050.     sta    RECTGL
  2051. ;
  2052.     IF    DEBUG
  2053.     ;
  2054.     call    ILPRT
  2055.     db    'DID READSEQ.',8,8,8,8,8,8,8,8,8,8,8,8,LF,0
  2056.     ;
  2057.     ENDIF    ;DEBUG
  2058. ;
  2059.     ret
  2060. ;
  2061. ;This routine corrects the 32-bit dit-delay constant for
  2062. ;the declared CPU clockrate.  The initial delay value as
  2063. ;assembled  is  the  empirically-determined extrapolated
  2064. ;dit delay  for a 0.1 wpm coderate  with  a 100 KHz  Z80
  2065. ;clock (as determined by  the PARIS test).  The  routine
  2066. ;itself is a  32-bit by 8-bit unsigned multiply, done in
  2067. ;longhand.  It is executed  once,  when  the program  is 
  2068. ;first loaded.
  2069. ;
  2070. MULTD:    lxi    h,DELCON
  2071.     lxi    d,RECORD    ;we're not using it yet...
  2072.     lxi    b,4
  2073.     call    M2D4B    ;copy a unity image up where it's safe
  2074.     lda    CLKBYT
  2075.     mov    b,a    ;INT(crystal frequency * 10) 
  2076.     mvi    c,8    ;bit-count of that value
  2077. MLDLP:    lxi    h,DELCON+3
  2078.     mov    a,m    ;maybe it's funky, but I need the
  2079.     rlc        ;flag and the initial non-carry.
  2080.     mov    m,a    ;Later I'll get real clever about
  2081.     dcx    h    ;stashing the CPU's flags, but right
  2082.     mov    a,m    ;now this one-time linear code is 
  2083.     ral        ;all right by me. Don't like it here?
  2084.     mov    m,a    ;Put it up in NAMBUF.
  2085.     dcx    h
  2086.     mov    a,m
  2087.     ral
  2088.     mov    m,a
  2089.     dcx    h
  2090.     mov    a,m
  2091.     ral
  2092.     mov    m,a
  2093. ;
  2094.     mov    a,b
  2095.     rlc
  2096.     mov    b,a
  2097.     jnc    NOADD
  2098. ;
  2099.     lxi    h,DELCON+3    ;add the initial value to
  2100.     lxi    d,RECORD+3    ;the developing product.
  2101.     ldax    d
  2102.     add    m
  2103.     mov    m,a
  2104.     dcx    h
  2105.     dcx    d
  2106.     ldax    d
  2107.     adc    m
  2108.     mov    m,a
  2109.     dcx    h
  2110.     dcx    d
  2111.     ldax    d
  2112.     adc    m
  2113.     mov    m,a
  2114.     dcx    h
  2115.     dcx    d
  2116.     ldax    d
  2117.     adc    m
  2118.     mov    m,a
  2119. NOADD:    dcr    c
  2120.     jnz    MLDLP
  2121.     ret
  2122. ;
  2123.     IF    NOT (NODBUG)
  2124. ;
  2125. ;========== TRACER PACKAGE ======================START 
  2126. ;
  2127. ;ILPRT:    xthl        ;In-Line Printer, as kind to
  2128. ;    push    psw    ;registers as I could make it.
  2129. ;ILLUP:    mov    a,m
  2130. ;    inx    h
  2131. ;    ora    a
  2132. ;    jz    ILDUN
  2133. ;    call    TRACER
  2134. ;    jmp    ILLUP
  2135. ;ILDUN:    pop    psw
  2136. ;    xthl
  2137. ;    ret
  2138. ;
  2139. DMPCTR:    db    0    ;Dumps a DDT-style display of two
  2140. DMPTIC:    db    0    ;records of memory, starting where
  2141. DUMPHL:    dw    0    ;hl points at entry. DMPCTR counts
  2142. DUMPR:    push b! push d    ;the lines up to 16. Stuff it nonzero
  2143. DUMPIN:    shld    DUMPHL    ;before calling, if you want fewer
  2144.     call    PHL    ;lines.
  2145.     call    ILPRT
  2146.     db    ': ',0
  2147.     lhld    DUMPHL
  2148.     mvi    e,16
  2149. DUMPHX:    mov    a,m
  2150.     inx    h
  2151.     push h! push d
  2152.     call    PHEX
  2153.     mvi    a,' '
  2154.     call    TRACER
  2155.     pop d! pop h
  2156.     dcr    e
  2157.     jnz    DUMPHX
  2158.     lhld    DUMPHL
  2159.     mvi    e,16
  2160. DUMPAS:    mov    a,m
  2161.     inx    h
  2162.     push h! push d
  2163.     ani    7Fh
  2164.     cpi    ' '
  2165.     jnc    ASOK
  2166.     mvi    a,'.'
  2167. ASOK:    call    TRACER
  2168.     pop d! pop h
  2169.     dcr    e
  2170.     jnz    DUMPAS
  2171.     mvi    a,CR
  2172.     call    TRACER
  2173.     mvi    a,LF
  2174.     call    TRACER
  2175. ;
  2176.     lxi    d,16
  2177.     lhld    DUMPHL
  2178.     dad    d
  2179.     shld    DUMPHL
  2180.     lda    DMPCTR
  2181.     inr    a
  2182.     sta    DMPCTR
  2183.     ani    0Fh
  2184.     jz    DUMPUP
  2185.     cpi    8
  2186.     jnz    DUMPIN
  2187.     mvi    a,CR
  2188.     call    TRACER
  2189.     mvi    a,LF
  2190.     call    TRACER
  2191.     jmp    DUMPIN
  2192. DUMPUP:    pop d! pop b
  2193.     xra    a    ;zero the counter for next time.
  2194.     sta    DMPCTR
  2195.     sta    DMPTIC
  2196.     ret
  2197. ;
  2198. PHL:    push    h
  2199.     mov    a,h
  2200.     call    PHEX
  2201.     pop    h
  2202.     mov    a,l
  2203. PHEX:    push    psw
  2204.     rrc
  2205.     rrc
  2206.     rrc
  2207.     rrc
  2208.     call    PNIB
  2209.     pop    psw
  2210. PNIB:    ani    0Fh
  2211.     adi    90h
  2212.     daa
  2213.     aci    40h
  2214.     daa
  2215. TRACER:    push b! push d! push h
  2216.     push    psw
  2217.     mov    e,a
  2218.     mvi    c,6
  2219.     call    BDOS
  2220.     mvi    c,0Bh
  2221.     call    BDOS
  2222.     ora    a
  2223.     jz    NOCSN
  2224. CSN:    mvi    e,0FFh
  2225.     mvi    c,6
  2226.     call    BDOS
  2227.     cpi    'S'-40h
  2228.     jz    CSN
  2229.     cpi    'C'-40h
  2230.     jz    0
  2231. NOCSN:    pop    psw
  2232.     pop h! pop d! pop b
  2233.     ret
  2234. ;
  2235. ;======= TRACER PACKAGE ============================END
  2236. ;
  2237.     ENDIF    ;NOT NODBUG
  2238. ;
  2239. ;
  2240. TABLE:    db    FX,FX,FX,FX    ;NUL SOH
  2241.     db    FX,FX,FX,FX    ;STX ETX
  2242.     db    FX,FX,FX,FX    ;EOT ENQ
  2243.     db    8,50h,FX,FX    ;ACK...<sn> BEL
  2244.     db    0,80h,FX,FX    ;BS...<hh> HT
  2245.     db    0Bh,60h,FX,FX    ;LF...<al> VT
  2246.     db    15h,50h,51h,70h    ;FF...<ka> CR...<bk> 
  2247.     db    FX,FX,FX,FX    ;SO SI
  2248.     db    FX,FX,FX,FX    ;DLE DC1
  2249.     db    FX,FX,FX,FX    ;DC2 DC3
  2250.     db    FX,FX,FX,FX    ;DC4 NAK
  2251.     db    FX,FX,0Ah,50h    ;SYN ETB...<ar>
  2252.     db    FX,FX,FX,FX    ;CAN EM
  2253.     db    FX,FX,FX,FX    ;SUB ESC
  2254.     db    FX,FX,FX,FX    ;FS GS
  2255.     db    FX,FX,FX,FX    ;RS US
  2256.     db    FX,FX,2,50h    ;<space> bang...<as>
  2257.     db    2Dh,60h,28h,60h    ;" #...<sk>
  2258.     db    84h,70h,21h,50h    ;$...<sx: dollarsign> 
  2259.                 ;%...<au: fractions follow>
  2260.     db    FX,FX,1Eh,60h    ;&...set up ES in a sub
  2261.                  ;'
  2262.     db    0Dh,50h,2Dh,60h    ;( )
  2263.     db    2,50h,0Ah,50h    ;+...<ar> *...<as>
  2264.     db    33h,60h,21h,60h    ;, -
  2265.     db    2Ah,60h,9,50h    ;. /...<fraction bar>
  2266.     db    1Fh,50h,1Eh,50h    ;0 1
  2267.     db    1Ch,50h,18h,50h    ;2 3
  2268.     db    10h,50h,0,50h    ;4 5
  2269.     db    1,50h,3,50h    ;6 7
  2270.     db    7,50h,0Fh,50h    ;8,9
  2271.     db    7,60h,15h,60h    ;: ;
  2272.     db    FX,FX,11h,50h    ;< =...<doubledash>
  2273.     db    FX,FX,0Ch,60h    ;> ?
  2274.     db    0Ah,50h,22h,FX    ;@...<ar> A
  2275.     db    41h,FX,45h,FX    ;B C
  2276.     db    31h,FX,10h,FX    ;D E
  2277.     db    44h,FX,33h,FX    ;F G
  2278.     db    40h,FX,20h,FX    ;H I
  2279.     db    4Eh,FX,35h,FX    ;J K
  2280.     db    42h,FX,23h,FX    ;L M
  2281.     db    21h,FX,37h,FX    ;N O
  2282.     db    46h,FX,4Bh,FX    ;P Q
  2283.     db    32h,FX,30h,FX    ;R S
  2284.     db    11h,FX,34h,FX    ;T U
  2285.     db    48h,FX,36h,FX    ;V W
  2286.     db    49h,FX,4Dh,FX    ;X Y
  2287.     db    43h,FX,FX,FX    ;Z [
  2288.     db    51h,70h,FX,FX    ;\...<bk> ]
  2289.     db    8,50h,2Ch,60h    ;^ _
  2290.     db    FX,FX,22h,FX    ;accent grave, a
  2291.     db    41h,FX,45h,FX    ;b c
  2292.     db    31h,FX,10h,FX    ;d e
  2293.     db    44h,FX,33h,FX    ;f g
  2294.     db    40h,FX,20h,FX    ;h i
  2295.     db    4Eh,FX,35h,FX    ;j k
  2296.     db    42h,FX,23h,FX    ;l m
  2297.     db    21h,FX,37h,FX    ;n o
  2298.     db    46h,FX,4Bh,FX    ;p q
  2299.     db    32h,FX,30h,FX    ;r s
  2300.     db    11h,FX,34h,FX    ;t u
  2301.     db    48h,FX,36h,FX    ;v w
  2302.     db    49h,FX,4Dh,FX    ;x y
  2303.     db    43h,FX,8,50h    ;z {
  2304.     db    FX,FX,FX,FX    ;| }
  2305.     db    0Dh,50h,0,80h    ;~...<kn> DEL...<hh>
  2306. ;
  2307. ;Prosigns:
  2308. ;         SIGN      KEY USED  MEANING
  2309. ;    au    %    fractions follow
  2310. ;    sx    $    dollar-sign
  2311. ;    ar    +,@,ETB    end of message or cross
  2312. ;    bk    \,CR    "over."
  2313. ;    sn    ACK,{    understand
  2314. ;    as    *,!    wait
  2315. ;    hh    BS,DEL    error
  2316. ;    sk    #    QSO END
  2317. ;    kn    (,~    go only
  2318. ;
  2319. ;'&', <es>, is best handled as an exception.
  2320. ; Inter-letter space is dah = 3 dits... space needed is 2 dits.
  2321. ;
  2322. ;----------
  2323. CURDRV:    ds    1
  2324. USRDRV:    ds    1    ;
  2325. USEMOV:    db    0    ;flag, which MOV routine to use.
  2326. FIRSTM:    db    0
  2327. WSPBYT:    db    0
  2328. XTNBYT:    db    0
  2329. PRYBYT:    db    0
  2330. STASH:    ds    1
  2331. STASH2:    ds    1
  2332. SHCNT:    db    0    ;shiftcounter for division routines
  2333. DIV:    db    0,0        ;32 bit 0.1 wpm delay constant,
  2334.     db    1,0,0,0        ;stored in STRAIGHT ASCENDING
  2335.                 ;BYTES, MSBy first. Plus some
  2336.                 ;operating room for the division.
  2337. DMADR:    dw    0
  2338. STASHW:    dw    0
  2339. RESULT:    dw    0
  2340. CRLIN:    db    0    ;characters/line counter for Function 6 
  2341. SPACNT:    db    0
  2342. PERCNT:    db    0
  2343. RECPTR:    ds    2
  2344. XHAUST:    db    0
  2345. RECTGL:    db    0
  2346. CONBUF:    db    8,0
  2347.     ds    10h
  2348.     dw    1A1Ah    ;...safety
  2349.     ds    100h
  2350. STAKS:    ds    2
  2351. NAMPTR:    dw    NAMBUF
  2352. NAMBEL:    ds    2    ;room for the first buffered line's controls. 
  2353. NAMBUF:    ds    100h
  2354.  
  2355. ;
  2356.     end
  2357. ;
  2358. ;Westlink Inc. News Report POBox 463 Pasadena CA 91102 
  2359. ;monday, 8PM  Santa Clarita ARC Net @ KB6C 147.735- Magic Mtn Rptr
  2360. ;
  2361. eof MORSTXT.ASM/Ampro[stuff.933]--CHR$(13)25JUN85
  2362. 02 
  2363. ;monday, 8PM  Santa Clarita ARC Net @ KB6C 147.735- Magic Mtn Rptr
  2364. ;
  2365. eof MORSTX