home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / BEEHIVE / COMMS / HAMMODEM.ARC / HAMMODEM.ASM next >
Assembly Source File  |  1988-08-07  |  51KB  |  2,589 lines
  1.     TITLE    'HAM MODEM PROGRAM Version 1.0, 20 Feb 82'
  2. ;
  3. ;A CP/M file transfer program for simplex operation on Amateur Radio bands.
  4. ;Adapted from MODEM74.ASM by Phil Cary, W5TYF and Ken Shutt, K5GUU.
  5. ;
  6. ;CP/M MACRO (MAC) assembler required along with MODEM7.LIB
  7. ;
  8. ;Will asemble as is to run on a North Star with the modem on the right
  9. ;serial port.  Conditional equates to use features of the Heath/Zenith H-19
  10. ;terminal if h19term is set to true.
  11. ;
  12. ;May be patched under DDT or SID for other port assignments. Value of "timer"
  13. ;may be changed to accomodate different transmitter and receiver recovery
  14. ;characteristics, and call sign for CWID may be entered. See HAMMODEM.SET and
  15. ;HAMMODEM.DOC.
  16. ;
  17. ;HAMMODEM is adapted from MODEM74 for use in a simplex mode on
  18. ;the Amateur radio bands.  It has been used by the authors on 2 meter
  19. ;FM, both direct and through repeaters, at 1200 baud for several months.
  20. ;No testing has been done on SSB on the low bands, but it should work
  21. ;at the appropriate baud rates as long as there is little or no QRM.
  22. ;
  23. ;A simple modem must be interfaced to the ham rig.  A schematic and
  24. ;parts list for a modem using the EXAR 2211 and 2206 chips is available
  25. ;upon receipt of a s.a.s.e. to either of the following:
  26. ;
  27. ;    Phil Cary, W5TYF        Ken Shutt, K5GUU
  28. ;    748 Kenilworth Parkway        12433 Archery Drive
  29. ;    Baton Rouge, LA 70808        Baton Rouge, LA 70815
  30. ;    (504) 766-5255            (504) 275-0330
  31. ;
  32. ;No audio filtering has been needed in 2 meter operation, but probably
  33. ;would be required for SSB use.
  34. ;
  35. ;MODEM.ASM was originally created by Ward Christensen, with numerous
  36. ;revisions by Mark Zeigler, Jim Mills and others.  MODEM74.ASM was the
  37. ;basis for this version of HAMMODEM.  The CWID routines were borrowed
  38. ;from PACKET by Dale Heatherington, WA4DSY, Decatur, GA.
  39. ;
  40. ;We believe that all of the routines in MODEM74 and PACKET have at one time
  41. ;or the other been copyrighted and/or placed in the public domain for non-
  42. ;commercial use only.  The routines may be used but not sold by others.
  43. ;All new and changed code in HAMMODEM .ASM is in lower case.
  44. ;
  45. ;All of the features of MODEM74 such as batch mode, blind send, etc. have
  46. ;been retained.  All routines associated with the PMMI modem have been
  47. ;removed to conserve space.  All IMSAI and FRONTPANEL code has been
  48. ;removed.  The CRC method of error checking is used during file transfer
  49. ;and the CHECKSUM code has been removed.  CHECKSUM is still used for file
  50. ;names in the batch mode.  The E(cho) mode has been removed, and echo has
  51. ;been added to the T(erminal) mode.  Added other functions to T(erminal)
  52. ;mode to send a CWID and to send a line    that has previously been entered
  53. ;with the transmitter off. Conditional equates to use features of the
  54. ;Heath/Zenith H-19 terminal added. See HAMMODEM.DOC for further details.
  55.  
  56.     MACLIB MODEM7    ;CONTAINS CMDLINE, INBUF, INLNCOMP,
  57.             ;DIR, AND MFACCESS ROUTINES
  58.             ;changed to MODEM.LIB by Jim Mills
  59.             ;to differentiate from other 'MACROS.LIB'
  60.  
  61.  
  62. TRUE    EQU     0FFH
  63. FALSE    EQU     0
  64.  
  65. DBUFSIZ    EQU     16        ;BUFFER SIZE IN KBYTES
  66.  
  67. ;Modem Equates
  68.  
  69. MODCTLP    EQU    05h        ;MODEM CONTROL PORT
  70. modsftp equ    05h        ;Modem control port for shift/unshift
  71. MODDATP    EQU    04h        ;MODEM DATA PORT
  72. MODSNDB    EQU    1        ;MODEM SEND BIT (XMIT BUFF EMPTY)
  73. MODSNDR    EQU    1        ;MODEM SEND READY
  74. MODRCVB    EQU    2        ;MODEM RECEIVE BIT (DAV)
  75. MODRCVR    EQU    2        ;MODEM RECEIVE READY
  76.  
  77. ERRLIM    EQU    20        ;NUMBER OF TIMES TO RETRY
  78.                 ;SEND/RECEIVE ERRORS BEFORE QUIT
  79.             
  80. EXITCHR    EQU    'E'-40H        ; ^E = EXIT terminal mode
  81. TRANCHR    EQU    'T'-40H        ; ^T = TRANSFER CHARACTER
  82. CAN    EQU    'X'-40H        ; ^X = CANCEL SEND/RECEIVE
  83. EOFCHAR    EQU    'Z'-40H        ; ^Z = END OF FILE
  84. SAVECHR    EQU    'Y'-40H        ; ^Y = SAVE CHARACTER
  85. ESC    equ    '['-40h     ; ^[ = Escape
  86. EXTCHR    EQU    '^'-40H        ; ^^ = SEND NXT CHR
  87. SOH    EQU    1        ; START OF HEADER
  88. EOT    EQU    4        ; END OF TEXT
  89. ACK    EQU    6        ; ACKNOWLEDGE
  90. NAK    EQU    15H        ; NOT ACKNOWLEDGE
  91. BDNMCH    EQU    75H        ; BAD NAME MATCH
  92. OKNMCH    EQU    ACK        ; OKAY NAME MATCH
  93. LF    EQU    10        ; LINEFEED
  94. CR    EQU    13        ; CARRIAGE RETURN
  95. BELL    EQU    7        ; BELL CHARACTER
  96.  
  97.  
  98. BOTTRAM    SET     LAST+100H AND 0FF00H
  99.  
  100.     ORG    100H
  101.  
  102.     JMP    START
  103.  
  104. ;THESE ROUTINES ARE AT THE BEGINNING OF THE PROGRAM SO
  105. ;THEY CAN BE PATCHED BY A MONITER WITHOUT RE-ASSEMBLING
  106. ;THE PROGRAM.
  107.  
  108. mycall        db    '        '    ;ID call. Pad with spaces to 8 char.
  109. timer        dw    00dfh        ;Value for transmitter delay routine
  110. ptton        db    035h        ;DTR=0
  111. pttoff        db    037h        ;DTR=1
  112. mark        db    035h        ;Char to reset modem to mark state
  113. space        db    03ch        ;Char for modem to send steady space
  114. IN$MODCTLP    IN  MODCTLP ! RET    ;in modem control port
  115. OUT$MODCTLP    OUT MODCTLP ! RET    ;out modem control port
  116. out$modsftp    out modsftp ! ret    ;out modem cntrl port for shift/unshift
  117. IN$MODDATP    IN  MODDATP ! RET    ;in modem data port
  118. OUT$MODDATP    OUT MODDATP ! RET    ;out modem data port
  119. ANI$MODSNDB    ANI MODSNDB ! RET    ;bit to test for send ready
  120. CPI$MODSNDR    CPI MODSNDR ! RET    ;value of send bit when ready
  121. ANI$MODRCVB    ANI MODRCVB ! RET    ;bit to test for receive ready
  122. CPI$MODRCVR    CPI MODRCVR ! RET    ;value of receive bit when ready
  123. FASTCLK        DB    TRUE         ;4 MHz or greater
  124. BAKUPBYTE    DB     false        ;true=make .BAK file
  125. XPRFLG        DB    false        ;true=no menu, false=print menu
  126. h19term        equ    false        ;True=Heath/Zenith H-19 terminal
  127.  
  128. START:    LXI    H,0
  129.     DAD    SP        ;GET CP/M'S STACK
  130.     SHLD    STACK        ;SAVE IT
  131.     LXI    SP,STACK    ;START LOCAL STACK
  132.  
  133.     CALL    START1
  134.  
  135.     DB CR,LF,'HAMMODEM  Ver 1.0, 20 Feb 82.',cr,lf,lf
  136.     db 'Adapted from MODEM74 by Phil Cary, W5TYF and Ken Shutt, K5GUU.'
  137.     db cr,lf,lf,'MODEM.ASM originally written by Ward Christensen.'
  138.     db cr,lf,'Revisions through MODEM74 by Mark Zeiger, Jim Mills, '
  139.     db 'and others.',cr,lf,'$'
  140.  
  141. START1:    POP    D        ;GET ADDRESS OF ABOVE MESSAGE
  142.     MVI    C,PRINT        ;Call CPM print string
  143.     CALL    BDOS        ;..function
  144.  
  145.     CALL    INITADR        ;INITIALIZE ADDRESSES
  146.     MVI    A,TRUE        ; 0FFH
  147.     STA    NFILFLG        ;No file specified in Terminal mode
  148.     CMA            ; 0
  149.     STA    SAVEFLG
  150.     CALL    PROCOPT        ;PROCESS CONTROL OPTIONS
  151.     LDA    OPTION        ;GET MAIN OPTION
  152.     CPI    'X'        ;EXPERT FLAG?
  153.     JNZ    RESTART    ;NO
  154.     MVI    A,TRUE        ;YES
  155.     STA    XPRFLG        ;MAKE EXPERT
  156.     JMP    MENU
  157.  
  158. RESTART
  159.     LDA    OPTION        ;GET MAIN OPTION
  160.     CPI    ' '        ;NO OPTION SPEC'D?
  161.     JZ    MENU        ;TRUE, GO MENU
  162.     CPI    'M'        ;MENU ASKED FOR?
  163.     JZ    MENU2        ;YES, GO MENU
  164.     CALL    MOVEFCB
  165.     MVI    A,FALSE
  166.     STA    NFILFLG
  167.  
  168.     CALL    IN$MODDATP    ;GOBBLE UP GARBAGE..
  169.     CALL    IN$MODDATP    ;..CHARACTERS ON LINE
  170.  
  171.     LDA    OPTION        ;PROCESS MAIN OPTION
  172.     CPI    'T'        ;TERMINAL MODE?
  173.     JZ    DSKSAVE        ;YES
  174.     CPI    'S'        ;SEND A FILE?
  175.     JZ    SENDFIL        ;YES
  176.     CPI    'R'        ;RECEIVE A FILE?
  177.     JZ    RCVFIL        ;YES
  178.     JMP    MENU        ;NO OPTION SPEC'D, GO MENU
  179.  
  180. ;REVISED TERMINAL ROUTINE ALLOWING MEMORY SAVE
  181.             
  182. DSKSAVE    LDA    NFILFLG        ;NEW FILE FLAG
  183.     CPI    TRUE        ;OFFH? (TRUE=NORMAL TERMINAL MODE)
  184.     JZ    termint        ;YES
  185.     LDA    FCB+1        ;FIRST CHAR OF FILENAME
  186.     CPI    ' '        ;FILE SPEC'D
  187.     JNZ    GOODNM        ;YES, GOOD NAME
  188.     MVI    A,TRUE        ;0FFH
  189.     STA    NFILFLG    
  190.     CMA        
  191.     STA    SAVEFLG    
  192.     JMP    termint    
  193.  
  194. GOODNM    CALL    ERASFIL
  195.     CALL    MOVE2
  196.     LXI    D,FCB3
  197.     MVI    C,MAKE
  198.     CALL    BDOS
  199.     LXI    D,FCB3
  200.     MVI    C,OPEN
  201.     CALL    BDOS
  202.     LXI    H,BOTTRAM
  203.     SHLD    HLSAVE
  204.     MVI    A,FALSE
  205.     STA    NFILFLG
  206.  
  207. termint:
  208.     if    h19term
  209.     call    ilprt 
  210.     db    esc,'E',esc,'j'        ;Clear screen, save cursor position
  211.     db    esc,'x','1'        ;Enable 25th line
  212.     db    esc,'Y',56,33        ;Position cursor to L25,C2
  213.     db    esc,'p'            ;Reverse video on
  214.     db    '  f1=CWID | f2=TX Line | f3=TX File Blind '
  215.     db    '| f4=Toggle Save | f5=Exit To Menu  '
  216.     db    esc,'q',esc,'k',0    ;Reverse video off, restore cursor
  217.     endif
  218. ;
  219. TERM:    CALL    STAT        ;KEYPRESS?
  220.     JZ    TERML        ;NO, CHECK LINE
  221.     CALL    KEYIN        ;GET CHAR FROM KBD
  222.     MOV    B,A        ;SAVE
  223.     LDA    EXACFL
  224.     ORA    A        ;EXACT?
  225.     MVI    A,0
  226.     STA    EXACFL        ;CLR FOR NEXT TIME
  227.     MOV    A,B        ;RESTORE
  228.     JNZ    NOTOG
  229.     cpi    esc        ;^[?
  230.     jz    txcmd        ;Process second character
  231.     CPI    EXITCHR        ;^E?
  232.     JZ    trmexit        ;YES, RETURN TO MENU after reseting terminal
  233.     CPI    EXTCHR        ;^^?
  234.     JZ    EXTFLG        ;YES, SET FLAG FOR NXT CHAR
  235.     CPI    TRANCHR        ;TEST FOR TRANSFER REQUEST (^T)
  236.     CZ    TRANSFER    ;SEND-A-FILE (BLIND SEND)
  237.     JZ    TERM        ;LOOP
  238.     CPI    SAVECHR
  239.     JNZ    NOTOG    
  240.     LDA    NFILFLG        ;DO NOT ALLOW SAVE IF..
  241.     CPI    TRUE        ;..THIS FLAG IS SET.
  242.     JZ    TERML
  243.     LDA    SAVEFLG
  244.     CMA
  245.     STA    SAVEFLG
  246.     JMP    TERML
  247.  
  248. txcmd:    call     stat        ;Character at keyboard?
  249.     jz    txcmd        ;Loop till there is
  250.     call    keyin        ;Get it
  251.     cpi    'S'        ;Is it S?(ESC S or f1 function key on H-19)
  252.     cz    cwidrou        ;If so, go id in cw
  253.     cpi    'T'        ;Is it T?(ESC T or f2 function key on H-19)
  254.     cz    linesend    ;Set up to send a line of charaters
  255.     CPI    'W'        ;Is it W?(ESC W or f5 function key on H-19)
  256.     JZ    trmexit        ;Yes, reset terminal and return to menu
  257.     CPI    'U'        ;ESC U or f3?
  258.     CZ    TRANSFER    ;SEND-A-FILE (BLIND SEND)
  259.     JZ    TERM        ;LOOP
  260.     CPI    'V'        ;ESC V or f4?
  261.     JNZ    txcmd2
  262.     LDA    NFILFLG        ;DO NOT ALLOW SAVE IF..
  263.     CPI    TRUE        ;..THIS FLAG IS SET.
  264.     JZ    TERM    
  265.     LDA    SAVEFLG
  266.     CMA
  267.     STA    SAVEFLG
  268.     jmp    term
  269. txcmd2:    cpi     'Q'        ;Is it Q?(ESC Q or Red function key on H-19)
  270.     cz    txon        ;If so, turn on transmitter
  271.     cpi     'P'        ;Is it P?(ESC P or Blue function key on H-19)
  272.     cz    txoff        ;If so, turn off transmitter
  273.     cpi    'R'        ;R?(ESC R or White function key on H-19)
  274.     jnz    term        ;If not, go get another character
  275.     call    txon        ;If so, turn on transmitter
  276.     mvi    a,true        ;..and set AUTO TX OFF on CR
  277.     sta    autotx        ;..flag
  278.     jmp     term        ;Get another character 
  279.  
  280. linesend:
  281.     lxi    h,linebuf    ;Point to line buffer
  282. lineret:
  283.     call    stat        ;Character at keyboard
  284.     jz    lineret        ;Loop if not
  285.     call    keyin        ;Get character
  286.     cpi    cr        ;Is it a CR
  287.     push    psw        ;Save character and flags
  288.     mov    m,a        ;Put character in linebuf
  289.     call    type        ;Display the character
  290.     inx    h        ;Increment linebuf
  291.     PUSH    PSW
  292.     LDA    SAVEFLG
  293.     CPI    FALSE
  294.     JZ    lineret1
  295.     xchg            ;Hold linebuf pointer in DE
  296.     lhld    hlsave        ;Point to main save buffer
  297.     POP    PSW
  298.     MOV    M,A
  299.     INX    H
  300.     SHLD    HLSAVE        
  301.     xchg            ;Linebuf pointer back in HL
  302. lineret1:
  303.     pop    psw        ;Get flag back
  304.     jz    lineout        ;Send line if CR
  305.     jmp    lineret        ;Get another character if not CR
  306.  
  307. lineout:
  308.     lda    saveflg        ;First see if saving
  309.     jnz    lineout1
  310.     lhld    hlsave        ;If so, point to main save buffer
  311.     mvi    m,lf        ;..and put a LF in the file
  312.     inx    h
  313.     shld    hlsave
  314. lineout1:
  315.     call    crlf
  316.     call    txon
  317.     lxi    h,linebuf    ;Point to line buffer
  318. lineout2:
  319.     call    in$modctlp
  320.     call    ani$modsndb
  321.     call    cpi$modsndr
  322.     jnz    lineout2
  323.     mov    a,m        ;Get character
  324.     push     psw        ;Save character
  325.     call    out$moddatp    ;Send character
  326.     call    type        ;Echo it
  327.     inx    h        ;Increment line buffer
  328.     pop    psw         ;Get character
  329.     cpi    cr        ;Was it a CR
  330.     jnz    lineout2    ;Loop for next character if not
  331. lineout3:
  332.     call     in$modctlp     ;Get status
  333.     call     ani$modsndb    ;Mask ready bit
  334.     call     cpi$modsndr    ;Ready?
  335.     jnz    lineout3
  336.     mvi    a,lf        ;Else get LF
  337.     call    out$moddatp    ;..and send it
  338.     call    type        ;..and echo it
  339.     lda    saveflg        ;If saving
  340.     cpi    true        ;..then
  341.     jnz    lineout4
  342.     mvi    a,':'        ;..type a ":"
  343.     call    type        ;..at beginning of line
  344. lineout4:
  345.     call    txoff        ;Finished with line if CR
  346.     lhld    hlsave        ;Restore save buffer pointer to HL before ret
  347.     jmp    term        ;Return to terminal mode with xmitter off
  348.  
  349. trmexit:
  350.     if     h19term        ;Routine to reset H-19.  Erases entire screen,
  351.     call    ilprt        ;..disables 25th line and homes cursor
  352.     db    esc,'z',0
  353.     endif
  354.  
  355.     call     txoff        ;Be sure transmitter is off and
  356.     jmp    menu        ;..exit terminal mode to menu
  357.  
  358. EXTFLG:    MVI    A,TRUE
  359.     STA    EXACFL
  360.     JMP    TERML
  361.  
  362. NOTOG:    push    psw
  363. notog1:    call     in$modctlp     ;Get status
  364.     call     ani$modsndb    ;Mask ready bit
  365.     call     cpi$modsndr    ;Ready?
  366.     jnz    notog1
  367.     pop    psw
  368.     CALL    OUT$MODDATP
  369.     call    type
  370.     PUSH    PSW
  371.     LDA    SAVEFLG
  372.     CPI    FALSE
  373.     JZ    notog2
  374.     POP    PSW
  375.     MOV    M,A
  376.     INX    H
  377.     SHLD    HLSAVE        ;MENU COMMAND DESTROYS HL-REG..
  378.     push      psw
  379. notog2:    pop    psw
  380.     cpi    cr        ;Is it CR?
  381.     jnz    terml        ;Continue if not
  382. notog3:    call     in$modctlp     ;Get status
  383.     call     ani$modsndb    ;Mask ready bit
  384.     call     cpi$modsndr    ;Ready?
  385.     jnz    notog3
  386.     mvi    a,lf
  387.     call    out$moddatp
  388.     call    type
  389.     MOV    M,A
  390.     INX    H
  391.     SHLD    HLSAVE        ;MENU COMMAND DESTROYS HL-REG..
  392.     lda    autotx        ;Otherwise, get auto TXOFF on CR flag
  393.     cpi    true        ;See if it is set
  394.     cz    txoff        ;Turn off TX if set
  395.     mvi    a,false        ;..and reset
  396.     sta    autotx        ;..flag
  397.     lda    saveflg
  398.     cpi    true
  399.     jnz    terml
  400.     mvi    a,':'
  401.     call    type
  402.  
  403.  
  404. TERML:    CALL    IN$MODCTLP
  405.     CALL    ANI$MODRCVB
  406.     CALL    CPI$MODRCVR
  407.     JNZ    TERM
  408.     CALL    IN$MODDATP
  409.     CPI    0        ;CHECK FOR NULLS
  410.     JZ    TERM        ;DON'T PROCESS THEM
  411.     ANI    7FH        ;STRIP PARITY
  412.     CALL    TYPE
  413.     PUSH    PSW
  414.     LDA    SAVEFLG
  415.     CPI    FALSE
  416.     JZ    NOSAVE
  417.     POP    PSW
  418.     MOV    M,A
  419.     INX    H
  420.     SHLD    HLSAVE        ;MENU COMMAND DESTROYS HL-REG..
  421.  
  422. COLON:    CPI    LF        ;If linefeed
  423.     JNZ    NOCOLON        ;..TYPE ":" AFTER EACH LINE FEED..
  424.     MVI    A,':'        ;..WHEN MEMORY SAVE ACTIVE.
  425.     CALL    TYPE
  426.  
  427. NOCOLON:
  428.     LDA    7        ;CHECK TO SEE IF..
  429.     DCR    A        ;..PAGE BELOW BDOS HAS BEEN..
  430.     CMP    H        ;..REACHED AND DISKSAVE IS NEEDED.
  431.     CZ    INTDSKSV
  432.     JMP    TERM
  433.  
  434. NOSAVE:    POP    PSW
  435.     JMP    TERM
  436.  
  437. autotx:     db    false
  438. SAVEFLG: DB    FALSE
  439.  
  440. INTDSKSV:
  441.     call    ilprt
  442.     db     cr,lf,lf,'WARNING!!!  BUFFER AREA IS FULL.',cr,lf,bell
  443.     db    'Data is being lost while buffer contents is being'
  444.     db    'written to disk.',bell,cr,lf
  445.     db    'Save will continue after disk write.',bell
  446.     db    cr,lf,lf,0
  447.     CALL    NUMREC1
  448.     CALL    WRTDSK        ;WRITE THE RECORDS
  449.     lxi    h,bottram
  450.     shld    hlsave
  451.     RET
  452.  
  453. NUMRECS    MVI    M,EOFCHAR
  454.     INX    H
  455.     LXI    D,127
  456.     DAD    D
  457. NUMREC1    LXI    D,-(BOTTRAM)
  458.     DAD    D
  459.     MOV    A,L        ;DIVIDE HL BY 128..
  460.     ORA    A
  461.     RAL            ;..TO GET THE..
  462.     MOV    L,H        ;..NUMBER OF SECTORS
  463.     MVI    H,0
  464.     PUSH    PSW
  465.     DAD    H
  466.     POP    PSW
  467.     MVI    A,0
  468.     ADC    L
  469.     MOV    L,A        ;RETURNS WITH NUMBER OF..
  470.     RET            ;..128 BYTE RECORDS IN HL.
  471.  
  472. WRTDSK    LXI    D,BOTTRAM
  473. NEXTWRT    MVI    C,STDMA
  474.     CALL    BDOSRT
  475.     PUSH    D
  476.     LXI    D,FCB3
  477.     MVI    C,WRITE
  478.     CALL    BDOSRT
  479.     POP    D
  480.     XCHG
  481.     PUSH    D
  482.     LXI    D,128
  483.     DAD    D
  484.     POP    D
  485.     XCHG
  486.     DCX    H
  487.     MOV    A,H
  488.     ORA    L
  489.     JNZ    NEXTWRT
  490.     RET
  491.  
  492. CLOSE3    LXI    D,FCB3
  493.     MVI    C,CLOSE
  494.     CALL    BDOS
  495.     RET
  496.  
  497. BDOSRT    PUSH B ! PUSH D ! PUSH H ! PUSH PSW
  498.     CALL    BDOS
  499.     POP PSW ! POP H ! POP D ! POP B
  500.     RET
  501.  
  502. MOVE2    LXI    H,FCB3
  503.     CALL    INITFCBS
  504.     LXI    H,FCB
  505.     LXI    D,FCB3
  506.     MVI    B,12
  507.     CALL    MOVE
  508.     RET
  509.  
  510. ;FILE TRANSFER ROUTINE - CALLED WITH 
  511. ;CONTROL-T FROM TERMINAL ROUTINE.
  512. ;TRANSFER MAY BE CANCELLED WHILE SENDING BY USING CONTROL-X.
  513.  
  514. TRANSFER:
  515.     PUSH H ! PUSH D ! PUSH B ! PUSH PSW
  516.     LXI    H,FCB4
  517.     CALL    INITFCBS    ;INITIALIZES FCBS POINTED..
  518.     LXI    H,FCB+16    ;..TO BY HL REG.
  519.     CALL    INITFCBS
  520. GET:    CALL    GETNAME
  521.     LDA    CMDBUF+2    ;WAS FILE ENTERED
  522.     CPI    20H
  523.     JZ    TRANSL2
  524.     CALL    MOVE4
  525.     CALL    OPEN4
  526.     CPI    0FFH        ;RETURN WITH 0FFH MEANS
  527.     JNZ    CONTIN        ;FILE DOES NOT EXIST
  528. TRANSL1:    
  529.     CALL    ILPRT
  530.         DB    CR,LF,'++FILE DOES NOT EXIST++',CR,LF,0
  531. TRANSL2:    
  532.     CALL    ILPRT
  533.         DB    'TYPE "R" TO RETURN TO MODEM',CR,LF
  534.         DB    'TYPE "A" TO RE-ENTER NAME: ',BELL,0
  535.     CALL    KEYIN
  536.     CALL    UCASE
  537.     CALL    TYPE        ;ECHO RESPONSE
  538.     CALL    CRLF
  539.     CPI    'A'
  540.     JZ    GET
  541.     CPI    'R'
  542.     JZ    RETURN
  543.     JMP    TRANSL2
  544.  
  545. CONTIN:    call    txon
  546.     LXI    D,80H
  547.     MVI    C,STDMA
  548.     CALL    BDOS
  549. READMR:    CALL    READ80
  550.     CPI    1        ;END OF FILE
  551.     JZ    RETURNS
  552.     CPI    2        ;BAD READ
  553.     JZ    RETURNU
  554.     CALL    SEND80C
  555.     CPI    EOFCHAR        ;END OF FILE - OMIT IF OBJECT..
  556.     JZ    RETURNS        ;..CODE IS TO BE SENT.
  557.     CPI    CAN        ;CANCELLATION?
  558.     JZ    TRANCAN
  559.     JMP    READMR
  560. RETURNS:    
  561.     CALL    ILPRT
  562.         DB    CR,LF,'++FILE TRANSFER COMPLETED++',CR,LF,BELL,BELL,0
  563.     JMP    RETURN
  564. RETURNU:    
  565.     CALL    ILPRT
  566.         DB    CR,LF,'++FILE TRANSFER UNSUCCESSFUL++',CR,LF,BELL,BELL,0
  567.     JMP    RETURN
  568. TRANCAN:    
  569.     CALL    ILPRT
  570.         DB    CR,LF,CR,LF,'++ TRANSFER CANCELLED ++',CR,LF,BELL,BELL,0
  571. RETURN:    POP PSW ! POP B ! POP D ! POP H
  572.     call    txoff
  573.     RET
  574.  
  575. INITFCBS            ;ENTRY AT +2 WILL LEAVE..
  576.     MVI    M,0        ;..DRIVE NO. INTACT.
  577.     INX    H        ;WILL INITIALIZE AN FCB..
  578.     MVI    B,11        ;..POINTED TO BY HL-REG. FILLS 1ST POS
  579. LOOP10    MVI    M,' '        ;..WITH 0, NEXT 11 WITH..
  580.     INX    H        ;..WITH BLANKS, AND LAST..
  581.     DCR    B        ;..21 WITH NULLS.
  582.     JNZ    LOOP10
  583.     MVI    B,21
  584. LOOP11    MVI    M,0
  585.     INX    H
  586.     DCR    B
  587.     JNZ    LOOP11
  588.     RET
  589.  
  590. GETNAME    CALL ILPRT
  591.         DB CR,LF,'ENTER FILE NAME TO BE TRANSFERRED -  C/R TO QUIT: ',0
  592.     LXI    D,CMDBUF
  593.     CALL    INBUFF
  594.     CALL    CRLF
  595.     RET
  596.  
  597. MOVE4    LXI    D,CMDBUF
  598.     LXI    H,FCB4
  599.     CALL    CPMLINE
  600.     RET
  601.  
  602. OPEN4    LXI    D,FCB4
  603.     MVI    C,OPEN
  604.     CALL    BDOS
  605.     RET
  606.  
  607. READ80    LXI    D,FCB4
  608.     MVI    C,READ
  609.     CALL    BDOS
  610.     RET
  611.  
  612. SEND80C    MVI    B,80H
  613.     LXI    H,80H
  614. SENDCH1    MOV    A,M
  615.     CALL    MODOUT
  616.     CPI    EOFCHAR
  617.     RZ
  618.     CALL    STAT        ;TEST TO SEE IF
  619.     ORA    A        ;CANCELLATION REQUESTED
  620.     JZ    SKIP12
  621.     CALL    KEYIN
  622.     CPI    CAN
  623.     RZ
  624. SKIP12    INX    H
  625.     DCR    B
  626.     JNZ    SENDCH1
  627.     RET
  628.  
  629. MODOUT    PUSH    PSW
  630. MODOUTL    CALL    IN$MODCTLP
  631.     CALL    ANI$MODSNDB
  632.     CALL    CPI$MODSNDR
  633.     JNZ    MODOUTL
  634.     POP    PSW
  635.     CALL    OUT$MODDATP
  636.     CALL    TYPE
  637.     RET
  638.  
  639. FCB4    DS 33
  640.  
  641. ;UNCOMMENTED LINES ARE THOSE OF ORIGINAL MODEM PROGRAM.
  642.  
  643. ;        SEND A CP/M FILE
  644.  
  645. SENDFIL:
  646.     LDA    BATCHFLG    ;CHECK IF MULTIPLE FILE..
  647.     ORA    A        ;..MODE IS SET.
  648.     JNZ    SENDC1
  649.     MVI    A,TRUE        ;INDICATE BATCH SEND
  650.     STA    SENDFLG
  651.     LDA    FSTFLG        ;IF FIRST TIME THRU..
  652.     ORA    A        ;..SCAN THE COMMAND LINE..
  653.     CNZ    TNMBUF        ;..FOR MULTIPLE NAMES.
  654.     CALL    SENDFN        ;SENDS FILE NAME TO RECEIVER
  655.     JNC    SENDC2        ;CARRY SET MEANS NO MORE FILES.
  656.     MVI    A,'B'        ;STOP BATCH..
  657.     STA    BATCHFLG    ;..MODE OPTION.
  658.     call    txon
  659.     MVI    A,EOT        ;FINAL XFER END
  660.     CALL    SEND
  661.     call    txoff
  662.     JMP    DONE
  663. SENDC1    LDA    FCB+1
  664.     CPI    ' '
  665.     JZ    BLKFILE
  666. SENDC2    CALL    CNREC        ;GET NUMBER OF RECORDS
  667.     CALL    OPENFIL
  668.     CALL    WAITNAK
  669. SENDLP    CALL    RDSECT
  670.     JC    SENDEOF
  671.     CALL    INCRSNO
  672.     XRA    A
  673.     STA    ERRCT
  674.  
  675. SENDRPT:
  676.     call    txon
  677.     CALL    SENDHDR
  678.     CALL    SENDSEC
  679.     call    sendcrc    
  680.     call    txoff
  681.     CALL    GETACK
  682.     JC    SENDRPT
  683.     JMP    SENDLP
  684.  
  685. SENDEOF:
  686.     call    txon
  687.     MVI    A,EOT
  688.     CALL    SEND
  689.     call    txoff
  690.     CALL    GETACK
  691.     JC    SENDEOF
  692.     JMP    DONE
  693.  
  694. ;        RECEIVE A FILE
  695.  
  696. RCVFIL:    LDA    BATCHFLG    ;CHECK IF MULT..
  697.     ORA    A        ;..FILE MODE.
  698.     JNZ    RCVC1
  699.     MVI    A,FALSE        ;FLAG WHERE TO RETURN..
  700.     STA    SENDFLG        ;..FOR NEXT FILE TRANS.
  701.     CALL    GETFN        ;GET THE FILE NAME.
  702.     JNC    RCVC2        ;CARRY SET MEANS NO MORE FILES.
  703.     MVI    A,'B'        ;STOP BATCH..
  704.     STA    BATCHFLG    ;..MODE OPTION.
  705.     JMP    DONE
  706. RCVC1    LDA    FCB+1        ;MAKE SURE FILE IS NAMED
  707.     CPI    ' '
  708.     JZ    BLKFILE
  709.     JMP    RCVC3
  710. RCVC2    CALL    CKCPM2
  711.     CALL    CKBAKUP
  712. RCVC3    CALL    ERASFIL
  713.     CALL    MAKEFIL
  714.     LDA    QFLG
  715.     ORA    A
  716.     JNZ    rcvlp
  717.     LDA    BATCHFLG
  718.     ORA    A        ;DON'T PRINT MSSG IF..
  719.     JZ    rcvlp        ;..IN MULTI AND QUIET.
  720.     CALL    ILPRT
  721.     DB    'FILE OPEN, READY TO RECEIVE',CR,LF,0
  722. ;
  723. RCVLP    CALL    RCVSECT
  724.     JC    RCVEOT
  725.     CALL    WRSECT
  726.     CALL    INCRSNO
  727.     CALL    SENDACK
  728.     JMP    RCVLP
  729.  
  730. RCVEOT:    CALL    WRBLOCK
  731.     CALL    SENDACK
  732.     CALL    CLOSFIL
  733.     JMP    DONE
  734.     
  735. ;SUBROUTINES
  736. ;
  737. ;FSK CWID routine.
  738. ;ASCII to CW translate table
  739. ASCII$CW:
  740.     DB    5+10010000B    ; / -..-.
  741.     DB    5+11111000B    ;ZERO
  742.     DB    5+01111000B    ;1
  743.     DB    5+00111000B    ;2
  744.     DB    5+00011000B    ;3
  745.     DB    5+00001000B    ;4
  746.     DB    5+00000000B    ;5
  747.     DB    5+10000000B    ;6
  748.     DB    5+11000000B    ;7
  749.     DB    5+11100000B    ;8
  750.     DB    5+11110000B    ;9
  751.     DB    0        ;:  NOT USED
  752.     DB    0        ; ; NOT USED
  753.     DB    0        ; < NOT USED
  754.     DB    0        ; = NOT USED
  755.     DB    0        ; > NOT USED
  756.     DB    0        ; ? NOT USED
  757.     DB    0        ; @ NOT USED
  758.     DB    2+01000000B    ; A  .-
  759.     DB    4+10000000B    ;B -...
  760.     DB    4+10100000B    ; C -.-.
  761.     DB    3+10000000B    ; D -..
  762.     DB    1+00000000B    ; E .
  763.     DB    4+00100000B    ; F ..-.
  764.     DB    3+11000000B    ;G --.
  765.     DB    4+00000000B    ;H
  766.     DB    2+00000000B    ; I ..
  767.     DB    4+01110000B    ; J .---
  768.     DB    3+10100000B    ; K -.-
  769.     DB    4+01000000B    ; L .-..
  770.     DB    2+11000000B    ; M --
  771.     DB    2+10000000B    ; N -.
  772.     DB    3+11100000B    ; O ---
  773.     DB    4+01100000B    ; P .--.
  774.     DB    4+11010000B    ; Q --.-
  775.     DB    3+01000000B    ; R .-.
  776.     DB    3+00000000B    ; S ...
  777.     DB    1+10000000B    ; T -
  778.     DB    3+00100000B    ; U ..-
  779.     DB    4+00010000B    ; V ...-
  780.     DB    3+01100000B    ; W .--
  781.     DB    4+10010000B    ; X -..-
  782.     DB    4+10110000B    ; Y -.--
  783.     DB    4+11000000B    ; Z --..
  784. ;End of translate table
  785. ;
  786. ID$STRING:    DS    14    ;RESERVE 14 BYTES FOR ID STRING
  787. DE$STR:        DB    'DE '
  788.  
  789. cwidrou:    push psw ! push h ! push d ! push b
  790.         call    cwid
  791.         pop b ! pop d ! pop h ! pop psw
  792.         ret
  793.  
  794. CWID:    LXI    D,ID$STRING
  795.     LXI    H,DE$STR    ;POINT TO "DE" STRING
  796.     MVI    B,3
  797.     CALL    MOVE
  798.     LXI    H,MYCALL    ;PUT OUR CALL IN
  799.     MVI    B,8
  800.     CALL    MOVE
  801.     XCHG
  802.     MVI    M,' '        ;TRAILING SPACE
  803.     INX    H
  804.     MVI    M,0        ;NULL TERMINATES STRING
  805.     CALL    txon        ;KEY TRANSMITTER
  806.     CALL    shift        ;Send space tone
  807.  
  808.     LXI    H,ID$STRING
  809. CWID1:    MOV    A,M        ;GET A ASCII CHAR.
  810.     ORA    A        ;NULL?
  811.     JZ    txoff        ;QUIT IF NULL
  812.     CPI    '0'
  813.     JC    CWID2        ;IGNORE INVALID CHAR
  814.     PUSH    H
  815.     MOV    C,A
  816.     CALL    SEND$CW$CHAR    ;CONVERT TO CW AND SEND
  817.     POP    H
  818. CWID2:    INX    H
  819.     JMP    CWID1        ;LOOP TILL DONE
  820.  
  821. SEND$CW$CHAR:
  822.     PUSH    B
  823.     CALL    shift        ;Send space tone
  824.     MVI    C,2
  825.     CALL    DELAYX        ;WAIT 2 DOT TIMES
  826.     POP    B        ;GET ASCII CHARACTER BACK
  827.     LXI    H,ASCII$CW-2FH    ;POINT TO CONVERSION TABLE
  828.     MOV    A,C
  829.     CPI    20H        ;TEST FOR SPACE
  830.     JNZ    CW1
  831.     MVI    C,7        ;7 DOT TIMES FOR SPACE
  832.     JMP    DELAYX
  833. CW1:    MVI    B,0
  834.     DAD    B        ;INDEX INTO TABLE
  835.     MOV    A,M        ;GET CW CODE
  836.     ANI    7        ;KEEP COUNT
  837.     RZ            ;RETURN IF ZERO COUNT
  838.     MOV    B,A        ;PUT COUNT IN REG. B
  839.     MOV    A,M        ;GET CODE AGAIN
  840. CW2:    ADD    A        ;SHIFT MSB INTO CARRY
  841.     MVI    E,1        ;ASSUME A DOT
  842.     JNC    CW3        ;JUMP IF DOT
  843.     MVI    E,3        ;ELSE SET FOR DASH
  844. CW3:    PUSH    B        ;SAVE COUNT
  845.     PUSH    PSW        ;SAVE CODE
  846.     CALL    unshift        ;Send mark tone
  847.     MOV    C,E        ;GET TIME
  848.     CALL    DELAYX
  849.     CALL    shift        ;Send space tone
  850.     MVI    C,1
  851.     CALL    DELAYX        ;WAIT 1 DOT TIME
  852.     POP    PSW        ;RESTORE CODE
  853.     POP    B        ;RESTORE COUNT
  854.     DCR    B        ;COUNT DOWN
  855.     JNZ    CW2        ;LOOP TILL FINISHED
  856.     RET
  857.  
  858. ;THIS TIMES 1 DIT.
  859.  
  860. DELAYX: MOV    A,C
  861.     ORA    A
  862.     RZ
  863.     PUSH    B
  864.     PUSH    D
  865. DLY1:    LXI    D,50        ;50 MS DELAY
  866.     CALL    delayd
  867.     DCR    C
  868.     JNZ    DLY1
  869.     POP    D
  870.     POP    B
  871.     RET
  872. ;
  873. ;Frequency shift keying routines
  874. ;
  875. unshift:
  876.     PUSH    PSW
  877.     lda    mark
  878.     call    out$modsftp
  879.     POP    PSW
  880.     RET
  881. ;
  882. shift:
  883.     PUSH    PSW
  884.     lda    space
  885.     call    out$modsftp
  886.     POP    PSW
  887.     RET
  888. ;
  889. ;txon/txoff.     Key the transmitter by setting
  890. ;               DTR on and off with appropriate
  891. ;        delays.
  892. ; 
  893. txon:    push    psw        ;SAVE A
  894.     lda    ptton        ;DTR=0
  895.     call     out$modctlp    ;Turn on transmitter
  896.     pop     psw        ;Get A
  897.     push    h        ;Save HL
  898.     lhld    timer        ;Get value of timer
  899.     call    delayh        ;Wait for full power
  900.     lhld     timer        ;Do it again
  901.         call    delayh        ;..yet
  902.     pop    h        ;Restore HL
  903.     ret
  904.  
  905. txoff:    push    psw        ;Save A
  906.     push     h        ;Save HL
  907.     lhld    timer        ;Get value of timer
  908.         call    delayh        ;Delay a little while other end is coming up
  909.     pop    h        ;Restore HL
  910. busy:    call     in$modctlp     ;Get status
  911.     call     ani$modsndb    ;Mask ready bit
  912.     call     cpi$modsndr    ;Ready?
  913.     jnz    busy        ;..No, wait
  914.     lda    pttoff         ;DTR=1
  915.     call     out$modctlp    ;Turn off transmitter
  916.     pop    psw        ;get A
  917.         call     in$moddatp    ;Clear garbage
  918.         call     in$moddatp    ;..again
  919.     ret
  920. ;
  921. ;
  922. ;This is a delay routine
  923. ;Enter at delayh with delay in ms. in HL or
  924. ;    enter at delayd with delay in ms. in DE
  925.  
  926. delayh:    xchg            
  927.     call    delayd
  928.     xchg
  929.     ret
  930.  
  931. delayd:    call    wait
  932.     dcx    d
  933.     mov    a,e
  934.     ora    d
  935.     jnz    delayd
  936.     ret
  937.  
  938. wait:    push    psw
  939.     lda    fastclk        ;FF=4 Mhz, 00=2 Mhz
  940.     ora    a
  941.     jz    wait1
  942.     mvi    a,216        ;Multiples of 108 for North Star(Z80)
  943.     jmp    wait2        ;..to give 1 millisecond delay
  944. wait1:    mvi    a,108        ;..in this routine.
  945. wait2:    dcr    a
  946.     nop
  947.     jnz    wait2
  948.     pop    psw
  949.     ret
  950. ;
  951.  
  952. SENDFN    LDA    QFLG
  953.     ORA    A
  954.     JZ    SWNAK
  955.     CALL    ILPRT
  956.     DB    'AWAITING NAME NAK',CR,LF,0
  957. SWNAK    CALL    WAITNLP
  958.     call    txon
  959.     MVI    A,ACK        ;GOT NAK, SEND ACK
  960.     CALL    SEND
  961.     call    txoff
  962.     LXI    H,FILECT
  963.     DCR    M
  964.     JM    NOMRNM
  965.     LHLD    NBSAVE        ;GET FILE NAME..
  966.     LXI    D,FCB        ;..IN FCB
  967.     MVI    B,12
  968.     CALL    MOVE
  969.     SHLD    NBSAVE
  970.     CALL    SENDNM        ;SEND IT
  971.     ORA    A        ;CLEAR CARRY
  972.     RET
  973. NOMRNM:    call    txon
  974.     MVI    A,EOT
  975.     CALL    SEND
  976.     call    txoff
  977.     STC
  978.     RET
  979.  
  980. SENDNM:    PUSH    H
  981. SENDNM1:
  982.     MVI    D,11        ;COUNT CHARS IN NAME
  983.     MVI    C,0        ;INIT CHECKSUM
  984.     LXI    H,FCB+1        ;ADDRESS NAME
  985. NAMLPS:    call    txon
  986.     MOV    A,M        ;SEND NAME
  987.     ANI    7FH        ;STRIP HIGH ORDER BIT SO CP/M 2..
  988.     CALL    SEND        ;..WON'T SEND R/O FILE DESIGNATION.
  989.     call    txoff
  990.     LDA    QFLG        ;SHOW NAME IF..
  991.     ORA    A        ;..QFLG NOT SET.
  992.     MOV    A,M
  993.     CNZ    TYPE
  994. ACKLP:    PUSH    B        ;SAVE CKSUM
  995.     MVI    B,2        ;WAIT FOR RECEIVER
  996.     CALL    recvdg        ;..TO ACKNOWLEDGE
  997.     POP    B        ;..GETTING LETTER
  998.     JC    SCKSER
  999.     CPI    ACK
  1000.     JNZ    ACKLP
  1001.     INX    H        ;NEXT CHAR
  1002.     DCR    D
  1003.     JNZ    NAMLPS
  1004.     call    txon
  1005.     MVI    A,EOFCHAR    ;TELL RECEIVER END OF NAME
  1006.     CALL    SEND
  1007.     call    txoff
  1008.     LDA    QFLG
  1009.     ORA    A
  1010.     CNZ    CRLF
  1011.     MOV    D,C        ;SAVE CHECKSUM
  1012.     MVI    B,2    
  1013.     CALL    recvdg        ;GET CHECKSUM
  1014.     CMP    D        ;..FROM RECEIVER.
  1015.     JZ    NAMEOK
  1016. SCKSER:    call    txon
  1017.     MVI    A,BDNMCH    ;BAD NAME-TELL RECEIVER
  1018.     CALL    SEND
  1019.     call    txoff
  1020.     LDA    QFLG
  1021.     ORA    A
  1022.     JZ    SKCSER1
  1023.     CALL    ILPRT
  1024.     DB    'CHECKSUM ERROR',CR,LF,0
  1025. SKCSER1:            ;Do handshaking over
  1026.     CALL    WAITNLP    
  1027.     call    txon
  1028.     MVI    A,ACK
  1029.     CALL    SEND
  1030.     call    txoff
  1031.     JMP    SENDNM1
  1032. NAMEOK:    call    txon
  1033.     MVI    A,OKNMCH    ;GOOD NAME-TELL RECEIVER
  1034.     CALL    SEND
  1035.     call    txoff
  1036.     POP    H
  1037.     RET    
  1038.  
  1039. GETFN:    LXI     H,FCB
  1040.     CALL     INITFCBS+2    ;DOES NOT INITIALIZE DRIVE
  1041.     LDA     QFLG
  1042.     ORA     A
  1043.     JZ     GNAMELP
  1044.     CALL     ILPRT
  1045.     DB 'AWAITING FILE NAME',CR,LF,0
  1046. GNAMELP:
  1047.     CALL     HSNAK
  1048.     JC     GNAMELP
  1049.     CALL     GETNM        ;GET THE NAME
  1050.     CPI     EOT        ;IF EOT, THEN NO MORE FILES
  1051.     JZ     NOMRNMG
  1052.     ORA     A        ;CLEAR CARRY
  1053.     RET
  1054. NOMRNMG:
  1055.     STC
  1056.     RET
  1057.  
  1058. GETNM:    PUSH     H
  1059. GETNM1:    MVI     C,0        ;INIT CHECKSUM
  1060.     LXI     H,FCB+1
  1061. NAMELPG:
  1062.     MVI     B,5
  1063.     CALL     recvdg        ;GET CHAR
  1064.     JNC     GETNM3
  1065.     LDA     QFLG
  1066.     ORA     A
  1067.     JZ     GETNM2
  1068.     CALL     ILPRT
  1069.     DB 'TIME OUT RECEIVING FILENAME',CR,LF,0
  1070. GETNM2    JMP     GCKSER
  1071. GETNM3    CPI     EOT        ;IF EOT, THEN NO MORE FILES
  1072.     JZ     GNRET
  1073.     CPI     EOFCHAR        ;GOT END OF NAME
  1074.     JZ     ENDNAME
  1075.     MOV     M,A        ;PUT NAME IN FCB
  1076.     LDA     QFLG        ;TYPE IT IF NO QFLG
  1077.     ORA     A
  1078.     MOV     A,M
  1079.     CNZ     TYPE
  1080.     PUSH     B        ;SAVE CKSUM
  1081.     call    txon
  1082.     MVI     A,ACK        ;ACK GETTING LETTER
  1083.     CALL     SEND
  1084.     call    txoff
  1085.     POP     B
  1086.     INX     H        ;GET NEXT CHAR
  1087.     MOV     A,L        ;DON'T LET NOISE...
  1088.     CPI     7FH        ;..CAUSE OVERFLOW..
  1089.     JZ     GCKSER        ;..INTO PROGRAM AREA.
  1090.     JMP     NAMELPG
  1091. ENDNAME    LDA     QFLG
  1092.     ORA     A    
  1093.     CNZ     CRLF
  1094.     call    txon
  1095.     MOV     A,C        ;SEND CHECKSUM
  1096.     CALL     SEND
  1097.     call    txoff
  1098.     MVI     B,2
  1099.     CALL     recvdg        ;CHECKSUM GOOD?
  1100.     CPI     OKNMCH        ;YES IF OKNMCH SENT..
  1101.     JZ     GNRET        ;..ELSE DO OVER.
  1102. GCKSER    LXI     H,FCB        ;CLEAR FCB (EXCEPT DRIVE)..
  1103.     CALL     INITFCBS+2    ;..SINCE IT MIGHT BE DAMAGED..
  1104.     LDA     QFLG        ;..BY TOO MANY CHARS.
  1105.     ORA     A
  1106.     JZ     GCKSER1
  1107.     CALL     ILPRT
  1108.     DB 'CHECKSUM ERROR',CR,LF,0
  1109. GCKSER1    CALL     HSNAK        ;DO HANDSHAKING OVER
  1110.     JC     GCKSER1
  1111.     JMP     GETNM1
  1112. GNRET    POP     H
  1113.     RET
  1114.  
  1115. HSNAK:    call    txon
  1116.     MVI     A,NAK        ;SEND NAK UNTIL..
  1117.     CALL     SEND        ;..RECEIVING ACK.
  1118.     call    txoff
  1119.     CALL     CKABORT        ;DON'T GET HUNG UP HERE
  1120.     MVI     B,5        ;WAIT 2 SECONDS
  1121.     CALL     recvdg        ;..IN RECEIVE
  1122.     CPI     ACK        ;IF ACK,RETURN WITH..
  1123.     RZ            ;..CARRY CLEAR.
  1124.     STC
  1125.     RET
  1126.  
  1127. TNMBUF    MVI    A,FALSE        ;CALL FROM SENDFIL ONLY ONCE.
  1128.     STA    FSTFLG
  1129.     STA    FILECT
  1130.     CALL    SCAN
  1131.     LXI    H,NAMEBUF
  1132.     SHLD    NBSAVE        ;SAVE ADDR OF 1ST NAME
  1133. TNLP1    CALL    TRTOBUF
  1134.     LXI    H,FCB
  1135.     LXI    D,FCBBUF
  1136.     CALL    CPMLINE        ;PARSE NAME TO CP/M FORMAT
  1137. TNLP2    CALL    MFNAME        ;SEARCH FOR NAMES (* FORMAT)
  1138.     JC    NEXTNM
  1139.     LDA    FCB+10        ;IF CP/M 2 $SYS FILE..
  1140.     ANI    80H        ;..DON'T SEND
  1141.     JNZ    TNLP2
  1142.     LHLD    NBSAVE        ;GET NAME
  1143.     LXI    D,FCB        ;MOVE IT TO FCB
  1144.     XCHG
  1145.     MVI    B,12
  1146.     CALL    MOVE
  1147.     XCHG
  1148.     SHLD    NBSAVE        ;ADDR OF NEXT NAME
  1149.     LXI    H,FILECT    ;COUNT FILES FOUND
  1150.     INR    M
  1151.     JMP    TNLP2
  1152. NEXTNM    LXI    H,NAMECT    ;COUNT NAMES FOUND
  1153.     DCR    M
  1154.     JNZ    TNLP1
  1155.     LXI    H,NAMEBUF    ;SAVE START OF BUFFER
  1156.     SHLD    NBSAVE
  1157.     LDA    FILECT
  1158.     CPI    65        ;NO MORE THAN 64 TRANSFERS
  1159.     RC
  1160.     MVI    A,64        ;ONLY X'FER FIRST 64
  1161.     STA    FILECT
  1162.     RET
  1163.  
  1164. ;SCANS CMDBUF COUNTING NAMES AND PUTTING DELIMITER (SPACE)
  1165. ;AFTER LAST NAME
  1166.  
  1167. SCAN    PUSH     H
  1168.     LXI     H,NAMECT
  1169.     MVI     M,0
  1170.     LXI     H,CMDBUF+1    ;FIND END OF CMD LINE..
  1171.     MOV     C,M        ;..AND PUT SPACE THERE.
  1172.     MVI     B,0
  1173.     LXI     H,CMDBUF+2
  1174.     DAD     B
  1175.     MVI     M,20H
  1176.     LXI     H,CMDBUF+1
  1177.     MOV     B,M
  1178.     INR     B
  1179.     INR     B
  1180. SCANLP1    INX     H
  1181.     DCR     B
  1182.     JZ     DNSCAN
  1183.     MOV     A,M
  1184.     CPI     20H
  1185.     JNZ     SCANLP1
  1186. SCANLP2    INX     H        ;EAT EXTRA SPACES
  1187.     DCR     B
  1188.     JZ     DNSCAN
  1189.     MOV     A,M
  1190.     CPI     20H
  1191.     JZ     SCANLP2
  1192.     SHLD     BGNMS        ;SAVE START OF NAMES IN CMDBUF
  1193.     INR     B
  1194.     DCX     H
  1195. SCANLP3    INX     H
  1196.     DCR     B
  1197.     JZ     DNSCAN
  1198.     MOV     A,M
  1199.     CPI     20H
  1200.     JNZ     SCANLP3
  1201.     LDA     NAMECT        ;COUNTS NAMES
  1202.     INR     A
  1203.     STA     NAMECT
  1204. SCANLP4    INX     H        ;EAT SPACES
  1205.     DCR     B
  1206.     JZ     DNSCAN
  1207.     MOV     A,M
  1208.     CPI     20H
  1209.     JZ     SCANLP4
  1210.     JMP     SCANLP3
  1211. DNSCAN    MVI     M,20H        ;SPACE AFTER LAST CHAR
  1212.     POP     H
  1213.     RET
  1214.  
  1215. ;PLACES NEXT NAME IN BUFFER SO CPMLINE MAY PARSE IT
  1216.  
  1217. TRTOBUF    LHLD    BGNMS
  1218.     MVI    B,0
  1219.     LXI    D,FCBBUF+2
  1220. TBLP    MOV    A,M
  1221.     CPI    20H
  1222.     JZ    TRBFEND
  1223.     STAX    D
  1224.     INX    H
  1225.     INX    D
  1226.     INR    B        ;COUNT CHARS IN NAME
  1227.     JMP    TBLP
  1228. TRBFEND    INX    H
  1229.     MOV    A,M        ;EAT EXTRA SPACES
  1230.     CPI    20H
  1231.     JZ    TRBFEND
  1232.     SHLD    BGNMS
  1233.     LXI     H,FCBBUF+1    ;PUT # CHARS BEFORE NAME
  1234.     MOV     M,B
  1235.     RET
  1236.  
  1237. ;IN CP/M V.2, IF FILE IS R/O OR SYS, IT IS CHANGED TO 'BAK'.
  1238.  
  1239. CKCPM2    MVI    C,12
  1240.     CALL    BDOS
  1241.     ORA    A        ;RETURN 0 MEANS CP/M 1
  1242.     RZ
  1243.     MVI    C,STDMA
  1244.     LXI    D,80H
  1245.     CALL    BDOS
  1246.     MVI    C,SRCHF        ;SEARCH FOR FILE
  1247.     LXI    D,FCB
  1248.     CALL    BDOS
  1249.     CPI    0FFH
  1250.     RZ
  1251.     ADD A ! ADD A        ;MULT A-REG BY..
  1252.     ADD A ! ADD A        ;..32 TO FIND..
  1253.     ADD    A        ;..NAME IN DMA.
  1254.     LXI    H,80H
  1255.     ADD    L
  1256.     MOV    L,A        ;HL POINTS TO DIR NAME
  1257.     LXI    D,9
  1258.     DAD    D        ;POINT TO R/O ATTRIB BYTE
  1259.     MOV    A,M
  1260.     ANI    80H        ;TEST MSB
  1261.     JNZ    MKCHG        ;IF SET, MAKE CHANGE
  1262.     INX    H        ;CHECK SYSTEM ATTRIB BYTE
  1263.     MOV    A,M
  1264.     ANI    80H
  1265.     RZ            ;NOT $SYS OR $R/O
  1266.     DCX    H
  1267. MKCHG    LXI    D,-8
  1268.     DAD    D        ;POINT HL TO FILENAME + 1
  1269.     LXI    D,FCB+1        ;MOVE DIR NAME TO FCB..
  1270.     MVI    B,11        ;..WITHOUT CHANGING DRIVE.
  1271.     CALL    MOVE
  1272.     LXI    H,FCB+9        ;R/O ATTRIB
  1273.     MOV    A,M
  1274.     ANI    7FH        ;STRIP R/O ATTRIB
  1275.     MOV    M,A
  1276.     INX    H        ;SYS ATTRIB
  1277.     MOV    A,M
  1278.     ANI    7FH
  1279.     MOV    M,A
  1280.     LXI    D,FCB
  1281.     MVI    C,30        ;SET NEW ATTRIBS IN DIR
  1282.     CALL    BDOS
  1283.  
  1284. ;MAY BE CALLED BY CKBAKUP BELOW. ITS RETURN DONE HERE
  1285.  
  1286. PLANCHG    LXI    H,FCB        ;CHANGE NAME TO TYPE "BAK"
  1287.     LXI    D,6CH
  1288.     MVI    B,9        ;MOVE DRIVE AND NAME (NOT TYPE)
  1289.     CALL    MOVE
  1290.     LXI    H,75H        ;START OF TYPE IN FCB2
  1291.     MVI    M,'B'
  1292.     INX    H
  1293.     MVI    M,'A'
  1294.     INX    H
  1295.     MVI    M,'K'
  1296.     LXI    D,6CH
  1297.     MVI    C,ERASE        ;ERASE ANY PREV BACKUPS
  1298.     CALL    BDOS
  1299.     LXI    H,6CH        ;FCB2 DR FIELD SHOULD..
  1300.     MVI    M,0        ;..0 FOR RENAME.
  1301.     LXI    D,FCB
  1302.     MVI    C,23        ;RENAME
  1303.     CALL    BDOS
  1304.     RET
  1305.  
  1306. CKBAKUP    LDA    BAKUPBYTE
  1307.     ORA    A
  1308.     RZ
  1309.     MVI    C,SRCHF
  1310.     LXI    D,FCB
  1311.     CALL    BDOS
  1312.     INR    A
  1313.     RZ            ;FILE NOT FOUND
  1314.     JMP    PLANCHG        ;IN "CKCPM2" - RET DONE THERE
  1315.  
  1316. ;MULTI-FILE ACCESS SUBROUTINE FROM CP/M USER'S GROUP
  1317. ;FIXED BY MARK ZEIGER 8/17/80
  1318. ;CARRY IS SET IF NO MORE NAMES CAN BE FOUND
  1319.  
  1320. MFNAME    MFACCESS    ;A MACRO IN MACROS.LIB
  1321.  
  1322.  
  1323. RCVSECT    XRA    A
  1324.     STA    ERRCT
  1325. RCVRPT:    LDA    QFLG
  1326.     ORA    A
  1327.     JZ    RCVSQ
  1328.     CALL    ILPRT
  1329.     DB    CR,'AWAITING # ',0
  1330.     PUSH    H        ;SAVE IT
  1331.     LHLD    SECTNO        ;GET SECTOR NUMBER
  1332.     INX    H        ;BUMP IT
  1333.     CALL    DECOUT        ;PRINT SECTOR NUMBER IN DECIMAL
  1334.     CALL    ILPRT
  1335.     DB    ' (', 0
  1336.     CALL    DHXOUT        ;16 BIT HEX CONVERSION & OUTPUT
  1337.     CALL    ILPRT
  1338.     DB    'H)',0
  1339.     MOV    A,L        ;ONLY THE LOW BYTE IS USED BY THE PROGRAM
  1340.     POP    H        ;RESTORE IT
  1341. ;
  1342. RCVSQ:    MVI    B,2
  1343.     CALL    RECV
  1344.     JC    RCVSTOT
  1345.     CPI    SOH
  1346.     JZ    RCVSOH
  1347.     ORA    A
  1348.     JZ    RCVSQ
  1349.     CPI    EOT
  1350.     STC
  1351.     RZ
  1352.     MOV    B,A
  1353.     LDA    VSEEFLG
  1354.     ORA    A
  1355.     JZ    RCVSEH
  1356.     LDA    QFLG
  1357.     ORA    A
  1358.     JZ    RCVSERR
  1359.  
  1360. RCVSEH    call    ilprt
  1361.     db    cr,lf,0
  1362.     MOV    A,B
  1363.     CALL    HEXO
  1364.     CALL    ILPRT
  1365.     DB    'H RCD, NOT SOH',CR,LF,0
  1366.  
  1367. RCVSERR    MVI    B,1
  1368.     CALL    RECV
  1369.     JNC    RCVSERR
  1370.     call    txon
  1371.     MVI    A,NAK
  1372.     CALL    SEND
  1373.     call    txoff
  1374.     LDA    ERRCT
  1375.     INR    A
  1376.     STA    ERRCT
  1377.     CPI    ERRLIM
  1378.     JC    RCVRPT
  1379.     LDA    VSEEFLG
  1380.     ORA    A
  1381.     JZ    RCVCKQ
  1382.     LDA    QFLG
  1383.     ORA    A
  1384.     JZ    RCVSABT
  1385. RCVCKQ    CALL    CKQUIT
  1386.     JZ    RCVSECT
  1387. RCVSABT    CALL    CLOSFIL
  1388.     CALL    ERXIT
  1389.     DB CR,LF,'++    UNABLE TO RECEIVE BLOCK     --  ABORTING ++',CR,LF,'$'
  1390.  
  1391. RCVSTOT    LDA    VSEEFLG
  1392.     ORA    A
  1393.     JZ    RCVSPT
  1394.     LDA    QFLG
  1395.     ORA    A
  1396.     JZ    RCVSERR
  1397. RCVSPT    CALL    ILPRT
  1398.         DB    CR,LF,'++  TIMEOUT ++ ',0
  1399. RCVPRN    LDA    ERRCT
  1400.     CALL    HEXO
  1401.     CALL    CRLF
  1402.     JMP    RCVSERR
  1403.  
  1404. RCVSOH: MVI    B,1
  1405.     CALL    RECV
  1406.     JC    RCVSTOT
  1407.     MOV    D,A
  1408.     MVI    B,1
  1409.     CALL    RECV
  1410.     JC    RCVSTOT
  1411.     CMA
  1412.     CMP    D
  1413.     JZ    RCVDATA
  1414.     LDA    VSEEFLG
  1415.     ORA    A
  1416.     JZ    RCVBSE
  1417.     LDA    QFLG
  1418.     ORA    A
  1419.     JZ    RCVSERR
  1420. RCVBSE    CALL    ILPRT
  1421.         DB    CR,LF,'++  BAD SECTOR # IN HDR',CR,LF,0
  1422.     JMP    RCVSERR
  1423.  
  1424. RCVDATA    MOV    A,D
  1425.     STA    RCVSNO
  1426.     MVI    A,1
  1427.     STA    DATAFLG
  1428.     MVI    C,0
  1429.     call    clrcrc        ;clear crc counter
  1430.     LXI    H,80H
  1431.  
  1432. RCVCHR    MVI    B,1
  1433.     CALL    RECV
  1434.     JC    RCVSTOT
  1435.     MOV    M,A
  1436.     INR    L
  1437.     JNZ    RCVCHR
  1438.     mvi    e,2        ;nr of crc bytes
  1439. rcvcrc    mvi    b,1
  1440.     call    recv
  1441.     jc    rcvstot
  1442.     dcr    e
  1443.     jnz    rcvcrc
  1444.     call    chkcrc
  1445.     ora    a
  1446.     jz    chksnum
  1447.     lda    vseeflg
  1448.     ora    a
  1449.     jz    rcvcrer
  1450.     lda    qflg
  1451.     ora    a
  1452.     jz    rcvserr
  1453. ;
  1454. rcvcrer    call    ilprt
  1455.     db    cr,lf,'++CRC err++ ',0
  1456.     jmp    rcvprn
  1457.  
  1458. chksnum    LDA    RCVSNO
  1459.     MOV    B,A
  1460.     LDA    SECTNO
  1461.     CMP    B
  1462.     JZ    RECVACK
  1463.     INR    A
  1464.     CMP    B
  1465.     JNZ    ABORT
  1466.     RET
  1467.  
  1468. RECVACK    CALL    SENDACK
  1469.     JMP    RCVSECT
  1470.  
  1471. SENDACK:
  1472.     call    txon
  1473.     MVI    A,ACK
  1474.     CALL    SEND
  1475.     call    txoff
  1476.     RET
  1477.  
  1478. ;Transmitter is on when arrive here from SENDRPT
  1479.  
  1480. SENDHDR    LDA    QFLG
  1481.     ORA    A
  1482.     JZ    SENDHNM
  1483.     CALL    ILPRT
  1484.         DB    CR,'SEND # ',0
  1485.     PUSH    H
  1486.     LHLD    SECTNO        ;GET SECTOR NUMBER
  1487.     CALL    DECOUT        ;PRINT IT IN DECIMAL
  1488.     CALL    ILPRT
  1489.     DB    '  (',0
  1490.     CALL    DHXOUT        ;16 BIT HEX CONVERSION & OUTPUT
  1491.     CALL    ILPRT
  1492.     DB    'H)',0
  1493.     POP    H
  1494. SENDHNM    MVI    A,SOH
  1495.     CALL    SEND
  1496.     LDA    SECTNO
  1497.     CALL    SEND
  1498.     LDA    SECTNO
  1499.     CMA
  1500.     CALL    SEND
  1501.     RET
  1502.  
  1503. SENDSEC    MVI    A,1
  1504.     STA    DATAFLG
  1505.     MVI    C,0
  1506.     call    clrcrc
  1507.     LXI    H,80H
  1508. SENDC    MOV    A,M
  1509.     CALL    SEND
  1510.     INR    L
  1511.     JNZ    SENDC
  1512.     XRA    A
  1513.     STA    DATAFLG
  1514.     RET
  1515. ;
  1516. sendcrc    call    fincrc
  1517.     mov    a,d
  1518.     call    send
  1519.     mov    a,e
  1520.     call    send
  1521.     xra    a
  1522.     ret
  1523. ;
  1524. ;Transmitter turned of after return to SENDRPT
  1525. ;
  1526. GETACK    MVI    B,7
  1527.     CALL    RECVDG
  1528.     JC    GETATOT
  1529.     CPI    ACK
  1530.     RZ
  1531.     MOV    B,A
  1532.     LDA    QFLG
  1533.     ORA    A
  1534.     JZ    ACKERR
  1535.     CALL    ILPRT
  1536.     DB    CR,LF,0
  1537.     MOV    A,B
  1538.     CALL    HEXO
  1539.     CALL    ILPRT
  1540.         DB    'H RCD, NOT ACK',CR,LF,0
  1541. ACKERR    LDA    ERRCT
  1542.     INR    A
  1543.     STA    ERRCT
  1544.     CPI    ERRLIM
  1545.     RC
  1546.     LDA    VSEEFLG
  1547.     ORA    A
  1548.     JZ    GACKV
  1549.     LDA    QFLG
  1550.     ORA    A
  1551.     JZ    CSABORT
  1552. GACKV    CALL    CKQUIT
  1553.     STC
  1554.     RZ
  1555. CSABORT    CALL    ERXIT
  1556.     DB    CR,LF,'CAN''T SEND SECTOR -- ABORTING',CR,LF,'$'
  1557.  
  1558. GETATOT    LDA    QFLG
  1559.     ORA    A
  1560.     JZ    ACKERR
  1561.     CALL    ILPRT
  1562.         DB    CR,LF,'TIMEOUT ON ACK',CR,LF,0
  1563.     JMP    ACKERR
  1564.  
  1565. CKABORT:    
  1566.     CALL     STAT
  1567.     RZ
  1568.     CALL     KEYIN
  1569.     CPI     CAN
  1570.     RNZ
  1571.  
  1572. ABORT    LXI     SP,STACK
  1573. ABORTL    MVI     B,1
  1574.     CALL     RECV
  1575.     JNC     ABORTL
  1576.     call    txon
  1577.     MVI     A,CAN
  1578.     CALL     SEND
  1579.     call    txoff
  1580. ABORTW    MVI     B,1
  1581.     CALL     RECV
  1582.     JNC     ABORTW
  1583.     call    txon
  1584.     MVI     A,' '
  1585.     CALL     SEND
  1586.     call    txoff
  1587.     CALL     ILPRT
  1588.         DB CR,LF,'ROUTINE CANCELLED',CR,LF,BELL,0
  1589.     MVI     A,'B'        ;TURN MULTI-FILE MODE..
  1590.     STA     BATCHFLG    ;..OFF SO ROUTINE ENDS.
  1591.     JMP     DONETCE
  1592.  
  1593. INCRSNO    PUSH    H
  1594.     LHLD    SECTNO        ;GET SECTOR NUMBER
  1595.     INX    H        ;BUMP IT
  1596.     SHLD    SECTNO        ;STORE IT
  1597.     MOV    A,L
  1598.     POP    H
  1599.     RET
  1600.  
  1601. ERASFIL    LDA     BATCHFLG    ;DON'T ASK FOR ERASE..
  1602.     ORA     A        ;..IN MULTI-FILE MODE,..
  1603.     JZ     NOASK        ;..JUST DO IT.
  1604.     LXI     D,FCB
  1605.     MVI     C,SRCHF
  1606.     CALL     BDOS
  1607.     INR     A
  1608.     RZ
  1609.     CALL     ILPRT
  1610.         DB 'FILES EXISTS -- TYPE ''Y'' TO ERASE: ',BELL,0
  1611.     CALL     KEYIN
  1612.     PUSH     PSW
  1613.     CALL     TYPE
  1614.     POP     PSW
  1615.     CALL     UCASE
  1616.     CPI     'Y'
  1617.     JNZ     MENU
  1618.     CALL     CRLF
  1619.  
  1620. NOASK    LXI     D,FCB
  1621.     MVI     C,ERASE
  1622.     CALL     BDOS
  1623.     RET
  1624.  
  1625. BLKFILE    CALL     ILPRT    ;ROUTINE IF NO FILE IS NAMED FOR "SEND" OR "RECEIVE"
  1626.     DB CR,LF,'No file specified',CR,LF,BELL,0
  1627.     JMP     MENU
  1628.  
  1629. MAKEFIL    LXI     D,FCB
  1630.     MVI     C,MAKE
  1631.     CALL     BDOS
  1632.     INR     A
  1633.     RNZ
  1634.     CALL     ERXIT
  1635.     DB 'ERROR - CAN''T MAKE FILE',CR,LF
  1636.     DB 'DIRECTORY MUST BE FULL',CR,LF,'$'
  1637.  
  1638. CNREC:    MVI    C,FILSIZ    ;COMPUTE FILE SIZE FUNCTION IN CP/M 2.x
  1639.     LXI    D,FCB        ;POINT TO FILE CONTROL BLOCK
  1640.     CALL    BDOS
  1641.     LHLD    FCB+33        ;GET RECORD COUNT
  1642.     SHLD    RCNT        ;STORE IT
  1643.     LXI    H,0        ;ZERO HL
  1644.     SHLD    FCB+33        ;RESET RANDOM RECORD IN FCB
  1645.     RET
  1646.  
  1647. OPENFIL    LXI     D,FCB
  1648.     MVI     C,OPEN
  1649.     CALL     BDOS        
  1650.     INR     A
  1651.     JNZ     OPENOK
  1652.     CALL     ERXIT
  1653.     DB 'CAN''T OPEN FILE$'
  1654.  
  1655. OPENOK    LDA     BATCHFLG
  1656.     ORA     A
  1657.     JNZ     OPENOK1
  1658.     LDA     QFLG
  1659.     ORA     A
  1660.     RZ
  1661. OPENOK1    CALL     ILPRT
  1662.     DB    'FILE OPEN, SIZE: ',0
  1663.     LHLD    RCNT        ;GET RECORD COUNT
  1664.     CALL    DECOUT        ;PRINT NUMBER OF SECTORS IN DECIMAL
  1665.     CALL    ILPRT        ;PRINT
  1666.     DB    ' (',0
  1667.     CALL    DHXOUT
  1668.     CALL    ILPRT
  1669.     DB    'H) SECTORS',CR,LF,0
  1670.     RET
  1671.  
  1672. CLOSFIL    LXI     D,FCB
  1673.     MVI     C,CLOSE
  1674.     CALL     BDOS
  1675.     INR     A
  1676.     RNZ
  1677.     CALL     ERXIT
  1678.     DB 'CAN''T CLOSE FILE$'
  1679.  
  1680. RDSECT    LDA     SECINBF
  1681.     DCR     A
  1682.     STA     SECINBF
  1683.     JM     RDBLOCK
  1684.     LHLD     SECPTR
  1685.     LXI     D,80H
  1686.     CALL     MOVE128
  1687.     SHLD     SECPTR
  1688.     RET
  1689.  
  1690. RDBLOCK    LDA     EOFLG
  1691.     CPI     1
  1692.     STC
  1693.     RZ
  1694.     MVI     C,0
  1695.     LXI     D,DBUF
  1696. RDSECLP    PUSH     B
  1697.     PUSH     D
  1698.     MVI     C,STDMA
  1699.     CALL     BDOS
  1700.     LXI     D,FCB
  1701.     MVI     C,READ
  1702.     CALL     BDOS
  1703.     POP     D
  1704.     POP     B
  1705.     ORA     A
  1706.     JZ     RDSECOK
  1707.     DCR     A
  1708.     JZ     REOF
  1709.     CALL     ERXIT
  1710.     DB '++    FILE READ ERROR    ++$'
  1711.  
  1712. RDSECOK    LXI     H,80H
  1713.     DAD     D
  1714.     XCHG
  1715.     INR     C
  1716.     MOV     A,C
  1717.     CPI     DBUFSIZ*8    ;BUFFER SIZE IN 128 BYTE SECTORS
  1718.     JZ     RDBFULL
  1719.     JMP     RDSECLP
  1720. REOF    MVI     A,1
  1721.     STA     EOFLG
  1722.     MOV     A,C
  1723.  
  1724. RDBFULL    STA     SECINBF
  1725.     LXI     H,DBUF
  1726.     SHLD     SECPTR
  1727.     LXI     D,80H
  1728.     MVI     C,STDMA
  1729.     CALL     BDOS
  1730.     JMP     RDSECT
  1731.  
  1732. WRSECT    LHLD     SECPTR
  1733.     XCHG
  1734.     LXI     H,80H
  1735.     CALL     MOVE128
  1736.     XCHG
  1737.     SHLD    SECPTR
  1738.     LDA     SECINBF
  1739.     INR     A
  1740.     STA     SECINBF
  1741.     CPI     DBUFSIZ*8    ;BUFFER SIZE IN 128 BYTE SECTORS
  1742.     RNZ
  1743.  
  1744. WRBLOCK    LDA     SECINBF
  1745.     ORA     A
  1746.     RZ
  1747.     MOV     C,A
  1748.     LXI     D,DBUF
  1749. DKWRLP    PUSH     H
  1750.     PUSH     D
  1751.     PUSH     B
  1752.     MVI     C,STDMA
  1753.     CALL     BDOS
  1754.     LXI     D,FCB
  1755.     MVI     C,WRITE
  1756.     CALL     BDOS
  1757.     POP     B
  1758.     POP     D
  1759.     POP     H
  1760.     ORA     A
  1761.     JNZ     WRERR
  1762.     LXI     H,80H
  1763.     DAD     D
  1764.     XCHG
  1765.     DCR     C
  1766.     JNZ     DKWRLP
  1767.     XRA     A
  1768.     STA     SECINBF
  1769.     LXI     H,DBUF
  1770.     SHLD     SECPTR
  1771.     RET
  1772.  
  1773. WRERR:    call    txon
  1774.     MVI    C,CAN
  1775.     CALL    SEND
  1776.     call    txoff
  1777.     CALL    ERXIT
  1778.     DB    'ERROR WRITING FILE',CR,LF,'$'
  1779.  
  1780. ;---->    RECV: Receive a character
  1781.  
  1782. ;Timeout time is in B, in seconds. Entry via 'RECVDG' deletes garbage
  1783. ;characters on the line. For example, having just sent a sector, calling
  1784. ;RECVDG will delete any line noise induced characters LONG before the
  1785. ;ACK/NAK would be received.
  1786.  
  1787. RECVDG    EQU    $
  1788.     CALL    IN$MODDATP
  1789.     CALL    IN$MODDATP
  1790.  
  1791. RECV    PUSH    D
  1792.     LDA    FASTCLK
  1793.     ORA    A
  1794.     JZ    MSEC
  1795.     MOV    A,B
  1796.     ADD    A
  1797.     MOV    B,A
  1798.  
  1799. MSEC    LXI    D,15000
  1800.     CALL    CKABORT
  1801. MWTI    CALL    IN$MODCTLP
  1802.     CALL    ANI$MODRCVB
  1803.     CALL    CPI$MODRCVR
  1804.     JZ    MCHAR
  1805.     DCR    E
  1806.     JNZ    MWTI
  1807.     DCR    D
  1808.     JNZ    MWTI
  1809.     DCR    B
  1810.     JNZ    MSEC
  1811.     POP    D
  1812.     STC
  1813.     RET
  1814.  
  1815. MCHAR:    CALL    IN$MODDATP
  1816.     POP    D
  1817.     PUSH    PSW
  1818.     call    updcrc        ;calc crc
  1819.     ADD    C
  1820.     MOV    C,A
  1821.     LDA    RSEEFLG
  1822.     ORA    A
  1823.     JZ    MONIN
  1824.     LDA    VSEEFLG
  1825.     ORA    A
  1826.     JNZ    NOMONIN
  1827.     LDA    DATAFLG
  1828.     ORA    A
  1829.     JZ    NOMONIN
  1830. MONIN    POP    PSW
  1831.     PUSH    PSW
  1832.     CALL    SHOW
  1833. NOMONIN    POP    PSW
  1834.     ORA    A
  1835.     RET
  1836.  
  1837. SEND    PUSH    PSW
  1838.     LDA    SSEEFLG
  1839.     ORA    A
  1840.     JZ    MONOUT
  1841.     LDA    VSEEFLG
  1842.     ORA    A
  1843.     JNZ    NOMONOT
  1844.     LDA    DATAFLG
  1845.     ORA    A
  1846.     JZ    NOMONOT
  1847. MONOUT    POP    PSW
  1848.     PUSH    PSW
  1849.     CALL    SHOW
  1850. NOMONOT    POP    PSW
  1851.     PUSH    PSW
  1852.     call    updcrc        ;calc crc
  1853.     ADD    C
  1854.     MOV    C,A
  1855. SENDW    CALL    IN$MODCTLP
  1856.     CALL    ANI$MODSNDB
  1857.     CALL    CPI$MODSNDR
  1858.     JNZ    SENDW
  1859.     POP    PSW
  1860.     CALL    OUT$MODDATP
  1861.     RET
  1862.  
  1863. WAITNAK    LDA    VSEEFLG
  1864.     ORA    A
  1865.     JZ    WAITNPR
  1866.     LDA    QFLG
  1867.     ORA    A
  1868.     JZ    WAITNLP
  1869. WAITNPR    CALL    ILPRT
  1870.         DB    'AWAITING INITIAL NAK',CR,LF,0
  1871. WAITNLP    CALL    CKABORT        ;Now waits indefinetly here. ^X to cancel.
  1872.     MVI    B,2
  1873.     CALL    RECV
  1874.     CPI    NAK
  1875.     RZ
  1876.     JMP    WAITNLP
  1877. ;
  1878. INITADR
  1879.     LHLD     1
  1880.     LXI     D,3
  1881.     DAD     D
  1882.     SHLD     VSTAT+1
  1883.     DAD     D
  1884.     SHLD     VKEYIN+1
  1885.     DAD     D
  1886.     SHLD     VTYPE+1
  1887.     RET
  1888.  
  1889. PROCOPT
  1890.     LXI    D,FCB+1
  1891.     LDAX    D
  1892.     STA    OPTION
  1893. OPTLP    INX    D
  1894.     LDAX    D
  1895.     CPI    ' '
  1896.     JZ    ENDOPT
  1897.     LXI    H,OPTBL
  1898.     MVI    B,OPTBE-OPTBL
  1899. OPTCK    CMP    M
  1900.     JNZ    OPTNO
  1901.     MVI    M,0
  1902.     JMP    OPTLP
  1903. OPTNO    INX    H
  1904.     DCR    B
  1905.     JNZ    OPTCK
  1906.     JMP    BADOPT
  1907.  
  1908. ENDOPT: LDA    VSEEFLG
  1909.     ORA    A
  1910.     RNZ
  1911.     STA    QFLG
  1912.     RET
  1913.  
  1914. DONE:    LDA    BATCHFLG
  1915.     ORA    A
  1916.     JNZ    DONETCC
  1917.     LDA    QFLG
  1918.     ORA    A
  1919.     JZ    NMSTRNS
  1920.     LXI    H,FCB+1        ;PUT FILE NAME IN..
  1921.     LXI    D,FTRNMSG    ;..SPACES IN MESSAGE..
  1922.     MVI    B,8        ;..BELOW.
  1923.     CALL    MOVE
  1924.     INX    D        ;PUT FILE TYPE AFTER..
  1925.     MVI    B,3        ;..SKIPPING ONE SPACE..
  1926.     CALL    MOVE        ;..BELOW.    
  1927.     CALL    ILPRT
  1928.     db '  '            ;Leave a couple of spaces
  1929. FTRNMSG    DB '              TRANSFERRED',CR,LF,CR,LF,0    ;13 SPACES
  1930.  
  1931. NMSTRNS    LDA    FCB        ;SAVE DRIVE NO.
  1932.     STA    DISKNO
  1933.     LXI    H,FCB        ;BLANK OUT FILE CONTROL BLOCKS
  1934.     CALL    INITFCBS
  1935.     LDA    DISKNO        ;PUT DRIVE NUMBER BACK
  1936.     STA    FCB
  1937.     LXI    H,RESTSN    ;RESTORE SECTORE NUMBERS..
  1938.     LXI    D,SECTNOB    ;..FOR NEW FILE TRANSFER.
  1939.     MVI    B,SECTNOE-SECTNOB    ;ROUTINE ALSO DONE IN MENU.
  1940.     CALL    MOVE
  1941.     LDA    SENDFLG        ;GOES TO EITHER SEND OR..
  1942.     ORA    A        ;..RECEIVE FILE, DEPENDING..
  1943.     JNZ    SENDFIL        ;..UPON WHICH ROUTINE SET..
  1944.     JMP    RCVFIL        ;..THE FLAG IN MULTI-FILE MODE.
  1945.  
  1946. DONETCC    MVI    A,TRUE        ;INDICATE NO FILES BEING..
  1947.     STA    FSTFLG        ;RESET MULTIFILE TRANS
  1948.     STA    NFILFLG        ;..USED IN TERMINAL ROUTINE.
  1949.     CMA
  1950.     STA    SAVEFLG        ;STOP MEMORY SAVE IN TERM ROUTINE.
  1951.     LDA    VSEEFLG
  1952.     ORA    A
  1953.     JZ    DONETC
  1954.     LDA    QFLG
  1955.     ORA    A
  1956.     JZ    donetce
  1957. DONETC    CALL    ILPRT
  1958.         DB    CR,LF,'ALL TRANSFERS COMPLETED'
  1959.     DB    CR,LF,BELL,0
  1960. DONETCE:
  1961.     LDA    TERMFLG        ;SEE IF RETURN TO..
  1962.     ORA    A        ;..TERMINAL MODE..
  1963.     JNZ    MENU        ;..AFTER X'FER.
  1964.     CALL    CRLF
  1965.     JMP    termint
  1966.  
  1967.  
  1968. MOVEFCB    LXI     H,FCB+16
  1969.     LXI     D,FCB
  1970.     MVI     B,16
  1971.     CALL     MOVE
  1972.     XRA     A
  1973.     STA     FCBSNO
  1974.     STA     FCBEXT
  1975.     RET
  1976.  
  1977. SHOW    CPI     LF
  1978.     JZ     CTYPE
  1979.     CPI     CR
  1980.     JZ     CTYPE
  1981.     CPI     9
  1982.     JZ     CTYPE
  1983.     CPI     ' '
  1984.     JC     SHOWHEX
  1985.     CPI     7FH
  1986.     JC     CTYPE
  1987. SHOWHEX    PUSH     PSW
  1988.     MVI     A,'('
  1989.     CALL     CTYPE
  1990.     POP     PSW
  1991.     CALL     HEXO
  1992.     MVI     A,')'
  1993.     JMP     CTYPE
  1994.  
  1995. CTYPE    PUSH     B
  1996.     PUSH     D
  1997.     PUSH     H
  1998.     MOV     E,A
  1999.     MVI     C,WRCON
  2000.     CALL     BDOS
  2001.     POP     H
  2002.     POP     D
  2003.     POP     B
  2004.     RET
  2005.  
  2006. CRLF    PUSH     PSW
  2007.     MVI     A,CR
  2008.     CALL     TYPE
  2009.     MVI     A,LF
  2010.     CALL     TYPE
  2011.     POP     PSW
  2012.     RET
  2013.  
  2014. TYPE    PUSH     PSW
  2015.     PUSH     B
  2016.     PUSH     D
  2017.     PUSH     H
  2018.     MOV     C,A
  2019. VTYPE    CALL     $-$
  2020.     POP     H
  2021.     POP     D
  2022.     POP     B
  2023.     POP     PSW
  2024.     RET
  2025.  
  2026. STAT    PUSH     B
  2027.     PUSH     D
  2028.     PUSH     H
  2029. VSTAT    CALL     $-$
  2030.     POP     H
  2031.     POP     D
  2032.     POP     B
  2033.     ORA     A
  2034.     RET
  2035.  
  2036. KEYIN    PUSH     B
  2037.     PUSH     D
  2038.     PUSH     H
  2039. VKEYIN    CALL     $-$
  2040.     POP     H
  2041.     POP     D
  2042.     POP     B
  2043.     RET
  2044.  
  2045. UCASE    CPI     61H        ;CHANGES LOWER CASE CHARACTER..
  2046.     RC            ;..IN A-REG TO UPPER CASE.
  2047.     CPI     7BH
  2048.     RNC
  2049.     ANI     5FH
  2050.     RET
  2051.  
  2052. DECOUT:    PUSH    PSW
  2053.     PUSH    B
  2054.     PUSH    D
  2055.     PUSH    H
  2056.     LXI    B,-10
  2057.     LXI    D,-1
  2058.  
  2059. DECOU2:    DAD    B
  2060.     INX    D
  2061.     JC    DECOU2
  2062.     LXI    B,10
  2063.     DAD    B
  2064.     XCHG
  2065.     MOV    A,H
  2066.     ORA    L
  2067.     CNZ    DECOUT
  2068.     MOV    A,E
  2069.     ADI    '0'
  2070.     CALL    CTYPE
  2071.     POP    H
  2072.     POP    D
  2073.     POP    B
  2074.     POP    PSW
  2075.     RET
  2076.  
  2077. ;---->    DHXOUT: - double precision hex output routine.
  2078.  
  2079. DHXOUT:    PUSH    H
  2080.     PUSH    PSW
  2081.     MOV    A,H        ;GET MS BYTE
  2082.     CALL    HEXO        ;OUTPUT HIGH ORDER BYTE
  2083.     MOV    A,L        ;GET LS BYTE
  2084.     CALL    HEXO        ;OUTPUT LOW ORDER BYTE
  2085.     POP    PSW
  2086.     POP    H
  2087.     RET
  2088.  
  2089. HEXO    PUSH     PSW
  2090.     RAR
  2091.     RAR
  2092.     RAR
  2093.     RAR
  2094.     CALL     NIBBL
  2095.     POP     PSW
  2096. NIBBL    ANI     0FH
  2097.     CPI     10
  2098.     JC     ISNUM
  2099.     ADI     7
  2100. ISNUM    ADI     '0'
  2101.     JMP     TYPE
  2102.  
  2103. ;RETURNS W/ ZERO SET IF RETRY ASKED. IF MULTI-FILE MODE, THEN
  2104. ;NO QUESTIONS ASKED, JUST QUIT
  2105.  
  2106. CKQUIT    LDA     BATCHFLG
  2107.     ORA     A
  2108.     JNZ     CKQTASK        ;ASK FOR RETRY
  2109.     INR     A        ;RESET ZERO FLG
  2110.     RET
  2111. CKQTASK    XRA    A
  2112.     STA    ERRCT
  2113.     CALL    ILPRT
  2114.         DB    'MULTIPLE ERRORS ENCOUNTERED.',CR,LF
  2115.         DB    'TYPE Q TO QUIT, R TO RETRY:  ',BELL,0
  2116.     CALL    KEYIN
  2117.     PUSH    PSW
  2118.     CALL    CRLF
  2119.     POP    PSW
  2120.     CALL    UCASE        ;INSTEAD OF "ANI 5FH"
  2121.     CPI    'R'
  2122.     RZ
  2123.     CPI    'Q'
  2124.     JNZ    CKQUIT
  2125.     ORA    A
  2126.     RET
  2127.  
  2128. ILPRT    XTHL
  2129. ILPLP    MOV     A,M
  2130.     ORA     A
  2131.     JZ     ILPRET
  2132.     CALL     CTYPE
  2133.     INX     H
  2134.     JMP     ILPLP
  2135. ILPRET    XTHL
  2136.     RET
  2137.  
  2138. PRTMSG    MVI     C,PRINT
  2139.     JMP     BDOS
  2140.  
  2141. ERXIT    POP    D
  2142.     CALL    PRTMSG
  2143.     CALL    ILPRT
  2144.     DB    BELL,0
  2145.     LDA    BATCHFLG
  2146.     ORA    A
  2147.     JNZ    DONETCE
  2148.     MVI    A,'Q'        ;RESET QFLG
  2149.     STA    QFLG
  2150.     JMP    ABORT        ;ABORT OTHER COMPUTER
  2151.  
  2152. EXIT    LXI     D,80H
  2153.     MVI     C,STDMA
  2154.     CALL     BDOS
  2155.     JMP     0
  2156.  
  2157. MOVE128    MVI     B,128
  2158. MOVE    MOV     A,M
  2159.     STAX     D
  2160.     INX     H
  2161.     INX     D
  2162.     DCR     B
  2163.     JNZ     MOVE
  2164.     RET
  2165.  
  2166.  
  2167. ;INITIALIZES CP/M FILE CONTROL BLOCKS AT 5CH AND 6CH
  2168.  
  2169. SETFCB    LXI     D,CMDBUF
  2170.     LXI     H,FCB
  2171.     CALL     CPMLINE
  2172.     CALL     PROCOPT
  2173.  
  2174. CHECKNM    LDA    FCB+1        ;CHECK ON THE PRIMARY OPTION
  2175.     CPI    'M'        ;RETURN TO MENU
  2176.     RZ
  2177.     CPI    'T'
  2178.     JZ    TERMSEL
  2179.     CPI    'S'
  2180.     JZ    CKFILE
  2181.     CPI    'R'
  2182.     JNZ    BDOPT
  2183.     LDA    BATCHFLG    ;IF MULT FILE MODE, THEN..
  2184.     ORA    A        ;..RECV OPT DOES NOT NEED..
  2185.     RZ            ;..NAME.
  2186.     JMP    CKFILE
  2187. BDOPT    CALL    ILPRT
  2188.     DB    CR,LF,'++Bad Option++',CR,LF,0
  2189.     JMP    REENT
  2190. CKFILE    LDA    FCB+17        ;IF OPTION THAT NEEDS FILE NAME,..
  2191.     CPI    ' '        ;..THEN CHECK TO SEE IF NAME..
  2192.     RNZ            ;..EXISTS. IF NOT..
  2193. REENT    CALL    ILPRT        ;..DO EVERYTHING OVER.
  2194.         DB CR,LF,'Re-enter PRIMARY option and file name only: ',BELL,0
  2195.     LXI    D,CMDBUF
  2196.     CALL    INBUFF
  2197.     JMP    SETFCB
  2198.  
  2199. TERMSEL    LDA    FCB+17
  2200.     CPI    ' '
  2201.     JNZ    SAVAGN
  2202.     MVI    A,FALSE
  2203.     STA    SAVEFLG
  2204.     MVI    A,TRUE
  2205.     STA    NFILFLG
  2206.     CMA
  2207.     RET
  2208.  
  2209. SAVAGN    MVI    A,FALSE
  2210.     STA    NFILFLG
  2211.     RET
  2212.  
  2213. ;
  2214. ;************************************************************************
  2215. ;* CRCSUBS (Cyclic Redundancy Code Subroutines) version 1.20        *
  2216. ;* 8080 Mnemonics                            *
  2217. ;*                                    *
  2218. ;*         These subroutines will compute and check a true 16-bit        *
  2219. ;*    Cyclic Redundancy Code for a message of arbitrary length.    *
  2220. ;*                                    *
  2221. ;*    The  use  of this scheme will guarantee detection of all    *
  2222. ;*    single and double bit errors, all  errors  with  an  odd    *
  2223. ;*    number  of  error bits, all burst errors of length 16 or    *
  2224. ;*    less, 99.9969% of all 17-bit error bursts, and  99.9984%    *
  2225. ;*    of  all  possible  longer  error bursts.  (Ref: Computer    *
  2226. ;*    Networks, Andrew S.  Tanenbaum, Prentiss-Hall, 1981)        *
  2227. ;*                                    *
  2228. ;*    Designed & coded by Paul Hansknecht, June 13, 1981        *
  2229. ;*                                    *
  2230. ;*    Copyright (c) 1981, Carpenter Associates            *
  2231. ;*                Box 451                    *
  2232. ;*                Bloomfield Hills, MI 48013            *
  2233. ;*                313/855-3074                *
  2234. ;*                                    *
  2235. ;*    This program may be freely reproduced for non-profit use.    *
  2236. ;*                                    *
  2237. ;************************************************************************
  2238. ;
  2239. ;    ENTRY    CLRCRC,UPDCRC,FINCRC,CHKCRC
  2240. ;
  2241. CLRCRC:    EQU    $        ; Reset CRC Accumulator for a new message.
  2242.     PUSH    H
  2243.     LXI    H,0
  2244.     SHLD    CRCVAL
  2245.     POP    H
  2246.     RET
  2247. ;
  2248. UPDCRC:    EQU    $        ; Update CRC Accumulator using byte in (A).
  2249.     PUSH    PSW
  2250.     PUSH    B
  2251.     PUSH    H
  2252.     MVI    B,8
  2253.     MOV    C,A
  2254.     LHLD    CRCVAL
  2255. ;
  2256. UPDLOOP:MOV    A,C
  2257.     RLC
  2258.     MOV    C,A
  2259.     MOV    A,L
  2260.     RAL
  2261.     MOV    L,A
  2262.     MOV    A,H
  2263.     RAL
  2264.     MOV    H,A
  2265.     JNC    SKIPIT
  2266.     MOV    A,H        ; The generator is X^16 + X^12 + X^5 + 1
  2267.     XRI    10H        ; as recommended by CCITT.
  2268.     MOV    H,A        ; An alternate generator which is often
  2269.     MOV    A,L        ; used in synchronous transmission protocols
  2270.     XRI    21H        ; is X^16 + X^15 + X^2 + 1. This may be
  2271.     MOV    L,A        ; used by substituting XOR 80H for XOR 10H
  2272. SKIPIT:    DCR    B        ; and XOR 05H for XOR 21H in the adjacent code.
  2273.     JNZ    UPDLOOP
  2274.     SHLD    CRCVAL
  2275.     POP    H
  2276.     POP    B
  2277.     POP    PSW
  2278.     RET
  2279. ;
  2280. FINCRC:    EQU    $        ; Finish CRC calc for outbound message.
  2281.     PUSH    PSW
  2282.     XRA    A
  2283.     CALL    UPDCRC
  2284.     CALL    UPDCRC
  2285.     PUSH    H
  2286.     LHLD    CRCVAL
  2287.     MOV    D,H
  2288.     MOV    E,L
  2289.     POP    H
  2290.     POP    PSW
  2291.     RET
  2292. ;
  2293. CHKCRC:    EQU    $        ; Check CRC bytes of received message.
  2294.     PUSH    H
  2295.     LHLD    CRCVAL
  2296.     MOV    A,H
  2297.     ORA    L
  2298.     POP    H
  2299.     RZ
  2300.     MVI    A,0FFh
  2301.     RET
  2302. ;
  2303. CRCVAL:    DW    0
  2304. ;
  2305. MENU:    LXI    H,RESTSN    ;RESTORE SECTORE NUMBERS..
  2306.     LXI    D,SECTNOB    ;..FOR NEW FILE TRANSFER.
  2307.     MVI    B,SECTNOE-SECTNOB
  2308.     CALL    MOVE
  2309.     LXI    H,RESTROPT    ;RESTORE OPTION TABLE
  2310.     LXI    D,OPTBL
  2311.     MVI    B,OPTBE-OPTBL
  2312.     CALL    MOVE
  2313.     MVI    A,0
  2314.     STA    MFFLG1        ;RESET MFACCESS ROUTINE..
  2315.     CMA            ;..AND MULTI TRANS IN CASE..
  2316.     STA    FSTFLG        ;..OF ABORT.
  2317.  
  2318. MENU1:    LDA    XPRFLG        ;TEST IF MENU SHOULD BE SHOWN
  2319.     ORA    A
  2320.     JNZ    XPRT
  2321. MENU2:    CALL    ILPRT
  2322.     DB    CR,LF,CR,LF,0
  2323.  
  2324.     if    h19term
  2325.     call    ilprt
  2326.     db    esc,'E',0    ;Clear screen
  2327.     endif
  2328.  
  2329.     call    ilprt
  2330.     db    '*PRIMARY OPTIONS*                        *SECONDARY OPTIONS*'
  2331.     db    cr,lf,lf
  2332.     DB     'WRT- Write file to disk(terminal mode)   '
  2333.     db    'B- Multi file transfer(send or recv)',cr,lf
  2334.     DB     'DEL- Erase present file(terminal mode)   '
  2335.     db    'T- Return to Terminal after transfer',cr,lf
  2336.     DB     'RET- Return to terminal mode(save data)  '
  2337.     db    'Q- Quiet transfer(fatal messages only)',cr,lf
  2338.     DB    'XPR- Toggle expert mode (Menu on/off)    '
  2339.     db    'V- View what is sent and received',cr,lf
  2340.     DB    'DIR- List directory(may specify drive)   '
  2341.     db    'S- View what is sent during transfer',cr,lf
  2342.     DB    'CPM- Exit to CP/M                        '
  2343.     db    'R- View what is rcvd during transfer',cr,lf
  2344.     DB    'S  - Send CP/M file',CR,LF
  2345.     DB    'R  - Receive CP/M file',CR,LF
  2346.     DB    'T  - Terminal mode (optional file name)',CR,LF,lf
  2347.     db    '*TERMINAL MODE FUNCTIONS*',cr,lf,lf
  2348.  
  2349.     if      h19term
  2350.     db    'f1 Key   - Transmit CWID',cr,lf
  2351.     db    'f2 Key   - Send a line (Press f2 first, enter up to 80'
  2352.     db    ' characters then press CR)',cr,lf
  2353.     db    'f3 Key   - Initiate blind file transfer',cr,LF
  2354.     db    'f4 Key   - Toggle file save mode(File previously named'
  2355.     db    ' at "T")',cr,lf
  2356.     db    'f5 Key   - Exit terminal mode',cr,lf
  2357.     db    'Blue Key - Transmitter OFF',cr,lf
  2358.     db     'Red Key  - Transmitter ON',cr,lf
  2359.     db    'White Key- Transmitter ON, automatic OFF on CR',cr,0
  2360.     endif
  2361.  
  2362.     if not    h19term
  2363.     db    '^E   - Exit terminal mode',cr,lf
  2364.     db    '^Y   - Toggle file save mode(File previously named'
  2365.     db    ' at "T")',cr,lf
  2366.     db    '^T   - Initiate blind file transfer',cr,LF
  2367.     db    'ESC S- Transmit CWID',cr,lf
  2368.     db    'ESC T- Send a line (Enter ESC T first, enter up to 80'
  2369.     db    ' characters then press CR)',cr,lf
  2370.     db    'ESC P- Transmitter OFF',cr,lf
  2371.     db     'ESC Q- Transmitter ON',cr,lf
  2372.     db    'ESC R- Transmitter ON, automatic OFF on CR',cr,0
  2373.     endif
  2374.  
  2375. XPRT    CALL    ILPRT
  2376.     DB    CR,LF,CR,LF,'DEFAULT DRIVE: ',0
  2377.     MVI    C,25        ;CURRENT DISK FUNCTION
  2378.     CALL    BDOS
  2379.     ADI    41H        ;MAKE ASCII
  2380.     CALL    TYPE
  2381.     call    ilprt
  2382.     db    '   ',0
  2383.  
  2384.     if     h19term
  2385.     call    ilprt
  2386.     db    esc,'p',0
  2387.     endif
  2388.  
  2389.     CALL    ILPRT
  2390.     DB    ' Command? '
  2391.     DB    0
  2392.  
  2393.     if    h19term
  2394.     call    ilprt
  2395.     db    esc,'q',0
  2396.     endif
  2397.  
  2398. GETCMD    LXI    D,CMDBUF    ;ENTER COMMAND
  2399.     CALL    INBUFF
  2400.     CALL    CRLF
  2401.     LXI    D,CMDBUF+2    ;POINT TO COMMAND
  2402.     CALL    ILCOMP
  2403.     DB    'CPM',0
  2404.     JNC    EXIT
  2405.     CALL    ILCOMP
  2406.     DB    'DIR',0
  2407.     JNC    DIR
  2408.     CALL    ILCOMP
  2409.     DB    'RET',0
  2410.     JC    NXTOPT1        ;CARRY SET = NO MATCH
  2411.     LHLD    HLSAVE        ;RETURN TO TERMINAL..
  2412.     JMP    termint        ;..MODE WITH SAVE OPTION..
  2413.                 ;..IF PREVIOUSLY ENABLED.
  2414. NXTOPT1:
  2415.     CALL     ILCOMP
  2416.     DB     'WRT',0
  2417.     JNC     WRTFIL
  2418.     CALL     ILCOMP
  2419.     DB     'XPR',0
  2420.     JNC     XPRMODE
  2421.     CALL     ILCOMP
  2422.     DB     'DEL',0
  2423.     JNC     NEWFILE
  2424.  
  2425. NXTOPT2 PUSH     H
  2426.     LDA     CMDBUF+2
  2427.     LXI     H,COMPLIST
  2428.     CALL     COMPARE        ;COMPARES LIST POINTED TO BY HL..
  2429.     POP     H        ;..TO CHAR IN A-REG.
  2430.     JC     MENU1        ;CARRY SET = NO MATCH
  2431.  
  2432. DOOPT    PUSH     H        ;LOAD ORIGINAL FCB WITH TRANSFER..
  2433.     CALL     SETFCB        ;..CMDS AND GO TO BEGINNING OF..
  2434.     POP     H        ;..PROGRAM. WILL FOLLOW SAME LOGIC..
  2435.     JMP     RESTART        ;..AS IF PROGRAM WERE CALLED WITH..
  2436.                 ;..CP/M COMMAND LINE.
  2437.  
  2438.  
  2439. DIR    CALL     DIRLST
  2440.     JMP     XPRT
  2441.  
  2442. NEWFILE    LDA     FCB3+1
  2443.     CPI     ' '
  2444.     JZ     MENU1        ;IF NO FILE, DON'T ERASE
  2445.     LXI     D,FCB3
  2446.     MVI     C,ERASE
  2447.     CALL     BDOSRT
  2448.     MVI     A,TRUE        ;DO NOT ALLOW TERMINAL..
  2449.     STA     NFILFLG        ;..SAVE SINCE NO FILE..
  2450.     CMA            ;..SPECIFIED.
  2451.     STA     SAVEFLG
  2452.  
  2453.     LXI    H,FCB3
  2454.     CALL    INITFCBS
  2455.     JMP    MENU1
  2456.  
  2457. WRTFIL    LDA    NFILFLG
  2458.     CPI    TRUE
  2459.     JZ    MENU1
  2460.     LDA    FCB3+1        ;CHECK THAT FILE WAS REQUESTED
  2461.     CPI    ' '
  2462.     JZ    MENU1
  2463.     LHLD    HLSAVE
  2464.     CALL    NUMRECS        ;DISK WRITE ROUTINE AS USED IN..
  2465.     CALL    WRTDSK        ;..IN THE INTDSKSV ROUTINE.
  2466.     CALL    CLOSE3
  2467.     MVI    A,TRUE
  2468.     STA    NFILFLG
  2469.     CMA
  2470.     STA    SAVEFLG
  2471.  
  2472.     LXI    H,FCB3
  2473.     CALL    INITFCBS    ;BLANK OUT FCB SO WRITTEN FILE..
  2474.     JMP    MENU1        ;..CAN'T BE ERASED.
  2475.  
  2476. XPRMODE    LDA    XPRFLG
  2477.     CMA
  2478.     STA    XPRFLG
  2479.     JMP    MENU1
  2480.  
  2481.  
  2482. COMPARE    MOV    B,M        ;COMPARES A-REG WITH LIST..
  2483. COMPLP    INX    H        ;..ADDRESSED BY HL. FIRST ELEMENT..
  2484.     CMP    M        ;..OF LIST MUST BE NUMBER OF ELEMENTS..
  2485.     JZ    VALID        ;..BEING COMPARED. RETURNS WITH..
  2486.     DCR    B        ;..CARRY SET IF A-REG DOES NOT..
  2487.     JNZ    COMPLP        ;.. CONTAIN AN ELEMENT IN LIST.
  2488.     STC
  2489. VALID    RET
  2490. ;
  2491. ;
  2492. COMPLIST DB 4, 'S', 'R', 'T', 'M'
  2493.  
  2494. ILCOMP    INLNCOMP    ;A MACRO IN MACROS.LIB
  2495.  
  2496.  
  2497. INBUFF    INBUF        ;A MACRO IN "MACROS.LIB"
  2498.  
  2499. CPMLINE    CMDLINE        ;A MACRO IN "MACROS.LIB"
  2500.  
  2501. DIRLST    DIRLIST        ;A MACRO IN "MACROS.LIB"
  2502.  
  2503. NFILFLG    DB     FALSE    ;NORMALLY SET TO FALSE. ALLOWS WRITE TO..
  2504.             ;..MEMORY IN TERMINAL MODE.
  2505.  
  2506. OPTION    DB     0
  2507.  
  2508. OPTBL    EQU     $
  2509. QFLG    DB     'Q'
  2510. RSEEFLG    DB     'R'
  2511. SSEEFLG    DB     'S'
  2512. VSEEFLG    DB     'V'
  2513. TERMFLG DB     'T'
  2514. BATCHFLG DS     1    ;SET TO 'B' BY MENU. DOES NOT ALLOW MULTI-..
  2515. OPTBE    EQU     $    ;..FILE XFER WHEN PROGRAM INITIALLY CALLED.
  2516.  
  2517. RESTROPT        ;MUST BE IN SAME ORDER AS TABLE ABOVE
  2518.  
  2519.         DB     'Q','R','S','V','T','B'
  2520.  
  2521. RESTSN    DB     0,0,0,0,0
  2522.     DW     DBUF
  2523.     DB     0,0,0,0,0,0
  2524.  
  2525. SECTNOB    EQU     $
  2526. RCVSNO    DB     0
  2527. SECTNO    DW     0
  2528. ERRCT    DB     0
  2529. EOFLG    DB     0
  2530. SECPTR    DW     DBUF
  2531. SECINBF    DB     0
  2532. MAXEXT    DB     0
  2533. RCNT    DW     0
  2534. DATAFLG    DB     0
  2535. EXACFL    DB     0
  2536. SECTNOE    EQU     $
  2537.  
  2538. BADOPT    CALL     ILPRT
  2539.     DB 'INVALID OPTION',CR,LF,BELL,0
  2540.     JMP     MENU
  2541.  
  2542. FSTFLG    DB     TRUE
  2543.  
  2544. CMDBUF    DB     80H,0
  2545.     DS     80H
  2546. HLSAVE    DS     2
  2547. DISKNO    DS     1
  2548. SENDFLG    DS     1
  2549. NBSAVE    DS     2
  2550. BGNMS    DS     2
  2551. FILECT    DS     1
  2552. NAMECT    DS     1
  2553.  
  2554.     DS     60
  2555. STACK    DS     2
  2556. FCB3    DS     33
  2557. FCBBUF    DS     15
  2558. linebuf    ds     82
  2559. DBUF    EQU     $    
  2560. NAMEBUF    EQU DBUF+(DBUFSIZ*1024)    ;BUFFER FOR NAMES IN BATCH MODE. OVERFLOWS..
  2561.                 ;..ABOVE PROGRAM CODE.
  2562. ;    BDOS EQUATES
  2563.  
  2564. RDCON    EQU 1
  2565. WRCON    EQU 2
  2566. PRINT    EQU 9
  2567. RDBUF    EQU 10
  2568. CONST    EQU 11
  2569. OPEN    EQU 15
  2570. CLOSE    EQU 16
  2571. SRCHF    EQU 17
  2572. SRCHN    EQU 18
  2573. ERASE    EQU 19
  2574. READ    EQU 20
  2575. WRITE    EQU 21
  2576. MAKE    EQU 22
  2577. REN    EQU 23
  2578. STDMA    EQU 26
  2579. FILSIZ    EQU 35
  2580. BDOS    EQU 5
  2581. REIPL    EQU 0
  2582. FCB    EQU 5CH
  2583. FCBEXT    EQU FCB+12
  2584. FCBSNO    EQU FCB+32
  2585. FCBRNO    EQU FCB+32
  2586. FCB2    EQU 6CH
  2587.  
  2588. LAST    END 100H
  2589.