home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / BYE5 / B5AA-3.IQS / B5AA-3.INS
Text File  |  2000-06-30  |  7KB  |  320 lines
  1. ; B5AA-3.INS for the Apple PCPI & Super Serial Card for BYE5 - 9/20/85
  2. ;
  3. ;       6551 I/O with internal baudrate generator
  4. ;
  5. ;
  6. ; This version is for Apple ][ computers, using the PCPI Applicard
  7. ; CPM card, and the Apple Super Serial Card.
  8. ;
  9. ;
  10. ; Note:  This is an insert, not an overlay.
  11. ;
  12. ;
  13. ;    MODEM=DCE            Super Serial Card
  14. ;
  15. ;    TXD    2  -------->    2    RXD    received data
  16. ;    RXD    3  <--------    3    TXD    tranmitted data
  17. ;    SG    7  ---------    7    SG    signal ground
  18. ;    DCD    8  -------->    6    DSR    data set ready (carrier)
  19. ;    DTR    20 <-------    20    DTR    data terminal ready
  20. ;
  21. ;
  22. ; This cable configuration uses DSR signal at the SSC to check carrier
  23. ; and Serial card DCD wired to DTR (Jumper pin 20-8) so that modem
  24. ; result codes are received when carrier is off.
  25. ;
  26. ; Set modem switches as defined in B5IM-1.DQC.
  27. ;
  28. ; THIS WORKS PROPERLY WITH BYE5 AND IS COMPATABLE WITH IMP WITHOUT ANY
  29. ; CHANGES, ANY OTHER CONFIGURATION MIGHT REQUIRE RESETTING SOME MODEM
  30. ; SWITCHES WHEN GOING FROM BYE5 TO IMP, MDM7, MEX, ETC.
  31. ;
  32. ;-----------------------------------------------------------------------
  33. ;
  34. ; For the Apple //e, a user entered Control Q can trash the local dis-
  35. ; play by reverting back to 40 column mode.  This is a patch to turn
  36. ; that Control Q into a back space.
  37. ;
  38. ; In BYE5 find the label MINP2A:  Just prior to MINP2A should be the
  39. ; lines:
  40. ;        JNZ    MINP2A
  41. ;        MVI    A,08H
  42. ;
  43. ; Add the following code just before JNZ MINP2A
  44. ;
  45. ;        JZ    CHNGIT
  46. ;        CPI    'Q'-'@'
  47. ;        JNZ    MINP2A
  48. ;    ;
  49. ;    CHNGIT: MVI    A,08H    << note the added label
  50. ;
  51. ; 
  52. ; NOTE: In later versions of BYE5 just set one of the FILTx noise
  53. ; filters to trap Control Q.
  54. ;
  55. ;=  =  =  =  =    =  =  =  =  =  =  =  =    =  =  =  =  =  =  =  =    =  =
  56. ;
  57. ; 08/25/86  Fixed bug that prevented BYE5 from dropping DTR to hang up.
  58. ;                                                -Joe England
  59. ;
  60. ; 12/01/85  Changed RDBYTE label to RDBYT to avoid conflict with RDBYTE
  61. ;        label in BYE502.             -Jerry Levy
  62. ;
  63. ; 09/20/85  Created overlay for BYE5.         -Norman Beeler
  64. ;
  65. ;=  =  =  =  =    =  =  =  =  =  =  =  =    =  =  =  =  =  =  =  =    =  =
  66. ;
  67. SLOT    EQU    2        ; Slot 2 is normal
  68. OFFS    EQU    16*SLOT        ; This is the slot offset
  69. ;
  70. PORT    EQU    0C088H+OFFS    ; Dataport    
  71. STPORT    EQU    PORT+1        ; Status port
  72. CPORT    EQU    PORT+2        ; Command port
  73. BRPORT    EQU    PORT+3        ; Baud rate port
  74. ;......
  75. ;
  76. ;
  77. ; PCPI CP/M card I/O equates
  78. ;
  79. RDBYT    EQU    0FFE0H        ; Read a Byte from Apple (A = BYTE)
  80. WRBYTE    EQU    0FFE3H        ; Write a Byte to Apple (C = BYTE)
  81. RDWORD    EQU    0FFE6H        ; Read 2 Bytes from Apple (DE = BYTES)
  82. WRWORD    EQU    0FFE9H        ; Write 2 Bytes to Apple (DE = BYTES)
  83. RDNBYTS    EQU    0FFECH        ; Read N Bytes (DE = COUNT, HL = BUFFER)
  84. WRNBYTS    EQU    0FFEFH        ; Write N Bytes (DE = COUNT, HL = BUFFER)
  85. ;
  86. PEEK1BYTE EQU    6        ; Command to Peek 1 Byte in the Apple
  87. POKE1BYTE EQU    7        ; Command to Poke 1 Byte to the Apple
  88. ;
  89. ;======================================================================
  90. ;
  91. ; These routines are specific to the Apple ][+ with Applicard.    The
  92. ; routines read modem hardware (Apple Super Serial Card ACIA) directly
  93. ; from the Applicard.
  94. ;
  95. ; Peek at 1 byte from Apple 6502 address space
  96. ;
  97. ;     ENTRY: DE = Address in Apple
  98. ;     EXIT:  A = Data
  99. ;
  100. PEEK:    PUSH    B
  101.     MVI    C,PEEK1BYTE
  102.     CALL    WRBYTE
  103.     CALL    WRWORD
  104.     CALL    RDBYT
  105.     POP    B
  106.     RET
  107. ;.....
  108. ;
  109. ;
  110. ; Poke 1 byte to Apple 6502 address space
  111. ;
  112. ;     ENTRY: DE = Address in Apple
  113. ;     EXIT:  A = Data
  114. ;
  115. POKE:    PUSH    B
  116.     MOV    B,A
  117.     MVI    C,POKE1BYTE
  118.     CALL    WRBYTE
  119.     CALL    WRWORD
  120.     MOV    C,B
  121.     CALL    WRBYTE
  122.     POP    B
  123.     RET
  124. ;.....
  125. ;
  126. ;
  127. ; Read the baud rate port of the ACIA
  128. ;
  129. RD$BRPORT:
  130.     PUSH    D
  131.     LXI    D,BRPORT
  132.     CALL    PEEK
  133.     POP    D
  134.     RET
  135. ;.....
  136. ;
  137. ;
  138. ; Read the command port of ACIA
  139. ;
  140. RD$CPORT:
  141.     PUSH    D
  142.     LXI    D,CPORT
  143.     CALL    PEEK
  144.     POP    D
  145.     RET
  146. ;.....
  147. ;
  148. ;
  149. ; Read data port of ACIA
  150. ;
  151. RD$PORT:PUSH    D
  152.     LXI    D,PORT
  153.     CALL    PEEK
  154.     POP    D
  155.     RET
  156. ;.....
  157. ;
  158. ;
  159. ; Read the status port of the ACIA
  160. ;
  161. RD$STPORT:
  162.     PUSH    D
  163.     LXI    D,STPORT
  164.     CALL    PEEK
  165.     POP    D
  166.     RET
  167. ;.....
  168. ;
  169. ;
  170. ; Write to the baud rate port of the ACIA
  171. ;
  172. WR$BRPORT:
  173.     PUSH    D
  174.     LXI    D,BRPORT
  175.     CALL    POKE
  176.     POP    D
  177.     RET
  178. ;.....
  179. ;
  180. ;
  181. ; Write to the command port of ACIA
  182. ;
  183. WR$CPORT:
  184.     PUSH    D
  185.     LXI    D,CPORT
  186.     CALL    POKE
  187.     POP    D
  188.     RET
  189. ;.....
  190. ;
  191. ;
  192. ; Write to the serial data port of the ACIA
  193. ;
  194. WR$PORT:PUSH    D
  195.     LXI    D,PORT
  196.     CALL    POKE
  197.     POP    D
  198.     RET
  199. ;.....
  200. ;
  201. ;
  202. ;----------------------------------------------------------------------
  203. ;
  204. ;
  205. ; Check for a carrier, if none return with the zero flag set.
  206. ;
  207. MDCARCK:CALL    RD$STPORT    ; Get status
  208.     ANI    40H        ; Check DSR pin for DCD (see above)
  209.     XRI    40H        ; Reverse the zero flag (the 6551
  210.     RET            ; Has status 0 for DCD/DSR true)
  211. ;......
  212. ;
  213. ;
  214. ; This routine will turn off the serial card and hang up the phone.
  215. ;
  216. MDINIT:    MVI    A,4AH        ; Turn off DTR
  217.     CALL    WR$CPORT
  218.     PUSH    B        ; Save register
  219.     MVI    B,20        ; Delay 2 sec to drop carrier
  220. ;
  221. OFFTI:    CALL    DELAY        ; 1 sec per loop
  222.     DCR    B
  223.     JNZ    OFFTI        ; Keep going until finished
  224.     POP    B        ; Restore register
  225.     MVI    A,4BH        ; Raise DTR
  226.     CALL    WR$CPORT
  227.     MVI    A,18H        ; Set 1200,8 bits, 1 stop
  228.     CALL    WR$BRPORT
  229. ;
  230.       IF    IMODEM
  231.     CALL    IMINIT
  232.       ENDIF
  233. ;
  234.     RET
  235. ;.......
  236. ;
  237. ;
  238. ; Input a character from the modem port.
  239. ;
  240. MDINP:    CALL    RD$PORT        ; Get character
  241.     RET
  242. ;......
  243. ;
  244. ;
  245. ; Check the status to see if a character is available.  Return with zero
  246. ; flag set, if not.  If yes, use 0FFH to clear the flag.
  247. ;
  248. MDINST:    CALL    RD$STPORT    ; Get modem status
  249.     ANI    8        ; Is data available?
  250.     RZ            ; If no, return
  251.     ORI    0FFH        ; Otherwise return true
  252.     RET
  253. ;......
  254. ;
  255. ;
  256. ; This routine will output a character to the data port.
  257. ;
  258. MDOUTP:    CALL    WR$PORT        ; Send character
  259.     RET
  260. ;.....
  261. ;
  262. ;
  263. ; See if the output is ready for another character.
  264. ;
  265. MDOUTST:CALL    RD$STPORT    ; Get modem status
  266.     ANI    10H        ; Mask out junk
  267.     RET
  268. ;.......
  269. ;
  270. ;
  271. ; Reinitialize the modem and hang up the phone by dropping DTR and
  272. ; leaving it inactive.
  273. ;
  274. MDQUIT:     IF    IMODEM        ; If using a smartmodem
  275.     CALL    IMQUIT        ; Tell it to shut down
  276.      ENDIF            ; IMODEM
  277. ;
  278. ;
  279. ; Called by the main program after caller types BYE
  280. ;
  281. MDSTOP:    MVI    A,4AH        ; Drop DTR
  282.     JMP    WR$CPORT
  283. ;.....
  284. ;
  285. ;
  286. ; If you do not support a particular baud rate, put it here
  287. ; before SETINV:
  288. ;
  289. SETINV:    ORI    0FFH
  290.     RET
  291. ;.....
  292. ;
  293. ;
  294. SET300:    MVI    A,16H
  295.     JMP    WR$BRPORT    ; Go change the baud rate
  296. ;.....
  297. ;
  298. ;
  299. SET1200:MVI    A,18H
  300.     JMP    WR$BRPORT
  301. ;.....
  302. ;
  303. ;
  304. SET2400:MVI    A,1AH
  305.     JMP    WR$BRPORT
  306. ;.....
  307. ;
  308. ;
  309. SET4800:MVI    A,1CH
  310.     JMP    WR$BRPORT
  311. ;.....
  312. ;
  313. ;
  314. SET9600:MVI    A,1EH
  315.     JMP    WR$BRPORT
  316. ;.....
  317. ;
  318. ;                end
  319. ;---------------------------------------------------------------------
  320.