home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / BEEHIVE / UTILITYS / SDZD-138.ARC / SDZD#138.ASM < prev    next >
Assembly Source File  |  1991-02-10  |  124KB  |  5,513 lines
  1.  
  2.  
  3. ;              SUPER DIRECTORY PROGRAM
  4. ;
  5. ;             SDZD+138  1 FEB 89
  6. ;
  7. ;    Read SDZD+.INF for detailed instructions on configuring SD for your
  8. ;    system.  For information regarding this utility's modification
  9. ;    history, read SDZD+.HIS.
  10. ;
  11. ;        This program is being distributed ready
  12. ;        to use on a CP/M v2.2 computer with two
  13. ;        disk drives , no Z80DOS, no CPM3, and no ZCPR in use.
  14. ;
  15. ;        (Options often changed for RCPM use are
  16. ;        marked with an asterisk.)  The typical
  17. ;        RCPM Sysop might change only these:
  18. ;
  19. ;            a)    3 options starting at MAXDRV
  20. ;            b)    how many drives at LODRV and
  21. ;            c)    6 options starting at USEF
  22. ;            d)    USELCW needs wheel to prevent
  23. ;               showing archive bits
  24. ;
  25. ;
  26. ;         NOTE:  This version can be assembled with
  27. ;            ASM, LASM, M80, MAC or SLRMAC.
  28. ;
  29. ; SD displays the directory of a CP/M disk, sorted alphabetically, with
  30. ; the file size in k, rounded to the nearest CP/M block size.  It also
  31. ; displays library and archive files with the file size in k, if the $L
  32. ; option is selected.
  33. ;
  34. ; Current versions of SD automatically adjust for any block size and di-
  35. ; rectory length under CP/M 2.2,  3.0 or MP/M.    They can also handle any
  36. ; number of disk drives or skip those not available.  Current features:
  37. ;
  38. ;     1) Automatic pauses when the screen fills up except when the
  39. ;        F, N, or P options are specified
  40. ;     2) Searching individual or multiple drives and/or user areas
  41. ;     3) Unconditional or optional disk system reset before execution
  42. ;        begins
  43. ;     4) Directing output to a disk file called DISK.DIR and append-
  44. ;        ing to that file on subsequent runs
  45. ;     5) Summary line output giving drive and user information, num-
  46. ;        ber of files matched, how much space they consume and free
  47. ;        space remaining on the disk
  48. ;     6) Displaying or suppressing "system" files
  49. ;     7) Accepting ambiguous filenames with or without a drive name
  50. ;     8) Printer output (automatically suppresses the [more] pauses)
  51. ;     9) Optional help menu with '?'
  52. ;    10) Displaying number of records used by files
  53. ;    11) Alphabetization of files sorted by type (extent)
  54. ;    12) Selecting alternate list format - vertical if horizontal
  55. ;        is default, and vice versa.
  56. ;    13) Shows contents of .ARC, .ARK or .LBR files with $L option
  57. ;    14) Summary line output optionally contains name of ZCPR3 named
  58. ;        directory, if selected
  59. ;    15) ZCPR3 named directory may be used in command line instead
  60. ;        of DU: if selected
  61. ;    16) ZCPR3 Public user areas may be displayed with or without
  62. ;        WHEEL byte
  63. ;    17) Z80DOS or CPM3 time stamping and SETD22 type stamping of .LBR's
  64. ;        supported via Z80DOS or CPM3 equate.
  65. ;    18) Normal multi-page vertical sort or single page vertical sort
  66. ;    19) Choose files based upon attributes 1-4
  67. ;    20) Z33 ENViorment support of wheel, maxdrv, maxusr location
  68. ;    21) Summary totals now supplied if /A,/D,/H (or combo).
  69. ;    22) Greatly expanded date math capabilities
  70. ;    23) Support for CPM3 date stamping
  71. ;
  72. ;-----------------------------------------------------------------------
  73. ;
  74. ;    ASEG            ; Needed for M80 and RMAC, ignore error
  75. ;
  76.     ORG    0100H
  77. ;
  78.     JMP    START
  79. ;
  80. NO    EQU    0
  81. YES    EQU    NOT NO        ; (Some assemblers don't like 0FFh)
  82. ;
  83. ; Define version number
  84. ;
  85. MAIN    EQU    1        ; Main block number
  86. VER    EQU    38        ; Current version
  87. MONTH    EQU    02        ; Month
  88. DAY    EQU    01        ; Day
  89. YEAR    EQU    89        ; Year
  90. ;
  91. ;-----------------------------------------------------------------------
  92. ;                 options
  93. ;
  94. MAXDRV    EQU    NO        ; *Yes if MAXD byte is supported
  95. MAXUR    EQU    NO        ; *Yes if MAXU byte is supported
  96. WHEEL    EQU    NO        ; *Yes if using ZCPR wheel byte
  97.  
  98. ; If using equate ZCPR33 set to YES, then the following 3 will be
  99. ; taken from the ENV descriptor automaticaly if the corresponding
  100. ; MAXDRV, MAXUR, or WHEEL equate is set YES
  101. MXDRV    EQU    3DH        ; *Set to max drive address if MAXDRV=Yes
  102. MXUSR    EQU    3FH        ; *Set to max user  address if MAXUR=Yes
  103. WHLOC    EQU    3EH        ; *Set to wheel location if WHEEL=Yes
  104.  
  105. MXZUSR    EQU    15        ; Maximum user # allowed with WHEEL set
  106.  
  107. PRBRDR    EQU    NO        ; Yes = print quasi-borders for libraries
  108. WMBOOT    EQU    NO        ; If warmboot is needed on exit
  109. VLIST    EQU    YES        ; Yes for vertical alphabetization
  110. VSPAGE    EQU    YES        ; If Vertical sort is to be by page
  111.  
  112.     DB    'Z3ENV'        ; For ZCPR3 Environment ID
  113.     DB    1        ; Class 1, External
  114. Z3ENV:    DW    0        ; Environment Address.    If using ZCPR33
  115.                 ; This can be left as is.
  116. ;-------------------------------
  117. ;
  118. ; Drive/User area lookup table:
  119. ; ----------------------------
  120. ; Change the following table as appropriate for your version of CP/M.
  121. ; You can limit the maximum user area without wheel byte independently
  122. ; for any drive available.  Use 0FFh for drives that are not available.
  123. ;
  124. ;        CP/M  v2.2 has 16 user areas, 0-15
  125. ;        CP/M  v3.0 has 32 user areas, 0-31
  126. ;
  127. ; NOTE: Use your editor to move the "HIDRV" line below the correct
  128. ; number of drives for your system.  This not only saves time when the
  129. ; highest drive has been reached, but will display a drive/user error
  130. ; message which otherwise will not be shown.
  131. ;
  132. LODRV    EQU    $        ; Mark beginning of drive/user table
  133.  
  134.     DB    15        ; Maximum user area for drive A
  135.     DB    15        ; "      "    "    "    "     B
  136. HIDRV    EQU    $        ; Mark end of drive/user table
  137.     DB    0FFH        ; "      "    "    "    "     C
  138.     DB    0FFH        ; "      "    "    "    "     D
  139.     DB    0FFH        ; "      "    "    "    "     E
  140.     DB    0FFH        ; "      "    "    "    "     F
  141.     DB    0FFH        ; "      "    "    "    "     G
  142.     DB    0FFH        ; "      "    "    "    "     H
  143.     DB    0FFH        ; "      "    "    "    "     I
  144.     DB    0FFH        ; "      "    "    "    "     J
  145.     DB    0FFH        ; "      "    "    "    "     K
  146.     DB    0FFH        ; "      "    "    "    "     L
  147.     DB    0FFH        ; "      "    "    "    "     M
  148.     DB    0FFH        ; "      "    "    "    "     N
  149.     DB    0FFH        ; "      "    "    "    "     O
  150.     DB    0FFH        ; "      "    "    "    "     P
  151. ;
  152. ;-------------------------------
  153. ;
  154. ; Command line options:
  155. ; --------------------
  156. ; If any of the following equates are set NO, it prevents their use by
  157. ; any user (including the SYSOP) unless the wheel byte has been set for
  158. ; SYSOP use.  If running an RCPM, you may wish to say NO for those with
  159. ; an asterisk, such as USEF, USERO, USEP and USES to prevent others from
  160. ; using them - the wheel byte makes them available for SYSOP use.
  161. ;
  162. ; NOTE:  For RCPM use, all 5 would normally be set to "NO" to prevent
  163. ; remote use, but would be available to the Sysop with the WHEEL byte.
  164. ;
  165. USEF    EQU    YES        ; *Allow making a local disk copy?
  166. USEO    EQU    YES        ; *Allow showing only $SYS files?
  167. USEP    EQU    YES        ; *Allow making local printer listing?
  168. USER    EQU    YES        ; *Allow disk system reset?
  169. USES    EQU    YES        ; *Allow showing all, and $SYS files?
  170.  
  171. ; Above note goes for the following
  172. USEA    EQU    NO        ; *Allow specifying attributes 1-4?
  173.  
  174. ;
  175. ;-------------------------------
  176. ;
  177. ; Showing tagged attributes
  178. ; -------------------------
  179. ; Displaying files with tagged attributes ($R/O, $SYS, $ARC etc.) in an
  180. ; in an unique manner so they are easy to find, if present.
  181. ;
  182. ;    Example:
  183. ;        FILENAME.SyS    -  $SYS attribute set
  184. ;        FILENAME.doC    -  $SYS and $R/O both set
  185. ;        FILENAME.com    -  $SYS, $R/O and $ARC all set
  186. ;
  187. ; The following equates will permit SD to display the files with tagged
  188. ; attributes in lower case letters (a-z) as in example above.
  189. ;
  190. USELC    EQU    NO        ; Allow lower case letters (a-z)
  191. USELCW    EQU    NO        ; *Allow lower case without wheel byte?
  192. ;
  193. ;-----------------------------------------------------------------------
  194. ;
  195. ; Reverse video options
  196. ; ---------------------
  197. ; The following equate will permit SD to display the files with tagged
  198. ; attributes in either reverse video or bright/dim modes.  This will al-
  199. ; low any character tagged to be visible, as opposed to the USELD method.
  200. ; Up to 7 bytes for enter and exit video modes are provided.  These can
  201. ; be easily patched with DDT, etc.
  202. ;
  203. REVID    EQU    NO        ; Yes = inverse or bright/dim display
  204. ;
  205. ; The following equate will highlight/underline the summary line
  206. ;
  207. ULINE    EQU    NO        ; Yes = highlight/underline summary
  208. ;
  209. ;
  210. ; Reverse video control bytes
  211. ; ---------------------------
  212. ; If byte at RVON is 0, simple lower case will be used to display file
  213. ; attributes.
  214. ;
  215.      IF    REVID
  216. RVON:    DB    0,0,0,0,0,0,0    ; Up to 7 characters for ENTER REVERSE
  217.     DB    0        ; String Terminator MUST BE 0
  218. ;
  219. RVOFF:    DB    0,0,0,0,0,0,0    ; Up to 7 characters for EXIT REVERSE
  220.     DB    0        ; String Terminator MUST BE 0
  221.      ENDIF            ; REVID
  222. ;
  223. ; If byte at ULON is 0, no highlighting/underlining will be used in the
  224. ; banner line.
  225. ;
  226.      IF    ULINE
  227. ULON:    DB    0,0,0,0,0,0,0    ; Up to 7 characters for ENTER ULINE
  228.     DB    0        ; String Terminator, MUST BE 0
  229. ;
  230. ULOFF:    DB    0,0,0,0,0,0,0    ; Up to 7 characters for EXIT ULINE
  231.     DB    0        ; String Terminator MUST BE 0
  232.      ENDIF            ; ULINE
  233. ;
  234. ;-------------------------------
  235. ;
  236. ; Time/date options
  237. ; -----------------
  238. ; The following equate will get the TIMEON from BYE, if BYE is active.
  239. ; The message "Time on system is xx Minutes" will be displayed.
  240. ;
  241. TIMEON    EQU    NO        ; Yes, gets TIMEON from BYE5
  242. ;
  243. ; The following equate will permit the date to be displayed using the
  244. ; European system DD/MM/YY or the American system MM/DD/YY.  This only
  245. ; shows when using Z80DOS, CPM3 or 'V' to display version number.
  246. ;
  247. EDATE    EQU    NO        ; Yes = European, No = American
  248. ;
  249. ;-------------------------------
  250. ;
  251. ; If using Z80DOS and you want date stamping support, set to YES.
  252. ;
  253. Z80DOS    EQU    NO
  254. ;
  255. ;-------------------------------------
  256. ;
  257. ; If using CPM3 that supports DATE/TIME stamps & you want date stamping
  258. ; support, then set to YES
  259. ;
  260. CPM3    EQU    NO
  261. ;
  262. ; Set to YES if you want to have the date default to UPDATE else set
  263. ; to NO for CREATE/ACCESS default.
  264. ;
  265. UPDATE    EQU    YES        ; Default to update if YES else access/create
  266. ;
  267. ;-------------------------------
  268. ;
  269. ; If want to be able to specify files to be displayed based upon attribute
  270. ;    1 thru 4 , set the following to yes
  271. ;
  272. FATTRIB EQU    YES
  273. ;
  274. ;-------------------------------
  275. ;
  276. ; Z3CPR options
  277. ; -------------
  278. ; for ZCPR33 users - leave all set to NO if not using ZCPR3
  279. ;
  280. ZCPR33    EQU    NO        ; Allow named dir's and ENV support
  281. ZCPR3    EQU    NO        ; Allow named directory in command line
  282. NDIRS    EQU    NO        ; To display directory names
  283. SHOPUB    EQU    NO        ; To display ZRDOS Public Directories
  284. WHLPUB    EQU    NO        ; To make SHOPUB wheel dependent
  285. ZRDOS    EQU    NO        ; Set to yes if using ZRDOS
  286. Z3DRV    EQU    44        ; Offset from ENV location to find drive max
  287. Z3USR    EQU    45        ; Offset from ENV location to find user max
  288. Z3WHL    EQU    41        ; Offset from ENV location to find wheel address
  289. Z3NDR    EQU    21        ; Offset from ENV location to find NDIR address
  290. ;
  291. ;            end of options
  292. ;-----------------------------------------------------------------------
  293. ;
  294. ; Reference items
  295. ; ---------------
  296. RECORD    EQU    36
  297. FRN    EQU    33
  298. FCR    EQU    32
  299. READRN    EQU    33
  300. HDRSIZ    EQU    27
  301. ARCMAR    EQU    26
  302. SBCDE    EQU    52EDH        ; Z80's SBC HL,DE
  303. ZMOVE    EQU    0B0EDH        ; Z80's LDIR 
  304. TMPLT0    EQU    $        ; Start of initialization template
  305.  
  306.      IF    VLIST
  307.     DB    0
  308.      ENDIF            ; VLIST
  309.  
  310.      IF    NOT VLIST
  311.     DB    0FFH
  312.      ENDIF            ; NO VLIST
  313.  
  314.     DB    'A'        ; All-users option flag
  315.     DB    'C'        ; File size in records option
  316.     DB    'D'        ; Multi-disk option flag
  317.  
  318.      IF    USEF
  319.     DB    'F'        ; DISK.DIR file output option
  320.      ENDIF            ; USEF
  321.  
  322.      IF    NOT USEF
  323.     DB    'F'+80H
  324.      ENDIF            ; NOT USEF
  325.  
  326.     DB    'H'        ; Show areas from current to highest
  327.     DB    'L'        ; Display library members flag
  328.     DB    'N'        ; No page-pause option flag
  329.  
  330.      IF    USEO
  331.     DB    'O'        ; To show $SYS files only
  332.      ENDIF            ; USEO
  333.  
  334.      IF    NOT USEO
  335.     DB    'O'+80H
  336.      ENDIF            ; NOT USEO
  337.  
  338.      IF    USEP
  339.     DB    'P'        ; Printer output option
  340.      ENDIF            ; USEP
  341.  
  342.      IF    NOT USEP
  343.     DB    'P'+80H
  344.      ENDIF            ; NOT USEP
  345.  
  346.     DB    'Q'        ; To show only non-$ARC files
  347.  
  348.      IF    USER
  349.     DB    'R'        ; Optional reset of disk system
  350.      ENDIF            ; USER
  351.  
  352.      IF    NOT USER
  353.     DB    'R'+80H
  354.      ENDIF            ; NOT USER
  355.  
  356.      IF    USES
  357.     DB    'S'        ; Include $SYS files
  358.      ENDIF            ; USES
  359.  
  360.      IF    NOT USES
  361.     DB    'S'+80H
  362.      ENDIF            ; NOT USES
  363.  
  364.     DB    'T'        ; Primary sort by file type
  365.     DB    'V'        ; Show SD version
  366.     DB    'X'        ; Alternate alphabetization
  367.  
  368.      IF    Z80DOS OR CPM3
  369.     DB    '='        ; Look for exact match of date given
  370.     DB    '+'        ; Look for files of date GE date given
  371.     DB    '-'        ; Look for files of date LT date given
  372.      ENDIF            ; Z80DOS/CPM3
  373.  
  374.      IF    Z80DOS
  375.     DB    '!'        ; Match with creation date
  376.      ENDIF            ; Z80DOS
  377.  
  378.      IF    Z80DOS OR CPM3
  379.     DB    '%','%'        ; Match with alteration date
  380.     DB    '@'        ; Match with access date
  381.     DB    'Z'        ; Show dates
  382.      ENDIF            ; Z80DOS/CPM3
  383.  
  384. ;     IF    FATTRIB        ; Allow spec of file attributes 1-4?
  385.      IF    USEA AND FATTRIB
  386.     DB    '1'        ; Only files with attrib 1
  387.      ENDIF            ; USEA
  388.  
  389.      IF    NOT USEA AND FATTRIB
  390.     DB    80H+'1'
  391.      ENDIF            ; NOT USEA
  392.  
  393.      IF    USEA AND FATTRIB
  394.     DB    '2'        ; Only files woth attrib 2
  395.      ENDIF            ; USEA
  396.  
  397.      IF    NOT USEA AND FATTRIB
  398.     DB    80H+'2'
  399.      ENDIF            ; NOT USEA
  400.  
  401.      IF    USEA AND FATTRIB
  402.     DB    '3'        ; Only files with attrib 3
  403.      ENDIF            ; USEA
  404.  
  405.      IF    NOT USEA AND FATTRIB
  406.     DB    80H+'3'
  407.      ENDIF            ; NOT USEA
  408.  
  409.      IF    USEA AND FATTRIB
  410.     DB    '4'        ; Only files with attrib 4
  411.      ENDIF            ; USEA
  412.  
  413.      IF    NOT USEA AND FATTRIB
  414.     DB    80H+'4'
  415.      ENDIF            ; NOT USEA
  416.  
  417. ;     ENDIF        ;FATTRIB
  418. ;
  419. ; End of option lookup table
  420. ;
  421.     DW    OUTBUF        ; Next location in output buffer
  422.     DB    128        ; # of bytes left in output buffer
  423.     DB    0,'DISK    DIR'    ; Output Filename.typ
  424. ;
  425. TMPLT1    EQU    $        ; End of initialization data template
  426.  
  427. VERNAME:DB    13,10,'SDZD+',MAIN+'0'
  428.     DB    VER/10+'0',VER MOD 10+'0',' -- '
  429.  
  430.      IF    NOT EDATE
  431.     DB    MONTH/10+'0',MONTH MOD 10+'0','/'
  432.      ENDIF            ; NOT EDATE
  433.  
  434.     DB    DAY/10+'0',DAY MOD 10+'0','/'
  435.  
  436.      IF    EDATE
  437.     DB    MONTH/10+'0',MONTH MOD 10+'0','/'
  438.      ENDIF            ; EDATE
  439.  
  440.     DB    YEAR/10+'0',YEAR MOD 10+'0'
  441.  
  442.      IF    CPM3
  443.     DB    ', CP/M 3.0'
  444.      ENDIF
  445.  
  446.      IF    Z80DOS
  447.     DB    ', Z80DOS'
  448.      ENDIF
  449.  
  450.      IF    ZCPR3        ; 
  451.     DB    ', ZCPR3/ARC/ARK Version'
  452.      ENDIF            ; ZCPR3 
  453.  
  454.      IF    ZCPR33        ; 
  455.     DB    ', ZCPR33/ARC/ARK Version'
  456.      ENDIF            ; ZCPR33
  457.  
  458.     DB    0
  459. ;
  460. ;-----------------------------------------------------------------------
  461. ;             Program starts here
  462. ;-----------------------------------------------------------------------
  463. ;
  464. START:    LXI    H,0
  465.     DAD    SP        ; HL=old stack
  466.     SHLD    STACK        ; Save it
  467.     LXI    SP,STACK    ; Get new stack
  468.  
  469.      IF    ZCPR33
  470.     LHLD    Z3ENV        ; Get ENV address
  471.     PUSH    H
  472.     LXI    D,Z3DRV        ; Point to max drv byte
  473.     DAD    D
  474.     SHLD    Z3DRVL        ; Save location away
  475.     POP    H
  476.     PUSH    H
  477.     LXI    D,Z3USR        ; Point to maxuser byte
  478.     DAD    D
  479.     SHLD    Z3USRL        ; Save location away
  480.     POP    H
  481.     PUSH    H
  482.     LXI    D,Z3WHL        ; Point to address pointer of wheel
  483.     DAD    D
  484.     MOV    E,M        ; Get address of wheel byte
  485.     INX    H
  486.     MOV    D,M
  487.     XCHG
  488.     SHLD    Z3WHLL        ; Save it away
  489.     POP    H
  490.      ENDIF            ; ZCPR33
  491.  
  492.      IF    NDIRS
  493.     LHLD    Z3ENV        ; Get Environment Address
  494.     LXI    D,Z3NDR        ; Point to named directory space
  495.     DAD    D
  496.     MOV    E,M
  497.     INX    H
  498.     MOV    D,M        ; DE Now contains NDR Address
  499.     INX    H
  500.     MOV    A,M
  501.     ADI    1
  502.     STA    NUMDIR        ; Maximum number of entries plus 1
  503.     XCHG
  504.     SHLD    NAMADR        ; Keep Address for later
  505.      ENDIF            ; NDIRS
  506. ;
  507. ; Clear Public User Areas so they can be displayed
  508. ;
  509.      IF    SHOPUB
  510.     LHLD    0109H        ; Get Environment Address
  511.     MVI    D,0
  512.     MVI    E,07EH
  513.     DAD    D        ; HL Points to Public Drive Byte
  514.     MOV    A,M        ; Get public DRV byte
  515.     STA    PUBDRV
  516.     INX    H
  517.     MOV    A,M        ; Get public USR byte
  518.     STA    PUBUSR
  519.      ENDIF            ; SHOPUB
  520.  
  521. ;     IF    WHLPUB
  522.  
  523.      IF    ZCPR33 AND WHLPUB
  524.     PUSH    H
  525.     LHLD    Z3WHLL        ; Point to ENV
  526.     MOV    A,M        ; Get wheel
  527.     POP    H
  528.      ENDIF            ; ZCPR33
  529.  
  530.      IF    NOT ZCPR33 AND WHLPUB
  531.     LDA    WHLOC        ; Load wheel byte
  532.      ENDIF            ; NOT ZCPR33
  533.  
  534.      IF    WHLPUB
  535.     ORA    A
  536.     JZ    NOPUB
  537.      ENDIF            ; WHLPUB
  538.  
  539.      IF    SHOPUB
  540.     DCX    H
  541.     MVI    A,0        ; Clear Public Areas temporarily
  542.     MOV    M,A
  543.     INX    H
  544.     MOV    M,A
  545.      ENDIF            ; SHOPUB
  546.  
  547.      IF    WHLPUB AND SHOPUB
  548. NOPUB:    DS    0
  549.      ENDIF            ; WHLPUB
  550. ;
  551. ; (WHLPUB enabled, the R option is redundant)
  552. ;
  553. ;     ENDIF            ; SHOPUB
  554. ;
  555. ; See if help is wanted
  556. ;
  557.     LXI    H,FCB+1        ; Filename
  558.     MOV    A,M        ; 1st Character
  559.  
  560.      IF    NOT ZCPR33
  561.     CPI    '?'        ; Is it "?"
  562.     JNZ    INIT        ; No, Continue
  563.     INX    H        ; Yes, Next Char
  564.     MOV    A,M        ; 2nd Character
  565.     CPI    ' '        ; Is it " "
  566.     JNZ    INIT        ; If not, did not want help guide
  567.     LDA    FCB+9        ; Check for any extent
  568.     CPI    ' '
  569.     JZ    HELPME        ; If none, wanted help
  570.      ENDIF            ; NOT ZCPR33
  571.  
  572.      IF    ZCPR33
  573.     CPI    '?'        ; Is it "?"
  574.     JNZ    CHKSLH        ; No, Continue
  575.     INX    H        ; Yes, Next Char
  576.     MOV    A,M        ; 2nd Character
  577.     CPI    ' '        ; Is it " "
  578.     JNZ    INIT        ; If not, did not want help guide
  579.     LDA    FCB+9        ; Check for any extent
  580.     CPI    ' '
  581.     JZ    HELPME        ; If none, wanted help
  582.     JMP    INIT
  583. CHKSLH:    CPI    '/'        ; Is it a slash?
  584.     JNZ    INIT
  585.     INX    H
  586.     MOV    A,M        ; two slashes gets help
  587.     CPI    '/'
  588.     JZ    HELPME
  589.      ENDIF            ; ZCPR33
  590.  
  591. ;
  592. ; Zero out the entire initialization data area
  593. ;
  594. INIT:    LXI    H,DATA0        ; Point to start of initialized data area
  595.     PUSH    H        ; Save for non-zero filling later
  596.     MVI    C,DATA1-DATA0    ; Data area length
  597.     XRA    A        ; Clear the "A" register
  598.  
  599. ZFILL:    MOV    M,A        ; Null the address
  600.     INX    H        ; Pointer+1
  601.     DCR    C        ; One less to go
  602.     JNZ    ZFILL
  603.  
  604.      IF    SHOPUB        ; In order for the Public Directories
  605.     MVI    A,0FFH        ; To be displayed, Option 'R' must be
  606.     STA    ROPFLG        ; Forced true.
  607.      ENDIF            ; SHOPUB
  608. ;
  609. ; Now copy non-zero initialization data from the template area
  610. ;
  611.     POP    H        ; Load A(DATA0)
  612.  
  613.      IF    Z80DOS OR CPM3
  614.     XCHG
  615.     LXI    H,TMPLT0    ; Load A(TMPLT0)
  616.     LXI    B,TMPLT1-TMPLT0    ; Template area length
  617.     DW    ZMOVE        ; Z80's LDIR
  618.      ENDIF            ; Z80DOS/CPM3
  619.  
  620.      IF    NOT (Z80DOS OR CPM3)
  621.     LXI    D,TMPLT0    ; Load A(TMPLT0)
  622.     MVI    C,TMPLT1-TMPLT0    ; Template area length
  623. NZFILL:    LDAX    D        ; Load template byte
  624.     MOV    M,A        ; Move to data area
  625.     INX    D        ; Next location to store data
  626.     INX    H        ; Next location to get data
  627.     DCR    C        ; One less to go
  628.     JNZ    NZFILL
  629.      ENDIF            ; NOT Z80DOS/CPM3
  630.  
  631.     LXI    H,0        ; Clear HL
  632.  
  633.      IF    ZRDOS
  634.     MVI    C,ZRDVER    ; Get ZRDOS version
  635.     CALL    BDOS
  636.     MOV    A,L        ; ZRDOS Version #
  637.     STA    ZRDFLG        ; Save it
  638.      ENDIF            ; ZRDOS
  639.  
  640.     MVI    C,CPMVER    ; Get CP/M  version
  641.     CALL    BDOS
  642.     MOV    A,L        ; CP/M Version number
  643.     STA    VERFLG        ; Save it
  644.     STA    SOHFLG        ; Prevents initial unwanted CRLF
  645.     CPI    20H        ; Set carry if CP/M 1.4
  646.     PUSH    PSW        ; Save for BYE test
  647.     MVI    E,0FFH        ; Load current user number if CP/M 2
  648.     MVI    C,STUSER    ; Fall through with A=0 if not
  649.     CNC    CPM        ; Only if CP/M 2.0 or ZRDOS
  650.     STA    OLDUSR        ; Initial user number
  651.     STA    NEWUSR        ; New user = Initial user
  652.     STA    BASUSR        ; Directories
  653.     POP    PSW        ; Recover Version Flag
  654.     MVI    E,241        ; Special BYE5xx Call
  655.     MVI    C,STUSER    ; Returns 77 if BYE5xx active
  656.     CNC    CPM        ; BYE5nn not on CP/M 1.4 system
  657.     SUI    77        ; Return code expected
  658.     STA    BYEACT        ; BYEACT = 0, BYE5nn active
  659.  
  660.      IF    TIMEON
  661.     CALL    TIME
  662.      ENDIF            ; TIMEON
  663.  
  664.      IF    ZCPR3 OR ZCPR33
  665.     LDA    FCB+13        ; Point to command line buffer (CLB)
  666.     STA    NEWUSR
  667.      ENDIF            ; ZCPR3
  668.  
  669.      IF    NOT ZCPR3 AND NOT ZCPR33
  670.     LXI    H,TBUF+1    ; Point to command line buffer (CLB)
  671.     MOV    A,M        ; CLB Character
  672.     CPI    '['        ; CP/M 3.0 style delimiter
  673.     JZ    CLOK        ; (may follow command in CP/M 3.0)
  674.     INX    H        ; CLB pointer +1
  675.     ORA    A        ; Terminator?
  676.     JNZ    CLOK        ; No, continue
  677.     MOV    M,A        ; Yes, set 2nd terminator
  678.  
  679. CLOK:    LXI    D,FCB        ; A(file control block)
  680.     CALL    FNAME        ; Process filename.typ
  681.     MOV    A,B        ; Disk specification
  682.     CPI    0FFH        ; Current?
  683.     JZ    CLUS        ; Yes
  684.     STAX    D        ; No, set disk specification
  685.  
  686. CLUS:    MOV    A,C        ; User specification
  687.     CPI    0FFH        ; Current?
  688.     JZ    CLNON        ; Yes
  689.     STA    NEWUSR        ; No, set user specification
  690.     STA    BASUSR
  691.      ENDIF            ; NOT ZCPR3 AND NOT ZCPR33
  692.  
  693. CLNON:    MVI    C,CURDSK
  694.     CALL    CPM        ; Load current disk number
  695.     STA    OLDDSK        ; Save for reset if needed
  696.     INR    A        ; Adjust
  697.     STA    OUTFCB        ; Save directory file drive
  698.     LXI    H,FCB        ; A(file control block)
  699.     MOV    A,M        ; Load directory search drive
  700.     ORA    A        ; Any specified?
  701.     JNZ    START1        ; Yes, skip next routine
  702.     LDA    OLDDSK        ; Otherwise, get default disk
  703.     INR    A        ; Adjust
  704.     JMP    START2
  705.  
  706. START1:    PUSH    PSW        ; Save status
  707.     MVI    A,1
  708.     STA    DRVFLG        ; Set DRVFLG = 1
  709.     POP    PSW        ; Load status
  710.  
  711. START2:    MOV    M,A        ; Absolute drive code in directory FCB
  712. ;
  713. ; If at least one option is allowed,  scan command line for the option
  714. ; field delimiter. The option field delimiter is considered valid only
  715. ; if it is preceded by at least 1 space  (otherwise may be part of the
  716. ; directory filename).     Any unrecognized options/illegal user numbers
  717. ; will be flagged.(We scan the command line buffer rather than the 2nd
  718. ; default FCB because all 8 options + 2 digit user number will not fit
  719. ; in the 2nd FCB name field).
  720. ;
  721.     LXI    H,TBUF        ; CLB pointer
  722.     MOV    B,M        ; CLB length
  723. ;
  724. ; Search for valid command line delimiter, if not found, assume no
  725. ; options.  Show help menu if single "?" entered.
  726. ;
  727. SCNDOL:    INX    H        ; CLB PTR+1
  728.     DCR    B        ; CLB LEN-1
  729.     JM    DOPTN        ; Exit if command line buffer empty
  730.     MOV    A,M        ; CLB Character
  731.     CPI    '['        ; CPM+ style delimiter?
  732.     JZ    OPTDLM        ; Yes
  733.     CPI    '$'        ; CPM2 style delimiter?
  734.     JZ    SPB4        ; Yes
  735.     CPI    '/'        ; ZCPR style delimiter?
  736.     JNZ    SCNDOL        ; No
  737.  
  738. SPB4:    DCX    H        ; '$' found, space must precede
  739.     MOV    A,M        ; Previous character
  740.     INX    H
  741.     CPI    ' '
  742.     JNZ    SCNDOL        ; No space, ignore '$'
  743. ;
  744. ; Valid delimiter found.  Scan the rest of the buffer for options.
  745. ; Errors past this point cause an abort.
  746. ;
  747. OPTDLM:    XCHG            ; DE = CLB pointer (swap pointers)
  748.  
  749. SCNOPT:    INX    D        ; CLB PRT+1
  750.     DCR    B        ; CLB LEN-1
  751.     JM    DOPTN        ; If option field exhausted, exit
  752.  
  753. SCNAGN:    LDAX    D        ; Load option character
  754.     CPI    ' '        ; Is it " "?
  755.  
  756.      IF    Z80DOS OR CPM3
  757.     JZ    LOKDAT        ; Space, go look for date info
  758.      ENDIF            ; Z80DOS/CPM3
  759.  
  760.      IF    NOT (Z80DOS OR CPM3)
  761.     JZ    SCNOPT        ; Yes, Ignore it
  762.      ENDIF            ; NOT Z80DOS
  763.  
  764.     CPI    ']'        ; CPM+ style terminator?
  765.     JZ    SCNOPT        ; Options may follow terminator
  766.     LXI    H,OTBL-1    ; OTBL pointer
  767.     MVI    C,OEND-OTBL+1    ; OTLB length
  768.  
  769. NOMACH:    INX    H        ; OTLB pointer+1
  770.     DCR    C        ; OTLB length-1
  771.     JZ    CLERR        ; Error if option table end
  772.  
  773.      IF    WHEEL        ; ZCMD/ZCPR2/ZCPR3?
  774.     PUSH    PSW        ; Save "A" value
  775.      ENDIF            ; WHEEL
  776.  
  777.      IF    ZCPR33 AND WHEEL
  778.     PUSH    H
  779.     LHLD    Z3WHLL        ; Point to ENV
  780.     MOV    A,M        ; Get wheel
  781.     POP    H
  782.      ENDIF            ; ZCPR33
  783.  
  784.      IF    NOT ZCPR33 AND WHEEL
  785.     LDA    WHLOC        ; Load wheel byte
  786.      ENDIF            ; NOT ZCPR33
  787.  
  788.      IF    WHEEL
  789.     ORA    A        ; Set Flags
  790.     JZ    NOMAC1        ; Not set, so forget it
  791.     MOV    A,M        ; Load the table option
  792.      ENDIF            ; WHEEL
  793.  
  794.      IF    FATTRIB AND WHEEL
  795.     ANI    7FH
  796.      ENDIF            ; FATTRIB
  797.  
  798.      IF    NOT (FATTRIB AND WHEEL) AND (NOT CPM3)
  799.     ANI    5FH        ; Allow the option
  800.      ENDIF            ; NOT FATTRIB
  801.  
  802.      IF    WHEEL
  803.     MOV    M,A        ; Stuff back in table
  804.  
  805. NOMAC1:    POP    PSW        ; Restore "A" value
  806.      ENDIF            ; WHEEL
  807.  
  808.     CMP    M        ; Compare with table entry
  809.     JNZ    NOMACH        ; If no match, check next
  810.     MVI    M,0        ; Else, activate the option
  811.     JMP    SCNOPT        ; Continue scan
  812. ;.....
  813. ;
  814. ; Playback the command line up to the character that stopped the scan
  815. ; and exit
  816. ;
  817. CLERR:    XRA    A        ; Clear "A" register
  818.     INX    D        ; Tag end of CLB
  819.     STAX    D        ; With terminator
  820.     CALL    CRLF        ; New line
  821.     LXI    D,ERRMS2    ; 'Error'
  822.     CALL    PUTS
  823.     LXI    D,ERRTAG    ; '->'
  824.     CALL    PUTS
  825.     LXI    H,TBUF+1    ; Playback CLB to error point
  826.  
  827. CLELP:    MOV    A,M        ; Character
  828.     ORA    A        ; Zero?
  829.     JZ    CLEX        ; Yes, exit
  830.     CALL    PUTCHR        ; No, output to console
  831.     INX    H        ; CLB pointer+1
  832.     JMP    CLELP        ; Continue
  833.  
  834. CLEX:    MVI    A,'?'        ; Tag line with a '?' field
  835.     CALL    PUTCHR
  836.     CALL    CRLF        ; New Line
  837.  
  838.      IF    SHOPUB
  839.     CALL    RSTPUB
  840.      ENDIF            ; SHOPUB
  841.  
  842. ;;;;;    RST    0        ; And reset CCP, all finished
  843.     JMP    EXIT2
  844.  
  845.      IF    Z80DOS OR CPM3
  846. LOKDAT:    INX    D
  847.     LDAX    D        ; Check to see if * was entered meaning
  848.     CPI    '*'        ; use current system time
  849.     JNZ    LOKDAT1        ; NZ=no
  850.     CALL    SYSTIM        ; Get the current system time
  851.     JMP    LOKDAT2        ; And continue
  852.  
  853. LOKDAT1:CALL    EVAL10        ; convert month to binary
  854.  
  855.      IF    (Z80DOS OR CPM3) AND NOT EDATE
  856.     ORA    A        ; month can't be 0
  857.     JZ    BADDATE
  858.     CPI    13        ; can't be >12
  859.     JNC    BADDATE
  860.     STA    MONTHS        ; store month
  861.     LDAX    D        ; End of input line?
  862.     ORA    A
  863.     JZ    BADDATE        ; Z=yes, a no-no
  864.     INX    D        ; Skip /
  865.     CALL    EVAL10        ; convert
  866.     ORA    A        ; day can't be 0
  867.     JZ    BADDATE
  868.     CPI    32        ; or >31
  869.     JNC    BADDATE
  870.     STA    DAYS1        ; store day
  871.     LDAX    D        ; End of input line?
  872.     ORA    A
  873.     JZ    BADDATE        ; Z=yes, a no-no
  874.      ENDIF            ; Z80DOS/CPM3
  875.  
  876.      IF    (Z80DOS OR CPM3) AND EDATE
  877.     ORA    A        ; day can't be 0
  878.     JZ    BADDATE
  879.     CPI    32        ; or >31
  880.     JNC    BADDATE
  881.     STA    DAYS1        ; store day
  882.     LDAX    D        ; End of input line?
  883.     ORA    A
  884.     JZ    BADDATE        ; Z=yes, a no-no
  885.     INX    D        ; Skip /
  886.     CALL    EVAL10        ; convert
  887.     ORA    A
  888.     JZ    BADDATE        ; month can' be 0
  889.     CPI    13        ; can't be >12
  890.     JNC    BADDATE
  891.     STA    MONTHS        ; store month
  892.      ENDIF            ; Z80DOS/CPM3
  893.  
  894.     INX    D        ; Skip /
  895.     CALL    EVAL10
  896.     STA    YEARS1        ; store year
  897.     PUSH    D
  898.     LXI    H,YEARS1    ; pt at date
  899.     CALL    BIN2JUL        ; get jul date in hl
  900.     POP    D
  901.  
  902. LOKDAT2:CALL    DOPLMI        ; Process any + or - operators
  903.     SHLD    DATCHK
  904.     LDAX    D
  905.     CPI    ' '        ; Next char a space?
  906.     JNZ    DOPTN        ; NZ=no, continue
  907. ;    LHLD    DATCH1
  908. ;    MOV    A,H
  909. ;    ORA    L
  910. ;    JZ    CLERR
  911.     LHLD    DATCHK        ; set last input date=first input date
  912.     SHLD    DATCH1
  913.     JMP    LOKDAT        ; And go try to get some more dates
  914.  
  915. SYSTIM:    PUSH    D        ; Save pointer to input line
  916.     LXI    D,ASCII        ; Tell Z80DOS/CPM3 to put time here
  917.     MVI    C,105
  918.     CALL    BDOS        ; Go get the time
  919.     LXI    D,ASCII
  920.     LDAX    D        ; Get LSB of JDAY
  921.     MOV    L,A
  922.     INX    D
  923.     LDAX    D        ; Get MSB of JDAY
  924.     MOV    H,A
  925.     POP    D        ; Get input pointer back
  926.     INX    D        ; Point ot next
  927. DOPLMI:    LDAX    D
  928.     CPI    '-'        ; Does operator want a subtraction?
  929.     JZ    SUBDAT
  930.     CPI    '+'        ; an add?
  931.     RNZ            ; NZ=no
  932.     MVI    A,1
  933.     STA    DATPLS
  934.     JMP    OPDAT
  935. SUBDAT:    XRA    A
  936.     STA    DATPLS
  937. OPDAT:    INX    D
  938.     CALL    EVAL10        ; Yes go get number
  939.     PUSH    D
  940.     MOV    E,A
  941.     XRA    A
  942.     MOV    D,A
  943.     LDA    DATPLS        ; Chec if adding
  944.     ORA    A
  945.     JNZ    DTIPLS        ; NZ=yes
  946.     MOV    A,L
  947.     SBB    E
  948.     MOV    L,A
  949.     MOV    A,H
  950.     SBB    D
  951.     MOV    H,A
  952.     POP    D
  953.     RET
  954.  
  955. DTIPLS:    DAD    D
  956.     POP    D
  957.     RET
  958.  
  959. EVAL10:    XRA    A
  960.     MOV    B,A        ; B holds current number input
  961. EVAL1:    LDAX    D        ; Get input
  962.     CPI    '/'        ; / is seperator
  963.     JZ    DEVAL10        ; Z= done
  964.     CPI    ' '
  965.     JZ    DEVAL10
  966.     CPI    '+'
  967.     JZ    DEVAL10
  968.     CPI    '-'
  969.     JZ    DEVAL10
  970.     ORA    A
  971.     JZ    DEVAL10        ; Z= at end of line
  972.     SUI    '0'        ; Verify ascii 0-9
  973.     JC    BADDATE
  974.     CPI    10
  975.     JNC    BADDATE
  976.     INX    D
  977.     MOV    C,A        ; Old*10+new
  978.     MOV    A,B
  979.     ADD    A
  980.     ADD    A
  981.     ADD    B
  982.     ADD    A
  983.     ADD    C
  984.     MOV    B,A        ; B has current
  985.     JMP    EVAL1
  986.  
  987. DEVAL10:MOV    A,B
  988.     RET
  989.  
  990. BADDATE:PUSH    D
  991.     LXI    D,BDTMES
  992.     CALL    PUTS
  993.     POP    D
  994.     JMP    CLERR
  995.  
  996. BDTMES:    DB    13,10,13,10
  997.  
  998.      IF    (Z80DOS OR CPM3) AND NOT EDATE
  999.     DB    ' *** Illegal Date Entered, form MM/DD/YY or MM/D/YY or M/DD/YY'
  1000.      ENDIF
  1001.  
  1002.      IF    (Z80DOS OR CPM3) AND EDATE
  1003.     DB    ' *** Illegal Date Entered, form DD/MM/YY or D/MM/YY or DD/M/YY'
  1004.      ENDIF
  1005.  
  1006.     DB    13,10,13,10,0
  1007. ;
  1008. ;    Binary to Julian Date routine.
  1009. ;
  1010. ; >>    hl -> yr,mo,da in bin
  1011. ; <<     hl = Julian date
  1012. ;
  1013. ;    Convert to 8080 code from the original BCD2JUL
  1014. ;
  1015. ;    by Bridger Mitchel and Howard Goldstein - 4/16/88
  1016. ;
  1017. BIN2JUL:PUSH    PSW
  1018.     PUSH    B
  1019.     PUSH    D
  1020.     MOV    A,M        ; A=yr
  1021.     INX    H
  1022.     MOV    C,M        ; C = mo
  1023.     INX    H
  1024.     PUSH    H        ; Save ptr to day
  1025.     PUSH    PSW        ; Save year
  1026. ;
  1027. ; set hl= initial julian value of 77/12/31 or if CPM3 78/1/1
  1028. ;
  1029.     LXI    H,0
  1030.     SUI    78
  1031.     JZ    B2JUL3
  1032.     JNC    B2JUL0
  1033.     ADI    100        ; <78, assume next century
  1034. B2JUL0:    MOV    B,A        ; B = # yrs > 78
  1035.     MVI    A,1        ; Init modulo 4 counter
  1036.     LXI    D,365        ; Days/yr
  1037. B2JUL1:    DAD    D        ; Calc julian val. of  (yr/01/01 - 1)
  1038.     INR    A
  1039.     ANI    3        ; Every 4 yrs,
  1040.     JNZ    B2JUL2
  1041.     INX    H        ; ..add 1 for leap year
  1042. B2JUL2:    DCR    B
  1043.     JNZ    B2JUL1
  1044. ;
  1045. ;     hl now = # days in years before current year
  1046. ;
  1047. B2JUL3:    POP    PSW
  1048.     ANI    3        ; If current yr == leap year
  1049.     JNZ    B2JUL5
  1050.     MOV    A,C
  1051.     CPI    3        ; ..and mo >= march
  1052.     JC    B2JUL5
  1053.     INX    H        ; ..add the extra day (Feb 29)
  1054. ;
  1055. B2JUL5:    MOV    B,C        ; b = month = # months +1 to sum
  1056.     LXI    D,DPERMO    ; Point at table
  1057.     JMP    B2JUL7
  1058. ;
  1059. B2JUL6:    CALL    ADDHL        ; Add # days in this month
  1060.     INX    D        ; Bump tbl ptr
  1061. B2JUL7:    DCR    B
  1062.     JNZ    B2JUL6
  1063. ;
  1064.     POP    D        ; Ptr to day
  1065.     CALL    ADDHL
  1066.     POP    D
  1067.     POP    B
  1068.     POP    PSW
  1069.     RET
  1070.  
  1071. ADDHL:    LDAX    D        ; Add day of current month
  1072. ;
  1073. ADDA2HL:ADD    L
  1074.     MOV    L,A
  1075.     RNC
  1076.     INR    H
  1077.     RET
  1078. ;
  1079. ; table of days per month (non-leap year)
  1080. ;
  1081. DPERMO:    DB    31        ; Jan
  1082.     DB    28        ; Feb
  1083.     DB    31        ; Mar
  1084.     DB    30        ; Apr
  1085.     DB    31        ; May
  1086.     DB    30        ; Jun
  1087.     DB    31        ; Jul
  1088.     DB    31        ; Aug
  1089.     DB    30        ; Sep
  1090.     DB    31        ; Oct
  1091.     DB    30        ; Nov
  1092.     DB    31        ; Dec
  1093.      ENDIF            ; Z80DOS/CPM3
  1094. ;.....
  1095. ;
  1096. ; Options input or not specified, and associated flags set.
  1097. ;
  1098. ; If D-option, swap error vectors, then start at drive A if no
  1099. ; drive specified on command line.
  1100. ;
  1101. DOPTN:
  1102.      IF    Z80DOS OR CPM3
  1103.     LHLD    DATCH1
  1104.     MOV    A,H
  1105.     ORA    L
  1106.     JZ    DOPTN1
  1107.     XCHG
  1108.     LHLD    DATCHK
  1109.     ORA    A
  1110.     DW    SBCDE
  1111.     JZ    CLERR
  1112.     JNC    DOPTN1
  1113.     LHLD    DATCHK
  1114.     SHLD    DATCH1
  1115.     XCHG
  1116.     SHLD    DATCHK
  1117. DOPTN1:
  1118.      ENDIF            ; Z80DOS/CPM3
  1119.  
  1120.     LDA    DOPFLG        ; If multi-disk flag set,
  1121.     ORA    A        ; Need to set error traps
  1122.     JNZ    AOPTN        ; If not, go check A-option
  1123.     CALL    SWAPEM        ; Swap BDOS error vector tables
  1124.     LDA    DRVFLG        ; Directory drive specified?
  1125.     ORA    A
  1126.     JNZ    AOPTN        ; No, don't reset
  1127.     MVI    A,1        ; Yes, Set FCB to A:
  1128.     STA    FCB
  1129. ;
  1130. ; Start user at 0 if A-option selected without U-option
  1131. ;
  1132. AOPTN:    LDA    AOPFLG        ; Check All-users option
  1133.     ORA    A
  1134.     JNZ    COPTN        ; Jump if not
  1135.     LDA    HOPFLG        ; Asking to show all from current?
  1136.     ORA    A
  1137.     JZ    COPTN        ; If yes, do not reset "A" to zero
  1138.     XRA    A        ; No, Start at user 0
  1139.     STA    NEWUSR
  1140.     STA    BASUSR
  1141. ;
  1142. ; Test if C-option and set indicator character 'r', else 'k'
  1143. ;
  1144. COPTN:    LDA    COPFLG        ; File sizes wanted in records?
  1145.     ORA    A
  1146.     MVI    A,'k'
  1147.     JNZ    COPTN1        ; Jump if not
  1148.     MVI    A,'r'
  1149.  
  1150. COPTN1:    STA    FSIZEC        ; Indicator char after size
  1151. ;
  1152. ; Determine whether horizontal or vertical alphabetization.
  1153. ; If X-option selected, use alternate format.
  1154. ; Set flag and fence character accordingly.
  1155. ;
  1156.     LDA    XOPFLG        ; Check for X option
  1157.     ORA    A
  1158.     LDA    VFLAG        ; Get vertical flag
  1159.     JNZ    XOPTN1        ; Jump if no X option
  1160.     CMA            ; Else swap vertical/horizontal indicator
  1161.     STA    VFLAG        ; And change VFLAG other way
  1162.  
  1163. XOPTN1:    DS    0
  1164. ;
  1165. ; The following optionally resets the disk system.  The reset must
  1166. ; be done OUTSIDE of the multiple drive loop if the $F option is
  1167. ; enabled because CP/M 1.4 will clobber the DMA buffer on reset.
  1168. ;
  1169.     LDA    ROPFLG        ; Reset Disk?
  1170.     ORA    A
  1171.     JNZ    NOOPT
  1172. ;
  1173. ; Disk reset if R option entered on command line
  1174. ;
  1175.     MVI    C,RESET
  1176.     CALL    CPM
  1177. ;
  1178. ; Validate drive code and user area numbers from the drive table
  1179. ;
  1180. NOOPT:    LXI    D,DRUMSG    ; Get drive/user error message
  1181.     PUSH    D
  1182.     LDA    FCB        ; Get directory drive code
  1183.     DCR    A        ; Normalize to range of 0-31
  1184.     CPI    HIDRV-LODRV    ; Compare with max drives on-line
  1185.     JNC    ERXIT        ; Drive error exit if out of range
  1186.  
  1187. ;     IF    MAXDRV        ; Look for MXDRV
  1188.  
  1189.      IF    ZCPR33 AND MAXDRV
  1190.     LHLD    Z3DRVL        ; Point to ENV as loaded
  1191.      ENDIF            ; ZCPR33
  1192.  
  1193.      IF    NOT ZCPR33 AND MAXDRV
  1194.     LXI    H,MXDRV        ; A(MXDRV) to HL
  1195.      ENDIF            ; NOT ZCPR33
  1196.  
  1197.      IF    MAXDRV
  1198.     MOV    L,M        ; (MXDRV) to L
  1199.      ENDIF            ; MAXDRV
  1200.  
  1201. ;     IF    MAXDRV
  1202.  
  1203.      IF    NOT ZCPR33 AND MAXDRV
  1204.     INX    H        ; +1
  1205.      ENDIF            ; NOT ZCPR33
  1206.  
  1207.      IF    MAXDRV
  1208.     CMP    L        ; Check it
  1209.     JNC    ERXIT        ; Oops if not bigger
  1210.      ENDIF            ; MAXDRV
  1211. ;
  1212. ; Skips any drives marked 0FFh, some computers do not have contiguous
  1213. ; drives, such as Heath H89, etc.
  1214. ;
  1215.     MOV    E,A        ; Drive code = table index
  1216.     MVI    D,0
  1217.     LXI    H,LODRV        ; DUTBL Pointer
  1218.     DAD    D        ; DUTBL Pointer+INDEX
  1219.     MOV    A,M        ; User Number
  1220.     ORA    A        ; Set Status
  1221.     JM    NDSK        ; If negative, ignore drive
  1222.  
  1223. ;     IF    WHEEL
  1224.  
  1225.      IF    ZCPR33 AND WHEEL
  1226.     PUSH    H
  1227.     LHLD    Z3WHLL        ; Point to enviorment
  1228.     MOV    A,M        ; Get it
  1229.     POP    H
  1230.      ENDIF            ; ZCPR33
  1231.  
  1232.      IF    NOT ZCPR33 AND WHEEL
  1233.     LDA    WHLOC        ; Get wheel byte
  1234.      ENDIF            ; NOT ZCPR33
  1235.  
  1236.      IF    WHEEL
  1237.     ORA    A        ; Check it
  1238.     JZ    USRCK        ; If reset, restrict user
  1239.     MVI    A,MXZUSR    ; If set, max user = MXZUSR
  1240.     JMP    USRCK1
  1241.      ENDIF            ; WHEEL
  1242.  
  1243. USRCK:    LXI    H,LODRV        ; DUTBL PTR
  1244.     DAD    D        ; DUTLB PTR+INDEX
  1245.     MOV    A,M        ; Load max user for this drive
  1246.  
  1247.      IF    MAXUR        ; Use low memory values if smaller
  1248.     MOV    H,A        ; Current value of MAXUSR
  1249.      ENDIF            ; MAXUR
  1250.  
  1251.      IF    ZCPR33 AND MAXUR
  1252.     PUSH    H
  1253.     LHLD    Z3USRL        ; Point to ENV
  1254.     MOV    A,M        ; Get user
  1255.     POP    H
  1256.      ENDIF            ; ZCPR33
  1257.  
  1258.      IF    NOT ZCPR33 AND MAXUR
  1259.     LDA    MXUSR        ; Alternate value
  1260.      ENDIF            ; NOT ZCPR33
  1261.  
  1262. ;     ENDIF            ; MAXUR
  1263.  
  1264.      IF    ( MAXUR AND NOT ZCPR3 ) AND NOT ZCPR33
  1265.     SBI    1        ; MAXUSR is really maximum user+1
  1266.      ENDIF            ; MAXUR AND NOT ZCPR3 AND NOT ZCPR33
  1267.  
  1268.      IF    MAXUR
  1269.     CMP    H        ; Compare the two
  1270.     JNC    USRCK1        ; OK if MAXU <= table value
  1271.     STA    MAXUSR        ; Else replace it
  1272.      ENDIF            ; MAXUR
  1273.  
  1274. USRCK1:    MOV    B,A        ; Save max user for later testing
  1275.     ANI    1FH        ; Insure in range 0-31
  1276.     STA    MAXUSR        ; Save it for later
  1277.     LXI    H,NEWUSR    ; Point to directory user area
  1278.     CMP    M        ; Compare with the maximum
  1279.     JC    ERXIT        ; User number illegal, error exit
  1280.     POP    D        ; Destroy error message pointer
  1281.     MOV    A,B        ; Check to see if this drive
  1282.     ORA    A        ; Has been mapped out
  1283.     JM    NDSK        ; Yes, skip this drive
  1284.     LXI    H,FCB+1        ; No, point to name
  1285.     MOV    A,M        ; Any name specified?
  1286.     CPI    '$'        ; Delimiter?
  1287.     JZ    WCD        ; Yes, All files
  1288.     CPI    '/'        ; Unix/ZCPR3 delimiter?
  1289.     JZ    WCD        ; Yes, All files
  1290.     CPI    '['        ; CP/M+ delimiter?
  1291.     JZ    WCD
  1292.     CPI    ' '        ; No, Filename specified
  1293.     JNZ    GOTFCB
  1294. ;
  1295. ; No FCB - make FCB all '?'
  1296. ;
  1297. WCD:    MVI    B,11        ; Filename+typ length
  1298.  
  1299. QLOOP:    MVI    M,'?'        ; Store "?" in FCB
  1300.     INX    H        ; FCB pointer+1
  1301.     DCR    B        ; FCB length-1
  1302.     JNZ    QLOOP        ; Continue
  1303.  
  1304. GOTFCB:    MVI    A,'?'        ; Force wild extent
  1305.     STA    FCB+12
  1306.     CALL    SETSRC        ; Set DMA for BDOS media change check
  1307.     LXI    H,FCB        ; Point to FCB drive code for directory
  1308.     MOV    E,M        ; Load drive code from FCB
  1309.     DCR    E        ; Normalize drive code for select
  1310.     MVI    C,SELDSK    ; Select directory drive to retrieve
  1311.     CALL    CPM        ; The proper allocation vector
  1312.     CALL    CKVER        ; Check version
  1313.     JC    V14        ; Pre-2.x...get parameters the 1.4 way
  1314.     MVI    C,DSKPAR    ; If 2.2 or MP/M...request DPB
  1315.     CALL    BDOS
  1316.     INX    H
  1317.     INX    H
  1318.     MOV    A,M        ; Load block shift
  1319.     STA    BLKSHF        ; Block Shift
  1320.     INX    H        ; Bump to block mask
  1321.     MOV    A,M        ; Load block mask
  1322.     STA    BLKMSK        ; Block Mask
  1323.     INX    H
  1324.     INX    H
  1325.     MOV    E,M        ; Get maximum block #
  1326.     INX    H
  1327.     MOV    D,M
  1328.     XCHG
  1329.     SHLD    BLKMAX        ; Maximum Block #
  1330.     XCHG
  1331.     INX    H
  1332.     MOV    E,M        ; Load directory size
  1333.     INX    H
  1334.     MOV    D,M
  1335.     XCHG
  1336.     JMP    FREE
  1337.  
  1338. V14:    LHLD    BDOS+1        ; Get parameters 1.4 style
  1339.     MVI    L,3BH        ; Point to directory size
  1340.     MOV    E,M        ; Get it
  1341.     MVI    D,0        ; Force high order to 0
  1342.     PUSH    D        ; Save for later
  1343.     INX    H        ; Point to block shift
  1344.     MOV    A,M        ; Fetch
  1345.     STA    BLKSHF        ; Save
  1346.     INX    H        ; Point to block mask
  1347.     MOV    A,M        ; Fetch it
  1348.     STA    BLKMSK        ; And save it
  1349.     INX    H
  1350.     MOV    E,M        ; Get maximum block #
  1351.     MVI    D,0
  1352.     XCHG
  1353.     SHLD    BLKMAX        ; Save it
  1354.     POP    H        ; Restore directory size
  1355.     JMP    FREE20        ; Calculate free space from alloc vector
  1356. ;
  1357. ; Calculate number of K free on selected drive now so the FREE figure
  1358. ; will not reflect either creation or additions to the DISK.DIR file.
  1359. ; Note: This routine will not always function correctly as coded.  To
  1360. ; insure the proper calculation when the $F option is specified and
  1361. ; cataloging multiple disks on a single drive, you should do a CTL-C
  1362. ; AFTER the disk to be cataloged has been readied.
  1363. ;
  1364. FREE:    SHLD    DIRMAX        ; Save max number of directory entries
  1365.     LDA    VERFLG        ; Check version number
  1366.     CPI    30H        ; CP/M 3.0?
  1367.     JC    FREE20        ; No, Use old method
  1368.     LDA    FCB        ; Load drive number
  1369.     DCR    A        ; Normalize
  1370.     MOV    E,A        ; Use compute free space BDOS call
  1371.     MVI    C,46        ; Calculate free space
  1372.     CALL    CPM
  1373.     MVI    C,3        ; Answer is a 24-bit integer
  1374.  
  1375. FRE3L1:    LXI    H,TBUF+2    ; Answer in 1st 3 bytes of TBUF
  1376.     MVI    B,3        ; Convert from records to k
  1377.     ORA    A        ; By dividing by 8
  1378.  
  1379. FRE3L2:    MOV    A,M        ; LS byte record count
  1380.     RAR            ; /2
  1381.     MOV    M,A        ; Replace
  1382.     DCX    H        ; Next byte record count
  1383.     DCR    B        ; 
  1384.     JNZ    FRE3L2        ; Loop for 3 bytes
  1385.     DCR    C
  1386.     JNZ    FRE3L1        ; Shift 3 times
  1387.     LHLD    TBUF        ; Now get result in k
  1388.     JMP    SAVFRE        ; Save Free Space
  1389.  
  1390. FREE20:    MVI    C,DSKALL    ; Allocation vector address
  1391.     CALL    BDOS
  1392.     XCHG
  1393.     LHLD    BLKMAX        ; Max Block Number
  1394.     INX    H
  1395.     LXI    B,0        ; Init block count = 0
  1396.  
  1397. GSPBYT:    PUSH    D        ; Save allocation address
  1398.     LDAX    D
  1399.     MVI    E,8        ; Set to process 8 blocks
  1400.  
  1401. GSPLUP:    RAL            ; Test bit
  1402.     JC    NOTFRE
  1403.     INX    B
  1404.  
  1405. NOTFRE:    MOV    D,A        ; Save bits
  1406.     DCX    H        ; Count down blocks
  1407.     MOV    A,L
  1408.     ORA    H
  1409.     JZ    ENDALC        ; Quit if out of blocks
  1410.     MOV    A,D        ; Restore bits
  1411.     DCR    E        ; Count down 8 bits
  1412.     JNZ    GSPLUP        ; Do another bit
  1413.     POP    D        ; Bump to next byte of allocation vector
  1414.     INX    D
  1415.     JMP    GSPBYT        ; Process it
  1416.  
  1417. ENDALC:    POP    D        ; Clear stack of allocation vector pointer
  1418.     MOV    L,C        ; Copy blocks to HL
  1419.     MOV    H,B
  1420.     LDA    BLKSHF        ; Load block shift factor
  1421.     SUI    3        ; Convert from records to k
  1422.     JZ    SAVFRE        ; Skip shifts if 1k blocks return free in HL
  1423.  
  1424. FREKLP:    DAD    H        ; Multiply blocks by k/block
  1425.     DCR    A
  1426.     JNZ    FREKLP
  1427. ;
  1428. SAVFRE:    SHLD    FREEBY        ; Save free space for output later
  1429.     XCHG
  1430.     LHLD    TOTFRE
  1431.     DAD    D
  1432.     SHLD    TOTFRE
  1433. ;
  1434. ; Reenter here on subsequent passes while in the all-users mode
  1435. ;
  1436. SETTBL:    LHLD    DIRMAX        ; Load directory maximum size
  1437.     INX    H        ; Directory size is DIRMAX+1
  1438.     DAD    H        ; Double directory size
  1439.     LXI    D,ORDER        ; Too get order table size
  1440.     DAD    D        ; Allocate order table
  1441.     SHLD    TBLOC        ; Name tbl begins where order tbl ends
  1442.     SHLD    NEXTT
  1443.     XCHG
  1444.     LHLD    BDOS+1        ; Insure we have room to continue
  1445.     MOV    A,E
  1446.     SUB    L
  1447.     MOV    A,D
  1448.     SBB    H
  1449.     JNC    OUTMEM
  1450.     CALL    CKVER        ; Set carry if pre-CP/M 2
  1451.     LDA    NEWUSR        ; Load directory user area
  1452.     MOV    E,A
  1453.     MVI    C,STUSER    ; Get the user function
  1454.     CNC    CPM        ; Set new user number if CP/M 2
  1455. ;
  1456. ; Look up the FCB in the directory
  1457. ;
  1458.     MVI    A,'?'        ; Check for wild FCB extent
  1459.     LXI    H,FCB+12
  1460.     MOV    M,A        ; Match all extents
  1461.     INX    H
  1462.     MOV    M,A        ; Match all S1 bytes
  1463.     INX    H
  1464.     MOV    M,A        ; Match all S2 bytes
  1465.     LXI    H,0
  1466.     SHLD    COUNT        ; Initialize match counter
  1467.     SHLD    TOTFIL        ; "  total file counter
  1468.     SHLD    TOTSIZ        ; "  total size counter
  1469.     CALL    SETSRC        ; Set DMA for directory search
  1470.     MVI    C,SRCHF        ; Load 'search first' function
  1471.     JMP    LOOK        ; Go search for 1st match
  1472. ;
  1473. ; Read more directory entries
  1474. ;
  1475. MORDIR:    MVI    C,SRCHN        ; Search next function
  1476.  
  1477. LOOK:    LXI    D,FCB        ; A(file control block)
  1478.     CALL    CPM        ; Read directory entry
  1479.     INR    A        ; End (0FFH)?
  1480.     JZ    SPRINT        ; Yes, sort & print what we have
  1481. ;
  1482. ; Point to directory entry
  1483. ;
  1484.     DCR    A        ; Undo previous INC A
  1485.     ANI    3        ; Make modulus 4
  1486.     ADD    A        ; Multiply
  1487.     ADD    A        ; By 32 because
  1488.     ADD    A        ; Each directory
  1489.     ADD    A        ; Entry is 32
  1490.     ADD    A        ; Bytes long
  1491.     LXI    H,TBUF+1    ; Point to buffer (skip to FN/FT)
  1492.     ADD    L        ; Point to entry
  1493.  
  1494.      IF    FATTRIB
  1495.     MOV    L,A        ; HL now point to file name
  1496.     LDA    ONEFLG        ; Looking for only attribute 1?
  1497.     ORA    A
  1498.     JNZ    NOTONE        ; NZ=no
  1499.     MOV    A,M
  1500.     ORA    A
  1501.     JP    MORDIR        ; P=not attr 1
  1502. NOTONE:    INX    H
  1503.     LDA    TWOFLG        ; Only attribute 2?
  1504.     ORA    A
  1505.     JNZ    NOTTWO        ; NZ=no
  1506.     MOV    A,M
  1507.     ORA    A
  1508.     JP    MORDIR        ; P=not attr 2
  1509. NOTTWO:    INX    H
  1510.     LDA    THRFLG        ; Only attrib 3?
  1511.     ORA    A
  1512.     JNZ    NOTTHR        ; NZ=no
  1513.     MOV    A,M
  1514.     ORA    A
  1515.     JP    MORDIR        ; P= not attr 3
  1516. NOTTHR:    INX    H
  1517.     LDA    FORFLG        ; Only attr 4?
  1518.     ORA    A
  1519.     JNZ    NOTFOR        ; NZ=no
  1520.     MOV    A,M
  1521.     ORA    A
  1522.     JP    MORDIR        ; P= not attr 4
  1523. NOTFOR:    MOV    A,L
  1524.     ADI    6
  1525.      ENDIF            ; FATTRIB
  1526.  
  1527.      IF    NOT FATTRIB
  1528.     ADI    9        ; Point to sys byte
  1529.      ENDIF            ; NOT FATTRIB
  1530.  
  1531.     MOV    L,A        ; Save (can't carry to H)
  1532.     LDA    QOPFLG        ; Find only non-$ARC files?
  1533.     ORA    A
  1534.     JNZ    OSYS        ; No, check for only $SYS files
  1535.     INX    H        ; Yes, get the archive byte
  1536.     MOV    A,M
  1537.     DCX    H
  1538.     ORA    A        ; Check bit 7 for $ARC file
  1539.     JM    MORDIR        ; If set, ignore this filename
  1540.  
  1541. OSYS:    LDA    OOPFLG        ; Find only $SYS files?
  1542.     ORA    A
  1543.     JNZ    CKSYS
  1544.     MOV    A,M        ; Yes, get system byte
  1545.     ORA    A        ; Check bit 7 for $SYS file
  1546.     JP    MORDIR        ; If not set, ignore this filename
  1547.     JMP    SYSFOK        ; Else check for a match
  1548.  
  1549. CKSYS:    LDA    SOPFLG        ; Did user request $SYS files?
  1550.     ORA    A
  1551.     JZ    SYSFOK        ; If yes, exit
  1552.     MOV    A,M        ; Get system byte back
  1553.     ORA    A        ; Check bit 7 for $SYS file
  1554.     JM    MORDIR        ; Skip that file
  1555.  
  1556. SYSFOK:    MOV    A,L        ; Go back now
  1557.     SUI    10        ; Back to user number (allocation flag)
  1558.     MOV    L,A        ; HL points to entry now
  1559.     LDA    NEWUSR        ; Get current user
  1560.     CMP    M
  1561.     JNZ    MORDIR        ; Ignore if different
  1562.  
  1563.      IF    Z80DOS OR CPM3
  1564.     PUSH    D        ; 
  1565.     PUSH    H        ; 
  1566.      ENDIF            ; Z80DOS/CPM3
  1567.  
  1568. ; CPM3 does not support BDOS function 54 as does Z80DOS, so we must check
  1569. ; if the filename in the DMA buffer has a ZERO extent [and if not fall
  1570. ; through the routine] so as to obtain the correct DATE/TIME stamp.
  1571. ; Also we have to locate the correct file in the DMA buffer and point to
  1572. ; the relevent DATE/TIME stamp in the SFCB for that filename.
  1573. ; It also checks to see if DATE/TIME stamping has been initilised.
  1574. ; 
  1575. ; CREATE & ACCESS are mutually exclusive. Either one or the other, but NOT
  1576. ; both.
  1577. ;
  1578. ; Bytes 0-3: Create or Access Date and Time stamp field
  1579. ; Bytes 4-7: Update and Time stamps field
  1580. ;
  1581. ; Offset =DMA+97+(A*10)
  1582.  
  1583.      IF    CPM3
  1584.     MOV    C,L        ; Save 'L' for later
  1585.     MVI    A,12        ; Offset to get the extent
  1586.     ADD    L        ; Add offset to point to the extent
  1587.     MOV    L,A        ; Update pointer
  1588.     XRA    A        ; Zero 'A'
  1589.     CMP    M        ; Is it a zero extent?
  1590.     MOV    L,C        ; Retreive 'L'
  1591.     JNZ    NODATA        ; NZ=no
  1592.     MVI    L,0E0H        ; Address of init byte if date/time stamp is
  1593.     MVI    A,21H        ; in use.
  1594.     CMP    M        ; Is there DATE/TIME stamps?
  1595.     MOV    L,C        ; Restore 'L'
  1596.     JNZ    NODATA        ; Not using date stamps, so exit this routine.
  1597.     MVI    A,80H        ; Is this the 1st' entry in the DMA buffer
  1598.     CMP    L        ; that we are after?
  1599.     JNZ    SECOND        ; Nope, might be the 2nd time through
  1600.     MVI    L,0E1H        ; Point to the address of the date stamp
  1601.     JMP    CONT        ; in the SFCB for the 1st entry.
  1602. SECOND:    MVI    A,0A0H        ; Is this the 2nd' entry in the DMA buffer
  1603.     CMP    L        ; that we are after?
  1604.     JNZ    THIRD        ; Nope, try for a 3rd time through
  1605.     MVI    L,0EBH        ; Point to the address of the date stamp
  1606.     JMP    CONT        ; in the SFCB for the 2nd entry.
  1607. THIRD:    MVI    L,0F5H        ; Point to the address of the date stamp
  1608.                 ; in the SFCB for the 3rd entry
  1609.      ENDIF            ; CPM3
  1610. CONT:
  1611.      IF    CPM3 AND UPDATE
  1612.     LXI    D,0        ; Point to Access/Create field
  1613.     LDA    DGOPFL
  1614.     ORA    A
  1615.     JZ    ACCESS
  1616.     LXI    D,4        ; Default to Update field
  1617.      ENDIF            ; UPDATE
  1618.  
  1619.      IF    CPM3 AND NOT UPDATE
  1620.     LXI    D,4        ; Point to Update field
  1621.     LDA    DNOPFL
  1622.     ORA    A
  1623.     JZ    ACCESS        ; Z=what is wanted
  1624.     LXI    D,0        ; Default to Access/Create field
  1625.      ENDIF            ; NOT UPDATE
  1626.  
  1627.      IF    Z80DOS
  1628.     MVI    C,54        ; Get time stamp from last search
  1629.     CALL    BDOS        ; 
  1630.     LXI    D,6        ; Point to last access field
  1631.     LDA    DGOPFL
  1632.     ORA    A
  1633.     JZ    ACCESS        ; Z=what is wanted
  1634.     LXI    D,2        ; Point to last alteration field
  1635.     LDA    DAOPFL
  1636.     ORA    A
  1637.     JZ    ACCESS        ; Z=what is wanted
  1638.     LXI    D,0        ; Point to creation field
  1639.     LDA    DNOPFL
  1640.     ORA    A
  1641.     JZ    ACCESS        ; Z=what is wanted
  1642.     LXI    D,2        ; Didn't say, so give him alteration date
  1643.      ENDIF            ; Z80DOS
  1644.  
  1645.      IF    Z80DOS OR CPM3
  1646. ACCESS:    PUSH    H
  1647.     DAD    D        ; Point to right field in returned database
  1648.     MOV    E,M        ; Get the date in Julian
  1649.     INX    H
  1650.     MOV    D,M
  1651.     MOV    A,D        ; Is requested date 0 for the file?
  1652.     ORA    E
  1653.     JNZ    ACCESS1        ; NZ=no, use it
  1654.     POP    H
  1655.     MOV    E,M        ; Was zero, use creation date
  1656.     INX    H
  1657.     MOV    D,M
  1658.     PUSH    H
  1659. ACCESS1:
  1660.     XCHG
  1661.     SHLD    DATMOD
  1662.     POP    H
  1663. ;////
  1664. NODATA:    POP    H
  1665.     POP    D
  1666.      ENDIF            ; Z80DOS/CPM3
  1667. ;
  1668. ; Move entry to table
  1669. ;
  1670.     INX    H
  1671.     XCHG            ; Entry to DE
  1672.     LHLD    NEXTT        ; Next table entry to HL
  1673.     MVI    B,11        ; Entry length (name, type, extent)
  1674.  
  1675. TMOVE:    LDAX    D        ; Get entry character
  1676.  
  1677.      IF    NOT (USELC OR REVID)
  1678.     ANI    7FH        ; Remove attributes
  1679.      ENDIF            ; NOT (USELC OR REVID)
  1680.  
  1681.     MOV    M,A        ; Store in table
  1682.     INX    D
  1683.     INX    H
  1684.     DCR    B        ; More?
  1685.     JNZ    TMOVE
  1686.     INX    D        ; DE->> S1
  1687.     INX    D        ; DE->> S2
  1688.     LDAX    D        ; Get S2 byte, oflo=int(extents/32)
  1689.     PUSH    H        ; Save HL
  1690.     MOV    L,A        ; Set up 16-bit multiply
  1691.     MVI    H,0
  1692.     MVI    B,5
  1693.     CALL    SHLL        ; HL is now # of oflo extents
  1694.     DCX    D        ; DE->> S1
  1695.     DCX    D        ; DE->> extent
  1696.     LDAX    D        ; Get extent
  1697.     ADD    L
  1698.     MOV    L,A
  1699.     MOV    A,H
  1700.     ACI    0
  1701.     MOV    H,A        ; HL has total extents
  1702.     MVI    B,7
  1703.     CALL    SHLL        ; HL has total records less last ext
  1704.     INX    D        ; DE->> S1
  1705.     INX    D        ; DE->> S2
  1706.     INX    D        ; Point to sector count
  1707.     LDAX    D        ; Get it
  1708.     ADD    L
  1709.     MOV    L,A
  1710.     MOV    A,H
  1711.     ACI    0
  1712.     MOV    H,A        ; HL has total records
  1713.     XTHL            ; Do some fancy shuffling
  1714.     XCHG
  1715.     XTHL
  1716.     XCHG
  1717.     MOV    M,D
  1718.     INX    H
  1719.     MOV    M,E
  1720.     POP    D        ; All back to normal
  1721.     INX    H
  1722.  
  1723.      IF    Z80DOS OR CPM3
  1724.     LDA    DATMOD        ; Get LSB of last modified date
  1725.     MOV    M,A        ; 
  1726.     INX    H        ; 
  1727.     LDA    DATMOD+1    ; Get MSB of last modified date
  1728.     MOV    M,A        ; 
  1729.     INX    H        ; 
  1730.      ENDIF            ; Z80DOS/CPM3
  1731.  
  1732.     SHLD    NEXTT        ; Save updated table address
  1733.     XCHG
  1734.     LHLD    COUNT        ; Bump the # of matches made
  1735.     INX    H
  1736.     SHLD    COUNT
  1737.  
  1738.      IF    Z80DOS OR CPM3
  1739.     LXI    H,15        ; Size of entry include date
  1740.      ENDIF            ; Z80DOS/CPM3
  1741.  
  1742.      IF    NOT (Z80DOS OR CPM3)
  1743.     LXI    H,13        ; Size of next entry
  1744.      ENDIF            ; NOT Z80DOS
  1745.  
  1746.     DAD    D
  1747.     XCHG            ; Future NEXTT is in DE
  1748.     LHLD    BDOS+1        ; Pick up TPA end
  1749.     MOV    A,E
  1750.     SUB    L        ; Compare NEXTT-TPA end
  1751.     MOV    A,D
  1752.     SBB    H
  1753.     JC    MORDIR        ; If TPA end > NEXTT, loop back for more
  1754.  
  1755. OUTMEM:    CALL    ERXIT        ; Exit if directory too large
  1756.     DB    'Memory',0
  1757. ;
  1758. ; Shift HL left by B bits
  1759. ;
  1760. SHLL:    DAD    H
  1761.     DCR    B
  1762.     RZ
  1763.     JMP    SHLL
  1764. ;
  1765. ; Sort and print
  1766. ;
  1767. SPRINT:    CALL    SETFOP        ; Return to file output DMA & user #
  1768.     LHLD    COUNT        ; Get file name count
  1769.     MOV    A,L
  1770.     ORA    H        ; Any found?
  1771.     JZ    PRTOTL        ; Exit if no files found
  1772.     PUSH    H        ; Save file count
  1773.     STA    SUPSPC        ; Enable leading zero suppression
  1774. ;
  1775. ; Initialize the order table
  1776. ;
  1777.     LHLD    TBLOC        ; Get start of name table
  1778.     XCHG            ; Into DE
  1779.     LXI    H,ORDER        ; Point to order table
  1780.  
  1781.      IF    Z80DOS OR CPM3
  1782.     LXI    B,15        ; Entry length including date
  1783.      ENDIF            ; Z80DOS/CPM3
  1784.  
  1785.      IF    NOT (Z80DOS OR CPM3)
  1786.     LXI    B,13        ; Entry length
  1787.      ENDIF            ; NOT Z80DOS/CPM3
  1788.  
  1789. BLDORD:    MOV    M,E        ; Save low order address
  1790.     INX    H
  1791.     MOV    M,D        ; Save high order address
  1792.     INX    H
  1793.     XCHG            ; Table address to HL
  1794.     DAD    B        ; Point to next entry
  1795.     XCHG
  1796.     XTHL            ; Save table address, load loop counter
  1797.     DCX    H        ; Count down loop
  1798.     MOV    A,L
  1799.     ORA    H        ; More?
  1800.     XTHL            ; Load table address, save loop counter
  1801.     JNZ    BLDORD        ; Yes, go do another one
  1802.     POP    H        ; Clean loop counter off stack
  1803.     LHLD    COUNT        ; Get count
  1804.     SHLD    SCOUNT        ; Save as # to sort
  1805.     DCX    H        ; Only 1 entry?
  1806.     MOV    A,L
  1807.     ORA    H
  1808.     JZ    DONE        ; Yes, so skip sort
  1809. ;
  1810. ; This sort routine is adapted from SOFTWARE TOOLS
  1811. ;
  1812.     LHLD    SCOUNT        ; Number of entries
  1813.  
  1814. L1:    ORA    A        ; Clear carry
  1815.     MOV    A,H        ; GAP=GAP/2
  1816.     RAR
  1817.     MOV    H,A
  1818.     MOV    A,L
  1819.     RAR
  1820.     MOV    L,A
  1821.     ORA    H        ; Is it zero?
  1822.     JZ    DONE        ; Then none left
  1823.     MOV    A,L        ; Make gap odd
  1824.     ORI    1
  1825.     MOV    L,A
  1826.     SHLD    GAP
  1827.     INX    H        ; I=GAP+1
  1828.  
  1829. L2:    SHLD    I
  1830.     XCHG
  1831.     LHLD    GAP
  1832.     MOV    A,E        ; J=I-GAP
  1833.     SUB    L
  1834.     MOV    L,A
  1835.     MOV    A,D
  1836.     SBB    H
  1837.     MOV    H,A
  1838.  
  1839. L3:    SHLD    J
  1840.     XCHG
  1841.     LHLD    GAP        ; JG=J+GAP
  1842.     DAD    D
  1843.     SHLD    JG
  1844.     CALL    COMPARE        ; Compare (J) and (JG)
  1845.     JP    L4        ; If A(J)<=A(JG)
  1846.     LHLD    J
  1847.     XCHG
  1848.     LHLD    JG
  1849.     CALL    SWAP        ; Exchange a(J) and a(JG)
  1850.     LHLD    J        ; J=J-GAP
  1851.     XCHG
  1852.     LHLD    GAP
  1853.     MOV    A,E
  1854.     SUB    L
  1855.     MOV    L,A
  1856.     MOV    A,D
  1857.     SBB    H
  1858.     MOV    H,A
  1859.     JM    L4        ; If J>0 go to l3
  1860.     ORA    L        ; Check for zero
  1861.     JZ    L4
  1862.     JMP    L3
  1863.  
  1864. L4:    LHLD    SCOUNT        ; For later
  1865.     XCHG
  1866.     LHLD    I        ; I=I+1
  1867.     INX    H
  1868.     MOV    A,E        ; If I<=n go to l2
  1869.     SUB    L
  1870.     MOV    A,D
  1871.     SBB    H
  1872.     JP    L2
  1873.     LHLD    GAP
  1874.     JMP    L1
  1875. ;
  1876. ; Sort is all done - print entries
  1877. ;
  1878. DONE:    LDA    FOPFLG        ; File output flag
  1879.     ORA    A        ; Set?
  1880.     JNZ    NOOUT        ; No, skip open
  1881. ;
  1882. ; If all user option enabled, and we're not on the first pass, then the
  1883. ; output file is already open and positioned, so we can skip the open.
  1884. ;
  1885.     LXI    H,OPNFLG    ; Output file open flag
  1886.     CMP    M        ; A=0,set Z if OPNFLG=0 also
  1887.     JNZ    NOOUT        ; If OPNFLG not zero, skip open
  1888.     DCR    M        ; Else, set OPNFLG for next user #
  1889. ;
  1890. ; First pass on file append - prepare DISK.DIR to receive new
  1891. ; or appended output.
  1892. ;
  1893.     LXI    D,OUTFCB    ; Does output file exist?
  1894.     MVI    C,SRCHF
  1895.     CALL    CPM
  1896.     INR    A
  1897.     JNZ    OPENIT        ; Yes, open for processing
  1898.     MVI    C,MAKE        ; Else, create output file
  1899.     CALL    CPM
  1900.     INR    A        ; Successful?
  1901.     JNZ    NOOUT        ; Yes, Continue
  1902. ;
  1903. ; If make or open fails, declare error
  1904. ;
  1905. OPNERR:    CALL    ERXIT
  1906.     DB    'Open',0
  1907. ;
  1908. WRTERR:    CALL    ERXIT
  1909.     DB    'Write',0
  1910. ;
  1911. ; Output file already exists - open it and position
  1912. ; it to the last record of the last extent.
  1913. ;
  1914. OPENIT:    MVI    C,OPEN        ; Open 1st extent of output file
  1915.     CALL    CPM
  1916.     INR    A
  1917.     JZ    OPNERR        ; Bad deal if 1st won't open
  1918.  
  1919. OPNMOR:    LDA    OUTFCB+15    ; Record count (RC)
  1920.     CPI    128
  1921.     JC    LSTEXT        ; If RC<128, this is last extent
  1922.     LXI    H,OUTFCB+12
  1923.     INR    M        ; Else, increment to next extent
  1924.     MVI    C,OPEN        ; Try to open it
  1925.     CALL    CPM
  1926.     INR    A
  1927.     JNZ    OPNMOR        ; Continue opening extents to end
  1928.     DCR    M        ; Then, reopen preceding extent
  1929.     MVI    C,OPEN
  1930.     CALL    CPM
  1931.     LDA    OUTFCB+15    ; Get RC for the last extent
  1932. ;
  1933. ; At this point, OUTFCB is opened to the last extent of the file, so
  1934. ; read in the last record in the last extent.
  1935. ;
  1936. LSTEXT:    ORA    A        ; Is this extent empty?
  1937.     JZ    NOOUT        ; Yes, starting a clean slate
  1938.     DCR    A        ; Normalize record count
  1939.     STA    OUTFCB+32    ; Set record number to read
  1940.     MVI    C,READ        ; Read last record of file
  1941.     CALL    CPM
  1942.     ORA    A        ; Successful read?
  1943.     JZ    RDOK        ; Yes, scan for EOF mark
  1944.  
  1945. APERR:    CALL    ERXIT
  1946.     DB    'Append',0
  1947. ;
  1948. ; We now have the last record in the file in the buffer. Scan the last
  1949. ; record for the EOF mark, indicate where we can start adding data.
  1950. ;
  1951. RDOK:    LXI    H,OUTBUF    ; Point to output buffer start
  1952.     MVI    B,128        ; Output buffer length
  1953.  
  1954. SCAN:    MOV    A,M        ; Character
  1955.     CPI    'Z'-40H        ; End of file?
  1956.     JZ    RESCR        ; Yes, save pointers and reset CR
  1957.     INX    H        ; Pointer+1
  1958.     DCR    B        ; Length-1
  1959.     JNZ    SCAN        ; Continue to end of buffer
  1960. ;
  1961. ; If an explicit EOF mark or an implied EOF (last record is full) in
  1962. ; the last buffer, move the FCB record and extent pointer back to cor-
  1963. ; rect for the read operation so the first write operation will replace
  1964. ; the last record of the DISK.DIR file.
  1965. ;
  1966. RESCR:    PUSH    H        ; Save EOF buffer pointer
  1967.     PUSH    B        ; Save EOF buffer remaining
  1968.     LXI    H,OUTFCB+32    ; Load current record again
  1969.     DCR    M        ; Record-1
  1970.     JP    SAMEXT        ; If CR>=0, still in same extent
  1971.     LXI    H,OUTFCB+12    ; Else, move to previous extent
  1972.     DCR    M
  1973.     MVI    C,OPEN        ; Then, reopen previous extent
  1974.     CALL    CPM
  1975.     INR    A
  1976.     JZ    APERR        ; Append error if can not reopen
  1977.     LDA    OUTFCB+15    ; Else,
  1978.     DCR    A        ; Position to last record of
  1979.     STA    OUTFCB+32    ; The extent
  1980.  
  1981. SAMEXT:    POP    PSW        ; Recall EOF location in buffer
  1982.     STA    BUFCNT        ; Set buffer counter
  1983.     POP    H        ; Recall next buffer pointer
  1984.     SHLD    BUFPNT        ; Set pointer for first addition
  1985.  
  1986. NOOUT:    LDA    FIRSTT        ; First time through?
  1987.     ORA    A
  1988.     JNZ    NOVOPT        ; No, we've been here before
  1989.     MVI    A,0FFH        ; Yes,
  1990.     STA    FIRSTT        ; Set first time flag
  1991.     LDA    VOPFLG        ; Version display flag
  1992.     ORA    A        ; Set?
  1993.     JNZ    NOVOPT        ; No, skip version print
  1994.     LXI    D,VERNAME    ; Yes, print version
  1995.     CALL    PUTS        ; Print the string
  1996.     CALL    CRLF
  1997.  
  1998. NOVOPT:    LHLD    COUNT
  1999.     SHLD    LCOUNT
  2000.     LXI    H,0
  2001.     SHLD    LBTOTL
  2002.     SHLD    LMTOTL
  2003.     LXI    H,ORDER        ; Initialize order table pointer
  2004.     SHLD    NEXTL
  2005.     SHLD    NEXTT
  2006.     LDA    VFLAG        ; Check display form
  2007.     ORA    A
  2008.     JNZ    NEWLIN        ; Jump if not vertical
  2009.     LHLD    COUNT        ; Code computes end of name table
  2010.     CALL    MULT13        ; (or start of second table
  2011.     XCHG            ; where files to be stored after
  2012.     LHLD    TBLOC        ; redundant extents removed)
  2013.     DAD    D
  2014.     SHLD    NEWPTR        ; Save it twice
  2015.     SHLD    XPOINT        ; For later
  2016.  
  2017. ENTRY:
  2018.      IF    CPM3
  2019.  
  2020. ; We need to check that we have the first extent of the filename, as it is the
  2021. ; only extent that contains a valid DATE
  2022. ; 
  2023.     LHLD    NEXTT        ; Address of filename
  2024.     MOV    E,M
  2025.     INX    H
  2026.     MOV    D,M
  2027.     XCHG
  2028.     LXI    D,11
  2029.     DAD    D        ; Point to the extent field
  2030.     XRA    A
  2031.     CMP    M        ; Is it zero? 
  2032.     JNZ    NOEXTZ        ; Nope, then we don't want to know about it
  2033.     INX    H
  2034.     MVI    A,81H
  2035.     CMP    M        ; Is it > than 129?
  2036.     JC    NOEXTZ        ; If it is, than it's not the first extent
  2037.     INX    H        ; Got this far, must be the first extent
  2038.     MOV    E,M        ; Get the DATE
  2039.     INX    H        ; into the
  2040.     MOV    D,M        ; DE regester pair
  2041.     XCHG
  2042.     SHLD    LATDAT        ; Save the DATE for latter on
  2043.      ENDIF            ; CPM3
  2044. ;
  2045. ; Output directory files we've matched
  2046. ;
  2047. NOEXTZ:    LHLD    COUNT        ; Files matched count
  2048.     DCX    H        ; Count-1
  2049.     SHLD    COUNT
  2050.     MOV    A,H        ; Is this the last file?
  2051.     ORA    L
  2052.     JZ    OKPRNT        ; Yes, last file so skip compare
  2053. ;
  2054. ; Compare each entry to make sure that it isn't part of a multiple
  2055. ; extent file.    Go only when we have the last extent of the file.
  2056. ;
  2057.     PUSH    B        ; Save number of columns
  2058.     LDA    VFLAG        ; Check display form
  2059.     ORA    A
  2060.     CNZ    CKABRT        ; If horiz, check for abort from keyboard
  2061.     LHLD    NEXTT
  2062.     MVI    A,11
  2063.     CALL    COMPR        ; Does this entry match next one?
  2064.     POP    B        ; Restore number of columns
  2065.     JNZ    OKPRNT        ; No, print it
  2066. NOKPRN:    INX    H
  2067.     INX    H        ; Skip, highest extent last in list
  2068.     SHLD    NEXTT
  2069.     JMP    ENTRY        ; Loop back for next lowest extent
  2070. ;
  2071. ; VLIST substitution. If VLIST option chosen, OKPRINT moves unique
  2072. ; filenames and sizes in "k" to a second table above the first for
  2073. ; use later.
  2074. ;
  2075. OKPRNT:    
  2076.      IF    CPM3
  2077.     PUSH    H
  2078.     PUSH    D
  2079.     PUSH    B
  2080.     MOV    E,M        ; Get the address of
  2081.     INX    H        ; the filename
  2082.     MOV    D,M        ; into the DE regester pair
  2083.     LHLD    LATDAT        ; Recover the DATE
  2084.     XCHG
  2085.     LXI    B,13
  2086.     DAD    B        ; Point to the DATE field
  2087.     MOV    M,E        ; Replace the now corrupted DATE
  2088.     INX    H        ; with the real DATE into the
  2089.     MOV    M,D        ; now new DATE field
  2090.      ENDIF            ; CPM3
  2091.  
  2092.      IF    Z80DOS
  2093.     PUSH    H
  2094.     PUSH    D
  2095.     PUSH    B
  2096.      ENDIF            ; Z80DOS
  2097.  
  2098.      IF    Z80DOS OR CPM3
  2099.     LHLD    NEXTT        ; Get order table pointer
  2100.     MOV    E,M        ; Get low order address
  2101.     INX    H
  2102.     MOV    D,M        ; Get high order address
  2103.     LXI    H,13
  2104.     DAD    D
  2105.     MOV    E,M
  2106.     INX    H
  2107.     MOV    D,M
  2108.     LHLD    DATCHK        ; Get the date we are looking for
  2109.     MOV    A,H
  2110.     ORA    L
  2111.     JZ    GDTMTC        ; Z=not looking
  2112.     LHLD    DATCH1
  2113.     MOV    A,H
  2114.     ORA    L
  2115.     JZ    ONEDAT        ; Z=only 1 date on input line
  2116.     DW    SBCDE
  2117.     JZ    GDTMTC        ; Z=file date=low date
  2118.     JNC    NDTMTC        ; NC=file date < low date, no output
  2119.     LHLD    DATCHK
  2120.     ORA    A
  2121.     DW    SBCDE
  2122.     JZ    GDTMTC        ; Z=file date=high date
  2123.     JNC    GDTMTC        ; NC=file date < high date
  2124.     JMP    NDTMTC        ; File date > high date
  2125. ONEDAT:    LHLD    DATCHK
  2126.     MOV    A,H
  2127.     CMP    D        ; Check if given date >,=,< the files date
  2128.     JZ    CHDLOW        ; High EQ, check low
  2129.     JC    DATLT        ; C=LT
  2130.     JMP    DATGE        ; Given date GT file date
  2131. CHDLOW:    MOV    A,L        ; Check low byte of date vs. file date
  2132.     CMP    E
  2133. DATGE:    MVI    A,0        ; Assume EQ
  2134.     JC    DATLT        ; C= given LT files date
  2135.     JZ    DATFLG        ; Z= they are EQ
  2136.     MVI    A,2        ; Given GT files date
  2137.     JMP    DATFLG
  2138. DATLT:    MVI    A,1        ; Given was less than files
  2139. DATFLG:    STA    DTMTCH
  2140.     LDA    DEOPFL        ; What kind of date match?
  2141.     ORA    A
  2142.     JZ    DTEXAC        ; Z=exact
  2143.     LDA    DPOPFL
  2144.     ORA    A
  2145.     JZ    DTABVE        ; Z=GE
  2146.     LDA    DMOPFL        ; LT wanted?
  2147.     ORA    A
  2148.     JNZ    DTEXAC        ; NZ=no, didn't tell us so do anything but gave
  2149.                 ; us a date so assume want exact match
  2150.     LDA    DTMTCH
  2151.     CPI    2
  2152.     JZ    GDTMTC        ; Date was below and they wanted below
  2153. NDTMTC:
  2154.     POP    B
  2155.     POP    D
  2156.     POP    H
  2157.     PUSH    H
  2158.     LHLD    COUNT
  2159.     MOV    A,L
  2160.     ORA    H
  2161.     POP    H
  2162.     JZ    PRTOTL
  2163.     JMP    NOKPRN
  2164.  
  2165. DTEXAC:    LDA    DTMTCH        ; They wanted exact, was it?
  2166.     ORA    A
  2167.     JZ    GDTMTC        ; Z=yes
  2168.     JMP    NDTMTC
  2169. DTABVE:    LDA    DTMTCH        ; They wanted GE
  2170.     CPI    1
  2171.     JZ    GDTMTC        ; Z=G
  2172.     ORA    A
  2173.     JNZ    NDTMTC        ; Must be 2, so not equal
  2174. GDTMTC:    POP    B
  2175.     POP    D
  2176.     POP    H
  2177.      ENDIF            ; Z80DOS/CPM3
  2178.     
  2179.     LHLD    NEXTT        ; Get order table pointer
  2180.     MOV    E,M        ; Get low order address
  2181.     INX    H
  2182.     MOV    D,M        ; Get high order address
  2183.     INX    H
  2184.     SHLD    NEXTT        ; Save updated table pointer
  2185.     XCHG            ; Table entry to HL
  2186.     LDA    VFLAG        ; Check display form
  2187.     ORA    A
  2188.     JNZ    OKPR1        ; Jump if not vertical
  2189.     PUSH    H        ; Save address of byte to be moved
  2190.     LHLD    NEWPTR        ; Address in new table to put byte
  2191.     PUSH    H        ; Save address
  2192.  
  2193.      IF    Z80DOS OR CPM3
  2194.     LXI    D,15        ; Update address including date
  2195.      ENDIF            ; Z80DOS/CPM3
  2196.  
  2197.      IF    NOT (Z80DOS OR CPM3)
  2198.     LXI    D,13        ; Update address
  2199.      ENDIF            ; NOT Z80DOS/CPM3
  2200.  
  2201.     DAD    D
  2202.     SHLD    NEWPTR        ; Save for later (end of table)
  2203.     POP    H        ; Set current move  to    address
  2204.     XCHG            ; Swap pointers
  2205.     POP    H        ; Set current move from address
  2206.  
  2207.      IF    Z80DOS OR CPM3
  2208.     LXI    B,11
  2209.     DW    ZMOVE        ; Z80's LDIR
  2210.      ENDIF            ; Z80DOS/CPM3
  2211.  
  2212.      IF    NOT (Z80DOS OR CPM3)
  2213.     MVI    B,11        ; Filename.typ length
  2214.     CALL    MOVE        ; Move it
  2215.      ENDIF            ; NOT Z80DOS/CPM3
  2216.  
  2217.      IF    Z80DOS OR CPM3
  2218.     PUSH    H
  2219.      ENDIF            ; Z80DOS
  2220.  
  2221.     PUSH    D
  2222.     JMP    OKPR2
  2223.  
  2224. OKPR1:    MVI    B,8        ; Filename length
  2225.     CALL    PUTSB        ; Output
  2226.     MVI    A,'.'        ; Period after filename
  2227.     CALL    PUTCHR        ; Output
  2228.     MVI    B,3        ; Filetype length
  2229.     CALL    PUTSB        ; Output
  2230.  
  2231.      IF    Z80DOS OR CPM3
  2232.     LDA    NODFLG
  2233.     ORA    A
  2234.     JNZ    NOD1
  2235.     CALL    DISDAT
  2236. NOD1:
  2237.      ENDIF            ; Z80DOS/CPM3
  2238.  
  2239. OKPR2:    
  2240.     CALL    SIZEFL
  2241.     LHLD    TOTSIZ        ; DE = rounded size in K
  2242.     DAD    D        ; Add to total used
  2243.     SHLD    TOTSIZ
  2244.     LHLD    TOTFIL        ; Increment filecount
  2245.     INX    H
  2246.     SHLD    TOTFIL
  2247.     XCHG
  2248.     LDA    COPFLG        ; Size wanted in records?
  2249.     ORA    A
  2250.     JNZ    OKPR3        ; Jump if not
  2251.     LHLD    FILERC        ; Else get record count
  2252.  
  2253. OKPR3:    LDA    VFLAG        ; Check display form
  2254.     ORA    A
  2255.     JNZ    OKPR4        ; Jump if not vertical
  2256.     POP    D        ; A(size to go)
  2257.     MOV    A,H        ; Move size to table two
  2258.     STAX    D
  2259.     INX    D
  2260.     MOV    A,L
  2261.     STAX    D
  2262.  
  2263.      IF    Z80DOS OR CPM3
  2264.     POP    H        ; Currently pointing to file size
  2265.     INX    H        ; Skip size
  2266.     INX    H
  2267.     INX    D
  2268.     MOV    A,M        ; Get LSB of date
  2269.     STAX    D        ; Save it away
  2270.     INX    D
  2271.     INX    H
  2272.     MOV    A,M        ; Ditto for MSB of date
  2273.     STAX    D
  2274.      ENDIF            ; Z80DOS/CPM3
  2275. ;
  2276. ; One File Moved - Test to see if we have to move another
  2277. ;
  2278.     LHLD    COUNT        ; Current file counter
  2279.     MOV    A,H
  2280.     ORA    L
  2281.     JZ    PRTOTL        ; Zero, output summary
  2282.     JMP    ENTRY
  2283. ;
  2284. ; Output the size of the individual file
  2285. ;
  2286. OKPR4:    CALL    DECPRT        ; Print it
  2287.     LDA    FSIZEC        ; Follow with 'k' or 'r'
  2288.     CALL    PUTCHR
  2289. ;
  2290. ; One file output - test to see if we have to output another one.
  2291. ;
  2292.     LHLD    COUNT        ; Current file counter
  2293.     MOV    A,H
  2294.     ORA    L        ; Zero?
  2295.     JZ    PRTOTL        ; Yes, exit to summary output
  2296. ;
  2297. ; At least one more file to output,
  2298. ; can we put it on the current line?
  2299. ;
  2300.     DCR    C
  2301.     PUSH    PSW
  2302.     CNZ    FENCE        ; If room left output fence character
  2303.     POP    PSW
  2304.     JNZ    ENTRY        ; Output another file
  2305. ;
  2306. ; Current line full, start a new one
  2307. ;
  2308. NEWLIN:
  2309.      IF    Z80DOS OR CPM3
  2310.     MVI    C,2        ; 2 names per line
  2311.     LDA    NODFLG
  2312.     ORA    A
  2313.     JZ    NOD2        ; WAS NZ,NOD2
  2314.     MVI    C,4
  2315. NOD2:
  2316.      ENDIF            ; Z80DOS/CPM3
  2317.  
  2318.      IF    NOT (Z80DOS OR CPM3)
  2319.     MVI    C,4        ; Reset names per line counter
  2320.      ENDIF            ; NOT Z80DOS/CPM3
  2321.  
  2322.     CALL    CRLF        ; Space down to next line
  2323.     JMP    ENTRY        ; Output another file
  2324. ;.....
  2325. ;
  2326. ; Compute the size of the file/library and update our summary datum.
  2327. ; This has been changed into a subroutine so that both the file size
  2328. ; computation and a library size (when printing out library members)
  2329. ; can be computed in K.
  2330. ;
  2331. SIZEFL:    MOV    D,M
  2332.     INX    H
  2333.     MOV    E,M        ; Size in DE (records)
  2334.     XCHG
  2335.     SHLD    FILERC        ; Save record count
  2336.     XCHG
  2337.     LDA    BLKMSK
  2338.     PUSH    PSW
  2339.     ADD    E
  2340.     MOV    E,A
  2341.     MOV    A,D
  2342.     ACI    0
  2343.     MOV    D,A
  2344.     POP    PSW
  2345.     CMA
  2346.     ANA    E
  2347.     MOV    E,A
  2348.     MVI    B,3
  2349.  
  2350. SHRR:    MOV    A,D
  2351.     ORA    A
  2352.     RAR
  2353.     MOV    D,A
  2354.     MOV    A,E
  2355.     RAR
  2356.     MOV    E,A
  2357.     DCR    B
  2358.     JNZ    SHRR
  2359.     RET
  2360. ;
  2361. ; Print HL in decimal with leading zero suppression
  2362. ;
  2363. DECPRT:    XRA    A        ; Clear leading zero flag
  2364.     STA    LZFLG
  2365.     LXI    D,-10000
  2366.     LDA    SUPSPC
  2367.     PUSH    PSW
  2368.     XRA    A
  2369.     STA    SUPSPC
  2370.     CALL    DIGIT
  2371.     POP    PSW
  2372.     STA    SUPSPC
  2373.     LXI    D,-1000        ; Print 1000's digit
  2374.     CALL    DIGIT
  2375.     LXI    D,-100        ; Etc.
  2376.     CALL    DIGIT
  2377.     LXI    D,-10
  2378.     CALL    DIGIT
  2379.     MVI    A,'0'        ; Get 1's digit
  2380.     ADD    L
  2381.     JMP    PUTCHR
  2382.  
  2383. DIGIT:    MVI    B,'0'        ; Start off with ASCII 0
  2384.  
  2385. DIGLP:    PUSH    H        ; Save current remainder
  2386.     DAD    D        ; Subtract
  2387.     JNC    DIGEX        ; Quit on overflow
  2388.     POP    PSW        ; Throw away remainder
  2389.     INR    B        ; Bump digit
  2390.     JMP    DIGLP        ; Loop back
  2391.  
  2392. DIGEX:    POP    H        ; Restore pointer
  2393.     MOV    A,B
  2394.     CPI    '0'        ; Zero digit?
  2395.     JNZ    DIGNZ        ; No, type it
  2396.     LDA    LZFLG        ; Leading zero?
  2397.     ORA    A
  2398.     MVI    A,'0'
  2399.     JNZ    PUTCHR        ; Print digit
  2400.     LDA    SUPSPC        ; Get space suppression flag
  2401.     ORA    A        ; See if printing file totals
  2402.     RZ            ; Yes, don't give leading spaces
  2403.     JMP    SPACE        ; Leading zero..print space
  2404. ;
  2405. DIGNZ:    STA    LZFLG        ; Leading zero flag set
  2406.     JMP    PUTCHR        ; Print leading zero & digit
  2407. ;.....
  2408. ;
  2409. ;-----------------------------------------------------------------------
  2410. ;          VLIST subroutines begin here
  2411. ;
  2412. ;Multiply contents of HL register by 13
  2413. ;
  2414. MULT13:    MOV    D,H
  2415.     MOV    E,L
  2416.     DAD    H
  2417.     DAD    D
  2418.     DAD    H
  2419.     DAD    H
  2420.     DAD    D
  2421.  
  2422.      IF    Z80DOS OR CPM3
  2423.     DAD    D        ; Actually by 15
  2424.     DAD    D        ; 
  2425.      ENDIF            ; Z80DOS/CPM3
  2426.  
  2427.     RET
  2428. ;.....
  2429. ;
  2430. ; Main VLIST subroutine to output a filename and column delimiter
  2431. ;
  2432. VENTRY:    STA    VSFRST
  2433.     CALL    PFILE1        ; Routine to print a filename
  2434.     RZ            ; If at end of line return with zero set
  2435.     CC    FENCE        ; Print column delimiter if more
  2436.     LHLD    JUMPER        ; Put the jumper back in DE
  2437.     XCHG
  2438.     ORI    1        ; Insure non zero return
  2439.     RET
  2440. ;.....
  2441. ;
  2442. PFILE1:    PUSH    H
  2443.     PUSH    D
  2444.     XCHG
  2445.     LHLD    NEWPTR
  2446.     MOV    A,H
  2447.     CMP    D
  2448.     JNC    PFILE2
  2449.     MOV    A,L
  2450.     CMP    E
  2451.     POP    D
  2452.     POP    H
  2453.     RZ
  2454.     JNC    PFILE3
  2455.     XRA    A
  2456.     RET
  2457. PFILE2:    POP    D
  2458.     POP    H
  2459. PFILE3:
  2460.     MOV    A,M        ; Let's see what we have
  2461.     CPI    0FEH
  2462.     RNC
  2463.     ANI    7FH        ; Strip parity bit
  2464.     PUSH    B        ; Save number of columns
  2465.     MVI    B,8        ; Print filename and type
  2466.     CALL    PUTSB
  2467.     MVI    A,'.'
  2468.     CALL    PUTCHR
  2469.     MVI    B,3
  2470.     CALL    PUTSB
  2471.     
  2472.      IF    Z80DOS OR CPM3
  2473.     LDA    NODFLG
  2474.     ORA    A
  2475.     JNZ    NOD3
  2476.     CALL    DISDAT        ; Display the date
  2477. NOD3:
  2478.      ENDIF            ; Z80DOS/CPM3
  2479.  
  2480.     MOV    D,M        ; Get it into DE
  2481.     INX    H
  2482.     MOV    E,M
  2483.     XCHG            ; HL <-> DE
  2484.     CALL    DECPRT        ; Print it out
  2485.     LDA    FSIZEC        ; Follow with 'k' or 'r'
  2486.     CALL    PUTCHR
  2487.     POP    B        ; Load number of columns
  2488.     LHLD    TOTFIL        ; Load number of files left
  2489.     DCX    H        ; # files-1
  2490.     SHLD    TOTFIL        ; Resave it
  2491.     MOV    A,H
  2492.     ORA    L        ; Zero yet?
  2493.     RZ            ; Yes, no more files
  2494.     DCR    C        ; No, decrement it
  2495.     STC            ; Force carry on
  2496.     RET            ; This return
  2497. ;.....
  2498. ;
  2499. ;              End of VLIST routines
  2500. ;-----------------------------------------------------------------------
  2501. ;
  2502. ; Show total space and files used
  2503. ;
  2504. PRTOTL:    XRA    A
  2505.     STA    VSFRST
  2506.     LDA    VFLAG        ; Check display form
  2507.     ORA    A
  2508.     JZ    PRTOT1        ; Jump if vertical
  2509.     LDA    LOPFLG
  2510.     ORA    A
  2511.     JNZ    PRTOT1
  2512.     LHLD    TOTFIL        ; How many files matched?
  2513.     MOV    A,H
  2514.     ORA    L
  2515.     CNZ    PRTLMEM        ; Skip .LBR check if none found
  2516.  
  2517. PRTOT1:    XRA    A        ; Get a zero to
  2518.     STA    SUPSPC        ; Suppress leading spaces in totals
  2519.     LHLD    TOTFIL        ; How many files matched?
  2520.     MOV    A,H
  2521.     ORA    L
  2522.     JZ    NXTUSR        ; Skip summary if none found
  2523.     PUSH    H        ; Save TOTFIL
  2524.     STA    FNDFLG        ; Set file found flag
  2525.     LDA    VFLAG        ; Check display form
  2526.     ORA    A
  2527.     JNZ    PRTOT3        ; Horizontal = 0FFh, exit if not zero
  2528.     LDA    SOHFLG
  2529.     ORA    A
  2530.     JZ    PRTOT2
  2531.     XRA    A
  2532.     STA    SOHFLG
  2533.     JMP    PRTOT3
  2534.  
  2535. PRTOT2:    CALL    CRLF
  2536.  
  2537. PRTOT3:    LXI    D,CRLSPC    ; CR,LF,'      ',0
  2538.     CALL    PUTS
  2539.  
  2540.      IF    ULINE
  2541.     LDA    BYEACT        ; Is BYE active
  2542.     ORA    A
  2543.     JZ    YODRIV        ; BYE active=Z
  2544.     LXI    D,ULON        ; Turn underline on
  2545.     CALL    COUTS        ; If not null
  2546.      ENDIF            ; ULINE
  2547.  
  2548. YODRIV:    LXI    D,TOTMS1    ; Print "' Drive '"
  2549.     CALL    PUTS
  2550.     LDA    FCB
  2551.     ADI    'A'-1
  2552.     CALL    PUTCHR        ; Output the drive code
  2553.     CALL    CKVER
  2554.     JC    NOUSER
  2555.     CALL    PUTUSR        ; Output user number
  2556.     MVI    A,':'
  2557.     CALL    PUTCHR
  2558.  
  2559.      IF    NDIRS
  2560.     MVI    A,' '
  2561.     CALL    PUTCHR
  2562.     CALL    NAMDIR
  2563.      ENDIF            ; NDIRS
  2564.  
  2565.     LDA    USRNR
  2566.     CPI    10
  2567.     LXI    D,NOFMS2
  2568.     JC    $+6
  2569.     LXI    D,NOFMS2+1    ; Print some spaces
  2570.     CALL    PUTS
  2571.  
  2572. NOUSER:    LXI    D,TOTMS6    ; Print " Files: "
  2573.     CALL    PUTS
  2574.     POP    H        ; Recall TOTFIL
  2575.     XCHG
  2576.     LHLD    TOTFL1        ; Get total number of files so far
  2577.     DAD    D        ; Add in number this DU
  2578.     SHLD    TOTFL1        ; And save it away
  2579.     XCHG
  2580.     CALL    DECPRT        ; Print # of files matched
  2581.     LXI    D,TOTMS4    ; No CRLF needed, display > 40
  2582.     CALL    PUTS
  2583.     LHLD    TOTSIZ        ; Total k used by matched files
  2584.     XCHG
  2585.     LHLD    TOTSZ1        ; Get running total of all files
  2586.     DAD    D
  2587.     SHLD    TOTSZ1        ; And put it back
  2588.     XCHG
  2589.     CALL    DECPRT        ; Print file size
  2590.     LXI    D,TOTMS5    ; Print "k"
  2591.     CALL    PUTS
  2592.     CALL    PRTFRE        ; Print free space remaining
  2593.  
  2594.      IF    ULINE
  2595.     LDA    BYEACT        ; Bye active?
  2596.     ORA    A        ; 
  2597.     JZ    NPRNT        ; Yes, skip ULINE off
  2598.     LXI    D,ULOFF        ; Turn off underline
  2599.     CALL    COUTS        ; If not null
  2600.      ENDIF            ; ULINE
  2601. ;
  2602. ; Summary line printed, now print detail files, first compute total
  2603. ; printout lines.
  2604. ;
  2605. NPRNT:    LDA    VFLAG        ; Check display form
  2606.     ORA    A
  2607.     JNZ    NXTUSR        ; Jump if horizontal
  2608.  
  2609.      IF    Z80DOS OR CPM3
  2610.     LXI    B,1
  2611.     LDA    NODFLG
  2612.     ORA    A
  2613.     JZ    NOD4
  2614.     LXI    B,3
  2615. NOD4:
  2616.      ENDIF            ; Z80DOS/CPM3
  2617.  
  2618.      IF    NOT (Z80DOS OR CPM3)
  2619.     LXI    B,3
  2620.      ENDIF            ; NOT Z80DOS/CPM3
  2621.  
  2622.     MOV    A,C        ; Get number of names per line
  2623.     CMA            ; Negative of number of columns
  2624.     MOV    E,A        ; Into DE
  2625.     MVI    D,0FFH
  2626.     LHLD    TOTFIL        ; Load total number of files
  2627.     DAD    B        ; Round up to a full line
  2628.     MVI    C,0FFH
  2629.  
  2630. NPRNT1:    INR    C        ; C-reg will hold number of
  2631.     DAD    D        ; Lines to be displayed
  2632.     JC    NPRNT1
  2633.     MOV    A,C
  2634.     STA    LINES        ; Done, save it for later
  2635.     STA    SUPSPC        ; Allow spaces preceding file sizes
  2636. ;
  2637. ; Number lines times entry size = the number of bytes to skip in the
  2638. ; second table when outputting files in vertical order.
  2639. ;
  2640.      IF    VSPAGE
  2641.     LDA    FOPFLG        ; Check File output
  2642.     ORA    A
  2643.     JZ    NVSORT
  2644.     LDA    POPFLG
  2645.     ORA    A
  2646.     JZ    NVSORT
  2647.     LDA    NOPFLG
  2648.     ORA    A
  2649.     JNZ    VSORT
  2650. NVSORT:    MOV    A,C
  2651.     JMP    OVSORT
  2652. VSORT:
  2653.     LDA    LINCNT        ; Get number of lines currently displayed
  2654.     MOV    B,A
  2655.     MVI    A,22        ; Calc number left
  2656.     SUB    B
  2657.     MOV    B,A
  2658.     MOV    A,C        ; Get how many lines this DU
  2659.     CMP    B
  2660.     JC    OVSORT        ; If C, then this DU will fit on the page whole
  2661.     MOV    A,B        ; This DU won't fit, so calc to fill up page
  2662.     ORA    A
  2663.     JNZ    OVSORT
  2664.     MOV    A,C
  2665.     CPI    23
  2666.     JC    OVSORT
  2667.     MVI    A,23
  2668. OVSORT:
  2669.      ENDIF            ; VSPAGE
  2670.  
  2671.     MOV    L,A        ; Put number of lines into HL
  2672.     MVI    H,0
  2673.     CALL    MULT13
  2674.     SHLD    JUMPER        ; Put it away
  2675.     XRA    A
  2676.     STA    WASHERE        ; Set flag for FENCE that says next calc
  2677.                 ; is for the next page of display
  2678. ;
  2679. ; Fill a record with FF at the end of table 2
  2680. ;
  2681.     LHLD    NEWPTR        ; Now points to end of table 2
  2682.     MVI    B,128
  2683.     MVI    A,0FFH
  2684.  
  2685. NPRNT2:    MOV    M,A
  2686.     INX    H
  2687.     DCR    B
  2688.     JNZ    NPRNT2
  2689. ;
  2690. ; Increment the number of files for use later in VENTRY.  This insures
  2691. ; that a column delimiter will be printed after the last filename, if
  2692. ; the file appears in other than the last column of the display.
  2693. ;
  2694.      IF    NOT (Z80DOS OR CPM3)
  2695.     LXI    H,TOTFIL
  2696.     INR    M
  2697.      ENDIF            ; NOT Z80DOS/CPM3
  2698. ;
  2699. ; Print out a line of files
  2700. ;
  2701. NPRNT3:    
  2702.      IF    Z80DOS OR CPM3
  2703.     MVI    C,2
  2704.     LDA    NODFLG
  2705.     ORA    A
  2706.     JZ    NOD5
  2707.     MVI    C,4
  2708. NOD5:
  2709.      ENDIF            ; Z80DOS/CPM3
  2710.  
  2711.      IF    NOT (Z80DOS OR CPM3)
  2712.     MVI    C,4        ; Reset number of columns
  2713.      ENDIF            ; NOT Z80DOS/CPM3
  2714.  
  2715.     CALL    CRLF        ; Start a new line
  2716.     MVI    A,1
  2717.     STA    VSFRST
  2718. ;
  2719. ; Print first filename
  2720. ;
  2721.     LHLD    XPOINT        ; XPOINT = to start of second table
  2722.     CALL    VENTRY        ; At entry. Below, it is incremented
  2723.                 ; For additional lines of printout
  2724.     JZ    NLINE        ; Either out of columns or out of files
  2725. ;
  2726. ; Print second filename
  2727. ;
  2728.     LHLD    XPOINT
  2729.     DAD    D
  2730.     CALL    VENTRY
  2731.     JZ    NLINE
  2732. ;
  2733. ; Print third filename
  2734. ;
  2735.     LHLD    XPOINT
  2736.     DAD    D
  2737.     DAD    D
  2738.     CALL    VENTRY
  2739.     JZ    NLINE
  2740. ;
  2741. ; Print fourth filename
  2742. ;
  2743.     LHLD    XPOINT
  2744.     DAD    D
  2745.     DAD    D
  2746.     DAD    D
  2747.     CALL    VENTRY
  2748.  
  2749. NLINE:    LHLD    XPOINT        ; Increment XPOINT to next file
  2750.  
  2751.      IF    Z80DOS OR CPM3
  2752.     LXI    D,15
  2753.      ENDIF            ; Z80DOS/CPM3
  2754.  
  2755.      IF    NOT (Z80DOS OR CPM3)
  2756.     LXI    D,13
  2757.      ENDIF            ; NOT Z80DOS/CPM3
  2758.  
  2759.     DAD    D
  2760.     SHLD    XPOINT
  2761.     LHLD    TOTFIL        ; Out of files?
  2762.     MOV    A,H
  2763.     ORA    L
  2764.     JZ    DOLIB        ; Yes, Check for libraries
  2765.     LXI    H,LINES        ; No, just need a new line
  2766.     DCR    M
  2767.     JNZ    NPRNT3
  2768.  
  2769. DOLIB:    LDA    LOPFLG
  2770.     ORA    A
  2771.     JNZ    NXTUSR
  2772.     LHLD    TOTFIL        ; How many files matched?
  2773.     MOV    A,H
  2774.     ORA    L
  2775.  
  2776.      IF    NOT (Z80DOS OR CPM3)
  2777.     CNZ    PRTLMEM        ; Skip library check if none found
  2778.      ENDIF
  2779.  
  2780.      IF    Z80DOS OR CPM3
  2781.     CALL    PRTLMEM
  2782.      ENDIF            ; ZRDOS/CPM3
  2783.  
  2784. ;
  2785. ; Directory for one user area completed.  If all users option is select-
  2786. ; ed, then go do another directory on the next user number until we ex-
  2787. ; ceed the maximum user # for the selected drive.
  2788. ;
  2789. NXTUSR:    LDA    AOPFLG        ; All user flag
  2790.     ORA    A        ; Set?
  2791.     JZ    NXTUSU        ; Set if zero, show all user areas
  2792.     LDA    HOPFLG        ; "H" flag to show remaining areas
  2793.     ORA    A
  2794.     JNZ    GOCLZ        ; Non-zero, not set, exit
  2795.  
  2796. NXTUSU:    CALL    CKVER        ; Running CP/M 2?
  2797.     JC    GOCLZ        ; No, Skip user increment
  2798.     CALL    CKABRT        ; Yes, Check for user abort
  2799.     LDA    MAXUSR        ; No abort - get maximum user #
  2800.     LXI    H,NEWUSR    ; Increment directory user number
  2801.     INR    M
  2802.     CMP    M        ; Next user # exceed maximum?
  2803.     JNC    SETTBL        ; No, more user areas to go
  2804.     LDA    BASUSR        ; Reset base user number for
  2805.     MOV    M,A        ; The next directory search
  2806. ;
  2807. ; We've finished all of our outputting. Flush the remainder of the out-
  2808. ; put buffer and close the file before going to exit routine.
  2809. ;
  2810. GOCLZ:    LXI    H,OPNFLG    ; Get file open status, reset flag
  2811.     MOV    A,M        ; To force reopen on next pass
  2812.     MVI    M,0
  2813.     ORA    A        ; File open?
  2814.     JZ    NXTDSK        ; No, Skip closing DISK.DIR
  2815.     LXI    H,BUFCNT
  2816.     MOV    A,M        ; Load # of unflushed characters in
  2817.     MVI    M,128        ; Buffer, force BUFCNT to empty status
  2818.     ORA    A        ; If BUFCNT=128, buffer empty set sign
  2819.     JM    DDCLOS        ; Close DISK.DIR if buffer is empty
  2820.     JZ    FLUSH        ; Write last record to DISK.DIR if full
  2821.     LHLD    BUFPNT        ; Else pad unused buffer with CTL-Z
  2822.  
  2823. PUTAGN:    MVI    M,'Z'-40H    ; EOF marker
  2824.     INX    H        ; Next buffer location
  2825.     DCR    A        ; Count-1
  2826.     JNZ    PUTAGN        ; Continue buffer padding fill
  2827.  
  2828. FLUSH:    LXI    D,OUTFCB    ; Flush the last output buffer
  2829.     MVI    C,WRITE
  2830.     CALL    CPM
  2831.     ORA    A
  2832.     JNZ    WRTERR
  2833.  
  2834. DDCLOS:    LXI    D,OUTFCB    ; Close DISK.DIR output file
  2835.     MVI    C,CLOSE
  2836.     CALL    CPM
  2837. ;
  2838. ; Directory for all user areas finished.  If the multi-disk option is
  2839. ; enabled and selected, reset to the base user area and repeat the
  2840. ; directory for next drive on-line until we either exceed the drives in
  2841. ; our LODRV-HIDRV table, or the BDOS shuts us down with a select or bad
  2842. ; record error, which will be intercepted back to the EXIT module.
  2843. ;
  2844. NXTDSK:    LXI    H,FNDFLG    ; Load file found flag
  2845.     MOV    A,M
  2846.     MVI    M,0        ; Clear found flag for next drive
  2847.     ORA    A
  2848.     JNZ    NDSK        ; Continue if at least 1 file found
  2849.     LXI    H,FOPFLG
  2850.     DCR    M
  2851.     PUSH    H
  2852.     LXI    D,NOFMS1    ; Print 1st part of no files message
  2853.     CALL    PUTS        ; Print it
  2854.     LXI    D,NOFLM
  2855.     CALL    PUTS        ; Print message
  2856.     LDA    FCB
  2857.     ADI    'A'-1
  2858.     CALL    PUTCHR        ; Output the drive
  2859.     CALL    CKVER
  2860.     JC    NOUSR1
  2861.     CALL    PUTUSR        ; Output the user number
  2862.  
  2863. NOUSR1:    LXI    D,NOFMS3    ; Print divider
  2864.     CALL    PUTS
  2865.     CALL    PRTFRE        ; Tag with free message
  2866.     LDA    VFLAG        ; Check display form
  2867.     ORA    A
  2868.     CNZ    CRLF        ; Need another CRLF in horizontal mode
  2869.     POP    H
  2870.     INR    M
  2871.  
  2872. NDSK:    LDA    DOPFLG        ; Multi-disk selected?
  2873.     ORA    A
  2874.     JNZ    NPRT        ; No, skip next check
  2875.     CALL    CKABRT        ; Check for user abort
  2876.     MVI    A,HIDRV-LODRV    ; Load max drive code to search
  2877.     LXI    H,FCB        ; Increment directory FCB drive code
  2878.     INR    M
  2879.     CMP    M        ; Does next disk exceed maximum?
  2880.     JC    NPRT
  2881.  
  2882. ;     IF    MAXDRV
  2883.  
  2884.      IF    ZCPR33 AND MAXDRV
  2885.     PUSH    H
  2886.     LHLD    Z3DRVL        ; Point to ENV
  2887.     MOV    A,M        ; Get it
  2888.     POP    H
  2889.      ENDIF            ; ZCPR33
  2890.  
  2891.      IF    NOT ZCPR33 AND MAXDRV
  2892.     LDA    MXDRV        ; Look at another value limit
  2893.     INR    A
  2894.      ENDIF            ; NOT ZCPR33
  2895.  
  2896.      IF    MAXDRV
  2897.     CMP    M        ; Is it lower?
  2898.     JC    NPRT        ; Bail out if too low
  2899.     JMP    NOOPT        ; Search next disk
  2900.      ENDIF            ; MAXDRV
  2901.  
  2902.     JNC    NOOPT        ; Search next disk if maxdr not true
  2903. ;
  2904. ; If no printer, fall through to EXIT
  2905. ;
  2906. NPRT:    LDA    POPFLG
  2907.     ORA    A        ; Printer active?
  2908.     JNZ    EXIT        ; No, just exit
  2909.     MVI    C,LIST
  2910.     MVI    E,13        ; Print a CRLF
  2911.     CALL    CPM
  2912.     MVI    E,10        ; Line feed
  2913.     CALL    CPM
  2914.     JMP    EXIT        ; All done - exit to CCP
  2915. ;.....
  2916. ;
  2917. ; Output the user number of the directory in decimal
  2918. ;
  2919. PUTUSR:    LDA    NEWUSR
  2920.     CPI    10        ; User no. < 10?
  2921.     JC    DUX        ; Yes, skip 10's digit
  2922.     STA    USRNR
  2923.     PUSH    B        ; No, process 10's digit
  2924.     MVI    C,'0'-1
  2925.  
  2926. DUY:    INR    C        ; Get tens digit
  2927.     SUI    10
  2928.     JNC    DUY        ; Loop until we've gone too far
  2929.     ADI    10
  2930.     MOV    B,A        ; Save units digit
  2931.     MOV    A,C        ; Print tens digit
  2932.     CALL    PUTCHR
  2933.     MOV    A,B        ; Recall units digit
  2934.     POP    B
  2935.  
  2936. DUX:    ADI    '0'        ; Make it ASCII
  2937.     JMP    PUTCHR
  2938.  
  2939. ;.....
  2940. ;
  2941. ; Force new line on output and check for page pause
  2942. ;
  2943. CRLF:    MVI    A,13        ; Send CR
  2944.     CALL    PUTCHR
  2945.     MVI    A,10        ; Send LF
  2946.     JMP    PUTCHR
  2947. ;.....
  2948. ;
  2949. ; Separate the directory output on a line with a space,
  2950. ; the delimiter, followed by another space.
  2951. ;
  2952. FENCE:    CALL    SPACE
  2953.  
  2954.      IF    Z80DOS OR CPM3
  2955.     LDA    NODFLG
  2956.     ORA    A
  2957.     JNZ    FENCE1
  2958.     CALL    SPACE
  2959.     CALL    SPACE
  2960. FENCE1:
  2961.      ENDIF            ; Z80DOS/CPM3
  2962.  
  2963.     MVI    A,':'        ; Fence character
  2964.     CALL    PUTCHR        ; Print it, then a space character
  2965.  
  2966.      IF    Z80DOS OR CPM3
  2967.     LDA    NODFLG
  2968.     ORA    A
  2969.     JNZ    NOD6
  2970.     CALL    SPACE
  2971.     CALL    SPACE
  2972. NOD6:
  2973.      ENDIF            ; Z80DOS/CPM3
  2974.  
  2975. SPACE:    MVI    A,' '
  2976. ;
  2977. ; Output character in A to console, and optionally to printer
  2978. ; and/or the output file.  Detects user abort request.
  2979. ;
  2980. PUTCHR:    PUSH    B
  2981.     PUSH    D
  2982.     PUSH    H
  2983.     PUSH    PSW        ; Save the character to output
  2984.     CALL    HITYPE        ; Send it to console
  2985.     POP    PSW        ; Restore the output character
  2986.     ANI    7FH        ; Strip parity bit on character
  2987. ;
  2988. ; Test file output mode and skip to page pause test if not active
  2989. ;
  2990.     MOV    B,A        ; Save stripped character to B
  2991.     CPI    10        ; At end of line?
  2992.     CZ    CKABRT        ; Check for user abort request
  2993.     LDA    FOPFLG        ; Is file output active?
  2994.     ORA    A
  2995.     JNZ    NOWRIT        ; Go check for page pause if not
  2996. ;
  2997. ; File output mode active - make sure we have room in buffer to add
  2998. ; the next character. If buffer full, write out current record first
  2999. ; and then start a new record with current character.
  3000. ;
  3001.     LHLD    BUFPNT        ; Load current buffer pointer
  3002.     LDA    BUFCNT        ; Load buffer capacity remaining
  3003.     ORA    A        ; Buffer full?
  3004.     JNZ    PUTBUF        ; No, Continue
  3005.     CALL    SETFOP        ; Yes, Set the DMA address
  3006.     LXI    D,OUTFCB    ; Else, write current buffer out
  3007.     MVI    C,WRITE
  3008.     CALL    CPM        ; (call must save character in B)
  3009.     ORA    A        ; Error?
  3010.     JNZ    WRTERR        ; Yes, exit if disk full or R/O
  3011.     LXI    H,OUTBUF    ; Reset buffer pointer
  3012.     MVI    A,128        ; Reset buffer capacity
  3013.  
  3014. PUTBUF:    MOV    M,B        ; Move char to next buffer position
  3015.     INX    H        ; Bump buffer pointer
  3016.     SHLD    BUFPNT        ; And save it
  3017.     DCR    A        ; Buffer char count-1
  3018.     STA    BUFCNT        ; And save it
  3019.  
  3020. NOWRIT:    MOV    A,B        ; Recall stripped character
  3021.     ANI    7FH        ; Strip parity bit on character
  3022.     MOV    E,A        ; Setup list output call
  3023.     MVI    C,LIST
  3024.     LDA    POPFLG        ; Load printer flag
  3025.     ORA    A        ; Set?
  3026.     CZ    CPM        ; Yes, print character
  3027.     MOV    A,E        ; Recall character
  3028.     CPI    10        ; Do we have a line feed?
  3029.     JNZ    PUTRET        ; Exit if not
  3030.     LDA    NOPFLG        ; Page pause function disabled?
  3031.     ORA    A
  3032.     JZ    PUTRET        ; Yes, exit
  3033.     LDA    POPFLG        ; Load, printer flag
  3034.     ORA    A        ; Set?
  3035.     JZ    PUTRET        ; Yes, skip page pause
  3036.     LDA    FOPFLG        ; File output flag
  3037.     ORA    A        ; Set?
  3038.     JZ    PUTRET        ; Yes, skip page pause
  3039.  
  3040.     LDA    LINCNT        ; Load line count
  3041.     INR    A        ; Bump it
  3042.     STA    LINCNT
  3043.     MVI    L,23        ; Allows use of [more] to finish display
  3044.     CMP    L        ; End of the screen?
  3045.     JC    PUTRET
  3046.  
  3047.     LXI    D,EOSMSG    ; Else, display pause message
  3048.     MVI    C,PRINT        ; Without checking for line feeds
  3049.     CALL    BDOS
  3050.     CALL    GETCH        ; Wait for character
  3051.     CPI    'C'-40H        ; Abort on CTL-C
  3052.     JZ    EXIT1
  3053.     CPI    'K'-40H        ; Or CTL-K
  3054.     JZ    EXIT1
  3055.     CPI    'X'-40H        ; Or CTL-X
  3056.     JZ    EXIT1
  3057.     CPI    ' '        ; See if printing character
  3058.     JC    NOTEOS        ; Exit if not
  3059.  
  3060.      IF    NOT VSPAGE
  3061.     JZ    NOTEOS1        ; If a space, exit to different place
  3062.      ENDIF
  3063.  
  3064.     ANI    5FH        ; Change to upper-case
  3065.     CPI    'C'        ; Can abort with c, C
  3066.     JZ    EXIT1
  3067.     CPI    'K'        ; Can abort with k, K
  3068.     JZ    EXIT1
  3069.     CPI    'X'        ; Can abort with x, X
  3070.     JZ    EXIT1
  3071.  
  3072. NOTEOS:    XRA    A        ; Reset line count
  3073.     STA    WASHERE        ; Say are starting over
  3074.  
  3075. NOTEOS1:STA    LINCNT
  3076.     LXI    D,MORERA    ; Overwrite the [more] display
  3077.     MVI    C,PRINT
  3078.     CALL    BDOS
  3079.  
  3080.      IF    VSPAGE
  3081.     LDA    VSFRST
  3082.     ORA    A
  3083.     JZ    DLINES1
  3084.     LDA    WASHERE        ; Were we here before?
  3085.     ORA    A
  3086.     JZ    WEWERE        ; Z=no
  3087.     CPI    23        ; Yes, must be moving by space bar, see how
  3088.                 ; many times
  3089.     JNZ    DLINES        ; NZ=not a full page worth yet
  3090.     XRA    A        ; A full page, move JUMPER up
  3091.     STA    WASHERE
  3092. WEWERE:    LHLD    JUMPER        ; Get current jumper
  3093.     XCHG
  3094.     LHLD    XPOINT        ; Get current position in array
  3095.     DAD    D        ; Skip the right number of files
  3096.      ENDIF
  3097.  
  3098.      IF    (Z80DOS OR CPM3) AND VSPAGE
  3099.     LDA    NODFLG
  3100.     ORA    A
  3101.     JZ    WEWERE1
  3102.     DAD    D
  3103.     DAD    D
  3104. WEWERE1:
  3105.      ENDIF            ; Z80DOS/CPM3
  3106.  
  3107.      IF    NOT (Z80DOS OR CPM3) AND VSPAGE
  3108.     DAD    D
  3109.     DAD    D
  3110.      ENDIF            ; NOT Z80DOS/CPM3
  3111.  
  3112.      IF    VSPAGE
  3113.     SHLD    XPOINT        ; New current poition in output array
  3114.     LXI    H,23        ; Calc new jumper, 23 lines/page
  3115.     LDA    LINES
  3116.     CPI    24
  3117.     JNC    MLINES
  3118.     MOV    L,A
  3119. MLINES:    CALL    MULT13
  3120.     SHLD    JUMPER
  3121. DLINES:
  3122.     LDA    WASHERE
  3123.     INR    A
  3124.     STA    WASHERE
  3125. DLINES1:
  3126.     MVI    A,1
  3127.     STA    VSFRST
  3128.      ENDIF            ; VSPAGE
  3129.  
  3130.     XRA    A        ; Reset the 'A' register
  3131. PUTRET:    POP    H        ; Exit from PUTCHR
  3132.     POP    D
  3133.     POP    B
  3134.     RET
  3135. ;.....
  3136. ;
  3137. ; Output character, with low-case or reverse-video highlighting if high
  3138. ; bit set and conditionals enabled.
  3139. ;
  3140. HITYPE:    DS    0
  3141.  
  3142.      IF    USELC OR REVID
  3143.     ORA    A        ; Check for attributes not set
  3144.     JP    CONOUT        ; No attribute..ignore this one
  3145.     ANI    7FH        ; Attribute set, delete now
  3146.      ENDIF            ; USELC OR REVID
  3147.  
  3148.      IF    NOT USELCW AND WHEEL
  3149.     MOV    E,A        ; Save the character for later
  3150.      ENDIF
  3151.  
  3152.      IF    ZCPR33 AND (NOT USELCW AND WHEEL)
  3153.     PUSH    H
  3154.     LHLD    Z3WHLL        ; Point to enviorment
  3155.     MOV    A,M        ; Get it
  3156.     POP    H
  3157.      ENDIF            ; ZCPR33
  3158.  
  3159.      IF    NOT ZCPR33 AND (NOT USELCW AND WHEEL)
  3160.     LDA    WHLOC        ; Get wheel byte
  3161.      ENDIF            ; NOT ZCPR33
  3162.  
  3163.      IF    NOT USELCW AND WHEEL
  3164.     ORA    A        ; Don't use lower case or REVID
  3165.     MOV    A,E        ; Get back the character to display
  3166.     JZ    CONOUT
  3167.      ENDIF            ; NOT USELCW AND WHEEL
  3168.  
  3169.      IF    REVID
  3170.     PUSH    PSW        ; Save character
  3171.     LXI    D,RVON        ; Turn on reverse video
  3172.     CALL    COUTS        ; If not null
  3173.     POP    PSW        ; Restore character
  3174.      ENDIF            ; REVID
  3175.  
  3176.      IF    USELC
  3177.     CPI    'A'        ; Change only from A-Z
  3178.     JC    TYPEC
  3179.     CPI    'Z'+1
  3180.     JNC    TYPEC        ; Punctuation can change so leave it
  3181.     ORI    20H        ; If attribute, make lower case
  3182.      ENDIF            ; USELC
  3183.  
  3184.      IF    USELC OR REVID
  3185. TYPEC:    CALL    CONOUT        ; Send the processed character
  3186.      ENDIF            ; USELC OR REVID
  3187.  
  3188.      IF    REVID
  3189.     LXI    D,RVOFF        ; Turn off reverse video
  3190.     CALL    COUTS        ; If not null
  3191.      ENDIF            ; REVID
  3192.  
  3193.      IF    USELC OR REVID
  3194.     RET
  3195.      ENDIF            ; USELC OR REVID
  3196. ;.....
  3197. ;
  3198. ; Output character in A to console
  3199. ;
  3200. CONOUT:    MOV    E,A        ; Get character for BDOS entry
  3201.     MVI    C,WRCON
  3202.     JMP    BDOS        ; Console Output
  3203. ;.....
  3204. ;
  3205. ; Output (raw) null-terminated string at (DE) to console.
  3206. ;
  3207.  
  3208. COUTS:    LDAX    D        ; Get byte of string
  3209.     ORA    A        ; Null?
  3210.     RZ            ; Return if so
  3211.     PUSH    D
  3212.     CALL    CONOUT
  3213.     POP    D
  3214.     INX    D        ; Next byte
  3215.     JMP    COUTS
  3216. ;.....
  3217. ;
  3218. ; Output bytes at HL of length B to console/printer/file
  3219. ;
  3220. PUTSB:    MOV    A,M
  3221.     CALL    PUTCHR
  3222.     INX    H
  3223.     DCR    B
  3224.     JNZ    PUTSB
  3225.     RET
  3226. ;.....
  3227. ;
  3228. ; Output null-terminated string to console/printer/file
  3229. ;
  3230. PUTS:    LDAX    D        ; Load character from DE string
  3231.     ANI    7FH        ; Strip off parity
  3232.     ORA    A        ; Is a 0?
  3233.     RZ            ; Yes, Terminate
  3234.     CALL    PUTCHR        ; Display character
  3235.     INX    D        ; Next string position
  3236.     JMP    PUTS        ; Continue
  3237. ;.....
  3238. ;
  3239. ; Fetch character from console (without echo)
  3240. ;
  3241. GETCH:    LHLD    0000H+1        ; Warm Boot Address
  3242.     MVI    L,9        ; Direct Console
  3243.     CALL    GOHL        ; Get Character
  3244.     ANI    7FH        ; Strip off any parity
  3245.     RET
  3246. ;.....
  3247. ;
  3248. ; Check for a CTL-C or CTL-S entered from the keyboard.  Jump to EXIT if
  3249. ; CTL-C, pause on CTL-S.
  3250. ;
  3251. CKABRT:    PUSH    H
  3252.     PUSH    D
  3253.     PUSH    B
  3254.     MVI    C,CONST
  3255.     CALL    BDOS
  3256.     ORA    A
  3257.     JZ    CKAB3        ; No character, exit
  3258.     MVI    C,RDCON
  3259.     CALL    BDOS
  3260.     ANI    5FH
  3261.     CPI    'S'-40H
  3262.     JZ    CKAB0
  3263.     CPI    'S'
  3264.     JNZ    CKAB1
  3265.     CALL    CKAB4
  3266.  
  3267. CKAB0:    MVI    C,RDCON
  3268.     CALL    BDOS
  3269.     ANI    5FH
  3270.  
  3271. CKAB1:    CPI    'C'-40H        ; CTL-C?
  3272.     JZ    CKAB2        ; Yes, quit
  3273.     CPI    'K'-40H
  3274.     JZ    CKAB2
  3275.     CPI    'X'-40H
  3276.     JZ    CKAB2
  3277.     CPI    ' '        ; Any other CTL-character, abort
  3278.     JC    CKAB3
  3279.     CALL    CKAB4        ; Clear the character from screen
  3280.     CPI    'C'
  3281.     JZ    CKAB2
  3282.     CPI    'K'
  3283.     JZ    CKAB2
  3284.     CPI    'X'
  3285.     JNZ    CKAB3
  3286.  
  3287. CKAB2:    LXI    D,CKMS1
  3288.     CALL    PUTS
  3289.     POP    B
  3290.     POP    D
  3291.     POP    H
  3292.     JMP    EX0        ; All done
  3293.  
  3294. CKAB3:    POP    B
  3295.     POP    D
  3296.     POP    H
  3297.     RET
  3298.  
  3299. CKAB4:    PUSH    PSW
  3300.     LXI    D,CKMS2
  3301.     CALL    PUTS
  3302.     POP    PSW
  3303.     RET
  3304. ;.....
  3305. ;
  3306. ; Call here to call address in HL
  3307. ;
  3308. GOHL:    PCHL
  3309. ;
  3310. ; Enter BDOS, save all extended registers
  3311. ;
  3312. CPM:    PUSH    B        ; Save Registers
  3313.     PUSH    D
  3314.     PUSH    H
  3315.  
  3316.      IF    ZRDOS
  3317.     LDA    ZRDFLG        ; ZRDOS running?
  3318.     ORA    A
  3319.     JNZ    ZRD        ; ZRDOS error trap and DOSs call
  3320.      ENDIF            ; ZRDOS
  3321.  
  3322.     CALL    BDOS
  3323.     MOV    B,A        ; Save return code
  3324.     LDA    VERFLG        ; Is this 3.0?
  3325.     CPI    30H
  3326.     MOV    A,B
  3327.     JC    CPM20        ; No, exit normally
  3328.     CPI    0FFH        ; Yes, was return code FF?
  3329.     JNZ    CPM20        ; No, exit normally
  3330.     MOV    A,H        ; Yes, check for error code
  3331.     ORA    A
  3332.     JNZ    DSKERR        ; Exit if physical error
  3333.     MOV    A,B        ; Else, continue normally
  3334.  
  3335. CPM20:    POP    H
  3336.     POP    D
  3337.     POP    B
  3338.     RET
  3339. ;.....
  3340. ;
  3341. ; ZRDOS Error Trap and System Call exits to CPM20
  3342. ;
  3343.      IF    ZRDOS
  3344. ZRD:    CALL    SETTRAP        ; Set the warm boot trap
  3345.     CALL    BDOS        ; Do what we're told
  3346.     CALL    RESTRAP        ; Reset the trap
  3347.     JMP    CPM20        ; Error free exit
  3348. ;.....
  3349. ;
  3350. ; Set Warm Boot Trap in ZRDOS
  3351. ;
  3352. SETTRAP:PUSH    H
  3353.     PUSH    D
  3354.     PUSH    B
  3355.     MVI    C,SETWBT    ; Set warm boot trap to come here
  3356.     LXI    D,WBTRAP
  3357.     CALL    BDOS
  3358.     POP    B
  3359.     POP    D
  3360.     POP    H
  3361.     RET
  3362. ;.....
  3363. ;
  3364. ; WBTRAP is where the ZRDOS returns control on warm boot (error)
  3365. ;
  3366. WBTRAP:    LXI    H,DSKERR    ; Return here after trap reset
  3367.     PUSH    H        ; Save DSKERR on stack
  3368. ;
  3369. ; Reset Warm Boot Trap in ZRDOS
  3370. ;
  3371. RESTRAP:PUSH    H
  3372.     PUSH    D
  3373.     PUSH    B
  3374.     PUSH    PSW
  3375.     MVI    C,RESWBT    ; Reset warm boot trap
  3376.     CALL    BDOS
  3377.     POP    PSW
  3378.     POP    B
  3379.     POP    D
  3380.     POP    H
  3381.     RET
  3382.      ENDIF            ; ZRDOS
  3383. ;.....
  3384. ;
  3385. ; For file output mode, return to old user area and set DMA for the file
  3386. ; output buffer.
  3387. ;
  3388. SETFOP:    CALL    CKVER        ; Clear carry if CP/M 2 or later
  3389.     LDA    OLDUSR        ; Get user number at startup
  3390.     MOV    E,A
  3391.     MVI    C,STUSER
  3392.     CNC    CPM        ; Reset old user number if CP/M 2
  3393.     LXI    D,OUTBUF    ; Move DMA from search buffer into
  3394.     JMP    SET2        ; Output buffer
  3395.     RET
  3396. ;.....
  3397. ;
  3398. ; Move disk buffer DMA to default buffer for directory search operations
  3399. ; and BDOS media change routines (required for pre-CP/M 2 systems while
  3400. ; in file output mode with active buffer).
  3401. ;
  3402. SETSRC:    LXI    D,TBUF        ; Default DMA Address
  3403.  
  3404. SET2:    MVI    C,STDMA        ; Set DMA Address
  3405.     JMP    CPM
  3406. ;.....
  3407. ;
  3408. ; Print amount of free space remaining on selected drive
  3409. ;
  3410. PRTFRE:    LXI    D,TOTMS7    ; Print " Free: '
  3411.     CALL    PUTS
  3412.     LHLD    FREEBY
  3413.     CALL    DECPRT        ; Print k free
  3414.     LXI    D,TOTMS8    ; Print "k "
  3415.     CALL    PUTS
  3416.     LDA    VFLAG        ; Alphabetizing vertically?
  3417.     ORA    A
  3418.     RZ            ; If yes, finished
  3419.     JMP    CRLF        ; Else turn up an extra line
  3420. ;.....
  3421. ;
  3422. ; Show string on the console
  3423. ;
  3424. SHOW:    LDAX    D        ; Get character from DE string
  3425.     ANI    7FH        ; Strip off parity
  3426.     ORA    A        ; Is it a 0?
  3427.     RZ            ; Yes, terminate
  3428.     PUSH    B        ; Save registers
  3429.     PUSH    D
  3430.     PUSH    H
  3431.     CALL    CONOUT        ; Show character on console
  3432.     POP    H        ; Load registers
  3433.     POP    D
  3434.     POP    B
  3435.     INX    D        ; Next string position
  3436.     JMP    SHOW        ; Continue
  3437. ;.....
  3438. ;
  3439. ; Compare routine for last extent of file search
  3440. ;
  3441. COMPR:    PUSH    H        ; Save table address
  3442.     MOV    E,M        ; Load low order
  3443.     INX    H
  3444.     MOV    D,M        ; Load high order
  3445.     INX    H
  3446.     MOV    C,M
  3447.     INX    H
  3448.     MOV    B,M
  3449. ;
  3450. ; BC, DE now point to entries to be compared
  3451. ;
  3452.     XCHG
  3453.     MOV    E,A        ; Get count
  3454.  
  3455. CMPLP:    LDAX    B
  3456.     XRA    M        ; Copy bit 7 of M
  3457.     ANI    7FH        ; Into bit 7 of A
  3458.     XRA    M
  3459.     CMP    M        ; Then compare
  3460.     INX    H
  3461.     INX    B
  3462.     JNZ    NOTEQL        ; Quit on mismatch
  3463.     DCR    E        ; Or end of count
  3464.     JNZ    CMPLP
  3465. ;
  3466. NOTEQL:    POP    H
  3467.     RET            ; Condition code tells all
  3468. ;.....
  3469. ;
  3470. ; Swap entries in the order table
  3471. ;
  3472. SWAP:    LXI    B,ORDER-2    ; Table base
  3473.     DAD    H        ; *2
  3474.     DAD    B        ; + base
  3475.     XCHG
  3476.     DAD    H        ; *2
  3477.     DAD    B        ; + base
  3478.     MOV    C,M
  3479.     LDAX    D
  3480.     XCHG
  3481.     MOV    M,C
  3482.     STAX    D
  3483.     INX    H
  3484.     INX    D
  3485.     MOV    C,M
  3486.     LDAX    D
  3487.     XCHG
  3488.     MOV    M,C
  3489.     STAX    D
  3490.     RET
  3491. ;.....
  3492. ;
  3493. ; New compare routine for sorting
  3494. ;
  3495. COMPARE:LXI    B,ORDER-2
  3496.     DAD    H
  3497.     DAD    B
  3498.     XCHG
  3499.     DAD    H
  3500.     DAD    B
  3501.     XCHG
  3502.     MOV    C,M
  3503.     INX    H
  3504.     MOV    B,M
  3505.     XCHG
  3506.     MOV    E,C
  3507.     MOV    D,B
  3508.     MOV    C,M
  3509.     INX    H
  3510.     MOV    H,M
  3511.     MOV    L,C
  3512.     MVI    B,13        ; Count for normal sort
  3513.     LDA    TOPFLG        ; Check for sort by type
  3514.     ORA    A
  3515.     JNZ    CMPLPE        ; Jump if normal sort
  3516.     PUSH    H        ; Save name pointers for later
  3517.     PUSH    D
  3518.     LXI    B,8        ; Point to file types
  3519.     DAD    B
  3520.     XCHG
  3521.     DAD    B
  3522.     XCHG
  3523.     MVI    B,3        ; Count for type compare
  3524.     CALL    CMPLPE
  3525.     POP    D        ; Retrieve name pointers
  3526.     POP    H        ; 
  3527.     RNZ
  3528.     MVI    B,8        ; Count for name compare
  3529.     CALL    CMPLPE
  3530.     RNZ
  3531.     INX    D        ; Point to extent
  3532.     INX    D
  3533.     INX    D
  3534.     INX    H
  3535.     INX    H
  3536.     INX    H
  3537.     MVI    B,2        ; Count for extent compare
  3538.  
  3539. CMPLPE:    LDAX    D        ; 
  3540.     XRA    M        ; Copy bit 7 of M
  3541.     ANI    7FH        ; Into bit 7 of A
  3542.     XRA    M        ; 
  3543.     CMP    M        ; Then compare
  3544.     INX    D
  3545.     INX    H
  3546.     RNZ
  3547.     DCR    B
  3548.     JNZ    CMPLPE
  3549.     RET
  3550. ;.....
  3551. ;
  3552. ; Error exit
  3553. ;
  3554. ERXIT:    MVI    A,0FFH        ; Error Flag
  3555.     STA    FOPFLG        ; Disable file output on error
  3556.     CALL    CRLF        ; Space down
  3557.     POP    D        ; Load message string pointer
  3558.     CALL    PUTS        ; Print message
  3559.     LXI    D,ERRMS1    ; " Error"
  3560.     CALL    PUTS        ; Print message
  3561.     CALL    CRLF        ; Space down
  3562. ;
  3563. ; Exit - all done, restore stack
  3564. ;
  3565. EXIT:    LDA    DOPFLG        ; Multi-disk selected?
  3566.     ORA    A
  3567.     JNZ    EX0        ; No, skip next
  3568.     CALL    CKABRT        ; Check for user abort
  3569.     MVI    A,HIDRV-LODRV    ; Maximum drive code to search
  3570.     LXI    H,FCB        ; Increment directory FCB drive code
  3571.     INR    M
  3572.     CMP    M        ; Does next disk exceed maximum?
  3573.     JC    EX0
  3574.  
  3575. ;     IF    MAXDRV
  3576.  
  3577.      IF    ZCPR33 AND MAXDRV
  3578.     PUSH    H
  3579.     LHLD    Z3DRVL        ; Point to ENV
  3580.     MOV    A,M        ; Get it
  3581.     POP    H
  3582.      ENDIF            ; ZCPR33
  3583.  
  3584.      IF    NOT ZCPR33 AND MAXDRV
  3585.     LDA    MXDRV        ; Look at another value limit
  3586.     INR    A
  3587.      ENDIF            ; NOT ZCPR33
  3588.  
  3589.      IF    MAXDRV
  3590.     CMP    M        ; Is it lower?
  3591.     JC    EX0        ; Bail out if too low
  3592.     JMP    NOOPT        ; Search next disk
  3593.      ENDIF            ; MAXDRV
  3594.  
  3595.     JNC    NOOPT        ; Search next disk if MAXDR not true
  3596.  
  3597. EX0:    LDA    VFLAG        ; Check display form
  3598.     ORA    A
  3599.     CZ    CRLF        ; Turn up a blank line at end if vertical
  3600.     MVI    C,CONST        ; Check console status
  3601.     CALL    CPM
  3602.     ORA    A        ; Character waiting?
  3603.     MVI    C,RDCON
  3604.     CNZ    CPM        ; Gobble up character
  3605.  
  3606.      IF    ZRDOS
  3607.     LDA    ZRDFLG        ; ZRDOS running?
  3608.     ORA    A
  3609.     JNZ    EXIT2        ; Yes
  3610.      ENDIF            ; ZRDOS
  3611.  
  3612.     LDA    VERFLG        ; Version flag
  3613.     CPI    30H        ; CP/M 3.0?
  3614.     JC    EXIT1        ; No
  3615.     MVI    C,2DH        ; Yes,
  3616.     MVI    E,0        ; Reset error mode to default
  3617.     CALL    CPM
  3618.     JMP    EXIT2        ; Quit
  3619.  
  3620. EXIT1:    LDA    DOPFLG        ; If they were swapped
  3621.     ORA    A
  3622.     CZ    SWAPEM
  3623.  
  3624. EXIT2    EQU    $
  3625.  
  3626.      IF    SHOPUB
  3627.     CALL    RSTPUB
  3628.      ENDIF            ; SHOPUB
  3629.  
  3630.     LDA    AOPFLG        ; Doing all users
  3631.     MOV    C,A
  3632.     LDA    DOPFLG        ; Or disk?
  3633.     ANA    C
  3634.     MOV    C,A
  3635.     LDA    HOPFLG        ; Or higher users?
  3636.     ANA    C
  3637.     JNZ    TOTDONE        ; If no, skip totals
  3638.     MVI    A,1        ; Force no file output
  3639.     STA    LINCNT
  3640.     STA    FOPFLG
  3641.     LXI    D,ALLTOT    ; First part of message
  3642.     CALL    PUTS
  3643.     LHLD    TOTFL1        ; Total files found
  3644.     CALL    DECPRT
  3645.     LXI    D,TOTMS4
  3646.     CALL    PUTS
  3647.     LHLD    TOTSZ1        ; Total 'k' found
  3648.     CALL    DECPRT
  3649.     LXI    D,TOTMS8
  3650.     CALL    PUTS
  3651.     LXI    D,TOTMS7
  3652.     CALL    PUTS
  3653.     LHLD    TOTFRE
  3654.     CALL    DECPRT
  3655.     LXI    D,ALLTO1
  3656.     CALL    PUTS
  3657. TOTDONE:
  3658.      IF    WMBOOT
  3659.     JMP    0000H
  3660.      ENDIF            ; WMBOOT
  3661.  
  3662.     LDA    OLDDSK        ; Restore original drive
  3663.     MOV    E,A
  3664.     MVI    C,14
  3665.     CALL    CPM
  3666.     LDA    OLDUSR        ; Restore original user area
  3667.     MOV    E,A
  3668.     MVI    C,32
  3669.     CALL    CPM
  3670.  
  3671. EXIT3:    LHLD    STACK        ; Get old stack pointer
  3672.     SPHL            ; Move back to old stack
  3673.     RET            ; And return to CCP
  3674. ;.....
  3675. ;
  3676. ; Restore Public areas if they were changed
  3677. ;
  3678.      IF    SHOPUB
  3679. RSTPUB:    LHLD    0109H
  3680.     MVI    D,0
  3681.     MVI    E,07EH
  3682.     DAD    D
  3683.     LDA    PUBDRV
  3684.     MOV    M,A
  3685.     INX    H
  3686.     LDA    PUBUSR
  3687.     MOV    M,A
  3688.     RET
  3689.      ENDIF            ; SHOPUB
  3690. ;.....
  3691. ;
  3692.      IF    NDIRS
  3693. NAMDIR:    MVI    A,0
  3694.     STA    CURDIR        ; Initial check count
  3695.  
  3696. NAMDR1:    LHLD    NAMADR        ; Named directory buffer address
  3697.  
  3698. NAMDR2:    LDA    FCB        ; Get current Drive
  3699.     CMP    M        ; Does NDR entry match current drive?
  3700.     JNZ    NXTDIR        ; No, check next
  3701.     LDA    NEWUSR        ; Get current user
  3702.     INX    H
  3703.     CMP    M        ; Does NDR entry match current user?
  3704.     JNZ    NXTDIR        ; No, check next
  3705.     MVI    A,'['        ; Frame the name in brackets
  3706.     CALL    PUTCHR
  3707.     MVI    C,8        ; Number of Characters in entry
  3708.  
  3709. DIRCHR:    INX    H        ; Match, Point to Directory Name
  3710.     MOV    A,M        ; Get Character
  3711.     CPI    20H        ; End of entry?
  3712.     JNZ    DIRCH1        ; No
  3713.  
  3714. DIRCH0:    PUSH    PSW
  3715.     MVI    A,']'        ; Print closing bracket
  3716.     CALL    PUTCHR
  3717.     POP    PSW
  3718.     JMP    DIRCH2
  3719.  
  3720. DIRCH1:    CALL    PUTCHR
  3721.     DCR    C
  3722.     JNZ    DIRCHR        ; Output Eight characters
  3723.     JMP    DIRCH0
  3724.     RET            ; Done
  3725. DIRCH2:    MOV    A,C
  3726.     ORA    A
  3727.     RZ
  3728.     MVI    A,20H        ; Fill with spaces for neatness sake
  3729.     CALL    PUTCHR
  3730.     DCR    C
  3731.     JNZ    DIRCH2
  3732.     RET
  3733.  
  3734. NXTDIR:    LDA    CURDIR
  3735.     ADI    1        ; Increment Directory pointer
  3736.     STA    CURDIR
  3737.     LXI    H,NUMDIR
  3738.     CMP    M        ; Exceeded Max Entry?
  3739.     JZ    NODIR        ; Yes, there is no entry for this DU
  3740.     LHLD    NAMADR        ; Get base NDR address
  3741.     MVI    D,0
  3742.     MVI    E,18        ; Increment to next entry
  3743.  
  3744. NXTD:    DAD    D
  3745.     DCR    A        ; Decrement count
  3746.     JNZ    NXTD        ; Until current Offset reached
  3747.     JMP    NAMDR2        ; And check the entry for a match
  3748. NODIR:    MVI    C,10        ; No match, output ten spaces
  3749.  
  3750. NODIR1:    MVI    A,20H
  3751.     CALL    PUTCHR
  3752.     DCR    C
  3753.     JNZ    NODIR1
  3754.     RET
  3755.      ENDIF            ; NDIRS
  3756. ;.....
  3757. ;
  3758. ; Trap BDOS select and sector error vectors to our own intercept routine
  3759. ; so we can catch a reference to an illegal drive.
  3760. ;
  3761. SWAPEM:    DS    0
  3762.  
  3763.      IF    ZRDOS
  3764.     LDA    ZRDFLG        ; See if ZRDOS running
  3765.     ORA    A
  3766.     RNZ            ; Yes, quit this
  3767.      ENDIF            ; ZRDOS
  3768.  
  3769.     LDA    VERFLG        ; Version flag
  3770.     CPI    30H        ; Error mode call available?
  3771.     JC    SWAP20        ; No, use BDOS error vectors
  3772.     MVI    C,2DH        ; Yes, use error mode call
  3773.     MVI    E,0FFH        ; 
  3774.     CALL    CPM        ; Set "return code only" mode
  3775.     RET
  3776.  
  3777. SWAP20:    LHLD    BDOS+1        ; Load pointer to base of BDOS
  3778.     INX    H        ; Swap new pointer if running a
  3779.     MOV    E,M        ; Program below the CCP
  3780.     INX    H
  3781.     MOV    D,M
  3782.     XCHG            ; HL points to the proper vector
  3783.     MVI    L,9        ; Point to record error vector
  3784.     LXI    D,VECTBL    ; Exchange with our vector table
  3785.     MVI    A,4        ; 4 bytes to swap
  3786.  
  3787. SWAPLP:    MOV    B,M        ; Load byte from HL
  3788.     XCHG
  3789.     MOV    C,M        ; Load byte from DE
  3790.     MOV    M,B        ; Save byte from HL
  3791.     XCHG
  3792.     MOV    M,C        ; Save byte from DE
  3793.     INX    H        ; Increment exchange pointers
  3794.     INX    D
  3795.     DCR    A        ; Counter-1
  3796.     JNZ    SWAPLP        ; Continue swapping
  3797.     RET
  3798. ;.....
  3799. ;
  3800. ; Check CP/M version number. Return carry flag set if pre-CP/M 2.  If
  3801. ; CP/M 2 or later or MP/M (any version), return carry clear.
  3802. ;
  3803. CKVER:    LDA    VERFLG        ; Version Flag
  3804.     CPI    20H        ; CP/M 2.0?
  3805.     RET
  3806. ;.....
  3807. ;
  3808. ; Return point from intercepted BDOS select and bad record errors.
  3809. ;
  3810. DSKERR:    LXI    SP,STACK    ; Get out of BDOS' stack
  3811.     JMP    EXIT        ; And exit back to CCP
  3812. ;.....
  3813. ;
  3814. ;-----------------------------------------------------------------------
  3815. ;             Start of FNAME routine
  3816. ;
  3817. ; Main module
  3818. ;    on entry, DE points to FCB to be filled, HL points to first
  3819. ;        byte of target string, RFCB is 36 bytes long
  3820. ;    on exit, B=disk number (1 for A, etc.) and C=user number
  3821. ;        HL points to terminating character
  3822. ;        A=0 and Z set if error in disk or user numbers
  3823. ;        A=0FFH and NZ if ok
  3824. ;
  3825. MAXDISK EQU    16        ; Maximum number of disks
  3826. MAXUSER EQU    31        ; Maximum user number
  3827.  
  3828. FNAME:    PUSH    D        ; Save DE
  3829.     MVI    A,0FFH        ; Set default disk and user
  3830.     STA    DISKNO
  3831.     STA    USERNO
  3832.     MVI    B,36        ; Initialize FCB
  3833.     PUSH    D        ; Save pointer
  3834.     XRA    A        ; A=0
  3835.  
  3836. FNINI:    STAX    D        ; Store zero
  3837.     INX    D        ; Point to next
  3838.     DCR    B        ; Count down
  3839.     JNZ    FNINI
  3840.     POP    D        ; Get pointer back
  3841.     PUSH    H        ; Save pointer
  3842. ;
  3843. ; Scan for colon, comma, or space in string
  3844. ;
  3845. COLON:    MOV    A,M        ; Scan for colon or space
  3846.     INX    H        ; Point to next
  3847.     CPI    ':'        ; Colon found?
  3848.     JZ    COLON1
  3849.     CPI    ','        ; Comma found?
  3850.     JZ    GETF1
  3851.     CPI    ' '+1        ; Delimiter?
  3852.     JC    GETF1
  3853.     JMP    COLON        ; Continue if not EOL
  3854. ;
  3855. COLON1:    POP    H        ; Clear stack
  3856.     MOV    A,M        ; Save possible drive specification
  3857.     CALL    CAPS        ; Capitalize
  3858.     CPI    'A'        ; Digit if less than "A"
  3859.     JC    USERCK        ; Process user number
  3860.     SUI    'A'        ; Change from ASCII to binary
  3861.     CPI    MAXDISK        ; Within bounds?
  3862.     JC    SVDISK
  3863. ;
  3864. ERREXIT:XRA    A        ; Error indicator
  3865.     POP    D        ; Restore DE
  3866.     RET
  3867. ;.....
  3868. ;
  3869. ; Log in specified disk
  3870. ;
  3871. SVDISK:    INR    A        ; Adjust to 1 for "A"
  3872.     STA    DISKNO        ; Save flag
  3873.     INX    H        ; Point to next character
  3874. ;
  3875. ; Check for user
  3876. ;
  3877. USERCK:    MOV    A,M        ; Get possible user #
  3878.     CPI    ':'        ; No user number
  3879.     JZ    GETFILE
  3880.     CPI    '?'        ; All user numbers?
  3881.     JNZ    USERC1
  3882.     STA    USERNO        ; Set value
  3883.     INX    H        ; Point to after
  3884.     MOV    A,M        ; Must be colon
  3885.     CPI    ':'
  3886.     JZ    GETFILE
  3887.     JMP    ERREXIT        ; Fatal error if not colon after ?
  3888.  
  3889. USERC1:    XRA    A        ; Zero user number
  3890.     MOV    B,A        ; B = A for user number
  3891.  
  3892. USRLOOP:MOV    A,M        ; Get digit
  3893.     INX    H        ; Point to next
  3894.     CPI    ':'        ; Done?
  3895.     JZ    USRDN
  3896.     SUI    '0'        ; Convert to binary
  3897.     JC    ERREXIT        ; User number error?
  3898.     CPI    10
  3899.     JNC    ERREXIT
  3900.     MOV    C,A        ; Next digit in C
  3901.     MOV    A,B        ; Old number in A
  3902.     ADD    A        ; *2
  3903.     ADD    A        ; *4
  3904.     ADD    B        ; *5
  3905.     ADD    A        ; *10
  3906.     ADD    C        ; *10+new digit
  3907.     MOV    B,A        ; Result in B
  3908.     JMP    USRLOOP
  3909.  
  3910. USRDN:    MOV    A,B        ; Get newer user number
  3911.     CPI    MAXUSER+1    ; Within range?
  3912.     JNC    ERREXIT
  3913.     STA    USERNO        ; Save in flag
  3914.     JMP    GETFILE
  3915. ;
  3916. ; Extract file name
  3917. ;
  3918. GETF1:    POP    H        ; Get pointer to byte
  3919. ;
  3920. GETFILE:MOV    A,M        ; Pointing to colon?
  3921.     CPI    ':'
  3922.     JNZ    GFILE1
  3923.     INX    H        ; Skip over colon
  3924.  
  3925. GFILE1:    MOV    A,M        ; Get next character
  3926.     CPI    ','        ; Delimiter?
  3927.     JZ    GFQUES
  3928.     CPI    ' '+1        ; Not a delimiter?
  3929.     JNC    GFILE2
  3930.  
  3931. GFQUES:    INX    D        ; Fill with ???
  3932.     MVI    B,11        ; 11 bytes
  3933.     MVI    A,'?'
  3934.  
  3935. GFFILL:    STAX    D        ; Put?
  3936.     INX    D        ; Point to next
  3937.     DCR    B        ; Count down
  3938.     JNZ    GFFILL
  3939.  
  3940. FNDONE:    LDA    DISKNO        ; Get disk number
  3941.     MOV    B,A        ; In 'B'
  3942.     LDA    USERNO        ; Get user number
  3943.     MOV    C,A        ; In 'C'
  3944.     POP    D        ; Restore registers
  3945.     MVI    A,0FFH        ; No error
  3946.     ORA    A        ; Set flags
  3947.     RET
  3948. ;
  3949. ; Get file name fields
  3950. ;
  3951. GFILE2:    MVI    B,8        ; At most, 8 byte filename
  3952.     CALL    SCANF        ; Scan and fill
  3953.     MVI    B,3        ; At most, 3 byte filetype
  3954.     MOV    A,M        ; Get delimiter
  3955.     CPI    '.'        ; Filename ending in "."?
  3956.     JNZ    GFILE3
  3957.     INX    H        ; Point to character after "."
  3958.     CALL    SCANF        ; Scan and fill
  3959.     JMP    FNDONE        ; Done, return to "args"
  3960.  
  3961. GFILE3:    CALL    SCANF4        ; Fill with spaces
  3962.     JMP    FNDONE
  3963. ;
  3964. ; Scanner routine
  3965. ;
  3966. SCANF:    CALL    DELCK        ; Check for delimiter
  3967.     JZ    SCANF4        ; Fill with spaces if found
  3968.     INX    D        ; Next byte in filename
  3969.     CPI    '*'        ; Question mark fill ?
  3970.     JNZ    SCANF1
  3971.     MVI    A,'?'        ; Place "?"
  3972.     STAX    D
  3973.     JMP    SCANF2
  3974.  
  3975. SCANF1:    STAX    D        ; Place character
  3976.     INX    H        ; Next position
  3977.  
  3978. SCANF2:    DCR    B        ; Count down
  3979.     JNZ    SCANF        ; Continue loop
  3980.  
  3981. SCANF3:    CALL    DELCK        ; Skip to delimiter
  3982.     RZ
  3983.     INX    H        ; Point to next
  3984.     JMP    SCANF3
  3985.  
  3986. SCANF4:    INX    D        ; Next filename or filetype
  3987.     MVI    A,' '        ; Fill with spaces
  3988.     STAX    D
  3989.     DCR    B        ; Count down
  3990.     JNZ    SCANF4
  3991.     RET
  3992. ;.....
  3993. ;
  3994. ; Check character pointed to by HL for a delimiter,
  3995. ; return with Zero flag set if the character is a delimiter
  3996. ;
  3997. DELCK:    MOV    A,M        ; Get the character
  3998.     CALL    CAPS        ; Capitalize
  3999.     ORA    A        ; 0=delimiter
  4000.     RZ
  4001.     CPI    ' '+1        ; Space character+1
  4002.     JC    DELCK1        ; Space character or less
  4003.     CPI    '='
  4004.     RZ
  4005.     CPI    5FH        ; Underscore
  4006.     RZ
  4007.     CPI    '.'
  4008.     RZ
  4009.     CPI    ':'
  4010.     RZ
  4011.     CPI    ';'
  4012.     RZ
  4013.     CPI    ','
  4014.     RZ
  4015.     CPI    '<'
  4016.     RZ
  4017.     CPI    '>'
  4018.     RET
  4019. ;
  4020. DELCK1:    CMP    M        ; Compare with self for OK
  4021.     RET
  4022. ;.....
  4023. ;
  4024. CAPS:    CPI    'a'
  4025.     RC
  4026.     CPI    'z'+1
  4027.     RNC
  4028.     SUI    20H
  4029.     RET
  4030. ;.....
  4031. ;              End of FNAME routine
  4032. ;-----------------------------------------------------------------------
  4033. ;
  4034. ; Subroutines to read library file directory
  4035. ;
  4036. PRTLMEM:LXI    H,ORDER        ; Initialize order table pointer
  4037.     SHLD    NEXTL
  4038.     XRA    A
  4039.     STA    LNCNT
  4040.  
  4041. ENTRYL:    LHLD    LCOUNT        ; Get FCB count
  4042.     DCX    H        ; Decrement it
  4043.     SHLD    LCOUNT
  4044.     MOV    A,H        ; Is this the last file?
  4045.     ORA    L
  4046.     JZ    LBRTST        ; Yes, skip compare
  4047.     PUSH    B
  4048.     CALL    CKABRT        ; Keyboard abort?
  4049.     LHLD    NEXTL
  4050.     MVI    A,11
  4051.     CALL    COMPR        ; This entry match next one?
  4052.     POP    B
  4053.     JNZ    LBRTST        ; No, print it
  4054.     INX    H
  4055.     INX    H        ; Skip, highest extent last in list
  4056.     SHLD    NEXTL
  4057.     JMP    ENTRYL        ; Loop back for next lowest extent
  4058. ;.....
  4059. ;
  4060. ; Exit Library member printing
  4061. ;
  4062. LBEXIT:    LHLD    LMTOTL
  4063.     MOV    A,H
  4064.     ORA    L
  4065.     RZ
  4066.     PUSH    H        ; Save member count
  4067.     XRA    A        ; Get a zero to
  4068.     STA    SUPSPC        ; Suppress leading spaces in totals
  4069.  
  4070.      IF    Z80DOS
  4071.     MVI    L,2        ; If last line is full, don't turn
  4072.     LDA    NODFLG
  4073.     ORA    A
  4074.     JZ    NOD7
  4075.     MVI    L,4
  4076. NOD7:
  4077.      ENDIF            ; Z80DOS
  4078.  
  4079.      IF    NOT Z80DOS
  4080.     MVI    L,4        ; If last line is full, don't turn
  4081.      ENDIF            ; NOT Z80DOS
  4082.  
  4083.     LDA    LNCNT
  4084.     CMP    L        ; Up extra line
  4085.     CNZ    CRLF        ; If partial line, extra line needed
  4086.     LXI    D,CONTM1    ; Print "There are "
  4087.     CALL    PUTS
  4088.     POP    H        ; Get total member count back
  4089.     CALL    DECPRT
  4090.     LXI    D,MFILES    ; Print "Members in "
  4091.     CALL    PUTS
  4092.     LHLD    LBTOTL
  4093.     CALL    DECPRT
  4094.     LXI    D,LIBR
  4095.     JMP    PUTS
  4096. ;
  4097. ; Valid entry obtained - spit it out
  4098. ;
  4099. LBRTST:    MVI    A,1        ; Turn off .ARC/ARK
  4100.     STA    ISARC
  4101.     LHLD    NEXTL        ; Load order table pointer
  4102.     MOV    E,M        ; Low order address
  4103.     INX    H
  4104.     MOV    D,M        ; High order address
  4105.     INX    H
  4106.     SHLD    NEXTL        ; Save updated table pointer
  4107.     LXI    H,8
  4108.     DAD    D
  4109.     CALL    CKLBR
  4110.     JZ    LBRSET
  4111.     CALL    CKARC
  4112.     JNZ    LBRNEX
  4113.     XRA    A
  4114.     STA    ISARC
  4115.  
  4116. LBRSET:    PUSH    D
  4117.  
  4118.      IF    Z80DOS OR CPM3
  4119.     LDA    NODFLG
  4120.     ORA    A
  4121.     JNZ    ZARC0
  4122.     LDA    ISARC
  4123.     ORA    A
  4124.     JZ    ZARC0
  4125.     MVI    L,2        ; 2 NAMES PER LINE
  4126.     JMP    ZARC0A
  4127. ZARC0:    MVI    L,4        ; 4 NAMES PER LINE
  4128. ZARC0A:    LDA    LNCNT
  4129.      ENDIF            ; Z80DOS/CPM3
  4130.  
  4131.      IF    NOT (Z80DOS OR CPM3)
  4132.     LDA    LNCNT
  4133.     MVI    L,4
  4134.      ENDIF            ; NOT Z80DOS/CPM3
  4135.  
  4136.     CMP    L
  4137.     CNZ    CRLF
  4138.     PUSH    PSW        ; Just in case
  4139.     LXI    D,LFMSP1    ; Long Library directory message
  4140.     LDA    ISARC
  4141.     ORA    A
  4142.     JNZ    SARCM1
  4143.     LXI    D,AFMSP1
  4144.  
  4145. SARCM1:    CALL    PUTS        ; Print it
  4146.     POP    PSW        ; Put it back
  4147.     LDA    FCB        ; Load current drive
  4148.     ADI    'A'-1        ; Convert to ASCII
  4149.     CALL    PUTCHR        ; Print it
  4150.     CALL    PUTUSR        ; Print user # after it
  4151.     MVI    A,':'        ; And colon
  4152.     CALL    PUTCHR
  4153.     POP    H
  4154.     PUSH    H
  4155.     MVI    B,8        ; Filename length
  4156.     CALL    PUTSB
  4157.     MVI    A,'.'        ; Period after filename
  4158.     CALL    PUTCHR
  4159.     MVI    B,3        ; 3 characters of filetype
  4160.     CALL    PUTSB
  4161.  
  4162.      IF    Z80DOS OR CPM3
  4163.     LDA    NODFLG
  4164.     ORA    A
  4165.     JNZ    NOD8
  4166.     CALL    DISDAT
  4167. NOD8:
  4168.      ENDIF            ; Z80DOS/CPM3
  4169.  
  4170.     CALL    SIZEFL        ; Compute size of library in k
  4171.     XCHG
  4172.     CALL    DECPRT
  4173.     LXI    D,LFMSP3
  4174.     CALL    PUTS
  4175.     POP    H
  4176. ;
  4177. ; Saves the library file name into LBRFCB
  4178. ;
  4179.     LDA    FCB
  4180.     LXI    D,LBRFCB    ; To
  4181.     STAX    D
  4182.     INX    D
  4183.  
  4184.      IF    Z80DOS OR CPM3
  4185.     LXI    B,11        ; Length
  4186.     DW    ZMOVE        ; Z80's LDIR
  4187.      ENDIF            ; Z80DOS/CPM3
  4188.  
  4189.      IF    NOT (Z80DOS OR CPM3)
  4190.     MVI    B,11        ; Length
  4191.     CALL    MOVE        ; Do the move
  4192.      ENDIF            ; NOT Z80DOS/CPM3
  4193.  
  4194.     XCHG
  4195.     MVI    B,25
  4196.  
  4197. CLMFCB:    MVI    M,0
  4198.     INX    H
  4199.     DCR    B
  4200.     JNZ    CLMFCB
  4201.     CALL    SETLDMA
  4202.     LXI    D,LBRFCB    ; Point to file
  4203.     MVI    C,OPEN        ; Get function
  4204.     CALL    CPM        ; Open it
  4205.     MVI    C,READ
  4206.     LXI    D,LBRFCB
  4207.     CALL    CPM
  4208.     CALL    SETFOP
  4209.     LXI    H,LBBUF
  4210.     MOV    A,M
  4211.     ORA    A
  4212.     JZ    CKLDIR        ; Check directory present?
  4213.  
  4214.     LDA    ISARC
  4215.     ORA    A
  4216.     JNZ    BADLBR
  4217.     MOV    A,M
  4218.     CPI    ARCMAR
  4219.     JZ    CKADIR
  4220.  
  4221. BADLBR:    LXI    H,NLBRF
  4222.     LDA    ISARC
  4223.     ORA    A
  4224.     JNZ    NBARC
  4225.     LXI    H,NARCF
  4226.  
  4227. NBARC:    MVI    B,25
  4228.     CALL    PUTSB
  4229. ;
  4230. LMLEXI:    CALL    LBCLOS
  4231. ;
  4232. ; Do next library file
  4233. ;
  4234. LBRNEX:    LHLD    LCOUNT        ; Check count
  4235.     MOV    A,H
  4236.     ORA    L
  4237.     JZ    LBEXIT        ; No more, all done
  4238.     JMP    ENTRYL        ; Else, get next .LBR file
  4239. ;.....
  4240. ;
  4241. ; Close the library file
  4242. ;
  4243. LBCLOS:    LXI    D,LBRFCB
  4244.     MVI    C,CLOSE
  4245.     CALL    CPM
  4246.     RET
  4247. ;.....
  4248. ;
  4249. ; Set the Library file DMA address
  4250. ;
  4251. SETLDMA:CALL    CKVER        ; Set carry if pre-CP/M 2
  4252.     LDA    NEWUSR        ; Get user area for directory
  4253.     MOV    E,A
  4254.     MVI    C,STUSER    ; Get the user function
  4255.     CNC    CPM        ; And set new user number if CP/M 2
  4256.     LXI    D,LBBUF
  4257.     MVI    C,STDMA
  4258.     CALL    CPM
  4259.     RET
  4260. ;.....
  4261. ;
  4262. ; Check to see if there indeed is a LBR file directory
  4263. ;
  4264. CKLDIR:    MVI    B,11        ; Length of file name
  4265.     MVI    A,' '        ; Space
  4266.     INX    H
  4267.  
  4268. CKDLP:    CMP    M
  4269.     JNZ    BADLBR
  4270.     DCR    B
  4271.     INX    H
  4272.     JNZ    CKDLP
  4273. ;
  4274. ; The first entry in the LBR directory is indeed blank.  Now see if the
  4275. ; directory size is > 0
  4276. ;
  4277.     MOV    E,M        ; File starting location low
  4278.     INX    H        ; Must be zero here
  4279.     MOV    A,M        ; File starting location high
  4280.     ORA    E        ; Must be zero here also
  4281.     JNZ    BADLBR
  4282.     INX    H
  4283.     MOV    E,M        ; Get library size low
  4284.     INX    H        ; Point to library size high
  4285.     MOV    D,M        ; Get library size high
  4286.     MOV    A,D
  4287.     ORA    E        ; Library must have some size
  4288.     JZ    BADLBR
  4289.     DCX    D
  4290.     XCHG
  4291.     SHLD    SLFILE
  4292.     LHLD    LBTOTL
  4293.     INX    H
  4294.     SHLD    LBTOTL
  4295.  
  4296.      IF    Z80DOS OR CPM3
  4297.     LDA    ISARC
  4298.     ORA    A
  4299.     JZ    ZARC1
  4300.     LDA    NODFLG
  4301.     ORA    A
  4302.     JNZ    ZARC1
  4303.     MVI    A,2
  4304.     JMP    ZARC1A
  4305. ZARC1:    MVI    A,4
  4306. ZARC1A:
  4307.      ENDIF            ; Z80DOS/CPM3
  4308.  
  4309.      IF    NOT (Z80DOS OR CPM3)
  4310.     MVI    A,4
  4311.      ENDIF            ; NOT Z80DOS/CPM3
  4312.  
  4313.     STA    LNCNT        ; Reset names per line counter
  4314.     MVI    B,3
  4315.     LXI    H,17
  4316.     DAD    D
  4317.     JMP    LMTEST
  4318.  
  4319. LFMLOP:    LHLD    SLFILE        ; Get next buffer if more
  4320.     MOV    A,L
  4321.     ORA    H
  4322.     JZ    LMLEXI
  4323.     DCX    H
  4324.     SHLD    SLFILE
  4325.     CALL    SETLDMA
  4326.     MVI    C,READ
  4327.     LXI    D,LBRFCB
  4328.     CALL    CPM
  4329.     CALL    SETFOP
  4330.     MVI    B,4        ; Get file count per record
  4331.     LXI    H,LBBUF        ; Get buffer starting address
  4332.  
  4333. LMTEST:    MOV    A,M        ; Get member open flag
  4334.     ORA    A        ; Test for open
  4335.     JZ    PRMNAM
  4336.  
  4337. LMTESA:    LDA    ISARC
  4338.     ORA    A
  4339.     RZ
  4340.     LXI    D,32        ; Member not open get offset
  4341.     DAD    D        ; To next and add it in
  4342.     DCR    B        ; Is buffer empty ?
  4343.     JNZ    LMTEST        ; No so test next entry
  4344.     JMP    LFMLOP        ; Yes, get next buffer
  4345. ;
  4346. PRMNAM:    PUSH    H        ; Print member name and size
  4347.     PUSH    B
  4348.     CALL    CKABRT        ; Keyboard abort?
  4349.     LXI    H,LNCNT
  4350.  
  4351.      IF    Z80DOS OR CPM3
  4352.     LDA    ISARC
  4353.     ORA    A
  4354.     JZ    ZARC2
  4355.     LDA    NODFLG
  4356.     ORA    A
  4357.     JNZ    ZARC2
  4358.     MVI    A,2
  4359.     JMP    ZARC2A
  4360. ZARC2:    MVI    A,4
  4361. ZARC2A:
  4362.      ENDIF            ; Z80DOS/CPM3
  4363.  
  4364.      IF    NOT (Z80DOS OR CPM3)
  4365.     MVI    A,4
  4366.      ENDIF            ; NOT Z80DOS/CPM3
  4367.  
  4368.     CMP    M
  4369.     JNZ    PRMNA1
  4370.  
  4371.      IF    PRBRDR
  4372.     MVI    A,'*'        ; Load "A" with border character
  4373.     CALL    PUTCHR        ; Print it
  4374.     MVI    A,' '        ; 
  4375.     CALL    PUTCHR        ; Space between border and text
  4376.      ENDIF            ; PRBRDR
  4377.  
  4378.     JMP    PRMNA2
  4379.  
  4380. PRMNA1:    CALL    SPACE
  4381.     MVI    A,':'
  4382.     CALL    PUTCHR
  4383.     CALL    SPACE
  4384.  
  4385. PRMNA2:    POP    B
  4386.     POP    H
  4387.     PUSH    H
  4388.     PUSH    B
  4389.     INX    H
  4390.     MVI    B,8        ; Filename length
  4391.     CALL    PUTSB
  4392.     MVI    A,'.'        ; Period after filename
  4393.     CALL    PUTCHR
  4394.     MVI    B,3        ; 3 characters of filetype
  4395.     CALL    PUTSB
  4396.     INX    H
  4397.     INX    H
  4398.  
  4399.      IF    Z80DOS OR CPM3
  4400.     PUSH    H        ; Save pointer
  4401.     LDA    ISARC
  4402.     ORA    A
  4403.     JZ    ZARC3
  4404.     LDA    NODFLG
  4405.     ORA    A
  4406.     JNZ    ZARC3
  4407.     LXI    D,2
  4408.     DAD    D        ; Skip size field and point to CRC
  4409.                 ; DISDAT will point it to date field
  4410.     CALL    DISDAT        ; Show the date
  4411. ZARC3:    POP    H
  4412.      ENDIF            ; Z80DOS/CPM3
  4413.  
  4414.     MOV    E,M
  4415.     INX    H
  4416.     MOV    D,M
  4417.     XCHG
  4418. ;
  4419. ; Output the size of the individual file
  4420. ;
  4421.     PUSH    D
  4422.     PUSH    H
  4423.     XCHG
  4424.     LHLD    LLENLOC
  4425.     XCHG
  4426.     DAD    D
  4427.     SHLD    LLENLOC
  4428.     POP    H
  4429. ;
  4430. ; New code added to convert lib members from records to 'k'.  Upon entry
  4431. ; member's size in records is in HL.
  4432. ;
  4433.     LDA    COPFLG        ; File sizes wanted in records?
  4434.     ORA    A
  4435.     JZ    PRMNA3        ; Jump if so
  4436.     LXI    D,7        ; Round up to nearest 1k
  4437.     DAD    D
  4438.     XCHG
  4439.     LXI    H,0
  4440.     MOV    A,E        ; Low byte of record count in A
  4441.     RRC
  4442.     RRC
  4443.     RRC
  4444.     ANI    1FH
  4445.     MOV    E,A        ; And put it back
  4446.     MOV    L,D        ; Get the high byte if any
  4447.     MVI    D,0        ; Clean out the old resting place
  4448.     DAD    H        ; Multiply it by 32 to convert to
  4449.     DAD    H        ; Number of k bytes
  4450.     DAD    H
  4451.     DAD    H
  4452.     DAD    H
  4453.     DAD    D        ; And add in the low byte
  4454.  
  4455. PRMNA3:    POP    D
  4456.     CALL    DECPRT        ; Go print it
  4457.     LDA    FSIZEC        ; Follow with 'k' or 'r'
  4458.     CALL    PUTCHR
  4459. ;
  4460. ; Update library member total and name counter
  4461. ;
  4462.     LHLD    LMTOTL
  4463.     INX    H
  4464.     SHLD    LMTOTL
  4465.     LDA    LNCNT
  4466.     DCR    A
  4467.     STA    LNCNT
  4468.     POP    B
  4469.     POP    H
  4470.     JNZ    LMTESA        ; And go output another file
  4471. ;
  4472. ; Current line full, start a new one
  4473. ;
  4474.      IF    Z80DOS OR CPM3
  4475.     LDA    ISARC
  4476.     ORA    A
  4477.     JZ    ZARC4
  4478.     LDA    NODFLG
  4479.     ORA    A
  4480.     JNZ    ZARC4
  4481.     MVI    A,2
  4482.     JMP    ZARC4A
  4483. ZARC4:    MVI    A,4
  4484. ZARC4A:
  4485.      ENDIF            ; Z80DOS/CPM3
  4486.  
  4487.      IF    NOT (Z80DOS OR CPM3)
  4488.     MVI    A,4
  4489.      ENDIF            ; NOT Z80DOS/CPM3
  4490.  
  4491.     STA    LNCNT        ; Reset names per line counter
  4492.     CALL    CRLF        ; Space down to next line
  4493.     JMP    LMTESA
  4494. ;.....
  4495. ;
  4496. ; Move characters from "HL" to "DE" length in "B"
  4497. ;
  4498.      IF    NOT (Z80DOS OR CPM3)
  4499. MOVE:    MOV    A,M        ; Get a character
  4500.     STAX    D        ; Store it
  4501.     INX    H        ; To next "from"
  4502.     INX    D        ; To next "to"
  4503.     DCR    B        ; More?
  4504.     JNZ    MOVE        ; Yes, loop
  4505.     RET            ; No, return
  4506.      ENDIF            ; NOT Z80DOS/CPM3
  4507. ;.....
  4508. ;
  4509. ; Archive file subroutines
  4510. ;
  4511. CKADIR:    XRA    A
  4512.     DCR    A
  4513.     STA    GETABL        ; Say buffer is full (first read by lbr test)
  4514.     LHLD    LBTOTL        ; Bump library count total
  4515.     INX    H
  4516.     SHLD    LBTOTL
  4517.     MVI    A,4        ; LDA     MNPL
  4518.     STA    LNCNT        ; Reset names per line counter
  4519.  
  4520. ARCLP:    CALL    GET        ; Get the next character from buffer
  4521.     CPI    ARCMAR        ; Is it archive header marker?
  4522.     JNZ    BADLBR        ; And abort if not
  4523.     CALL    GET        ; Get header version
  4524.     ORA    A        ; If zero, that's logical end of file,
  4525.     JZ    LMLEXI        ; And we're done
  4526.     LXI    D,ANAME        ; Set to fill header buffer
  4527.     MVI    B,HDRSIZ    ; Setup normal header size less file name
  4528.     CPI    1        ; But test if version 1
  4529.     JNZ    GETHD1        ; Skip if not version 1
  4530.     LXI    B,HDRSIZ-4    ; Else, header is 4 bytes less
  4531.  
  4532. GETHD1:    CALL    GET        ; Get header byte
  4533.     STAX    D        ; Store in buffer
  4534.     INX    D
  4535.     DCR    B
  4536.     JNZ    GETHD1        ; Loop for all bytes
  4537.     LXI    H,ARCFIL    ; Prefill dummy arc FCB name with spaces
  4538.     MVI    B,11
  4539.  
  4540. FIXAN:    MVI    M,' '
  4541.     INX    H
  4542.     DCR    B
  4543.     JNZ    FIXAN
  4544.     MVI    B,5        ; Prefill rest of dummy FCB with zero
  4545.  
  4546. FIXAE:    MVI    M,0
  4547.     INX    H
  4548.     DCR    B
  4549.     JNZ    FIXAE
  4550.     LXI    H,ANAME        ; Get pointer to archive header buffer
  4551.     LXI    D,ARCFIL    ; Point to our dummy FCB
  4552.     MVI    B,8        ; Get name length
  4553.  
  4554. MANAME:    MOV    A,M        ; Get character from header
  4555.     INX    H
  4556.     ORA    A
  4557.     JZ    AEDONE        ; Nothing in buffer so we're done
  4558.     CPI    02EH        ; Is the char a point
  4559.     JZ    DAEXT        ; DO FILE EXTENT
  4560.     STAX    D
  4561.     INX    D
  4562.     DCR    B
  4563.     JNZ    MANAME
  4564.  
  4565. DAEXT:    LXI    D,ARCFIL+8    ; Get dummy file extent address
  4566.     MVI    B,3
  4567.     MOV    A,M
  4568.     CPI    2EH
  4569.     JNZ    AELOP
  4570.     INX    H
  4571.  
  4572. AELOP:    MOV    A,M        ; Fill in the file extent
  4573.     ORA    A
  4574.     JZ    AEDONE
  4575.     STAX    D
  4576.     INX    H
  4577.     INX    D
  4578.     DCR    B
  4579.     JNZ    AELOP
  4580.  
  4581. AEDONE:    LXI    H,ASIZE
  4582.     MOV    E,M        ; Fetch BCDE from (HL)
  4583.     INX    H
  4584.     MOV    D,M
  4585.     INX    H
  4586.     MOV    C,M
  4587.     XRA    A        ; Clear flags
  4588.     MOV    A,E        ; Convert file length count in bytes
  4589.     RAL            ; To length in records for output
  4590.     MOV    A,D
  4591.     RAL
  4592.     MOV    E,A
  4593.     MOV    A,C
  4594.     RAL
  4595.     MOV    D,A
  4596.     XCHG
  4597.     SHLD    ARCFIL+13    ; Save file length
  4598.     LXI    H,ARCFIL-1    ; Point to dummy FCB
  4599.     CALL    PRMNAM        ; List the file info
  4600.     LXI    H,ASIZE        ; Get remaining file size
  4601.     MOV    A,M
  4602.     ANI    7FH
  4603.     LHLD    ARCFIL+13    ; Save file length
  4604.     XCHG            ; Save record offset
  4605.     LXI    H,GETABL    ; Point to offset of last byte read
  4606.     ADD    M        ; Add byte offsets
  4607.     CPI    80H        ; Does it overflow current record?
  4608.     JC    NRAD
  4609.     SUI    80H        ; Adjust pointer
  4610.     INX    D        ; Bump record number
  4611.  
  4612. NRAD:    MOV    M,A        ; Update buffer pointer for new position
  4613.     MOV    A,D        ; Check record offset
  4614.     ORA    E
  4615.     JZ    LEXIT        ; Return if none (still in same record)
  4616.     PUSH    D        ; Save record offset
  4617.     LXI    D,LBRFCB
  4618.     MVI    C,RECORD    ; Compute current "random" record no.
  4619.     CALL    CPM        ; (I.e. next sequential record to read)
  4620.     LHLD    LBRFCB+FRN    ; Get result
  4621.     DCX    H        ; Adjust next record to current record
  4622.     POP    D        ; Restore record offset
  4623.     DAD    D        ; Compute new record no.
  4624.     JC    BADLBR        ; If >64k, it's past largest (8 Mb) file
  4625.     SHLD    LBRFCB+FRN    ; Save new record no.
  4626.     MVI    C,READRN    ; Read the random record
  4627.     CALL    GETREC
  4628.     ORA    A
  4629.     JNZ    BADLBR        ; File read error
  4630.     LXI    H,LBRFCB+FCR    ; Point to current record in extent
  4631.     INR    M        ; Bump for subsequent sequential read
  4632.  
  4633. LEXIT:    JMP    ARCLP        ; Loop for next file
  4634. ;.....
  4635. ;
  4636. ; Get next sequential byte from archive file
  4637. ;
  4638. GET:    PUSH    B        ; Save registers
  4639.     PUSH    D
  4640.     PUSH    H
  4641.     LDA    GETABL        ; Point to last byte read
  4642.     INR    A        ; At end of buffer?
  4643.     CPI    80H
  4644.     CNC    GETNXT        ; Yes, read next record and reset pointer
  4645.     STA    GETABL        ; Save new buffer pointer
  4646.     MOV    L,A
  4647.     MVI    H,0
  4648.     LXI    D,LBBUF
  4649.     DAD    D
  4650.     MOV    A,M        ; Fetch byte from there
  4651.     POP    H        ; Restore registers
  4652.     POP    D
  4653.     POP    B
  4654.     RET            ; Return
  4655. ;
  4656. ; Get next sequential record from archive file
  4657. ;
  4658. GETNXT:    MVI    C,READ        ; Setup read-sequential function code
  4659.     CALL    GETREC
  4660.     ORA    A
  4661.     JNZ    RDERR
  4662.     PUSH    PSW
  4663.     XRA    A
  4664.     DCR    A
  4665.     STA    GETABL
  4666.     POP    PSW
  4667.     RET
  4668. ;
  4669. RDERR:    POP    H        ; Strip GETNXT return
  4670.     POP    H        ; Clean up the get stack
  4671.     POP    D
  4672.     POP    B
  4673.     POP    H        ; Strip get calling address
  4674.     JMP    BADLBR        ; Show error
  4675. ;
  4676. ; Get record (sequential or random) from archive file
  4677. ;
  4678. GETREC:    PUSH    H
  4679.     PUSH    B
  4680.     CALL    SETLDMA        ; Set library DMA address
  4681.     LXI    D,LBRFCB    ; Setup FCB address
  4682.     POP    B        ; Restore read function
  4683.     CALL    CPM        ; Do it
  4684.     PUSH    PSW        ; Save read status
  4685.     CALL    SETFOP        ; Reset Print file DMA address
  4686.     POP    PSW        ; Restore read status
  4687.     POP    H        ; Restore buffer pointer
  4688.     RET
  4689. ;.....
  4690. ;
  4691. ; Test file extent for ARC/ARK
  4692. ;
  4693. CKARC:    PUSH    H
  4694.     PUSH    D
  4695.     PUSH    B
  4696.     XCHG
  4697.     LXI    H,ARCTYP
  4698.     MVI    C,2        ; Number for the loop to test
  4699. ;
  4700. CKARL:    LDAX    D
  4701.     ANI    7FH
  4702.     CMP    M
  4703.     JNZ    CKARX
  4704.     INX    H
  4705.     INX    D
  4706.     DCR    C
  4707.     JNZ    CKARL
  4708. ;
  4709. ; The first 2 match now see if C or K for .ARC or .ARK
  4710. ;
  4711.     LDAX    D
  4712.     ANI    7FH
  4713.     CPI    'C'        ; See if "C"
  4714.     JZ    CKARX
  4715.     CPI    'K'        ; See if "K"
  4716.  
  4717. CKARX:    POP    B
  4718.     POP    D
  4719.     POP    H
  4720.     RET
  4721. ;.....
  4722. ;
  4723. ; Test file extent for LBR
  4724. ;
  4725. CKLBR:    PUSH    H
  4726.     PUSH    D
  4727.     PUSH    B
  4728.     XCHG
  4729.     LXI    H,LBRTYP
  4730.     MVI    C,3
  4731.  
  4732. CKLBL:    LDAX    D
  4733.     ANI    7FH
  4734.     CMP    M
  4735.     JNZ    CKLBX
  4736.     INX    H
  4737.     INX    D
  4738.     DCR    C
  4739.     JNZ    CKLBL
  4740.  
  4741. CKLBX:    POP    B
  4742.     POP    D
  4743.     POP    H
  4744.     RET
  4745. ;
  4746. ; TIMEON routine
  4747. ;
  4748. ; Go through a search to see if BYE is active
  4749. ;
  4750.      IF    TIMEON
  4751. TIME:    LHLD    0001H        ; Point to warm boot again
  4752.     DCX    H        ; If BYE active,
  4753.     MOV    D,M        ; Pick up pointer to BYE variables
  4754.     DCX    H        ; (COVECT) followed by "BYE"
  4755.     MOV    E,M
  4756.     LXI    H,15        ; Calculate address of BYE variable
  4757.     DAD    D        ; Where ptr to orig BIOS vector stored
  4758.     MOV    E,M        ; Load that address into DE
  4759.     INX    H        ; If BIOS active, DE now points to
  4760.     MOV    D,M        ; Original BIOS console output vector
  4761.     INX    H        ; Point to BYE signon message
  4762.     MOV    A,M        ; Get letter
  4763.     ANI    05FH        ; Convert to upper case if needed
  4764.     CPI    'B'        ; Try to match "BYE"
  4765.     RNZ            ; Out if BYE not active
  4766.     INX    H
  4767.     MOV    A,M
  4768.     ANI    05FH        ; Convert to u-case if needed
  4769.     CPI    'Y'
  4770.     RNZ
  4771.     INX    H
  4772.     MOV    A,M
  4773.     ANI    05FH        ; Convert to u-case if needed
  4774.     CPI    'E'
  4775.     RNZ
  4776.  
  4777.     LXI    D,6        ; Bye running, point to RTCBUF
  4778.     DAD    D
  4779.     MOV    E,M        ; Get RTCBUF address
  4780.     INX    H        ; And copy
  4781.     MOV    D,M        ; In DE
  4782.     XCHG            ; Put in HL
  4783.     LXI    D,7        ; Offset to
  4784.     DAD    D        ; Time-on-system byte
  4785.     MOV    A,M        ; Load TOS byte
  4786.     LXI    H,TONMS1    ; Where to store in ASCII
  4787.     CALL    DEC8        ; Convert binary to ASCII
  4788.     LXI    D,TONMSG
  4789.     CALL    PUTS        ; Print the message
  4790.     RET            ; And return
  4791. ;.....
  4792. ;
  4793. ; DEC8 will convert an 8 bit binary number in A to 3 ASCII
  4794. ; bytes. HL points to the MSB location where the ASCII bytes
  4795. ; will be stored. Leading zeros are suppressed, store spaces
  4796. ; in your buffer before calling.
  4797. ;
  4798. DEC8:    PUSH    B
  4799.     PUSH    D
  4800.     MVI    E,0        ; Leading zero flag
  4801.     MVI    D,100
  4802.  
  4803. DEC81:    MVI    C,'0'-1
  4804.  
  4805. DEC82:    INR    C
  4806.     SUB    D        ; 100 or 10
  4807.     JNC    DEC82        ; Still +
  4808.     ADD    D        ; Now add it back
  4809.     MOV    B,A        ; Remainder
  4810.     MOV    A,C        ; Get 100/10
  4811.     CPI    '1'        ; Zero?
  4812.     JNC    DEC83        ; Yes
  4813.     MOV    A,E        ; Check flag
  4814.     ORA    A        ; Reset?
  4815.     MOV    A,C        ; Restore byte
  4816.     JZ    DEC84        ; Leading zeros are skipped
  4817.  
  4818. DEC83:    MOV    M,A        ; Store in buffer
  4819.     INX    H        ; Increment storage location
  4820.     MVI    E,0FFH        ; Set zero flag
  4821.  
  4822. DEC84:    MOV    A,D
  4823.     SUI    90        ; 100 to 10
  4824.     MOV    D,A
  4825.     MOV    A,B        ; Remainder
  4826.     JNC    DEC81        ; Do it again
  4827.     ADI    '0'        ; Make ASCII
  4828.     MOV    M,A        ; And store it
  4829.     POP    D
  4830.     POP    B
  4831.     RET
  4832.  
  4833. TONMSG:    DB    13,10,'Minutes on System: '
  4834. TONMS1:    DB    '    ',0
  4835.      ENDIF            ; TIMEON
  4836. ;
  4837. ;              end of TIMEON routine
  4838. ;-----------------------------------------------------------------------
  4839. ;               help routine
  4840. ;
  4841. ; Help menu if ? is typed, using a fancy ZCMD or ZCPR system
  4842. ;
  4843.      IF    WHEEL
  4844. HELPME:    LXI    D,OPTMSG    ; Point at message
  4845.     CALL    SHOW
  4846.      ENDIF            ; WHEEL
  4847.  
  4848.      IF    ZCPR33 AND WHEEL
  4849.     PUSH    H
  4850.     LHLD    Z3WHLL        ; Point to enviorment
  4851.     MOV    A,M        ; Get it
  4852.     POP    H
  4853.      ENDIF            ; ZCPR33
  4854.  
  4855.      IF    NOT ZCPR33 AND WHEEL
  4856.     LDA    WHLOC        ; Get wheel byte
  4857.      ENDIF            ; NOT ZCPR33
  4858.  
  4859.      IF    WHEEL
  4860.     ORA    A        ; If set, help out poor SYSOP
  4861.     JZ    EXIT3        ; No - exit
  4862.     LXI    D,SYSOP1    ; Point at message
  4863.     CALL    SHOW
  4864.     JMP    EXIT3        ; And exit
  4865. ;
  4866. ; This menu of options will appear to normal users (WHEEL not set).
  4867. ; Modify the menus to accommodate your system requirements.
  4868. ;
  4869. OPTMSG:    DB    13,10,13,10
  4870.     DB    '  Available Options (start with a  $  or  /  or'
  4871.     DB    '  [ character):',13,10,13,10
  4872.     DB    '  A - all user areas               N - no page pause'
  4873.     DB    ' [more]',13,10
  4874.     DB    '  C - file sizes in records        Q - show non-$ARCHived'
  4875.     DB    ' files',13,10
  4876.     DB    '  D - all drives                   T - order files'
  4877.     DB    ' by EXT type',13,10
  4878.     DB    '  H - Current area to highest      V - show version'
  4879.     DB    ' number',13,10
  4880.     DB    '  L - list LBR/ARC/ARK members     X - aux. format'
  4881.     DB    ' (horiz/vert)'
  4882.      ENDIF
  4883.  
  4884.      IF    Z80DOS AND WHEEL
  4885.     DB    13,10
  4886.     DB    '  Z - show any dates',13,10
  4887.     DB    '  = - exact date match             + - GE date match',13,10
  4888.     DB    '  - - LT date match                ! - use creation date for'
  4889.     DB    ' match',13,10
  4890.     DB    '  % -use alteration date match     @ - use access date for'
  4891.     DB    ' match',13,10
  4892.     DB    'A date input with no =+-!%@ will use =% default, * as'
  4893.     DB    ' date is current date'
  4894.      ENDIF            ; Z80DOS
  4895.  
  4896.      IF    CPM3 AND WHEEL
  4897.     DB    13,10
  4898.     DB    '  Z - show any dates               - - LT date match',13,10
  4899.     DB    '  = - exact date match             + - GE date match',13,10
  4900.     DB    '  % - use UPDATE date match        @ - use ACCESS/CREATE date'
  4901.     DB    ' for match',13,10,13,10
  4902.      ENDIF
  4903.  
  4904.      IF    (CPM3 AND WHEEL) AND UPDATE
  4905.     DB    'A date input with no =+-%@ will use =% as the default, * as'
  4906.     DB    ' date is current date',13,10
  4907.      ENDIF            ; CPM3
  4908.  
  4909.      IF    (CPM3 AND WHEEL) AND NOT UPDATE
  4910.     DB    'A date input with no =+-%@ will use =@ as the default, * as'
  4911.     DB    ' date is current date',13,10
  4912.      ENDIF
  4913.  
  4914.      IF    WHEEL AND (NOT CPM3)
  4915.     DB    13,10,13,10
  4916.      ENDIF
  4917.  
  4918.      IF    (Z80DOS OR CPM3) AND WHEEL
  4919.     DB    ' Example - to list all drives/users, no pauses,'
  4920.     DB    ' GE date match on access date:',13,10,13,10
  4921.     DB    '                     B0>SD $AND+@ 7/1/88'
  4922.      ENDIF            ; Z80DOS/CPM3
  4923.  
  4924.      IF    NOT (Z80DOS OR CPM3) AND WHEEL
  4925.     DB    '  Example - to list all drives and user areas,'
  4926.     DB    ' no pauses:',13,10,13,10
  4927.     DB    '                     B0>SD $AND <ret>'
  4928.      ENDIF            ; NOT Z80DOS/CPM3
  4929.  
  4930.      IF    WHEEL
  4931.     DB    13,10,13,10,0
  4932. ;
  4933. ; This menu of options appears only when the WHEEL is set.
  4934. ;
  4935. SYSOP1:    DB    '  * * * Special SYSOP Options (WHEEL SET) * * *'
  4936.      ENDIF
  4937.  
  4938.      IF    NOT FATTRIB AND WHEEL
  4939.     DB    13,10,13,10
  4940.      ENDIF            ; NOT FATTRIB
  4941.  
  4942.      IF    FATTRIB AND WHEEL
  4943.     DB    13,10
  4944.      ENDIF            ; FATTRIB
  4945.  
  4946.      IF    WHEEL
  4947.     DB    '  F - file output (DISK.DIR)       R - reset disk'
  4948.     DB    ' system',13,10
  4949.     DB    '  O - show $SYS files only         S - include'
  4950.     DB    ' $SYS files',13,10
  4951.     DB    '  P - printer output',13,10
  4952.      ENDIF
  4953.  
  4954.      IF    FATTRIB AND WHEEL
  4955.     DB    '  1 - Check attrib 1               2 - Check attrib 2',13,10
  4956.     DB    '  3 - Check attrib 3               4 - Check attrib 4',13,10
  4957.      ENDIF            ; FATTRIB
  4958.  
  4959.      IF    WHEEL
  4960.     DB    0
  4961.      ENDIF            ; WHEEL
  4962. ;
  4963. ; Help menu if ? is typed, NOT using any fancy ZCMD or ZCPR system
  4964. ;
  4965.      IF    NOT WHEEL
  4966. HELPME:    LXI    D,OPTMSG    ; Point at message
  4967.     CALL    SHOW
  4968.     JMP    EXIT3        ; And exit
  4969. ;
  4970. OPTMSG:    DB    13,10,13,10
  4971.     DB    '  Available Options (start with a  $  or  /  or'
  4972.     DB    '  [  character):',13,10
  4973.     DB    13,10
  4974.     DB    '  A - all user areas               P - printer output'
  4975.     DB    13,10
  4976.     DB    '  C - file sizes in records        Q - show non $ARChived'
  4977.     DB    ' files',13,10
  4978.     DB    '  D - all drives                   R - reset disk system'
  4979.     DB    13,10
  4980.     DB    '  F - file output (DISK.DIR)       S - include $SYS'
  4981.     DB    ' files',13,10
  4982.     DB    '  H - Current area to highest      T - order files'
  4983.     DB    ' by EXT type',13,10
  4984.     DB    '  L - list LBR/ARC/ARK members     V - show version'
  4985.     DB    ' number',13,10
  4986.     DB    '  N - no page pause [more]         X - aux. format'
  4987.     DB    ' (horiz/vert)',13,10
  4988.     DB    '  O - show $SYS files only'
  4989.      ENDIF            ; NOT WHEEL
  4990.  
  4991.      IF    (Z80DOS OR CPM3) AND NOT WHEEL
  4992.     DB    '         Z - show any dates'
  4993.      ENDIF            ; Z80DOS/CPM3
  4994.  
  4995.      IF    NOT WHEEL
  4996.     DB    13,10
  4997.      ENDIF            ; NOT WHEEL
  4998.  
  4999.      IF    FATTRIB AND NOT WHEEL
  5000.     DB    '  1 - Check attrib 1               2 - Check attrib 2',13,10
  5001.     DB    '  3 - Check attrib 3               4 - Check attrib 4',13,10
  5002.      ENDIF            ; FATTRIB
  5003.  
  5004.      IF    Z80DOS AND NOT WHEEL
  5005.     DB    '  = - exact date match             + - GE date match',13,10
  5006.     DB    '  - - LT date match                ! - use creation date for'
  5007.     DB    ' match',13,10
  5008.     DB    '  % - use alteration date match    @ - use access date for'
  5009.     DB    ' match',13,10
  5010.     DB    '  A date input with no =+-!%@ will use =% for dafault,'
  5011.     DB    ' * as date is current date.',13,10,13,10
  5012.      ENDIF            ; Z80DOS
  5013.  
  5014.      IF    CPM3 AND NOT WHEEL
  5015.     DB    '  = = exact date match             + - GE date match',13,10
  5016.     DB    '  - - LT date match',13,10
  5017.     DB    '  % - use UPDATE date match        @ - use ACCESS/CREATE date'
  5018.     DB    ' for match',13,10
  5019.      ENDIF            ; CPM3
  5020.  
  5021.      IF    CPM3 AND UPDATE
  5022.     DB    'A date input with no =+-%@ will use =% as the default, * as'
  5023.     DB    ' date is current date',13,10
  5024.      ENDIF            ; CPM3
  5025.  
  5026.      IF    CPM3 AND NOT UPDATE
  5027.     DB    'A date input with no =+-%@ will use =@ as the default, * as'
  5028.     DB    ' date is current date',13,10
  5029.      ENDIF
  5030.  
  5031.      IF    Z80DOS OR CPM3
  5032.     DB    ' Example - to list all drives/users, no pauses,'
  5033.     DB    ' GE date match on access date:',13,10,13,10
  5034.     DB    '                     B0>SD $AND+@ 7/1/88',13,10,13,10,0
  5035.      ENDIF            ; Z80DOS/CPM3
  5036.  
  5037.      IF    NOT (Z80DOS OR CPM3) AND NOT WHEEL
  5038.     DB    13,10,'  Example - to list all drives and user areas,'
  5039.     DB    ' no pauses:',13,10,13,10
  5040.     DB    '                     B0>SD $AND <ret>'
  5041.     DB    13,10,13,10,13,10,13,10,13,10,13,10,13,10
  5042.     DB    0
  5043.      ENDIF            ; NOT Z80ODS/CPM3
  5044.  
  5045.      IF    Z80DOS OR CPM3
  5046. DISDAT:    PUSH    B
  5047.     PUSH    H        ; Save pointer to size field
  5048.     PUSH    D
  5049.     INX    H        ; and skip over size
  5050.     INX    H        ; 
  5051.     MOV    E,M        ; Get JD in DE
  5052.     INX    H        ; 
  5053.     MOV    D,M        ; 
  5054.     XCHG            ; to HL
  5055.     CALL    DATEHL        ; 
  5056.     PUSH    H        ; Month and Year in L,H
  5057.     PUSH    PSW        ; Day in A
  5058.     CALL    SPACE
  5059.     CALL    SPACE
  5060.     POP    PSW
  5061.     JNZ    DAYOK        ; NZ = was a day there
  5062.     POP    H
  5063.     CALL    NODATE
  5064.     JMP    DNOTOK
  5065.      ENDIF            ; Z80DOS/CPM3
  5066. DAYOK:    
  5067.      IF    (Z80DOS OR CPM3) AND NOT EDATE
  5068.     PUSH    PSW
  5069.     MOV    A,L        ; Month out
  5070.     CALL    BCDOUT
  5071.     MVI    A,'/'
  5072.     CALL    PUTCHR
  5073.     POP    PSW
  5074.     CALL    BCDOUT        ; Day out
  5075.      ENDIF            ; Z80DOS/CPM3
  5076.  
  5077.      IF    (Z80DOS OR CPM3) AND EDATE
  5078.     PUSH    H
  5079.     CALL    BCDOUT        ; Day out
  5080.     MVI    A,'/'
  5081.     CALL    PUTCHR
  5082.     POP    H
  5083.     MOV    A,L
  5084.     CALL    BCDOUT        ; Month out
  5085.      ENDIF            ; Z80DOS/CPM3
  5086.  
  5087.      IF    Z80DOS OR CPM3
  5088.     MVI    A,'/'
  5089.     CALL    PUTCHR
  5090.     POP    H
  5091.     MOV    A,H        ; Year out
  5092.     CALL    BCDOUT
  5093. DNOTOK:    CALL    SPACE
  5094.     CALL    SPACE
  5095.     POP    D
  5096.     POP    H
  5097.     POP    B
  5098.     RET
  5099.  
  5100. NODATE:
  5101.     LXI    D,NODATM
  5102.     CALL    PUTS
  5103.     RET
  5104. NODATM:
  5105.     DB    '--------',0
  5106.  
  5107. BCDOUT:
  5108.     PUSH    B        ; Save
  5109.     MOV    B,A        ; A holds BCD digits
  5110.     RAR
  5111.     RAR
  5112.     RAR
  5113.     RAR
  5114.     CALL    BCDOT1        ; Output high order
  5115.     MOV    A,B
  5116.     CALL    BCDOT1        ; And low order
  5117.     POP    B
  5118.     RET
  5119. BCDOT1:    ANI    0FH
  5120.     ADI    '0'
  5121.     CALL    PUTCHR
  5122.     RET
  5123.  
  5124. ;
  5125. ; DATEHL converts the value in HL to BCD year, month, day
  5126. ;     for use with Z80DOS or CPM3 time stamps.
  5127. ;
  5128. ;
  5129. ; Inputs:    HL contains hex days since December 31, 1977 or if CPM3
  5130. ;               Janurary 1, 1978
  5131. ;
  5132. ; Outputs:    H contains BCD 20th century year
  5133. ;        L contains BCD month
  5134. ;        A contains BCD day
  5135. ;
  5136. ;        Zero flag set (Z) and A=0 if invalid date (zero) detected,
  5137. ;        Zero flag reset (NZ) and A=0ffh otherwise.
  5138.  
  5139. ; DATEHL by Carson Wilson who Adapted from B5C-CPM3.INS
  5140.  
  5141. DATEHL:    MOV    A,H
  5142.     ORA    L        ; Test blank date (zero)
  5143.     RZ            ; Return Z and A=0 if so
  5144.     SHLD    DAYS        ; Save initial value
  5145.     MVI    B,78        ; Set years counter
  5146. LOOP:    CALL    CKLEAP
  5147.     LXI    D,-365        ; Set up for subtract
  5148.     JNZ    NOPLY        ; Skip if no leap year
  5149.     DCX    D        ; Set for leap year
  5150. NOPLY:    DAD    D        ; Subtract
  5151.     JNC    YDONE        ; Continue if years done
  5152.     MOV    A,H
  5153.     ORA    L
  5154.     JZ    YDONE
  5155.     SHLD    DAYS        ; Else save days count
  5156.     INR    B        ; Increment years count
  5157.     JMP    LOOP        ; And do again
  5158. ;
  5159. ; The years are now finished, the years count is in 'B' (HL is invalid)
  5160. ;
  5161. YDONE:    MOV    A,B
  5162.     CALL    BINBCD
  5163.     STA    YEARS        ; save BCD year
  5164. ;
  5165.     CALL    CKLEAP
  5166.     MVI    A,0E4H        ; -28
  5167.     JNZ    FEBNO        ; February not 29 days
  5168.     MVI    A,0E3H        ; Leap year -29
  5169. FEBNO:    STA    FEB        ; Set february
  5170.     LHLD    DAYS        ; Get days count
  5171.     LXI    D,MTABLE    ; Point to months table
  5172.     MVI    B,0FFH        ; Set up 'B' for subtract
  5173.     MVI    A,0        ; Set a for # of months
  5174. MLOOP:    PUSH    PSW
  5175.     LDAX    D        ; Get month
  5176.     MOV    C,A        ; Put in 'C' for subtract
  5177.     POP    PSW
  5178.     SHLD    DAYS        ; save days count
  5179.     DAD    B        ; Subtract
  5180.     INX    D        ; Increment months counter
  5181.     INR    A
  5182.     JC    MLOOP        ; Loop for next month
  5183.  
  5184. ;
  5185. ; The months are finished, days count is on stack.  First, calculate
  5186. ; month.
  5187. ;
  5188. MDONE:    MOV    B,A        ; Save months
  5189.     LHLD    DAYS
  5190.     MOV    A,H
  5191.     ORA    L
  5192.     JNZ    NZD
  5193.     DCX    D
  5194.     DCX    D
  5195.     LDAX    D
  5196.     CMA
  5197.     INR    A
  5198.     MOV    L,A
  5199.     DCR    B
  5200. NZD:    MOV    A,L        ; Retrieve binary day of month
  5201.     CALL    BINBCD        ; Convert to BCD
  5202.     PUSH    PSW        ; Save day in A
  5203. ;
  5204.     MOV    A,B        ; Retrieve the binary month
  5205.     CALL    BINBCD        ; Convert binary month to BCD
  5206.     MOV    L,A        ; Return month in L
  5207. ;
  5208.     LDA    YEARS
  5209.     MOV    H,A        ; Return year in H
  5210.     POP    PSW        ; Restore day
  5211.     ORA    A        ; Set NZ flag
  5212.     RET
  5213.  
  5214. ;
  5215. ; Support Routines:
  5216. ;
  5217.  
  5218. ; Check for leap years.
  5219. ;
  5220. CKLEAP:    MOV    A,B
  5221.     ANI    0FCH
  5222.     CMP    B
  5223.     RET
  5224. ;
  5225. ; Convert A to BCD & store back in A
  5226. ;
  5227. BINBCD:    ORA    A
  5228.     RZ
  5229.     PUSH    B
  5230.     MOV    B,A
  5231.     XRA    A
  5232. BINBCD1:ADI    1
  5233.     DAA
  5234.     DCR    B
  5235.     JNZ    BINBCD1
  5236.     POP    B
  5237.     RET
  5238. ;
  5239. ; Buffers:
  5240. ;
  5241. ; Months table
  5242. ;
  5243. MTABLE:    DB    0E1H        ; January -31
  5244. FEB:    DB    0E4H        ; February -28
  5245.     DB    0E1H,0E2H,0E1H,0E2H ; Mar-Jun -31,-30,-31,-30
  5246.     DB    0E1H,0E1H,0E2H    ; Jul-Sep -31,-31,-30
  5247.     DB    0E1H,0E2H,0E1H    ; Oct-Dec -31,-30,-31
  5248.  
  5249.      ENDIF            ; Z80DOS/CPM3
  5250. ;
  5251. ; Messages and Error statements
  5252. ;
  5253. CKMS1:    DB    13,10,'++ ABORTED ++',0
  5254. CKMS2:    DB    8,' ',8,0
  5255. DRUMSG:    DB    'Drive/User',0
  5256. EOSMSG:    DB    '[more] ','$'
  5257.  
  5258.      IF    VSPAGE
  5259. MORERA:    DB    13,'                  ----------------------------------------'
  5260.     DB    13,10,'$'
  5261.      ENDIF            ; VSPAGE
  5262.  
  5263.      IF    NOT VSPAGE
  5264. MORERA:    DB    13,'        ',13,'$'
  5265.      ENDIF
  5266.  
  5267. ERRMS1:    DB    ' '
  5268. ERRMS2:    DB    'Error',0
  5269. ERRTAG:    DB    ' ->',0
  5270. NOFLM:    DB    '>> No detectable file(s) on ',0
  5271. NOFMS1:    DB    13,10,13,10,' ',0
  5272. NOFMS2:    DB    '  ',0
  5273. NOFMS3:    DB    ':  ',0
  5274. SOHFLG:    DB    0
  5275. CRLSPC:    DB    13,10,'          ',0
  5276. TOTMS1:    DB    ' Drive ',0
  5277. TOTMS4:    DB    '/',0
  5278. TOTMS5:    DB    'k  ',0
  5279. TOTMS6:    DB    ' Files: ',0
  5280. TOTMS7:    DB    ' Free: ',0
  5281. TOTMS8:    DB    'k ',0
  5282. ALLTOT:    DB    13,10,'             Total files: ',0
  5283. ALLTO1:    DB    'k',13,10,0
  5284.  
  5285.      IF    PRBRDR
  5286. CONTM1:    DB    13,10,'** There are ',0
  5287. MFILES:    DB    ' member files in ',0
  5288. LIBR:    DB    ' library(s) and/or archive(s) **',0
  5289. AFMSP1:    DB    13,10,'** Archive directory for ',0
  5290. LFMSP1:    DB    13,10,'** Library directory for ',0
  5291. LFMSP3:    DB    'k'
  5292.     DB    ' **'
  5293.     DB    13,10,0
  5294.      ENDIF            ; PRBRDR
  5295.  
  5296.      IF    NOT PRBRDR
  5297. CONTM1:    DB    13,10,'There are ',0
  5298. MFILES:    DB    ' member files in ',0
  5299. LIBR:    DB    ' library(s) and/or archive(s)',0
  5300. AFMSP1:    DB    13,10,'Archive directory for ',0
  5301. LFMSP1:    DB    13,10,'Library directory for ',0
  5302. LFMSP3:    DB    'k'
  5303.     DB    13,10,0
  5304.      ENDIF            ; Not PRBRDR
  5305.  
  5306. NLBRF:    DB    '++ Not a library file ++',13,10
  5307. NARCF:    DB    '++ Not an archive file ++',13,10
  5308. LBRTYP:    DB    'LBR'
  5309. ARCTYP:    DB    'AR'        ; We only test the first 2 in the loop.
  5310.                 ; The C or K are tested separately.
  5311. ;
  5312. ; Permanently initialized data area
  5313. ;
  5314. VECTBL:    DW    DSKERR        ; BDOS record error intercept vector
  5315.     DW    DSKERR        ; BDOS select error intercept vector
  5316. ;
  5317. ; End of code that must be stored on disk in the .COM file
  5318. ;
  5319. ; Data area reinitialized by code when SD is run or rerun
  5320. ;
  5321. DATA0    EQU    $        ; Start of area to initialize
  5322.  
  5323. OTBL    EQU    $        ; Mark start of option table
  5324. VFLAG:    DS    1
  5325. AOPFLG:    DS    1
  5326. COPFLG:    DS    1
  5327. DOPFLG:    DS    1
  5328. FOPFLG:    DS    1
  5329. HOPFLG:    DS    1
  5330. LOPFLG:    DS    1
  5331. NOPFLG:    DS    1
  5332. OOPFLG:    DS    1
  5333. POPFLG:    DS    1
  5334. QOPFLG:    DS    1
  5335. ROPFLG:    DS    1
  5336. SOPFLG:    DS    1
  5337. TOPFLG:    DS    1
  5338. VOPFLG:    DS    1
  5339. XOPFLG:    DS    1
  5340.  
  5341.      IF    Z80DOS OR CPM3
  5342. DEOPFL:    DS    1
  5343. DPOPFL:    DS    1
  5344. DMOPFL:    DS    1
  5345. DNOPFL:    DS    1
  5346. DAOPFL:    DS    1
  5347. DGOPFL:    DS    1
  5348. NODFLG:    DS    1
  5349.      ENDIF            ; Z80DOS/CPM3
  5350.  
  5351.      IF    FATTRIB
  5352. ONEFLG:    DS    1
  5353. TWOFLG:    DS    1
  5354. THRFLG:    DS    1
  5355. FORFLG:    DS    1
  5356.      ENDIF
  5357.  
  5358. OEND    EQU    $        ; End of option table
  5359. ;
  5360. ; End of option lookup table
  5361. ;
  5362. BUFPNT:    DS    2        ; Next location in output buffer
  5363. BUFCNT:    DS    1        ; Number of bytes left in output buffer
  5364. OUTFCB:    DS    1+8+3        ; User number, filename, and filetype
  5365. ;
  5366. ; Beginning of area reinitialized to zero each time SD.COM is run
  5367. ;
  5368.     DS    21        ; Rest of DISK.DIR FCB
  5369. DISKNO:    DS    1        ; Disk number
  5370. USERNO:    DS    1        ; User number
  5371. OPNFLG:    DS    1        ; File open flag
  5372. DRVFLG:    DS    1        ; D option check for prior drive specificaton
  5373. FNDFLG:    DS    1        ; Files Matched Flag
  5374. BYEACT:    DS    1        ; BYE Active Flag
  5375.  
  5376. LINCNT:    DS    1        ; # lines printed on screen
  5377. LLENLOC:DS    2        ; Running total of .LBR length
  5378. LMTOTL:    DS    2
  5379. LBTOTL:    DS    2
  5380. LNCNT:    DS    1
  5381. LCOUNT:    DS    2
  5382. NEXTL:    DS    2
  5383. SLFILE:    DS    2
  5384. LINES:    DS    1        ; Number of lines to be printed
  5385. FIRSTT:    DS    1        ; First time flag for version number
  5386. ISARC:    DS    1
  5387. ;
  5388. ; Uninitialized data area
  5389. ;
  5390. BASUSR:    DS    1        ; Copy of original directory user #
  5391. BLKMAX:    DS    2        ; Highest block # on drive
  5392. BLKMSK:    DS    1        ; Records/block - 1
  5393. BLKSHF:    DS    1        ; Number shifts to mult by sec/blk
  5394. COUNT:    DS    2        ; Entry count
  5395. DIRMAX:    DS    2        ; Highest file # in directory
  5396. FILERC:    DS    2        ; File size in records
  5397. FREEBY:    DS    2        ; Number of k left on dir. drive
  5398. FSIZEC:    DS    1        ; File size character ('k' or 'r')
  5399. GAP:    DS    2        ; Sort routine storage
  5400. I:    DS    2        ; Sort routine storage
  5401. J:    DS    2        ; Sort routine storage
  5402. JG:    DS    2        ; Sort routine storage
  5403. LZFLG:    DS    1        ; 0 when printing leading zeros
  5404. MAXUSR:    DS    1        ; Max user # for drive
  5405. NEWUSR:    DS    1        ; User # selected by "$U" option
  5406. NEXTT:    DS    2        ; Next table entry
  5407. OLDDSK:    DS    1        ; Currently logged-in drive
  5408. OLDUSR:    DS    1        ; User number upon invocation
  5409. SCOUNT:    DS    2        ; # to sort
  5410. SUPSPC:    DS    1        ; Leading space flag
  5411. TBLOC:    DS    2        ; Start of name table
  5412. TOTFIL:    DS    2        ; Total number of files
  5413. TOTSIZ:    DS    2        ; Total size of all files
  5414. TOTFL1:    DS    2        ; Total files of all D/U
  5415. TOTSZ1:    DS    2        ; Total size of all D/U
  5416. TOTFRE:    DS    2
  5417. USRNR:    DS    1        ; User number
  5418. VERFLG:    DS    1        ; CP/M version number (0=pre-CP/M 2)
  5419. ZRDFLG:    DS    1        ; ZRDOS version number
  5420.  
  5421.      IF    Z80DOS OR CPM3
  5422. DATPLS:    DS    1        ; Holds +/- flag for date math
  5423. DATCH1:    DS    2        ; Holds first input date
  5424. DATCHK:    DS    2        ; Holds date to look for
  5425. DTMTCH:    DS    1        ; Holds <,>=,>
  5426. DATMOD:    DS    2        ; Holds date found for file
  5427. DAYS:    DS    2        ; temporary buffers
  5428. YEARS:    DS    1        ; 
  5429. YEARS1:    DS    1
  5430. MONTHS:    DS    1
  5431. DAYS1:    DS    1
  5432. ASCII:    DS    5        ; holds date from system
  5433.      ENDIF            ; Z80DOS/CPM3
  5434.  
  5435.      IF    CPM3
  5436. LATDAT:    DS    2
  5437.      ENDIF            ; CPM3
  5438.  
  5439. DATA1    EQU    $        ; End of area to initialize
  5440.  
  5441.      IF    ZCPR33
  5442. Z3DRVL:    DS    2        ; Points to Z33 max drv location
  5443. Z3USRL:    DS    2        ; Points to Z33 max user location
  5444. Z3WHLL:    DS    2        ; Points to Z33 wheel location
  5445.      ENDIF            ; ZCPR33
  5446.  
  5447.      IF    NDIRS
  5448. NAMADR:    DS    2        ; Named Directory Buffer Address
  5449. NUMDIR:    DS    1        ; Number of entries
  5450. CURDIR:    DS    1        ; NDR Check counter
  5451.      ENDIF            ; NDIRS
  5452.  
  5453.      IF    SHOPUB
  5454. PUBDRV:    DS    1        ; Storage for Public Drive byte
  5455. PUBUSR:    DS    1        ; "    "    "      User     "
  5456.      ENDIF            ; SHOPUB
  5457.  
  5458. GETABL:    DS    1
  5459. LBRFCB:    DS    36
  5460. LBBUF:    DS    128
  5461.  
  5462. ANAME:    DS    13
  5463. ASIZE:    DS    14
  5464. ARCFIL:    DS    16
  5465.  
  5466. NEWPTR:    DS    2        ; Start of second table
  5467. XPOINT:    DS    2
  5468. JUMPER:    DS    2        ; Increment for second table to
  5469. WASHERE:
  5470.     DS    1
  5471. VSFRST:    DS    1
  5472. OUTBUF:    DS    128        ; Output file buffer
  5473. ;
  5474. ; BDOS equates
  5475. ;
  5476. BDOS    EQU    0005H        ; Entry Point for BDOS calls
  5477. FCB    EQU    005CH        ; Default FCB Address
  5478. TBUF    EQU    0080H        ; Default DMA Address
  5479.  
  5480. RDCON    EQU    1        ; Console input
  5481. WRCON    EQU    2        ; Console output
  5482. LIST    EQU    5        ; List output
  5483. PRINT    EQU    9        ; Print string
  5484. CONST    EQU    11        ; Get console status
  5485. CPMVER    EQU    12        ; Return CP/M version
  5486. RESET    EQU    13        ; Reset disk system
  5487. SELDSK    EQU    14        ; Select disk
  5488. OPEN    EQU    15        ; Open file
  5489. CLOSE    EQU    16        ; Close file
  5490. SRCHF    EQU    17        ; Search for first
  5491. SRCHN    EQU    18        ; Search for next
  5492. READ    EQU    20        ; Read sequential
  5493. WRITE    EQU    21        ; Write sequential
  5494. MAKE    EQU    22        ; Make file
  5495. CURDSK    EQU    25        ; Return current disk
  5496. STDMA    EQU    26        ; Set DMA Address
  5497. DSKALL    EQU    27        ; Get address of allocation vector
  5498. DSKPAR    EQU    31        ; Get address of disk parameters
  5499. STUSER    EQU    32        ; Set/get user number
  5500.  
  5501.      IF    ZRDOS
  5502. ZRDVER    EQU    48        ; Return version (ZRDOS)
  5503. SETWBT    EQU    50        ; Set warm boot trap (ZRDOS)
  5504. RESWBT    EQU    52        ; Reset warm boot trap (ZRDOS)
  5505.      ENDIF            ; ZRDOS
  5506.  
  5507.     DS    60        ; Stack area
  5508. STACK:    DS    2        ; Old stack pointer
  5509.  
  5510. ORDER    EQU    $        ; Order table starts here
  5511.  
  5512.     END
  5513.