home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / BYE5 / B5AM-1.INS < prev    next >
Text File  |  2000-06-30  |  4KB  |  174 lines
  1.  
  2. ; B5AM-1.INS - AMPRO "Little Board" insert for BYE5 - 07/17/85
  3. ;
  4. ;        DART I/O and CTC timer 2.000 MHz
  5. ;
  6. ; Note:  This is an insert, not an overlay.
  7. ;
  8. ; This version is for the AMPRO "Little Board" using channel "B" of the
  9. ; Z80 DART.  The Z80-CTC is used as the baud rate generator.
  10. ;
  11. ;       The AMPRO computer does not implement DTR or DCD
  12. ;       (CTS and RTS are used instead - however they take
  13. ;       the CTS to the AMPRO pin 20!)
  14. ;
  15. ;       Make up a RS232 cable per the instructions below:
  16. ;
  17. ;            Modem       Ampro
  18. ;            -----       -----
  19. ;            pin 2    -  pin 3
  20. ;            pin 3    -  pin 2
  21. ;            pin 7    -  pin 7
  22. ;            pin 8    -  pin 20
  23. ;            pin 20    -  pin 5
  24. ;
  25. ; Note: These pin assignments assume that your Little Board RS232 female
  26. ; connector is wired the same as the Ampro assembled computers.
  27. ;
  28. ; 
  29. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  30. ;
  31. ; 07/17/85  Written for use with BYE5        - Irv Hoff
  32. ; 02/08/84  Initial Version            - Jerry Haigwood
  33. ;
  34. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  35. ;
  36. ;-----------------------------------------------------------------------
  37. ;
  38. ;
  39. PORT    EQU    88H        ; Data port
  40. MDCTL1    EQU    PORT+4        ; Status/control port
  41. BRPORT    EQU    50H        ; Baud rate port
  42. ;
  43. ;
  44. BD300    EQU    47D0H        ; 62400/300  (first half is CTC command)
  45. BD1200    EQU    4734H        ; 62400/1200
  46. BD2400    EQU    471AH        ; 62400/2400
  47. ;
  48. ;
  49. ;-----------------------------------------------------------------------
  50. ;
  51. ; See if we still have a carrier - if not, return with the zero flag set
  52. ;
  53. MDCARCK:MVI    A,10H        ; Reset status
  54.     OUT    MDCTL1
  55.     IN    MDCTL1        ; Get status
  56.     ANI    20H        ; Check for data carrier
  57.     RET
  58. ;.....
  59. ;
  60. ;
  61. ; Disconnect and wait for an incoming call
  62. ;
  63. MDINIT:    MVI    A,18H        ; Reset channel
  64.     OUT    MDCTL1
  65.     MVI    A,4        ; Setup to write register 4
  66.     OUT    MDCTL1
  67.     MVI    A,84H        ;*1 stop, 8 bits, no parity, 32x
  68.     OUT    MDCTL1
  69.     MVI    A,5        ; Setup to write register 5
  70.     OUT    MDCTL1
  71.     MVI    A,68H        ; Clear RTS causing hangup
  72.     OUT    MDCTL1
  73.     PUSH    B        ; Save in case it's being used elsewhere
  74.     MVI    B,20        ; 2 seconds delay to drop any carrier
  75. ;
  76. OFFTI:    CALL    DELAY        ; 0.1 second delay
  77.     DCR    B
  78.     JNZ    OFFTI        ; Keep looping until finished
  79.     POP    B        ; Restore bc
  80.     MVI    A,3        ; Setup to write register 3
  81.     OUT    MDCTL1
  82.     MVI    A,0C1H        ; Initialize receive register
  83.     OUT    MDCTL1
  84.     MVI    A,5        ; Setup to write register 5
  85.     OUT    MDCTL1
  86.     MVI    A,0EAH        ; Turn on RTS so modem can answer phone
  87.     OUT    MDCTL1
  88. ;
  89.      IF    IMODEM        ; If using intelligent modem
  90.     CALL    IMINIT        ; Go initialize
  91.      ENDIF            ; IMODEM
  92. ;
  93.     RET
  94. ;.....
  95. ;
  96. ;
  97. ; Input a character from the modem port
  98. ;
  99. MDINP:    IN    PORT        ; Get character
  100.     RET
  101. ;.....
  102. ;
  103. ;
  104. ; Check the status to see if a character is available.    If not, return
  105. ; with the zero flag set.  If yes, use 0FFH to clear the flag.
  106. ;
  107. MDINST:    IN    MDCTL1        ; Get status
  108.     ANI    01H        ; Check receive ready bit
  109.     RZ            ; Return if none
  110.     ORI    0FFH        ; Otherwise, set the proper flag
  111.     RET
  112. ;.....
  113. ;
  114. ;
  115. ; Send a character to the modem
  116. ;
  117. MDOUTP:    OUT    PORT        ; Send it
  118.     RET
  119. ;.....
  120. ;
  121. ;
  122. ; See if the output is ready for another character
  123. ;
  124. MDOUTST:IN    MDCTL1
  125.     ANI    04H        ; Check transmit ready bit
  126.     RET
  127. ;.....
  128. ;
  129. ;
  130. ; Reinitialize the modem and hang up the phone by dropping DTR and
  131. ; leaving it inactive.
  132. ;
  133. MDQUIT:     IF    IMODEM        ; If using a smartmodem
  134.     CALL    IMQUIT        ; Tell it to shut down
  135.      ENDIF            ; IMODEM
  136. ;
  137. ;
  138. ; Called by the main program after caller types BYE
  139. ;
  140. MDSTOP:    MVI    A,5        ; Setup to write register 5
  141.     OUT    MDCTL1
  142.     MVI    A,68H        ; Clear RTS causing shutdown
  143.     OUT    MDCTL1
  144.     RET
  145. ;.....
  146. ;
  147. ;
  148. ; The following routine sets the baudrate.  BYE5 asks for the maximum
  149. ; speed you have available.
  150. ;
  151. SETINV:    ORI    0FFH        ; Make sure zero flag is not set
  152.     RET            ; Return
  153. ;.....
  154. ;
  155. ;
  156. SET300:    LXI    H,BD300        ; Get 300 bps parameters in 'HL'
  157.     JMP    LOADBD        ; Go load them
  158. ;
  159. SET1200:LXI    H,BD1200
  160.     JMP    LOADBD
  161. ;
  162. SET2400:LXI    H,BD2400
  163. ;
  164. LOADBD:    MOV    A,H        ; CTC command word
  165.     OUT    BRPORT
  166.     MOV    A,L        ; Baudrate
  167.     OUT    BRPORT
  168.     XRA    A
  169.     RET
  170. ;.....
  171. ;
  172. ;                   end
  173. ;-----------------------------------------------------------------------
  174.