home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / BEEHIVE / COMMS / IMP-OVL.ARC / I2SI-1.ASM < prev    next >
Assembly Source File  |  1991-02-02  |  11KB  |  348 lines
  1.  
  2. ; I2SI-1.ASM - IMP overlay for Sinclair 2068 with Zebra FDD  - 01/15/88
  3. ;
  4. ;    USES Western Digital 2123 with built-in baudrate generator
  5. ;
  6. ; You will want to look this file over carefully. There are a number of
  7. ; options that you can use to configure the program to suit your taste.
  8. ; This file adapts the Sinclair 2068 with Zebra FDD to IMP.
  9. ;
  10. ; Edit this file for your preferences then follow the "TO USE:" example
  11. ; shown below.
  12. ;
  13. ; Many terminals will clear the screen with a CTL-Z.  If yours does, put
  14. ; a 1AH at CLEAR: (010AH).  Many terminals use two characters, the first
  15. ; normally an ESC.  For example, ESC *.  In this case put '*' at CLEAR:
  16. ; (The ESC will automatically be typed with no CTL-character present.)
  17. ; If you don't know what your terminal uses, put a 0 at CLEAR: and IMP
  18. ; will scroll up 24 blank lines to clear the CRT for things like MENU,
  19. ; looking at the function key table, typing CTL-Z in command mode, etc.
  20. ;
  21. ; Use the "SET" command to change the baudrate when desired.  The value
  22. ; at MSPEED controls the baudrate when the program is first called up.
  23. ;
  24. ;    TO USE: First edit this file filling in answers for your own
  25. ;        equipment.  Then assemble with ASM.COM or equivalent
  26. ;        assembler.  Then use MLOAD to merge into the main file:
  27. ;
  28. ;        MLOAD IMP.COM=IMP.COM,I2SI-1.HEX
  29. ;
  30. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  31. ;
  32. ; 01/15/88  Written to work with IMP        - Irv Hoff
  33. ;
  34. ; =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =   =
  35. ;
  36. ;
  37. YES    EQU    0FFH
  38. NO    EQU    0
  39. ;
  40. ;
  41. ; Values shown are for a WE2123
  42. ;
  43. PORT    EQU    40H    ; Your base port (data or status)
  44. MDCTL1    EQU    PORT+1    ; Modem control port
  45. MDDATP    EQU    PORT    ; Modem data port
  46. MDRCV    EQU    02H    ; Modem receive ready
  47. MDSND    EQU    01H    ; Modem send ready bit
  48. MDTXE    EQU    05H    ; Modem send buffer empty, holding buffer empty
  49. ;
  50. ;
  51. MDMODE    EQU    82H    ; Insures 8251 is out of mode with DTR high
  52. MDRSET    EQU    42H    ; Resets USART for additional commands
  53. MDCOM    EQU    17H    ; Reset error flags, RCV, DTR, TX ready
  54. ;
  55. BRPORT    EQU    11H    ; Baudrate generator port
  56. ;
  57. ;-----------------------------------------------------------------------
  58. ;
  59. ESC    EQU    '['-40H    ; ^[ = Escape
  60. BELL    EQU    'G'-40H    ; ^G = Bell character
  61. LF    EQU    'J'-40H    ; ^J = Linefeed
  62. NEXTRY    EQU    'K'-40H    ; ^K = Try next phone number, abort this try
  63. CR    EQU    'M'-40H    ; ^M = Carriage return
  64. CLEARSC    EQU    'J'-40H    ; ^Z = Clears screen, command mode only
  65. EOFCHAR    EQU    'Z'-40H    ; ^Z = End of file
  66. ;
  67. ;
  68. ;-----------------------------------------------------------------------
  69. ;
  70. ;
  71.     ORG    0100H
  72. ;
  73. ;
  74.     DS    3        ; Skip the data area below
  75. ;
  76. ;
  77. ; These routines and equates are at the beginning of the program so
  78. ; they can be patched by a monitor or overlay file without re-assembling
  79. ; the program.
  80. ;
  81. MSPEED:     DB    5    ; 0=110 1=300 2=450 3=600 4=710 5=1200        103H
  82.             ; 6=2400 7=4800 8=9600 9=19200 default
  83. HS2400:     DB    NO    ; Yes=2400 bps highest speed            104H
  84. HS1200:     DB    YES    ; Yes=1200 bps highest speed            105H
  85. RACAL:     DB    NO    ; Yes=Racal-Vadic 1200V or 2400V or 2400PA    106H
  86. PROMODM: DB    NO    ; Yes=Prometheus ProModem 1200 bps        107H
  87. RESVD1:     DB    NO    ; Reserved for special modems            108H
  88. RESVD2:     DB    NO    ; Reserved for special modems            109H
  89. ;
  90. ;
  91. CLEAR:     DB    4AH    ; Clear screen character (ESC not needed)    10AH
  92. CLOCK:     DB    37    ; Clock speed in MHz x10, 25.5 MHz max.     10BH
  93.             ; 20=2 MHh, 37=3.68 MHz, 40=4 MHz, etc.
  94. BYTDLY:     DB    2    ; 0=0 delay  1=10ms  5=50 ms - 9=90 ms        10CH
  95.             ;   default time to send character in ter-
  96.             ;   minal mode file transfer for slow BBS
  97. CRDLY:     DB    2    ; 0=0 delay 1=100 ms 5=500 ms - 9=900 ms    10DH
  98.             ;   default time for extra wait after CRLF
  99.             ;   in terminal mode file transfer
  100. NOFCOL:     DB    5    ; Number of directory columns shown        10EH
  101. TCHPUL:     DB    'T'    ; T=tone, P=Pulse (Hayes 2400 modems)        10FH
  102. ;.....
  103. ;
  104. ;
  105. ADDLFD:     DB    NO    ; Yes=add LF after CR to send file in terminal    110H
  106.             ;   mode (normally added by remote echo)
  107. CONVRUB: DB    YES    ; Yes=convert rub to backspace            111H
  108. CRCDFLT: DB    YES    ; Yes=default to CRC checking            112H
  109. IGNRCTL: DB    YES    ; Yes=CTL-chars above ^M not displayed        113H
  110. ;.....
  111. ;
  112. ;
  113. EXTCHR:     DB    '['-40H    ; ESC = preceeds local control character    114H
  114. EXITCHR: DB    'E'    ; Exit character                115H
  115. FILESND: DB    'F'    ; Send file when in terminal mode        116H
  116. NOCONCT: DB    'N'    ; Disconnect from phone line            117H
  117. LOGCHR:     DB    'L'    ; Send logon                    118H
  118. LSTCHR:     DB    'P'    ; Toggle printer                119H
  119. UNSAVCH: DB    'R'    ; Close input text buffer            11AH
  120. SAVECHR: DB    'Y'    ; Open input text buffer            11BH
  121. CLEARS:     DB    'J'    ; Clears screen, terminal mode            11CH
  122. BRKCHR:     DB    'Q'    ; Send a break tone                11DH
  123. NODTR:     DB    NO    ; YES if no DTR and need ATH0 to disconnect    11EH
  124. ;.....
  125. ;
  126. ; Handles in/out ports for data and status
  127. ;
  128. I$MDCTL1: IN    MDCTL1        ;                    11FH
  129.       RET            ; IN modem control port         121H
  130.       DB    0,0,0,0,0,0,0    ; Spares if needed            122H
  131. ;
  132. I$MDTXE:  IN    MDCTL1        ; (Needed for SIO or DART register 1    129H
  133.       RET            ;                    12BH
  134.       DB    0,0,0,0,0,0,0    ;                    12CH
  135. ;
  136. I$MDDATP: MVI    A,37H        ;                    133H
  137.       OUT    MDCTL1        ;                    135H
  138.       IN    MDDATP        ;                    137H
  139.       RET            ;                    139H
  140.       DB    0,0,0        ; Spares if needed            13AH
  141. ;
  142. O$MDDATP: OUT    MDDATP        ;                    13DH
  143.       RET            ; OUT modem data port            13FH
  144.       DB    0,0,0,0,0,0,0    ; Spares if needed            140H
  145. ;.....
  146. ;
  147. A$MDRCV:  ANI    MDRCV        ;                    147H
  148.       RET            ;                    149H
  149. ;
  150. C$MDRCV:  CPI    MDRCV        ;                    14AH
  151.       RET            ;                    14CH
  152. ;
  153. A$MDSND:  ANI    MDSND        ;                    14DH
  154.       RET            ;                    14FH
  155. ;
  156. C$MDSND:  CPI    MDSND        ;                    150H
  157.       RET            ;                    152H
  158. ;
  159. A$MDTXE:  ANI    MDTXE        ;                    153H
  160.       RET            ;                    155H
  161. ;
  162. C$MDTXE:  CPI    MDTXE        ;                    156H
  163.       RET            ;                    158H
  164. ;.....
  165. ;
  166. ; Special exit vector, used by some computers to reset interrupt vectors
  167. ;
  168. J$EXITVEC:RET            ;                    159H
  169.       DB    0,0        ;                    15AH
  170. ;.....
  171. ;
  172. ; Jump vectors needed by each overlay
  173. ;
  174. J$GOODBYE:JMP    GOODBYE        ; Disconnects modem by dropping DTR    15CH
  175. J$INITMOD:JMP    INITMOD        ; Initializes modem, autosets baudrate    15FH
  176. J$STUPR:  JMP    STUPR        ; SET routine to change baudrate    162H
  177. J$SYSVR:  JMP    SYSVR        ; Signon message            165H
  178. ;.....
  179. ;
  180. ; "AT" command strings, can be replaced in individual overlay if needed
  181. ;
  182. J$STRNGA: DS    3        ; 1200 bps "AT" string            168H
  183. J$STRNG1: DS    3        ; 2400 bps "AT" string            16BH
  184. ;
  185. ; Next fourteen lines should not be changed by user overlay as these go
  186. ; to specific locations in the main program, not in the overlay.
  187. ;
  188. J$CMDSPL: DS    3        ; Allows entry of baudrate on CMD line    16EH
  189. J$CRLF:      DS    3        ; Turns up one new line on display    171H
  190. J$DIAL:      DS    3        ; Start of dialing routine        174H
  191. J$DSCONT: DS    3        ; Terminates modem use            177H
  192. J$GOLST:  DS    3        ; Printer routine, needed by Apple //e    17AH
  193. J$ILPRT:  DS    3        ; Prints an inline string, 0 to end    17DH
  194. J$INBUF:  DS    3        ; Stores a keybd string for comparison    180H
  195. J$INLNCP: DS    3        ; Inline "compare strings" routine    183H
  196. J$INMDM:  DS    3        ; Max .1 sec wait for modem character    186H
  197. J$RCVRSP: DS    3        ; For 3801 I/O use (TV-803)        189H
  198. J$SNDCHR: DS    3        ; Sends a character to the modem    18CH
  199. J$SNDSTR: DS    3        ; Sends a string to the modem, $ to end 18FH
  200. J$TIMER:  DS    3        ; .1 second timer (amount in 'B' reg.)    192H
  201. J$BREAK:  JMP    SENDBRK        ; Break routine             195H
  202. J$NEW2:      DB    0,0,0        ; For future needs            198H
  203. ;.....
  204. ;
  205. ; For 2400 bps auto-stepdown units
  206. ;
  207. MANUAL:      DB    0        ; For manual selection flag        19BH
  208. J$300:      JMP    OK300        ; Sets baudrate to 300 baud        19CH
  209. J$1200:      JMP    OK1200        ; Sets baudrate to 1200 bps        19FH
  210. J$2400:      JMP    OK2400        ; Sets baudrate to 2400 bps        1A2H
  211. ;.....
  212. ;
  213. LOGPTR:      DW    LOGON        ; Pointer to display LOGON message    1A5H
  214. ;
  215. SYSVR:      CALL    J$ILPRT        ; Display the following line        1A7H
  216.       DB    'Version for Sinclair 2068 with Zerbra FDD'    ;    1AAH
  217.       DB    CR,LF,0
  218.       RET
  219. ;.....
  220. ;
  221. ;-----------------------------------------------------------------------
  222. ;
  223. ; NOTE:  You can change the SYSVER message to be longer or shorter.  The
  224. ;     end of your last routine should terminate by 0400H (601 bytes
  225. ;     available after start of SYSVER).
  226. ;
  227. ;-----------------------------------------------------------------------
  228. ;
  229. ; You can put in a message at this location which can be called up with
  230. ; (special character-L).  You can put in several lines.  End with a 0.
  231. ;
  232. LOGON:    DB    'This is a Sinclair 2068 computer...'
  233.     DB    CR,LF,0
  234. ;
  235. ;-----------------------------------------------------------------------
  236. ;
  237. ; This routine sets a 300 ms break tone
  238. ;
  239. SENDBRK:
  240.     MVI    A,3FH        ; DTR normal, send break tone
  241.     JMP    GOODBYE+2
  242. ;.....
  243. ;
  244. ; This routine sets DTR low for 300 ms to disonnect the phone
  245. ;
  246. GOODBYE:
  247.     MVI    A,3DH        ; Send break, turn off DTR
  248.     OUT    MDCTL1        ; Send to status port
  249.     MVI    B,3        ; Delay 300 ms to hang up phone
  250.     CALL    J$TIMER
  251.     MVI    A,37H        ; Normal send/receive with DTR
  252.     OUT    MDCTL1        ; Send to status port
  253.     RET
  254. ;.....
  255. ;
  256. ; Sets 8251 to 8 bits, DTR, RCV and TX ready
  257. ;
  258. INITMOD:
  259.     LDA    MSPEED        ; Get the selected value
  260.     CPI    1        ; 300 bps
  261.     JZ    OK300
  262.     CPI    5        ; 1200 bps
  263.     JZ    OK1200
  264.     CPI    6        ; 2400 bps
  265.     JZ    OK2400
  266.     CPI    8        ; 9600 bps
  267.     JZ    OK9600
  268.     CPI    9        ; 19200
  269.     JZ    OK19200
  270.     JMP    STUPR1        ; Else ask what is wanted
  271. ;.....
  272. ;
  273. ; Setup routine to allow changing modem speed with the SET command.
  274. ;
  275. STUPR:    CALL    J$CMDSPL    ; Gives us CMDBUF+6
  276.     JNC    STUPR2
  277. ;
  278. STUPR1:    CALL    J$ILPRT
  279.     DB    'Input Baud Rate (300, 1200, 2400, 9600, 19200): ',0
  280.     LXI    D,BAUDBUF    ; Point to new input buffer
  281.     CALL    J$INBUF
  282.     CALL    J$CRLF
  283.     LXI    D,BAUDBUF+2
  284. ;
  285. STUPR2:    CALL    J$INLNCP    ; Compare BAUDBUF+2 with chars. below
  286.     DB    '300',0
  287.     JNC    OK300        ; Go if got match
  288.     CALL    J$INLNCP
  289.     DB    '1200',0
  290.     JNC    OK1200
  291.     CALL    J$INLNCP
  292.     DB    '2400',0
  293.     JNC    OK2400
  294.     CALL    J$INLNCP
  295.     DB    '9600',0
  296.     JNC    OK9600
  297.     CALL    J$INLNCP
  298.     DB    '19200',0
  299.     JNC    OK19200
  300.     CALL    J$ILPRT        ; All matches failed, tell operator
  301.     DB    '++ Incorrect entry ++',CR,LF,BELL,CR,LF,0
  302.     JMP    STUPR1        ; Try again
  303. ;
  304. OK300:    MVI    A,1        ; MSPEED 300 bps value
  305.     MVI    B,BD300
  306.     JMP    LOADBD
  307. ;
  308. OK1200:    MVI    A,5
  309.     MVI    B,BD1200
  310.     JMP    LOADBD
  311. ;
  312. OK2400:    XRA    A        ; Reset to maximum auto-speed
  313.     STA    MANUAL
  314.     MVI    A,6
  315.     MVI    B,BD2400
  316.     JMP    LOADBD
  317. ;
  318. OK9600:    MVI    A,8
  319.     MVI    B,BD9600
  320.     JMP    LOADBD
  321. ;
  322. OK19200:MVI    A,9
  323.     MVI    B,BD19200
  324. ;
  325. LOADBD:    STA    MSPEED        ; Change time-to-send to match baudrate
  326.     MOV    A,B        ; Get baudrate byte
  327.     OUT    BRPORT        ; Send to 'CTC' timer for new baudrate
  328.     RET
  329. ;.....
  330. ;
  331. ; Baudrate table
  332. ;
  333. BD300    EQU    6
  334. BD1200    EQU    8
  335. BD2400    EQU    10
  336. BD9600    EQU    14
  337. BD19200    EQU    15
  338. ;
  339. BAUDBUF:DB    10,0,0,0,0,0
  340.     DB    0,0,0,0,0,0
  341. ;
  342. ;                   end
  343. ;-----------------------------------------------------------------------
  344. ;
  345. ; NOTE: Must terminate prior to 0400H
  346. ;
  347.     END
  348.