home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / DATABASE / DIMS103.ARK / DGETP.ASC < prev    next >
Text File  |  1986-12-07  |  6KB  |  225 lines
  1. 10 PRINT"This program must be entered via DIMS
  2. 20 STOP
  3. 1000 GOSUB 2460 'cs
  4. 1010 PRINT:PRINT TAB(30);"DGET 1.04 - March 12, 1984
  5. 1020 ' by Dan Dugan -- public domain
  6. 1030 PRINT
  7. 1040 DEFINT A-Z
  8. 1050 COMMON I,J,K,X,Y,T$,R$,S$,T1$,SKIPPARSE,FT,SEARCH,
  9.     C,N,NC,P6,P7,P8,P9,PI,S,T,T1,T2,C(),B$(),N$(),
  10.     SEARCHWORD$(),SEARCHFIELD(),SKIPWORD$(),LOOKFIELD(),DD$(),F$,FT$
  11. 1060 DIM DEST(30),USED(30),B1$(30):INREC=0
  12. 1070 '
  13.  
  14.                 OPEN SOURCE FILE
  15.  
  16. 1080 PRINT:INPUT"Name of source file";X$
  17. 1085 IF X$="" THEN 2390
  18. 1090 GOSUB 2490:F2$=Y$        'ucv
  19. 1100 IF MID$(F2$,2,1)=":" THEN 1120
  20. 1110 F2$=DD$(5)+F2$
  21. 1120 '
  22.  
  23.         TEST FOR EXISTENCE
  24.  
  25. 1130 ON ERROR GOTO 1160
  26. 1140    OPEN"I",3,F2$
  27. 1150    ON ERROR GOTO 0:GOTO 1200    'ok
  28. 1160 CLOSE 3
  29. 1170 IF ERR=53 THEN CLOSE 3:PRINT"File not found":RESUME 1070
  30. 1180 IF ERR=64 THEN PRINT"Bad file name, try again.":RESUME 1070
  31. 1190 ON ERROR GOTO 0
  32. 1200 '
  33.  
  34.                 ENTER SEQUENCE OF FIELDS
  35.  
  36. 1210 PRINT:PRINT"Here's the first line of "F2$".
  37. 1220 LINE INPUT#3,T$
  38. 1230 PRINT:PRINT T$
  39. 1240 CLOSE 3:OPEN"I",3,F2$
  40. 1250 PRINT:PRINT"Would you like to re-assign or skip fields? (n/y) ";:A$=INPUT$(1)
  41. 1252 IF A$="y" OR A$="Y" THEN 1260 ELSE FOR I=1 TO NC:DEST(I)=I:NEXT:NF=NC:PRINT:GOTO 1370
  42. 1260 PRINT:FOR I=1 TO NC:USED(I)=0:NEXT
  43. 1265 PRINT:INPUT"Number of fields in source file";NF:PRINT
  44. 1270 FOR I=1 TO NF
  45. 1280    PRINT"Destination field of field"I"(enter 0 to ignore)";:INPUT DEST(I)
  46. 1290    IF DEST(I)>NC THEN PRINT "This file only has"NC"fields.":GOTO 1280
  47. 1300    IF DEST(I)=0 THEN 1330
  48. 1310    IF USED(DEST(I)) THEN PRINT"Won't accept putting two fields into one.":GOTO 1280
  49. 1320    USED(DEST(I))=1
  50. 1330 NEXT
  51. 1340 PRINT:PRINT"Is this ok (y/n)? ";
  52. 1350 A$=INPUT$(1):PRINT A$
  53. 1360 IF A$<>"y" THEN GOTO 1200
  54. 1370 PRINT
  55. 1380 '
  56.  
  57.                 READ FILE
  58.  
  59. 1390 GOSUB 2410            'exit
  60. 1400 IF EOF(3) THEN 2360
  61. 1410 FOR I=1 TO NC:B$(I)="":NEXT
  62. 1420 LINE INPUT #3,T$
  63. 1430 PRINT"+";:INREC=INREC+1:GOSUB 2580         'parse into B1$ array j=fields found
  64. 1440 IF J<>NF THEN 1450 ELSE 1470
  65. 1450 IF P9 THEN PRINT CHR$(7);:LPRINT:LPRINT"Input file line"INREC"defective."
  66. 1460 PRINT:PRINT"Input file line"INREC"defective."CHR$(7)
  67. 1470 FOR I=1 TO J 
  68. 1480    IF DEST(I) THEN 1490 ELSE 1520
  69. 1490    QUOTE=INSTR(T$,CHR$(126))
  70. 1500    IF QUOTE THEN MID$(T$,QUOTE,1)=CHR$(34):GOTO 1490
  71. 1510    B$(DEST(I))=B1$(I)
  72. 1520 NEXT
  73. 1530 '
  74.  
  75.  
  76.                 SEARCH
  77.  
  78. 1540 IF SEARCH<>2 THEN 1590
  79. 1550 '
  80.  
  81.         FIND
  82.  
  83. 1560 IF INSTR(T$,SEARCHWORD$(0))=0 THEN 2200    'skip
  84. 1580 GOTO 1830
  85. 1590 '
  86.  
  87.         FIELD SEARCH
  88.  
  89. 1600 J=0 '            check for skips first
  90. 1610 IF SKIPWORD$(J)="" THEN 1700 ' try search then
  91. 1620 IF LOOKFIELD(J)<>0 THEN 1660 ' look in field
  92. 1630 IF INSTR(T1$,SKIPWORD$(J))<>0 THEN 2200 ' check whole rec - skip it
  93. 1640 J=J+1
  94. 1650 GOTO 1610
  95. 1660 IF INSTR(B$(LOOKFIELD(J)),SKIPWORD$(J))<>0 THEN 2200 ' field compare - skip
  96. 1670 IF B$(LOOKFIELD(J))="" AND SKIPWORD$(J)="_" THEN 2200    'blank
  97. 1680 J=J+1
  98. 1690 GOTO 1610
  99. 1700 IF SEARCHWORD$(0)="" THEN 1810 ' don't care so print it
  100. 1710 J=0: GOTO 1730 '        now search
  101. 1720 IF SEARCHWORD$(J)="" THEN 2200 ' hesitate no longer
  102. 1730 IF SEARCHFIELD(J)<>0 THEN 1770 ' field
  103. 1740 IF INSTR(T1$,SEARCHWORD$(J))<>0 THEN 1810 ' found it
  104. 1750 J=J+1
  105. 1760 GOTO 1720
  106. 1770 IF INSTR(B$(SEARCHFIELD(J)),SEARCHWORD$(J))<>0 THEN 1810
  107. 1780 IF B$(SEARCHFIELD(J))="" AND SEARCHWORD$(J)="_" THEN 1810
  108. 1790 J=J+1
  109. 1800 GOTO 1720
  110. 1810 '
  111.  
  112.         GET READY TO DO IT
  113.  
  114. 1830 '
  115.  
  116.  
  117.                 PAUSE CONTROLS (TERM DEP IF UPPERCASE ONLY)
  118.  
  119. 1840 GOSUB 2410            ' exit returns A
  120. 1850 IF A=122 THEN 2100        ' z means go on
  121. 1860 PRINT INREC;B$(1);TAB(30);"Ready (SPACE/z/ESC) > ";
  122. 1870 A$=INPUT$(1):A=ASC(A$):IF A=27 THEN 2360    ' finish
  123. 1880 PRINT A$;:IF A=13 OR A=32 OR A=122 THEN 2100
  124. 1890 GOSUB 2410            ' exit
  125. 2100 '
  126.  
  127.                 ADD RECORD TO DIMS FILE
  128.  
  129. 2110 T$="":NR=NR+1
  130. 2120 FOR J=1 TO NC
  131. 2130    IF LEN(T$)+LEN(B$(J))+1>FT*128
  132.     THEN 2140 ELSE 2160
  133. 2140    IF P9 THEN LPRINT "Input line"INREC"too long."
  134. 2150    PRINT"Input line"INREC"too long."CHR$(7)
  135. 2160    T$=T$+B$(J)+CHR$(126)
  136. 2170 NEXT
  137. 2180 N=N+1:PRINT INREC"="N:PRINT T$;
  138. 2190 GOSUB 2220:PRINT" *";:GOSUB 2290:PRINT"!":C=1
  139. 2200 '
  140.  
  141.                 LOOP
  142.  
  143. 2210 GOTO 1380
  144. 2220 '
  145.  
  146.         (SUB) WRITE T$ AS RECORD # N
  147.  
  148. 2230 ON FT GOTO 2260,2240
  149. 2240 LSET R$=MID$(T$,129)    'latter half
  150. 2250 PUT #1,FT*N+2
  151. 2260 LSET R$=LEFT$(T$,128)    'first half
  152. 2270 PUT #1,FT*N+1
  153. 2280 RETURN
  154. 2290 '
  155.  
  156.         (SUB) WRITE T$ AS DUPE REC N
  157.  
  158. 2300 ON FT GOTO 2330,2310
  159. 2310 LSET S$=MID$(T$,129)
  160. 2320 PUT #2,FT*N+2
  161. 2330 LSET S$=LEFT$(T$,128)
  162. 2340 PUT #2,FT*N+1
  163. 2350 RETURN
  164. 2360 '
  165.  
  166.                 FINISH
  167.  
  168. 2370 CLOSE 3
  169. 2380 PRINT:PRINT NR"records added.
  170. 2390 PRINT:PRINT TAB(32)"Re-loading DEDIT.
  171. 2400 CHAIN DD$(1)+"DEDIT",1000
  172. 2410 '
  173.  
  174.  
  175.                 EXIT TEST (TERM DEP)
  176.  
  177. 2420 X$=INKEY$
  178. 2430 IF X$<>"" THEN A=ASC(X$)
  179. 2440 IF A=27 THEN CLOSE 3:GOTO 2360    'use ESC to escape listing
  180. 2450 RETURN
  181. 2460 '
  182.  
  183.  
  184.                 CLEAR SCREEN (TERM DEP)
  185.  
  186. 2470 PRINT CHR$(12);
  187. 2480 RETURN
  188. 2490 '
  189.  
  190.                 (SUB) UCV
  191.  
  192. 2500 Y$=""
  193. 2510 FOR K=1 TO LEN(X$)
  194. 2520    Y$=Y$+CHR$(32)
  195. 2530    X=ASC(MID$(X$,K,1))
  196. 2540    IF 96<X AND X<123 THEN MID$(Y$,K,1)=CHR$(X-32):GOTO 2560
  197. 2550    MID$(Y$,K,1)=MID$(X$,K,1)
  198. 2560 NEXT
  199. 2570 RETURN
  200. 2580 '
  201.  
  202.                 (SUB) PARSE ,-DELIM. RECORD T$ > B1$ ARRAY
  203.  
  204. 2590 '                returns J = number of fields found
  205. 2600 FOR J=1 TO NF:B1$(J)="":NEXT
  206. 2610 J=0
  207. 2620 ' process loop
  208. 2630    J=J+1:IF J=NF THEN 2730
  209. 2640    X=INSTR(T$,CHR$(44)) 'comma
  210. 2650    IF X=0 THEN 2730    'must be last field
  211. 2660    Y=INSTR(T$,CHR$(34))     'quote
  212. 2670    IF Y=0 OR ( Y<>0 AND X<Y ) THEN 2700 ELSE 2680 'comma before quote
  213. 2680    Z=INSTR(Y+1,T$,CHR$(34))
  214. 2690    X=INSTR(Z+1,T$,CHR$(44))'loc of next comma after close quote
  215. 2700    B1$(J)=MID$(T$,1,X-1):GOSUB 2760
  216. 2710 '        TRIM OFF USED PART
  217. 2720    T$=MID$(T$,X+1):GOTO 2620
  218. 2730 '        LAST FIELD
  219. 2740    B1$(J)=T$:GOSUB 2760
  220. 2750 RETURN
  221. 2760 '                (SUB) TRIM QUOTES OFF STRING
  222. 2770 IF LEFT$(B1$(J),1)=CHR$(34) THEN B1$(J)=RIGHT$(B1$(J),LEN(B1$(J))-1)
  223. 2780 IF RIGHT$(B1$(J),1)=CHR$(34) THEN B1$(J)=LEFT$(B1$(J),LEN(B1$(J))-1)
  224. 2790 RETURN
  225. N B1$(J)=RIGHT$(B1$(J),LEN(B1$(J)