home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / CPM3 / CCP105P.ARK / CCP105.MAC < prev    next >
Text File  |  1986-10-17  |  82KB  |  3,677 lines
  1. ;
  2. ;This is the main module for both the CCP and CMDRUN.
  3. ;
  4. ;Assemble CCPHDR.MAC to produce the CCP, and LRUNHDR.MAC to
  5. ; produce the library processor.
  6. ;
  7. ;Version 1.02A    10/03/85 - Fixed bugs relating to loading of .SUB
  8. ;        files from COMMAND.LBR
  9. ;
  10. ;Version 1.02B  11/04/85 - Fixed bug which caused bad drive/user parse to
  11. ;        return with indication of a good drive or user parse (eg:
  12. ;        CUG: would return with a good drive C: parse). Also, CCP
  13. ;        now checks for a valid drive/user spec whenever a file is
  14. ;        to be run (ie: COMfiles, SUBfiles and PRLfiles). Also added
  15. ;        EXPAND,PRINT0 and WHLLBR equates and equates for user's own
  16. ;        MAXUSR, WHEEL, and MAXUSR boot values (see CCPHDR.MAC for
  17. ;        details).
  18. ;                        - Stuart Rose
  19. ;
  20. ;Version 1.03    11/06/85 - Removed PRINT0 equate, changed EXPAND and
  21. ;        WHLLBR equate to flag options.  Fixed more bugs relating
  22. ;        to library command processor.  CMDRUN now properly scans
  23. ;        more than one command library along the drive search chain.
  24. ;
  25. ;Version 1.04    03/08/85 - Added EXDRV and EXUSR variables for CMDRUN
  26. ;
  27. ;        04/14/86 - Fixed bug that prevents nested multiple command
  28. ;        lines from being run properly.  That is, if a multiple command
  29. ;        is issued, and one of the commands issues a chain command
  30. ;        with a multiple command, the initial multiple command line
  31. ;        would be lost, leaving an active RSX, which will not go
  32. ;        away.  Added a name to RSX containing next command.
  33. ;        (NEXTCMND)
  34. ;
  35. ;        07/13/86 - Added option to display time-on-system of current
  36. ;        caller in an RCPM running under BYE509 or newer.  If TIMEON
  37. ;        is YES, and both TIME and BYECHK are YES, then if BYE is
  38. ;        active displays time-on-system rather than time-of-day.
  39. ;        Set CCPPLUS to YES in BYE to use this option.
  40. ;        (Thanks to Stuart Rose)
  41. ;
  42. ;        07/14/86 - Changed from using a flag byte to equates in
  43. ;        CCPHDR.MAC and LRUNHDR.MAC.  It is now necessary to 
  44. ;        reassemble the source to change options.  With the new
  45. ;        fixes and options in version 1.04, the CCP will be larger
  46. ;        than 25 sectors, and may require special loading or BIOS
  47. ;        modifications to accept a larger CCP.
  48. ;
  49. ;
  50. ;Version 1.05    9/1986 - Added history mechanism,print0, and makecolon fix
  51. ;
  52. ;        Added history mechanism that is similar to 
  53. ;        Unix (tm of AT&T) csh's. This includes the internal
  54. ;        'h' command that displays the history.  This option
  55. ;        is probably only acceptable with the "temp-disk" being
  56. ;        a RAMDISK or possibly a fast Harddisk.  This
  57. ;        feature also gives a mechanism for additional extension.
  58. ;
  59. ;        Added print0 back again.
  60. ;
  61. ;        Added makecolon so when  running "make", where 
  62. ;        commands generated can have leading colons, an error
  63. ;        set by one of the commands will terminate the entire
  64. ;        rest of the (nested) submit file(s).
  65. ;
  66. ;                        -Mike Kersenbrock
  67.  
  68. bdos         EQU    5    ;Bdos entry point
  69. USRDSK         EQU    4    ;User/disk (for CP/M 1.4,2.2 compatibility)
  70. FCB         EQU    5CH    ;default FCB
  71. FCB2         EQU    6CH    ;default 2nd FCB
  72. FCBCR         EQU    7CH    ;CR field of FCB
  73. LOADDRV     EQU    50H    ;.COM file load drive
  74. PASS1ADR     EQU    51H    ;password 1 address
  75. PASS1LEN     EQU    53H    ;password 1 length
  76. PASS2ADR     EQU    54H    ;password 2 address
  77. PASS2LEN     EQU    56H    ;password 2 length
  78. SIZECMDLINE     EQU    0E7H    ;command line max length    ; V. 1.05
  79.     if    ccp
  80.  
  81. ;---------------------------------------------------------------
  82. ;Loader save area and entry points
  83.  
  84. SCBBASE     EQU    11bH    ;address of System Control Block
  85. MEMBASE     EQU    11dH    ;location of common memory base
  86. CHKRSX         EQU    11eH    ;loader check RSX entry point
  87. RELOC         EQU    121H    ;loader relocate entry point
  88. SETLOAD     EQU    124H    ;loader set load entry point
  89. SETNEXT     EQU    127H    ;loader set next RSX pointer entry point
  90. SETRSX         EQU    12aH    ;loader set RSX pointers entry point
  91. xbdos        equ    12dh    ;save IX and call bdos entry point
  92.  
  93.     endif        ;CCP
  94.  
  95. ;
  96. ;--------------------------------------------------------------
  97.  
  98. maxdrv         EQU    3dh    ;ZCPR maxdrive
  99. wheel         EQU    3eh    ;ZCPR wheel
  100. maxusr         EQU    3fh    ;ZCPR maxuser
  101.  
  102. ;........
  103. ;
  104. ;Main entry point.  The BIOS loads the CCP into the tpa.
  105. ;The loader module has a JMP START at 100H to bring us here.
  106. ;
  107.  
  108. START:
  109.     LD    SP,STACK    ;set up local stack
  110.     LD    HL,CCPRET    ;
  111.     PUSH    HL        ;push CCP return onto stack
  112.     LD    DE,SCBPB    
  113.     LD    C,49        ;RETURN BASE PAGE OF SYSTEM CONTROL BLOCK
  114.     CALL    BDOS
  115.     ld    l,80h        ;set up for IX register
  116.     LD    (SCBBASE),HL    ;Save address of SCB
  117.     push    hl
  118.     pop    ix        ;IX points to SCB (xx80H)
  119.  
  120.     if    ccp
  121.  
  122.     LD    a,(ix+7aH)    ;0FAH = COMMON MEMORY BASE PAGE
  123.     LD    (MEMBASE),A    ;Save common mem base page
  124.     LD    a,(ix+19H)    ;99H = BASE PAGE OF BDOS SYSTEM
  125.     LD    (BDOSBASE),A    ;Save Base page of BDOS system
  126. ;
  127. ;CHECK TO SEE IF ANY RSX'S AND/OR LOADER PRESENT
  128. ;
  129.     LD    A,(BDOS+2)    ;Get top of TPA page
  130.     SUB    (ix+19H)    ;compare with BDOS page
  131.     jr    NZ,NOLOAD    ;jump if loader already in place
  132. ;
  133. ;need to relocate the loader into high ram
  134. ;
  135.     LD    BC,(LOADLEN)    ;PREPARE FOR RELOCATION
  136.     CALL    SETLOAD        ;Set up relocation paramaters
  137.     LD    H,E
  138.     LD    L,E
  139.     CALL    RELOC        ;relocate the loader
  140.     LD    HL,(BDOS+1)
  141.     LD    L,E
  142.     LD    C,6
  143.     CALL    MOVEC        ;move the serial number into place
  144.     LD    E,0BH
  145.     CALL    SETNEXT        ;Set up next address in loader RSX header
  146. NOLOAD:
  147.     if    byechk
  148.  
  149.     LD    DE,rsxpb    ;point to call RSX pb
  150.     CALL    rsx        ;check for bye present
  151.     LD    (byeact),A    ;save BYE active flag
  152.  
  153.     endif            ; byechk
  154.  
  155.     LD    C,98        ;FREE BLOCKS
  156.     CALL    xbdos        ;free blocks
  157.     LD    (ix+53H),'$'    ;0B6H = String delimiter
  158.     LD    (ix+66H),1    ;0E6H = MULTI-SECTOR COUNT
  159.     LD    (ix+67H),0    ;Init BDOS error mode
  160.     LD    (ix+4FH),3    ;0CFH = CONSOLE MODE LOW BYTE
  161.     LD    (ix+50H),0    ;Init Console mode high byte
  162.     ld    a,(ix+2bh)    ;get submit drive
  163.     ld    (subfcb),a    ;save it
  164.     bit    5,(ix+34H)    ;0B4H = SYSTEM FLAGS (b5=reset disk system)
  165.     ld    c,13
  166.     CALL    NZ,xbdos    ;Reset disk system if set
  167.     bit    1,(ix+33H)    ;0B3H = SYSTEM FLAGS (b1=RSX flag)
  168.     CALL    Z,CHKRSX    ;Delete inactive RSXs if clear
  169.     res    1,(ix+33H)    ;Clear RSX flag
  170.  
  171.     endif        ;CCP
  172.  
  173.     LD    c,25
  174.     CALL    xbdos        ;get current drive
  175.     LD    (disknum),A    ;save it
  176.     LD    BC,USERNUM    ;Point to our user number save
  177.  
  178.     if    ccp
  179.  
  180.     LD    A,(ix+60h)    ;Get BDOS user number
  181.  
  182.     else        ;if not CCP
  183.  
  184.     ld    a,(ix+30h)    ;get CCP user number
  185.  
  186.     endif        ;not CCP
  187.  
  188.     LD    (BC),A        ;Save it for us
  189.  
  190.     if    ccp
  191.  
  192.     LD    A,(ix+30H)    ;Get CCP user number
  193.     bit    6,(ix+33h)    ;Bit 6 = change default u/d to last program
  194.     jr    NZ,OLDUSR    ;Jump if to set to last program user number
  195.     LD    (BC),A        ;Save CCP user number
  196. OLDUSR:
  197.     LD    (ix+60h),A    ;Set the BDOS user number
  198.     INC    BC        ;Point to our drive save
  199.     LD    A,(BC)        ;Get BDOS disk
  200.     jr    NZ,OLDDSK    ;Jump if to set to last program disk number
  201.     LD    A,0FFH        ;Flag that we must login drive
  202. OLDDSK:
  203.     res    6,(ix+33h)    ;reset default u/d bit
  204.     LD    (BC),A        ;Save disk number for us
  205.     INC    BC        ;POINT TO CURDSK
  206.     LD    A,(ix+2fH)    ;Get CCP disk
  207.     LD    (BC),A        ;Save it for us
  208.     CALL    seldsk        ;select drive
  209.     LD    DE,rsx66    ;point to RSX function 66
  210.     CALL    rsx        ;see if directory names loaded
  211.     OR    a
  212.     jr    NZ,noroot    ;jump if no directory names
  213.     LD    (diradr),HL    ;save directory name table address
  214. noroot:
  215.     bit    7,(ix+33H)    ;Bit 7 of B3H = chain flag
  216.     jr    Z,NOCHAIN    ;jump if normal CCP command
  217.     LD    HL,80H        ;Point to location of chain command
  218.  
  219.     else        ;if not CCP
  220.  
  221.     ld    hl,81h        ;point to location of command
  222.  
  223.     endif        ;not CCP
  224.  
  225. ;
  226. ;MOVE THE COMMAND LINE FOR PROCESSING
  227. ;
  228. MOVCMD:
  229.     LD    DE,CMDLINE    ;Point to internal command line buffer
  230.     LD    BC,7FH        ;Length of move
  231.     LD    A,C
  232.     LD    (DE),A        ;Save command line max length
  233.     INC    DE
  234.     ldir            ;Move command line into place
  235.  
  236.     if    ccp
  237.  
  238.     jp    DOCMD        ;And go process it.
  239. NOCHAIN:            ;Here if no chain function call
  240.     bit    1,(ix+35H)    ;0B5H = SYSTEM FLAGS (b1=cold start)
  241.     jr    nz,nocold    ;jump if normal warm start
  242.  
  243.     if   makecolon                        ; V1.05
  244.  
  245.     xor    a        ;get a zero            ; V1.05
  246.     LD    (ix+2cH),a    ;Zero program return code    ; V1.05
  247.     LD    (ix+2dH),a                    ; V1.05
  248.     
  249.     endif ; makecolon                    ; V1.05
  250.  
  251.     set    1,(ix+35h)    ;SET COLD START FLAG
  252.     ld    a,1
  253.     LD    (msgflag),A    ;Save copy for us
  254.     ld    c,13
  255.     CALL    xbdos        ;reset disk system on cold boot
  256.     ld    hl,maxdrv    ;point to ZCPR maxdrv
  257.     ld    (hl),mydrv    ;Init ZCPR MAXDRV         ; V1.02B
  258.     inc    hl
  259.     ld    (hl),mywhl    ;Init ZCPR WHEEL        ; V1.02B
  260.     inc    hl
  261.     ld    (hl),myusr    ;Init ZCPR MAXUSR        ; V1.02B
  262.     LD    HL,PROFSUB    ;point to 'PROFILE.SUB' command
  263.     jr    MOVCMD        ;execute PROFILE.SUB on cold start
  264.  
  265. PROFSUB:
  266.     DEFB    'PROFILE.S',0    ;Cold start command
  267. ;
  268. ; 
  269. ;
  270. NOCOLD:
  271.     CALL    SETFLG        ;SETFLG sets Bits 7 & 5 in offset B4H
  272.     CALL    CRLF        ;Turn up a new line
  273.     bit    6,(ix+24h)    ;test for erase of $$$.SUB file
  274.     ld    c,19
  275.     call    nz,dosubfcb    ;erase any $$$.SUB file
  276.     res    6,(ix+24h)    ;reset erase $$$.SUB file
  277.  
  278. ;.........
  279. ;
  280. ;Internal commands and errors return here
  281. ;
  282.  
  283. CCPRET:
  284.     LD    sp,STACK-2    ;Set up the stack
  285.     LD    HL,CCPRET
  286.     PUSH    HL        ;Push return onto stack
  287.     CALL    SETFLG        ;Set bits 7 & 5 in offset B4H
  288. ;
  289. ;DISPLAY THE SYSTEM PROMPT ( A> )
  290. ;
  291.     call    prompt        ; V 1.05 (code change, but same logic)
  292.     jp    prmpt2
  293.  
  294.  
  295. prompt:    
  296.     if    time
  297.  
  298.     LD    E,'['
  299.     CALL    co        ;display "["
  300.  
  301.     if    timeon and byechk
  302.  
  303.     ld    a,(byeact)    ;get BYE active flag
  304.     or    a        ;is BYE running?
  305.     jr    nz,shwtim    ;nope, just show time
  306.     ld    c,79
  307.     call    xbdos        ;get time on from BYE
  308.     call    prtnum        ;display time on
  309.     ld    de,minmsg    ; display " min."
  310.     ld    c,9
  311.     call    xbdos
  312.     jr    st1        ;clean up
  313. shwtim:
  314.  
  315.     endif            ; timeon and byechk
  316.  
  317.     LD    DE,datpb
  318.     LD    c,105
  319.     CALL    xbdos        ;return time
  320.     LD    HL,datpb+3
  321.     LD    a,(HL)        ;get minutes
  322.     PUSH    AF        ;Save for later
  323.     DEC    HL        ;Point to hours
  324.     LD    A,(HL)
  325.     CALL    hexprt        ;display hours
  326.     LD    E,':'        ;separater
  327.     CALL    co
  328.     POP    AF        ;get minutes
  329.     CALL    hexprt        ;display minutes
  330. st1:
  331.     LD    E,']'
  332.     CALL    co
  333.     LD    E,' '    
  334.     CALL    co
  335.  
  336.     endif            ; time
  337.  
  338.     CALL    PCURDSK        ;Display the current drive
  339.     LD    A,(USERNUM)    ;get user number
  340.     
  341.     if  not print0                        ; V 1.05
  342.  
  343.     or    a                        ; V 1.05
  344.     jr    z,noprtusr    ;No user number if it is zero   ; V 1.05
  345.  
  346.     endif   ; not print0
  347.  
  348.     call    PRTNUM        ;Display user number         ; V 1.02B
  349. noprtusr:                            ; V 1.05
  350.     bit    7,(ix+24h)    ;test for directory name display
  351.     jr    Z,nodirnm    ;jump if no directory name display
  352.     LD    HL,(diradr)    ;get directory name address
  353.     LD    a,h
  354.     OR    l
  355.     jr    Z,norfile    ;jump if null
  356.     EX    DE,HL
  357.     LD    HL,rootdrv    ;point to drive returned by rootget
  358. rootloop:
  359.     CALL    rootget        ;get an entry
  360.     jr    Z,norfile    ;jump if at end
  361.     LD    A,(curdsk)    ;get current drive
  362.     CP    (HL)        ;same as table entry?
  363.     jr    NZ,rootloop
  364.     INC    HL        ;point to user number from rootget
  365.     LD    A,(usernum)    ;get current user
  366.     CP    (HL)        ;same as table entry?
  367.     jr    Z,rootok
  368.     DEC    HL
  369.     jr    rootloop
  370. rootok:
  371.     LD    a,':'
  372.     CALL    cono        ;display a colon
  373.     LD    HL,rootname    ;point to directory name
  374.     LD    c,' '        ;it terminates with a blank
  375.     CALL    prtname        ;print the directory name
  376. norfile:
  377.     LD    DE,rootrsx    ;point to RSX function 65
  378.     CALL    rsx        ;Any LBR RSX's will print their names
  379. nodirnm:
  380.     LD    A,'>'    
  381.     JP    CONO        ;Display the system prompt
  382.  
  383. prmpt2:    LD    DE,0B1BAH
  384.     CALL    MOVSCB        ;Move offsets B1,B2 to BA,BB in SCB
  385.     OR    A        ;Test for address of second command line
  386.     PUSH    AF        ;save flags on stack
  387.     jr    z,notmulti
  388.     res    7,(ix+34h)    ;Clear Multiple command line flag
  389. notmulti:
  390.     CALL    GETLINE        ;Get command
  391.     CALL    CRFLGA        ;clear bits 7 & 5 in B4H
  392.     POP    AF        ;Restore 2nd command flag
  393.     CALL    NZ,CHK2ND    ;Check 2nd command line
  394. ;........
  395. ;
  396. ;Here to process command line
  397. ;
  398. DOCMD:
  399.     endif        ;CCP
  400.  
  401.     xor    a
  402.     ld    (ix+25h),a    ;Init user number for load overlay function
  403.  
  404.     if    ccp
  405.  
  406.     ld    (subflag),a    ;init submit flag
  407.     ld    a,(ix+24h)    ;get submit user number
  408.     and    0e0h        ;set it to default
  409.     ld    (ix+24h),a    ;and save it
  410.  
  411.     endif        ;CCP
  412.  
  413.     bit    6,(ix+34h)    ;test default page mode
  414.     jr    nz,oldpmode
  415.     ld    a,(ix+49h)    ;get default page mode
  416.     ld    (ix+48h),a    ;reset default page mode
  417. oldpmode:
  418.     CALL    SCANLINE    ;get first item in command line
  419.     RET    Z        ;Return to CCPRET if nothing there
  420.     LD    DE,CMDFCB    ;Point to command FCB
  421.     CALL    CHKDRV        ;Check for drive spec and parse command line
  422.     LD    A,(FILETYPE)    ;Get Filetype first byte
  423.     CP    ' '        ;Do we have a filetype?
  424.  
  425.     if    CCP
  426.  
  427.     jr    NZ,FTYPE    ;jump if filetype present
  428.     LD    HL,CMDFCB    ;Point to command FCB
  429.     LD    A,(HL)        ;Get user number
  430.     INC    HL        ; Point to drive in FCB
  431.     OR    (HL)        ;Test for user or drive spec
  432.     INC    HL        ;Point to filename
  433.     LD    A,(HL)        ;get first byte of filename
  434.     jr    NZ,DRVSPEC    ;Jump if drive or user number specified
  435.     LD    HL,(diradr)    ;get directory name address
  436.     LD    a,h
  437.     OR    l
  438.     jr    Z,nocmd        ;jump if not loaded
  439.     EX    DE,HL
  440.     LD    HL,filename    ;point to filename retuned by rootget
  441. rootcloop:
  442.     CALL    rootget        ;get an entry
  443.     jr    Z,nocmd        ;jump if at end
  444.     CALL    scomp        ;is directory name=command?
  445.     jr    NZ,rootcloop
  446.     CALL    chkpass        ;verify if passworded directory
  447.     LD    HL,rootdrv    ;point to directory drive
  448.     LD    a,(HL)
  449.     INC    a
  450.     LD    (filedisk),A    ;save it in command drive
  451.     INC    HL        ;point to directory user
  452.     LD    a,(HL)
  453.     jp    newuser        ;process drive/user change
  454.  
  455.     else        ;if    not ccp
  456.  
  457.     ld    a,1
  458.     jr    nz,setftype
  459.     xor    a
  460. setftype:
  461.     ld    (typeflag),a    ;save filetype flag
  462.     ld    a,(ix+6ch)    ;get temp file drive
  463.     ld    (ix+2bh),a    ;set submit file drive
  464.     ld    (subfcb),a    ;save it
  465.     ld    hl,(cmdfcb)    ;get user/drive spec
  466.     ld    (lbrfcb),hl    ;put it in LBR FCB
  467.     ld    (usrsav),hl    ;and save it            ;V 1.03
  468.     ld    hl,0e704h    ;set up search offset, length    ;V 1.03
  469.     ld    (searoff),hl                    ;V 1.03
  470.     ld    a,(disknum)    ;get default drive        ;V 1.03
  471.     inc    a                        ;V 1.03
  472.     ld    h,a                        ;V 1.03
  473.     ld    l,1                        ;V 1.03
  474.     ld    (searflg),hl                    ;V 1.03
  475. docmpf:                                ;V 1.03
  476.     ld    a,(usernum)                    ;V 1.03
  477.     ld    (ix+60h),a    ;set the user number        ;V 1.03
  478.     ld    hl,0
  479.     ld    (cmdfcb),hl    ;zero user/drive for member
  480.     ld    hl,(usrsav)    ;get user/drive            ;V 1.03
  481.     ld    (lbrfcb),hl    ;put it in LBR FCB        ;V 1.03
  482.     call    cmpftype    ;attempt to open COMMAND.LBR using CPM's
  483.                 ;drive search chain.
  484.     call    lbrread        ;read first library sector
  485.     jr    z,lbrok                        ;V 1.03
  486. badlbr:                                ;V 1.03
  487.     call    ilprt                        ;V 1.03
  488.     db    'Invalid COMMAND.LBR',13,10,0            ;V 1.03
  489.     jr    lbrdone                        ;V 1.03
  490. lbrok:                                ;V 1.03
  491.     ld    hl,buff
  492.     ld    de,lbrcmp
  493.     ld    b,14
  494.     call    comp        ;test for valid library
  495.     jr    nz,badlbr                    ;V 1.03
  496.     ld    hl,(buff+14)    ;get dir length
  497.     ld    (lbrsec),hl    ;save dir length
  498.     ld    hl,buff+32    ;point to first member
  499.     ld    b,3        ; 3 members left
  500.     jr    lbr2
  501. lbr1:
  502.     ld    hl,(lbrsec)
  503.     dec    hl
  504.     ld    (lbrsec),hl    ;decr sector count
  505.     ld    a,h
  506.     or    l
  507.     jr    z,lbrdone                    ;V 1.03
  508.     call    lbrread        ;read a directory sector
  509.     jr    nz,badlbr                    ;V 1.03
  510.     ld    hl,buff
  511.     ld    b,4        ;4 members per sector
  512. lbr2:
  513.     push    bc
  514.     ld    a,(hl)
  515.     or    a        ;active member?
  516.     jr    nz,lbr3
  517.     inc    hl
  518.     ld    (memaddr),hl    ;save member address
  519.     ld    a,(typeflag)
  520.     or    a
  521.     jr    nz,ftype    ;jump if file type present
  522.  
  523.     endif        ;not CCP
  524.  
  525. NOCMD:
  526.     ld    a,(ix+34h)
  527.     and    18h        ;Test bits 3,4 of B4H (file type search order)
  528.     jr    Z,FTYPE        ;Jump if search .COM only
  529.     LD    B,8        ;init B for later
  530.     SUB    B        ;Test for .COM, then .SUB
  531.     jr    Z,NOCMD1    ;Jump if .COM, then .SUB
  532.     LD    B,0        ;Here if order is .SUB, then .COM
  533. NOCMD1:
  534.     PUSH    BC        ;Save search order indicator for 2nd filetype
  535.     CALL    MOVETYPE    ;Move first filetype into FCB (indicator in A)
  536.     CALL    CMPRFTYPE    ;Try First filetype
  537.     POP    AF        ;retrieve second filetype indicator
  538.     CALL    MOVETYPE    ;Move 2nd filetype into FCB
  539. FTYPE:
  540.     CALL    CMPRFTYPE    ;Attempt to execute the command
  541.  
  542.     if    ccp
  543.  
  544.     if    yeslbr
  545.  
  546.     ld    hl,crname    ;Point to CMDRUN fcb
  547.  
  548.     if    whllbr
  549.  
  550.     ld    A,(wheel)    ; get the wheel byte        ; V1.02B
  551.     and    A        ; check for wheel byte set (non-zero); V1.02B
  552.     call    nz,setcmd    ;set up CMDRUN fcb and attempt
  553.  
  554.     else            ; if not whllbr
  555.  
  556.     call    setcmd        ;set up CMDRUN fcb and attempt
  557.  
  558.     endif            ; not whllbr
  559.  
  560.     endif            ; yeslbr
  561.  
  562.     jp    ERRXIT        ;If we returned, then its an error
  563.  
  564.     else        ;if not CCP
  565.  
  566.     ld    hl,(memaddr)    ;get member address
  567.     dec    hl
  568. lbr3:
  569.     pop    bc
  570.     inc    (hl)        ;test for 0ffh
  571.     jr    z,lbrdone                    ;V 1.03
  572.     ld    de,32
  573.     add    hl,de        ;next member
  574.     djnz    lbr2
  575.     jr    lbr1
  576.  
  577. lbrdone:                            ;V 1.03
  578.     ld    a,(duspec)    ;drive/user specified?        ;V 1.03
  579.     or    a                        ;V 1.03
  580.     jp    z,docmpf    ;try again if no drive/user    ;V 1.03
  581.     jp    errxit                        ;V 1.03
  582.  
  583.     endif        ;not CCP
  584.  
  585.     if    ccp
  586.  
  587. ;
  588. ;.........
  589. ;
  590. ;Here if Drive spec or user number in command line
  591. ;
  592. DRVSPEC:
  593.     CP    ' '        ;Test for filename in FCB
  594.     jr    NZ,NOCMD    ;Jump if Drive spec & filename
  595.     CALL    CHKBLANK    ;Check for embedded blanks
  596.     LD    HL,cmdfcb    ;point to command user
  597.     LD    a,(HL)
  598.     DEC    a
  599.     JP    P,sisusr    ;jump if user # specified
  600.     LD    A,(usernum)    ;else get current user #
  601. sisusr:
  602.     INC    a
  603.     LD    (HL),a        ;put user number in command user
  604.     INC    HL        ;point to command drive
  605.     LD    a,(HL)
  606.     DEC    a
  607.     JP    P,sisdrv    ;jump if new drive
  608.     LD    A,(curdsk)    ;else get current drive
  609. sisdrv:
  610.     INC    a
  611.     LD    (HL),a        ;put drive in command drive
  612.     LD    A,(cmdfcb)    ;get command user
  613.     DEC    a
  614. NEWUSER:
  615.     LD    (USERNUM),A    ;Save new user number
  616.     ld    (ix+30h),a    ;Set CCP user number
  617.     ld    (ix+60h),a    ;Set BDOS user number
  618. SAMEUSER:
  619.     LD    A,(FILEDISK)    ;Get drive from FCB
  620.     DEC    A        ;Test it
  621.     RET    M        ;Back to CCPRET if no drive spec
  622.     PUSH    AF        ;Save new drive on stack
  623.     CALL    SELDSK        ;Select new drive
  624.     POP    AF        ;restore new drive
  625.     LD    (CURDSK),A    ;Save it for us
  626.     ld    (ix+2fh),a    ;Set CCP drive, and return to CCPRET
  627.     ret
  628.  
  629. ;..........
  630. ;
  631. ;PRINT DISK IN [A] IF > 0 OR CURRENT DISK
  632. ;
  633. PRTDISK:
  634.     DEC    A        ;Drive specified in FCB?
  635.     JP    P,PRTDSK    ;Jump if specified
  636. ;
  637. ;PRINT CURRENT DISK
  638. ;
  639. PCURDSK:
  640.     LD    A,(CURDSK)    ;Get current drive
  641. ;
  642. ;PRINT DISK IN [A]
  643. ;
  644. PRTDSK:
  645.     ADD    A,'A'        ;convert to ASCII
  646.     jp    CONOUT        ;and print it
  647.  
  648. ;...........
  649. ;
  650. ;SUBMIT FILE FCB
  651. ;
  652. SUBNAME:
  653.     DEFB    0,0,'SUBMIT  COM'
  654.  
  655. ;.............
  656. ;
  657. ;CONSTRUCT SUBMIT COMMAND LINE
  658. ;
  659. SUBMIT:
  660.     LD    A,(DE)        ;Save submit drive
  661.     LD    (ix+2BH),a    ;Save submit drive in SCB
  662.     inc    a        ;non-zero
  663.     ld    (subflag),a    ;set submit flag
  664.     LD    HL,SUBNAME    ;Point to submit file name
  665. setcmd:
  666.     ld    de,cmdfcb
  667.     ld    bc,13        ;13 bytes long
  668.     ldir            ;move it
  669.     ld    hl,cmdline    ;point to command line
  670.     ld    (hl),' '    ;start with a blank
  671.     inc    hl        ;point to second byte
  672.     ld    (pfcb),hl    ;Store its address for Parse
  673.     jr    cmprftype
  674.  
  675.     else        ;if not CCP
  676.  
  677. ;...........
  678. ;
  679. ;Submit file handler for CMDRUN.  The .SUB file is
  680. ;read from the Library, and saved as $$$.SUB in the current
  681. ;CCP drive/user location, and a Chain command is executed
  682. ;to let the CCP handle the submit function.
  683. ;
  684.  
  685. submit:
  686.     ld    (ix+25h),0    ;reset Loader user number
  687.     call    setlbr        ;set up things to read member
  688.     ld    c,19
  689.     call    dosubfcb    ;erase any $$$.SUB file
  690.     ld    c,22
  691.     call    dosubfcb    ;make new $$$.SUB file
  692.     jr    z,smakeok
  693.     call    ilprt
  694.     db    'No directory space for $$$.SUB',0
  695.     rst    0
  696. smakeok:
  697.     ld    hl,(lbrfcb+36)    ;get member length
  698.     inc    h
  699.     dec    h
  700.     jr    nz,longsub    ;.SUB file member must be < 16k
  701.     ld    a,l
  702.     cp    129
  703.     jr    c,slenok
  704. longsub:
  705.     call    ilprt
  706.     db    'SUB member > 16k',0
  707.     rst    0
  708. slenok:
  709.     ld    (ix+66h),a    ;set multi-sector count
  710.     ld    de,stack
  711.     call    setdma        ;set up dma for mass transfer
  712.     call    setlusr        ;set library user if no default
  713.     ld    c,20
  714.     call    xbdos        ;read in the .SUB member
  715.     or    a
  716.     jr    z,sreadok
  717.     call    ilprt
  718.     db    'Cannot read SUB member',0
  719.     rst    0
  720. sreadok:
  721.     ld    c,21
  722.     call    dosubfcb    ;write the $$$.SUB file
  723.     jr    z,swriteok
  724.     call    ilprt
  725.     db    'Out of disk space writing $$$.SUB',0
  726.     rst    0
  727. swriteok:
  728.     ld    c,16
  729.     call    dosubfcb    ;close the $$$.SUB file
  730.     jr    z,scloseok
  731.     call    ilprt
  732.     db    'Cannot close $$$.SUB',0
  733.     rst    0
  734. scloseok:
  735.     ld    (ix+66h),1    ;reset multi-sector count
  736.     call    sdefdma        ;reset dma
  737.     set    6,(ix+24h)    ;flag $$$.SUB file present
  738.     ld    a,(subfcb)    ;get submit drive
  739.     ld    de,80h        ;point to target of move
  740.     or    a        ;submit drive?
  741.     jr    z,nosubdrv
  742.     add    a,'A'-1        ;make drive ASCII
  743.     ld    (de),a
  744.     inc    de
  745.     ld    a,':'
  746.     ld    (de),a        ;put colon into place
  747.     inc    de
  748. nosubdrv:
  749.     ld    hl,subname
  750.     ld    bc,5
  751.     ldir            ;move $$$.S into place
  752.     ld    hl,(pfcb)
  753.     dec    hl        ;point to command tail
  754.     ex    de,hl
  755.     call    movetil0    ;move command tail into place
  756.     ld    c,47
  757.     ld    e,0
  758.     jp    bdos        ;chain to submit handler in CCP
  759.  
  760. subname:
  761.     db    '$$$.S'
  762.  
  763.     endif        ;not CCP
  764.  
  765. dosubfcb:
  766.     xor    a        ;submit fcb always user 0
  767.     ld    (ix+60h),a    ;set submit user number
  768.     ld    de,subfcb    ;point to submit FCB
  769.     call    xbdos        ;do the function
  770.  
  771.     if    not ccp
  772.  
  773.     or    a        ;set flag
  774.  
  775.     endif        ;not CCP
  776.  
  777.     ld    a,(usernum)    ;get our user #
  778.     ld    (ix+60h),a    ;set BDOS user number
  779.     ret
  780.  
  781. subfcb:
  782.     db    0,'$$$     SUB',0,0,0,0
  783.     ds    16
  784.     db    0        ;cr field
  785.  
  786.  
  787. ;............
  788. ;
  789. ;COMPARE AND PROCESS FILE TYPE IN COMMAND
  790. ;
  791. CMPRFTYPE:
  792.     LD    DE,FILETYPE    ;point to filetype in FCB
  793.     LD    HL,TYPNAME    ;Point to filetype table
  794.     CALL    COMPARE        ;Is it .COM, .SUB or .PRL?
  795.     RET    NZ        ;Return if no match
  796.  
  797.     if    ccp
  798.  
  799.     LD    DE,CMDFCB    ;point to command FCB
  800.  
  801.     else        ;if not CCP
  802.  
  803.     push    bc        ;save filetype code
  804.     ld    de,filename    ;point to filename
  805.     ld    hl,(memaddr)    ;get member address
  806.     ld    b,11        ;11 bytes to compare
  807.     call    comp        ;have we found the member?
  808.     pop    bc
  809.     ret    nz        ;return if not found
  810.     push    bc
  811.     dec    de        ;point to drive code
  812.     jp    noprtfile
  813.  
  814. ;..........
  815. ;
  816. ;Entry point for locating COMMAND.LBR using CP/M's search chain.
  817. ;
  818. cmpftype:
  819.     ld    de,lbrfcb
  820.     or    0ffh                        ;V 1.03
  821.     ld    (duspec),a    ;set to show is drive/user spec    ;V 1.03
  822.  
  823.     endif        ;not CCP
  824.  
  825.     CALL    setdusr        ;Set FCB user number if specified
  826.     LD    A,(DE)        ;get drive code
  827.     LD    C,A        ;    into C
  828.  
  829.     if    ccp
  830.  
  831.     PUSH    BC        ;Save filetype code
  832.  
  833.     endif        ;not CCP
  834.  
  835.     LD    C,0
  836.     OR    A        ;Test for default drive
  837.     jr    NZ,NOTDEFDSK    ;Jump if drive specified
  838.     DEC    DE        ;Point to user code
  839.     LD    A,(DE)        ;get user
  840.     INC    DE        ;back to drive code
  841.     OR    A        ;test user code
  842.     jr    NZ,notdefdsk    ;Jump if user specified
  843.  
  844.     if    ccp
  845.  
  846.     LD    BC,0E704H    ;[B] = DRIVE SEARCH OFFSET-1, (E7H)
  847.                 ;[C] = LENGTH OF TABLE (4 bytes)
  848.     LD    A,(CURDSK)    ;Get current drive
  849.     INC    A        ;Adjust drive
  850.     LD    H,A        ;H = current drive + 1
  851.     LD    L,1        ;flag to prevent duplicate search on same drive
  852.  
  853.     else        ;if not CCP
  854.  
  855.     ld    bc,(searoff)    ;get search offset and count    ;V 1.03
  856.     ld    hl,(searflg)    ;get flags            ;V 1.03
  857.     xor    a                        ;V 1.03
  858.     ld    (duspec),a    ;flag no drive/user spec    ;V 1.03
  859.  
  860.     endif        ;not CCP
  861.  
  862.  
  863. ;..........
  864. ;
  865. ;Loop to inspect drive search chain as specified in offsets E8H to EBH
  866. ;in the SCB
  867. ;
  868. CPRFT1:
  869.     INC    B        ;Bump search offset
  870.     DEC    C        ;Decrement length left
  871.     LD    A,C        ;Length left in A
  872.     PUSH    HL        ;save HL
  873.     CALL    P,GETSCB    ;Test this drive entry if length left > 0
  874.     POP    HL        ;restore HL
  875.     OR    A        ;test for end of table
  876.     JP    M,SRCHEND    ;Jump if at end of table
  877.     jr    Z,DEFSPEC    ;Jump if default drive
  878.     CP    H        ;Is the drive the current disk?
  879.     jr    NZ,NOTCURDSK    ;Jump if not current disk
  880. DEFSPEC:
  881.     LD    A,H        ;Get current drive
  882.     DEC    L        ;adjust duplicate search flag
  883.     JP    M,CPRFT1    ;Jump if we already scanned this drive
  884. NOTCURDSK:
  885.     LD    (DE),A        ;Put drive spec into FCB
  886. NOTDEFDSK:
  887.     PUSH    BC        ;Save these
  888.     PUSH    HL        ;    registers
  889.  
  890.     if    not    ccp
  891.  
  892.     call    checkex        ;Check for Exclude d/u
  893.     CALL    nz,OPENFILE    ;Attempt to open the file
  894.  
  895.     else        ;if CCP
  896.  
  897.     CALL    OPENFILE    ;Attempt to open the file
  898.  
  899.     endif        ;CCP
  900.  
  901.     jr    NZ,fileok    ;Jump if open ok
  902.     POP    HL        ;restore these
  903.     POP    BC        ;    registers
  904.     DEC    DE        ;point to user code
  905.     LD    A,(DE)        ;get user code
  906.     INC    DE        ;point to drive code
  907.     OR    A        ;test user code
  908.     jp    NZ,srchend    ;jump if user number specified
  909.     LD    A,(usernum)    ;get current user number
  910.     OR    A        ;is it zero?
  911.     jr    Z,cprft1    ;jump if current user is zero
  912.     XOR    A
  913.     PUSH    BC        ;save these
  914.     PUSH    HL        ;    registers
  915.     ld    (ix+60h),a    ;set user number to zero
  916.  
  917.     if    not    ccp
  918.  
  919.     call    checkex        ;Check for exclude d/u
  920.     CALL    nz,OPENFILE    ;Attempt to open the file (user 0)
  921.  
  922.     else        ;if CCP
  923.  
  924.     CALL    OPENFILE    ;Attempt to open the file (user 0)
  925.  
  926.     endif        ;CCP
  927.  
  928.     LD    A,(usernum)    ;get current user number
  929.     ld    (ix+60h),a    ;restore current user number
  930.     jr    NZ,filok1    ;jump if ok
  931.     POP    HL        ;restore these
  932.     POP    BC        ;    registers
  933.     jr    cprft1        ;and loop for next drive
  934.  
  935. ;............
  936. ;
  937. ;Here if file open is ok at user 0
  938. ;
  939. filok1:
  940.     DEC    DE        ;point to user number in FCB
  941.     LD    A,1        ;set it to zero (1-1)
  942.     LD    (DE),A        ;Save user number in FCB
  943.     INC    DE        ;back to drive code
  944.  
  945. ;...........
  946. ;
  947. ;Here if file open is ok at current user 
  948. ;
  949. fileok:
  950.     POP    HL        ;restore these
  951.     POP    BC        ;    registers
  952.  
  953.     if    not ccp                        ;V 1.03
  954.  
  955.     ld    (searoff),bc    ;save search offset and length    ;V 1.03
  956.     ld    (searflg),hl    ;save search flags        ;V 1.03
  957.  
  958.     endif        ;not CCP                ;V 1.03
  959.  
  960.     DEC    DE        ;point to user number
  961.  
  962.     if    ccp
  963.  
  964.     ld    a,(subflag)    ;get submit flag
  965.     or    a
  966.     jr    z,notsubset    ;jump if we haven't been here before
  967.     LD    a,(ix+25h)    ;A5H = user number for loader
  968.     ld    b,a
  969.     ld    a,(ix+24h)    ;get submit user
  970.     or    b        ;or in user number
  971.     ld    (ix+24h),a    ;save it for submit
  972. notsubset:
  973.  
  974.     endif        ;CCP
  975.  
  976.     LD    A,(DE)        ;get FCB user number
  977.  
  978.     if    not ccp
  979.  
  980.     or    80h        ;set library load flag for loader
  981.  
  982.     endif        ;not CCP
  983.  
  984.     ld    (ix+25h),a    ;Set the user number for loader
  985.  
  986.     if    ccp
  987.  
  988.     XOR    A
  989.     LD    (DE),A        ;set FCB user number to default
  990.  
  991.     endif        ; CCP
  992.  
  993.     INC    DE        ;point to drive code
  994.  
  995.     if    ccp
  996.  
  997.     LD    a,(ix+34h)
  998.     and    3        ;Test bits 0,1 of B4H (Display command flag)
  999.     jr    Z,NOPRTFILE    ;Jump if no dayfile logging
  1000.     LD    A,(DE)        ;get FCB drive spec
  1001.     CALL    PRTDISK        ;print drive code
  1002.     LD    A,':'        ;print colon
  1003.     CALL    CONOUT
  1004.     PUSH    DE
  1005.     CALL    PRTFNAME    ;print the file name
  1006.     POP    DE
  1007.     PUSH    DE
  1008.     LD    HL,8
  1009.     ADD    HL,DE        ;point to sys flag
  1010.     LD    A,(HL)
  1011.     AND    80H        ;isolate sys flag
  1012.     LD    DE,USER0MSG    ;point to (User 0) msg
  1013.     CALL    NZ,PRNSTR    ;print this msg if sys file
  1014.     CALL    CRLF        ;turn up new line
  1015.     POP    DE
  1016.  
  1017.     else        ;if not CCP
  1018.  
  1019.     ret            ;all ok
  1020.  
  1021.     endif        ;not CCP
  1022.  
  1023. NOPRTFILE:
  1024.     POP    AF        ;get file type code
  1025.     LD    HL,TYPADDR    ;point to vector table
  1026.  
  1027.     if    yesprl
  1028.  
  1029.     cp    2        ;is it PRL?
  1030.     jr    nz,notprl
  1031.     set    6,(ix+25h)    ;set prl flag for loader
  1032. notprl:
  1033.  
  1034.     endif            ; yesprl
  1035.  
  1036.     ADD    A,A        ;DOUBLE COMMAND # FOR WORD OFFSET
  1037.     CALL    ADDHLA        ;form table entry address
  1038.     PUSH    DE        ;save fcb address
  1039.     LD    E,(HL)        ;Load command routine address into [DE]
  1040.     INC    HL
  1041.     LD    D,(HL)
  1042.     EX    DE,HL        ;routine address in [HL]
  1043.     POP    DE        ;restore FCB address
  1044.     JP    (HL)        ;Jump to file type handler
  1045.  
  1046. ;.............
  1047. ;
  1048. ;VALID COMMAND FILE TYPES
  1049. ;
  1050. TYPNAME:
  1051.     DEFB    'COM '
  1052.     DEFB    'SUB '
  1053.  
  1054.     if    yesprl
  1055.  
  1056.     DEFB    'PRL '
  1057.  
  1058.     endif            ; yesprl
  1059.  
  1060.     DEFB    0
  1061.  
  1062. ;...............
  1063. ;
  1064. ;SUBROUTINE ADDRESS FOR FILE TYPES
  1065. ;
  1066. TYPADDR:
  1067.     DEFW    LOADGO        ;COM handler
  1068.     DEFW    SUBMIT        ;Submit handler
  1069.  
  1070.     if    yesprl
  1071.  
  1072.     DEFW    LOADGO        ;PRL handler (same as COM)
  1073.  
  1074.     endif            ; yesprl
  1075.  
  1076. ;..............
  1077. ;
  1078. ;HERE IF AT END OF DRIVE SEARCH CHAIN
  1079. ;
  1080. SRCHEND:
  1081.  
  1082.     if    ccp
  1083.  
  1084.     POP    BC        ;restore filetype code
  1085.     LD    A,C        ;get drive spec
  1086.     LD    (DE),A        ;put drive spec into FCB
  1087.     RET            ;and return
  1088.  
  1089.     else        ;if not CCP
  1090.  
  1091.     jp    errxit
  1092.  
  1093. ;..............
  1094. ;
  1095. ;Routine to check for Exclude drive/user
  1096. ;
  1097. checkex:
  1098.     ld    a,(wheel)
  1099.     or    a
  1100.     ret    nz        ;ignore if wheel set
  1101.     ld    a,(exdrv)
  1102.     or    a        ;do we check for excluded d/u?
  1103.     jr    nz,checkex1
  1104.     or    0ffh        ;set nz
  1105.     ret
  1106. checkex1:
  1107.     ld    a,(de)        ;get drive spec
  1108.     or    a        ;default?
  1109.     jr    nz,fcbdiskok
  1110.     ld    a,(disknum)    ;get current drive
  1111.     inc    a
  1112. fcbdiskok:
  1113.     ld    b,a
  1114.     ld    a,(exdrv)
  1115.     cp    b        ;same as EXDRV?
  1116.     ret    nz
  1117.     ld    a,(exusr)    ;get exclude user
  1118.     cp    (ix+60h)    ;same as current user?
  1119.     ret            ;Z flag properly set
  1120.  
  1121.     endif        ;not CCP
  1122.  
  1123. ;.............
  1124. ;
  1125. ;MOVE FILE TYPE INTO FCB
  1126. ;
  1127. MOVETYPE:
  1128.     RRCA            ;Divide by 2
  1129.     LD    HL,TYPNAME    ;point to file type list
  1130.     CALL    ADDHLA        ;compute entry address
  1131.     LD    DE,FILETYPE    ;point to filetype in FCB
  1132.     LD    C,3        ;3 bytes to move
  1133.     jp    MOVEC        ;move file type
  1134.  
  1135.  
  1136.     if    not ccp
  1137.  
  1138. ;..........
  1139. ;
  1140. ;Read a library directory sector
  1141. ;
  1142. lbrread:
  1143.     ld    de,buff        ;point to buffer
  1144.     call    setdma        ;set the dma
  1145.     call    setlusr
  1146.     ld    c,20
  1147.     call    xbdos        ;read a sector
  1148.     or    a
  1149.     ret
  1150.  
  1151. ;...........
  1152. ;
  1153. ;Inline print routine
  1154. ;
  1155. ilprt:
  1156.     pop    hl
  1157.     ld    a,(hl)
  1158.     inc    hl
  1159.     push    hl
  1160.     or    a
  1161.     ret    z
  1162.     call    cono
  1163.     jr    ilprt
  1164.  
  1165. ;...........
  1166. ;
  1167. ;Compare two strings , ignore parity bit
  1168. ;
  1169. comp:
  1170.     push    de
  1171.     push    hl
  1172.     inc    b
  1173. comp1:
  1174.     dec    b
  1175.     jr    z,comp2
  1176.     ld    a,(de)
  1177.     and    7fh
  1178.     ld    c,a
  1179.     ld    a,(hl)
  1180.     and    7fh
  1181.     cp    c
  1182.     inc    hl
  1183.     inc    de
  1184.     jr    z,comp1
  1185. comp2:
  1186.     pop    hl
  1187.     pop    de
  1188.     ret
  1189.  
  1190. ;..............
  1191. ;
  1192. ;Set up stuff to load the Library member
  1193. ;
  1194.  
  1195. setlbr:
  1196.     ld    hl,(memaddr)    ;get member address
  1197.     ld    de,11
  1198.     add    hl,de        ;point to member start record
  1199.     ld    e,(hl)
  1200.     inc    hl
  1201.     ld    d,(hl)
  1202.     ld    (lbrfcb+34),de    ;put it in RR field
  1203.     inc    hl
  1204.     ld    e,(hl)
  1205.     inc    hl
  1206.     ld    d,(hl)        ;get member length
  1207.     push    de        ;save on stack
  1208.     ld    de,buff
  1209.     call    setdma        ;set the dma
  1210.     call    setlusr
  1211.     ld    c,33
  1212.     call    xbdos        ;random read first member sector (sets
  1213.                 ; up for loader sequential read)
  1214.     or    a
  1215.     jp    z,lbrreadok
  1216.     call    ilprt
  1217.     db    'Error reading COMMAND.LBR',13,10,0
  1218.     jp    errxit
  1219. lbrreadok:
  1220.     pop    hl        ;get member length
  1221.     ld    (lbrfcb+36),hl    ;save it for loader
  1222.     ret
  1223.  
  1224.     endif        ;not CCP
  1225.  
  1226. ;...........
  1227. ;
  1228. ;.COM and .PRL command type handler
  1229. ;SET UP PAGE ZERO AND CALL LOADER
  1230. ;
  1231. LOADGO:
  1232.  
  1233.     if    not ccp
  1234.  
  1235.     call    setlbr        ;set up for lbr member read
  1236.  
  1237.     endif        ;not CCP
  1238.  
  1239.     LD    HL,TPA        ;load address
  1240.  
  1241.     if    ccp
  1242.  
  1243.     LD    (LOADADDR),HL    ;Save load address
  1244.     LD    HL,(BOFFSET)    ;Get BDOS base page in H
  1245.     DEC    H        ;Less one
  1246.     LD    L,0C0H        ;HL points to free area in loader RSX
  1247.     PUSH    HL        ;Save on stack
  1248.  
  1249.     else        ;if not CCP
  1250.  
  1251.     ld    (lbrfcb+34),hl    ;save load address
  1252.     ld    d,(ix+19h)    ;get bdos base page
  1253.     dec    d        ;less one
  1254.     ld    e,0c0h        ;DE points to free area in loader RSX
  1255.     push    de        ;save on stack
  1256.     ld    hl,lbrfcb+1    ;source
  1257.     ld    a,(hl)        ;get load drive
  1258.  
  1259.     endif        ;not CCP
  1260.  
  1261.     if    ccp
  1262.  
  1263.     LD    A,(DE)        ;get load drive
  1264.  
  1265.     endif        ;CCP
  1266.  
  1267.     LD    (LOADDRV),A    ;save load drive
  1268.  
  1269.     if    ccp
  1270.  
  1271.     EX    DE,HL        ;swap for move
  1272.     LD    C,35        ;35 bytes to move
  1273.     CALL    MOVEC        ;Move FCB into loader RSX
  1274.  
  1275.     else        ;not CCP
  1276.  
  1277.     ld    bc,37        ;37 bytes to move
  1278.     ldir            ;move it
  1279.  
  1280.     endif        ;not CCP
  1281.  
  1282.     ld    hl,msgflag    ;point to message flag
  1283.     inc    (hl)        ;bump it
  1284.     LD    HL,(PFCB)    ;get command tail pointer
  1285.     DEC    HL
  1286.     LD    DE,81H        ;target of command tail
  1287.     EX    DE,HL    
  1288.     LD    (PFCB),HL    ;save new command tail pointer
  1289.     CALL    MOVETIL0    ;move command tail into place
  1290.     LD    (80H),A        ;save command tail length
  1291.     CALL    SETDFFCB    ;set up default FCB at 5CH
  1292.     LD    (PASS1ADR),HL    ;Save password 1 address
  1293.     LD    A,B
  1294.     LD    (PASS1LEN),A    ;Save password 1 length
  1295.     LD    DE,FCB2        ;Point to FCB2
  1296.     CALL    SETFCB        ;Set up FCB2
  1297.     LD    (PASS2ADR),HL    ;Save password 2 address
  1298.     LD    A,B
  1299.     LD    (PASS2LEN),A    ;Save password 2 length
  1300.  
  1301.     if    ccp
  1302.  
  1303.     LD    A,(curdsk)    ;get ccp drive
  1304.  
  1305.     else        ;if not CCP
  1306.  
  1307.     ld    a,(disknum)
  1308.  
  1309.     endif        ;not CCP
  1310.  
  1311.     CALL    SELDSK        ;Select drive
  1312.  
  1313.     if    ccp
  1314.  
  1315.     ld    a,(disknum)    ;get old drive flag
  1316.     or    a
  1317.     call    p,seldsk    ;select old drive if to be kept
  1318.  
  1319.     endif        ;CCP
  1320.  
  1321.     LD    A,(USERNUM)    ;get user number
  1322.     ld    (ix+60h),a    ;set the user number
  1323.     ADD    A,A        ;Shift user number over to high nybble
  1324.     ADD    A,A
  1325.     ADD    A,A
  1326.     ADD    A,A
  1327.     or    (ix+5AH)    ;or in BDOS drive
  1328.     LD    (USRDSK),A    ;Save at location 4 for previous CP/M compatibility
  1329.     call    sdefdma        ;set default dma
  1330.     POP    DE        ;restore FCB address
  1331.  
  1332.     if    ccp
  1333.  
  1334.     LD    HL,(BOFFSET)    ;Get BDOS base page in H
  1335.  
  1336.     else        ;if not CCP
  1337.  
  1338.     ld    h,(ix+19h)    ;get bdos base page
  1339.  
  1340.     endif        ;not CCP
  1341.  
  1342.     XOR    A
  1343.     LD    L,A
  1344.     LD    SP,HL        ;Set up stack just below the BDOS
  1345.     LD    H,A        ;HL = 0
  1346.     PUSH    HL        ;Push return to 0 at top of stack
  1347.     INC    H        ;HL = 100H
  1348.     PUSH    HL        ;Push return address for loader
  1349.                 ;goes to loaded program
  1350.     LD    (FCBCR),A    ;zero the record count
  1351.  
  1352.     if    ccp
  1353.  
  1354.     if    byechk
  1355.  
  1356.     ld    a,(byeact)    ;get BYE active flag
  1357.     or    a        ;is BTE active?
  1358.     jr    nz,noqs
  1359.  
  1360.     endif            ; byechk
  1361.  
  1362.     if    byechk or noxoff
  1363.  
  1364.     ld    a,2        ;disable flow control if bye present
  1365.  
  1366.     endif            ; byechk or noxoff
  1367.  
  1368.     if    byechk
  1369.  
  1370.     jr    setcon
  1371. noqs:
  1372.     XOR    A        ;enable stop/start scroll
  1373. setcon:
  1374.  
  1375.     endif            ; byechk
  1376.  
  1377.     LD    (ix+4FH),a    ;Set low byte console mode
  1378.     XOR    A
  1379.     LD    (ix+10H),a    ;Zero offsets 90H - 93H in SCB
  1380.     LD    (ix+11H),A
  1381.     LD    (ix+12H),A
  1382.     LD    (ix+13H),A
  1383.     bit    7,(ix+33H)    ;Test chain flag
  1384.     jr    NZ,CHAINSET    ;Jump if chain flag set
  1385.  
  1386.     if  makecolon                        ; V 1.05
  1387.  
  1388.     ld     a,(ix+2ch)    ;get error code lsb        ; V 1.05
  1389.     cp    0feh        ;CTL-C error?            ; V 1.05
  1390.     jr    nz,CHAINSET    ;nope, so nothing gets reset    ; V 1.05
  1391.     ld    a,(ix+2dh)    ;get error code msb        ; V 1.05
  1392.     inc    a        ;CTL-C error?            ; V 1.05
  1393.     jr    nz,CHAINSET    ;nope, so no reset again    ; V 1.05
  1394.                 ;yep, we reset ONLY CTL-C generated errors
  1395.     endif    ; makecolon                    ; V 1.05
  1396.  
  1397.  
  1398.     LD    (ix+2cH),a    ;Zero program return code
  1399.     LD    (ix+2dH),a
  1400.  
  1401. CHAINSET:
  1402.     res    7,(ix+33h)    ;Zero chain flag
  1403.  
  1404.     endif        ;CCP
  1405.  
  1406.     LD    C,59        ;load overlay function
  1407.     JP    bdos        ;jump to loader to complete load function
  1408.  
  1409.  
  1410.     if    ccp and byechk
  1411.  
  1412. ;
  1413. rsxpb:
  1414.     DEFB    4        ;rsx function for bye present test
  1415. byeact:
  1416.     DEFB    0        ;BYE active flag
  1417.  
  1418.     endif        ;CCP and byechk
  1419.  
  1420. ;...............
  1421. ;
  1422. ;OUTPUT CHAR IN [A]
  1423. ;
  1424. OUTCHAR:
  1425. cono:
  1426.     LD    E,A        ;BDOS likes char in E
  1427. ;
  1428. ;OUTPUT CHAR IN [E]
  1429. ;
  1430. CO:
  1431.     LD    C,2        ;console output function
  1432.     jp    xbdos
  1433.  
  1434. ;
  1435. ;PRINT STRING AT [DE]
  1436. ;
  1437. PRNSTR:
  1438.     LD    C,9        ;print string function
  1439.     jp    xbdos
  1440.  
  1441.     if    ccp
  1442.  
  1443. ;
  1444. ;GET LINE OF INPUT FROM CONSOLE
  1445. ;
  1446. GETLINE:
  1447.     LD    HL,CMDLINE-1    ;point to command line length
  1448.     LD    (HL),SIZECMDLINE ;set the command line max length  ; V. 1.05
  1449.     EX    DE,HL        ;BDOS likes the address in DE
  1450.     LD    C,10        ;getline function
  1451.     CALL    xbdos
  1452.     LD    HL,CMDLINE    ;point to length
  1453.     LD    A,(HL)        ;get length
  1454.     INC    HL        ;point to command string
  1455.     CALL    ADDHLA        ;point to end of command string
  1456.     LD    (HL),0        ;put terminator at end
  1457.     
  1458.     if    ccphistory
  1459.     if    ccp
  1460.  
  1461.     call    CCPEXT        ; first try for CCP extension program
  1462.     call    z,HISTORY    ; then do internal history mechanism,
  1463.                 ; optionally turned off by the CCPEXT
  1464.     endif    ; ccp
  1465.     endif    ; ccphistory
  1466.  
  1467.     jp    CRLF        ;and turn up a new line
  1468. ;
  1469. ;CHECK FOR CONSOLE INPUT
  1470. ;
  1471. STATINP:
  1472.     LD    C,11        ;console status function
  1473.     CALL    CBDOS
  1474.     RET    Z        ;return if nothing there
  1475.     LD    C,1        ;console input function
  1476.     jp    CBDOS
  1477.  
  1478.     endif        ;CCP
  1479.  
  1480. ;
  1481. ;SET DEFAULT DMA ADDRESS
  1482. ;
  1483. SDEFDMA:
  1484.     LD    DE,80H        ;default DMA address
  1485. ;
  1486. ;SET DMA ADDRESS IN [DE]
  1487. ;
  1488. SETDMA:
  1489.     LD    C,26        ;set DMA function
  1490.     jp    xbdos
  1491. ;
  1492. ;SELECT DISK IN [A]
  1493. ;
  1494. SELDSK:
  1495.     LD    E,A        ;BDOS likes it in E
  1496.     LD    C,14        ;select disk function
  1497.     jp    xbdos
  1498.  
  1499.     if    not ccp
  1500.  
  1501. ;
  1502. ;Point to Library FCB and Set user
  1503. ;
  1504. setlusr:
  1505.     ld    de,lbrfcb
  1506.  
  1507.     endif        ;not CCP
  1508.  
  1509. ;
  1510. ;Set FCB user number
  1511. ;
  1512. setdusr:
  1513.     ld    a,(de)        ;get FCB user number
  1514.     inc    de        ;point to drive code
  1515.     or    a
  1516.     ret    z        ;return if default
  1517.     DEC    A        ;adjust to true user number
  1518.     ld    (ix+60h),a    ;set the user number
  1519.     RET
  1520.  
  1521. ;
  1522. ;SET UP FCB AND OPEN DISK FILE
  1523. ;
  1524. OPENFILE:
  1525.     LD    BC,0ff0fh    ;B = Error mode to set, C = function
  1526.  
  1527.     if    ccp
  1528.  
  1529.     LD    DE,FILEDISK    ;point to drive code
  1530.  
  1531.     else        ;if not CCP
  1532.  
  1533.     ld    de,lbrfcb+1    ;point to drive code
  1534.  
  1535.     endif
  1536.  
  1537.     LD    HL,32    
  1538.     ADD    HL,DE        ;point to CR in FCB
  1539.     LD    (HL),0        ;zero CR field
  1540.  
  1541.     if    not ccp
  1542.  
  1543.     ld    hl,12
  1544.     add    hl,de        ;point to extent
  1545.     ld    (hl),0
  1546.     inc    hl
  1547.     ld    (hl),0
  1548.     inc    hl
  1549.     ld    (hl),0
  1550.  
  1551.     endif        ;not CCP
  1552.  
  1553.     PUSH    BC
  1554.     PUSH    DE
  1555.     LD    DE,PASSWORD    ;point to password field
  1556.     CALL    SETDMA        ;Set the DMA to password field
  1557.     POP    DE
  1558.     POP    BC
  1559.     PUSH    DE
  1560. openf2:
  1561.     LD    (ix+67H),B    ;set the error mode
  1562.     CALL    xbdos        ;execute the function in C
  1563.     LD    (ix+67h),0    ;set error mode to zero
  1564.     INC    L        ;test for physical error
  1565.     jr    NZ,noerr    ;jump if not physical error
  1566.     LD    A,H        ;get physical error code
  1567.     OR    A
  1568.     jr    Z,noerr        ;if zero, not a physical error
  1569.     CP    7        ;invalid password?
  1570.     jr    NZ,notpwd    ;jump if not invalid password
  1571.     CALL    getpass
  1572.     LD    BC,15        ;B = 0 (error mode), C = 15 (open file)
  1573.  
  1574.     if    ccp
  1575.  
  1576.     LD    DE,filedisk    ;point to FCB drive code
  1577.  
  1578.     else        ;if not CCP
  1579.  
  1580.     ld    de,lbrfcb+1    ;point to FCB drive code
  1581.  
  1582.     endif        ;not CCP
  1583.  
  1584.     jr    openf2        ;and attempt another open with new password
  1585.  
  1586. ;.......
  1587. ;
  1588. ;Here if not a password error.  determine physical error and print it
  1589. ;
  1590. notpwd:        
  1591.     LD    DE,iomsg
  1592.     CP    1
  1593.     jr    Z,prtmsg
  1594.     LD    DE,drvmsg
  1595.     CP    4
  1596.     jr    Z,prtmsg
  1597.     LD    DE,qmsg
  1598. prtmsg:
  1599.     CALL    prnstr        ;print error message
  1600.  
  1601.     if    ccp
  1602.  
  1603.     jp    nocold        ;and restart CCP
  1604.  
  1605.     else        ;if not CCP
  1606.  
  1607.     rst    0
  1608.  
  1609.     endif
  1610.  
  1611. ;..........
  1612. ;
  1613. ;Here if open sucessful
  1614. ;
  1615. noerr:
  1616.     DEC    L        ;test return code from open
  1617.  
  1618.     if    ccp
  1619.  
  1620.     LD    A,(CURDSK)    ;get current drive
  1621.  
  1622.     else        ;if not CCP
  1623.  
  1624.     ld    a,(disknum)
  1625.  
  1626.     endif        ;not CCP
  1627.  
  1628.     PUSH    HL        ;save return code
  1629.     call    seldsk        ;select the disk
  1630.     CALL    SDEFDMA        ;Set the DMA to 80H
  1631.     POP    HL        ;restore return code
  1632.     INC    L        ;Set return code flag from open
  1633.     POP    DE        ;align stack
  1634.     RET
  1635.  
  1636.     if    ccp
  1637.  
  1638. ;..........
  1639. ;
  1640. ;Print BCD number in A
  1641. ;
  1642. hexprt:
  1643.     PUSH    AF        ;save it
  1644.     REPT    4
  1645.     RRA            ;Shift high nibble into place
  1646.     ENDM
  1647.     CALL    hexpr1        ;print high nibble
  1648.     POP    AF        ;restore number
  1649. hexpr1:
  1650.     AND    0fh        ;isolate low nibble
  1651.     ADD    A,'0'        ;convert to ASCII
  1652.     jp    outchar        ;and print it.
  1653.  
  1654.     endif        ;CCP
  1655.  
  1656. ;............
  1657. ;
  1658. ;Physical error messages
  1659. ;
  1660.  
  1661. pwdmsg:
  1662.     DEFB    'Password: $'
  1663. iomsg:
  1664.     DEFB    'Disk I/O Error$'
  1665. drvmsg:
  1666.     DEFB    'Invalid drive$'
  1667. qmsg:
  1668.     DEFB    '"?" in command$'
  1669.  
  1670.     if    timeon
  1671.  
  1672. minmsg:
  1673.     defb    ' min.$'
  1674.  
  1675.     endif            ; timeon
  1676.  
  1677.     if    ccp
  1678.  
  1679. scomp:
  1680.     PUSH    HL
  1681.     PUSH    DE
  1682.     LD    DE,rootname
  1683. scomp1:
  1684.     LD    A,(DE)
  1685.     CP    (HL)
  1686.     jr    NZ,scompret
  1687.     CP    ' '
  1688.     jr    Z,scompret
  1689.     INC    HL
  1690.     INC    DE
  1691.     jr    scomp1
  1692. scompret:
  1693.     POP    DE
  1694.     POP    HL
  1695.     RET
  1696.  
  1697. rootget:
  1698.     PUSH    HL
  1699.     PUSH    DE
  1700.     LD    HL,rootname
  1701.     LD    DE,rootname+1
  1702.     LD    c,17
  1703.     LD    (HL),' '
  1704.     CALL    movec
  1705.     POP    DE
  1706.     LD    HL,rootname
  1707.     LD    b,8
  1708. rootnmove:
  1709.     LD    A,(DE)
  1710.     OR    a
  1711.     jr    Z,rgetdone
  1712.     INC    DE
  1713.     CP    ';'
  1714.     jr    Z,getp
  1715.     LD    (HL),a
  1716.     INC    HL
  1717.     djnz    rootnmove
  1718.     LD    A,(DE)
  1719.     INC    DE
  1720.     CP    ';'
  1721.     jr    Z,getp
  1722.     XOR    a
  1723.     jr    rgetdone
  1724. getp:
  1725.     LD    HL,rootpass
  1726.     LD    b,8
  1727. rootpmove:
  1728.     LD    A,(DE)
  1729.     INC    DE
  1730.     OR    a
  1731.     jr    Z,rgetdu
  1732.     LD    (HL),a
  1733.     INC    HL
  1734.     djnz    rootpmove
  1735.     LD    A,(DE)
  1736.     INC    DE
  1737.     OR    a
  1738.     jr    Z,rgetdu
  1739.     XOR    a
  1740.     jr    rgetdone
  1741. rgetdu:
  1742.     LD    A,(DE)
  1743.     INC    DE
  1744.     LD    b,a
  1745.     LD    HL,rootdrv
  1746.     AND    0fh
  1747.     LD    (HL),a
  1748.     INC    HL
  1749.     LD    a,b
  1750.     AND    0f0h
  1751.     RRA
  1752.     RRA
  1753.     RRA
  1754.     RRA
  1755.     LD    (HL),a
  1756.     INC    a
  1757. rgetdone:
  1758.     POP    HL
  1759.     RET
  1760.  
  1761.     endif        ;CCp
  1762.  
  1763. getpass:
  1764.     LD    DE,pwdmsg    ;point to password message
  1765.     CALL    prnstr        ;print "Password:"
  1766.     LD    B,8        ;password is 8 bytes max
  1767.     LD    HL,password    ;point to password field
  1768. pwdlop:
  1769.     PUSH    HL
  1770.     PUSH    BC
  1771.     LD    E,0fdh        ;get console input without echo
  1772.     LD    C,6
  1773.     CALL    xbdos
  1774.     POP    BC
  1775.     POP    HL
  1776.     CALL    ucase        ;convert to upper case
  1777.     CP    13        ;is it CR?
  1778.     jr    Z,pwdon        ;jump if done
  1779.     LD    (HL),A        ;save password char
  1780.     INC    HL
  1781.     djnz    pwdlop        ;and loop for more password chars
  1782.     jr    pwdon1
  1783. pwdon:
  1784.     LD    (HL),' '    ;blank out the rest of the password field
  1785.     INC    HL
  1786.     djnz    pwdon
  1787. pwdon1:
  1788.     CALL    crlf        ;turn up new line
  1789.     RET
  1790.  
  1791.     if    ccp
  1792.  
  1793. chkpass:
  1794.     LD    A,(wheel)
  1795.     INC    a
  1796.     RET    Z
  1797.     LD    A,(rootpass)
  1798.     CP    ' '
  1799.     jr    Z,norootp
  1800.     LD    HL,rootdrv
  1801.     LD    A,(maxdrv)
  1802.     DEC    a
  1803.     CP    (HL)
  1804.     jr    C,needpass
  1805.     LD    A,(maxusr)
  1806.     DEC    a
  1807.     INC    HL
  1808.     CP    (HL)
  1809.     RET    NC
  1810. needpass:
  1811.     LD    A,(password)
  1812.     CP    ' '
  1813.     CALL    Z,getpass
  1814.     LD    HL,rootpass
  1815.     LD    DE,password
  1816.     LD    b,8
  1817. rpasslop:
  1818.     LD    A,(DE)
  1819.     CP    (HL)
  1820.     jr    NZ,badpass
  1821.     CP    ' '
  1822.     jr    Z,norootp
  1823.     INC    DE
  1824.     INC    HL
  1825.     djnz    rpasslop
  1826. norootp:
  1827.  
  1828.     if    expand
  1829.  
  1830.     LD    HL,rootdrv
  1831.     LD    A,(maxdrv)
  1832.     CP    (HL)
  1833.     jr    NC,testusr
  1834.     LD    a,(HL)
  1835.     LD    (maxdrv),A
  1836. testusr:
  1837.     INC    HL
  1838.     LD    A,(maxusr)
  1839.     DEC    a
  1840.     CP    (HL)
  1841.     RET    NC
  1842.     LD    a,(HL)
  1843.     INC    a
  1844.     LD    (maxusr),A
  1845.  
  1846.     endif
  1847.  
  1848.     RET
  1849. badpass:
  1850.     POP    HL
  1851.     LD    DE,badpmsg
  1852.     JP    prnstr
  1853. badpmsg:
  1854.     DEFB    'Password Error',13,10,'$'
  1855.  
  1856.     endif        ;CCP
  1857.  
  1858. ;............
  1859. ;
  1860. ;CALL BDOS and return with Z flag status of function
  1861. ;
  1862. CBDOS:
  1863.     CALL    xbdos        ;Do the function
  1864.     OR    A        ;Set/clear the Z flag
  1865.     RET
  1866.  
  1867. ;................
  1868. ;
  1869. ;SCAN THE COMMAND LINE
  1870. ;
  1871. SCANLINE:
  1872.  
  1873.     if    ccp
  1874.  
  1875.     CALL    CRFLGA        ;Clear bits 7 & 5 if offset B4 of SCB
  1876.  
  1877.     endif        ;CCP
  1878.  
  1879.     LD    HL,CMDLINE+1    ;Point to command line start
  1880.     CALL    SIPBLNK        ;Skip over initial blanks
  1881.     CP    ';'        ;Is it a comment line?
  1882.     RET    Z        ;Ignore comment lines
  1883.  
  1884.     if    ccp
  1885.  
  1886.     CP    '!'        ;Command delimiter?
  1887.     jr    Z,DELIM        ;Jump if command delimiter
  1888.     CP    ':'        ;Conditional Execution (begins with colon)?
  1889.     jr    NZ,NOCOLON    ;Jump if not a colon
  1890.     
  1891.  
  1892.     if makecolon        ; needs to be non-destructive
  1893.  
  1894.                 ;If the error code is ff00-fffd or ffff
  1895.                 ;the command is "punted"  -mdk
  1896.  
  1897.     ld    a,(ix+2cH)    ;Test program return code for non-zero
  1898.     INC    a
  1899.     INC    a
  1900.     jr    Z,DELIM        ;If low byte is zero, then jump
  1901.     ld    a,(ix+2dH)    ;Test high byte for 0FFH
  1902.     INC    a
  1903.     RET    Z        ;Return if we are not to execute this
  1904.  
  1905.     endif    ; makecolon
  1906.  
  1907.  
  1908.  
  1909.     if not makecolon
  1910.  
  1911.     INC    (ix+2cH)    ;Test program return code for non-zero
  1912.     INC    (ix+2cH)
  1913.     jr    Z,DELIM        ;If low byte is zero, then jump
  1914.     INC    (ix+2dH)    ;Test high byte for 0FFH
  1915.     RET    Z        ;Return if we are not to execute this
  1916.                 ;command because of return code
  1917.     endif ; not makecolon
  1918.     
  1919.  
  1920. DELIM:
  1921.     INC    hl        ;skip over delimiter
  1922. NOCOLON:
  1923.  
  1924.     endif        ;CCP
  1925.  
  1926.     LD    (PFCB),HL    ;Save address of command
  1927.  
  1928. ;..........
  1929. ;
  1930. ;Loop to convert to upper case and check for second command
  1931. ;
  1932.  
  1933. NEXTCHAR:
  1934.     LD    A,(HL)        ;get char
  1935.     CALL    ucase        ;convert to upper case
  1936.     LD    (HL),A        ;put it back
  1937.  
  1938.     if    ccp
  1939.  
  1940.     CP    '!'        ;Is it command delimiter?
  1941.     CALL    Z,CHKEXCM    ;save 2nd command if present
  1942.  
  1943.     endif        ;CCP
  1944.  
  1945.     INC    HL        ;bump pointer
  1946.     OR    A        ;End of command line?
  1947.     jr    NZ,NEXTCHAR    ;loop for more
  1948.  
  1949. ;.............
  1950. ;
  1951. ;Skip over initial blanks
  1952. ;
  1953. SKIPBLA:
  1954.     LD    HL,(PFCB)    ;Get command address
  1955. SIPBLNK:
  1956.     LD    (PFCB),HL    ;Save new command address
  1957.     LD    (NXTNMA),HL    ;and Next command address
  1958.     LD    A,(HL)        ;Get char
  1959.     OR    A        ;End of command line?
  1960.     RET    Z        ;return if done
  1961.     CP    ' '        ;Is it a blank?
  1962.     jr    Z,SKPBLNK
  1963.     CP    9        ;Test for tab char too.
  1964.     RET    NZ    
  1965. SKPBLNK:
  1966.     INC    HL        ;Bump pointer
  1967.     jr    SIPBLNK        ;And loop for more
  1968.  
  1969.  
  1970.     if    ccp
  1971.  
  1972. ;................
  1973. ;
  1974. ;Save 2nd command in line by creating a dummy RSX of one page 
  1975. ;to protect the 2nd command after exclamation point
  1976. ;
  1977. CHKEXCM:
  1978.     LD    E,L
  1979.     LD    D,H        ;DE = HL
  1980.     INC    DE        ;DE points to next char after exclamation
  1981.     LD    A,(DE)        ;Get it
  1982.     CP    '!'        ;Is it another exclamation?
  1983.     PUSH    AF        ;save flags
  1984.     PUSH    HL        ;and char pointer
  1985.     CALL    Z,MOVETIL0    ;move command line down one notch to kill
  1986.                 ;2nd exclamation immediately after exclamation
  1987.     POP    HL        ;restore char pointer
  1988.     POP    AF        ;and flags
  1989.     RET    Z        ;ignore double exclamations
  1990.     LD    (HL),0        ;replace exclamation with null
  1991.     EX    DE,HL        ;char pointer in DE
  1992.     LD    HL,(BDOS+1)    ;get top of TPA
  1993.     DEC    H        ;Reserve 1 page for 2nd command
  1994.     LD    L,1ah        ;2nd command begins at offset 1bH in RSX;V1.03a
  1995.     PUSH    HL        ;save start of 2nd command addr
  1996.  
  1997. ;...............
  1998. ;
  1999. ;MOVE 2ND COMMAND LINE INTO PROTECTED PAGE
  2000. ;
  2001. MOV2ND:
  2002.     INC    HL        ;Bump these
  2003.     INC    DE        ;    pointers
  2004.     LD    A,(DE)        ;get source char
  2005.     LD    (HL),A        ;put in dest
  2006.     CP    '!'        ;Test for exclamation
  2007.     Jr    NZ,NOTEXCM    ;Jump if not exclamation
  2008.     LD    (HL),0DH    ;Replace all exclamations with CR
  2009. NOTEXCM:
  2010.     OR    A        ;End of command?
  2011.     Jr    NZ,MOV2ND    ;loop for more
  2012.     LD    (HL),0DH    ;Put a CR at end of command
  2013.     INC    HL
  2014.     LD    (HL),A        ;And a null after the CR
  2015.     LD    L,6
  2016.     LD    (HL),0C3H    ;Put a JMP inst at offset 6 in RSX
  2017.     INC    HL
  2018.     LD    (HL),9        ;Target of JMP is offset 9 
  2019.                 ;(Next in RSX header)
  2020.     INC    HL
  2021.     LD    (HL),H        ;Complete JMP inst
  2022.     INC    HL
  2023.     LD    (HL),0C3H    ;Put a JMP at location 9 in RSX
  2024.     LD    L,0EH        ;point to remove flag
  2025.     LD    (HL),A        ;clear remove flag
  2026.     ld    l,10h        ;where name goes            ;1.03a
  2027.     ld    de,next_cmnd    ;point to RSX name            ;1.03a
  2028.     EX    DE,HL        ;Setrsx likes it in DE
  2029.     ld    bc,8        ;length                    ;1.03a
  2030.     ldir            ;move it into place            ;1.03a
  2031.     LD    E,A        ;point to base of RSX
  2032.     CALL    SETRSX        ;Set up this RSX
  2033.     POP    DE        ;recover address of command line
  2034.     ld    e,19h        ;point to address of next command line    ;1.03a
  2035.     ld    a,(ix+31h)                        ;1.03a
  2036.     ld    (de),a                            ;1.03a
  2037.     inc    de                            ;1.03a
  2038.     ld    a,(ix+32h)                        ;1.03a
  2039.     ld    (de),a        ;save next 2nd command line addr    ;1.03a
  2040.     inc    de        ;start of 2nd command            ;1.03a
  2041.     LD    (ix+31H),E    ;Save command address for next time
  2042.                 ;CCP is executed
  2043.     LD    (ix+32H),D
  2044.     LD    (ix+2eH),D    ;Save the base page
  2045.     XOR    A        ;flag no errors
  2046.     RET
  2047.  
  2048. next_cmnd:
  2049.     db    'NEXTCMND'    ;RSX name for next command        ;1.03a
  2050.  
  2051.     endif        ;CCP
  2052.  
  2053. ;...................
  2054. ;
  2055. ;CONVERT TO UPPER CASE
  2056. ;
  2057. UCASE:
  2058.     AND    7fh
  2059.     CP    61H
  2060.     RET    C    
  2061.     CP    7BH
  2062.     RET    NC    
  2063.     SUB    ' '        ;Convert to upper case
  2064.     RET
  2065.  
  2066.     if    ccp
  2067.  
  2068. ;......................
  2069. ;
  2070. ;CHECK FOR SECOND COMMAND LINE
  2071. ;
  2072. CHK2ND:
  2073.     LD    DE,0BAB1H
  2074.     CALL    MOVSCB        ;Move offsets BA,BB to B1,B2 in SCB
  2075.     OR    A        ;Is address in offset BB valid?
  2076.     LD    DE,0BCB1H
  2077.     CALL    Z,MOVSCB    ;Move offsets BC,BD to B1,B2 if prev invalid
  2078.     CALL    STATINP        ;test for console break
  2079.     jr    NZ,NO2ND    ;Jump if console break
  2080. ;
  2081. ;GET ADDRESS AT B1,B2 INTO [DE] (2ND COMMAND LINE)
  2082. ;
  2083.     LD    D,(ix+32H)
  2084.     INC    d        ;Is address valid?
  2085.     DEC    d
  2086.     Jr    Z,NO2ND        ;Jump if no valid address (no 2nd command)
  2087.     LD    E,(ix+31H)
  2088.     LD    A,(DE)        ;Get first char from 2nd command
  2089.     OR    A        ;test for null
  2090.     RET    NZ        ;return if something there
  2091. NO2ND:            ;Here if no 2nd command 
  2092.     LD    H,(ix+2eh)    ;get base page
  2093.     LD    L,0EH        ;point to remove flag
  2094.     DEC    (HL)        ;set remove flag for removal
  2095.     ld    l,19h        ;point to addr of next 2nd command    ;1.03a
  2096.     ld    a,(hl)                            ;1.03a
  2097.     ld    (ix+31h),a                        ;1.03a
  2098.     inc    hl                            ;1.03a
  2099.     ld    a,(hl)                            ;1.03a
  2100.     ld    (ix+32h),a    ;save next 2nd command            ;1.03a
  2101.     ld    (ix+2eh),a    ;save base page of next 2nd command    ;1.03a
  2102.     JP    CHKRSX        ;and remove the dummy RSX
  2103.  
  2104.     endif        ;CCP
  2105.  
  2106. ;..................
  2107. ;
  2108. ;SET UP DEFAULT FCB
  2109. ;
  2110. SETDFFCB:
  2111.     LD    DE,FCB
  2112. ;
  2113. ;SET UP FCB AT [DE]
  2114. ;
  2115. SETFCB:
  2116.     CALL    SKIPBLA        ;Go over leading blanks and tabs
  2117.     PUSH    AF        ;save flags
  2118.     CALL    PARSEFCB    ;Parse the item into FCB
  2119.     POP    AF        ;restore flags
  2120.     RET
  2121. ;
  2122. ;PARSE THE COMMAND LINE INTO FCB
  2123. ;
  2124. PARSEFCB:
  2125.     LD    (PFCB),HL    ;Save item pointer
  2126.     LD    (NXTNMA),HL    ;and next item pointer
  2127.     PUSH    DE        ;save DE
  2128.     LD    DE,PFCB        ;point to parse file control block
  2129.     LD    C,152        ;parse FCB function
  2130.     CALL    xbdos        ;parse the FCB
  2131.     POP    DE        ;restore DE
  2132.     LD    A,H        ;Test for zero return
  2133.     OR    L
  2134.     LD    B,(HL)        ;get next char after parse into B
  2135.     INC    HL        ;go over delimiter or trailing blank
  2136.     Jr    NZ,NOTPEND    ;Jump if not end of command line
  2137.     LD    HL,NULCMD    ;Point to null command
  2138. NOTPEND:
  2139.     LD    A,H        ;Test for error return (0FFFFH)
  2140.     OR    L
  2141.     Jr    NZ,NOPERR    ;Jump if no error
  2142.     LD    HL,NULCMD    ;Point to null command
  2143.     CALL    ERRXIT        ;and process error
  2144. NOPERR:
  2145.     LD    A,B        ;get next char
  2146.     CP    '.'        ;is it dot (.)?
  2147.     Jr    NZ,NOPDOT    ;Jump if not dot
  2148.     DEC    HL        ;Adjust if dot
  2149. NOPDOT:
  2150.     LD    (PFCB),HL    ;Save new item pointer
  2151.     LD    C,16        ;16 bytes to move
  2152.     LD    HL,PRSEFCB    ;source
  2153.     PUSH    DE        ;save dest
  2154.     CALL    MOVEC        ;Move first 16 bytes into place
  2155.     LD    DE,PASSWORD    ;point to password field
  2156.     LD    C,10        ;10 bytes to move
  2157.     CALL    MOVEC        ;move the password into place
  2158.     POP    DE        ;restore DE
  2159.     LD    A,(HL)        ;get password length (PRSEFCB+26)
  2160.     LD    HL,0        ;init HL
  2161. NULCMD     EQU    $-1
  2162.     OR    A        ;test for no password
  2163.     LD    B,A        ;password length in B
  2164.     Jr    Z,NOPASS    ;Jump if no password
  2165.     LD    HL,(NXTNMA)    ;get next item pointer
  2166. FINDSEMI:
  2167.     LD    A,(HL)        ;get first char
  2168.     CP    ';'        ;is it password delimiter?
  2169.     INC    HL        ;bump pointer
  2170.     Jr    NZ,FINDSEMI    ;loop until ";" found
  2171. NOPASS:
  2172.     RET
  2173.  
  2174. ;...............
  2175. ;
  2176. ;CHECK FOR DRIVE SPEC IN COMMAND LINE
  2177. ;
  2178. CHKDRV:
  2179.     PUSH    DE        ;save DE
  2180.     XOR    A        ;Just a zero
  2181.     LD    (DE),A        ;clear to default user
  2182.     INC    DE
  2183.     LD    (DE),A        ;clear to default drive
  2184.     INC    DE        ;point to file name
  2185.     CALL    SKIPBLA        ;skip over leading blanks and tabs
  2186.     LD    HL,(PFCB)    ;get item address
  2187.     POP    DE        ;restore DE
  2188.     PUSH    DE
  2189.     LD    B,4        ;Colon (:) must be found with first 4 bytes
  2190. FNDCOLON:
  2191.     LD    A,(HL)        ;Get char
  2192.     CP    ':'        ;Is it colon?
  2193.     Jr    Z,COLONFND    ;Jump if colon
  2194.     OR    A        ;test for end of command line
  2195.     Jr    Z,ENDCOLON    ;jump if at end
  2196.     CP    ' '        ;is it a blank ?
  2197.     Jr    Z,endcolon
  2198.     CP    9        ;is it a tab ?
  2199.     Jr    Z,endcolon
  2200.     INC    HL        ;adjust pointer
  2201.     djNZ    FNDCOLON    ;loop for more
  2202. ENDCOLON:        ;Here if colon not found within first 4 bytes
  2203.     POP    DE        ;restore DE
  2204.     XOR    A        ;Just a zero
  2205.     LD    (DE),A        ;flag no user spec
  2206.     inc    DE        ;point to drive code    ; V1.02B
  2207.     ld    (DE),A        ;flag no drive spec    ; V1.02B
  2208.     dec    DE        ;point to user code    ; V1.02B
  2209.     LD    HL,(PFCB)    ;get item pointer
  2210. PASTCOLON:
  2211.     INC    DE        ;point to drive code
  2212.     LD    A,(DE)        ;get it
  2213.     PUSH    AF        ;save on stack
  2214.     CALL    PARSEFCB    ;parse first item into FCB
  2215.     POP    AF        ;restore drive spec
  2216.     LD    (DE),A        ;and restore it.
  2217.     RET
  2218.  
  2219.  
  2220. COLONFND:        ;Here if possible drive/user spec in command line
  2221.     LD    HL,(PFCB)    ;get item pointer
  2222.     LD    A,(HL)        ;get the char
  2223. NUMCHECK:
  2224.     CP    '0'        ;Numeric range check
  2225.     Jr    C,NOTNUM
  2226.     CP    ':'        ;Numeric range check
  2227.     Jr    NC,NOTNUM
  2228.     CALL    CVDEC        ;convert to User number in binary
  2229.     POP    DE        ;restore DE
  2230.     PUSH    DE
  2231.     LD    A,(DE)        ;get old user number
  2232.     OR    A        ;is there one already?
  2233.     Jr    NZ,ENDCOLON    ;invalid if user number specified twice
  2234.     LD    A,B        ;get the user number
  2235.     INC    A        ;adjust 
  2236.     LD    (DE),A        ;Save the user number spec
  2237.     Jr    CKDRV1        ;and go and check drive spec
  2238.  
  2239. ;.......
  2240. ;
  2241. ;check for possible drive spec
  2242. ;
  2243. NOTNUM:
  2244.     CP    'A'        ;Drive range check
  2245.     Jr    C,ENDCOLON
  2246.     CP    'Q'        ;Drive range check
  2247.     Jr    NC,ENDCOLON
  2248.     POP    DE        ;restore DE
  2249.     PUSH    DE
  2250.     INC    DE        ;point to drive spec
  2251.     LD    A,(DE)        ;get drive spec
  2252.     OR    A        ;test for drive spec
  2253.     Jr    NZ,ENDCOLON    ;jump if this is second drive spec
  2254.     LD    A,(HL)        ;Get new drive char
  2255.     SUB    40H        ;adjust
  2256.     LD    (DE),A        ;Save drive spec
  2257.     INC    HL        ;go over drive char
  2258. CKDRV1:
  2259.     LD    A,(HL)        ;get next char
  2260.     CP    ':'        ;Is it a colon?
  2261.     Jr    NZ,NUMCHECK    ;Loop until colon found
  2262.     INC    HL        ;go over colon
  2263.     POP    DE        ;restore DE
  2264.  
  2265.     if    ccp
  2266.  
  2267.     call    CHKDU        ;check the drive/user        ; V1.02B
  2268.  
  2269.     endif    ;CCP
  2270.  
  2271.     Jr    PASTCOLON    ;And continue with rest of command line
  2272.  
  2273.     if    ccp
  2274.  
  2275. CHKDU:
  2276.     LD    A,(wheel)    ;get wheel byte            ; V1.02B
  2277.     inc    a        ;is it set?            ; V1.02B
  2278.     ret    Z        ;yep, then no DU: check        ; V1.02B
  2279.     ex    de,hl        ;point to command user        ; V1.02B
  2280.     LD    A,(maxusr)    ;get max user # allowed        ; V1.02B
  2281.     CP    (HL)        ;within range?            ; V1.02B
  2282.     jr    C,invalid    ;return with CARRY set if not    ; V1.02B
  2283.     INC    HL        ;point to command drive        ; V1.02B
  2284.     LD    A,(maxdrv)    ;get max drive            ; V1.02B
  2285.     INC    a        ;adjust                ; V1.02B
  2286.     CP    (HL)        ;within range?            ; V1.02B
  2287.     dec    hl                        ; V1.02B
  2288.     ex    de,hl                        ; V1.02B
  2289.     ret    NC        ;ret with CARRY in proper state    ; V1.02B
  2290.  
  2291. invalid:
  2292.     LD    DE,baddu    ;point to Invalid drive/user msg
  2293.     call    prnstr        ;print msg
  2294.     jp    ccpret
  2295.  
  2296. baddu:
  2297.     DEFB    'Invalid Drive/User',13,10,'$'
  2298.  
  2299.  
  2300. ;.................
  2301. ;
  2302. ;MOVE 2 BYTES OF SCB FROM [D] TO [E]
  2303. ;
  2304. MOVSCB:
  2305.     LD    HL,(SCBBASE)    ;get SCB address
  2306.     LD    L,D        ;set source offset
  2307.     LD    D,H        ;set dest offset
  2308.     LD    C,2        ;2 bytes to move
  2309.  
  2310.     endif        ;CCP
  2311.  
  2312. ;................
  2313. ;
  2314. ;MOVE [HL] TO [DE] FOR LENGTH IN [C]
  2315. ;
  2316. MOVEC:
  2317.     push    bc
  2318.     ld    b,0
  2319.     ldir
  2320.     pop    bc
  2321.     dec    hl
  2322.     ld    a,(hl)
  2323.     inc    hl
  2324.     ret
  2325.  
  2326. ;....................
  2327. ;
  2328. ;MOVE [DE] TO [HL] UNTIL NULL
  2329. ;
  2330. MOVETIL0:
  2331.     LD    C,0        ;Set move terminator
  2332. MOVE1:
  2333.     LD    A,(DE)
  2334.     LD    (HL),A
  2335.     OR    A
  2336.     LD    A,C        ;Return length of move in A
  2337.     RET    Z        ;Return if at end
  2338.     INC    HL
  2339.     INC    DE
  2340.     INC    BC
  2341.     jr    MOVE1
  2342.  
  2343.     if    ccp
  2344.  
  2345. ;................
  2346. ;
  2347. ;SET BITS 7,5 IN OFFSET 0B4H in SCB
  2348. ;
  2349. SETFLG:
  2350.     set    7,(ix+34h)
  2351.     set    5,(ix+34h)
  2352.     ret
  2353.  
  2354. ;...............
  2355. ;
  2356. ;CLEAR BITS 7,5 IN OFFSET 0B4H
  2357. ;
  2358. CRFLGA:
  2359.     res    7,(ix+34h)
  2360.     res    5,(ix+34h)
  2361.     ret
  2362.  
  2363.     endif        ;CCP
  2364.  
  2365. ;..............
  2366. ;
  2367. ;GET SCB BYTE AT OFFset IN [B]
  2368. ;
  2369. GETSCB:
  2370.     LD    HL,(SCBBASE)        ;get SCB pointer
  2371.     LD    L,B        ;set the offset
  2372.     LD    A,(HL)        ;get the byte
  2373.     RET
  2374.  
  2375. ;..............
  2376. ;
  2377. ;PRINT CR,LF
  2378. ;
  2379. CRLF:
  2380.     LD    A,0DH
  2381.     CALL    CONOUT
  2382.     LD    A,0AH
  2383.     jp    CONOUT
  2384.  
  2385.     if    ccp
  2386.  
  2387. ;............
  2388. ;
  2389. ;Call RSX
  2390. ;
  2391. rsx:
  2392.     ld    c,60
  2393.     jp    xbdos
  2394.  
  2395.  
  2396. ;...............
  2397. ;
  2398. ;PRINT NUMBER IN [A]
  2399. ;
  2400. PRTNUM:
  2401.     ld    h,0
  2402.     ld    l,a
  2403. decout:
  2404.     push    hl
  2405.     push    de
  2406.     push    bc
  2407.     push    af
  2408.     ld    bc,-10
  2409.     ld    de,-1
  2410. decou1:
  2411.     add    hl,bc
  2412.     inc    de
  2413.     jr    c,decou1
  2414.     sbc    hl,bc
  2415.     ex    de,hl
  2416.     ld    a,h
  2417.     or    l
  2418.     call    nz,decout
  2419.     ld    a,e
  2420.     add    a,'0'
  2421.     call    cono
  2422.     pop    af
  2423.     pop    bc
  2424.     pop    de
  2425.     pop    hl
  2426.     ret
  2427.  
  2428.     else        ;if not CCP
  2429.  
  2430. xbdos:
  2431.     push    ix
  2432.     call    bdos
  2433.     pop    ix
  2434.     ret
  2435.  
  2436.     endif        ;not CCP
  2437.  
  2438. ;................
  2439. ;
  2440. ;PRINT STRING AT [HL] TERMINATED BY NULL OR CHAR IN [C]
  2441. ;
  2442. PRTNAME:
  2443.     LD    A,(HL)        ;get char
  2444.     OR    A        ;is it null?
  2445.     RET    Z    
  2446.     CP    C        ;is it same as char in C?
  2447.     RET    Z    
  2448.     CALL    CONOUT        ;print it
  2449.     INC    HL        ;bump pointer
  2450.     jr    PRTNAME        ;and loop
  2451.  
  2452. ;.............
  2453. ;
  2454. ;TEST FOR BLANKS AND ABORT IF BLANKS PRESENT
  2455. ;
  2456. CHKBLANK:
  2457.     CALL    SKIPBLA        ;skip over blanks
  2458.     RET    Z        ;return if non-blank found
  2459.  
  2460. ;...............
  2461. ;
  2462. ;ERROR EXIT SUBROUTINE
  2463. ;
  2464. ERRXIT:
  2465.  
  2466.     if    not ccp
  2467.  
  2468. ccpret:
  2469.  
  2470.     endif        ;not CCP
  2471.  
  2472.     LD    HL,msgflag    ;point to error count
  2473.     dec    (hl)        ;is it zero?
  2474.     inc    (hl)
  2475.     LD    (HL),0        ;reset it to zero
  2476.     RET    NZ        ;return if non-zero
  2477.     LD    HL,(nxtnma)    ;get command address
  2478.     LD    C,' '        ;print until blank or null
  2479.     CALL    prtname        ;print the first item in command line
  2480.     LD    DE,notfnm    ;point to "command not found" message
  2481.     CALL    prnstr        ;print command not found
  2482.  
  2483.     if    ccp
  2484.  
  2485.     jp    NOCOLD        ;and restart the CCP
  2486.  
  2487.     else        ;if not CCP
  2488.  
  2489.     rst    0
  2490.  
  2491.     endif        ;not CCP
  2492.  
  2493. notfnm:
  2494.     DEFB    ' command not found.$'
  2495.  
  2496. ;...............
  2497. ;
  2498. ;CONVERT ITEM IN COMMAND LINE TO BINARY
  2499. ;
  2500. CVNUM:
  2501.     CALL    SKIPBLA        ;skip over blanks
  2502.     LD    HL,(PFCB)    ;get item pointer
  2503.     LD    (NXTNMA),HL    ;save it
  2504.     RET    Z        ;return if nothing there
  2505.     LD    A,(HL)        ;get first char
  2506.     CP    '0'        ;numeric range check
  2507.     jr    C,ERRXIT
  2508.     CP    ':'        ;numeric range check
  2509.     jr    NC,ERRXIT
  2510.     CALL    CVDEC        ;convert to binary
  2511.     LD    (PFCB),HL    ;save new item pointer
  2512.     OR    1        ;set NZ return
  2513.     LD    A,B        ;return number in A
  2514.     RET
  2515.  
  2516. ;...............
  2517. ;
  2518. ;CONVERT ITEM TO BINARY NUMBER
  2519. ;
  2520. CVDEC:
  2521.     LD    B,0        ;start with 0
  2522. CVDECLP:    
  2523.     LD    A,(HL)        ;get char
  2524.     SUB    '0'        ;convert from ASCII to binary
  2525.     RET    C        ;return if out of range
  2526.     CP    10        ;numeric range check
  2527.     RET    NC        ;return if out of range
  2528.     PUSH    AF        ;save it
  2529.     LD    A,B        ;prepare to multiply B * 10
  2530.     ADD    A,A        ;*2
  2531.     ADD    A,A        ;*4
  2532.     ADD    A,B        ;*5
  2533.     ADD    A,A        ;*10
  2534.     LD    B,A
  2535.     POP    AF        ;restore number
  2536.     INC    HL        ;bump pointer
  2537.     ADD    A,B        ;add in current digit
  2538.     LD    B,A
  2539.     CP    16        ;must be less than 16
  2540.     jr    C,CVDECLP    ;loop if ok.
  2541.     jr    ERRXIT        ;otherwise an error
  2542.  
  2543.     if    ccp
  2544.  
  2545. ;.................
  2546. ;
  2547. ;PRINT FILENAME IN FCB POINTED TO BY [DE]
  2548. ;
  2549. PRTFNAME:
  2550.     INC    DE        ;point to filename
  2551.     LD    H,8        ;filename is 8 bytes
  2552.     CALL    PRTDESTR    ;print the filename
  2553.     CALL    PRTBLANK    ;print a blank
  2554.     LD    H,3        ;filetype is 3 bytes
  2555.  
  2556. ;...............
  2557. ;
  2558. ;PRINT STRING AT [DE] FOR LENGTH OF [H] BYTES
  2559. ;
  2560. PRTDESTR:
  2561.     LD    A,(DE)        ;get a char
  2562.     AND    7FH        ;strip parity
  2563.     CALL    CONOUT        ;print it
  2564.     INC    DE        ;bump pointer
  2565.     DEC    H        ;adjust count
  2566.     jr    NZ,PRTDESTR    ;loop for more
  2567.     RET
  2568.  
  2569. ;.............
  2570. ;
  2571. ;PRINT A BLANK
  2572. ;
  2573. PRTBLANK:
  2574.     LD    A,' '
  2575.  
  2576.     endif        ;CCP
  2577.  
  2578. ;.............
  2579. ;
  2580. ;CONSOLE OUTPUT WITH REGISTERS SAVED
  2581. ;
  2582. CONOUT:
  2583.     PUSH    BC
  2584.     PUSH    DE
  2585.     PUSH    HL
  2586.     CALL    CONO
  2587.     POP    HL
  2588.     POP    DE
  2589.     POP    BC
  2590.     RET
  2591.  
  2592. ;..................
  2593. ;
  2594. ;[HL] = [HL] + [A]
  2595. ;
  2596. ADDHLA:
  2597.     ADD    A,L
  2598.     LD    L,A
  2599.     RET    NC    
  2600.     INC    H
  2601.     RET
  2602.  
  2603. ;................
  2604. ;
  2605. ;COMPARE STRINGS [DE] TO [HL]
  2606. ;
  2607. COMPARE:
  2608.     LD    BC,0FFH        ;B = 0 , C = -1
  2609. CMPARE1:
  2610.     PUSH    DE        ;Save the 
  2611.     PUSH    HL        ;    pointers
  2612. CMPRLOOP:
  2613.     LD    A,(DE)        ;get a byte
  2614.     AND    7FH        ;strip parity
  2615.     CP    21h        ;is it non-blank and graphic?
  2616.     jr    C,COPARE2    ;jump if blank or non-graphic
  2617.     CP    (HL)        ;compare with target char
  2618.     jr    NZ,NOMATCH    ;jump if no match
  2619. COPARE2:
  2620.     INC    DE        ;bump source pointer
  2621.     INC    C        ;bump counter
  2622.     LD    A,' '
  2623.     CP    (HL)        ;at end of target string (terminated by blank)?
  2624.     INC    HL        ;bump target pointer
  2625.     jr    NZ,CMPRLOOP    ;jump if more to compare
  2626.     POP    HL        ;restore these
  2627.     POP    DE        ;    pointers
  2628.     CALL    MOVEC        ;move target string to source.. match found
  2629.     LD    A,B        ;A = string number
  2630.     RET
  2631. NOMATCH:        ;Here if no match found
  2632.     LD    A,' '
  2633. COMARE4:        ;Find end of target string
  2634.     CP    (HL)        ;are we at end?
  2635.     INC    HL        ;bump pointer
  2636.     jr    NZ,COMARE4
  2637.     POP    DE        ;align stack
  2638.     POP    DE        ;recover DE
  2639.     INC    B        ;bump string number
  2640.     LD    C,0FFH        ;init length
  2641.     LD    A,(HL)        ;get first char of next string
  2642.     SUB    1        ;end of list?
  2643.     jr    NC,CMPARE1    ;jump if more strings to compare
  2644.     RET
  2645.  
  2646.  
  2647.     if    ccphistory
  2648.  
  2649. ;
  2650. ;   >>>>>>--  COMMAND LINE HISTORY PROCESSING FOR CP/M PLUS --<<<<<<
  2651. ;
  2652. ;    (C) Copyright 1986 by Michael D. Kersenbrock, 18625 S.W. Hennig
  2653. ;    Court, Aloha, Oregon 97006  All rights Reserved.
  2654. ;
  2655. ;       Personal non-commercial use and distribution of this software
  2656. ;    is permitted so long as the above Copyright notice is maintained
  2657. ;    with this and subsequent copies.
  2658. ;
  2659. ;    History (no pun intended, but noted):
  2660. ;
  2661. ;        Version 1.0 - September 1986  Original release
  2662. ;
  2663. ;
  2664. ;  This was written first in psuedo HLL code, then hand coded into assembly
  2665. ;  language.  That psuedo-HLL code is included below as comment lines.
  2666. ;
  2667. ;Note: No matter how efficiently written, this isn't really practical without
  2668. ;      a ramdisk or a fast hard disk.  No strong effort is done to minimize
  2669. ;      the file size (and thus disk speed) because it isn't likely to 
  2670. ;      acceptably fast with a floppy (regardless). I use a FAST 720K ramdisk.
  2671. ;      Actually, I have tried it with my floppy, and it isn't too bad at all
  2672. ;      but then, the floppy IS cache'd.  I did my own cacheing over and above
  2673. ;      CP/M 3.0's (didn't like theirs), so I don't know how it works with
  2674. ;      DRI's version of cache. I have 178K of floppy-file cacheing.
  2675. ;
  2676. ;      This history implements "!!", "!pattern", "!number" for command
  2677. ;      substitution, and implements the command 'h' to give a list of 
  2678. ;      previous commands and their numbers.
  2679. ;
  2680. ;      These examples use '!' as the history command character, this is
  2681. ;      the same as Berkeley-UNIX's (tm of AT&T) CSH shell.  This CP/M
  2682. ;      implementation uses '|' interchangeably.  The functions implemented
  2683. ;      are:
  2684. ;
  2685. ;        !!            Repeat last command, similar to ^W
  2686. ;
  2687. ;        !<pattern>    Repeat last command that starts with
  2688. ;                the given pattern.
  2689. ;
  2690. ;        !<number>    Repeat command numbered <number>
  2691. ;
  2692. ;                EACH OF THE ABOVE THREE: append the rest of
  2693. ;                "this line" to the substituted line. Example:
  2694. ;
  2695. ;                   If command #40 were: "COMPILE -O -C", then
  2696. ;                   "!40 ROUTINE.C" would result in:
  2697. ;                   "COMPILE -O -C ROUTINE.C"
  2698. ;
  2699. ;        h        Command that gives numbered command history 
  2700. ;                list to be used with the above command.
  2701. ;
  2702. ;    When a history-substitution is made for a command, the new
  2703. ;    command line is presented to the console for editing in a
  2704. ;    similar fashion to the banked-^W command (unlike csh).
  2705. ;
  2706. ;    With the substitutions, the rest of the calling command line
  2707. ;    (if any) is added onto the substitution-replacement line.
  2708. ;
  2709. ;    If you don't want submit files to store their internal-commands
  2710. ;    into the history record, put a space in front of those commands.
  2711. ;
  2712. ;    If the file "<tempdisk>: CCP.EXT" exists, then that program is
  2713. ;    loaded into memory at address 6000H, then executed with HBUFFER 
  2714. ;    and CMDLINE address-pointers passed on the stack "above" the
  2715. ;       return address. CMDLINE's pointer is "just" above the return address.
  2716. ;
  2717. ;
  2718. ;    Data structure "buffer" has 42 CMDSIZE-byte records numbered 0-41.
  2719. ;
  2720. ;        defns: when file is read in, 
  2721. ;                record 1: contains the last command number
  2722. ;                record 2: contains the last command
  2723. ;            then...
  2724. ;                record 0: is where last command nr is moved to
  2725. ;                record 1: is where "translated" current command
  2726. ;                      is built.
  2727. ;    
  2728. ;        
  2729. ;History file format:
  2730. ;
  2731. ;        One command line per RECSIZE byte logical record.
  2732. ;
  2733. ;        First sector contains the current command number (1-byte)
  2734. ;
  2735. ;        Second sector contains the last command 
  2736. ;        Third sector contains the command before last 
  2737. ;                (etc.)
  2738. ;
  2739. ;        If the first byte of a sector is a null, we have
  2740. ;        "reached the end" of the history (null-commands are
  2741. ;        not stored).
  2742. ;
  2743. ;        The file saves the last 40 command lines.
  2744. ;
  2745. ;        A "command-line" has the first byte being the byte count,
  2746. ;        and a null-terminator just after the last "real" byte.
  2747. ;
  2748. ;            If a substituted command line is modified by the line
  2749. ;          editor (when given the opportunity), then this new changed
  2750. ;        version will be put into the history along with the one
  2751. ;        "fetched" from history.
  2752. ;
  2753. ; Pattern: String of non-space and non-control characters
  2754. ;
  2755. ;
  2756. ;
  2757. ; This history routine is called with a newly gotten command in the
  2758. ; CMDLINE buffer.  This routine will play games with the buffer (possibly
  2759. ; modifying its contents), then return.
  2760. ;
  2761.  
  2762. HBUFFER        EQU    2000H        ; Put buffer past CCP/STACK
  2763. ADRCCPEXT    EQU    6000H        ; Give buffer 16K of room
  2764. NRCMDS      EQU    40              ; Number of commands in history
  2765. NRRECS          EQU    NRCMDS + 2    ; Number of records in history buffer
  2766. RECSIZE        EQU    SIZECMDLINE + 4    ; Size of each record in history buffer
  2767. HBUFFSIZE    EQU    NRRECS * RECSIZE  ; The buffer's size
  2768. NRSECTORS    EQU    (HBUFFSIZE/128)+1 ; sector count of file
  2769. HIST1        EQU    '!'        ; Unix csh compatible history char
  2770. HIST2        EQU    '|'        ; Alternate easier to hit
  2771. RCORD0        EQU    HBUFFER        ; Address of record-0
  2772. RCORD1        EQU    HBUFFER+RECSIZE ; Address of record-1
  2773. RCORD2        EQU    HBUFFER+2*RECSIZE ; Address of record-2
  2774.  
  2775. HISTORY:
  2776.  
  2777. ;    if (Command length == 0 || cmd starts w/' ' or ':') {
  2778.  
  2779.     ld    a,(CMDLINE)    ; get command's length
  2780.     or    a        ; zero length?
  2781.  
  2782. ;        return();
  2783.  
  2784.     ret    z        ; yep, punt
  2785.     ld    a,(CMDLINE + 1);
  2786.     cp    ' '        ; space?
  2787.     ret    z
  2788.     cp    ':'
  2789.     ret    z
  2790.  
  2791. ;    }
  2792. ;    buffer is cleared to nulls
  2793.  
  2794.     ld    de,HBUFFER    ; Point to history buffer
  2795.     ld    bc,HBUFFSIZE    ; Indicate size
  2796.     call    CLRBUF        ; Clear it to zeros
  2797.  
  2798.  
  2799. ;    Check to see if "temp:Historyx.dat" exists
  2800. ;
  2801. ;    if (exists) {
  2802. ;        readfile into data buffer starting at record-1 point
  2803. ;    }
  2804. ;
  2805.  
  2806.     call    GETHIST        ; load history buffer
  2807.  
  2808. ;    read command number from record-1, and write it to record-0 
  2809.  
  2810.     ld    a,(RCORD1)     ; fetch the last command's number
  2811.  
  2812.     ld    (RCORD0),a    ; put it into place at record-0
  2813.  
  2814. ;    reset substitution and error flags;
  2815.     
  2816.     xor    a        ; get a zero
  2817.     ld    (FLAGSUB),a    ; reset substitution-happened flag
  2818.     ld    (HERROR),a    ; reset error flag
  2819.  
  2820.  
  2821.  
  2822. ;    if (first-char == '!') {
  2823.  
  2824.     ld     hl,CMDLINE+1    ; point to first character
  2825.     ld    a,(HL)        ; get that character
  2826.     call    ISHISTCHAR    ; one of the history-triggering characters?
  2827.     jp    nz,HST1        ; nope, go...
  2828.  
  2829. ;        if (2nd char == '!') {
  2830.  
  2831.     inc    hl        ; point to second character
  2832.     ld    a,(HL)        ; get it
  2833.     call     ISHISTCHAR    ; is it a history-triggering character?
  2834.     jr    nz,HST2        ; nope, go...
  2835.  
  2836. ;            copy line at record-2 to record-1;
  2837.  
  2838.     ld    hl,RCORD2    ; put record-2's address into source register
  2839.     ld    de,RCORD1    ; put record-1's address into dest register
  2840.     ld    bc,RECSIZE    ; load size of a record
  2841.     ldir            ; do the copy
  2842.  
  2843. ;            copy rest of cmdline onto end of the record-1 line;
  2844.  
  2845.     ld    hl,CMDLINE+3    ; point to rest of command line
  2846.     ld    de,RCORD1    ; point at line to put it at
  2847.     call    CMDCAT        ; concatinate the command lines
  2848.  
  2849. ;            set substitution flag;
  2850.     ld    a,1
  2851.     ld    (FLAGSUB),a    ; set substitution-happened flag
  2852.     jp    HST3
  2853.  
  2854. ;        }
  2855. ;        else if (rest up to a terminator is numeric) {
  2856.  
  2857. HST2:
  2858.  
  2859.     call    ISNUMERIC    ; numeric?
  2860.     jp    nc,HST4        ; nope
  2861. HST21:
  2862.     inc    hl        ; yep, so it MIGHT be a numeric substitution
  2863.     ld    a,(hl)        ; get next character
  2864.     call    ISNUMERIC    ; numeric?
  2865.     jr    c,HST21        ; yep, look at next character
  2866.     cp    ' '+1        ; a "proper" terminator?
  2867.     jp    nc,HST4        ; nope
  2868.                 ; yep
  2869.  
  2870. ;            translate number to binary;
  2871.  
  2872.     push    hl        ; save pointer to "rest-of-command-line".
  2873.     call    ATOI        ; value is now in DE, rest of cmd is at (HL)
  2874.  
  2875. ;            if ( command number wanted is NOT in our list ) {
  2876.  
  2877.     ld    a,(RCORD0)    ; get command number for entry at record-2
  2878.     ld    d,a
  2879.     ld    a,e
  2880.     sub    d        ; calculate difference  reqnr - cmdnr
  2881.     dec    a        ; correct boundary condition
  2882.     and    63        ; make modulo-64 loop-around
  2883. HST7:    cp    64-NRCMDS    ; range within history database size?
  2884.     jr    c,HST5        ; nope, go do error dance
  2885.     ld    d,a
  2886.     ld    a,65
  2887.     sub    d        ; calculate record number for our data
  2888.     call    RECADDR        ; calculate address of that record into HL
  2889.     ld    a,(hl)        ; get count of that record
  2890.     or    a        ; set flags, is this an active record?
  2891.     jr    nz,HST6        ; yes, so number is effectively valid
  2892.                 ; no
  2893.     
  2894. HST5:
  2895.  
  2896.     pop    hl        ; clean stack
  2897. ;                clear cmd line
  2898.  
  2899.     ld    hl,0        ; get a double-zero
  2900.     ld    (CMDLINE),hl    ; zero command line count, and nul terminate it
  2901.  
  2902. ;                print "not found"
  2903.  
  2904.     ld    hl,HERR1    ; point to error message
  2905.     ld    c,0        ; indicate null-termination
  2906.     call    PRTNAME
  2907.     call    CRLF
  2908.  
  2909. ;                set errorflag;
  2910.  
  2911.     ld    a,1
  2912.     ld    (HERROR),a
  2913. ;                break out from first level 'if'
  2914.  
  2915.     jp    HST8
  2916.  
  2917. ;            }
  2918. ;            else {
  2919.  
  2920. HST6:
  2921.  
  2922. ;                copy record[(cmdnr-number+1)] to record-1;
  2923.  
  2924.     ;
  2925.     ; we enter with the substitution record already pointed to by HL
  2926.     ;
  2927.     
  2928.     ld    de,RCORD1    ; load destination address
  2929.     ld    bc,RECSIZE    ; load size of record
  2930.     ldir            ; do the copy
  2931.  
  2932. ;            copy rest of cmdline onto end of the record-1 line;
  2933.  
  2934.     pop    hl        ; get back pointer to rest-of-command-line
  2935.     ld    de,RCORD1    ; point at line to put it at
  2936.     call    CMDCAT        ; concatinate the command lines
  2937.  
  2938. ;                set substitution flag;
  2939.  
  2940.     ld    a,1
  2941.     ld    (FLAGSUB),a
  2942.  
  2943. ;            }
  2944.     jp    HST3
  2945. ;        }
  2946. ;        else {
  2947.  
  2948. HST4:
  2949.  
  2950. ;            search (bottom-up) for a string match (no white space)
  2951.  
  2952.     ld    b,1        ; initialize record counter
  2953. HST44:    inc    b        ; point to next record
  2954.     ld    a,b        ; get record number
  2955.     cp    NRRECS        ; already checked "last" one?
  2956.     jr    nc,HST10     ; yep, none matched
  2957.     call    RECADDR        ; get pointer to next record to check
  2958.     inc    hl        ; point to first character in string
  2959.     push    hl        ; save database string pointer
  2960.     ex    de,hl        ; put record pointer into DE
  2961.     ld    hl,CMDLINE+2    ; point at first character after !/|
  2962.     call    CMPSTRG        ; string match?
  2963.     pop    de        ; get database string pointer back
  2964.     jr    nc,HST44    ; nope, try next one
  2965.                 ; yep, we found it
  2966.  
  2967. ;            if (found) {
  2968. ;                copy that line to record-1;
  2969.  
  2970.     ;
  2971.     ; We enter with the substitution record already pointed to by DE,
  2972.     ; and the "rest of the commandline" pointed to by HL.
  2973.     ;
  2974.     
  2975.     push    hl        ; save "rest of commandline"
  2976.     ex    de,hl        ; put found matching-line-pointer into src pntr
  2977.     dec    hl        ; point back to byte count part of record
  2978.     ld    de,RCORD1    ; load destination address
  2979.     ld    bc,RECSIZE    ; load size of record
  2980.     ldir            ; do the copy
  2981.  
  2982. ;                copy rest of cmd line onto end of record-1 line
  2983.  
  2984.     pop    hl        ; get pointer to "rest of commandline"
  2985.     ld    de,RCORD1    ; point to the line we just fetched above
  2986.     call    CMDCAT        ; concatinate the lines
  2987.  
  2988.  
  2989. ;                set substitution flag;
  2990.  
  2991.     ld    a,1
  2992.     ld    (FLAGSUB),a
  2993.     jp    HST11
  2994.  
  2995. ;            }
  2996. ;            else {    
  2997.  
  2998. HST10:
  2999. ;                clear cmd line
  3000. ;                print "not found"
  3001. ;                set errorflag;
  3002. ;                break out from first level 'if'
  3003.  
  3004.     jp    HST5    ; does same as needed here, so we'll save a byte or two
  3005.  
  3006. ;            }
  3007.  
  3008. HST11:
  3009.  
  3010. ;        }
  3011.  
  3012. HST3:
  3013.  
  3014. ;        copy record-1 to cmdline;
  3015.  
  3016.     ld    hl,RCORD1    ; load source pointer
  3017.     ld    de,CMDLINE    ; load destination
  3018.     ld    bc,SIZECMDLINE  ; max size
  3019.     ldir            ; do the copying
  3020.     jp    HST8    
  3021.  
  3022. ;
  3023. ;    }
  3024. ;    else if (1st char == 'h' && 2rd char == terminator) {
  3025.  
  3026. HST1:
  3027.     ld    hl,CMDLINE+1    ; point to first character
  3028.     ld    a,(hl)        ; get it
  3029.     cp    'h'        ; an 'h'?
  3030.     jp    nz,HST9        ; nope
  3031.     inc    hl        ; point to second character
  3032.     ld    a,(hl)        ; get that one also
  3033.     cp    ' '+1        ; a terminator?
  3034.     jp    nc,HST9        ; nope, so go handle "regular" command
  3035.  
  3036. ;        reset substitution flag, and set err flag
  3037.  
  3038.     xor    a        ; get a zero
  3039.     ld    (FLAGSUB),a    ; reset substitution flag
  3040.     inc    a        ; get nonzero
  3041.     ld    (HERROR),a    ; set error flag
  3042.  
  3043. ;        print cmd lines w/numbers to screen
  3044.  
  3045.  
  3046.     call    CRLF        ; start on fresh line
  3047.     ld    a,(RCORD0)    ; get cmd number of record at record-2
  3048.     sub    NRCMDS-1    ; calculate number of last record
  3049.     and    63        ; modulo 64
  3050.     ld    b,a        ; put into record counter location
  3051.     dec    b        ; pre-decrement for proper start
  3052.     ld    c,NRRECS    ; load record counter
  3053. HST111:
  3054.     ld    a,b        ; get command number
  3055.     inc    a        ; increment to next command number
  3056.     and    63        ; do modulo 64
  3057.     ld    b,a        ; put counter back
  3058.     dec    c        ; count to next record number
  3059.     ld    a,c        ; get it
  3060.     cp    2        ; Done with all of them?
  3061.     jp    c,HST8        ; yep
  3062.     call    RECADDR        ; nope, so go get pointer to record
  3063.     ld    a,(hl)        ; get byte count of that record
  3064.     or    a        ; a null-line?
  3065.     jr    z,HST111    ; yes, don't display those
  3066.     inc    hl        ; no, so point to the line's data
  3067.     push    bc        ; save counters
  3068.     push    hl        ; save that data pointer for a second
  3069.     ld    a,b        ; get command number
  3070.     cp    10        ; single digit?
  3071.     call    c,PRTBLANK    ; yes, align display columns
  3072.     ld    a,b        ; get command number
  3073.     call    PRTNUM        ; print it
  3074.     call    PRTBLANK    ; print a space
  3075.     call    PRTBLANK    ; print a space
  3076.     pop    hl        ; get data pointer to historical cmd line
  3077.     ld    c,0        ; indicate null-termination
  3078.     call    PRTNAME        ; print the string
  3079.     call    CRLF        ; and complete the line
  3080.     pop    bc        ; get our counters back
  3081.     jp    HST111        ; do next command line in history
  3082.  
  3083.  
  3084. ;    }
  3085. ;    else {
  3086.  
  3087. HST9:
  3088.  
  3089. ;        copy cmdline to record-1
  3090.  
  3091.     ld    hl,CMDLINE
  3092.     ld    de,RCORD1
  3093.     ld    bc,RECSIZE
  3094.     ldir
  3095.  
  3096. ;    }
  3097.  
  3098.  
  3099. HST8:
  3100.  
  3101.  
  3102. ;    if (not ERRORFLAG) {
  3103.  
  3104.     ld    a,(HERROR)    ;get error flag
  3105.     or    a        ;errors?
  3106.     jr    nz,HST13    ;yep, so don't change the history database
  3107.  
  3108. ;        increment command number at 0 ;
  3109.  
  3110.     ld    a,(RCORD0)    ;get the command number
  3111.     inc    a        ;increment it
  3112.     and    63        ;modulo 64
  3113.     ld    (RCORD0),a    ;put it back
  3114.  
  3115. ;        if (first-char-of-cmd is printable, and not ' ' or ':') {
  3116.  
  3117.     ld    a,(RCORD1+1)    ; get first byte of new command string
  3118.     cp    ' '+1        ; ctl char or space?
  3119.     jr    c,HST88        ; yep, so don't save line in history
  3120.     cp    ':'        ; colon?
  3121.     jr    z,HST88        ; yep, so don't save line in history
  3122.  
  3123. ;            write buffer starting at record0 (bumps last one out)
  3124.  
  3125.     call    PUTHIST        ;save history back to file in ramdisk
  3126.  
  3127. ;        }
  3128.  
  3129. HST88:    jr    HST99
  3130.  
  3131. ;    }
  3132. ;    else {
  3133. ;        reset command line;
  3134. HST13: 
  3135.     ld    hl,0        ; get a zero
  3136.     ld    (CMDLINE),hl    ; reset command line
  3137.     jr    hst14
  3138.  
  3139. ;    }
  3140.  
  3141. HST99:
  3142. ;
  3143. ;    if (substitution flag set) {
  3144.  
  3145.     ld    a,(FLAGSUB)    ;get substitution flag
  3146.     or    a        ;was the command line modified?
  3147.     jr    z,HST14        ;nope, so just process normally
  3148.                 ;yes
  3149.  
  3150. ;        calculate checksum of cmdline;
  3151.  
  3152.     ld    hl,CMDLINE-1    ; point to full command line buffer
  3153.     call    CMDSUM        ; calculate it's checksum
  3154.     ld    (HCMDSUM),de    ; save it
  3155.  
  3156. ;        set DMA address to cmdline;
  3157.  
  3158.     ld    de,CMDLINE-1    ; put buffer's address into DE
  3159.     call     SETDMA        ; set the dma address
  3160.     
  3161. ;        set DE to zero and call function 10 (edit substitution line);
  3162.  
  3163.     call    CRLF
  3164.     call    prompt        ; print a prompt
  3165.     ld    de,0        ; indicate that the buffer is loaded
  3166.     ld    c,10        ; function number 10
  3167.     call    xbdos        ; allow line be be edited
  3168.     call    SDEFDMA        ; put Dma back to default value
  3169.     ld    hl,CMDLINE    ; point to new command line
  3170.     ld    a,(hl)        ; fetch count
  3171.     inc    hl        ; point to first char
  3172.     call    addhla        ; calculate where just-past-end-is
  3173.     xor    a        ; get a zero
  3174.     ld    (hl),a        ; terminate string 
  3175.  
  3176. ;        if (new checksum != old checksum) {
  3177.  
  3178.     ld    hl,CMDLINE-1    ;point to command line buffer again
  3179.     call    CMDSUM        ;calulate checksum again
  3180.     ld    hl,(HCMDSUM)    ;get previous checksum
  3181.     or    a        ;reset carry
  3182.     sbc    hl,de        ;checksum the same (no change by user)?
  3183.  
  3184. ;            go through self again;
  3185.  
  3186.     jp    nz,HISTORY    ;do again if it was changed 
  3187.                 ;incase it was modified for substitution
  3188.                 ;again (silly operator).  Also we will put
  3189.                 ;this new version into the history.
  3190. ;        }
  3191.  
  3192.  
  3193.  
  3194. HST15:
  3195.  
  3196. ;    }
  3197.  
  3198. HST14:
  3199. ;
  3200. ;    command line now contains command line, ready for "normal" processing.
  3201.  
  3202.     ret
  3203.  
  3204.     ;
  3205.     ; Clear buffer pointed to by DE that is of size BC
  3206.     ;
  3207. CLRBUF:
  3208.     push    hl        ; save whatever
  3209.     ld     l,e        ; load hl with
  3210.     ld     h,d        ;        de
  3211.     ld     (hl),0        ; load first location in block
  3212.     inc     de        ; point the "to" pointer at second location
  3213.     dec      bc        ; count the one we did "manually"
  3214.     ldir            ; block move the rest
  3215.     pop     hl        ; get whatever back
  3216.     ret            ; all pau
  3217.  
  3218.  
  3219.     ;
  3220.     ; Calculate and return address of record number in 'a'
  3221.     ; Return value in HL
  3222.     ;
  3223. RECADDR:
  3224.     push     bc        ; save whatever
  3225.     ld      hl,0        ; zero accumulator
  3226.     ld      bc,RECSIZE    ; load size of ONE record
  3227. CALCADR: sub    1        ; set carry (borrow) flag
  3228.     jr     c,RECEXIT    ; calculated offset?
  3229.     add     hl,bc        ; nope, add in another record size
  3230.     jr     CALCADR        ; test it again
  3231. RECEXIT:
  3232.     ld      bc,HBUFFER    ; load start address of the buffer itself
  3233.     add     hl,bc        ; add in the calculated offset
  3234.     pop     bc        ; restore whatever
  3235.     ret
  3236.  
  3237.  
  3238.     ;
  3239.     ; Opens History file and loads buffer at record-1.  Hbuffer is assumed
  3240.     ; to be already cleared upon entry.
  3241.     ;
  3242. GETHIST:
  3243.     call     OPENHIST    ; open history file
  3244.     jr     nz,CLOSEHIST    ; close if only now created
  3245.     ld       e,NRSECTORS    ; Get size of file (16K max)
  3246.     ld       c,2ch        ; get bdos nr for setting multi-sectors
  3247.     call     xbdos        ; set that many sectors
  3248.     ld      de,RCORD1    ; get record-1's address into DE
  3249.     call    SETDMA        ; set the dma address
  3250.     call    GETBLK        ; read that many sectors all at once
  3251.     jr       CLOSEHIST    ; close file
  3252.  
  3253. GETBLK:
  3254.     ld       de,HFCB        ; point DE at history's FCB
  3255.     ld       c,14h        ; get bdos number for read sequential
  3256.     call     xbdos        ; read file into buffer
  3257.     push    af        ; save return value
  3258.     ld       e,1        ; set multi-sector count back to one
  3259.     ld       c,2ch        ; get bdos nr for setting multi-sectors
  3260.     call     xbdos        ; set that many sectors
  3261.     pop    af        ; get read status back
  3262.     ret
  3263.     
  3264.  
  3265.     ;
  3266.     ; Writes out History file from buffer at record-0.
  3267.     ; Also closes the file.
  3268.     ;
  3269. PUTHIST:
  3270.     call     OPENHIST    ; Open history file
  3271.     ld       e,NRSECTORS    ; Get size of file (16K max)
  3272.     ld       c,2ch        ; get bdos nr for setting multi-sectors
  3273.     call     xbdos        ; set that many sectors
  3274.     ld       de,RCORD0    ; get record-0's address into DE
  3275.     call     SETDMA        ; set the dma address
  3276.     xor    a        ; get a zero
  3277.     ld    (HFCBCR),a    ; zero "cr" field of the FCB
  3278.     ld       de,HFCB        ; point DE at history's FCB
  3279.     ld       c,15h        ; get bdos number for write sequential
  3280.     call     xbdos        ; write file from buffer
  3281.     ld       e,1        ; set multi-sector count back to one
  3282.     ld       c,2ch        ; get bdos nr for setting multi-sectors
  3283.     call     xbdos        ; set that many sectors 
  3284.  
  3285.  
  3286. CLOSEHIST:
  3287.  
  3288.     ld       de,HFCB        ; point at history's FCB again
  3289.     ld       c,10h        ; get bdos number for file closing
  3290.     call       xbdos        ; close file, then return
  3291.     jp    SDEFDMA        ; reset DMA address back to default
  3292.  
  3293.  
  3294.     ;
  3295.     ; Find and open/create history file on the "TEMP" disk.
  3296.     ;
  3297.     ; Returns: ZeroFlag   SET if file existed
  3298.     ;                RESET if file just created
  3299.     ;
  3300.  
  3301. OPENHIST:
  3302.     ld    hl,HNAME    ; load source of extension file's name
  3303.     ld    de,HFCB+1    ; load addr of FCB Name-field
  3304.     ld    bc,11        ; load size of CPM name
  3305.     ldir            ; move it
  3306.     ld    a,(usernum)    ; get user number
  3307.     add    a,'A'        ; make unique and printable
  3308.     ld    (HFCBUSER),a    ; make history file unique to user number
  3309.     ld     a,(ix+6ch)    ; get temp file drive
  3310.     ld    (HFCB),a    ; put into FCB
  3311.     xor    a        ; get a zero
  3312.     ld    (HFCBCR),a    ; zero "cr" field of the FCB
  3313.  
  3314.  
  3315.     ;
  3316.     ; Opens file at HFCB, the name is assumed
  3317.     ; to be already loaded, and it is assumed to be on the temp drive.
  3318.     ;
  3319.     ; 
  3320.  
  3321. OPENTEMP:
  3322.     call    OPENEXIST    ; Open existing file 
  3323.     ret    z        ; return with existing file opened
  3324.     ld    c,16h        ; didn't exist, so get make-file bdos number
  3325.     ld    de,HFCB        ; make sure still pointed at FCB
  3326.     call    xbdos        ; create file
  3327.     ld    a,1        ; un-set zero flag
  3328.     or    a
  3329.     ret
  3330.  
  3331.     ;
  3332.     ; Opens file at FCB if it already exists.
  3333.     ; Returns: Zero flag SET with Success 
  3334.     ;       Zero flag RESET if file doesn't already exist
  3335.  
  3336. OPENEXIST:
  3337.     ld     a,(ix+6ch)    ; get temp file drive
  3338.     ld    (HFCB),a    ; put into FCB
  3339.     ld    de,HFCB2    ; point just past name
  3340.     ld    bc,26        ; size of FCB past name
  3341.     call    CLRBUF        ; clear out FCB
  3342.     ld    de,HFCB        ; point to History file FCB
  3343.     ld    c,0fh        ; open file bdos code
  3344.     call    xbdos        ; open the file
  3345.     or    a        ; set flags, did file exist?
  3346.     ret            ; zero flag set if it did exist
  3347.  
  3348.     ;
  3349.     ; Translate numeric string at (HL) into binary, and return
  3350.     ; value in DE, and HL pointing just after the number (which is
  3351.     ; where it entered at).
  3352.     ;
  3353.     ; It is assumed that the input stream has already been checked
  3354.     ; for at least a single numeric character and that only the
  3355.     ; two LSB's count anyway.
  3356.  
  3357. ATOI:  push    hl        ;save pointer to "just after the number"
  3358.     ld    d,0        ;init our accumulator
  3359.     dec    hl        ;point to LSB character
  3360.     ld    a,(hl)        ;get character
  3361.     call    ATOB        ;convert to binary
  3362.     ld    e,a        ;finish accumulator initialization
  3363.     dec    hl        ;point to next-LSB character
  3364.     ld    a,(hl)        ;get next character
  3365.     call    ISNUMERIC    ;We have a second digit?
  3366.     jr    nc,ATOIEXIT    ;nope, so exit already
  3367.     call    ATOB        ;convert to binary
  3368.     ex    de,hl        ;put accumulator into hl
  3369.     ld    de,10        ;tens digit
  3370. ATOI4:    sub    1
  3371.     jr    c,ATOI5
  3372.     add    hl,de        ;add a ten
  3373.     jr    ATOI4
  3374. ATOI5:  ex    de,hl        ;put accumlator back
  3375.  
  3376. ATOIEXIT:
  3377.     pop    hl        ;get the "just after" pointer
  3378.     ret
  3379.     
  3380.     ;
  3381.     ; Convert ascii numeral in 'a' to binary 
  3382.     ; return: CARRY FLAG SET indicates ERROR
  3383.     ;
  3384. ATOB:    sub    '0'        ; subtract ascii offset
  3385.     ret    c        ; punt if ascii was not numeric (too low)
  3386.     cp    10        ; test to see if it was (too high) numeric
  3387.     ccf            ; make same sense as first test
  3388.     ret
  3389.     
  3390.  
  3391.     ;
  3392.     ; Calculates checksum of command line string pointed to by HL,
  3393.     ; returning that 16-bit checksum in DE
  3394.     ; 
  3395.     ; The format of the command line string is assumed to be
  3396.     ; that as returned by a BDOS-10 call.
  3397.     ;
  3398. CMDSUM:
  3399.     inc    hl        ;point at byte count
  3400.     ld    b,(hl)        ;get number of bytes
  3401.     ld    de,0        ;initialize checksum
  3402. SUMLOOP:
  3403.     inc    hl        ;point at next character
  3404.     ld    a,(hl)        ;get it
  3405.     add    a,e        ;add partially to checksum
  3406.     jr    nc,SUMLP2    ;carry into checksum MSB?
  3407.     inc    d        ;yep, do the carry
  3408. SUMLP2: ld    e,a        ;reassemble checksum
  3409.     djnz    SUMLOOP        ;do for entire string
  3410.     ret            ;and done.
  3411.  
  3412.  
  3413.  
  3414.     ;
  3415.     ; Compares string at (HL) with string at (DE) returning
  3416.     ; CARRY FLAG: SET if equal
  3417.     ; CARRY FLAG: RESET if different
  3418.     ;
  3419.     ; Returns with both DE and HL pointers pointing just one past
  3420.     ; the matching-string (when it matches).
  3421.     ;
  3422.     ; Controlling string is at (HL).  This string, up to it's first
  3423.     ; non-alphanumeric, is tested for equality to that at (DE).
  3424.     ; Comparison is not case sensitive.
  3425.     ;
  3426. CMPSTRG:
  3427.     push    bc
  3428. CMPAGN:    ld    a,(hl)        ;get controlling string
  3429.     cp    '!'        ;alpha numeric (printable)?
  3430.     jr    c,CMPST2     ;nope, HL ended first, so strings matched
  3431.     call    UCASE        ;make sure upper case
  3432.     ld    b,a        ;save for a sec.
  3433.     ld    a,(de)        ;get other string's char
  3434.     call    UCASE        ;make sure upper case
  3435.     cp    b        ;strings match?
  3436.     inc    hl        ;     (update
  3437.     inc    de        ;        pointers to next in strings)
  3438.     jr    z,CMPAGN    ;yup they match, do next character
  3439.     or    a        ;reset carry flag
  3440. CMPST2:    pop    bc
  3441.     ret            ;return a no-match
  3442.  
  3443.  
  3444.     ;
  3445.     ; This checks to see if the ascii character in register
  3446.     ; 'a' is the history-mechanism's invocation character
  3447.     ; (or it's alternate).
  3448.     ;
  3449.     ; Modifies nothing but flags
  3450.     ;
  3451.     ; Returns: ZERO FLAG SET if it is one of those characters
  3452.     ;       ZERO FLAG RESET if NOT one
  3453. ISHISTCHAR:
  3454.     cp    HIST1
  3455.     ret    z
  3456.     cp    HIST2
  3457.     ret
  3458.  
  3459.  
  3460.     ;
  3461.     ; This checks to see if the ascii character in register
  3462.     ; 'a' is numeric.
  3463.     ;
  3464.     ; Modifies nothing but flags
  3465.     ;
  3466.     ; Returns: CARRY FLAG SET if it is numeric
  3467.     ;       CARRY FLAG RESET if NOT numeric
  3468.  
  3469. ISNUMERIC:
  3470.     cp    '0'
  3471.     ccf    
  3472.     ret    nc
  3473.     cp    '9'+1
  3474.     ret
  3475.  
  3476.  
  3477.     ;
  3478.     ; Concatinate the null-terminated string pointed to by HL to
  3479.     ; the "command-format" string pointed to by DE.  The DE string
  3480.     ; has only the string-length and a null-terminated string.
  3481.     ;
  3482. CMDCAT:
  3483.     push    de        ; save pointer to string length
  3484.     ld    a,(de)        ; get current string length
  3485.     ld    b,a        ; install into our length counter
  3486.     inc    de        ; point at the string's first character
  3487.     push     hl        ; save source string for a second
  3488.     ex    de,hl        ; calculate where the command's null is at
  3489.     call    ADDHLA
  3490.     ex      de,hl        ; put destination pointer into DE
  3491.     pop    hl        ; put source string pointer into HL
  3492. CMDCT2:
  3493.     ld    a,(hl)        ; get source character
  3494.     or    a        ; null terminator?
  3495.     jr    z,CMDCT3    ; yep, go clean up
  3496.     ld    (de),a        ; nope, load it to the destination
  3497.     inc    hl        ; update..
  3498.     inc    de        ;     .. both src/dest pointers to next char
  3499.     inc    b        ; count the added character
  3500.     ld    a,b        ; get that count
  3501.     cp    SIZECMDLINE    ; combined length too long?
  3502.     jr    c,CMDCT2    ; nope, go do another character
  3503.                 ; yep, so it's exit time prematurely
  3504. CMDCT3: xor    a        ; get a null
  3505.     ld    (de),a        ; null-terminate destination string
  3506.     pop    hl        ; get back pointer to destination's byte count
  3507.     ld    (hl),b        ; update it to the new length
  3508.     ret
  3509.     
  3510.  
  3511.  
  3512.     ;
  3513.     ; Looks for file "tempdisk: CCP.EXT".  If it exists, it is loaded
  3514.     ; at address ADRCCPEXT, and passed HBUFFER (two above) and
  3515.     ; CMDLINE (just above) the return address on the stack.
  3516.     ;
  3517.     ; Upon CCP.EXT's Return: "Return value" is to be returned in register
  3518.     ; HL and it normally should be a zero.  If it is non-zero, then
  3519.     ; the internal history mechanism will be bypassed.  
  3520.     ;
  3521.     ; The basic idea here is that additional "shell" concepts could
  3522.     ; be implemented in a HLL ("C" being thought of in particular).
  3523.     ; Like this history mechanism, this probably is only practical
  3524.     ; with systems with bank-switched RAMDISK.  My system executes
  3525.     ; this history mechanism with no noticeable pause.  My "temp-disk"
  3526.     ; is a 720K DMA-driven bank-switching RAMDISK.  My floppies are
  3527.     ; 8" DSDD 1.2MB each.  I have no hard disk to try it out on.
  3528.     ; My Z80 runs at 5Mhz with no waitstates.
  3529.     ;
  3530.     ;
  3531. CCPEXT:
  3532.     ld    hl,HEXTNAME        ; load source of extension file's name
  3533.     ld    de,HFCB+1        ; load addr of FCB Name-field
  3534.     ld    bc,11            ; load size of CPM name
  3535.     ldir                ; move it
  3536.     call    OPENEXIST        ; try to open the file
  3537.     jr    nz,CCPEX2        ; exit if not successful
  3538.     xor    a            ; get a zero
  3539.     ld    (HFCBCR),a        ; zero "cr" field of the FCB
  3540.     ld    hl,ADRCCPEXT        ; get starting address
  3541.     ld    de,0
  3542. CCPEX1: add    hl,de            ; calculate next address
  3543.     push    hl            ; save it
  3544.     ex    de,hl            ; put into de
  3545.     call    SETDMA            ; point DMA there
  3546.     call    GETBLK            ; read a block
  3547.     pop    hl            ; get dma pointer back
  3548.     ld    de,128            ; sector size
  3549.     or    a            ; last sector?
  3550.     jr    z,CCPEX1        ; nope, so read another
  3551.     call    CLOSEHIST
  3552.     ld    hl,HBUFFER        ; get pointer to history buffer
  3553.     push    hl            ; 
  3554.     ld    hl,CMDLINE        ; get pointer to incoming command line
  3555.     push    hl
  3556.     call    ADRCCPEXT        ; call loaded program
  3557.     ld    a,h            ; get..
  3558.     or    l            ;     ....hl value
  3559.     pop    hl
  3560.     pop    hl            ; clean stack
  3561.     ret
  3562. CCPEX2: xor    a            ; set zero flag
  3563.     ret                ;
  3564.     
  3565.  
  3566.     
  3567.     
  3568.     
  3569.  
  3570. HEXTNAME:    defb    'CCP     EXT'
  3571. HNAME:        defb    'HISTORY DAT'
  3572. HERR1:        defb    0dh,0ah,'Substitution not found',0
  3573. HFCB:        defb    0,'HISTORY'
  3574. HFCBUSER:    defb    ' '
  3575.         defb    'DAT'
  3576. HFCB2:        defw    0,0,0,0,0,0,0,0,0,0
  3577. HFCBCR:        defb    0,0,0,0,0,0,0,0,0
  3578. FLAGSUB:    defb    0
  3579. HERROR:        defb    0
  3580. HCMDSUM:    defw    0
  3581.  
  3582.  
  3583. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  3584. ;;;;;;;;;;;;;;;;;;;;;;;                    ;;;;;;;;;;;;;;;;;;;;;;
  3585. ;;;;;;;;;;;;;;;;;;;;;;;        END OF HISTORY MODULE    ;;;;;;;;;;;;;;;;;;;;;;
  3586. ;;;;;;;;;;;;;;;;;;;;;;;                    ;;;;;;;;;;;;;;;;;;;;;;
  3587. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  3588.  
  3589.     endif    ;ccphistory
  3590.  
  3591.  
  3592. ;..................
  3593. ;
  3594. ;MESSAGES
  3595. ;
  3596.  
  3597. msgflag:    DEFB    0
  3598. SCBPB:        DEFB    3ah,0
  3599. PFCB:        DEFW    0
  3600.         DEFW    PRSEFCB
  3601.  
  3602.     if    not ccp
  3603.  
  3604. lbrcmp:        defb    0,'           ',0,0
  3605. lbrfcb:        defb    0,0,'COMMAND LBR',0,0,0,0
  3606.         defs    21
  3607.  
  3608.     else        ;if CCP
  3609.  
  3610. USER0MSG:    DEFB    ' (User 0)$'
  3611. rootrsx:    DEFB    65
  3612. rsx66:        DEFB    66
  3613. diradr:        DEFW    0
  3614. rootname:    DEFS    9
  3615. rootpass:    DEFS    9
  3616. rootdrv:    DEFS    1
  3617. rootusr:    DEFS    1
  3618. datpb:        DEFS    4
  3619.  
  3620.     endif
  3621.  
  3622. subflag:    defs    1
  3623. USERNUM:    DEFs    1
  3624. DISKNUM:    DEFs    1
  3625. CURDSK:        DEFs    1
  3626. NXTNMA:        DEFS    2
  3627. CMDPTR:        DEFS    2
  3628. BOFFSET:    DEFS    1
  3629. BDOSBASE:    DEFS    1
  3630.  
  3631.     if    not ccp
  3632.  
  3633. searoff:    ds    2
  3634. searflg:    ds    2
  3635. duspec:        ds    1
  3636. usrsav:        ds    2
  3637. buff:        defs    128
  3638. scbbase:    defs    2
  3639. memaddr:    defs    2
  3640. lbrsec:        defs    2
  3641. typeflag:    defs    1
  3642.  
  3643.     endif
  3644.  
  3645. PASSWORD:    DEFS    10
  3646. CMDFCB:        DEFS    1
  3647. FILEDISK:    DEFS    1
  3648. FILENAME:    DEFS    8
  3649. FILETYPE:    DEFS    24
  3650. LOADADDR:    DEFS    2
  3651. PRSEFCB:    DEFS    37
  3652. CMDLINE:    DEFS    138H
  3653.  
  3654.     if not ccphistory
  3655.  
  3656. STACK     EQU    $
  3657.  
  3658.     endif ; not ccphistory
  3659.  
  3660.     if ccphistory
  3661.  
  3662. STACK   EQU    1300H
  3663.  
  3664.     endif ; ccphistory
  3665.  
  3666.     END
  3667.     ;ccphistory
  3668.  
  3669.  
  3670. ;..................
  3671. ;
  3672. ;MESSAGES
  3673. ;
  3674.  
  3675. msgflag:    DEFB    0
  3676. SCBPB:        DEFB    3ah,0
  3677. PFCB:        DEFW