home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / BBSING / MBBS / MBMMII-1.ASM < prev    next >
Assembly Source File  |  2000-06-30  |  7KB  |  202 lines
  1. ;*****************************************************************
  2. ;
  3. ;            MBYE (Modular 'BYE')
  4. ;          D. C. Hayes MicroModem ][ modem I/O routines
  5. ;            v1.0 (02/07/84) by Kim Levitt
  6. ;
  7. ; These routines will allow the easy patching of MBYE for any type of
  8. ; modem/serial port combination.  Certain routines must return status
  9. ; flags, so please be careful to set the flags as directed.
  10. ;
  11. ; This version is for the Apple ][ running with a MicroModem ][ card.
  12. ; It seems to work on those Apples that even APBYE barfed on.  The prob-
  13. ; lem was in the Carrier Detect routine, because the Microsoft Z80 card
  14. ; screws up on a double strobe type of I/O that they tried to use.  Any-
  15. ; way, that means the Answer Phone routine is a crock,  but the thing
  16. ; works...
  17. ;
  18. ; For the Apple, you should set BYELOW to YES. (??)
  19. ;
  20. ;-----------------------------------------------------------------------
  21. ;
  22. ; 02/07/84  Altered and renamed to work with MBYE    - Kim Levitt
  23. ; 11/27/83  Altered and renamed to work with BYE3    - Irv Hoff
  24. ; 08/04/83  Updated for use with ByeII version 1.6    - Paul Traina
  25. ; 04/16/83  General code cleanup and optimization.    - Paul Traina
  26. ; 03/09/83  Fixed a missing '$+OFFSET' in MDANSW
  27. ;        routine, also improved the "flip" logic
  28. ;        needed for checking carrier and ring.    - Paul Traina
  29. ; 10/04/82  Routines added, no fuss, mess, or frills.    - Paul Traina
  30. ;
  31. ;-----------------------------------------------------------------------
  32. ;
  33. ; The following define the slot address to use.
  34. ;
  35. BASE:    EQU    0E0A6H        ;This is the status port location
  36. ;                ;for slot #2
  37. ;
  38. ;***********************************************************************
  39. ;
  40. ; MMII Modem address equates
  41. ;
  42. SPORT:    EQU    BASE        ;Control/status port
  43. DPORT:    EQU    BASE+1        ;Data port
  44. RPORT:    EQU    BASE-1        ;Baud rate/modem status port
  45. CPORT:    EQU    BASE-1        ;Modem control port
  46. ;
  47. ; Switch hook and modem commands, output to SPORT
  48. ;
  49. BYE:    EQU    0        ;on hook or dial-break
  50. ORIG:    EQU    8EH        ;off hook originate
  51. ANSW:    EQU    8AH        ;off hook answer
  52. TSB:    EQU    8        ;2 stop bits
  53. NORM:    EQU    15H        ;8 bits, no parity, 1 stop bit
  54. F110:    EQU    11H        ;same w/2 stop bits
  55. ;
  56. ; Modem status input
  57. ;
  58. RDET:    EQU    80H        ;ring detect
  59. CTS:    EQU    4        ;carrier detect
  60. TBMT:    EQU    2        ;xmit buffer empty
  61. DAV:    EQU    1        ;data available
  62. ; 
  63. ; Baud rate divisors
  64. ;
  65. B110:    EQU    0        ;110 bps
  66. B300:    EQU    1        ;300 bps
  67. ;
  68. ;
  69. ;***********************************************************************
  70. ;
  71. ; If any of your routines zaps anything other than the Accumulator, then
  72. ; you must preserve all other registers.
  73. ;
  74. ;***********************************************************************
  75. ;
  76. ; This routine should turn off everything on the modem, hang up the
  77. ; phone, and get it ready to wait for a ring.
  78. ;
  79. MDINIT:    XRA    A
  80.     STA    CPORT        ;Hang up phone
  81.     STA    SPORT        ;Turn of Xmit/Recv
  82.     RET
  83. ;
  84. ; The following is a routine to determine if there is a character wait-
  85. ; ing to be received.  If none are there, the Zero flag will be set,
  86. ; otherwise, 255 will be returned in register A.  Remember that the
  87. ; system will like you a little more if you also mask out framing,
  88. ; parity, and overrun errors.
  89. ;
  90. MDINST:    LDA    SPORT        ;Get modem status
  91.     ANI    DAV        ;Data available?
  92.     RZ            ;nope
  93.     ORI    0FFH        ;return true
  94.     RET
  95. ;
  96. ; The following is a routine to determine if the transmit buffer is
  97. ; empty.  If it is empty, it will return with the Zero flag clear.  If
  98. ; the transmitter is busy, then it will return with the Zero flag set.
  99. ;
  100. MDOUTST:LDA    SPORT        ;Get modem status
  101.     ANI    TBMT        ;mask out junk
  102.     RET
  103. ;
  104. ; The following is a routine that will check to make sure we still have
  105. ; carrier.  If there is no carrier it will return with the Zero flag set.
  106. ;
  107. MDCARCK:LDA    RPORT        ;The Z80 interface likes this dummy load...
  108.     LDA    SPORT        ;Get modem status
  109.     CMA            ;flip/flop the Zero flag
  110.     ANI    CTS        ;got a carrier?
  111.     RET
  112. ;
  113. ; The following routine will check to see if the phone is ringing, if it
  114. ; isn't, it will return with Zero set, otherwise Zero will be cleared.
  115. ;
  116. MDRING:    LDA    RPORT        ;get ring port status
  117.     CMA            ;flip/flop the proper bit
  118.     ANI    RDET        ;ringing?
  119.     RET
  120. ;
  121. ; The following is a routine that will input one character from the
  122. ; modem port.  If there is nothing there, it will return garbage... so
  123. ; use the MDINST routine first.
  124. ;
  125. MDINP:    LDA    DPORT        ;get character
  126.     ANI    7FH        ;strip parity and other garbage
  127.     RET
  128. ;
  129. ; The following is a routine that will output one character in register
  130. ; A to the modem.  REMEMBER, that is register A, not register C.
  131. ;
  132. ; **** Use MDOUTST first to see if buffer is empty ****
  133. ;
  134. MDOUTP:    STA    DPORT        ;send character
  135.     RET
  136. ;
  137. ; The following routine will make the modem answer the phone.  It should
  138. ; set baudrate to 300 baud.
  139. ;
  140. MDANSW:    MVI    A,ANSW        ;Answer phone
  141.     STA    CPORT
  142.     PUSH    D        ;save register pair DE
  143.     MVI    E,20        ;Wait for modem to turn on
  144. ;
  145. ALOP1:    CALL    DELAY
  146.     DCR    E
  147.     JNZ    ALOP1
  148.     POP    D        ;restore registers
  149.     CALL    SET300
  150.     PUSH    B        ;here is the crock I was telling you
  151.     MVI    B,30        ;  about,  I was beating my head for two
  152. ;
  153. ALOOP:    CALL    DELAY        ;  days trying to figure out why the
  154.     LDA    RPORT        ;  carrier detect routine was not work-
  155.     LDA    SPORT        ;  ing - it turns out this corck here
  156.     LDA    DPORT        ;  will get the modem to work properly.
  157.     LDA    DPORT
  158.     DCR    B
  159.     JNZ    ALOOP
  160.     POP    B
  161.     RET
  162. ;
  163. ; These next routines set the proper baud rates for the modem.  If you
  164. ; do not support the particular rate, then simply put in a JMP to SETINV.
  165. ; If the baud rate change was successful, make SURE the Zero flag is set.
  166. ;
  167. ; The following routine returns a 255 because we were not able to set to
  168. ; the proper baud rate because either the serial port or the modem can't
  169. ; handle it.
  170. ;
  171. SET110:                ;110 bps too slow to support
  172. SET450:                ;450 bps not supported
  173. SET600:                ;600 bps not supported
  174. SET710:                ;710 bps not supported
  175. SET1200                ;1200 bps not supported
  176. ;
  177. SETINV:    ORI    0FFH        ;make sure the Zero flag isn't set
  178.     RET
  179. ;
  180. ; Set speed to 110 baud.
  181. ;
  182. SET110:    MVI    A,B110+ANSW
  183.     STA    CPORT        ;Set 110 bps
  184.     MVI    A,F110
  185.     STA    SPORT        ;Set 8 bits, no parity, 2 stop bits
  186.     RET
  187. ;
  188. ; Set up for 300 bps
  189. ;
  190. SET300:    MVI    A,B300+ANSW
  191.     STA    CPORT        ;Set 300 bps
  192.     MVI    A,NORM
  193.     STA    SPORT        ;Set 8 bits, no parity, 1 stop bit
  194.     RET
  195. ;
  196. ; Ok, that's all of the modem dependent routines that MBYE uses, so if
  197. ; you patch this file into your copy of MBYE, then it should work out
  198. ; well.
  199. ;
  200. ;**********************************************************************
  201. ;
  202.