home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
BEEHIVE
/
COMMS
/
ZMP-OV16.ARC
/
ZMO-XE04.Z80
< prev
next >
Wrap
Text File
|
1991-02-02
|
14KB
|
579 lines
;
; System-dependent installation overlay for ZMP
; Author: Ron Murray
; Xerox/Kaypro overlay written by S.V. Hovater
; 24 Sep 1988 Email: Houston NW Znode 713-937-8886
; -- this version sets up the UART.
;
; Modified to v1.3 standard rjm 12/10/88
; Modified to v1.4 standard rjm 11/12/88
;
; Insert your own code as necessary in this file. Code contained herein
; has been written in Z80 code for use with M80. Once assembled,
; convert to hex with RELHEX and use MLOAD to overlay it over the main
; ZMPX.COM file to produce your very own ZMP.COM.
;
; Notes on modifying this file:
; Hi-Tech C requires that functions do not change either index register
; (IX or IY). If your overlay requires either of these to be changed, ensure
; they are restored to their original values on return.
; Since collecting parameters from C functions can be tricky, only change
; the parts marked 'Insert your own code here'. Do NOT modify the jump
; table at the start. Do NOT modify the entry/exit sections of each
; function. Do NOT pass 'GO'. Do NOT collect $200.
; Apart from defining modem functions, this file also defines terminal
; characteristics. Most have been set up for ADM-3A (with a few of my own
; additions). Modify to suit your own terminal. An inline print routine
; is provided for printing strings in the usual way: usage is
;
; call print
; db 'required string',0
;
; Don't forget to set your clock speed at the clkspd variable.
;
; If you find your overlay exceeds the maximum size (currently 0400h),
; you will have to re-compile the whole thing. Good luck. You might try
; informing us if you need to do this: if too many people need to do it, we
; haven't allowed enough room.
;
; Ron Murray 15/8/88
;
;User-set variables:
;Set the following two equates to the drive and user area which will contain
; ZMP's .OVR files, .CFG file, .FON file and .HLP file. Set both to zero
; (null) to locate them on the drive from which ZMP was invoked.
overdrive equ 'A' ; Drive to find overlay files on ('A'-'P')
overuser equ 0 ; User area to find files
clkspd equ 4 ; Processor clock speed in MHz
mspeed equ 003ch ; Current baud rate: as used by BYE etc
; This MUST be the same as Mspeed in
; ZMP.H
PORT equ 04H ; Xerox base port (data or status)
MDCTL1 equ PORT+2 ; Modem control port
MDDATP equ PORT ; Modem data port
MDRCV equ 01H ; Modem receive ready
MDSND equ 04H ; Modem send ready bit
MDTXE equ 01H ; Modem send buffer empty, holding buffer empty
BRPORT equ 00H ; 8116 port for baudrate
userdef equ 00145h ; origin of this overlay: get this value
; from the .SYM file produced when ZMP.COM
; is linked
ovsize equ 0400h ; max size of this overlay
.z80 ; use z80 code
aseg ; absolute
org userdef
esc equ 1bh
ctrlq equ 11h
cr equ 0dh
lf equ 0ah
bdos equ 5
;Jump table for the overlay: do NOT change this
jump_tab:
jp scrnpr ; screen print
jp mrd ; modem read with timeout
jp mchin ; get a character from modem
jp mchout ; send a character to the modem
jp mordy ; test for tx buffer empty
jp mirdy ; test for character received
jp sndbrk ; send break
jp cursadd ; cursor addressing
jp cls ; clear screen
jp invon ; inverse video on
jp invoff ; inverse video off
jp hide ; hide cursor
jp show ; show cursor
jp savecu ; save cursor position
jp rescu ; restore cursor position
jp mint ; service modem interrupt
jp invec ; initialise interrupt vectors
jp dinvec ; de-initialise interrupt vectors
jp mdmerr ; test uart flags for error
jp dtron ; turn DTR on
jp dtroff ; turn DTR OFF
jp init ; initialise uart
jp wait ; wait seconds
jp mswait ; wait milliseconds
jp userin ; user-defined entry routine
jp userout ; user-defined exit routine
jp getvars ; get system variables
;
jp spare ; spare for later use
jp spare ; spare for later use
jp spare ; spare for later use
jp spare ; spare for later use
jp spare ; spare for later use
;
; Main code starts here
;
codebgn equ $
;
;Screen print function
scrnpr:
; <== Insert your own code here
call print
db 'This function not supported.',cr,lf,0
; <== End of your own code
spare:
ret
; User-defined entry routine
userin:
ret
; User-defined exit routine
userout:
ret
;Get a character from the modem: return in HL
; It is not necessary to test for status
mchin:
push bc
;-- Add code specific to Xerox
in a,(MDDATP) ; get the character in A
;-- End of this block of machine specific code
ld l,a ; put in HL
ld h,0
or a ; set/clear Z
pop bc
ret
;Send a character to the modem
mchout:
ld hl,2 ; get the character
add hl,sp
ld a,(hl) ; in A
;-- Add code specific to Xerox
push bc
ld c,a
mchout1:
in a,(MDCTL1)
and MDSND
jr z,mchout1
ld a,c
out (MDDATP),a
pop bc
;-- End of this block of machine specific code
ret ; done
;Test for output ready: return TRUE (1) in HL if ok
mordy:
;-- Add code specific to Xerox
in a,(MDCTL1)
and MDTXE
jr z,mordyx
ld l,1
ld h,0
mordyx:
;-- End of this block of machine specific code
ld a,l ; set/clear Z
or a
ret
;Test for character at modem: return TRUE (1) in HL if so
mirdy:
;-- Add code specific to Xerox
in a,(MDCTL1)
and MDRCV
jr z,mirdy1
ld l,1
jr mirdyx
mirdy1:
ld l,0
mirdyx:
ld h,00H
;-- End of this block of machine specific code
ld a,l ; set/clear Z
or a
ret
;Send a break to the modem: leave empty if your system can't do it
sndbrk:
;-- Add code specific to Xerox
ld a,5
out (MDCTL1),a ; Send to the status port
ld a,0F8H ; DTR normal, send break tone
out (MDCTL1),a
;-- End of this block of machine specific code
ld hl,300
call waithlms ; wait 300 mS
;-- Add code specific to Xerox
ld a,5 ; Restore normal, 8 bits, DTR on, etc.
out (MDCTL1),a
ld a,0E8H
out (MDCTL1),a
;-- End of this block of machine specific code
ret
;Test UART flags for error: return TRUE (1) in HL if error
mdmerr:
;-- Add code specific to Xerox
ld a,010H ; Register 0, reset interrupts
out (MDCTL1),a
in a,(MDCTL1)
;-- End of this block of machine specific code
ld a,l ; set/clear Z
or a
ret
;Turn DTR (and optionally RTS) ON.
dtron:
;-- Add code specific to Xerox
ld a,05H
out (MDCTL1),a
ld a,0E8H
out (MDCTL1),a
;-- End of this block of machine specific code
ret
;Turn DTR ( and RTS?) OFF
dtroff:
;-- Add code specific to Xerox
ld a,05H
out (MDCTL1),a
ld a,078H
out (MDCTL1),a
;-- End of this block of machine specific code
ret
;Initialise the UART
init:
ld hl,2 ; get parameters
add hl,sp
ex de,hl
call getparm ; in HL
ld (brate),hl ; baud rate
call getparm
ld (parity),hl ; parity
call getparm
ld (data),hl ; data bits
call getparm
ld (stop),hl ; stop bits
; <== Insert your own code here
;-- Add code specific to Xerox
push bc
ld a,0 ; select register
out (MDCTL1),a
ld a,018H ; Throw out of mode
out (MDCTL1),a
ld a,04H ; Select register
out (MDCTL1),a
ld a,044H ; Set ASCII parameters (44=1, 4C=2 stop)
out (MDCTL1),a
ld a,03H ; Select register
out (MDCTL1),a
ld a,0C1H ; Enable receive
out (MDCTL1),a
ld a,05H ; Select register
out (MDCTL1),a
ld a,0EAH ; enable send, 'DTR', RTS'
out (MDCTL1),a
ld a,(MSPEED) ; Get the selected value
cp 1 ; 300 bps
jp z,OK300
cp 5 ; 1200 bps
jp z,OK1200
cp 6 ; 2400 bps
jp z,OK2400
cp 8 ; 9600 bps
jp z,OK9600
cp 9 ; 19.2k bps
jp z,OK19200
jr setbrx ; not valid
OK300:
ld a,1 ; MSPEED 300 bps value
ld b,BD300
jp LOADED
OK1200:
ld a,5 ;
ld b,BD1200
jp LOADED
OK2400:
ld a,6
ld b,BD2400
jp LOADED
OK9600:
ld a,8
ld b,BD9600
jp LOADED
OK19200:
ld a,9
ld b,BD19200
LOADED:
ld (MSPEED),a ; change time-to-send baudrate
ld a,b
out (BRPORT),a
ld a,(brate) ; tell zmp it's ok
ld (mspeed),a
setbrx:
pop bc
;-- End of this block of machine specific code
ret
BD300 equ 5
BD1200 equ 7
BD2400 equ 10
BD9600 equ 14
BD19200 equ 15
; using values below
; <== End of your own code
ret
brate: ds 2 ; baud rate:
; 0 = 110 baud 1 = 300 baud 2 = 450 baud
; 3 = 600 baud 4 = 710 baud 5 = 1200 baud
; 6 = 2400 baud 7 = 4800 baud 8 = 9600 baud
; 9 = 19200 baud
parity: ds 2 ; parity (will be 'N', 'E' or 'O')
data: ds 2 ; data bits (will be 7 or 8)
stop: ds 2 ; stop bits (will be 1 or 2)
;****************************************************************************
;Video terminal sequences: these are for ADM-3A: Modify as you wish
;Cursor addressing:
cursadd:
ld hl,2 ; get parameters
add hl,sp
ex de,hl
call getparm ; in HL
ld (row),hl ; row
call getparm
ld (col),hl ; column
; <== Insert your own code here
; using values in row and col
call print
db esc,'=',0 ; ADM-3A leadin
ld a,(row) ; row first
add a,' ' ; add offset
call cout
ld a,(col) ; sane for column
add a,' '
call cout
; <== end of your own code
ret
row: ds 2 ; row
col: ds 2 ; column
;Clear screen:
cls:
call print
db 01ah,0
ret
;Inverse video on:
invon:
call print
db esc,')',0
ret
;Inverse video off:
invoff:
call print
db esc,'(',0
ret
;Turn off cursor:
hide:
call print
db esc,'z',0
ret
;Turn on cursor:
show:
call print
db esc,'v',0
ret
;Save cursor position:
savecu:
ret
;Restore cursor position:
rescu:
ret
;****************************************************************************
;Service modem interrupt:
mint:
ret ; my system doesn't need this
;Initialise interrupt vectors:
invec:
ret ; ditto
;De-initialise interrupt vectors:
dinvec:
ret ; ditto
;****************** End of user-defined code ********************************
; Don't change anything below this point. We needed some assembly language
; stuff for speed, and this seemed like a good place to put it.
;Modem character test for 100 ms
mrd:
push bc ; save bc
ld bc,100 ; set limit
mrd1:
call mirdy ; char at modem?
jr nz,mrd2 ; yes, exit
ld hl,1 ; else wait 1ms
call waithlms
dec bc ; loop till done
ld a,b
or c
jr nz,mrd1
ld hl,0 ; none there, result=0
xor a
mrd2:
pop bc
ret
; Inline print routine: destroys A and HL
print:
ex (sp),hl ; get address of string
ploop:
ld a,(hl) ; get next
inc hl ; bump pointer
or a ; done if zero
jr z,pdone
call cout ; else print
jr ploop ; and loop
pdone:
ex (sp),hl ; restore return address
ret ; and quit
;
;Output a character in A to the console
;
cout:
push bc ; save regs
push de
push hl
ld e,a ; character to E
ld c,2
call bdos ; print it
pop hl
pop de
pop bc
ret
;Wait(seconds)
wait:
ld hl,2
add hl,sp
ex de,hl ; get delay size
call getparm
; fall thru to..
;Wait seconds in HL
waithls:
push bc ; save bc
push de ; de
push ix ; and ix
ld ix,0 ; then point ix to 0
; so we don't upset memory-mapped i/o
;Calculate values for loop constants. Need to have two loops to avoid
; 16-bit overflow with clock speeds above 9 MHz.
outerval equ (clkspd / 10) + 1
innerval equ (6667 / outerval) * clkspd
wait10:
ld b,outerval
wait11:
ld de,innerval
wait12:
bit 0,(ix) ; time-wasters
bit 0,(ix)
bit 0,(ix) ; 20 T-states each
bit 0,(ix)
bit 0,(ix)
bit 0,(ix)
dec de
ld a,e
ld a,d
or e
jr nz,wait12 ; 150 T-states per inner loop
djnz wait11 ; decrement outer loop
dec hl ; ok, decrement count in hl
ld a,h
or l
jr nz,wait10
pop ix ; done -- restore ix
pop de ; de
pop bc ; and bc
ret
;Wait milliseconds
mswait:
ld hl,2
add hl,sp
ex de,hl ; get delay size
call getparm
; fall thru to..
;Wait milliseconds in HL
waithlms:
push de
w1ms0:
ld de,39 * clkspd
w1ms1:
dec de
ld a,d
or e
jr nz,w1ms1
dec hl
ld a,h
or l
jr nz,w1ms0
pop de
ret
;Get next parameter from (de) into hl
getparm:
ex de,hl ; get address into hl
ld e,(hl) ; get lo
inc hl
ld d,(hl) ; then hi
inc hl ; bump for next
ex de,hl ; result in hl, address still in de
ret
;Get address of user-defined variables
getvars:
ld hl,uservars
ret
uservars:
dw overdrive ; .OVR etc. drive/user
dw overuser
if ($ - codebgn) gt ovsize
toobig: jp errval ; Overlay too large!
endif
end