home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / CPM3 / BANKSWAP.LBR / BANKSWAP.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  11KB  |  493 lines
  1. ; BANKSWAP.ASM
  2. ; 
  3. ; A. S. Woodhull      28 June 83
  4. ; rev     1 July 85    -- minor editing
  5. ;     20 Oct 83
  6. ; 
  7. ; This is designed to be run as a subprogram under DDT
  8. ; or SID, in a banked version of CP/M 3.0  The function
  9. ; of BANKSWAP is to copy blocks of memory from other 
  10. ; banks to and from bank 1, using a buffer in the common
  11. ; area.  Normal DDT or SID functions can then be 
  12. ; performed, using the copy of the code in bank 1.  
  13. ; (Of course, you cannot trace through program segments
  14. ; that switch banks or access memory mapped I/O in 
  15. ; another bank.)
  16. ; 
  17. ; BANKSWAP must reside in the common area of memory, and
  18. ; a buffer area through which data can be copied must 
  19. ; also be present in the common area.  BANKSWAP is to be
  20. ; assembled as a Resident System Extension (RSX), which
  21. ; will automatically be relocated to the top of the TPA.
  22. ; It is assumed that the common area is large enough to 
  23. ; allow an RSX to fit--if this is not true BANKSWAP will
  24. ; not work in its present form.
  25. ; 
  26. ; Because the location of BANKSWAP in memory is not fixed
  27. ; a jump through a fixed location is set up when the BANK-
  28. ; SWAP code is installed.  In this version the  RST 5 vector
  29. ; at 28H is used, but any convenient location on page zero
  30. ; may be used. 
  31. ; 
  32. ; Under CP/M 3 direct access of BIOS routines is generally
  33. ; to be avoided by user programs, since BIOS routines may
  34. ; have expectations about which bank is selected when they 
  35. ; are called.  We will, however, do bank switching through
  36. ; the BIOS selmem routine.  For generality we will use the 
  37. ; BIOS vector at location 1.
  38. ; 
  39. true:    equ    0ffffh
  40. false:    equ    not true
  41. ; 
  42. alone:    equ    false    ;make false if attached to DDT/SID
  43. ; 
  44. biosv:    equ    1    ;address of wboot in BIOS found here
  45. selmem:    equ    4eh    ;offset from wboot 
  46. ; 
  47. buflen:    equ    100h    ;move block size
  48. ; 
  49. ; default parameters
  50. movcnt:    equ    1000h    ;to move 16 pages (4K) at a time
  51. b0dft:    equ    100h    ;start of block in bank 0
  52. b1dft:    equ    100h    ;start of block in bank 1
  53. ; 
  54. ; zero page addresses
  55. bdos:    equ    5    ;bdos entry point
  56. rstv:    equ    28h    ;RST 5 used as entry vector
  57. ; 
  58. ; BDOS functions used
  59. conin:    equ    1    ;get a char
  60. printf:    equ    9    ;print a string
  61. rdbuf:    equ    10    ;read a line
  62. ; 
  63. ; This is standard prefix for a Resident System Extension
  64. ;  see CP/M 3 Programmer's Guide, 1st ed., sec. 4.4, p.168
  65. ; 
  66. serial:    db    0,0,0,0,0,0
  67. start:    jmp    install    ;one-time routine
  68. next:    jmp    0    ;altered at installation
  69. prev:    dw    0
  70. ; 
  71.     if    alone
  72. rmvflg:    db    0    ;keep this in memory 
  73.     else    
  74. rmvflg:    db    0ffh    ;remove when main program ends
  75.     endif
  76. ; 
  77. nonbnk:    db    0    ;banked system
  78.     db    'BANKSWAP'
  79. loader:    db    0
  80.     db    0,0
  81. ; *** note: If BANKSWAP is to be attached directly to SID.COM
  82. ; or DDT.COM then make rmvflg 0ffh to force removal 
  83. ; 
  84. bankexam:
  85.     lxi    h,0    ;get stack pointer
  86.     dad    sp    ;...and hold it for return
  87.     shld    holdsp    ;...reset SP to a location
  88.     lxi    sp,locstk    ;...in common memory
  89. ; 
  90. ; Main loop--exit by Quit or Remove command
  91. bankex2:
  92.     call    prompt    ;this returns address of sub
  93.     call    doit    ;do subroutine addressed by HL
  94.     jmp    bankex2
  95. ; 
  96. prompt:    lxi    d,menu    ;get ready for menu
  97.     lda    quietflag
  98.     ora    a    ;suppress menu?
  99.     jz    prmpt2
  100. prmpt1:    lxi    d,query    ;set for prompt only
  101. prmpt2:    mvi    c,printf
  102.     call    bdos    
  103. ; Get a character
  104.     mvi    c,conin
  105.     call    bdos
  106.     call    crlf
  107. ; make upper case, reject non-alpha
  108.     ani    5fh
  109.     cpi    'A'
  110.     jc    prmpt1    ;ask again if invalid
  111.     cpi    'Z'+1
  112.     jnc    prmpt1    ;ask again if invalid
  113. ; find match in alphtbl
  114.     lxi    b,altblen    ;length of table
  115.     lxi    h,alphtbl+altblen    ;work back
  116. try:    cmp    m
  117.     jz    match
  118.     dcx    h
  119.     dcr    c    ;count down
  120.     jnz    try
  121. ; if c= 0 no match found.  Now form address
  122. match:    lxi    h,addrtbl
  123.     dad    b    ;add offset
  124.     dad    b    ;again, 2 bytes per table entry
  125. ; get the command address
  126.     mov    a,m
  127.     inx    h
  128.     mov    h,m
  129.     mov    l,a
  130.     ret        ;HL has action address
  131. ; 
  132. doit:    pchl        ;call here to use action address
  133. ; 
  134. getbank:
  135.     lhld    b0start    ;setup addresses
  136.     shld    source
  137.     lhld    b1start
  138.     shld    dest
  139.     lda    length+1    ;low byte ignored
  140.     sta    count
  141. ; page by page take a chunk of bank 0 to buffer, then move
  142. ; to bank 1 destination
  143. get2:    
  144.     di        ;be sure no interrupts
  145.     mvi    a,0
  146.     lhld    selmv
  147.     call    doit
  148.     call    getbuf
  149.     mvi    a,1
  150.     lhld    selmv    ;point to BIOS selmem routine
  151.     call    doit
  152.     ei        ;interrupts safe again
  153.     call    putbuf
  154.     lxi    d,buflen
  155.     lhld    source
  156.     dad    d
  157.     shld    source
  158.     lhld    dest
  159.     dad    d
  160.     shld    dest
  161.     lxi    h,count    ;repeat for required # of pages
  162.     dcr    m
  163.     jnz    get2
  164.     ret
  165. ; 
  166. putbank:
  167.     lhld    b1start
  168.     shld    source
  169.     lhld    b0start
  170.     shld    dest
  171.     lda    length+1    ;low byte ignored
  172.     sta    count
  173. ; page by page, move bank 1 data to buffer, then move it 
  174. ; to bank 0
  175. put2:
  176.     call    getbuf
  177.     di        ;be sure no interrupts
  178.     mvi    a,0
  179.     lhld    selmv
  180.     call    doit
  181.     call    putbuf
  182.     mvi    a,1
  183.     lhld    selmv
  184.     call    doit
  185.     ei        ;interrupts safe again
  186.     lxi    d,buflen
  187.     lhld    source
  188.     dad    d
  189.     shld    source
  190.     lhld    dest
  191.     dad    d
  192.     shld    dest
  193.     lxi    h,count
  194.     dcr    m
  195.     jnz    put2
  196.     ret
  197. ; source to buffer
  198. getbuf:
  199.     lhld    source
  200.     lxi    d,buffer
  201.     jmp    pb1
  202. ; buffer to dest
  203. putbuf:
  204.     lhld    dest
  205.     lxi    d,buffer
  206.     xchg
  207. ; common code for getbuf and putbuf
  208. pb1:    lxi    b,buflen
  209. ; move (BC) bytes from (HL) to (DE) (could use BIOS move
  210. ; routine for this)
  211. move:    mov    a,m    
  212.     stax    d
  213.     inx    h
  214.     inx    d
  215.     dcx    b
  216.     mov    a,b
  217.     ora    c
  218.     jnz    move
  219.     ret
  220. ; 
  221. ; Go back to SID/DDT
  222. quit:    lxi    d,qmsg    ;say how to get back
  223.     mvi    c,printf
  224.     call    bdos
  225.     lhld    holdsp    ;restore stack pointer
  226.     sphl
  227.     rst    7    ;back to DDT or SID
  228. ; 
  229.     if    alone
  230. ; Set for removal on termination of SID or DDT
  231. remove:    lxi    h,rmvflg    ;set the remove flag
  232.     mvi    m,0ffh        ;...in the RSX prefix 
  233.     lxi    h,rstv        ;then wipe out the entry
  234.     mvi    m,0ffh        ;...JMP with an RST 7
  235.     rst    7        ;leave via the debugger
  236.     endif    ;alone
  237. ; 
  238. ; Set up addresses for move, also set up length
  239. adset:    lxi    d,b0id    ;tell current bank 0 addr
  240.      mvi    c,printf
  241.     call    bdos
  242.     lhld    b0start    ;get the address
  243.     call    addro    ;and print it
  244.     lxi    h,b0start
  245.     call    update    ;enter hex to (HL)
  246.     lxi    d,b1id    ;do it again for bank 1
  247.      mvi    c,printf
  248.     call    bdos    ;tell
  249.     lhld    b1start
  250.     call    addro
  251.     lxi    h,b1start
  252.     call    update    ;get new address, if any
  253. ; Can fall through from adset or enter directly here to set
  254. ; length of block moved
  255. lnset:    lxi    d,lnmsg    ;tell current length
  256.      mvi    c,printf
  257.     call    bdos
  258.     lhld    length
  259.     call    addro
  260.     lxi    h,length
  261.     call    update    ;offer to change it
  262.     call    crlf
  263.     ret
  264. ; 
  265. ; Toggle menu off/on
  266. xpert:    lda    quietflag
  267.     cma            ;toggle
  268.     sta    quietflag
  269.     ret
  270. ; 
  271. ; Get here on invalid command
  272. na:    lxi    d,namsg        ;say can't do it
  273.     mvi    c,printf
  274.     call    bdos
  275.     ret
  276. ; 
  277. crlf:    push    b
  278.     push    d
  279.     push    h
  280.     push    psw
  281.     lxi    d,crlfstring
  282.     mvi    c,printf
  283.     call    bdos
  284.     pop    psw
  285.     pop    h
  286.     pop    d
  287.     pop    b
  288.     ret
  289. ; 
  290. ; get string, do nothing if null, else convert, store at (HL)
  291. update:
  292.     push    h        ;save the location
  293. ; loop back here if input is not valid
  294. upd1:    lxi    h,0        ;initial buffer
  295.     shld    inbuf+1
  296.     lxi    d,chquery    ;say what's up
  297.     mvi    c,printf
  298.     call    bdos
  299.     lxi    d,inbuf
  300.     mvi    c,rdbuf        ;read console until <ret>
  301.     call    bdos
  302.     call    crlf
  303.     lda    inbuf+1        ;get length of hex string
  304.     ora    a        ;check for 0 length input
  305.     jnz    convert
  306. ; null string, go back
  307.     pop    h        ;retrieve value at entry
  308.     ret
  309. ; 
  310. ; Convert the hex string in the buffer to binary
  311. convert:
  312.     lxi    h,0    ;start with a zero
  313.     mov    b,a    ;hold length in B
  314.     lxi    d,inbuf+2
  315. conv2:    ldax    d    ;get first (or next) char
  316.     inx    d
  317.     cpi    60h
  318.     jc    conv3
  319.     ani    5fh    ;make lower case if necessary
  320. conv3:    sui    '0'
  321.     jm    upd1    ;must be valid hex, 0..9, A..F
  322.     cpi    0ah
  323.     jc    num    ;jump if a good numeric
  324.     sui    7
  325.     cpi    0ah
  326.     jc    upd1    ;error if not good alpha
  327.     cpi    10h
  328.     jnc    upd1    ;error if not good alpha
  329. num:    dad    h    ;multiply current val by 16
  330.     dad    h
  331.     dad    h
  332.     dad    h
  333.     add    l    ;add new least significant digit
  334.     mov    l,a
  335.     dcr    b    ;countdown the digits
  336.     jnz    conv2
  337.     xchg        ;result to DE
  338.     pop    h    ;HL at entry says where to it
  339.     mov    m,e
  340.     inx    h
  341.     mov    m,d
  342.     ret
  343. ; 
  344. ; Print HL as hex
  345. addro:
  346.     push    d
  347.     push    h
  348.     xchg
  349.     lxi    h,hexstr    ;where to build string
  350.     mov    a,d
  351.     call    byte    ;get A as 2 ASCII chars at (HL)
  352.     mov    a,e
  353.     call    byte    ;again, low byte
  354.     lxi    d,hexstr
  355.     mvi    c,printf
  356.     call    bdos    ;print it
  357.     pop    h
  358.     pop    d
  359.     ret
  360. ; 
  361. ; Convert byte to hex ASCII chars, put at (HL)
  362. byte:    push    psw
  363.     rar        ;get high nybble
  364.     rar
  365.     rar
  366.     rar
  367.     call    nybble
  368.     pop    psw    ;fall through for low nybble
  369. ; nybble makes 1 char, advances output pointer    
  370. nybble:    ani    0fh
  371.     adi    '0'
  372.     cpi    3ah
  373.     jc    nput
  374.     adi    7
  375. nput:    mov    m,a
  376.     inx    h
  377.     ret
  378. ; 
  379. ; Acceptable command inputs go in this table
  380. alphtbl:
  381.     db    0    ;dummy for no match
  382.     db    'A'
  383.     db    'G'
  384.     db    'L'
  385.     db    'P'
  386.     db    'Q'
  387. ; 
  388.     if    alone
  389.     db    'R'
  390.     endif    ;alone
  391. ; 
  392.     db    'X'
  393. altblen:    equ    $-alphtbl
  394. ; addresses of action routines, same order as alphtabl
  395. addrtbl:
  396.     dw    na    ;not available
  397.     dw    adset    ;address set
  398.     dw    getbank
  399.     dw    lnset    ;length set
  400.     dw    putbank
  401.     dw    quit
  402. ; 
  403.     if    alone
  404.     dw    remove
  405.     endif
  406. ; 
  407.     dw    xpert    ;expert mode, no menu
  408. ; 
  409. menu:    db    'Bankswap 1.0 by A. S. Woodhull 10/20/83',0dh,0ah
  410.     db    'functions available:',0dh,0ah
  411.     db    '    A...set move Addresses',0dh,0ah
  412.     db    '    G...Get alternate bank',0dh,0ah
  413.     db    '    L...set move Length',0dh,0ah
  414.     db    '    P...Put alternate bank',0dh,0ah
  415.     db    '    Q...Quit to SID or DDT',0dh,0ah
  416. ; 
  417.     if    alone
  418.     db    '    R...Remove BANKSWAP',0dh,0ah
  419.     endif
  420. ; 
  421.     db    '    X...eXpert mode (no menu)',0dh,0ah
  422. query:    db    0dh,0ah,'?? $'
  423. namsg:    db    '...function not available.'
  424. crlfstring:
  425.     db    0dh,0ah,'$'
  426. b0id:    db    'Bank 0 addr: $'
  427. b1id:    db    'Bank 1 addr: $'
  428. lnmsg:    db    'Length is now $'
  429. chquery:
  430.     db    'Change to? (CR to keep): $'
  431. hexstr    ds    4
  432.     db    'H',0dh,0ah,'$'
  433. qmsg:    db    'Re-enter BANKSWAP from DDT or SID by "G28"'
  434.     db    0dh,0ah,'$'
  435. ; 
  436. quietflag:
  437.     db    0    ;initialized off
  438. inbuf:    db    8    ;max length of buffer
  439.     ds    9
  440. ; 
  441. ; default parameters: alter by Set and Length commands
  442. b0start:    dw    b0dft
  443. b1start:    dw    b1dft    
  444. length:        dw    movcnt     
  445. ; 
  446. ; One-time routine, on 1st BDOS call intercepted
  447. install:
  448.     push    b    ;keep everything as it was
  449.     push    d    ;...so BDOS function can be
  450.     push    h    ;...completed
  451.     push    psw
  452. ; set up restart vector for re-entry
  453.     mvi    a,0c3h    ;a JMP instruction
  454.     sta    rstv
  455.     lxi    h,bankexam
  456.     shld    rstv+1
  457. ; set up address of BIOS routine accessed directly
  458.     lhld    biosv        ;find where BIOS is
  459.     lxi    d,selmem    ;...and add offset
  460.     dad    d
  461.     shld    selmv
  462. ; then patch the RSX prefix to prevent reinstallation
  463.     lhld    next+1
  464.     shld    start+1
  465. ; tell 'em we're ready
  466.     mvi    c,printf
  467.     lxi    d,imsg
  468.     call    next
  469.     pop    psw    ;continue with the task that
  470.     pop    h    ;...was so rudely interrupted
  471.     pop    d
  472.     pop    b
  473.     jmp    next
  474. ; 
  475. imsg:    db    'BANKSWAP loaded. To access from DDT or '
  476.     db    'SID type "G28"'
  477.     db    0dh,0ah,'$'
  478. ; 
  479. ; reuse installation code area for stack space
  480. locstk:
  481. ; 
  482. ; uninitialized storage
  483. selmv:    ds    2    ;used for BIOS call to selmem
  484. source:    ds    2    ;for moves to buffer
  485. dest:    ds    2    ;for moves from buffer
  486. count:    ds    1    ;blocks to move
  487. holdsp:    ds    2    ;stack pointer from DDT or SID
  488. ; 
  489. buffer:
  490.     ds    buflen
  491.     endinstall:
  492.     push    b    ;keep everything as it was
  493.     p