home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / FORTH-83 / NIT4TH.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  6KB  |  262 lines
  1. ; 
  2. ;       INIT4TH Version 1.0 as of December 13, 1981
  3. ; 
  4. ;                By: Kelly Smith, CP/M-Net
  5. ; 
  6. ;      The purpose of INIT4TH,  came about from the flagrant 
  7. ; destruction  of Fig-Forth screens that were co-resident on 
  8. ; my CP/M diskettes...I would forget that the screens DO NOT 
  9. ; appear  in the CP/M directory,  and as such are  prone  to 
  10. ; eminent  destruction (due totally to my stupidity) by  the 
  11. ; CP/M "PIP" command.  What to do? Well, I also got tired of 
  12. ; clearing  out  screens  that  were  full  of  "e5's"  from 
  13. ; formatting,  and  decided  to  kill  two  birds  with  one 
  14. ; stone...
  15. ; 
  16. ;      INIT4TH  will  allow retention of all  relevant  CP/M 
  17. ; files (such as FORTH itself) on a CP/M and FORTH diskette, 
  18. ; initialize  all sectors NOT occupied by the resident  CP/M 
  19. ; files, and RESERVE all remaining sectors as available disk 
  20. ; area  for FORTH screens.  How is it  done?  Well,  INIT4TH 
  21. ; creats  one  "super  file"  called  RESERVED.4TH  that  is 
  22. ; nothing  but  blanks  (actually ASCII "space"  code)  that 
  23. ; aquires all CP/M groups remaining after the resident  CP/M 
  24. ; files...once    your   quasi   CP/M-FORTH   diskette    is 
  25. ; initialized,  it's  FULL  as far as CP/M is concerned  for 
  26. ; further PIPing,  and ready for whatever you want to  place 
  27. ; into  the  available  Fig-Forth screen  area  (my  version 
  28. ; starts  with a blank screen number 17,  up to  249).  It's 
  29. ; best,  if you PIP all the CP/M files to a blank  formatted 
  30. ; diskette first to make them contiguous on the diskette (no 
  31. ; "holes"),  and  then  run INIT4TH on it  to  "take-up-the-
  32. ; slack".
  33. ; 
  34. ;      But  WARNING...do  not  run this on a  diskette  that 
  35. ; already  has screens that you want to  preserve...this  is 
  36. ; ONLY  for diskette INITIALIZATION of FORTH  screens...copy 
  37. ; from  another  diskette as you normally do to  place  your 
  38. ; "treasured" screens on it.
  39. ; 
  40. ;      A  conditional assembly equate "SYS" is used to  make 
  41. ; RESERVED.4TH  invisible  in the directory (if you want  it 
  42. ; that way).
  43. ; 
  44. ;      I  hope this is of some use to you,  and if you  make 
  45. ; any  changes,  I  would appreciate it,  if you  modem  the 
  46. ; program to CP/M-Net (805) 527-9321 as INIT4TH.NEW...
  47. ; 
  48. ;      P.S.  I have learned many new WORDs using FORTH,  but 
  49. ; none are repeatable here...
  50. ; 
  51. ;                         Best regards: Kelly Smith CP/M-Net
  52. ;
  53. ;
  54. ;
  55. ; define TRUE/FALSE assembly parameters
  56. ;
  57. true    equ    -1    ; define TRUE
  58. false    equ    not true; define FALSE
  59. sys    equ    true    ; define SYS (make RESERVED.4TH a $SYS file)
  60. ;
  61. ;
  62. ; BDOS entry point and function codes
  63. ; 
  64. base    equ    0    ; base address of "standard" CP/M system
  65. bdos    equ    base+5    ; CP/M BDOS entry address
  66. msgfc    equ    9    ; message function
  67. resdsk    equ    13    ; reset disk system
  68. offc    equ    15    ; open file
  69. cffc    equ    16    ; close file
  70. wrfc    equ    21    ; write record
  71. mffc    equ    22    ; make file
  72. sdma    equ    26    ; set dma address
  73. ; 
  74. ; secondary FCB field definitions
  75. ; 
  76. fn    equ    1    ; file name field (rel)
  77. ft    equ    9    ; file type field (rel)
  78. ex    equ    12    ; file extent field (rel)
  79. frc    equ    15    ; file record count (rel)
  80. nr    equ    32    ; next record field (rel)
  81. ; 
  82. ; ASCII control characters
  83. ; 
  84. cr    equ    0dh    ; carriage return
  85. lf    equ    0ah    ; line feed
  86. bel    equ    07h    ; bell signal
  87. ;
  88. ;
  89.     org    base+100h
  90. ;
  91.     lxi    h,0    ; save old stack pointer
  92.     dad    sp
  93.     shld    oldstk
  94.     lxi    sp,stack; make a new stack pointer
  95.     lxi    d,initmsg    ; Forth Screen initialization in progress
  96.     mvi    c,msgfc
  97.     call    bdos
  98.     call    reset    ; reset disk in case it's R/O
  99. init4th:call    open    ; attempt to open RESERVED.4TH
  100.     inr    a    ; check CP/M return code
  101.     jnz    makeok    ; RESERVED.4TH already exist?
  102.     call    make    ; make new file
  103.     inr    a    ; check CP/M return code
  104.     jnz    makeok
  105.     lxi    d,dirful; oops...disk directory is full
  106. exit:    mvi    c,msgfc
  107.     call    bdos
  108.     lhld    oldstk    ; get old CP/M stack pointer
  109.     sphl
  110.     ret
  111. ;
  112. ; RESERVED.4TH exists, so set the FCB entry for next append to file
  113. ;
  114. makeok:        
  115. ;
  116.     lxi    d,active; indicate disk activity with "."
  117.     mvi    c,msgfc
  118.     call    bdos
  119.     call    setdma    ; set dma for record to write
  120.     call    write    ; write it out...
  121.     push    psw    ; save possible error code
  122.     lda    fcb+frc    ; get record count
  123.     sta    fcb+nr    ; make next record
  124.     pop    psw    ; get possible error code
  125.     ora    a    ; disk full yet, all available records?
  126.     jz    makeok    ; do more records, if not
  127.     call    close    ; close-up shop, and go home
  128.     lxi    d,dskful; Forth Screens are now initialized...
  129.     jmp    exit    ; exit to CP/M
  130. ; 
  131. ;  reset - reset disk
  132. ;
  133. reset:        
  134.     push    h
  135.     push    d
  136.     push    b
  137.     mvi    c,resdsk
  138.     call    bdos
  139.     pop    b
  140.     pop    d
  141.     pop    h
  142.     ret
  143. ; 
  144. ; open - open disk file
  145. ; 
  146. open:        
  147.     push    h
  148.     push    d
  149.     push    b
  150.     lxi    d,fcb
  151.     mvi    c,offc
  152.     call    bdos
  153.     pop    b
  154.     pop    d
  155.     pop    h
  156.     ret
  157. ;
  158. ; setdma - set dma for record
  159. ;
  160. setdma:
  161.     push    h
  162.     push    d
  163.     push    b
  164.     lxi    d,dbuf
  165.     mvi    c,sdma
  166.     call    bdos
  167.     pop    b
  168.     pop    d
  169.     pop    h
  170.     ret
  171. ;
  172. ; write - write record
  173. ;
  174. write:
  175.     push    h
  176.     push    d
  177.     push    b
  178.     lxi    d,fcb
  179.     mvi    c,wrfc
  180.     call    bdos
  181.     pop    b
  182.     pop    d
  183.     pop    h
  184.     ret
  185. ; 
  186. ; close - close disk file
  187. ; 
  188. close:        
  189.     push    h
  190.     push    d
  191.     push    b
  192.     lxi    d,fcb
  193.     mvi    c,cffc
  194.     call    bdos
  195.     pop    b
  196.     pop    d
  197.     pop    h
  198.     ret
  199. ; 
  200. ; make - make new disk file
  201. ; 
  202. make:        
  203.     push    h
  204.     push    d
  205.     push    b
  206.     lxi    d,fcb
  207.     mvi    c,mffc
  208.     call    bdos
  209.     pop    b
  210.     pop    d
  211.     pop    h
  212.     ret
  213. ;
  214.  
  215. initmsg:db    cr,lf,'Forth Screen initialization in progress',cr,lf,'$'
  216. ;
  217. active:    db    '.$'
  218. ;
  219. dirful:    db    cr,lf,'Oops, this diskette is already full!$'
  220. ;
  221. dskful:    db    cr,lf,lf,'Forth Screen initialization completed'
  222.  
  223.     if    SYS
  224.     db    ' as (RESERVED.4TH)$'
  225.     endif        ; SYS
  226.  
  227.     if    not SYS
  228.     db    ' as RESERVED.4TH$'
  229.     endif        ; SYS
  230.  
  231. ;
  232. fcb:    db    2    ; initialize diskette in B: drive
  233.  
  234.     if    SYS
  235.     db    'RESERVED4','T'+80H,'H'
  236.     endif        ; SYS
  237.  
  238.     if    not SYS
  239.     db    'RESERVED4TH'
  240.     endif        ; SYS
  241.  
  242.     db    0,0,0,0,0,0,0,0,0,0
  243. ;
  244. ; data area
  245. ; 
  246.     ds    128    ; 64 level stack
  247. stack    equ    $    ;local stack
  248. ;
  249. oldstk        
  250.     ds    2    ; storage for old CP/M stack pointer
  251. ;
  252. dbuf:    db    '                '    ; use blanks for initialization data
  253.     db    '                '
  254.     db    '                '
  255.     db    '                '
  256.     db    '                '
  257.     db    '                '
  258.     db    '                '
  259.     db    '                '
  260. ;
  261.     end
  262.