home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / CPM / 6502 / 6502SIM.LBR / ZX65SIM.MQC / ZX65SIM.MAC
Text File  |  2000-06-30  |  36KB  |  1,570 lines
  1. ; ZX65: SIMULATING A MICRO    1/80    R M KRUSE
  2. ; FOR Z80-BASED SYSTEMS USING THE CP/M DOS
  3. ;
  4. ;
  5. ;
  6. ; THIS FILE IS AN ENHANCED VERSION OF ZX65, BY R.M.KRUSE.
  7. ; THE FOLLOWING CHANGES HAVE BEEN MADE TO THE ORIGINAL:
  8. ;
  9. ;
  10. ; REVISION 1.0:    10/22/82 (RGF)
  11. ; THIS REVISION OF ZX65 ALLOWS ASSEMBLY UNDER THE M80
  12. ; (MICROSOFT RELOCATING ASSEMBLER) 
  13. ;
  14. ; SIMULATOR MODIFIED TO NOT NEED RELOCATION, BY REMAPPING 6502
  15. ; MEMORY REFERENCES THROUGH A COMPANION MODULE (ZX65HOST.MAC)
  16. ; INTO Z80 MEMORY. THE TWO MODULES MUST BE LINKED TOGETHER
  17. ; USING L80. 
  18. ;
  19. ; BUG FIXED 11/05/82 (RGF): FIXED PROBLEM WITH STORES
  20. ;   IN MULTI-MODE INSTRUCTIONS WHERE DESTINATION=ACC
  21. ;   (EG, LSR A)
  22. ;
  23. ; 11/22/82 (RGF) : ADDED IFETCH CALL TO MAPPER MODULE
  24. ;           TO ALLOW INSTRUCTION FETCH SETUP.  ALTHOUGH
  25. ;           NOT CURRENTLY USED, THIS WILL ALLOW SETUP OF
  26. ;           INSTRUCTION FETCH CYCLES IN COMPANION 6502 IN-
  27. ;           CIRCUIT HARDWARE EMULATION THAT MAY SOMEDAY
  28. ;           BE DESIGNED. (ANY TAKERS???)
  29.  
  30. ;
  31. ;           ADDED HISTOGRAM FEATURE, # OF STEPS
  32. ;           SET BY VARIABLE 'HSIZE', WHICH IS
  33. ;           THE # OF PREVIOUS PC'S TO REMEMBER
  34. ;           THIS FEATURE AVAILABLE THROUGH THE "H"
  35. ;           COMMAND.
  36. ;
  37. ;
  38. ;           REMOVED SELF-CONTAINED DOS, WHICH IS
  39. ;           NOT NEEDED WITH THE MEMORY REMAPPING 
  40. ;           FEATURE
  41. ;
  42. ; ZX65SIM IS BASED ON ZX65, A PROGRAM WRITTEN BY R.M. KRUSE.
  43. ; 90% OF THE CODE BELONGS TO MR. KRUSE.     FOR MORE INFORMATION,
  44. ; SEE THE ACCOMPANYING DOCUMENTATION FILES.
  45. ;            RON FOWLER
  46. ;            12/17/82
  47. ;
  48. ;
  49.     .Z80
  50. ;
  51. ;
  52. HSIZE    EQU    40        ;SIZE OF HISTOGRAM BUFFER (IN WORDS)
  53. ;
  54.     EXTRN    FETCHA,SENDA    ;EXTRNAL ROUTINES TO FETCH
  55.                 ;AND SEND BYTE TO 6502
  56.                 ;MEMORY (ADRS IN HL)
  57.     EXTRN    AINIT        ;EXTERNAL INITIALIZATION
  58.     EXTRN    IFETCH        ;INSTRUCTION FETCH SETUP
  59. ;
  60. ; ZX65 BEGINS...
  61. ;
  62.     LD    SP,SYSTK
  63.     CALL    AINIT        ;INITIALIZE ATARI
  64.     LD    HL,(1)        ;GET BIOS BASE
  65.     LD    L,0
  66.     LD    DE,VECTBL    ;MOVE TABLE TO LOCAL AREA
  67.     LD    BC,15*3        ;MOVE FIRST 15 VECTORS
  68.     LDIR
  69.     LD      IY,INTRO
  70.     CALL    PRTXT        ; PRINT HEADER
  71.     CALL    CRLF
  72. ;
  73. ; COMMAND LEVEL...RETURN HERE FROM ANY POINT IN PGM
  74. ;
  75. CMND::    LD      HL,CMND
  76.     PUSH    HL        ; RET ADDR ON STACK
  77.     CALL    CRLF
  78.     CALL    PROM
  79.     CALL    GETCHR        ; GET COMMAND
  80.     CP    'H'        ; PRINT HISTOGRAM
  81.     JP    Z,PRTHIS
  82.     CP    'E'
  83.     JP    Z,EXAM        ; EXAM MEMORY
  84.     CP    'M'
  85.     JP    Z,SUBM        ; SUB MEMORY
  86.     LD    IX,VREG        ; FOR SIMX
  87.     CP      'B'
  88.     JR      Z,BRKP        ; RUN TO BREAKPOINT
  89.     CP    'C'
  90.     JP    Z,RGSTR        ; DSPLY/MODIFY CPU REGS
  91.     CP      'G'
  92.     JP    Z,RUN        ; RUN FROM NPC
  93.     CP    'T'
  94.     JR    Z,MULTX    ; TRACE/DISPLAY N STEPS
  95.     CP      ' '
  96.     JR      Z,EXONE    ; EX ONE INSTR & STOP
  97.     LD    C,'?'
  98.     CALL    PRNC        ; INVALID COMMAND
  99.     JR    CMND
  100. ;
  101. ; EXECUTE N STEPS
  102. ;
  103. MULTX::    LD    IY,MLTMSG
  104.     CALL    PRTXT
  105.     CALL    GETWRD        ; GET N
  106.     LD    A,E
  107.     JR      NZ,DOMULT
  108. EXONE::    LD      A,1        ; EXECUTE 1 STEP
  109. ;
  110. ; EXECUTE # STEPS IN A
  111. ;
  112. DOMULT::LD      (NSTEPS),A      ; STORE N IN TEMP
  113.     CALL    STEP        ; EXEC & DSPLY INSTR
  114.     CALL    DSPLY
  115.     LD      A,(NSTEPS)
  116.     DEC     A
  117.     RET    Z
  118.     PUSH    AF
  119.     LD    BC,DLYCON    ; DELAY FOR VIEWING
  120. DOLP::    DEC    BC
  121.     LD    A,B
  122.     OR    C
  123.     JR    NZ,DOLP
  124.     POP    AF
  125.     JR    DOMULT
  126. ;
  127. ; RUN WITHOUT DISPLAY TO BREAKPOINT
  128. ;
  129. BRKP::    LD    IY,BKPMSG
  130.     CALL    PRTXT
  131.     CALL    GETWRD         ; GET IT
  132.     LD      (BREAK),DE      ; STORE IT IN TEMP
  133. BKLP::    CALL    STEP        ; EXEC ONE INSTR
  134.     LD      DE,(BREAK)
  135.     LD      A,H        ; CHECK IF AT BKPT
  136.     CP      D
  137.     JR      NZ,INTST
  138.     LD      A,L
  139.     CP      E
  140.     JR    NZ,INTST
  141.     CALL    STEP        ; DO ONE MORE
  142.     JR    DSPLY
  143. INTST::    CALL    KBST        ; TEST FOR KBD INP
  144.     JR    Z,BKLP    ; CONTINUE IF NONE
  145.     JR    QDSP
  146. ;
  147. ; RUN ONLY..NO DISPLAY OR BREAKPOINT
  148. ;
  149. RUN::    CALL    STEP        ; DO A STEP
  150.     CALL    KBST        ; CHECK FOR KB INPUT
  151.     JR    Z,RUN        ; IF NONE JUST REPEAT
  152. ;
  153. ; STOP, DISPLAY, & RET TO CMND
  154. ;
  155. QDSP::    CALL    KBIN        ; CLEAR UART
  156.     JR    DSPLY        ; DISP CPU & RET
  157. ; 
  158. ; DISPLAY & UPDATE CPU REGISTERS
  159. ;
  160. RGSTR::    PUSH    IX
  161.     CALL    CRLF
  162.     LD      IY,HEADR+42
  163.     CALL    PRN6         ; PRINT RG NAME
  164.     LD      DE,(NPC)     ; NEXT PC TO DE
  165.     CALL    PRTWRD        ; PRINT IT
  166.     CALL    PROM         ; PROMPT FOR CHANGE
  167.     CALL    GETWRD
  168.     JR      Z,AREG     ; SPACE = NO CHANGE
  169.     LD    (NPC),DE    ; PUT IN NEW VALUE
  170. AREG::    LD      IY,HEADR+12
  171.     LD      B,5
  172. NREG::    CALL    CRLF         ; DO REST OF REGS
  173.     CALL    PRN6         ; PRINT NAME
  174.     LD      E,(IX+0)
  175.     CALL    PRTBYT        ; PRINT CONTENTS
  176.     CALL    PROM        ; PROMPT FOR CHANGE
  177.     CALL    GETWRD
  178.     JR      Z,NXTREG      ; SPACE = NO CHANGE
  179.     LD      (IX+0),E
  180. NXTREG::INC     IX        ; POINT TO NEXT REG
  181.     DJNZ    NREG         ; DO AGAIN IF MORE
  182.     POP     IX
  183.     RET
  184. ;
  185. ; DISPLAY PC, INSTRUCTION, AND ALL REGISTERS
  186. ;
  187. DSPLY::    PUSH    IX        ; SAVE POINTER
  188.     PUSH    BC        ; SAVE MNEMONIC CODE
  189.     CALL    CRLF
  190.     LD    IY,HEADR
  191.     CALL    PRN6        ; 'CPC'
  192.     LD    DE,(CPC)
  193.     CALL    PRTWRD        ; VALUE
  194.     CALL    PRN6        ; 'INS'
  195.     POP    BC
  196.     PUSH    IY
  197.     PUSH    BC
  198.     LD    IY,MNMTBL    ; DET MNEM FROM BC
  199.     LD    A,0FCH
  200.     AND    C
  201.     SRL    A
  202.     LD    E,A
  203.     LD    D,0
  204.     ADD    IY,DE
  205.     LD    E,(IY+0)    ; GET PACKED MNEM
  206.     LD    D,(IY+1)
  207.     SLA    E        ; UNPACK IT
  208.     RL    D
  209.     LD    C,3        ; & PRINT THREE CHRS
  210. MNM2::    XOR    A
  211.     LD    B,5
  212. MNM1::    SLA    E
  213.     RL    D
  214.     RLA
  215.     DJNZ    MNM1
  216.     SET    6,A
  217.     PUSH    BC
  218.     CALL    PRNA
  219.     POP    BC
  220.     DEC    C
  221.     JR    NZ,MNM2
  222.     POP    BC        ; DECODE ADDR MODE
  223.     LD    A,B
  224.     SLA    A
  225.     SLA    A
  226.     SLA    A
  227.     LD    E,A
  228.     LD    D,0
  229.     LD    IY,AMDTBL
  230.     ADD    IY,DE
  231.     CALL    PRN8        ; PRINT ADDR MODE
  232.     POP    IY
  233.     LD    B,5
  234. DSP1::    CALL    PRN6        ; PRINT ALL REGS
  235.     LD    E,(IX+0)
  236.     CALL    PRTBYT
  237.     INC    IX
  238.     DJNZ    DSP1
  239.     CALL    PRN6        ; PRINT NEXT PC
  240.     LD    DE,(NPC)
  241.     CALL    PRTWRD
  242.     POP    IX
  243.     RET
  244. ;
  245. PRN6::    LD    E,6        ; PRINT 6 CHARS PER IY
  246.     JP    PRNLP
  247. PRN8::    LD      E,8        ; PRINT 8 CHRS PER IY
  248.     JP      PRNLP
  249. ;
  250. ; QUEUE PC (IN HL)
  251. ;
  252. QUEPC::    PUSH    HL            ; SAVE PC
  253.     LD    HL,HSBUFR+(HSIZE*2)-3    ; GET END OF BUFR-2
  254.     LD    DE,HSBUFR+(HSIZE*2)-1    ; GET END OF BUFFER
  255.     LD    BC,HSIZE*2-2        ; MOVE BUFR-2 WORDS
  256.     LDDR                ; CLEAR BOTTOM OF BUFFER
  257.     POP    DE            ; RESTORE PC TO QUEUE
  258.     LD    HL,HSBUFR        ; QUEUE IT AT START OF BUFR
  259.     LD    (HL),E              ; PUT IT IN THE QUEUE
  260.     INC    HL
  261.     LD    (HL),D        
  262.     EX    DE,HL            ; GET PC BACK TO HL
  263.     RET
  264. ;
  265. ; PRINT QUEUE
  266. ;
  267. PRTHIS::CALL    CRLF            ; TURN UP NEW LINE
  268.     LD    HL,HSBUFR        ; GET POINTER TO HISTO BUFR
  269.     LD    BC,HSIZE        ; GET COUNTER
  270. PHLP:    LD    A,B            ; DONE PRINTING? (BC=0?)
  271.     OR    C
  272.     JR    Z,PHDONE        ; JUMP IF SO
  273.     LD    E,(HL)            ; ELSE FETCH ANOTHER PC
  274.     INC    HL
  275.     LD    D,(HL)
  276.     INC    HL
  277.     PUSH    HL            ; SAVE BUFR PNTR
  278.     PUSH    BC            ; AND COUNT
  279.     CALL    PRTWRD            ; PRINT IT
  280.     LD    A,' '            ; SPACE BETWEEN WORDS
  281.     CALL    PRNA
  282.     POP    BC            ; GET COUNTER
  283.     PUSH    BC
  284.     LD    A,C            ; GET COUNT MOD 8
  285.     AND    7
  286.     CALL    Z,CRLF            ; CRLF EVERY 8 PC'S
  287.     POP    BC            ; GET COUNTER BACK
  288.     POP    HL
  289.     DEC    BC            ; COUNT DOWN
  290.     JR    PHLP
  291. PHDONE:    CALL    CRLF
  292.     RET
  293.  
  294. ;
  295. ; CODE FOR DECODING AND EXECUTING ONE INSTRUCTION
  296. ; ENTER WITH HL POINTING TO INSTR TO BE DECODED. EXITS
  297. ; WITH HL POINTING TO NEXT INSTR, B HOLDING ADDRESSING
  298. ; MODE CODE, C HOLDING MNEMONIC CODE
  299. ;
  300. STEP::    CALL    IFETCH        ; ALERT INSTR FETCH COMING
  301.     LD      HL,(NPC)     ; NEXT PC TO HL
  302.     CALL    QUEPC        ; GO PLACE IN QUEUE
  303.     LD      (CPC),HL     ; BECOMES CURRENT PC
  304.     CALL    FETCHA        ; GET OP CODE
  305.     LD      B,A        ; SAVE IT
  306.     OR      A         ; ZERO?
  307.     JP      Z,PBRK         ; IF SO, 'BRK'
  308.     BIT     0,A        ; TEST LSD FOR ODD/EVEN
  309.     JP      NZ,MLTMOD    ; ODD INSTRS MULTI MODE
  310.     AND     0FH
  311.     JR      NZ,FLGTST
  312.     LD      A,B         ; RESTORE OP CODE
  313.     BIT     4,A        ; MSD ODD/EVEN
  314.     JP      NZ,PBRNCH    ; IF ODD, BRANCH
  315.     CP      20H
  316.     JP      Z,PJSR        ; PROCESS JSR
  317.     CP      40H
  318.     JP      Z,PRTI        ; PROCESS RTI
  319.     CP      60H
  320.     JP      Z,PRTS        ; PROCESS RTS
  321.     JP      MLTMOD        ; ELSE MULTI MODE
  322. FLGTST::CP      8
  323.     JR      NZ,IMP2
  324.     LD      A,B        ; RESTORE
  325.     BIT     4,A        ; MSD ODD/EVEN
  326.     JP      Z,PIMPL        ; IF EVEN, MST BE IMPLD
  327.     CP      98H        ; MSD = 9?
  328.     JP      Z,PTYA        ; YES, PROC TYA SPECIAL
  329.     JP      PFLGS        ; ELSE PROCESS FLAG OPS
  330. IMP2::    CP      0AH
  331.     JR      NZ,JMPTST     ; MUST BE JUMP    
  332.     LD      A,B        ; RESTORE
  333.     AND     0F0H        ; TESTS ON MSD
  334.     BIT     4,A        ; ODD/EVEN
  335.     JP      NZ,PTSS        ; PROSESS SP OPS SPECIAL
  336.     CP      70H
  337.     JP      C,MLTMOD     ; PROCESS ACCUM MODES
  338.     JP      PIMPL       ; ELSE MORE IMPLIEDS
  339. JMPTST::LD      A,B        ; RESTORE OP CODE
  340.     CP      4CH
  341.         JP      Z,PJABS        ; PROCESS ABS JMP
  342.     CP      6CH
  343.         JP      Z,PJIND        ; PROCESS INDIRECT JMP
  344.     JP      MLTMOD
  345. ;
  346. ; INSTURCTION PROCESSORS BEGIN HERE.. ENTER WITH
  347. ; HL = PC, IX POINTING TO SIM CPU
  348. ;
  349. ; IF BRK VECTOR (IPOINT) = 0, RETURN TO CMND
  350. ;
  351. PBRK::    SET     4,(IX+1)    ; SET BRK STATUS BIT
  352.     LD    HL,(IPOINT)    ; SEE IF RET TO CMND
  353.     LD    A,H
  354.     OR    L
  355.     JR    NZ,BRK1
  356.     POP    BC        ; ADJUST SP
  357.     LD    BC,429H        ; RET TO CMND
  358.     JP    DSPLY
  359. BRK1::    INC    HL        ; NORMAL BREAK
  360.         CALL    TSPD          ; SP TO IY
  361.     LD    A,D        ; 'PUSH' PC
  362.     CALL    SENDA
  363.     DEC    HL
  364.     LD    A,E
  365.     CALL    SENDA
  366.     DEC    HL
  367.     LD    A,(IX+1)    ; 'PUSH' P
  368.     CALL    SENDA
  369.     DEC    HL
  370.     CALL    TDSP        ; DE TO SP
  371.     LD      HL,(IPOINT)    ; GET INTERRUPT VECTOR
  372.         LD      BC,429H        ; CODE FOR # BYTES & MNEM
  373.     JP      END1          ; AND FINISH
  374. ;
  375. ; PROCESS BRANCHES
  376. ;
  377. PBRNCH::LD      B,0            ; FORM INDEX INTO MSKTBL
  378.     CALL    FETCHA
  379.     LD      C,A        ; INSTR TO C
  380.     LD    IY,MSKTBL
  381.         SRL     C        ; GET MSD
  382.     SRL     C
  383.         SRL     C
  384.     SRL     C
  385.         DEC     C
  386.     ADD     IY,BC
  387.         INC     HL             ; POINT TO OFFSET
  388.     BIT     1,C        ; MSD ODD/EVEN
  389.     LD    A,(IX+1)    ; P REG TO ACC
  390.         LD      C,(IY+0)    ; # CODE
  391.     LD      B,(IY+1)    ; FLAG MASK
  392.         JR      NZ,BRSET    ; ODD/EVEN DET SET/CLR
  393.     AND     B             ; ISOLATE BIT FOR TEST
  394.         JR      Z,TRUE
  395.     JR      FALSE
  396. BRSET::    AND     B
  397.     JR      NZ,TRUE
  398.         JR      FALSE
  399. TRUE::    LD      D,0           ; CONDITION MET; BRANCH
  400.     CALL    FETCHA
  401.     LD      E,A        ; OFFSET TO E
  402.         BIT    7,E            ; CHECK SIGN OF OFFSET
  403.     JR      Z,TRU1
  404.         DEC     D              ; IF B7 IS SET, DO NEG
  405. TRU1::    ADD     HL,DE         ; ADD OFFSET FOR NEW PC
  406. FALSE::    LD      B,0        ; COND NOT MET; GO ON
  407.     JP      END
  408. ;
  409. ; PROCESS JUMPS AND JSR...JMP 0-4 AND JSR 0-4 GO INTO Z80
  410. ; ROUTINES PER JUMP TABLE AT USR0. CONTROL THEN RETURNS
  411. ; TO SIMULATOR UPON Z80 'RET' (C9).. ALL OTHERS PROCESSED
  412. ; NORMALLY.
  413. ;
  414. PJSR::    INC    HL        ; PROCESS JSR
  415.     CALL    SPCTST        ; TEST FOR SPECIALS
  416.     JR    NZ,PJS2
  417.     CALL    INUSR        ; GO TO USER ROUTINES
  418.     JR    PJS3
  419. PJS2::    PUSH    DE        ; SAVE NEW PC
  420.     CALL    TSPD        ; NORMAL JSR
  421.     LD    A,D        ; PUSH CURRENT PC
  422.     CALL    SENDA
  423.     DEC    HL
  424.     LD    A,E
  425.     CALL    SENDA
  426.     DEC    HL
  427.     CALL    TDSP
  428.     POP    DE        ; RESTORE NEW PC
  429.         EX      DE,HL         ; NEW PC
  430. PJS3::    LD      BC,273H
  431.         JP      END1
  432. PJABS::    INC    HL        ; ABS JUMP
  433.     LD      BC,26FH
  434.         JR      DOJP
  435. PJIND::    INC     HL            ; INDIRECT JUMP
  436.     CALL    FETCHA
  437.     LD    E,A
  438.         INC     HL
  439.     CALL    FETCHA
  440.     LD    D,A
  441.         EX      DE,HL         ; ADDR OF POINTER TO HL
  442.     LD      BC,0C6FH
  443. DOJP::    CALL    SPCTST        ; TEST FOR SPECIALS
  444.     JR    NZ,DOJ1
  445.     PUSH    BC
  446.     CALL    INUSR        ; FOR SPECIALS
  447.     CALL    PRET        ; DO SR RETURN
  448.     POP    BC
  449.     EX    DE,HL
  450. DOJ1::    EX    DE,HL        ; NEW PC
  451.         JP      END1
  452. ;
  453. ; TEST FOR USER SUBROUTINE CALLS/JUMPS. IF TARGET
  454. ; ADDRESS < 0005 THEN RET WITH Z FLG SET, ELSE CLR
  455. ;
  456. SPCTST::CALL    FETCHA        ;TEST FOR USER SPECIALS
  457.     LD    E,A
  458.     INC    HL
  459.     CALL    FETCHA        ;TARGET TO DE
  460.     LD    D,A
  461.     INC    HL        ; NXT INSTR
  462.     LD    A,0        ; TARGET < 0005?
  463.     OR    D
  464.     RET    NZ
  465.     LD    A,4
  466.     CP    E
  467.     RET    C
  468.     XOR    A        ; SET Z FLAG
  469.     RET
  470. ;
  471. ; INDEX INTO USER SUBROUTINE TABLE
  472. ; PASS A, X, & Y TO/FROM USER ROUTINE AS A, B, & C.
  473. ;
  474. INUSR::    PUSH    BC        ; SAVE CODES
  475.     LD    D,0
  476.     LD    A,E
  477.     ADD    A,E
  478.     ADD    A,E
  479.     LD    E,A
  480.     LD    IY,USR0
  481.     LD    BC,USRET    ; RETURN ON STACK
  482.     PUSH    BC
  483.     ADD    IY,DE
  484.     LD    A,(IX+0)    ; PASS A,X, & Y
  485.     LD    B,(IX+2)
  486.     LD    C,(IX+3)
  487.     JP    (IY)        ; AND GO
  488. USRET::    LD    (IX+0),A    ; RETURN HERE
  489.     LD    (IX+2),B    ; RETURN PARAMETERS
  490.     LD    (IX+3),C
  491.     POP    BC
  492.     RET
  493. ;
  494. ; PROCESS SR AND INTERRUPT RETURNS
  495. ;
  496. PRTI::    CALL    TSPD        ; RTI
  497.     INC    HL        ; GET TOS (FLAGS)
  498.     CALL    FETCHA
  499.     LD    (IX+1),A    ; RESTORE
  500.     CALL    PRET1
  501.     LD    BC,04A5H
  502.     JP    END1
  503. PRTS::    CALL    PRET        ; RTS...RESTORE PC
  504.     LD    BC,4A9H
  505.     JP    END1
  506. PRET::    CALL    TSPD
  507. PRET1::    INC    HL        ; POINT TO LAST ENTRY
  508.     CALL    FETCHA        ; RESTORE PC LO
  509.     LD    E,A
  510.     INC    HL        ; RESTORE PC HI
  511.     CALL    FETCHA
  512.     LD    D,A
  513.     JP    TDSP        ; GO RESTORE
  514. ;
  515. ; PROCESS SP EXCHANGES
  516. ;
  517. PTSS::    CP      90H           ; WHICH ONE IS IT?
  518.     JR      NZ,PTSX
  519. PTXS::    LD      A,(IX+2)    ; MOVE DATA FROM X...
  520.     LD      (IX+4),A    ; TO SP
  521.         LD      BC,4D9H
  522.     JP      END
  523. PTSX::    LD      A,(IX+4)    ; MOVE SP
  524.     LD      (IX+2),A    ; TO X REG
  525.         LD      C,0D1H
  526.     JP    COMPL        ; AND MODIFY FLAGS
  527. ;
  528. ; PROCESS ALL REMAINING IMPLIED INSTRUCTIONS
  529. ;
  530. PIMPL::    LD    C,A        ; OP CODE
  531.     SRL     C             ; GET MSD
  532.         SRL     C
  533.     SRL     C
  534.         SRL     C
  535.     AND    0FH        ; CHECK LSD
  536.     CP    8
  537.         LD      IY,IMPTBL    ; INDEX INTO TABLE
  538.     JP    Z,JPIB
  539.     LD      IY,IMPTBL+8
  540.     JP    JPIB
  541. ;
  542. ; IMPLIED INSTR PROCESSORS
  543. ;
  544. PINX::    INC     (IX+2)        ; INX
  545.     LD      C,65H
  546.         JR      IDEFLG
  547. PINY::    INC     (IX+3)        ; INY
  548.     LD      C,69H
  549.         JR      IDEFLG
  550. PDEX::    DEC     (IX+2)        ; DEX
  551.     LD      C,55H
  552.         JR      IDEFLG
  553. PDEY::    DEC     (IX+3)        ; DEY
  554.     LD      C,59H
  555. IDEFLG::RES    1,(IX+1)    ; SET/RES Z FLG
  556.     JR      NZ,SINTST    ; PER Z80 FLAGS
  557.         SET     1,(IX+1)
  558. SINTST::RES    7,(IX+1)    ; ALSO SIGN FLG
  559.         JP      P,ENDIT
  560.     SET     7,(IX+1)
  561.         JP      ENDIT
  562. PNOP::    LD    BC,485H        ; NOP
  563.     JP    END
  564. PPHA::    CALL    TSPD          ; PHA
  565.     LD      A,(IX+0)    ; ACCUM
  566.         LD      C,8DH
  567.     JR      DOPUSH    ; PUSH IT
  568. PPHP::    CALL    TSPD        ; PHP
  569.     LD      A,(IX+1)    ; P REG
  570.         LD      C,91H
  571. DOPUSH::PUSH    BC
  572.     CALL    SENDA        ; PLACE ON STACK
  573.     DEC     HL            ; BUMP SP DOWN
  574.         CALL    TDSP          ; & REPLACE IT
  575.     POP    BC
  576.         JP      ENDIT
  577. PPLA::    CALL    DOPULL        ; PLA
  578.     LD      (IX+0),A    ; DATA TO ACC
  579.     CALL    SINS1         ; SET/RES S,Z FLGS
  580.     CALL    TDSP        ; RESTORE SP
  581.         LD      BC,495H
  582.     JP      END
  583. PPLP::    CALL    DOPULL        ; PLP
  584.     LD      (IX+1),A    ; DATA TO P REG
  585.         CALL    TDSP          ; RESTORE SP
  586.     LD      BC,499H
  587.         JP      END
  588. DOPULL::CALL    TSPD        ; GET SP
  589.     INC     HL            ; BUMP SP
  590.     CALL    FETCHA        ; GET DATA
  591.     RET
  592. ;
  593. ; PROCESS ACC/INDEX TRANSFERS
  594. ;
  595. PTAX::    LD      A,(IX+0)    ; TAX
  596.     LD      (IX+2),A
  597.         LD      C,0C9H
  598.     JR      COMPL
  599. PTAY::    LD      A,(IX+0)    ; TAY
  600.     LD      (IX+3),A
  601.         LD      C,0CDH
  602.     JR      COMPL
  603. PTXA::    LD      A,(IX+2)    ; TXA
  604.     LD      (IX+0),A
  605.         LD      C,0D5H
  606.     JR    COMPL
  607. PTYA::    LD      A,(IX+3)    ; TYA
  608.     LD      (IX+0),A
  609.         LD      C,0DDH
  610. COMPL::    CALL    SINS1        ; SET/RES S,Z FLGS
  611.     JR    ENDIT
  612. ;
  613. ; PROCESS FLAG SET/RES INSTRUCTIONS
  614. ;
  615. PFLGS::    LD    IY,FLGTBL    ; TABLE START
  616.     LD    B,0
  617.     CP    0B8H        ; CLV SPECIAL
  618.     JR    NZ,PFL1
  619.     RES    5,A
  620. PFL1::    RRA            ; CHECK MSD
  621.     RRA
  622.     RRA
  623.     RRA
  624.     AND    0EH        ; MASK MSD + 1
  625.     BIT    1,A        ; TEST FOR SET/RES
  626.     LD    C,A        ; FORM TABLE INDEX
  627.     ADD    IY,BC
  628.     LD    C,(IY+0)    ; GET MNEM CODE
  629.     LD    A,(IY+1)    ; GET MASK
  630.     JR    NZ,PFL2
  631.     CPL            ; DO CLEARS
  632.     AND    (IX+1)
  633.     JR    PFL3
  634. PFL2::    OR    (IX+1)        ; DO SETS
  635. PFL3::    LD    (IX+1),A    ; AND STUFF IT
  636. ENDIT::    LD    B,4
  637.     JP    END
  638. ;
  639. ; PROCESS ALL INSTRUCTIONS HAVING MULTIPLE ADDRESSING
  640. ;
  641. MLTMOD::LD      BC,MLTEND    ; PUT RETURN ON STACK
  642.     PUSH    BC
  643.         CALL    FETCHA        ; GET INSTR TO A
  644.     LD      C,A           ; AND TO C
  645.         SRL     C             ; TEST EVEN/ODD
  646.     PUSH    AF
  647.         SRL     C             ; ROTATE MSD INTO LSD
  648.     SRL     C
  649.         SRL     C
  650.     RES     0,C           ; MASK LSB
  651.     POP    AF
  652.         LD      IY,EVNTBL    ; JUMP PER TABLES
  653.     JP    NC,JPIB
  654.     LD    IY,ODDTBL
  655.     JP    JPIB
  656. ;
  657. ; MULTI-MODE INSTRUCTION PROCESSORS
  658. ;
  659. PASL::    CALL    MODBBB        ; GET MODE,ADDR,&DATA
  660.     SLA     A             ; ASL
  661.         CALL    SINSET        ; SET/RES S,Z,C FLGS
  662.     CALL    PUTDAT        ; RESTORE DATA
  663.         LD      A,8
  664.     RET
  665. PBTRL::    BIT     1,A           ; BIT OR ROL?
  666.     JR      Z,PBIT
  667.         CALL    MODBBB        ; ROL
  668.     CALL    CARSET        ; SET UP C FLAG
  669. PROL1::    RLA                   ; DO ROTATE
  670.     CALL    SINSET
  671.         CALL    PUTDAT
  672.     LD      A,9CH
  673.         RET
  674. PBIT::    RES     6,(IX+1)    ; BIT
  675.     CALL    MODBBX
  676.         PUSH    BC
  677.     LD      B,A           ; SAVE IT IN B
  678.         LD      A,(IX+0)    ; GET SIM ACC
  679.     AND     B             ; AND IT
  680.         BIT     6,A           ; CHECK V BIT
  681.     JR      Z,PBIT1
  682.         SET     6,(IX+1)    ; SET V BIT IF REQD
  683. PBIT1::    CALL    SINS1         ; SET/RES S,Z FLGS
  684.     POP     BC
  685.         LD      A,18H
  686.     RET
  687. PLSR::    CALL    MODBBB        ; LSR
  688.     SRL     A
  689.         CALL    SINSET
  690.     CALL    PUTDAT
  691.         LD      A,80H
  692.     RET
  693. PROR::    CALL    MODBBB        ; ROR
  694.     CALL    CARSET        ; SET UP C FLG
  695. PROR1::    RRA                   ; DO ROTATE
  696.     CALL    SINSET
  697.         CALL    PUTDAT
  698.     LD      A,0A0H
  699.         RET
  700. PSTXY::    BIT     1,A           ; WHICH ONE?
  701.     JR      Z,PSY
  702.         CALL    MODBBX        ; STX
  703.     LD      A,(IX+2)
  704.     CALL    PUTDAT
  705.         LD      A,0C0H
  706.     RET
  707. PSY::    CALL    MODBBX        ; STY
  708.     LD      A,(IX+3)
  709.     CALL    PUTDAT
  710.         LD      A,0C4H
  711.     RET
  712. PLDXY::    BIT     1,A           ; WHICH ONE?
  713.     JR      Z,PLY
  714.         CALL    MODDDD        ; LDX
  715.     LD      (IX+2),A
  716.     CALL    SINS1
  717.         LD      A,78H
  718.     RET
  719. PLY::    CALL    MODDDD        ; LDY
  720.     LD      (IX+3),A
  721.     CALL    SINS1
  722.         LD      A,7CH
  723.     RET
  724. PDCY::    BIT     1,A           ; WHICH ONE?
  725.     JR      Z,PCPY
  726.         CALL    MODBBX        ; DEC
  727.     DEC     A
  728.         CALL    SINS1
  729.     CALL    PUTDAT
  730.         LD      A,50H
  731.     RET
  732. PICX::    BIT     1,A           ; WHICH ONE?
  733.     JR      Z,PCPX
  734.         CALL    MODBBX        ; INC
  735.     INC     A
  736.         CALL    SINS1
  737.     CALL    PUTDAT
  738.         LD      A,60H
  739.     RET
  740. PCPX::    CALL    CXY           ; CPX
  741.     CALL    SINSET
  742.         LD      A,48H
  743.     RET
  744. PCPY::    INC     IX
  745.     CALL    CXY           ; CPY
  746.         DEC     IX
  747.     CALL    SINSET
  748.         LD      A,4CH
  749.     RET
  750. CXY::    CALL    MODCC
  751.     PUSH    BC
  752.         LD      B,A           ; MEM DAT INTO B
  753.     LD      A,(IX+2)    ; X (Y) INTO A
  754.         SUB     B
  755.     CCF                   ; BORROW = 6502 /C
  756.         POP     BC
  757.     RET
  758. PSBC::    RES     6,(IX+1)    ; SBC...CLR V FLG
  759.     CALL    MODAAA
  760.         PUSH    BC
  761.     LD      B,A        ; DATA TO B
  762.         LD      A,(IX+0)    ; ACC TO A
  763.     CALL    CARSET        ; SET UP C FLAG
  764.     CCF            ; AND COMPLEMENT IT
  765. PSBC1::    BIT     3,(IX+1)    ; CHECK FOR DEC MODE
  766.     JR      NZ,PSDEC
  767.         SBC     A,B
  768.     JR      PSBC2
  769. PSDEC::    SBC     A,B           ; DECIMAL MODE
  770.     DAA
  771. PSBC2::    LD      (IX+0),A    ; RESULT TO ACCUM
  772.     CCF            ; BORROW = 6502 /C
  773.     CALL    SINSET
  774.     AND    0C0H        ; TEST XOR OF B6 & B7
  775.     JR    Z,SBC3
  776.     CP    0C0H
  777.     JR    Z,SBC3
  778.     SET     6,(IX+1)    ; SET V FLAG IF XOR = 1
  779. SBC3::    POP     BC
  780.         LD      A,0ACH
  781.     RET
  782. PORA::    CALL    MODAAA        ; ORA
  783.     PUSH    BC
  784.         LD      B,A           ; DATA TO B
  785.     LD      A,(IX+0)    ; ACC TO A
  786.         OR      B
  787.     LD      (IX+0),A    ; RESULT TO ACC
  788.         CALL    SINS1
  789.     POP     BC
  790.         LD      A,88H
  791.     RET
  792. PAND::    CALL    MODAAA        ; AND
  793.     PUSH    BC
  794.         LD      B,A           ; DATA TO B
  795.     LD      A,(IX+0)    ; ACC TO A
  796.         AND     B
  797.     LD      (IX+0),A    ; RESULT TO ACC
  798.         CALL    SINS1
  799.     POP     BC
  800.         LD      A,4
  801.     RET
  802. PEOR::    CALL    MODAAA        ; EOR
  803.     PUSH    BC
  804.         LD      B,A        ; DATA TO B
  805.     LD      A,(IX+0)    ; ACC TO A
  806.         XOR     B
  807.     LD      (IX+0),A    ; RESULT TO ACC
  808.         CALL    SINS1
  809.     POP     BC
  810.         LD      A,5CH
  811.     RET
  812. PADC::    RES     6,(IX+1)    ; ADC: CLEAR V FLAG
  813.     CALL    MODAAA
  814.         PUSH    BC
  815.     LD      B,A        ; DATA TO B
  816.         LD      A,(IX+0)    ; ACC TO A
  817.     CALL    CARSET        ; SET UP C FLG
  818. PADC1::    BIT     3,(IX+1)    ; CHECK FOR DEC MODE
  819.     JR      NZ,PADEC
  820.         ADC     A,B           ; BINARY MODE
  821.     JR      PADC2
  822. PADEC::    ADC     A,B           ; DECIMAL MODE
  823.     DAA
  824. PADC2::    LD      (IX+0),A    ; RESULT TO ACC
  825.     CALL    SINSET
  826.     AND    0C0H        ; CHECK XOR OF B6 & B7
  827.     JR    Z,PADC3
  828.     CP    0C0H
  829.     JR    Z,PADC3
  830.     SET     6,(IX+1)    ; SET V FLG IF XOR = 1
  831. PADC3::    POP     BC
  832.     LD      A,0
  833.         RET
  834. PSTA::    CALL    MODAAA        ; STA
  835.     LD      A,(IX+0)    ; ACC TO MEM
  836.         CALL    PUTDAT
  837.     LD      A,0BCH
  838.         RET
  839. PLDA::    CALL    MODAAA        ; LDA
  840.     LD      (IX+0),A    ; MEM TO ACC
  841.         CALL    SINS1
  842.     LD      A,74H
  843.         RET
  844. PCMP::    CALL    MODAAA        ; CMP
  845.     PUSH    BC
  846.         LD      B,A           ; DATA TO B
  847.     LD      A,(IX+0)    ; ACC TO A
  848.         SUB     B
  849.     CCF                   ; BORROW = 6502 /C
  850.         CALL    SINSET
  851.     POP     BC
  852.         LD      A,44H
  853.     RET
  854. ;
  855. ; END OF ALL MULTI MODE PROCESSORS
  856. ;
  857. MLTEND::PUSH    AF        ; SAVE MNEMONIC CODE
  858.     LD    A,0        ; TURN OFF ACCUM MODE FLAG
  859.     LD    (ACCFLG),A
  860.     POP    AF
  861.     ADD     A,C        ; FORM MNEM CODE IN C
  862.     LD      C,A
  863. END::    INC     HL        ; POINT TO NXT INSTR
  864. END1::    LD      (NPC),HL
  865.     RET            ; BACK TO CMND
  866. ;
  867. ; VARIOUS SUBROUTINES FOR TRANSLATOR
  868. ;
  869. ; SET Z80 C FLAG TO MATCH 6502 C FLG
  870. ;
  871. CARSET::SCF
  872.     BIT    0,(IX+1)
  873.     RET    NZ
  874.     CCF
  875.     RET
  876. ;
  877. ; SET SIMULATOR S,Z,C FLAGS PER Z80 RESULTS
  878. ;
  879. SINSET::RES     0,(IX+1)    ; RESET C FLAG
  880.     JR      NC,SINS1
  881.         SET     0,(IX+1)    ; SET C PER Z80 C
  882. SINS1::    RES     1,(IX+1)    ; CLEAR Z FLAG
  883.     OR      A             ; SEE IF ACC = 0
  884.         JR      NZ,SINS2
  885.     SET     1,(IX+1)    ; SET Z FLG
  886. SINS2::    RES     7,(IX+1)    ; CLEAR SIGN FLAG
  887.     BIT     7,A           ; CHECK SIGN OF ACC
  888.         RET     Z
  889.     SET     7,(IX+1)    ; SET S IF NECESSARY
  890.         RET
  891. ;
  892. ; TRANSFER SIMULATOR SP TO/FROM HL
  893. ;
  894. TSPD::    LD      D,1           ; XFER SP TO DE
  895.         LD      E,(IX+4)
  896.     EX    DE,HL        ; PC TO DE, SP TO HL
  897.     RET
  898. TDSP::    EX    DE,HL        ; PC TO HL, SP TO DE
  899.     LD    (IX+4),E    ; RESTORE SP
  900.         RET
  901. ;
  902. ; ADDRESS MODE DECODERS...RETURN WITH DATA TO BE MODIFIED
  903. ; IN A, ADDRESS MODE CODE IN B, # BYTES IN C, ADDRESS OF
  904. ; DATA IN DE
  905. ;
  906. MODAAA::LD      IY,AAATBL    ; GROUP 1
  907.     JR      MOD1
  908. MODBBB::LD      IY,BBBTBL    ; GROUP 2
  909.     JR      MOD1
  910. MODDDD::LD      IY,DDDTBL    ; GROUP 3
  911.         CP      0B6H          ; LDX ZPG,Y SPECIAL
  912.     JR      NZ,DDD1
  913.         LD      A,10H
  914. DDD1::    CP      0BEH          ; LDX ABS,Y SPECIAL
  915.     JR      NZ,MOD1
  916.         LD      A,18H
  917.     JR      MOD1
  918. MODBBX::LD      IY,BBXTBL    ; GROUP 4 & 6
  919.         CP      96H           ; STX ZPG,Y SPECIAL
  920.     JR      Z,BBX
  921.     RRA            ; EXTRA SHIFT
  922.     AND    0CH        ; EXTRA MASK
  923.     JR    MOD1
  924. BBX::    LD    A,10H        ; SPECIAL
  925.     JR    MOD1
  926. MODCC::    LD      IY,CCTBL    ; GROUP 5
  927. MOD1::    RRA                   ; ROTATE MODE INTO LSD
  928.         AND     0EH           ; MASK THE REST
  929.         LD      B,0           ; FORM OFFSET IN BC
  930.     LD      C,A
  931.         ADD     IY,BC         ; ADD TO TABLE START
  932.     LD      C,(IY+0)    ; MODE OFFSET
  933.         LD      B,(IY+1)    ; # CODE
  934.     PUSH    BC            ; SAVE FOR LATER
  935. GETDAT::LD      IY,GETTBL    ; JUMP TABLE
  936.     JP    JPIB
  937. PABY::    INC     HL            ; ABS,Y
  938.     CALL    FETCHA        ; 2ND BYTE INSTR
  939.         ADD     A,(IX+3)    ; PLUS Y INDEX
  940.     LD      E,A           ; TO E
  941.         INC     HL
  942.     CALL    FETCHA        ; 3RD BYTE INSTR
  943.         ADC     A,0           ; PLUS CARRY
  944.     LD      D,A           ; TO D
  945.         JP      EXIT
  946. PIMM::    INC     HL            ; IMMEDIATE
  947.     CALL    FETCHA        ; DATA TO ACC
  948.         JR      EX1
  949. PACX::    LD    A,1        ; SET ACCUM MODE FLAG
  950.     LD    (ACCFLG),A
  951.     LD      A,(IX+0)    ; ACCUM
  952.     PUSH    IX
  953.         POP     DE
  954.     JR      EX1
  955. PZPG::    INC     HL            ; ZPG
  956.     CALL    FETCHA
  957.     LD      E,A        ; ADDRESS TO DE
  958.         LD      D,0
  959.     JR      EXIT
  960. PAB::    INC     HL            ; ABSOLUTE
  961.     CALL    FETCHA
  962.     LD      E,A        ; ADDRESS TO DE
  963.         INC     HL
  964.     CALL    FETCHA
  965.     LD      D,A
  966.         JR      EXIT
  967. PZX::    LD      A,(IX+2)    ; ZPG,X...GET X INDEX
  968.     JR      PZ1
  969. PZY::    LD      A,(IX+3)    ; ZPG,Y...GET Y INDEX
  970. PZ1::    INC     HL
  971.     PUSH    BC        ; GET A WORK REG
  972.     LD    B,A        ; SAVE IN B
  973.     CALL    FETCHA        ; GET BASE ADRS
  974.     ADD    A,B        ; ADD IT IN
  975.     POP    BC
  976.         LD      E,A           ; PUT IN E
  977.     LD      D,0           ; ZERO PAGE, NO WRAP
  978.         JR      EXIT
  979. PZIX::    INC     HL            ; (ZPG,X)
  980.     CALL    FETCHA        ; 2ND BYTE INSTR
  981.         ADD     A,(IX+2)    ; ADD X INDEX
  982.     LD      E,A           ; TO FORM BASE ADDRESS...
  983.         LD      D,0           ; IN ZERO PG, NO WRAP
  984.     LD      IY,0
  985.         ADD     IY,DE         ; TRANSFER TO IY
  986.     LD      E,(IY+0)    ; EFF ADDR TO DE
  987.         LD      D,(IY+1)
  988.     JR      EXIT
  989. PZIY::    INC     HL            ; (ZPG),Y
  990.     CALL    FETCHA
  991.     LD      E,A        ; BASE ADDRESS
  992.         LD      D,0           ; IN ZERO PAGE
  993.     LD      IY,0
  994.         ADD     IY,DE         ; TRANSFER TO IY
  995.     LD      A,(IY+0)    ; EFF ADDRESS...
  996.         ADD     A,(IX+3)    ; PLUS Y INDEX...
  997.     LD      E,A           ; TO DE
  998.         LD      A,(IY+1)
  999.     ADC     A,0
  1000.         LD      D,A
  1001.     JR      EXIT
  1002. PABX::    INC     HL            ; ABS,X
  1003.     CALL    FETCHA        ; 2ND BYTE INSTR
  1004.         ADD     A,(IX+2)    ; PLUS X INDEX
  1005.     LD      E,A           ; TO E
  1006.         INC     HL            ; 3RD BYTE INSTR
  1007.     CALL    FETCHA
  1008.         ADC     A,0           ; PLUS CARRY
  1009.     LD      D,A           ; TO E
  1010. EXIT::    EX    DE,HL
  1011.     CALL    FETCHA        ; GET DATA
  1012.     EX    DE,HL
  1013. EX1::    POP     BC            ; RESTORE # CODE
  1014.     PUSH    AF            ; SAVE DATA
  1015.         LD      A,3
  1016.     AND     B             ; # BYTES...
  1017.         LD      C,A           ; TO C
  1018.     SRL     B
  1019.         SRL     B             ; B=ADDR MODE
  1020.     POP     AF            ; RESTORE DATA
  1021.         RET
  1022. ;
  1023. ; STORE DATA TO ADDRESS FROM GETDAT
  1024. ;
  1025. PUTDAT::EX    DE,HL
  1026.     PUSH    AF        ; SAVE OUTPUT BYTE
  1027.     LD    A,(ACCFLG)    ; GET ACCUMULATOR MODE FLAG
  1028.     OR    A        ; TEST IT
  1029.     JR    Z,P65MEM    ; GO STORE IN 6502 MEMORY IF OFF
  1030.     LD    A,0        ; NOPE, TURN OFF FLAG
  1031.     LD    (ACCFLG),A
  1032.     POP    AF        ; HL HAS POINTER TO ACCUMULATOR
  1033.     LD    (HL),A        ; (IN Z80 MEMORY SPACE)
  1034.     EX    DE,HL
  1035.     RET
  1036. P65MEM:    POP    AF        ; GET BYTE TO SEND
  1037.     CALL    SENDA
  1038.     EX    DE,HL
  1039.     RET
  1040. ;
  1041. ; INDEX INTO JUMP TABLES...ENTER WITH TABLE START
  1042. ; ADDRESS IN IY AND OFFSET IN C. CALCULATES TABLE
  1043. ; POSITION AND JUMPS TO RESULT
  1044. ;
  1045. JPIB::    LD    B,0        ; INDIRECT JUMP PER TABLE
  1046.     ADD    IY,BC        ; TABLE ADDRESS TO IY
  1047.     LD    C,(IY+0)    ; TABLE ENTRY TO BC
  1048.     LD    B,(IY+1)
  1049.     PUSH    BC
  1050.     POP    IY        ; ENTRY TO IY
  1051.     JP    (IY)        ; AND GO TO IT
  1052. ;
  1053. ; ELEMENTARY MONITOR FUNCTIONS TO EXAMINE A BLOCK OF
  1054. ; MEMORY LOCATIONS (E) AND TO CHECK AND UPDATE
  1055. ; INDIVIDUAL LOCATIONS (M)
  1056. ;
  1057. EXAM::    LD    DE,GETADR    ; EXAM BLOCK OF MEM
  1058.     CALL    PRTDE
  1059.     CALL    GETWRD        ; GET START ADDR
  1060.     PUSH    DE
  1061.     CALL    LINF
  1062.     LD    DE,GETN
  1063.     CALL    PRTDE
  1064.     CALL    GETWRD        ; GET # BYTES
  1065.     PUSH    DE
  1066.     POP    BC
  1067.     LD    E,4        ; CHANGE TO # LINES (/16)
  1068.     XOR    A
  1069. BYTLN::    SRL    B
  1070.     RR    C
  1071.     JR    NC,XXX
  1072.     INC    A
  1073. XXX::    DEC    E
  1074.     JR    NZ,BYTLN
  1075.     OR    A        ; SEE IF PARTIAL LINE
  1076.     JR    Z,YYY
  1077.     INC    BC
  1078. YYY::    POP    HL        ; HL = START, BC = COUNT
  1079.     DEC    BC        ; ONE LESS LINE
  1080. EXLP::    PUSH    BC        ; LOOP FOR ONE LINE
  1081.     CALL    CRLF
  1082.     CALL    LADR        ; PRINT ADDRESS AT START
  1083.     CALL    TWO        ; INSERT TWO SPACES
  1084.     PUSH    HL        ; SAVE ADDRESS FOR ALPHA
  1085.     LD    E,16        ; 16 ENTRIES PER LINE
  1086. LNLP::    CALL    FETCHA        ; GET BYTE FROM MEMORY
  1087.     CALL    PACC        ; PRINT IT HEX
  1088.     CALL    ONE        ; SPACE
  1089.     INC    HL        ; POINT TO NEXT BYTE
  1090.     DEC    E        ; DONE WITH HEX?
  1091.     JR    NZ,LNLP    ; NO, DO NEXT BYTE
  1092.     CALL    TWO        ; YES, SET UP FOR ALPHA
  1093.     POP    HL        ; SAME STARTING ADDRESS
  1094.     LD    E,16
  1095. ASCII::    CALL    FETCHA        ; GET BYTE
  1096.     CP    20H        ; IS IT PRINTABLE?
  1097.     JR    C,DOT
  1098.     CP    80H
  1099.     JR    C,ASOK
  1100. DOT::    LD    A,'.'        ; NO, PRINT A DOT
  1101. ASOK::    CALL    PRNA
  1102.     INC    HL        ; BUMP POINTER
  1103.     DEC    E        ; DONE WITH LINE?
  1104.     JR    NZ,ASCII
  1105.     POP    BC
  1106.     LD    A,B        ; SEE IF ALL DONE
  1107.     OR    C
  1108.     RET    Z        ; YES, RET TO CMND
  1109.     DEC    BC
  1110.     JR    EXLP        ; ELSE DO ANOTHER LINE
  1111. ;
  1112. ; SUBSTITUTE MEMORY...ENTER BY 'M'
  1113. ;
  1114. SUBM::    LD    DE,GETADR    ; ASK FOR ADDRESS
  1115.     CALL    PRTDE
  1116.     CALL    GETWRD        ; GET IT
  1117.     EX    DE,HL        ; MOVE IT TO HL
  1118. SULP::    CALL    CRLF
  1119.     CALL    LADR        ; PRINT THE ADDRESS
  1120.     CALL    TWO
  1121.     CALL    FETCHA
  1122.     CALL    PACC        ; PRINT THE CONTENTS
  1123.     CALL    TWO
  1124. JLP::    CALL    GETCHR        ; GET INPUT
  1125.     CP    2EH        ; EXIT ON "."
  1126.     RET    Z
  1127.     CP    20H
  1128.     JR    Z,FWD        ; SKIP AHEAD ON "SPACE"
  1129.     CALL    CONV        ; CONV HEX IF POSSIBLE
  1130.     JR    Z,JLP        ; NOT A HEX NUMBER
  1131.     PUSH    HL        ; SAVE ADDRESS AGAIN
  1132.     LD    HL,0        ; CLEAR FOR ROTATE
  1133. LLP::    CALL    ROBYT        ; ROTATE NYBBLE INTO HL
  1134. KLP::    CALL    GETCHR        ; GET ANOTHER CHARACTER
  1135.     CP    0DH
  1136.     JR    Z,PUTIN    ; IF "CR" STUFF IT
  1137.     CALL    CONV        ; CONV BINARY
  1138.     JR    Z,KLP        ; NOT A HEX NUMBER
  1139.     JR    LLP        ; CONTINUE
  1140. PUTIN::    PUSH    HL        ; DATA TO BC
  1141.     POP    BC
  1142.          POP    HL        ; RETRIEVE ADDRESS
  1143.     LD    A,C
  1144.     CALL    SENDA        ; STUFF THE DATA
  1145. FWD::    INC    HL        ; BUMP POINTER
  1146.     JR    SULP        ; ...AND CONTINUE
  1147. LADR::    EX    DE,HL        ; PRINT WORD IN HL
  1148.     CALL    PRTWRD
  1149.     EX    DE,HL
  1150.     RET
  1151. PACC::    PUSH    DE        ; PRINT BYTE IN A
  1152.     LD    E,A
  1153.     CALL    PRTBYT
  1154.     POP    DE
  1155.     RET
  1156. TWO::    CALL    ONE        ; PRINT 2 SPACES
  1157. ONE::    PUSH    BC        ; PRINT SPACE
  1158.     LD    C,' '
  1159.     CALL    PRNC
  1160.     POP    BC
  1161.     RET
  1162. ;
  1163. ; VARIOUS ROUTINES USED BY TRANSLATOR, MONITOR, AND DOS
  1164. ;
  1165. CRLF::    LD      C,0DH        ; PRINT CRLF
  1166.     CALL    PRNC
  1167. LINF::    LD      C,0AH
  1168.     JP      PRNC
  1169. PROM::    LD      C,' '        ; PRINT ' >'
  1170.     CALL    PRNC
  1171.         LD      C,'>'
  1172.     JP      PRNC
  1173. ;
  1174. ; GET HEX DATA IN DE. ROTATE CONTINUOUSLY UNTIL A
  1175. ; 'CR' IS INPUT. LSB IN E. SET Z FLG AND RET ON 'SPACE'
  1176. ;
  1177. GETWRD::CALL    GETCHR        ; GET BINARY DATA
  1178.     CP      ' '           ; RET Z IF SPACE
  1179.         RET     Z
  1180.     EX      DE,HL
  1181.         LD      HL,0          ; CLEAR HOLDING REG
  1182.     CALL    CONV        ; CHANGE TO HEX
  1183.     JR    Z,GETWRD    ; INVALID CHAR
  1184.     CALL    ROBYT        ; ROTATE INTO HL
  1185. WRDLP::    CALL    GETCHR        ; GET NEXT CHAR
  1186.     CP      0DH           ; TERMINATOR
  1187.     JR    Z,WRDON
  1188.     CALL    CONV
  1189.     JR    Z,WRDLP
  1190.     CALL    ROBYT
  1191.     JR    WRDLP
  1192. WRDON::    OR      A             ; CLEAR Z FLAG
  1193.         EX      DE,HL         ; DATA INTO DE
  1194.     RET
  1195. ;
  1196. ; CONVERT ASCII DATA IN A TO HEX. SET Z FLG IF INVALID
  1197. ;
  1198. CONV::    CP      '0'           ; CONVERT TO BINARY
  1199.     JR      C,BAD
  1200.         CP      3AH
  1201.     JR      C,GOOD
  1202.         CP      41H
  1203.     JR      C,BAD
  1204.         CP      47H
  1205.     JR      C,GOOD
  1206. BAD::    LD      C,'?'
  1207.     CALL    PRNC        ; NOTIFY BAD INPUT
  1208.     XOR    A        ; SET Z FLAG
  1209.     RET
  1210. GOOD::    SUB     30H
  1211.     CP      10
  1212.     JR      C,GOOD1
  1213.     SUB     7
  1214. GOOD1::    CP    0FFH        ; CLEAR Z FLAG
  1215.     RET
  1216. ;
  1217. ; ROTATE BYTE IN A INTO HL VIA L
  1218. ;
  1219. ROBYT::    ADD    HL,HL        ; ROTATE A INTO HL
  1220.     ADD     HL,HL        ; ROTATE HL 4 BITS LEFT
  1221.     ADD     HL,HL
  1222.     ADD     HL,HL
  1223.     OR      L             ; PUT NEW DIGIT INTO L
  1224.     LD      L,A
  1225.     RET
  1226. ;
  1227. ; PRINT FOUR DIGIT VALUE IN DE
  1228. ;
  1229. PRTWRD::LD      A,D
  1230.     CALL    PRBIN
  1231. PRTBYT::LD      A,E           ; PRINT VALUE IN E
  1232. PRBIN::    PUSH    AF
  1233.     RRC     A
  1234.     RRC     A
  1235.     RRC     A
  1236.     RRC     A
  1237.     CALL    PRB1
  1238.     POP     AF
  1239. PRB1::    AND     0FH
  1240.     ADD     A,90H
  1241.     DAA
  1242.     ADC     A,40H
  1243.     DAA
  1244.     JR      PRNA
  1245. ;
  1246. ; PRINT STRING POINTED TO BY DE. USES PRTXT
  1247. ;
  1248. PRTDE::    PUSH    IY        ; PRNT PER DE
  1249.     PUSH    DE
  1250.     POP    IY
  1251.     CALL    PRTXT
  1252.     POP    IY
  1253.     RET
  1254. ;
  1255. ; PRINT ASCII STRING POINTED TO BY IY. CHECK FOR
  1256. ; SPECIALS: '1' PRINTS AS BYTE POINTED TO BY HL, '2'
  1257. ; PRINTS (HL+1), '!' DOES NOT PRINT, '^' TERMINATES.
  1258. ;
  1259. PRTXT::    LD      E,0           ; PRNT UP TO 255 CHRSY
  1260. PRNLP::    LD      A,(IY+0)
  1261.     CP      '^'        ; TERMINATOR?
  1262.     RET     Z
  1263.     CP      '!'        ; NO PRINT?
  1264.     JR      Z,DONXT+1
  1265.     PUSH    DE
  1266.     LD      HL,(CPC)
  1267.     INC     HL
  1268.     CP      '2'        ; PRINT (HL+1)?
  1269.     JR      NZ,PRN1
  1270.     INC     HL
  1271.     CALL    FETCHA
  1272.     LD      E,A
  1273.     CALL    PRTBYT
  1274.     JR      DONXT
  1275. PRN1::    CP      '1'        ; PRINT (HL)?
  1276.     JR      NZ,DOALPH
  1277.     CALL    FETCHA
  1278.     LD      E,A
  1279.     CALL    PRTBYT
  1280.     JR      DONXT
  1281. DOALPH::LD      C,A        ; ALL OTHER CHARACTERS
  1282.     CALL    PRNC
  1283. DONXT::    POP     DE
  1284.     INC     IY
  1285.     DEC     E
  1286.     JR      NZ,PRNLP
  1287.     RET
  1288. ;
  1289. SPAC::    PUSH    BC            ; PRINT 6 SPACES
  1290.     LD      B,6
  1291.     LD      C,' '
  1292. SPLP::    CALL    PRNC
  1293.     DJNZ    SPLP
  1294.     POP     BC
  1295.     RET
  1296. ;
  1297. ; CONSOLE I/O
  1298. ;
  1299. GETCHR::CALL    KBIN         ; GET CHAR & TEST
  1300.     CP    3        ; ^C....
  1301.     JP    Z,CPWRM        ; CP/M WARM START
  1302.     CP    18H        ; ^X (CAN)...
  1303.     JR    NZ,PRNA
  1304.     LD    SP,SYSTK-2    ; FOR RET TO CMND
  1305.     LD    A,'#'
  1306. PRNA::    LD      C,A        ; PRINT CHAR IN A
  1307.     CALL    PRNC
  1308.     RET
  1309. ;
  1310. ; VECTOR TABLE COPY MOVED FROM BIOS
  1311. ;
  1312. VECTBL    EQU    $
  1313. ;
  1314. CPMCLD::JP    $-$        ; VECTOR TABLE FILLED IN..
  1315. CPWRM::    JP    $-$        ; ...AT STARTUP
  1316. KBST::    JP      $-$
  1317. KBIN::    JP    $-$
  1318. PRNC::    JP    $-$
  1319.     JP    $-$        ;LIST
  1320.     JP    $-$        ;PUNCH
  1321.     JP    $-$        ;READER
  1322. HOMB::    JP    $-$
  1323. DRVS::    JP    $-$
  1324. TRKS::    JP    $-$
  1325. SECS::    JP    $-$
  1326. BUFS::    JP    $-$
  1327. RDONE::    JP    $-$
  1328. WRONE::    JP    $-$
  1329. ;
  1330. ; HISTOGRAM BUFFER
  1331. ;
  1332. HSBUFR::
  1333.     REPT    HSIZE
  1334.     DW    0        ;INIT TO ZEROES
  1335.     ENDM
  1336. ;
  1337. ;
  1338. ; JUMP TABLE FOR LINKS TO Z80 ROUTINES...FILL IN AS REQD
  1339. ; FIRST TWO INITIALIZED TO CONSOLE I/O VIA ACC
  1340. ;
  1341. USR0::    JP    KBIN        ; 6502 USER ROUTINES
  1342. USR1::    JP    PRNA
  1343. USR2::    DEFB    0C9H,0,0
  1344. USR3::    DEFB    0C9H,0,0
  1345. USR4::    DEFB    0C9H,0,0
  1346. ;
  1347. ; 6502 BREAK VECTOR...INIT TO GO TO COMMAND LEVEL
  1348. ;
  1349. IPOINT::DEFW    0
  1350. ;
  1351. ; TEMPORARIES FOR TRANSLATOR
  1352. ;
  1353. NSTEPS::DEFB    1             ; # STEPS TO EXECUTE
  1354. NBYTES::DEFB    0             ; # BYTES IN INSTR
  1355. DLYCON::DEFW    0A00H        ; TIME DELAY FOR # STEP
  1356. BREAK:: DEFW    0             ; BREAKPOINT ADDRESS
  1357. ACCFLG::DEFB    0        ; MODE=ACCUM FLAG
  1358. ;
  1359. ; SIMULATED 6502 CPU REGISTERS...INIT TO THESE VALUES
  1360. ;
  1361. VREG::    DEFB    0             ; ACCUMULATOR
  1362.     DEFB    0             ; STATUS (P) REG
  1363.     DEFB    0             ; X INDEX REG
  1364.     DEFB    0             ; Y INDEX REG
  1365.     DEFB    0FFH          ; STACK POINTER
  1366. CPC::    DEFW    1000H         ; PROGRAM COUNTER
  1367. NPC::    DEFW    1000H          ; LOCATION OF NXT INSTR
  1368. ;
  1369. ; VARIOUS MESSAGES FOR SYSTEM
  1370. ;
  1371. INTRO::    DEFM    '*  ZX/65 65xx SIMULATOR *^'
  1372. HEADR::    DEFM    ' CPC:  INS:  A:... P:...'
  1373.     DEFM    ' X:... Y:... SP:.. NPC: '
  1374. GETADR::DEFM    ' ENTER START ADDRESS: ^'
  1375. GETN::    DEFM    ' ENTER NO. BYTES: ^'
  1376. MLTMSG::DEFM    ' ENTER # STEPS: ^'
  1377. BKPMSG::DEFM    ' ENTER BRKP ADDR: ^'
  1378. ;
  1379. ; DATA TABLES FOR TRANSLATOR BEGIN HERE
  1380. ;
  1381. ; ADDRESSING MODE TABLES
  1382. ;
  1383. AAATBL::DEFW    1A0CH         ; (ZPG,X)
  1384.     DEFW    0E04H         ; ZPG
  1385.     DEFW    0600H         ; IMM
  1386.     DEFW    0B06H         ; ABS
  1387.     DEFW    1E0EH         ; (ZPG),Y
  1388.     DEFW    2208H         ; ZPG,X
  1389.     DEFW    2F12H         ; ABS,Y
  1390.     DEFW    2B10H         ; ABS,X
  1391. BBBTBL::DEFW    0             ; INVALID
  1392.     DEFW    0E04H         ; ZPG
  1393.     DEFW    1502H         ; ACC
  1394.     DEFW    0B06H         ; ABS
  1395.     DEFW    260AH         ; ZPG,Y
  1396.     DEFW    2208H         ; ZPG,X
  1397.     DEFW    2F12H         ; ABS,Y
  1398.     DEFW    2B10H         ; ABS,X
  1399. DDDTBL::DEFW    0600H         ; IMM
  1400.     DEFW    0E04H         ; ZPG
  1401.     DEFW    0             ; INVALID
  1402.     DEFW    0B06H         ; ABS
  1403.     DEFW    260AH         ; ZPG,Y
  1404.     DEFW    2208H         ; ZPG,X
  1405.     DEFW    2F12H         ; ABS,Y
  1406.     DEFW    2B10H         ; ABS,X
  1407. BBXTBL::DEFW    0E04H         ; ZPG
  1408.     DEFW    0B06H         ; ABS
  1409.     DEFW    2208H         ; ZPG,X
  1410.     DEFW    2B10H         ; ABS,X
  1411.     DEFW    260AH        ; ZPG,Y
  1412. CCTBL::    DEFW    0600H         ; IMM
  1413.     DEFW    0E04H         ; ZPG
  1414.     DEFW    0             ; INVALID
  1415.     DEFW    0B06H         ; ABS
  1416. ;
  1417. ; BRANCH MASK TABLE
  1418. ;
  1419. MSKTBL::DEFW    8026H         ; BPL
  1420.     DEFW    801EH         ; BMI
  1421.     DEFW    402EH         ; BVC
  1422.     DEFW    4032H         ; BVS
  1423.     DEFW    010EH         ; BCC
  1424.     DEFW    0112H         ; BCS
  1425.     DEFW    0222H         ; BNE
  1426.     DEFW    0216H         ; BEQ
  1427. ;
  1428. ; FLAG SET/RESET CODES
  1429. ;
  1430. FLGTBL::DEFW    0135H          ; CLC
  1431.     DEFW    01B1H        ; SEC
  1432.     DEFW    043DH        ; CLI
  1433.     DEFW    04B9H        ; SEI
  1434.     DEFW    4041H        ; CLV
  1435.     DEFW    0000        ; INVALID
  1436.     DEFW    0839H        ; CLD
  1437.     DEFW    08B5H        ; SED
  1438. ;
  1439. ; JUMP TABLES TO IMPLIED INSTRUCTIONS
  1440. ;
  1441. IMPTBL::DEFW    PPHP          ; IMPLIED INSTR TABLE
  1442.     DEFW    PPLP
  1443.     DEFW    PPHA
  1444.     DEFW    PPLA
  1445.     DEFW    PDEY
  1446.     DEFW    PTAY
  1447.     DEFW    PINY
  1448.     DEFW    PINX
  1449.     DEFW    PTXA
  1450.     DEFW    PTAX
  1451.     DEFW    PDEX
  1452.     DEFW    PNOP
  1453. ;
  1454. ; JUMP TABLE TO ADDR MODE PROCESSORS
  1455. ;
  1456. GETTBL::DEFW    PIMM          ; INSTR MODE TABLE
  1457.     DEFW    PACX
  1458.     DEFW    PZPG
  1459.     DEFW    PAB
  1460.     DEFW    PZX
  1461.     DEFW    PZY
  1462.     DEFW    PZIX
  1463.     DEFW    PZIY
  1464.     DEFW    PABX
  1465.     DEFW    PABY
  1466. ;
  1467. ; JUMP TABLES TO MULTI-MODE PROCESSORS
  1468. ;
  1469. EVNTBL::DEFW    PASL          ; JUMPS TO PROCESSORS
  1470.     DEFW    PBTRL
  1471.     DEFW    PLSR
  1472.     DEFW    PROR
  1473.     DEFW    PSTXY
  1474.     DEFW    PLDXY
  1475.     DEFW    PDCY
  1476.     DEFW    PICX
  1477. ODDTBL::DEFW    PORA
  1478.     DEFW    PAND
  1479.     DEFW    PEOR
  1480.     DEFW    PADC
  1481.     DEFW    PSTA
  1482.     DEFW    PLDA
  1483.     DEFW    PCMP
  1484.     DEFW    PSBC
  1485. ;
  1486. ; MNEMONIC ASCII CODES (PACKED INTO 2 BYTES)
  1487. ;
  1488. MNMTBL::DEFW    0483H          ; MNEMONIC TABLE
  1489.     DEFW    05C4H
  1490.     DEFW    066CH
  1491.     DEFW    0863H         ; BCC
  1492.     DEFW    0873H
  1493.     DEFW    08B1H
  1494.     DEFW    0934H
  1495.     DEFW    09A9H
  1496.     DEFW    09C5H
  1497.     DEFW    0A0CH
  1498.     DEFW    0A4BH
  1499.     DEFW    0AC3H
  1500.     DEFW    0AD3H
  1501.     DEFW    0D83H         ; CLC
  1502.     DEFW    0D84H
  1503.     DEFW    0D89H
  1504.     DEFW    0D96H
  1505.     DEFW    0DB0H
  1506.     DEFW    0E18H
  1507.     DEFW    0E19H
  1508.     DEFW    10A3H        ; DEC
  1509.     DEFW    10B8H
  1510.     DEFW    10B9H
  1511.     DEFW    15F2H        ; EOR
  1512.     DEFW    25C3H        ; INC
  1513.     DEFW    25D8H
  1514.     DEFW    25D9H
  1515.     DEFW    29B0H        ; JMP
  1516.     DEFW    2A72H
  1517.     DEFW    3081H        ; LDA
  1518.     DEFW    3098H
  1519.     DEFW    3099H
  1520.     DEFW    3272H
  1521.     DEFW    39F0H        ; NOP
  1522.     DEFW    3E41H        ; ORA
  1523.     DEFW    4101H        ; PHA
  1524.     DEFW    4110H
  1525.     DEFW    4181H
  1526.     DEFW    4190H
  1527.     DEFW    49ECH        ; ROL
  1528.     DEFW    49F2H
  1529.     DEFW    4A89H
  1530.     DEFW    4A93H
  1531.     DEFW    4C43H        ; SBC
  1532.     DEFW    4CA3H
  1533.     DEFW    4CA4H
  1534.     DEFW    4CA9H
  1535.     DEFW    4E81H
  1536.     DEFW    4E98H
  1537.     DEFW    4E99H
  1538.     DEFW    5038H        ; TAX
  1539.     DEFW    5039H
  1540.     DEFW    5278H
  1541.     DEFW    5301H
  1542.     DEFW    5313H
  1543.     DEFW    5321H
  1544. ;
  1545. ; ADDRESS MODE PRINT TABLE
  1546. ;
  1547. AMDTBL::DEFM    ' $1    !'     ; ADDR MODE TABLE...REL
  1548.     DEFM    ' #$1   !'     ; IMMEDIATE
  1549.     DEFM    ' $21  !!'     ; ABS
  1550.     DEFM    ' $1    !'     ; ZPG
  1551.     DEFM    '        '     ; IMPLIED
  1552.     DEFM    ' A      '     ; ACCUM
  1553.     DEFM    ' ($1,X)!'     ; (ZPG,X)
  1554.     DEFM    ' ($1),Y!'     ; (ZPG),Y
  1555.     DEFM    ' $1,X  !'     ; ZPG,X
  1556.     DEFM    ' $1,Y  !'     ; ZPG,Y
  1557.     DEFM    ' $21,X!!'     ; ABS,X
  1558.     DEFM    ' $21,Y!!'     ; ABS,Y
  1559.     DEFM    ' ($21)!!'     ; INDIRECT
  1560. ;
  1561. ;
  1562.     DEFS    200           ; STACK AREA
  1563. ;
  1564. SYSTK    EQU    $
  1565. ;
  1566. ;
  1567. ; THAT'S ALL!
  1568. ;
  1569.     END
  1570.