home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
BEEHIVE
/
COMMS
/
ZMP-OV16.ARC
/
ZMO-MH04.Z80
< prev
next >
Wrap
Text File
|
1991-02-02
|
17KB
|
871 lines
;-----------------------------------------------------------------------------
;
; Overlay for ZMP (Z-Modem Program)
;
; Name ZMO-MH04.Z80
;
; Dated 19 Sep 1988
;
; Written by -
; Ron Murray, c/o Z-Node 62, 061-9-450-0200, Perth, Western Australia.
; Modified for the MD11 by Lindsay Allen, sysop, Z-Node 62.
;
; Modified to ZMP v1.2 standard rjm 15/9/88
; Modified to v1.3 standard rjm 12/10/88
; Modified to v1.4 standard and added 1200/75 rjm 23/11/88
;
;
; Rename subsequent versions as ZMO-MHxx.Z80 etc
;
;
; This overlay is set up for a Morrow MD11 using the SIO.
; Uses a Z80SIO and an 8253 CTC
;
;
;-----------------------------------------------------------------------------
;
;
; System-dependent code overlay for ZMODEM
;
;
;
; Insert your own code as necessary in this file. Code contained herein
; has been written in Z80 code for use with M80 or SLR. Assemble as follows:
;
; SLR ZMO-MHxx/h
; MLOAD ZMP.COM=ZMPX.COM,ZMO-MHxx.HEX
; or
; M80 =ZMO-MHxx.Z80
; RELHEX ZMO-MHxx
; MLOAD ZMP.COM=ZMPX.COM,ZMO-MHxx.HEX
;
;
; (Don't use L80 without changing the source for assembly as a
; cseg file.)
;
;-----------------------------------------------------------------------------
;
;
; Notes on modifying this file:
;
; C requires that functions do not change either index register
; (IX or IY), nor the BC register pair. If your overlay requires any of
; these to be changed, ensure they are restored to the original values
; on return.
; Since collecting parameters from C functions can be tricky, only change
; the parts marked 'Insert your own code here'. Do NOT modify the jump
; table at the start. Do NOT modify the entry/exit sections of each
; function. Do NOT pass 'GO'. Do NOT collect $200.
; Apart from defining modem functions, this file also defines terminal
; characteristics. Most have been set up for ADM-3A (with a few of my own
; additions). Modify to suit your own terminal. An inline print routine
; is provided for printing strings in the usual way: usage is
;
; call print
; db 'required string',0
;
;-----------------------------------------------------------------------------
;
;
; Don't forget to set your clock speed at the clkspd variable.
;
;
; If you find your overlay exceeds the maximum size (currently 0400h),
; you will have to contact me for another version. If too many people need
; to do it, we haven't allowed enough room.
;
; Ron Murray 15/8/88
;
;
;
;
;
;
;
;
;
;
;---------------------------------------------------------------------------
;
; |
; Ports: |
; Console data 60 | |
; stat 61 | |
; Modem data 62 | Rx bit 2 |
; stat 63 | Tx 0 |
; SIO data 70 | |
; stat 71 | |
; |
; |
; mode 3 bnkbios3 |
; CTC SIO 50 ch 0 3E port 3 (baud2) |
; modem 51 ch 1 7E port 2 (baud1) |
; con 52 ch 2 BE port 1 (baud0) |
; select 53 |
; |
; |
;
;
;---------------------------------------------------------------------------
false equ 0
true equ not false
; User-set variables: ***********
clkspd equ 4 ; Processor clock speed in MHz
debug equ false
userdef equ 00145h ; origin of this overlay
; This address should remain constant
; with subsequent revisions.
sio equ true ; true to use the SIO, false to use the DART
s1275 equ true ; true to use 1200/75, with the DART sending
; at 75 and the SIO receiving at 1200. Ensure
; the sio equate is set TRUE.
;Set the following two equates to the drive and user area which will contain
; ZMP's .OVR files, .CFG file, .FON file and .HLP file. Set both to zero
; (null) to locate them on the drive from which ZMP was invoked.
overdrive equ 'A' ; Drive to find overlay files on ('A'-'P')
overuser equ 3 ; User area to find files
; NOT user-set variables
mspeed equ 003ch ; baud rate id
ovsize equ 0400h ; max size of this overlay
.z80 ; use z80 code
aseg ; absolute
if debug
org 100h ; so you can debug it with cebug, zsid, etc
else
org userdef
endif
esc equ 1bh
ctrlq equ 11h
cr equ 0dh
lf equ 0ah
bdos equ 5
; MDII specific equates ***************************************************
if SIO
mdata equ 070h ; use RS232 socket at other end from Terminal
mstat equ mdata+1
ctc equ 50h
mode equ 3Eh
else
mdata equ 62h ; use RSs232 socket adjacent to Terminal
mstat equ mdata+1
ctc equ 51h
mode equ 7Eh
endif
if s1275 and sio ; must have sio set for 1200/75
bmdata equ 62h
bmstat equ bmdata+1
bctc equ 51h
bmode equ 7Eh
endif
rda equ 0
tbe equ 2
ctcsel equ 53h
onhook equ 7Fh
online equ 80h
error equ 70h
break equ 0F8h
reset equ 30h
; ******************************************
;-------------------------------------------------------------------------
; Main code starts here
codebgn equ $
;Jump table for the overlay: do NOT change this
jump_tab:
jp scrnpr ; screen print
jp mrd ; modem read with timeout
jp mchin ; get a character from modem
jp mchout ; send a character to the modem
jp mordy ; test for tx buffer empty
jp mirdy ; test for character received
jp sndbrk ; send break
jp cursadd ; cursor addressing
jp cls ; clear screen
jp invon ; inverse video on
jp invoff ; inverse video off
jp hide ; hide cursor
jp show ; show cursor
jp savecu ; save cursor position
jp rescu ; restore cursor position
jp mint ; service modem interrupt
jp invec ; initialise interrupt vectors
jp dinvec ; de-initialise interrupt vectors
jp mdmerr ; test uart flags for error
jp dtron ; turn DTR on
jp dtroff ; turn DTR OFF
jp init ; initialise uart
jp wait ; wait seconds
jp mswait ; wait milliseconds
jp userin ; user-defined entry routine
jp userout ; user-defined exit routine
jp getvars ; get system variables
;Spare jumps for compatibility with future versions
jp spare ; spares for later use
jp spare ; spares for later use
jp spare ; spares for later use
jp spare ; spares for later use
jp spare ; spares for later use
spare: ret
;-------------------------------------------------------------------------
;
;Screen print function
scrnpr:
; <== Insert your own code here
call print
db 'This function not supported.',cr,lf,0
; <== End of your own code
ret
;Get a character from the modem: return in HL
mchin:
push bc
; <== Insert your own code here
mchin2:
in a,(mstat) ; check for char waiting
bit rda,a
jr z,mchin2
in a,(mdata) ; read the char
; <== End of your own code
ld l,a ; put in HL
ld h,0
or a ; set/clear Z
pop bc
ret
;Send a character to the modem
mchout:
ld hl,2 ; get the character
add hl,sp
ld a,(hl)
; <== Insert your own code here
push bc
ld b,a ; save the char
if s1275
ld a,(mspeed) ; are we using 110 baud?
or a
jr nz,mchout2 ; no, act normally..
mchout1:
in a,(bmstat)
bit tbe,a
jr z,mchout1
ld a,b
out (bmdata),a
jr mchout3
endif ; s1275
mchout2:
in a,(mstat) ; check for uart ready
bit tbe,a
jr z,mchout2
ld a,b ; char in a
out (mdata),a ; send it
mchout3:
pop bc
; <== End of your own code
ret ; done
;Test for output ready: return TRUE (1) in HL if ok
mordy:
; <== Insert your own code here
ld hl,0 ; assume not ready
if s1275
ld a,(mspeed) ; are we running 12/75?
or a
jr nz,mordy1
in a,(bmstat)
bit tbe,a
jr z,mordy2
inc hl
jr mordy2
endif ; s1275
mordy1:
in a,(mstat)
bit tbe,a ; transmit buffer empty
jr z,mordy2
inc hl
mordy2:
; <== End of your own code
ld a,l ; set/clear Z
or a
ret
;Test for character at modem: return TRUE (1) in HL if so
mirdy:
; <== Insert your own code here
ld hl,0
in a,(mstat)
bit rda,a ; received data available
jr z,mirdy1
inc hl
mirdy1:
; <== End of your own code
ld a,l ; set/clear Z
or a
ret
;Send a break to the modem: leave empty if your system can't do it
sndbrk:
; <== Insert your own code here
ld a,5
out (mstat),a
ld a,break ; F8
out (mstat),a
ld hl,300 ; a 300 mS break
call waithlms
ld a,5
out (mstat),a
ld a,online ; 68
out (mstat),a
ld a,3
out (mstat),a
ld a,0E1h
out (mstat),a ; E1
; <== End of your own code
ret
;
;Test UART flags for error: return TRUE (1) in HL if error.
mdmerr:
; <== Insert your own code here
ld hl,0
in a,(mstat)
and error
jr z,mdmer2
inc hl
mdmer2:
; <== End of your own code
ld a,l ; set/clear Z
or a
ret
;Turn DTR ON
dtron:
; <== Insert your own code here
ld a,5
out (mstat),a
if s1275
out (bmstat),a
endif
ld a,(combyt) ; get the one we used last time
or online ; 80h - set bit 7 high
ld (combyt),a ; save it for next time
out (mstat),a ; go
if s1275
out (bmstat),a
endif
; <== End of your own code
ret
;Turn DTR OFF
dtroff:
; <== Insert your own code here
ld a,5
out (mstat),a
if s1275
out (bmstat),a
endif
ld a,(combyt) ; get the one we used last time
and onhook ; 7Fh - clear bit 7
ld (combyt),a ; save it for next time
out (mstat),a ; go
if s1275
out (bmstat),a
endif
; <== End of your own code
ret
;Initialise the SIO +++
; The SIO is set up in four steps:
; 1) Reset
; 2) Reg 4 - clock, stop bits, parity
; 3) Reg 5 - dtr, Tx bits, Brk, TxEn, rts
; 4) Reg 3 - Rx bits, RxEn
init:
ld hl,2 ; get parameters
add hl,sp
ex de,hl
call getparm ; in HL
ld (brate),hl ; baud rate
ld a,l
ld (003Ch),a ; save the baud rate in 3C for later as per IMP
call getparm
ld (parity),hl ; parity
call getparm
ld (data),hl ; data bits
call getparm
ld (stop),hl ; stop bits
; <== Insert your own code here
; using values below
push bc
ld a,0
out (mstat),a ; point to reg 0
ld a,18h ; reset
out (mstat),a ; *** step 1
if s1275
ld a,0
out (bmstat),a ; back channel too
ld a,18h
out (bmstat),a
endif
ld a,4 ; point to wrt reg 4
out (mstat),a
if s1275
out (bmstat),a ; back channel too
endif
ld e,44h ; assume x16, 1 stop, No parity
ld a,(stop) ; set stop bits
cp 2 ; set 2 if required
jr nz,setpar
set 3,e
setpar:
ld a,(parity) ; set parity bits
cp 'O'
jr nz,setpa2
set 0,e ; ODD
jr setpa3
setpa2: cp 'E'
jr nz,setpa3
set 0,e
set 1,e ; EVEN
setpa3: ld a,e
out (mstat),a ; *** step 2
if s1275
out (bmstat),a ; back channel too
endif
ld a,5 ; point to wrt reg 5 - dtr, Tx bits, etc
out (mstat),a
if s1275
out (bmstat),a ; back channel too
endif
ld e,0EAh ; assume dtr, TX 8 bits, TxEn, rts
ld a,(data)
cp 7
jr nz,setbi2
res 6,e ; 7 bits
setbi2: ld a,e
out (mstat),a ; *** step 3
if s1275
out (bmstat),a ; back channel too
endif
ld a,3 ; point to wrt reg 3
out (mstat),a
if s1275
out (bmstat),a ; back channel too
endif
ld e,0C1h ; assume 8 bits
ld a,(data)
cp 7
jr nz,setbi3
res 7,e ; 7 bits
setbi3: ld a,e
out (mstat),a ; *** step 4
if s1275
out (bmstat),a ; back channel too
endif
setbrate:
push ix
ld de,(brate) ; get baud rate value (0-10)
if s1275
ld a,e ; see if 12/75
or a
jr nz,setbr1 ; no
ld de,5 ; yes, set main channel to 1200
endif
setbr1:
ld hl,brval
add hl,de
add hl,de ; hl now points to the divisor dw
push hl ; look at it
pop ix
ld a,(ix)
or (ix+1)
jr z,setbrx ; zero = invalid
ld c,ctcsel ; 053h
ld a,mode ; 03Eh or 7Eh
out (c),a ; select the correct timer and mode of the 8253
ld c,ctc ; 050h or 51h
outi ; lo byte
outi ; hi byte
if s1275
ld hl,brv75 ; set back chnl to 75 baud
ld c,ctcsel ; 053h
ld a,bmode ; 03Eh or 7Eh
out (c),a ; select the correct timer and mode of the 8253
ld c,bctc ; 050h or 51h
outi ; lo byte
outi ; hi byte
endif ; s1275
ld a,(brate) ; tell zmp it's ok
ld (mspeed),a
setbrx:
pop ix
pop bc
; <== End of your own code
ret
;--------------------------------------------------------------------------
stop: dw 1 ; stop bits
parity: dw 'N' ; parity
data: dw 8 ; data bits
brate: dw 7 ; baud rate:
combyt: db 0EAh ; for now
;--------------------------------------------------------------------------
;Values for 8253 control reg for each baud rate
brv75:
dw 3332 ; 75 baud for 1200/75
brval:
dw 2273 ; 110 0
dw 833 ; 300 1
dw 555 ; 450 2
dw 417 ; 600 3
dw 352 ; 710 4
dw 208 ; 1200 5
dw 104 ; 2400 6
dw 52 ; 4800 7
dw 26 ; 9600 8
dw 13 ; 19200 9
dw 0 ; 38400 10
dw 0 ; 57600 11
dw 0 ; 76800 12
;****************************************************************************
;Video terminal sequences: these are for ADM-3A: Modify as you wish
;Cursor addressing:
cursadd:
ld hl,2 ; get parameters
add hl,sp
ex de,hl
call getparm ; in HL
ld (row),hl ; row
call getparm
ld (col),hl ; column
; <== Insert your own code here
; using values in row and col
call print
db esc,'=',0 ; ADM-3A leadin
ld a,(row) ; row first
add a,' ' ; add offset
call cout
ld a,(col) ; sane for column
add a,' '
call cout
; <== end of your own code
ret
row: ds 2 ; row
col: ds 2 ; column
;Clear screen:
cls:
call print
db esc,'*',0
ret
;Inverse video on:
invon:
call print
db esc,'G4',0
ret
;Inverse video off:
invoff:
call print
db esc,'G0',0
ret
;Turn off cursor:
hide:
call print
db esc,'.1',0
ret
;Turn on cursor:
show:
call print
db esc,'.3',0
ret
;Save cursor position:
savecu:
ret
;Restore cursor position:
rescu:
ret
;****************************************************************************
;Service modem interrupt:
mint:
ret ; my system doesn't need this
;Initialise interrupt vectors:
invec:
ret ; ditto
;De-initialise interrupt vectors:
dinvec:
ret ; ditto
;User-defined entry routine: leave empty if not used
userin:
ret
;User-defined exit routine: leave empty if not used
userout:
ret
;****************** End of user-defined code ********************************
; Do not change anything below here.
;Modem character test for 100 ms
mrd:
push bc ; save bc
ld bc,100 ; set limit
mrd1:
call mirdy ; char at modem?
jr nz,mrd2 ; yes, exit
ld hl,1 ; else wait 1ms
call waithlms
dec bc ; loop till done
ld a,b
or c
jr nz,mrd1
ld hl,0 ; none there, result=0
xor a
mrd2:
pop bc
ret
; Inline print routine: destroys A and HL
print:
ex (sp),hl ; get address of string
ploop:
ld a,(hl) ; get next
inc hl ; bump pointer
or a ; done if zero
jr z,pdone
call cout ; else print
jr ploop ; and loop
pdone:
ex (sp),hl ; restore return address
ret ; and quit
;
;Output a character in A to the console
;
cout:
push bc ; save regs
push de
push hl
ld e,a ; character to E
ld c,2
call bdos ; print it
pop hl
pop de
pop bc
ret
;Wait(seconds)
wait:
ld hl,2
add hl,sp
ex de,hl ; get delay size
call getparm
; fall thru to..
;Wait seconds in HL
waithls:
push bc ; save bc
push de ; de
push ix ; and ix
ld ix,0 ; then point ix to 0
; so we don't upset memory-mapped i/o
;Calculate values for loop constants. Need to have two loops to avoid
; 16-bit overflow with clock speeds above 9 MHz.
outerval equ (clkspd / 10) + 1
innerval equ (6667 / outerval) * clkspd
wait10:
ld b,outerval
wait11:
ld de,innerval
wait12:
bit 0,(ix) ; time-wasters
bit 0,(ix)
bit 0,(ix) ; 20 T-states each
bit 0,(ix)
bit 0,(ix)
bit 0,(ix)
dec de
ld a,e
ld a,d
or e
jr nz,wait12 ; 150 T-states per inner loop
djnz wait11 ; decrement outer loop
dec hl ; ok, decrement count in hl
ld a,h
or l
jr nz,wait10
pop ix ; done -- restore ix
pop de ; de
pop bc ; and bc
ret
;Wait milliseconds
mswait:
ld hl,2
add hl,sp
ex de,hl ; get delay size
call getparm
; fall thru to..
;Wait milliseconds in HL
waithlms:
push de
w1ms0:
ld de,39 * clkspd
w1ms1:
dec de
ld a,d
or e
jr nz,w1ms1
dec hl
ld a,h
or l
jr nz,w1ms0
pop de
ret
;Get next parameter from (de) into hl
getparm:
ex de,hl ; get address into hl
ld e,(hl) ; get lo
inc hl
ld d,(hl) ; then hi
inc hl ; bump for next
ex de,hl ; result in hl, address still in de
ret
;Get address of user-defined variables
getvars:
ld hl,uservars
ret
uservars:
dw overdrive ; .OVR etc. drive/user
dw overuser
if ($ - codebgn) gt ovsize
toobig: jp errval ; Overlay too large!
endif
end