home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / BEEHIVE / COMMS / ZMP-OV16.ARC / ZMO-CP05.Z80 < prev    next >
Text File  |  1991-02-02  |  17KB  |  751 lines
  1. ;-----------------------------------------------------------------------------
  2. ;
  3. ;    Name    ZMO-CP05.Z80
  4. ;
  5. ;    Dated Sep 14, 1988
  6. ;
  7. ;    Written by -
  8. ;      Ron Murray, c/o Z-Node 62, 061-9-450-0200, Perth, Western Australia.
  9. ;
  10. ;    Modified to ZMP v1.2 standard rjm 15/9/88
  11. ;    Modified to ZMP v1.3 standard rjm 11/10/88
  12. ;    Modified to ZMP v1.4 standard rjm 20/11/88
  13. ;    Modified to ZMP v1.5 standard rjm 25/3/89
  14. ;
  15. ;    This overlay is set up for an Amstrad CPC6128 under CPM Plus, with a
  16. ;      Zenith Z19/Z29 terminal emulation and a Z80SIO and 8253 counter.
  17. ;
  18. ;-----------------------------------------------------------------------------
  19. ;
  20. ;    System-dependent code overlay for ZMODEM
  21. ;
  22. ;
  23. ;    Insert your own code as necessary in this file. Code contained herein
  24. ; has been written in Z80 code for use with M80 or SLR. Assemble as follows:
  25. ;
  26. ;    SLR ZMO-xx01/h
  27. ;    MLOAD ZMP.COM=ZMODEM.COM,ZMO-xx01.HEX
  28. ; or
  29. ;    M80 =ZMO-xx01.Z80
  30. ;    RELHEX ZMO-xx01
  31. ;    MLOAD ZMP.COM=ZMODEM.COM,ZMO-xx01.HEX
  32. ;
  33. ;
  34. ;       (Don't use L80 without changing the source for assembly as a
  35. ;         cseg file.)
  36. ;
  37. ;-----------------------------------------------------------------------------
  38. ;
  39. ;
  40. ; Notes on modifying this file:
  41. ;
  42. ;    C requires that functions do not change either index register (IX or IY).
  43. ; If your overlay requires either of these to be changed, ensure they are
  44. ; restored to the original values on return.
  45. ;    Since collecting parameters from C functions can be tricky, only change
  46. ; the parts marked 'Insert your own code here'. Do NOT modify the jump
  47. ; table at the start. Do NOT modify the entry/exit sections of each
  48. ; function. Do NOT pass 'GO'. Do NOT collect $200.
  49. ;    Apart from defining modem functions, this file also defines terminal
  50. ; characteristics. Examples provided are for ADM-3A (with a few of my own
  51. ; additions). Modify to suit your own terminal. An inline print routine
  52. ; is provided for printing strings in the usual way: usage is
  53. ;
  54. ;    call    print
  55. ;    db    'required string',0
  56. ;
  57. ;-----------------------------------------------------------------------------
  58. ;
  59. ;
  60. ;    Don't forget to set your clock speed at the clkspd variable.
  61. ;
  62. ;
  63. ;    If you find your overlay exceeds the maximum size (currently 0400h),
  64. ; you will have to contact me for another version. If too many people need 
  65. ; to do it, we haven't allowed enough room.
  66. ;
  67. ; Ron Murray 15/8/88
  68. ;
  69. ;
  70. ;
  71. ;---------------------------------------------------------------------------
  72.  
  73. false    equ    0
  74. true    equ    not false
  75.  
  76. ;------------------------------------------------------------------------------
  77.  
  78. ; User-set variables: 
  79.  
  80. clkspd    equ    4        ; Processor clock speed in MHz
  81. debug    equ    false        ; to allow debugging of overlay with Z8E etc.
  82.  
  83. ;Set the following two equates to the drive and user area which will contain
  84. ;   ZMP's .OVR files, .CFG file, .FON file and .HLP file. Set both to zero
  85. ;   (null) to locate them on the drive from which ZMP was invoked.
  86.  
  87. overdrive    equ    'A'    ; Drive to find overlay files on ('A'-'P')
  88. overuser    equ    0    ; User area to find files
  89.  
  90. ;------------------------------------------------------------------------------
  91.  
  92.  
  93. ; NOT user-set variables
  94.  
  95. userdef    equ    0145h        ; origin of this overlay
  96.                 ; This address should not change with
  97.                 ; subsequent revisions.
  98. mspeed    equ    03ch        ; location of current baud rate. 
  99. ovsize    equ    0400h        ; max size of this overlay
  100.  
  101.     .z80            ; use z80 code
  102.     aseg            ; absolute
  103.  
  104.      if    debug
  105.     org    100h        ; so you can debug it with cebug, zsid, etc
  106.      else
  107.     org    userdef
  108.      endif
  109.  
  110.  
  111. esc    equ    1bh
  112. ctrlq    equ    11h
  113. cr    equ    0dh
  114. lf    equ    0ah
  115. bdos    equ    5
  116. ;--------------------------------------------------------------------
  117. ; 
  118. mdata    equ    0FADCH        ; data port  \_A port
  119. mstat    equ    0FADDH        ; status port/
  120.  
  121. mdatab    equ    0FADEH        ; data port  \_B port
  122. mstatb    equ    0FADFH        ; status port/
  123.  
  124. rda    equ    0        ; Received data available
  125. tbe    equ    2        ; Tx ready
  126. error    equ    70h
  127. break    equ    0F8h
  128.  
  129. ; 8253 Counter equates
  130.  
  131. ctcont    equ    0FBDFH        ; Control register of the 8253
  132.  
  133. ctc0    equ    0FBDCH        ; Counter #0 of the 8253\_A port 
  134. ctc1    equ    0FBDDH        ; Counter #1 '   '   '  /
  135.  
  136. ctc2    equ    0FBDEH        ; Conuter #2 '   '   ' ---B port
  137. ;------------------------------------------------------
  138. codebgn    equ    $
  139.  
  140. ;Jump table for the overlay: do NOT change this
  141. jump_tab:
  142.     jp    scrnpr        ; screen print
  143.     jp    mrd        ; modem read with timeout
  144.     jp    mchin        ; get a character from modem
  145.     jp    mchout        ; send a character to the modem
  146.     jp    mordy        ; test for tx buffer empty
  147.     jp    mirdy        ; test for character received
  148.     jp    sndbrk        ; send break
  149.     jp    cursadd        ; cursor addressing
  150.     jp    cls        ; clear screen
  151.     jp    invon        ; inverse video on
  152.     jp    invoff        ; inverse video off
  153.     jp    hide        ; hide cursor
  154.     jp    show        ; show cursor
  155.     jp    savecu        ; save cursor position
  156.     jp    rescu        ; restore cursor position
  157.     jp    mint        ; service modem interrupt
  158.     jp    invec        ; initialise interrupt vectors
  159.     jp    dinvec        ; de-initialise interrupt vectors
  160.     jp    mdmerr        ; test uart flags for error
  161.     jp    dtron        ; turn DTR on
  162.     jp    dtroff        ; turn DTR OFF
  163.     jp    init        ; initialise uart
  164.     jp    wait        ; wait seconds
  165.     jp    mswait        ; wait milliseconds
  166.     jp    userin        ; user-defined entry routine
  167.     jp    userout        ; user-defined exit routine
  168.     jp    getvars        ; get system variables
  169.     jp    setport        ; set port (1 or 2)
  170.  
  171. ; Spare jumps for compatibility with future versions
  172.     jp    spare        ; spare for later use
  173.     jp    spare        ; spare for later use
  174.     jp    spare        ; spare for later use
  175.     jp    spare        ; spare for later use
  176.     jp    spare        ; spare for later use
  177.     jp    spare        ; spare for later use
  178.  
  179. ;
  180. ; Main code starts here
  181. ;
  182. ;Screen print function
  183. scrnpr:
  184.                 ; <== Insert your own code here
  185.     call    print
  186.     db    'This function not supported.',cr,lf,0
  187.                 ; <== End of your own code
  188. spare:
  189.     ret
  190.  
  191. ; User-defined entry routine: leave empty if not needed
  192. userin:
  193.     ret
  194.  
  195. ; User-defined exit routine: leave empty if not needed
  196. userout:
  197.     ret
  198.  
  199.  
  200. ;Get a character from the modem: return in HL
  201. mchin:    push    bc
  202.                 ; <== Insert your own code here
  203.     ld    bc,(status)
  204. mchin2:    in    a,(c)        ; check for byte waiting
  205.     bit    rda,a
  206.     jr    z,mchin2
  207.     ld    bc,(portadd)
  208.     in    a,(c)        ; read in the byte
  209.  
  210.                 ; <== End of your own code
  211.     ld    l,a        ; put in HL
  212.     ld    h,0
  213.     or    a        ; set/clear Z
  214.     pop    bc
  215.     ret
  216.  
  217. ;Send a character to the modem
  218. mchout:
  219.     ld    hl,2        ; get the character
  220.     add    hl,sp
  221.     ld    a,(hl)
  222.                 ; <== Insert your own code here
  223.     push    bc
  224.     ld    bc,(status)
  225. mchout2:in    e,(c)        ; check for uart ready
  226.     bit    tbe,e
  227.     jr    z,mchout2
  228.     ld    bc,(portadd)
  229.     out    (c),a        ; send it
  230.     pop    bc
  231.                 ; <== End of your own code
  232.  
  233.     ret            ; done
  234.  
  235. ;Test for output ready: return TRUE (1) in HL if ok
  236. mordy:
  237.                 ; <== Insert your own code here
  238.     push    bc
  239.     ld    bc,(status)
  240.     ld    hl,0
  241.     in    a,(c)
  242.     bit    tbe,a        ; transmit buffer empty
  243.     jr    z,mordy1
  244.     inc    hl
  245. mordy1:    pop    bc
  246.                 ; <== End of your own code
  247.  
  248.     ld    a,l        ; set/clear Z
  249.     or    a
  250.     ret
  251.  
  252. ;Test for character at modem: return TRUE (1) in HL if so
  253. mirdy:
  254.                 ; <== Insert your own code here
  255.     push    bc
  256.     ld    bc,(status)
  257.     ld    hl,0
  258.     in    a,(c)
  259.     bit    rda,a        ; received data available
  260.     jr    z,mirdy1
  261.     inc    hl
  262. mirdy1:    pop    bc
  263.                 ; <== End of your own code
  264.  
  265.     ld    a,l        ; set/clear Z
  266.     or    a
  267.     ret
  268.  
  269. ;Send a break to the modem: leave empty if your system can't do it
  270. sndbrk:
  271.                 ; <== Insert your own code here
  272.  
  273.     ld    hl,300        ; wait 300 mS
  274.     call    waithlms
  275.  
  276.                 ; <== End of your own code
  277.     ret
  278. ;
  279. ;Test UART flags for error: return TRUE (1) in HL if error.
  280. mdmerr:
  281.                 ; <== Insert your own code here
  282.     push    bc
  283.     ld    bc,(status)
  284.     ld    hl,0
  285.     in    a,(c)
  286.        and    a,error
  287.     jr    z,mdmer2
  288.     inc    hl
  289. mdmer2:    pop    bc
  290.                 ; <== End of your own code
  291.  
  292.     ld    a,l        ; set/clear Z
  293.     or    a
  294.     ret
  295.  
  296.  
  297. ;Turn DTR ON
  298. dtron:
  299.             ; <== Insert your own code here
  300.     push    bc
  301.     ld    bc,(status)
  302.     ld    a,5
  303.     out    (c),a
  304.     ld    a,(combyt)    ; get the value of byte
  305.     set    7,a        ; set bit 7
  306.     out    (c),a        ; go
  307.     pop    bc        ;
  308.  
  309.                 ; <== End of your own code
  310.     ret
  311.  
  312. ;Turn DTR OFF
  313. dtroff:
  314.                 ; <== Insert your own code here
  315.     push    bc
  316.     ld    bc,(status)
  317.     ld    a,5
  318.     out    (c),a
  319.     ld    a,(combyt)    ; get the one we used last time
  320.     res    7,a        ; clear bit 7
  321.     out    (c),a        ; go
  322.     pop    bc
  323.                 ; <== End of your own code
  324.     ret
  325.  
  326. ;Initialise the SIO +++
  327. ; The SIO is set up in four steps:
  328. ;     1)  Reset
  329. ;       2)  Reg 4 - clock, stop bits, parity
  330. ;    3)  Reg 5 - dtr, Tx bits, Brk, TxEn, rts
  331. ;    4)  Reg 3 - Rx bits, RxEn
  332.  
  333. init:    ld    hl,2        ; get parameters
  334.     add    hl,sp
  335.     ex    de,hl
  336.     call    getparm        ; in HL
  337.     ld    (brate),hl    ; baud rate
  338.     call    getparm
  339.     ld    (parity),hl    ; parity
  340.     call    getparm
  341.     ld    (data),hl    ; data bits (BINARY 7 or 8)
  342.     call    getparm
  343.     ld    (stop),hl    ; stop bits (BINARY 1 or 2)
  344.  
  345.                 ; <== Insert your own code here
  346.     push    bc
  347.     push    ix
  348.     ld    bc,(status)
  349.     ld    a,0
  350.     out    (c),a        ; point to reg 0
  351.     ld    a,18h        ; reset
  352.     out    (c),a        ;                *** step 1
  353.  
  354.     ld    a,4        ; point to wrt reg 4
  355.     out    (c),a
  356.     ld    e,44H        ; assume  x16, 1 stop, No parity
  357.     ld    a,(stop)    ; set stop bits
  358.     cp    2        ; set 2 if required
  359.     jr    nz,setpar
  360.     ld    a,08h        ; 0000 1000
  361.     or    e
  362.     ld    e,a
  363. setpar:    ld    a,(parity)    ; set parity bits
  364.     cp    'O'
  365.     jr    nz,setpa2
  366.     ld    d,01h        ; 0000 0001    ODD
  367.     jr    setpa3
  368. setpa2:    cp    'E'
  369.     jr    nz,setpa4
  370.     ld    d,03h        ; 0000 0011    EVEN
  371. setpa3:    ld    a,e
  372.     or    a,d
  373.     ld    e,a
  374. setpa4:    ld    a,e
  375.     out    (c),a        ;                *** step 2
  376.  
  377.     ld    a,5        ; point to wrt reg 5 - dtr, Tx bits, etc
  378.     out    (c),a
  379.     ld    e,0EAH        ; assume dtr, TX 8 bits, TxEn, rts 1110 1010
  380.     ld    a,(data)
  381.     cp    7
  382.     jr    nz,setbi2
  383.     ld    d,0AAH        ; 1010 1010    7 bits
  384. setbi2:    ld    a,e
  385.     out    (c),a
  386.     ld    (combyt),a    ; This byte used for DTR on/off *** step 3
  387.  
  388.     ld    a,3        ; point to wrt reg 3
  389.     out    (c),a
  390.     ld    e,0C1H        ; assume 8 bits 1100 0001
  391.     ld    a,(data)
  392.     cp    7
  393.     jr    nz,setbi3
  394.     ld    d,041H        ; 7 bits 0100 0001
  395. setbi3:    ld    a,e
  396.     out    (c),a        ;                *** step 4
  397.  
  398. setbrate:
  399.     ld    de,(brate)    ; get baud rate value (0-10)
  400.     ld    ix,brval
  401.     add    ix,de
  402.     add    ix,de        ; ix now points to the 2-byte value
  403.     ld    a,(ix)        ; if zero,
  404.     or    (ix+1)
  405.     jr    z,setbrx    ; it's not valid
  406.  
  407.     ld    a,(port)    ; check to see which port to be setup
  408.     cp    1
  409.     jr    z,setupb
  410.  
  411.     ld    bc,ctcont
  412.     ld    a,36h
  413.     out    (c),a
  414.     ld    bc,ctc0
  415.     ld    a,(ix)
  416.     out    (c),a        ; lo byte
  417.     ld    a,(ix+1) 
  418.     out    (c),a        ; hi byte
  419.     ld    bc,ctcont
  420.     ld    a,76h
  421.     out    (c),a
  422.     ld    bc,ctc1
  423.     ld    a,(ix)
  424.     out    (c),a        ; lo byte
  425.     ld    a,(ix+1)
  426.     out    (c),a        ; hi byte
  427.     ld    a,(brate)    ; tell zmp it's valid
  428.  
  429.                 ; Using values below
  430.     ld    (mspeed),a    ; don't forget to load mspeed with the
  431.                 ; current brate value if the new rate is
  432.                 ; valid. See table of values below.
  433. setbrx:    pop    ix
  434.     pop    bc
  435.     ret
  436.  
  437. setupb:    ld    bc,ctcont
  438.     ld    a,0B6H
  439.     out    (c),a
  440.     ld    bc,ctc2
  441.     ld    a,(ix)
  442.     out    (c),a        ; lo byte
  443.     ld    a,(ix+1) 
  444.     out    (c),a        ; hi byte
  445.     ld    a,(brate)    ; tell zmp it's valid
  446.  
  447.                 ; Using values below
  448.     ld    (mspeed),a    ; don't forget to load mspeed with the
  449.                 ; current brate value if the new rate is
  450.                 ; valid. See table of values below.
  451.     pop    ix
  452.     pop    bc
  453.                 ; <== End of your own code
  454.     ret
  455. ;--------------------------------------------------------------------------
  456. ; ZMP will default to the values here, when assembled
  457. ;
  458. brate:    dw    5        ; baud rate
  459. parity:    dw    'N'        ; parity
  460. data:    dw    8        ; data bits
  461. stop:    dw    1        ; stop bits
  462. combyt    ds    1        ; used for DTR on/off
  463.  
  464. ;Values for 8253 control reg for each baud rate: 0 if invalid
  465.  
  466. brval:    dw    470H    ;   110        0
  467.     dw    1A1H    ;   300        1
  468.     dw    116H    ;   450        2
  469.     dw    0D0H    ;   600        3
  470.     dw    0B0H    ;   710        4
  471.     dw    068H    ;  1200        5
  472.     dw    034H    ;  2400        6
  473.     dw    01AH    ;  4800        7
  474.     dw    00DH    ;  9600        8
  475.     dw    007H    ; 19200        9 
  476.     dw    003H    ; 38400        10
  477.     dw    0    ; 57600        11
  478.     dw    0    ; 76800        12
  479. ;-----------------------------------------------------------------------
  480. ; Set the port. ZMP supplies either 0 or 1 as a parameter. You're on your
  481. ; own here -- your system is bound to be different from any other! You may
  482. ; implement a software switch on all the modem-dependent routines, or perhaps
  483. ; you can have one or two centralised routines for accessing the UARTs and
  484. ; modify the code from this routine to select one or the other. (Who said
  485. ; there was anything wrong with self-modifying code?). If you have only one
  486. ; UART port, or if you don't want to go through all the hassles, just have
  487. ; this routine returning with no changes made. Note that ZMP calls this
  488. ; routine with both values for the port on initialisation.
  489. ;
  490. setport:
  491.     ld    hl,2        ; get port number
  492.     add    hl,sp
  493.     ex    de,hl
  494.     call    getparm        ; in HL (values are 0 and 1)
  495.  
  496.                 ; <== Insert your own code here
  497.     ld    a,l
  498.     ld    (port),a
  499.     cp    1
  500.     jr    z,setb
  501.  
  502.     ld    hl,mdata
  503.     ld    (portadd),hl
  504.     inc    hl
  505.     ld    (status),hl
  506.     ret
  507.  
  508. setb:    ld    hl,mdatab
  509.     ld    (portadd),hl
  510.     inc    hl
  511.     ld    (status),hl
  512.  
  513.                 ; <== End of your own code
  514.     ret
  515.  
  516. port:    ds    1
  517. portadd:ds    2        ; Store address of SIO data address
  518. status:    ds    2        ; Store address of SIO status address
  519.  
  520. ;****************************************************************************
  521. ;Video terminal sequences: these are for Heath/Zenith Z19/Z29:
  522. ; Modify as you wish
  523.  
  524. ;Cursor addressing:
  525.  
  526. cursadd:
  527.     ld    hl,2        ; get parameters
  528.     add    hl,sp
  529.     ex    de,hl
  530.     call    getparm        ; in HL
  531.     ld    (row),hl    ; row
  532.     call    getparm
  533.     ld    (col),hl    ; column
  534.                 ; <== Insert your own code here
  535.  
  536.     call    print
  537.     db    esc,'Y',0    ; leadin
  538.     ld    a,(row)        ; row first
  539.     add    a,' '        ; add offset
  540.     call    cout
  541.     ld    a,(col)        ; sane for column
  542.     add    a,' '
  543.     call    cout
  544.                 ; <== end of your own code
  545.     ret
  546.  
  547. row:    ds    2        ; row
  548. col:    ds    2        ; column
  549.  
  550.  
  551. ;Clear screen:
  552. cls:    call    print
  553.     db    esc,'E',esc,'H',0
  554.     ret
  555.  
  556. ;Inverse video on:
  557. invon:    call    print
  558.     db    esc,'p',0
  559.     ret
  560.  
  561. ;Inverse video off:
  562. invoff:    call    print
  563.     db    esc,'q',0
  564.     ret
  565.  
  566. ;Turn off cursor:
  567. hide:    call    print
  568.     db    esc,'f',0
  569.     ret
  570.  
  571. ;Turn on cursor:
  572. show:    call    print
  573.     db    esc,'e',0
  574.     ret
  575.  
  576. ;Save cursor position:
  577. savecu:    call    print
  578.     db    esc,'j',0
  579.     ret
  580.  
  581. ;Restore cursor position:
  582. rescu:    call    print
  583.     db    esc,'k',0
  584.     ret
  585.  
  586. ;****************************************************************************
  587.  
  588. ;Service modem interrupt:
  589. mint:
  590.     ret            ; my system doesn't need this
  591.  
  592. ;Initialise interrupt vectors:
  593. invec:
  594.     ret            ; ditto
  595.  
  596. ;De-initialise interrupt vectors:
  597. dinvec:
  598.     ret            ; ditto
  599.  
  600. ;****************** End of user-defined code ********************************
  601. ;        Do not change anything below here.
  602.  
  603. ;Modem character test for 100 ms
  604. mrd:
  605.     push    bc        ; save bc
  606.     ld    bc,100        ; set limit
  607. mrd1:
  608.     call    mirdy        ; char at modem?
  609.     jr    nz,mrd2        ; yes, exit
  610.     ld    hl,1        ; else wait 1ms
  611.     call    waithlms
  612.     dec    bc        ; loop till done
  613.     ld    a,b
  614.     or    c
  615.     jr    nz,mrd1
  616.     ld    hl,0        ; none there, result=0
  617.     xor    a
  618. mrd2:
  619.     pop    bc
  620.     ret
  621.  
  622. ; Inline print routine: destroys A and HL
  623.  
  624. print:
  625.     ex    (sp),hl        ; get address of string
  626. ploop:
  627.     ld    a,(hl)        ; get next
  628.     inc    hl        ; bump pointer
  629.     or    a        ; done if zero
  630.     jr    z,pdone
  631.     call    cout        ; else print
  632.     jr    ploop        ; and loop
  633. pdone:
  634.     ex    (sp),hl        ; restore return address
  635.     ret            ; and quit
  636.  
  637. ;
  638. ;Output a character in A to the console
  639. ;
  640. cout:
  641.     push    bc        ; save regs
  642.     push    de
  643.     push    hl
  644.     ld    e,a        ; character to E
  645.     ld    c,2
  646.     call    bdos        ; print it
  647.     pop    hl
  648.     pop    de
  649.     pop    bc
  650.     ret
  651.  
  652. ;Wait(seconds)
  653. wait:
  654.     ld    hl,2
  655.     add    hl,sp
  656.     ex    de,hl        ; get delay size
  657.     call    getparm
  658.                 ; fall thru to..
  659. ;Wait seconds in HL
  660. waithls:
  661.     push    bc        ; save bc
  662.     push    de        ; de
  663.     push    ix        ; and ix
  664.     ld    ix,0        ; then point ix to 0
  665.                 ; so we don't upset memory-mapped i/o
  666.  
  667. ;Calculate values for loop constants. Need to have two loops to avoid
  668. ;   16-bit overflow with clock speeds above 9 MHz.
  669.  
  670. outerval    equ    (clkspd / 10) + 1
  671. innerval    equ    (6667 / outerval) * clkspd
  672.  
  673. wait10:
  674.     ld    b,outerval
  675.  
  676. wait11:
  677.     ld    de,innerval
  678.  
  679. wait12:
  680.     bit    0,(ix)        ; time-wasters
  681.     bit    0,(ix)
  682.     bit    0,(ix)        ; 20 T-states each
  683.     bit    0,(ix)
  684.     bit    0,(ix)
  685.     bit    0,(ix)
  686.     dec    de
  687.     ld    a,e
  688.     ld    a,d
  689.     or    e
  690.     jr    nz,wait12    ; 150 T-states per inner loop
  691.     djnz    wait11        ; decrement outer loop
  692.     dec    hl        ; ok, decrement count in hl
  693.     ld    a,h
  694.     or    l
  695.     jr    nz,wait10
  696.     pop    ix        ; done -- restore ix
  697.     pop    de        ; de
  698.     pop    bc        ; and bc
  699.     ret
  700.  
  701. ;Wait milliseconds
  702. mswait:
  703.     ld    hl,2
  704.     add    hl,sp
  705.     ex    de,hl        ; get delay size
  706.     call    getparm
  707.                 ; fall thru to..
  708. ;Wait milliseconds in HL
  709. waithlms:
  710.     push    de
  711. w1ms0:
  712.     ld    de,39 * clkspd
  713. w1ms1:
  714.     dec    de
  715.     ld    a,d
  716.     or    e
  717.     jr    nz,w1ms1
  718.     dec    hl
  719.     ld    a,h
  720.     or    l
  721.     jr    nz,w1ms0
  722.     pop    de
  723.     ret
  724.  
  725. ;Get next parameter from (de) into hl
  726. getparm:
  727.     ex    de,hl        ; get address into hl
  728.     ld    e,(hl)        ; get lo
  729.     inc    hl
  730.     ld    d,(hl)        ; then hi
  731.     inc    hl        ; bump for next
  732.     ex    de,hl        ; result in hl, address still in de
  733.     ret
  734.  
  735. ;Get address of user-defined variables
  736.  
  737. getvars:
  738.     ld    hl,uservars
  739.     ret
  740.  
  741. uservars:
  742.     dw    overdrive    ; .OVR etc. drive/user
  743.     dw    overuser
  744.  
  745.  
  746.      if    ($ - codebgn) gt ovsize
  747. toobig:    jp    errval        ; Overlay too large!
  748.      endif
  749.  
  750.     end
  751.