home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / BBSING / PBBS / PREG451.LBR / PREG451.MZC / PREG451.MAC
Text File  |  2000-06-30  |  20KB  |  674 lines
  1.     TITLE    PREG.MAC v4.51                Jul 30/89
  2.  
  3. ; Filename    PREG45.MAC
  4. ; Author    Terry Pinto
  5. ; Language    Z-80 Assembler
  6. ; Last Update    May 02/89
  7. ; By        Terry Pinto
  8.  
  9. ; Following are two examples of the assembly and linking process using
  10. ; two of the more popular assemblers today. Make sure that you set the
  11. ; appropriate equate in PBBSEQU.HDR.
  12.  
  13. ; Assembly/Link - Using M80/L80
  14. ;    M80 =PREGnn/N
  15. ;    L80 /P:100,PREGnn,PBBSUBS,SYSLIB/S,PREGnn/N/E
  16. ;
  17. ;              Using SLR180
  18. ;    SLR PREGnn
  19. ;    SLRNKP PREGnn,/A:100,PREGnn,PBBSUBS,SYSLIB/S,/E
  20.  
  21. ; PREG is a registration program designed to be used in conjunction with
  22. ; the Public Bulletin Board System (PBBS). On signon, PREG will get the
  23. ; users profile and check the registration flag, bit 0 of FBYTE, and if
  24. ; set will abort and return control to the operating system displaying
  25. ; a message (if SIGN is set YES) reporting that the user's registration
  26. ; has been validated. The entire signon process is bypassed if SIGN is
  27. ; set to yes rendering PREG transparent to the user. If PREG finds that
  28. ; the registration bit is not set, the user is forced to complete this
  29. ; registration. The user is asked if they wish to register at this time
  30. ; and if they select NO, the call is terminated and the registration bit
  31. ; is not set. This will force the user through this proceedure on every
  32. ; call until they complete their registration. The text at label WELC
  33. ; should relay this information to the user. When the user elects to
  34. ; continue with the registration process, they will be asked to supply
  35. ; additional information about themselves. The questions asked can be
  36. ; changed to suit the needs of the system. Pay close attention to the
  37. ; information requarding these changes should and be necessary. When the 
  38. ; user does not elect to fill out the registration, PREG exits through 
  39. ; the error handler defined as ERRFIL in the PBBSDB.HDR file.
  40. ;
  41. ; The registration database is set up so that you can  configure it as you 
  42. ; see fit. The default settings are those used on my system and I've found 
  43. ; that they work quite well. The only important thing to remember is that 
  44. ; each record is limited to 128 bytes in length. You will need to edit the 
  45. ; fields defined under REQ to suit your systems needs. Only the data will 
  46. ; be saved in the data base and each field is a fixed length. If you are 
  47. ; at all familiar with dBASE, you will be able to read this file in as an 
  48. ; ASCII file with the SDF clause...
  49. ;
  50. ; example:
  51. ;         CREATE filename              ALL FIELDS DEFINED AS CHARACTER
  52. ;            USE filename
  53. ;         APPEND FROM filename.ext SDF
  54. ; 
  55. ; This will read in the entire registration database and allow you to 
  56. ; utilize the powers of dBASE to sort or index the database and generate
  57. ; printouts based on whichever data you think is necessary. For instance,
  58. ; if you have a 500 name user base and a few of the fields you keep in 
  59. ; your database are NAME, ADDRESS, CITY, STATE, ZIP and a YES/NO field
  60. ; called DONATION, you could generate mailing labels of all those users
  61. ; that saw fit to donate to the upkeep of your system and send them a 
  62. ; personalized thank you note.
  63. ;
  64. ; NOTE: While this method will read in the registration database and allow
  65. ; you to index, sort and otherwise manipulate your registration database, it
  66. ; IS NOT recommended that you re-write the database back out to an ASCII disk
  67. ; file. Due to some inconsistancies in the way DBASE II handles the EOF marker,
  68. ; some file corruption can occur. The above proceedure will not alter your
  69. ; original registration database. 
  70.  
  71. ; PREG is used as part of:
  72.  
  73. ;        The Public Bulletin Board System
  74. ;        Author: Ian Cottrell
  75. ;            44 Lindhurst Cres
  76. ;            Ottawa, ON, Canada
  77. ;            K2G 0T7
  78. ;            The Information Centre RCP/M
  79. ;            (613) 952-2289 (300/1200/2400)
  80. ;------------------------------------------------------------------
  81.  
  82. ;    PBBS represents many hours of design,  coding and debugging.
  83. ;    However,  I do not believe in SHAREWARE.   So,    if you    find
  84. ;    PBBS  of  value to you and wish to pay for it in  some    way,
  85. ;    please consider a small contribution ($50 suggested) to your
  86. ;    local  Cancer Society in both of our names (thus creating  a
  87. ;    new  class of software - charityware!).   Then send a little
  88. ;    note telling me what you did and we will both feel good!  In
  89. ;    any case,  please share this program with others, it is free
  90. ;    and no form of remuneration may be accepted by anyone except
  91. ;    its author.
  92.  
  93. ;     Version 4.50     05/02/89    Initial release of PREG
  94. ;    Version 4.51    07/30/89    Removed ':' after labels in
  95. ;                    SIGN: EQU YES and STACK: EQU $
  96. ;                    to maintain M80 compatibility.
  97.  
  98. ;-------------------------------------------------------------------------
  99. ; NOTE: This file MUST be linked to PBSUB416.REL
  100. ;-------------------------------------------------------------------------
  101.  
  102.     EXT    F$OPEN,F$MOPEN,F$WRITE,F$CLOSE,F$APPEND,F$APPL
  103.     EXT    R$READ,R$WRITE
  104.     EXT    PFN2
  105.  
  106.     INCLUDE    PBBSEQU.HDR    ; PBBS configuration equates
  107.  
  108.      IF    M80        ; M80
  109.     .Z80            ; Needed for M80
  110.     ASEG
  111.     ORG    100H
  112.      ENDIF            ; M80
  113.  
  114.     JP    START        ; Jump around header and data
  115.  
  116. Z3IDEN:    DB    'Z3ENV'        ; Z3 Identifier
  117. Z3TYPE:    DB    1        ; Z3 Environment (external)
  118. Z3EADR:    DW    0000        ; Z3 Environment (address)
  119. Z3LOAD:    DW    0000        ; Z3 load address
  120.  
  121. ; Version name, date and levels
  122.  
  123. VNAME::    DB    'PREG '        ; Name
  124. VERDAT::DB    '89/'        ; Year
  125.     DB    '07/'        ; Month
  126.     DB    '30 '        ; Day
  127.     DB    'v',0        ; Status
  128.  
  129. VER::    DB    4        ; Version
  130. VERR::    DB    51        ; Revision
  131.  
  132. AUTHOR::DB    '  by:  Terry Pinto',CR,LF,0
  133.  
  134.     INCLUDE    PBBSDB.HDR    ; PBBS configuration strings, etc
  135.  
  136.     INCLUDE    BDOSHDR.MAC    ; Time and date conversions
  137.  
  138. BELL    EQU    7        ; bell character
  139. GETUSR    EQU    32        ; get user
  140. GETDRV    EQU    25        ; get drive
  141. REGLEN    EQU    128        ; length of registration record
  142.  
  143. ; ------------------------------------------------------------------------
  144. ; USER CONFIGURATION SECTION - EDIT AS NECESSARY!
  145. ; ------------------------------------------------------------------------
  146. ; Setting CNFRM to yes will display the maximum length of user input with
  147. ; underlines. This will give the user guidelines to the maximum allowable
  148. ; input expected. Setting to NO will disable this display.
  149. ;
  150. ; Example:           Name: TERRY PINTO___________________   (Max input 30)
  151. ; (CNFRM - YES)   Address: 14385 SW WALKER RD. B3________   (Max input 30)
  152. ;                  CitySt: BEAVERTON OR_______              (Max input 20)
  153. ;                     Zip: 97006                            (Max input  5)
  154. ;               Telephone: 503 644-0900                     (Max input 12)
  155. ;                     Age: 39                               (Max input  2)
  156. ;                     Sex: M                                (Max input  1)
  157.  
  158. CNFRM    EQU    YES        ; YES to show maximum allowable input
  159.  
  160. ; Setting of the LVL2 equate will bypass all activity of PREG for users
  161. ; above level 2 access. If you only want to present your first time users
  162. ; with the registration program, then set LVL2 to YES. Although PREG will
  163. ; check the registration bit in FBYTE and produce the same results, this
  164. ; activity takes a little longer time. Some SYSOPs may elect to speed up
  165. ; their systems by eliminating this check.
  166.  
  167. LVL2    EQU    NO        ; YES to run for access level 2 only
  168.  
  169. ; The signon message for this program can be controlled by this equate. If
  170. ; you set SIGN to NO the system will not display any signon message. If the
  171. ; settings for CREDIT and VERSION in the PBBSEQU.HDR file are also set to
  172. ; NO, PVER will be totally transparant to the user if they are already 
  173. ; validated by the system.
  174.  
  175. SIGN    EQU    YES        ; yes to display signon message
  176.  
  177. ; This next message will be part of the signon message. This part will
  178. ; be the actual request you issue for the information. 
  179.  
  180. WELC:    DB    CR,LF,'To apply for registration to APRAS, it is necessary'
  181.     DB    CR,LF,'for you to supply all of the additional information.'
  182.     DB    CR,LF,'If you fail to supply the information requested, it'
  183.     DB    CR,LF,'will result in your application being denied and your'
  184.     DB    CR,LF,'call being terminated. The information requested is'
  185.     DB    CR,LF,'for our records and will be kept confidential.'
  186.     DB    CR,LF,0
  187.  
  188. ; This next block contains all of the text sent to the user requesting
  189. ; your information. Edit so that they will make sense on your system.
  190. ; There is no restriction on the length of each statement as long as
  191. ; each is terminated with a binary 0. Each text is preceeded with the
  192. ; maximum length of input allowed. These lengths are reflected in the
  193. ; DS statements below.
  194.  
  195. RNAM:    DB    30,'     Name: ',0    ; text for field 1
  196. RADD:    DB    30,'  Address: ',0    ; text for field 2
  197. RCIT:    DB    20,' City, St: ',0    ; text for field 3
  198. RZIP:    DB     5,'      Zip: ',0    ; text for field 4
  199. RPHN:    DB    12,'Telephone: ',0    ; text for field 5
  200. RAGE:    DB     2,'      Age: ',0    ; text for field 6
  201. RSEX:    DB     1,'      Sex: ',0    ; text for field 7
  202.  
  203. NAME:    DS    30        ; field 1 length
  204. ADDR:    DS    30        ; field 2 length
  205. CITY:    DS    20        ; field 3 length
  206. ZIP:    DS    5        ; field 4 length
  207. TPHONE:    DS    12        ; field 5 length
  208. AGE:    DS    2        ; field 6 length
  209. SEX:    DS    1        ; field 7 length
  210.  
  211. ; The next statement defines the total length of the record and should
  212. ; always be the FILELENGTH-(LASTFIELD+1)-FIRSTFIELD.
  213.  
  214. RXTRA:    DS    REGLEN-(SEX+1-NAME)
  215.  
  216. ; ------------------------------------------------------------------------
  217. ; END OF USER CONFIGURATION SECTION - MAKE NO CHANGES FROM HERE ON!
  218. ; ------------------------------------------------------------------------
  219.  
  220. ; Check for BYE presence
  221.  
  222. START:     LD    E,241        
  223.     LD    C,BEXIST
  224.     CALL    BDOS        ; See if BYE5 is active
  225.     CP    77
  226.     JR    Z,CBBS        ; Check for PBBS operation
  227.     CALL    PRINT        ; Else, abort
  228.     DB    CR,LF,'BYE5 not available, aborting...',CR,LF,0
  229.     JP    EXIT        ; Restore D/U and exit
  230.  
  231. CBBS:    LD    A,(REENTR)    ; Get re-entry byte
  232.     OR    A        ; See if set
  233.     JR    NZ,BEGIN    ; if yes - start program
  234.     CALL    PRINT        ; If not - abort
  235.     DB    CR,LF,'User record not available, aborting...',CR,LF,0
  236.     JP    EXIT        ; Restore D/U and exit
  237.  
  238. ; Preserve system stack, and initialize program stack
  239.  
  240. BEGIN:    LD    (CCPSTK),SP    ; Save the return address
  241.     LD    SP,STACK    ; Install our stack
  242.  
  243.      IF    LVL2         
  244.     LD    A,(LOCK)    ; get user access level
  245.     CP    2        ; are they above level 2
  246.     JP    NZ,EXIT1    ; if yes - exit
  247.      ENDIF            ; LVL2
  248.  
  249. ; Save current drive/user
  250.  
  251.     LD    E,0FFH         
  252.     LD    C,GETUSR
  253.     CALL    BDOS        ; Get current user
  254.     LD    (OLDUSR),A    ; Save it
  255.     LD    C,GETDRV
  256.     CALL    BDOS        ; Get current drive
  257.     LD    (OLDDRV),A    ; Save it
  258.  
  259. ; Everything ok, let's begin
  260.  
  261. SIGNON:    
  262.      IF    SIGN
  263.     CALL    PVER        ; print program signon and version number
  264.  
  265.      IF    CREDITS
  266.     LD    HL,AUTHOR    ; point to author credits
  267.     CALL    PRINTM        ;  and display them
  268.      ELSE
  269.     CALL    PCRLF
  270.      ENDIF            ; CREDITS
  271.      ENDIF            ; SIGN
  272.  
  273. ; Now we log into the drive/user areas defined in the PBBSEQU.HDR file
  274. ; as the SYSDRV and SYSUSR.
  275.  
  276.     LD    A,SYSDRV    ; log into system drive
  277.     LD    E,A
  278.     LD    C,LOGDRV
  279.     CALL    SPBDOS
  280.     LD    A,SYSUSR    ; log into system user area
  281.     LD    E,A
  282.     LD    C,LOGUSR
  283.     CALL    SPBDOS
  284.  
  285. ; Routine to get the active user's record back into memory to be used as 
  286. ; source material for the user's name, city/state and telephone number.
  287. ; The use of this information will eliminate the need to duplicate input
  288. ; on the part of the user. It will also insure the accuracy of both the
  289. ; registration and user databases.
  290.  
  291.     LD    DE,USER        ; point to USERS.PBS FCB
  292.     CALL    F$OPEN        ; open file
  293.     JP    NZ,FOERR    ; file error routines
  294.  
  295. FOPEN:    CALL    SDMA        ; set DMA address
  296.     LD    DE,USER        ; point to USERS.PBS FCB
  297.     LD    HL,(USREC)    ; get users record number
  298.     CALL    R$READ        ; read user record into memory
  299.     JP    NZ,RERR
  300.     CALL    F$CLOSE        ; close user file
  301.     JP    NZ,FCERR
  302.     LD    HL,TBUFF    ; point to TBUFF
  303.     LD    DE,AVAIL     ; point to AVAIL (memory buffer)
  304.     LD    BC,USRLEN    ; length of user file record
  305.     LDIR            ; move data to memory buffer
  306.  
  307.     LD    A,(FBYTE)    ; get user flag byte
  308.     BIT    0,A        ; test registration bit
  309.     JP    Z,ALREG        ; if not set - continue with registration
  310.  
  311.      IF    SIGN
  312.     LD    HL,UNAME    ; point to user name
  313.     CALL    PRINTN        ;  and display it
  314.     CALL    PRINT
  315.     DB    ' - Registration Validated',cr,lf,0
  316.      ENDIF            ; SIGN
  317.     JP    EXIT
  318.  
  319. ; Open registration file for append with the last record in memory. Update
  320. ; the end-of-file marker and then get the next record for input. If the 
  321. ; file is not found it will be created.
  322.  
  323. ALREG:    LD    DE,REGS        ; point to FCB    
  324.     CALL    F$APPL        ; open for append with last record in memory
  325.     JR    NZ,NEOF        ; file not found
  326.  
  327.     LD    HL,NOEND    ; point to bytes for not end of file
  328.     LD    DE,TBUFF+125    ; position in buffer
  329.     LD    BC,3        ; length of no end of file
  330.     LDIR            ; move bytes
  331.     LD    DE,REGS        ; point to REGISTER.LIB FCB
  332.     CALL    F$WRITE        ; write record
  333.     JP    NZ,FWERR
  334.     CALL    F$CLOSE        ; close file
  335.     JP    NZ,FCERR
  336.  
  337. NEOF:    LD    HL,WELC        ; point to welcome message
  338.     CALL    PRINTM        ;  and display it
  339.     CALL    PCRLF    
  340.     CALL    PRINT        ; ask user if they want to register now
  341.     DB    'Would you like to register now? (Y/n) ',0
  342.     CALL    GETCH        ; get user input
  343.     CALL    CAPS        ; capitolize input
  344.     CALL    ECHO        ; echo input to display
  345.     CP    'N'        ; did user say NO
  346.     JP    Z,ERROR        ; if yes - exit and terminate call
  347.  
  348.     LD    A,' '        ; initialize buffer at NAME to spaces
  349.     LD    HL,NAME        ;  for proper field alignment
  350.     LD    BC,REGLEN    ; length of registration record
  351. CLBUF:    LD    (HL),A        ; clear buffer byte
  352.     INC    HL        ; point to next byte
  353.     DJNZ    CLBUF        ; continue until done
  354.  
  355. ;-------------------------------------------------------------------------
  356. ; Display request text, get response from user and save input in buffer
  357.  
  358. GETIN:    CALL    PCRLF1
  359.  
  360. ; Field for NAME displays a method for getting the information from the
  361. ; user record and moving it into the registration buffer automatically
  362. ; displaying the data to the user.
  363.  
  364.     LD    HL,RNAM        ; point to field 1 text
  365.     LD    A,(HL)        ; get length
  366.     LD    B,A        ;  and place in B
  367.     INC    HL        ; point to text
  368.     CALL    PRINTM        ;  and display it
  369.      IF    CNFRM
  370.     CALL    PRLINE
  371.      ENDIF            ; CNFRM
  372.     LD    HL,UNAME    ; point to user name
  373.     CALL    PRINTL        ;  and display it
  374.     CALL    PCRLF    
  375.     LD    HL,RNAM        ; print request for name
  376.     LD    A,(HL)        ; get length
  377.     LD    B,A        ;  and place in B
  378.     LD    HL,UNAME    ; point to user name
  379.     LD    DE,NAME        ; point to name buffer
  380.     CALL    MOVEBF        ; move data and padd with ' '
  381.  
  382. ; Field for ADDRESS displays a method for displaying the request text and
  383. ; getting the input from the user.
  384.  
  385.     LD    HL,RADD        ; print request for address
  386.     LD    DE,ADDR
  387.     CALL    DSPLY
  388.     LD    HL,ADDR
  389.  
  390.     LD    HL,RCIT
  391.     LD    A,(HL)
  392.     LD    B,A
  393.     INC    HL
  394.     CALL    PRINTM
  395.      IF    CNFRM
  396.     CALL    PRLINE
  397.      ENDIF            ; CNFRM
  398.     LD    HL,CITST
  399.     CALL    PRINTL
  400.     CALL    PCRLF
  401.     LD    HL,RCIT        ; print request for city
  402.     LD    A,(HL)
  403.     LD    B,A
  404.     LD    HL,CITST
  405.     LD    DE,CITY
  406.     CALL    MOVEBF
  407.  
  408.     LD    HL,RZIP        ; print request for zip
  409.     LD    DE,ZIP
  410.     CALL    DSPLY
  411.     LD    HL,ZIP
  412.  
  413.     LD    HL,RPHN
  414.     LD    A,(HL)
  415.     LD    B,A
  416.     INC    HL
  417.     CALL    PRINTM
  418.      IF    CNFRM
  419.     CALL    PRLINE
  420.      ENDIF            ; CNFRM
  421.     LD    HL,PHONE
  422.     CALL    PRINTL
  423.     CALL    PCRLF
  424.     LD    HL,RPHN        ; print request for telephone number
  425.     LD    A,(HL)
  426.     LD    B,A
  427.     LD    HL,PHONE
  428.     LD    DE,TPHONE
  429.     CALL    MOVEBF
  430.  
  431.     LD    HL,RAGE        ; print request for age
  432.     LD    DE,AGE
  433.     CALL    DSPLY
  434.     LD    HL,AGE
  435.  
  436.     LD    HL,RSEX        ; print request for sex (don't laugh!!)
  437.     LD    DE,SEX
  438.     CALL    DSPLY
  439.     LD    HL,SEX
  440.  
  441. ;-------------------------------------------------------------------------
  442.  
  443. LDONE:    CALL    PCRLF
  444.     CALL    PRINT        ; get user confirmation
  445.     DB    'Is the above information correct? (Y/n) ',0
  446.     CALL    GETCH        
  447.     CALL    CAPS
  448.     CALL    ECHO
  449.     CP    'N'        ; if not correct - restart registration
  450.     JP    Z,GETIN
  451.     CALL    PRINT
  452.     DB    CR,LF,LF,'Updating Registration Files >>> ',CR,LF,0
  453.  
  454. ; Open file registration file and position for save
  455.  
  456. ROPEN:    LD    DE,REGS        ; point to FCB
  457.     CALL    F$APPEND    ; open file for append
  458.     JP    Z,SETD        ; NZ set if file not found
  459.     CALL    F$MOPEN        ; open file (create if does not exist)
  460.     JP    NZ,FOERR
  461.  
  462. ; Move data to TBUFF. SYSLIB routines default to an FCB of 80H unless
  463. ; a SETDMA is used to change it.
  464.  
  465. SETD:    LD    HL,NAME        ; point to buffer
  466.     LD    DE,TBUFF    ; point to TBUFF
  467.     LD    BC,REGLEN    ; length of record 
  468.     LDIR            ; move data to TBUFF
  469.  
  470.      LD    HL,ENDOF    ; get end of file marker
  471.     LD    DE,TBUFF+125    ; point to last three bytes in file
  472.     LD    BC,3        ; length of end of file marker
  473.     LDIR            ; mark end of file
  474.  
  475. ; Write record to file
  476.  
  477. RPUT:    LD    DE,REGS        ; point to FCB
  478.     CALL    F$WRITE        ; write data from TBUFF to file
  479.     JP    NZ,FWERR
  480.     CALL    F$CLOSE        ; close file
  481.     JP    NZ,FCERR
  482.  
  483.     LD    DE,USER        ; open user file 
  484.     CALL    F$OPEN        
  485.     JP    NZ,FOERR
  486.     LD    HL,(USREC)    ; current user record number
  487.     CALL    R$READ        ; read record
  488.     JP    NZ,RERR
  489.     LD    A,(FBYTE)    ; get registration bit 
  490.     SET    0,A        ; set
  491.     LD    (FBYTE),A    ;  and save
  492.     LD    HL,AVAIL    ; move to TBUFF for write
  493.     LD    DE,TBUFF
  494.     LD    BC,USRLEN
  495.     LDIR
  496.     LD    HL,(USREC)    ; current user record number
  497.     LD    DE,USER        ; point to FCB
  498.     CALL    R$WRITE        ; write buffer to file
  499.     JP    NZ,RERR
  500.     CALL    F$CLOSE        ; close file
  501.     JP    NZ,FCERR
  502.  
  503. EXIT:    LD    A,(OLDDRV)    ; load into system drive
  504.     LD    E,A
  505.     LD    C,LOGDRV
  506.     CALL    SPBDOS
  507.     LD    A,(OLDUSR)    ; load into system user area
  508.     LD    E,A
  509.     LD    C,LOGUSR
  510.     CALL    SPBDOS
  511. EXIT1:    LD    SP,(CCPSTK)
  512.     JP    0
  513.  
  514. GETINP:    CALL    PRINT
  515.     DB    CR,LF,'You MUST supply ALL of the information requested',0 
  516.     RET
  517.  
  518. ; Subroutines
  519.  
  520. DSPLY:    PUSH    DE
  521.     LD    A,(HL)        ; get length of input
  522.     PUSH    AF        ; save input length on stack
  523.     LD    B,A        ; place in B
  524.     INC    HL        ; point to message
  525.     CALL    PRINTM        ; display request for input  
  526.      IF    CNFRM
  527.     CALL    PRLINE
  528.      ENDIF            ; CNFRM
  529.     POP    AF        ; restore input length from stack
  530.     LD    B,A        ; initialize INPUT routine for maximum input
  531.     LD    A,0        ; set INPUT to echo input to screen
  532.     LD    D,A        ; set INPUT to no-wrap
  533.     LD    C,20H        ; set INPUT to force upper case
  534.     CALL    INPUT        ; get user input
  535.     CP    0        ; get length of input
  536.     JR    NZ,INOK        ; if non-zero, there was input
  537.     CALL    GETINP        ; else - display error message
  538.     POP    BC        ; clear return address from stack
  539.     JP    GETIN        ; restart input
  540. INOK:    POP    DE           
  541.     LD    C,A        ; place length of input in BC
  542.     LD    B,0
  543.     LDIR            ; move input
  544.     CALL    PCRLF
  545.     RET
  546.  
  547. ; Move data to buffer and pad with ' '
  548.  
  549. MOVEBF:    LD    A,(HL)        ; get first byte
  550.     CP    0        ; is it a 0
  551.     JR    NZ,FILLBF    ; if not - save it
  552.     LD    A,' '        ; if yes - replace with ' '
  553. FILLBF:    LD    (DE),A        ; place in buffer
  554.     INC    HL        ; advance pointers
  555.     INC    DE
  556.     DJNZ    MOVEBF        ; continue until done
  557.     RET
  558.  
  559. ; Display line at the length of user input
  560.  
  561. PRLINE:    PUSH    HL
  562.     PUSH    DE
  563.     PUSH    BC
  564.     LD    A,'_'
  565.     CALL    LNE
  566.     POP    BC
  567.     PUSH    BC
  568.     LD    A,BS
  569.     CALL    LNE
  570.     POP    BC
  571.     POP    DE 
  572.     POP    HL
  573.     RET
  574.  
  575. LNE:    CALL    ECHO
  576.     DJNZ    LNE        
  577.     RET
  578.  
  579. ; Check input buffer for supplied data
  580.  
  581. SDMA:    LD    C,SETDMA
  582.     LD    DE,TBUFF
  583.     CALL    BDOS
  584.     RET
  585.  
  586. ; File error routines
  587.  
  588. FCERR:    INC    DE
  589.     CALL     PFN2
  590.     CALL    PRINT
  591.     DB    ' -> Error in Closing File',bell,0
  592.     JP    EXIT
  593.  
  594. FWERR:    INC    DE
  595.     CALL    PFN2
  596.     CP    1
  597.     JR    NZ,FW2
  598.     CALL    PRINT
  599.     DB    ' -> Error in Extending File',bell,0
  600.     JP    EXIT
  601. FW2:    CP    2
  602.     JR    NZ,FW3
  603.     CALL    PRINT
  604.     DB    ' -> End of Disk Data',bell,0
  605.     JP    EXIT
  606. FW3:    CP     0FFH
  607.     JR    NZ,FWU
  608.     CALL    PRINT
  609.     DB    ' -> No More Directory Space',bell,0
  610.     JP    EXIT
  611. FWU:    CALL    PRINT
  612.     DB     ' -> Unknown File Error',bell,0
  613.     JP    EXIT
  614.  
  615. FOERR:    INC    DE
  616.     CALL    PFN2
  617.     CALL    PRINT
  618.     DB    ' -> File Not Opened',bell,0
  619.     JP    EXIT
  620.  
  621. RERR:    INC    DE
  622.     CALL    PFN2
  623.     CP    1
  624.     JR    NZ,RR3
  625.     CALL    PRINT
  626.     DB    ' -> Attempt to Read Unwritten Record',bell,0
  627.     JP    EXIT
  628. RR3:    CP    3
  629.     JR    NZ,RR4
  630.     CALL    PRINT
  631.     DB    ' -> Could Not Close Current Extent',bell,0
  632.     JP    EXIT
  633. RR4:    CP      4
  634.     JR    NZ,RR5
  635.     CALL    PRINT
  636.     DB    ' -> Attempt to Read Unwritten Extent',bell,0
  637.     JP    EXIT
  638. RR5:    CP    5
  639.     JR    NZ,RR6
  640.     CALL    PRINT
  641.     DB    ' -> Directory Full',bell,0
  642.     JP    EXIT
  643. RR6:    CP    6
  644.     JP    NZ,FWU
  645.     CALL    PRINT
  646.     DB    ' -> Attempt to Read Beyond End of Disk',bell,0
  647.     JP    EXIT
  648.  
  649. ; Data section
  650.  
  651. USER:    DB    0        ; 0=search on default drive
  652.     DB    'USERS   '    ; file name
  653.     DB    'PBS'        ; file type
  654.     DS    24
  655.  
  656. REGS:    DB    0        ; 0=search on default drive
  657.     DB    'REGISTER'    ; file name
  658.     DB    'LIB'        ; file type
  659.     DS    24
  660.  
  661. ENDOF:    DB    0DH,0AH,1AH    ; marker for end of file
  662. NOEND:    DB    20H,0DH,0AH    ; not end of file
  663. TNAME:    DS    30        ; temporary name storage
  664. TCITST:    DS    30        ; temporary city-state storage
  665. TTPHNE:    DS    12        ; temporary telephone storage
  666. OLDDRV:    DB    0        ; storage for original drive
  667. OLDUSR:    DB    0        ; storage for original user
  668. REC:    DW    0        ; registration record number
  669. CCPSTK:    DW    0        ; storage for original stack address
  670.     DS    64          
  671. STACK    EQU    $
  672.  
  673.     END
  674.