home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / BEEHIVE / ZCAT / SYSIOP21.LBR / RELIOP.ZZ0 / RELIOP.Z80
Text File  |  2000-06-30  |  6KB  |  185 lines
  1. ; Edit Version 1.00
  2. ;**************************************************************************
  3. ;**************************************************************************
  4. ;***                                    ***
  5. ;***    Dummy IOP for MicroMint SB-180 bios.                ***
  6. ;***                                    ***
  7. ;**************************************************************************
  8. ;**************************************************************************
  9. ;
  10. ; File Name        : RELIOP.Z80
  11. ; Author        : Edmund Cramp
  12. ; Creation Date        : 29-Dec-1985
  13. ;
  14. ; Proccessor Type    : HD64180
  15. ; Assembler Name    : Z80ASM (S.L.R Systems)
  16. ;
  17. ; Ammendment Record
  18. ; *****************
  19. ; Name        Date        Details of Ammendment
  20. ; ----        ----        ---------------------
  21. ; Edmund Cramp    29-Dec-1985    Initial Creation.
  22. ;
  23. ; Module Function.
  24. ; ****************
  25. ;    This is a minimal IOP to provide I/O for the CONSOLE device only.
  26. ; It is written in relocatable code and uses polled I/O - you will need to
  27. ; modify the ASCI1 entry for STAT1 in the bios IOTABLE to DISABLE interrupts
  28. ; when the system is cold booted (see below).
  29. ;    This module is to be loaded into the IOP partition when the system
  30. ; is first cold booted and should be replaced by a compatible IOP via LDR
  31. ; or BLDR in the system startup alias.
  32. ; 
  33. ;**************************************************************************
  34.  
  35. ;    ==============
  36. ;    External Files
  37. ;    ==============
  38.  
  39.         MACLIB    HD64180.MLB    ; HD64180 macro library
  40.         MACLIB    PORTS.LIB    ; SB-180 hardware definitions.
  41.  
  42. ;    =============
  43. ;    Local Equates
  44. ;    =============
  45.  
  46. TDRE        EQU    00000010B    ; Transmit data register empty
  47. RDRF        EQU    10000000B    ; Receive data register full
  48.  
  49. ;**************************************************************************
  50. ;***    Changes to standard bios routines                ***
  51. ;**************************************************************************
  52.  
  53. ;+
  54. ;    ...in IOTABLE...
  55. ;    DEFB    00000100B    ; STAT1 - enable CTS*, no interrupts.
  56. ;                               ^^^^^^^^^^^^^^
  57. ;    ...in INTTBL...
  58. ;    DEFB    INTERR        ; ASCI 1 - Console does not use interrupts.
  59. ;                       ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
  60. ; Redirect ALL console I/O through the BIOS vectors to that any programs
  61. ; that PATCH the BIOS table will work correctly if the BIOS issues an
  62. ; internal error message...
  63. ;
  64. ; BIOS:        JP    BOOT        ; # 0 Cold start        
  65. ; WBOOTE:    JP    WBOOT        ; # 1 Warm start        
  66. ; CONST:    JP    IOP+12        ; # 2 Console status        <-- *
  67. ; CONIN:    JP    IOP+15        ; # 3 Console character in    <-- *
  68. ; CONOUT:    JP    IOP+18        ; # 4 Console character out    <-- *
  69. ;        JP    IOP+21        ; # 5 List character out    
  70. ;        JP    IOP+24        ; # 6 Punch character out    
  71. ;        JP    IOP+27        ; # 7 Reader character in    
  72. ;        JP    HOME        ; # 8 Move head to home position
  73. ;        JP    SELDSK        ; # 9 Select disk        
  74. ;        JP    SETTRK        ; #10 Set track number        
  75. ;        JP    SETSEC        ; #11 Set sector number        
  76. ;        JP    SETDMA        ; #12 Set dma address        
  77. ;        JP    READ        ; #13 Read disk            
  78. ;        JP    WRITE        ; #14 Write disk        
  79. ;        JP    IOP+30        ; #15 Return list status    
  80. ;        JP    SECTRAN        ; #16 Sector translate        
  81. ;        ; SB-180 BIOS vectors...                
  82. ;        JP    IOINIT        ; #17 Initialise SB-180.    
  83. ;        JP    TIME        ; #18 Return pointer to RTC buffer.
  84. ;-
  85.  
  86. ;**************************************************************************
  87. ;***    Minimum I/O package - supports CONSOLE only.            ***
  88. ;**************************************************************************
  89. ;+
  90. ; IOP jump table - all unused entries exit Z (not ready).  The jump table is
  91. ; constructed using two byte jump relative instructions at 3 byte intervals
  92. ; so that the table appears to ZCPR to be a standard IOP.
  93. ;-
  94. IOPENT:        JR    IOPERR        ; SELECT returns "NO IOP"
  95.         NOP            ; Pad to 3 bytes...
  96.         JR    IOPERR        ; SELECT n/a
  97.         NOP            ; 
  98.         JR    IOPERR        ; NAMER n/a
  99.         NOP            ; 
  100.         JR    IOPERR        ; TINIT n/a
  101.         NOP            ; 
  102.         JR    ICONST        ; Local console status support
  103.         NOP            ; 
  104.         JR    ICONIN        ; Local console input support
  105.         NOP            ; 
  106.         JR    ICONOUT        ; Local console output support
  107.         NOP            ; 
  108.         JR    IOPERR        ; LIST n/a
  109.         NOP            ; 
  110.         JR    IOPERR        ; PUNCH n/a
  111.         NOP            ; 
  112.         JR    IOPERR        ; READER n/a
  113.         NOP            ; 
  114.         JR    IOPERR        ; LISTST n/a
  115.         NOP            ; 
  116.         JR    IOPERR        ; NEWIO n/a
  117.         NOP            ; 
  118.         JR    IOPERR        ; COPEN n/a
  119.         NOP            ; 
  120.         JR    IOPERR        ; CCLOSE n/a
  121.         NOP            ; 
  122.         JR    IOPERR        ; LOPEN n/a
  123.         NOP            ; 
  124.         JR    IOPERR        ; LCLOSE n/a
  125.         NOP            ; 
  126.         DEFB    'Z3IOP'        ; IOP header.
  127.         DEFZ    'MINIMUM'    ; IOP name.
  128.  
  129. ;+
  130. ; General unimplemented error exit.
  131. ;-
  132. IOPERR:        XOR    A        ; Return ZERO...
  133.         RET            ; ...
  134.  
  135. ;+
  136. ; Console input status, return 0ffh if char ready, 00h if not.
  137. ;-
  138. ICONST:        IN0    A,(STAT1)    ; Get the console status...
  139.         AND    RDRF        ; ...test for data ready...
  140.         RET    Z        ; ...exit if No character waiting.
  141.         ; 
  142.         XOR    A        ; Return 0FFh if character waiting...
  143.         DEC    A        ; ...
  144.         RET            ; ...exit READY.
  145.  
  146. ;+
  147. ; Get a console character into register A.
  148. ;-
  149. ICONIN:        IN0    A,(STAT1)    ; Get the console status...
  150.         AND    RDRF        ; ...test for data ready...
  151.         JR    Z,ICONIN    ; ...branch until ready.
  152.         ; Character is waiting.
  153.         IN0    A,(RDR1)    ; Read character...
  154.         AND    01111111B    ; ...strip msb...
  155.         RET            ; ...exit - Char in Acc.
  156.  
  157. ;+
  158. ; Console character output from register C.
  159. ;-
  160. ICONOUT:    IN0    A,(STAT1)    ; Check console status register...
  161.         AND    TDRE        ; ...
  162.         JR    Z,ICONOUT    ; Wait for empty register.
  163.         OUT0    (TDR1),C    ; Output the C register...
  164.         RET            ; ...exit - done.
  165.  
  166. IOPLEN        EQU    $-IOPENT
  167.  
  168.  
  169. ;**************************************************************************
  170. ;***    Modifications to BIOS cold boot routine.            ***
  171. ;**************************************************************************
  172.  
  173. ;+
  174. ; This is the code that must be inserted in the SB180s' COLD BOOT routine
  175. ; prior to any use of CONIN, CONST or CONOUT to load the above routines
  176. ; into the IOP partition...
  177. ;
  178. ;        LD    HL,IOPENT    ; Load the minimum IOP...
  179. ;        LD    DE,IOP        ; ...into the IOP partition...
  180. ;        LD    BC,IOPLEN    ; ...
  181. ;        LDIR            ; ...
  182. ;-
  183.  
  184.         END
  185.