home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / BEEHIVE / BBS / ZCMD28.ASM < prev   
Assembly Source File  |  2000-06-30  |  82KB  |  2,961 lines
  1. ;
  2. ;   ZCMD   - Z80 CCP command processor program replacement
  3. ;   v2.8
  4. ; 07/22/86 - Tom Brady  Decibel RCP/M (PBBS)  (404) 288-6858
  5. ;
  6. ; The EQUates are currently set for use by an RCP/M -- you will want
  7. ;  verify the settings of those equates tagged with an asterisk (*)
  8. ;  beside the comment field for your particular system needs.
  9. ;
  10. ; NOTE:     Read ZCMD.HIS for a complete history of updates.
  11. ;
  12. ;   ZCMD2 is ZCPR2.2.3 with special RCPM features for RCPM use.
  13. ;   ZCPR2 was originally written by Richard Conn.
  14. ;
  15. ; Extensive documentation on ZCPR2 and the utilities in the ZCPR2 system
  16. ;  can be found in the following manuals:
  17. ;
  18. ;        ZCPR2 Concepts Manual
  19. ;        ZCPR2 Installation Manual
  20. ;        ZCPR2 User's Guide
  21. ;        ZCPR2 Rationale
  22. ;
  23. ; ******** Structure Notes ********
  24. ;
  25. ; ZCMD2 is divided into a number of major sections.  The following is an
  26. ;   outline of these sections and the names of the major routines located
  27. ;   therein.
  28. ;
  29. ; Section    Function/Routines
  30. ; -------    -----------------
  31. ;
  32. ;   --        Opening Comments, Equates, and Macro Definitions
  33. ;
  34. ;    0        JMP Table into ZCMD2
  35. ;
  36. ;    1        Buffers
  37. ;
  38. ;    2        CCP Starting Modules
  39. ;            CCP    CCP1    CONT    RESTRT    RS1
  40. ;            CAPBUF    RSTCCP    RCCPNL    ERROR    PRNNF
  41. ;
  42. ;    3        Utilities
  43. ;            CRLF    CONOUT    CONIN    LCOUT    LSTOUT
  44. ;            PAGER    READF    READ    BDOSB    PRINTC
  45. ;            PRINT    PRIN1    GETDRV    DEFDMA    DMASET
  46. ;            RESET    BDOSJP    LOGIN    OPENF    OPEN
  47. ;            GRBDOS    CLOSE    SEARF    SEAR1    SEARN
  48. ;            SUBKIL    DELETE    GETUSR    SETUSR
  49. ;
  50. ;     4     CCP Utilities
  51. ;            SETUD    UCASE    REDBUF    BREAK    SDELM
  52. ;            ADVAN    SBLANK    ADDAH    NUMBER    NUMERR
  53. ;            HEXNUM    DIRPTR    SLOGIN    DLOGIN    SCANLOG
  54. ;            SCANER    SCANX    SCANF    CMDSER
  55. ;
  56. ;     5     CCP-Resident Commands and Functions
  57. ;     5A        DIR    DIRPR    PRFN    GETSBIT FILLQ
  58. ;     5B        ERA
  59. ;     5C        LIST
  60. ;     5D        TYPE
  61. ;     5E        SAVE    EXTEST
  62. ;     5F        REN
  63. ;     5G        JUMP
  64. ;     5H        GO
  65. ;     5I        COM    CALLPROG
  66. ;     5J        GET    MLOAD    PRNLE    PATH
  67. ;
  68. ;-----
  69. ;
  70. ;  The following equates may be used to customize this CCP for the user's
  71. ;  system and integration technique.  The following constants are provided:
  72. ;
  73. ;    REL    - YES if integration is to be done via MOVCPM
  74. ;        - NO if integration is to be done via DDT and SYSGEN
  75. ;
  76. ;    CCPLOC - Beginning address of CCP; this value can be obtained by
  77. ;          running the public domain utility PROBE.
  78. ;
  79. ;=====
  80. ;
  81. ; SPECIAL NOTE:  Look for and change the following lines for your system
  82. ;         requirements.  This is the area that is stuffed with a 
  83. ;         command for auto-execution upon cold boot.  As an example,
  84. ;         upon cold boot, your computer would run SUBMIT.COM and 
  85. ;         look in BOOT.SUB for instructions.  The character count 
  86. ;         is 11.
  87. ;         
  88. ; * EXAMPLE ONLY * LEAVE COMMENTED OUT * 
  89. ;
  90. ;CHRCNT: DB    11        ; Number of valid chars in command line
  91. ;CMDLIN: DB    'SUBMIT BOOT'   ; Default (cold boot) command
  92. ;     DB    0        ; Command string terminator
  93. ;
  94. ;=====
  95. ;
  96. NO    EQU    0
  97. YES    EQU    NOT NO
  98. ;
  99. ; ************************************
  100. ; USER CONFIGURABLE EQUATES BEGIN HERE
  101. ; ************************************
  102. ;
  103. REL    EQU    NO        ; Yes, for MOVCPM integration
  104. MAKESPR    EQU    NO        ; Yes, for SPR generation
  105. OZFLOP    EQU    NO        ; Yes, if booting Ozzie-1 from floppy
  106.                 ;   disk system tracks.    
  107.                 ; No, if MAKESPR is YES (Read OZZIE-1.NOT)
  108. ;
  109.      IF    NOT MAKESPR
  110.      IF    REL
  111. CCPLOC    EQU    0        ; MOVCPM image
  112.      ENDIF
  113. ;
  114. ; If REL is NO, obtain the beginning address of your current CCP
  115. ;  using PROBE (or its equivalent), then merely set CCPLOC to that
  116. ;  value as as in the following line:
  117. ;
  118.      IF    (NOT OZFLOP) AND (NOT REL)
  119. CCPLOC    EQU    0D800H        ;*Fill in with BDLSLOC-supplied value
  120.      ENDIF
  121. ;
  122.      IF    OZFLOP AND (NOT REL)
  123. CCPLOC    EQU    0D400H        ; Ozzie-1 floppy disk default CCP
  124.                 ;   location is here
  125.      ENDIF
  126. ;
  127. ; The following gives the required offset to load the CCP into the CP/M
  128. ;  SYSGEN image through DDT (the Roffset command).  Note that this value
  129. ;  conforms with the standard value presented in the CP/M reference manuals,
  130. ;  but it may not necessarily conform with the location of the CCP in your
  131. ;  CP/M system -- several systems (Morrow Designs, P&T, Heath ORG-0 and
  132. ;  others) have the CCP located at a non-standard address in the SYSGEN image.
  133. ;
  134.      IF    NOT REL
  135. ;;CCPR    EQU    980H-CCPLOC    ; DDT load offset for normal systems
  136. ;;CCPR    EQU    1100H-CCPLOC    ; DDT load offset for Morrow Designs
  137. CCPR    EQU    0B00H-CCPLOC    ; DDT load offset for Kaypro w/Advent Turbo Rom
  138.      ENDIF
  139. ;
  140. ; The following equate identifies the location of the BIOS.  This equate
  141. ;  assumes the standard sizes of 800H for ZCMD2 and 0E00H for BDOS and
  142. ;  does not need to be modified if the user is running a standard CP/M
  143. ;  configuration.
  144. ;
  145. BIOS    EQU    CCPLOC+800H+0E00H ; Address of BIOS
  146.      ENDIF
  147. ;
  148. ; The following macros define the file types of the command object files
  149. ;  (.COM files under CP/M 2.2) to be loaded when a non-resident ZCMD2
  150. ;  command is given and of the indirect command files (SUB files under
  151. ;  CP/M 2.2) to be used to extract commands from when the indirect 
  152. ;  command facility is invoked.
  153. ;
  154. COMTYP     MACRO
  155.     DB    'COM'        ; File type of command file
  156.      ENDM
  157. ;
  158. SUBTYP     MACRO
  159.     DB    'SUB'        ; File type of indirect command file
  160.      ENDM
  161. ;
  162. ; The following flag enables or disables the ability of ZCMD2 to process
  163. ;  SUBMIT files (command files of the form $$$.SUB).  If SUBON is YES,
  164. ;  then ZCMD2 will process such files like CP/M's CCP normally does; if
  165. ;  SUBON is NO, ZCMD2 will not process such files (just ignores them).  In
  166. ;  such a case only indirect command file facilities like ZEX will work.
  167. ;
  168. SUBON    EQU    yes        ;*Yes, enable processing of $$$.SUB files.
  169.                 ;   This is a large code eater so beware
  170.                  ;   of size.  It's a good one to set NO if
  171.                  ;   size >800H.
  172. ;
  173. ; The following flag allows ZCMD2 to accept commands like:  "A1:DIR".
  174. ;  If DRVPREFIX is YES, this form is accepted; if NO, this form is not
  175. ;  accepted.  This flag has the additional side effect of automatically
  176. ;  selecting files in the current disk/user if the command is of the form
  177. ;  "A3>CMND".  The DRVPFATT determines the attributes of selected
  178. ;  files if DRVPREFIX is YES.
  179. ;
  180. DRVPREFIX EQU    NO        ; YES to enable prefix.
  181. ;
  182. ; The following flag allows the user to select the attributes of the
  183. ;  files in the current disk/current user to be examined if the DRVPREFIX
  184. ;  flag YES.  The following values are defined:
  185. ;
  186. ;        DRVPFATT    Files Selected
  187. ;            0        System
  188. ;           80H        Directory
  189. ;            1        Both System and Directory
  190. ;
  191. DRVPFATT EQU    1        ; Select both system and directory
  192. ;
  193. ; The following flag enables or disables the ability to switch user
  194. ;  areas.  If your BBS system pokes the maximum drive/user area available
  195. ;  areas.  If your BBS system pokes DRVMAX/USRMAX memory areas (see below)
  196. ;  with a user's maximum drive/user area access, set USERON to YES and you
  197. ;  will be just as secure as if you had set it to NO.
  198. ;
  199. USERON    EQU    yes        ; Enable user specification
  200. SUPRES    EQU    no        ; No to see A0> instead of A>
  201. ;
  202. ; The following equate specifies the address of the PATH to be followed
  203. ;  for the PATH command-search if the PATH is to be initialized by the BIOS
  204. ;  and set by the user via a PATH.COM program.  The value of PATH should
  205. ;  be the address of the PATH data area in memory.  If the internal PATH
  206. ;  provided by Z80CCP is to be used, then INTPATH should be equated to YES,
  207. ;  which selects the PATH defined by the IPATH MACRO and the SYSOP path
  208. ;  (WHEEL).
  209. ;  If the external PATH is to be used, then INTPATH should be equated to NO
  210. ;  and an equate value for the address of the PATH should be provided.
  211. ;
  212. ; A PATH is a series of byte-pairs, terminated by a binary 0.  The first
  213. ;  byte of each pair is the disk number (1-16 for disks A-P), and the second
  214. ;  byte of each pair is the user number (0-31).    The special character '$'
  215. ;  indicates the current user or current disk.  For example, the path
  216. ;  from current disk/current user to current disk/user 0 to disk A/user 0
  217. ;  is selected by the following sequence:
  218. ;
  219. ;        DB    '$$'    ;current disk/user
  220. ;        DB    '$',0    ;current disk/user 0
  221. ;        DB    1,0    ;disk A/user 0
  222. ;        DB    0    ;end of path
  223. ;
  224. ; NOTE:  If DRVPREFIX is YES, then current disk/user is automatically
  225. ;  searched, and including it in the command search path causes it to be
  226. ;  searched twice, wasting time (and space in the path).  Since many environs
  227. ;  will run with DRVPREFIX = YES, then a good command search path would not
  228. ;  include the current disk/user.
  229. ;
  230. INTPATH    EQU    YES        ; NO to use external ZCMD2 path
  231. ;
  232.      IF    INTPATH
  233. IPATH     MACRO
  234.     DB    '$$'        ; Current drive/user
  235.     DB    'A'-'@',0    ; Drive A, user 0.  Set as many pairs as
  236.      ENDM            ;  you like, but leave off terminating 0.
  237.                 ;  That last 0 is provided elsewhere.
  238. ;
  239. ; The following equates define the extra path to search if the Wheel
  240. ;  byte is ON, and INTPATH is YES.
  241. ;
  242. SYSDRV    EQU    'A'-'@'        ; Search this drive if WHEEL byte on
  243. SYSUSR    EQU    15        ; User area of SYSDRV to find Sysop's
  244.                 ;   .COM files.
  245.      ENDIF
  246. ;
  247. ; This equate defines the base address of the external path
  248. ;
  249.      IF    NOT INTPATH    ; External path selected
  250. PATH    EQU    40H        ; External ZCMD2 path at CBIOS buffer
  251.                 ;   area
  252.      ENDIF            ; NOT INTPATH
  253. ;
  254. ; The following equate causes ERA to confirm on the files to be erased
  255. ;  before it goes ahead and erases them.  If ERAOK is YES, then the user
  256. ;  will be prompted each time; if it is NO, then the user will not be
  257. ;  prompted.
  258. ;
  259. ERAOK    EQU    yes        ; YES for prompt
  260. ;
  261. ; If ERAOK is YES, the following equate adds a Verify option to the ERA
  262. ;  command which causes the user to be prompted only if the Verify option
  263. ;  letter, defined by ERDFLG, is given after the file name.  If ERAV is
  264. ;  NO then the user will be asked to verify only when ERDFLG is contained
  265. ;  in the command line; if ERAV is NO, the user will always be asked to
  266. ;  verify.
  267. ;
  268. ERAV    EQU    YES        ; Enable verify option
  269. ERDFLG    EQU    'V'        ; Set option letter
  270. ;
  271. ;
  272. ; If both BYCLOCK and BYTLOS are set NO (probably because you aren't
  273. ;  running NUBYE/BYE5), but you have a clock and want the [hh:mm] shown
  274. ;  before the drive/user prompt -- set CLOCK to YES.  You must also
  275. ;  edit the macro and clock reading code below for your system needs.
  276. ;
  277. CLOCK    EQU    no        ;*Yes, you have a clock, but aren't
  278.                 ;  running NUBYE/BYE5 and want a clock
  279.                 ;  display.
  280. ;
  281.      IF    CLOCK
  282. ;
  283. ; CKCLOK is used to check the clock's existence.  If it is turned off
  284. ;  (i.e. the clock is in your external modem, which is turned off) or
  285. ;  not present, it will skip putting the time in the prompt.  Also allows
  286. ;  easy assembly of ZCMD for machines in which the clock might be an
  287. ;  optional item to be added later (i.e. Kaypro's).  CKCLOK should 
  288. ;  initialize and check the real-time clock.  If it is present and
  289. ;  functioning, call TIME, else fall through without doing anything (just
  290. ;  displays the normal du> prompt).
  291. ;
  292. ; NOTE: Example code is for Kaypro internal clock
  293. ;
  294. CKCLOK     MACRO
  295.     MVI    A,0FH        ; Initialize PIO port to clock
  296.     OUT    22H
  297.     MVI    A,0CH        ; Check 'clock initialized' flag set
  298.     OUT    20H        ;  by TIME.COM and CLOCK.BAS
  299.     IN    24H        ; Get flag value
  300.     CPI    29H        ; Initialized?
  301.     CZ    TIME        ; Yes, so print [hh:mm]
  302.      ENDM
  303. ;
  304. ; RDCLOK is used to read the clock.  Defined as a macro, it will be located
  305. ;  at TIME:, and should get the HH and MM in BCD, call ASCII (as in the
  306. ;  sample below) to set up the prompt and then jump to PRIN1 to print it
  307. ;  and return.  Modify this to fit your system requirements if CLOCK is YES.
  308. ;
  309. ; NOTE: Example code is for Kaypro internal clock
  310. ;
  311. RDCLOK     MACRO
  312.     MVI    A,4        ; Get hours register
  313.     OUT    20H        ; Set that into latch
  314.     IN    24H        ; Input BCD value into A
  315.     ORA    A        ; Midnight (0)?
  316.     JRNZ    RDCLK1        ; No, skip fix
  317.     MVI    A,12H        ; Load 12 (midnight)
  318. RDCLK1:    CPI    13H        ; PM (13-23 o'clock)?
  319.     JRC    RDCLK2        ; No, so print it else...
  320.     SUI    12H        ; Subtract 12 to make it 12-hour time
  321.     DAA            ; BCD adjustment of subtract
  322. RDCLK2:    LXI    H,ANSHH        ; Set pointer to HH in prompt memory
  323.     CALL    ASCII        ; And put HH into it in ASCII
  324.     LDA    ANSHH        ; Get tens of hours
  325.     CPI    '0'        ; Leading zero?
  326.     JRNZ    RDCLK3        ; No, so skip fix
  327.     MVI    A,' '        ; Fix with space
  328.     STA    ANSHH        ; Put it in message
  329. RDCLK3:    MVI    A,3        ; Get minutes register
  330.     OUT    20H        ; Set that into latch
  331.     IN    24H        ; Input BCD value to A
  332.     LXI    H,ANSMM        ; Set pointer to MM in prompt memory
  333.     CALL    ASCII        ; And put MM into it in ASCII
  334.     MVI    A,16        ; Set to R/O register
  335.     OUT    20H        ; Put in latch to protect clock on power-down
  336.     LXI    H,TMSG
  337.     JP    PRIN1        ; And print it -- done.
  338.      ENDM
  339.      ENDIF            ; CLOCK AND (NOT BYCLOCK) and (NOT BYTLOS) 
  340. ;
  341. ; NOTE: Either specify BYCLOCK and BYTLOS as NO, or one as YES and the 
  342. ;  other as NO -- but -- don't specify both as YES.
  343. ;
  344. ; The following equates (BYCLOCK/BYTLOS/SHOW) enable the appearance of
  345. ;  [hh:mm], [Left:nn] and [On:nn] before the drive/user prompt, if you
  346. ;  have a clock and are running NUBYE or BYE5.  A check is made to see
  347. ;  if NUBYE/BYE5 is running and skips the clock read if not.
  348. ;
  349. BYCLOCK    EQU    NO        ;*Yes, if NYBYE/BYE5 has a clock installed
  350.                  ;   and you want the [HH:MM] displayed before
  351.                  ;   the du>.
  352.                 ;   PRIDRIV must be NO for this to work.
  353.                 ;
  354. BYTLOS    EQU    yes        ;*Yes, if NUBYE/BYE5 has a clock installed
  355.                  ;   and you want the [Left:nn] displayed
  356.                  ;   before the du>, where nn will indicate
  357.                  ;   time-left-on-system.
  358. SHOW    EQU    yes        ;*Yes, if WHEEL is set, or user has
  359.                 ;  unlimited time and you wish to show
  360.                 ;  time-on-system as: '[On:nn]'.
  361.                 ; NO, if you want to disable display when
  362.                 ;  WHEEL is set or user has unlimited time.
  363. ;
  364. ; WARNING -- BYTLOS takes more code than BYCLOCK -- You may have to
  365. ;  set SUBON to NO in order to keep the size below 800H.
  366. ;
  367. ; If you set one of the three transient command equates from above 
  368. ;  (i.e. ERAON, SAVEON, OR RENON) to NO, this should keep you well within
  369. ;  the 800H limit... The CP/M utility NSWEEP provides you with all three
  370. ;  functions.  If you wish to keep these transient commands and use BYTLOS,
  371. ;  you will probably have to set SUBON to NO. [tmb]
  372. ;
  373. ; The MULTCMD equate enables the feature of having more than
  374. ;  one command on the same line, separated by a separation char
  375. ;  which is defined by the CMDSEP equate. 
  376. ;
  377. ;  If SUBON is YES, then MULTCMD must be NO - a bug for future fix...? 
  378. ;
  379. MULTCMD    EQU    yes        ;*Yes, allow multiple commands
  380. CMDSEP    EQU    ';'        ; Command separator
  381. ;
  382. ; The following equate allows selection of using an internal or an ex-
  383. ; ternal command buffer.
  384. ;
  385. EXCBUF    EQU    yes        ; YES to use external command buffer
  386. ;
  387.      IF    MULTCMD    AND EXCBUF
  388. CLBASE    EQU    0F093H        ; Base address of buffer
  389. BUFLEN    EQU    164        ; 164 bytes in input buffer
  390.      ENDIF
  391. ;
  392. ; The following flags enable or disable various ZCMD2-resident commands.
  393. ;  The user may invoke these as desired, but should keep in mind the size
  394. ;  of the resulting ZCMD2 and make sure it does not exceed the required
  395. ;  limits.
  396. ;
  397. DIRON    EQU    NO        ; DIR
  398. LTON    EQU    NO        ; LIST, TYPE
  399. GOON    EQU    NO        ; GO
  400. ERAON    EQU    yes        ;*ERA  \    Can't have all 3 and stay <800H
  401. SAVEON    EQU    yes        ;*SAVE  --> (with BYTLOS and SUBON set YES)
  402. RENON    EQU    yes        ;*REN  /    Use NSWP to replace either/all.
  403. GETON    EQU    NO        ; GET
  404. JUMPON    EQU    NO        ; JUMP
  405. ; 
  406. ; When the WHEEL byte (low memory byte, normally located at 3EH) is
  407. ;  used, certain system functions can have restricted access (i.e.
  408. ;  ERA may only be used when the WHEEL is ON -- Sysop access).  If this
  409. ;  byte is not zero, then the command proceeds.    If it is zero, then the
  410. ;  command is not allowed to proceed and is exited with an error message.
  411. ;
  412. WHEEL    EQU    YES        ; Set YES for RCP/M use always and most
  413.                 ;   all other applications
  414. WHLADR    EQU    3EH        ; Normal address of WHEEL byte
  415. ;
  416. ; The following set of equates make each of the indicated commands
  417. ;  selectable to respond to the WHEEL byte or not (i.e. if WERA is YES,
  418. ;  then the ERAse function works when the WHEEL byte is on/set as for
  419. ;  Sysop privileges.)
  420. ;
  421. WERA    EQU    YES        ; ERA only if/when WHEEL is on/set?
  422. WREN    EQU    YES        ; REN  "     "         "     "    "
  423. WLT    EQU    YES        ; TYPE "     "         "     "    "
  424. WGO    EQU    YES        ; GO   "     "         "     "    "
  425. WSAVE    EQU    YES        ; SAVE "     "         "     "    "
  426. WGET    EQU    YES        ; GET  "     "         "     "    "
  427. WJUMP    EQU    YES        ; JUMP "     "         "     "    "
  428. WDU    EQU    NO        ; DU:  "     "         "     "    "
  429. ;
  430. PRIVDIR    EQU    NO        ; No, for most everybody (especially RCP/M's)
  431.                 ; If YES, do not allow users to access
  432.                 ;    other's directories unless the
  433.                 ;    WHEEL byte is on/set.  This disables
  434.                 ;    DU's in the FCB, DRVPREFIX and also
  435.                 ;    the printing of the current DU.
  436. ;
  437. ; The INTSTACK equate is used to specify if the stack is internal or
  438. ; external to ZCMD2.  Naturally, quite a bit of space is saved if the
  439. ; stack is placed external to ZCMD2.  If such is the case, the user
  440. ; should set the STKBASE equate to the beginning of the stack area
  441. ; (bottom of the stack).
  442. ;
  443. ; NOTE: THIS IS THE BOTTOM OF THE STACK, NOT THE TOP OF THE STACK.
  444. ;
  445. ; If INTSTACK is YES, the stack is internal to ZCMD2.  If INTSTACK is NO
  446. ; the stack is external to ZCMD2, and the base of the stack (bottom of
  447. ; the stack) is located at STKBASE.
  448. ;
  449. INTSTACK EQU    no        ; Enable or disable internal stack
  450. ;
  451.      IF    NOT INTSTACK
  452. STKBASE    EQU    0F043H        ; Address of bottom of external stack
  453. STACK    EQU    STKBASE+4FH    ; Address of top of stack
  454.                 ; (stack size should be at least 48 bytes)
  455.      ENDIF
  456. ;
  457. ; *** Terminal and 'type' customization equates
  458. ;
  459. NLINES    EQU    24        ;*Number of lines on crt screen
  460. WIDE    EQU    YES        ; Yes for normal directory display
  461. FENCE    EQU    '|'        ;*Separation character between files
  462. HBCON    EQU    NO        ;*Yes, ok to send characters with Hi bit
  463.                 ;   set (i.e. file attribute bits) to
  464.                 ;   screen unchanged.
  465. HBLST    EQU    NO        ;*Yes, ok to send characters with Hi bit
  466.                 ;   set to LST device unchanged.
  467. PGDFLT    EQU    NO        ; Yes, pauses at each screenful of output
  468. PGDFLG    EQU    'P'        ; For type command: page or not (dep on
  469.                 ;   PGDFLT).  This flag reverses the
  470.                 ;   default effect.
  471. ; other general equates
  472. ;
  473. MAXDISK    EQU    16        ;*Maximum number of drives
  474.                 ; (i.e. 8 = drives A through H available)
  475. USRMAX    EQU    3FH        ; *** 3FH is recommended, if used *** 
  476.                 ; Location of byte in memory containing
  477.                 ;   number of highest allowable user
  478.                 ;   code +1.  This is set to MAXUSR if BYE
  479.                 ;   is not present, and after that it is con-
  480.                 ;   trolled by system programs.  Then if
  481.                 ;   USRMAX=0, MAXUSR cannot be dynamically
  482.                  ;   changed, and should be permanently set.
  483. MAXUSR    EQU    15        ; Maximum user number accessable (0-15)
  484.                 ;
  485. DRVMAX    EQU    3DH        ; *** 03DH is reccomended, if used ***
  486.                 ; Location of byte in memory containing
  487.                 ;   maximum legal drive, this value is
  488.                 ;   set to MAXDISK if BYE is not present
  489.                 ;   After that controlled by system programs.
  490.                 ;   If DRVMAX=0 then MAXDISK cannot be
  491.                 ;   changed by external programs, and
  492.                 ;   should be permanently set.
  493. SYSFLG    EQU    'A'        ; For dir command: list $SYS and $DIR
  494. SOFLG    EQU    'S'        ; For dir command: list $SYS files only
  495. SPRMPT    EQU    '$'        ; CCP prompt indicating submit command
  496. NPROMPT    EQU    '>'        ; CCP prompt when WHEEL byte is OFF
  497.                 ;   NOTE: With ZEX, add +80H
  498. WPROMPT    EQU    '}'        ; CCP prompt if WHEEL byte is ON
  499.                 ;   (Set to '>' if you want both the same)
  500.                 ;   NOTE: With ZEX, add +80H
  501. NUMBASE    EQU    'H'        ; Switches from default to number base
  502. SECTFLG    EQU    'S'        ; Option character for save command
  503. CURIND    EQU    '$'        ; Symbol for current disk or user
  504. COMMENT    EQU    ';'        ; Depicts comment lines
  505. ;
  506. ; CCP command name table - each table entry is composed of the 4-byte
  507. ; command and 2-byte address
  508. ;
  509. NCHARS    EQU    4        ; Number of chars/command
  510. ;
  511. CTABLE     MACRO
  512. ;
  513.      IF    DIRON
  514.     DB    'ODIR'
  515.     DW    DIR        ; Directory display command
  516.      ENDIF
  517. ;
  518.      IF    LTON
  519.     DB    'LIST'
  520.     DW    LIST        ; List file on printer command
  521.     DB    'TYPE'
  522.     DW    TYPE        ; Type file on console command
  523.      ENDIF
  524. ;
  525.      IF    GOON
  526.     DB    'GO  '
  527.     DW    GO        ; Execute current tpa command
  528.      ENDIF
  529. ;
  530.      IF    ERAON
  531.     DB    'ERA '
  532.     DW    ERA        ; Erase files command
  533.      ENDIF
  534. ;
  535.      IF    SAVEON
  536.     DB    'SAVE'
  537.     DW    SAVE        ; Save tpa command
  538.      ENDIF
  539. ;
  540.      IF    RENON
  541.     DB    'REN '
  542.     DW    REN        ; Rename files command
  543.      ENDIF            ; RENON
  544. ;
  545.      IF    GETON
  546.     DB    'GET '
  547.     DW    GET        ; Load file into TPA command
  548.      ENDIF            ; GETON
  549. ;
  550.      IF    JUMPON
  551.     DB    'JUMP'
  552.     DW    JUMP        ; Jump to any memory location command
  553.      ENDIF
  554.      ENDM
  555. ;
  556. ; This equate determines if the ZCMD2 FCB is located internal to or ex-
  557. ; ternal to ZCMD2.  If EXTFCB is YES, FCBADR defines where it is found.
  558. ; Placing the ZCMD2 FCB external to ZCMD2, more space is left for other
  559. ; uses within ZCMD2.
  560. ;
  561. EXTFCB    EQU    NO        ; Allow external FCB
  562. ;
  563.      IF    EXTFCB
  564. FCBADR    EQU    0EFD0H        ; Address of external FCB
  565.      ENDIF
  566. ;
  567. ; CMDRUN - ZCMD2 Extended Command Processing Facility
  568. ;
  569. ; This equate enables the ZCMD2 CMDRUN facility.  If CMDRUN is YES, then
  570. ; another stage of command processing is invoked should ZCMD2 fail to
  571. ; find a COM file when the user gives a command.  This stage involves
  572. ; invoking the .COM file specified by CMDFCB and giving it the current
  573. ; command line as an argument.    In this way, if, say, M80 PROG2 fails as
  574. ; a command, a new command like LRUNZ M80 PROG2, SUB M80 PROG2, or ZEX
  575. ; M80 PROG2 may be processed.  If the new command fails, an appropriate
  576. ; error message is given.
  577. ;
  578. ; The ROOTONLY option causes ZCMD2 to only look at the Root (bottom of
  579. ; path) for the Extended Command Processor if it is set to YES.  If it
  580. ; is set to NO, the path is searched for the Extended Command Processor.
  581. ; The tradeoff here is that ROOTONLY = YES is less flexible but somewhat
  582. ; faster than ROOTONLY = NO.
  583. ;
  584. CMDRUN    EQU    NO        ; Enable the facility
  585. ;
  586.      IF    CMDRUN
  587. ROOTONLY EQU    YES        ; True if look at root only for extended
  588.                 ;   command processor, NO if look along
  589.                 ;   path
  590. CMDFCB     MACRO
  591.     DB    0
  592.     DB    'CMDRUN  '    ; Name of program
  593.     DB    'COM'        ; File type
  594.      ENDM
  595.      ENDIF
  596. ;
  597. ; end of customization section
  598. ;-----
  599. ;
  600. CR    EQU    0DH
  601. LF    EQU    0AH
  602. TAB    EQU    9
  603. ;
  604. WBOOT    EQU    0        ; CP/M warm boot address
  605. UDFLAG    EQU    4        ; User num in high nybble, disk in low
  606. BDOS    EQU    5        ; BDOS function call entry point
  607. TFCB    EQU    5CH        ; Default FCB buffer
  608. TBUFF    EQU    80H        ; Default disk I/O buffer
  609. TPA    EQU    100H        ; Base of TPA
  610. ;
  611. ; MACROS to provide Z80 extensions - MACROS include:
  612. ;
  613.     $-MACRO            ; First turn off the expansions
  614. ;
  615. ;    JR    - JUMP RELATIVE
  616. ;    JRC    - JUMP RELATIVE IF CARRY
  617. ;    JRNC    - JUMP RELATIVE IF NO CARRY
  618. ;    JRZ    - JUMP RELATIVE IF ZERO
  619. ;    JRNZ    - JUMP RELATIVE IF NO ZERO
  620. ;    DJNZ    - DECREMENT B AND JUMP RELATIVE IF NO ZERO
  621. ;    LDIR    - MOV @HL TO @DE FOR COUNT IN BC
  622. ;    LXXD    - LOAD DOUBLE REG DIRECT
  623. ;    SXXD    - STORE DOUBLE REG DIRECT
  624. ;
  625. ;    @GENDD macro used for checking and generating
  626. ;           8-bit jump relative displacements.
  627. ;
  628. @GENDD     MACRO    ?DD        ; ; Checks range of 8-bit displacements
  629. ;
  630.      IF    (?DD GT    7FH) AND (?DD LT 0FF80H)
  631.     DB    100H        ; Displacement range error on jump rel.
  632.      ELSE
  633.     DB    ?DD
  634.      ENDIF            ; ; Range error
  635.      ENDM            ; ; MACRO
  636. ;
  637. ;-----
  638. ;
  639. ; Z80 macro extensions
  640. ;
  641. JR     MACRO    ?N        ; ; Jump relative
  642.     DB    18H
  643.     @GENDD    ?N-$-1
  644.      ENDM
  645. ;
  646. JRC     MACRO    ?N        ; ; Jump relative on carry
  647.     DB    38H
  648.     @GENDD    ?N-$-1
  649.      ENDM
  650. ;
  651. JRNC     MACRO    ?N        ; ; Jump relative on no carry
  652.     DB    30H
  653.     @GENDD    ?N-$-1
  654.      ENDM
  655. ;
  656. JRZ     MACRO    ?N        ; ; Jump relative on zero
  657.     DB    28H
  658.     @GENDD    ?N-$-1
  659.      ENDM
  660. ;
  661. JRNZ     MACRO    ?N        ; ; Jump relative on no zero
  662.     DB    20H
  663.     @GENDD    ?N-$-1
  664.      ENDM
  665. ;
  666. DJNZ     MACRO    ?N        ; ; Decrement B and jump relative
  667.     DB    10H
  668.     @GENDD    ?N-$-1
  669.      ENDM
  670. ;
  671. LDIR     MACRO            ; ; LDIR
  672.     DB    0EDH,0B0H
  673.      ENDM
  674. ;
  675. LDED     MACRO    ?N        ; ; Load DE direct
  676.     DB    0EDH,5BH
  677.     DW    ?N
  678.      ENDM
  679. ;
  680. LBCD     MACRO    ?N        ; ; Load BC direct
  681.     DB    0EDH,4BH
  682.     DW    ?N
  683.      ENDM
  684. ;
  685. SDED     MACRO    ?N        ; ; Store DE direct
  686.     DB    0EDH,53H
  687.     DW    ?N
  688.      ENDM
  689. ;
  690. SBCD     MACRO    ?N        ; ; Store BC direct
  691.     DB    0EDH,43H
  692.     DW    ?N
  693.      ENDM
  694. ;
  695. ; end of Z80 macro extensions
  696. ;-----
  697. ;
  698. ; **** Section 0 ****
  699. ;
  700. ; Entry point into ZCMD2
  701. ;
  702. ; IF MULTCMD (MULTIPLE COMMANDS ON ONE LINE) is NO:  If ZCMD2 is entered
  703. ; at location CCPLOC (at the JMP to CCP), then the default command in
  704. ; CMDLIN will be processed.  If ZCMD2 is entered at location CCPLOC+3
  705. ; (at the JMP to CCP1), then the default command in CMDLIN will NOT be
  706. ; processed.  NOTE:  Entry into ZCMD2 at CCPLOC is permitted, but in
  707. ; order for this to work, CMDLIN MUST be initialized to contain the
  708. ; command line (ending in 0) and the C-register MUST contain a valid
  709. ; user/disk flag (the most significant nybble contains the user number
  710. ; and the least significant nybble contains the disk number.  Some user
  711. ; programs (such as SYNONYM3) attempt to use the default command fa-
  712. ; cility.  Under the original CCP, it was necessary to initialize the
  713. ; pointer after the reserved space for the command buffer to point to
  714. ; the first byte of the command buffer.  The NXTCHR (NeXT CHaRacter
  715. ; pointer) is located to be compatable with such programs (if they de-
  716. ; termine the buffer length from the byte at BUFSIZ [CCPLOC + 6]), but
  717. ; under ZCMD2 this is no longer necessary.  ZCMD2 automatically initial-
  718. ; izes this buffer pointer in all cases if MULTCMD is not enabled.
  719. ;
  720. ; IF MULTCMD is YES: Entry at CCP or CCP1 has the same effect.    Multiple
  721. ; command processing will still continue.  Hence, if MULTCMD is NO, a
  722. ; user program need only load the buffer CMDLIN with the desired command
  723. ; line, terminated by a zero, in order to have this command line exe-
  724. ; cuted.  If MULTCMD is YES, a user program must load this buffer as be-
  725. ; fore, but he must also set the NXTCHR pointer to point to the first
  726. ; character of the command line.  NOTE:  ***** (BIG STAR) ***** Programs
  727. ; such as SYNONYM3 will fail if multiple commands are enabled, but this
  728. ; feature is so very useful that it is worth the sacrifice.  The ZCMD2
  729. ; utilities of STARTUP and MENU require multiple commands, and this
  730. ; feature also permits simple chaining of programs to be possible under
  731. ; the ZCMD2 environment.
  732. ;
  733.      IF    NOT MAKESPR
  734.     ORG    CCPLOC
  735.      ENDIF
  736. ;
  737. ENTRY:     IF    NOT OZFLOP
  738.     JMP    CCP        ; Process potential default command
  739.      ENDIF
  740. ;
  741.      IF    OZFLOP
  742.     JMP    BOOTJMP        ; Used to properly set the Osborne CCP
  743.                 ; if using ZCMD from the floppy disk system
  744.                 ; tracks  the first two bytes must
  745.                 ; be C3H, 5CH
  746.      ENDIF
  747. ;
  748.     JMP    CCP1        ; Do not process potential default cmd
  749. ;
  750. ;-----
  751. ;
  752. ; **** Section 1 ****
  753. ;
  754. ; Buffers et al - input command line and default command
  755. ;
  756. ; The command line to be executed is stored here.  This command line is
  757. ; generated in one of 3 ways:
  758. ;
  759. ;    (1) by the user entering it through the BDOS READLN function at
  760. ;        the DU> prompt [user input from keyboard]
  761. ;    (2) by the SUBMIT File Facility placing it there from a $$$.SUB
  762. ;        file
  763. ;    (3) by an external program or user placing the required command
  764. ;        into this buffer
  765. ;
  766. ; In all cases, the command line is placed into the buffer starting at
  767. ; CMDLIN.  This command line is terminated by a binary zero.  ZCMD2 then
  768. ; parses, interprets, and executes the command line.  Case is not signi-
  769. ; ficant in the command line.  ZCMD2 converts all lower-case letters to
  770. ; upper-case.  If MULTCMD is YES, then the user must set a pointer to
  771. ; the first character of the command line into the buffer NXTCHR.  If
  772. ; MULTCMD is NO, no action other than placing a zero-terminated command
  773. ; line into the buffer starting at CMDLIN is required on the part of the
  774. ; user.  For multiple commands, the command line buffer (CMDLIN) is lo-
  775. ; cated external to ZCMD2 so that it is not overlayed during warm boots;
  776. ; the same is YES for NXTCHR, the 2nd key buffer.  BUFSIZ and CHRCNT are
  777. ; not important and are provided so the BDOS READLN function can load
  778. ; CMDLIN directly and a user program can see how much space is available
  779. ; in CMDLIN for its text.
  780. ;
  781.      IF    MULTCMD    AND EXCBUF
  782. NXTCHR    EQU    CLBASE        ; Nxtchr stored externally (2 bytes)
  783. BUFSIZ    EQU    NXTCHR+2    ; Bufsiz stored externally (1 byte)
  784. CHRCNT    EQU    BUFSIZ+1    ; Chrcnt stored externally (1 byte)
  785. CMDLIN    EQU    CHRCNT+1    ; Cmdlin stored externally (long)
  786.      ENDIF
  787. ;
  788. ; These buffers are left internal to ZCMD2 so that the original CCP
  789. ; command line facility (as used by programs like SYNONYM3) can be left
  790. ; intact.
  791. ;
  792. ; **** NOTE: Change the two lines marked with an asterisk (*) in the
  793. ;      comment field for command execution on cold boot (i.e. system
  794. ;      resets).
  795. ;
  796.      IF    NOT EXCBUF
  797. BUFLEN    EQU    80            ; Maximum buffer length
  798. BUFSIZ:    DB    BUFLEN            ; Maximum buffer length
  799. CHRCNT:    DB    0            ;*Number of valid chars in command line
  800. CMDLIN:    DB    '           '       ;*Default (cold boot) command
  801.     DB    0            ; Command string terminator
  802.     DS    BUFLEN-($-CMDLIN)+1 ; Total is 'BUFLEN' bytes
  803. NXTCHR:    DW    CMDLIN            ; Pointer to command input buffer
  804.      ENDIF
  805. ;
  806. ; File type for command
  807. ;
  808. COMMSG:    COMTYP            ; Use macro
  809. ;
  810. ; Submit file control block
  811. ;
  812.      IF    SUBON
  813. SUBFCB:    DB    1        ; Disk name set to default to drive A:
  814.     DB    '$$$'        ; File name
  815.     DB    '     '
  816.     SUBTYP            ; Use macro from ZCMDHDR.LIB
  817.     DB    0        ; Extent number
  818.     DB    0        ; S1
  819. SUBFS2:    DS    1        ; S2
  820. SUBFRC:    DS    1        ; Record count
  821.     DS    16        ; Disk group map
  822. SUBFCR:    DS    1        ; Current record number
  823.      ENDIF
  824. ;
  825. ; Command file control block
  826. ;
  827.      IF    EXTFCB
  828. FCBDN    EQU    FCBADR        ; Disk name
  829. FCBFN    EQU    FCBDN+1        ; File name
  830. FCBFT    EQU    FCBFN+8        ; File type
  831. FCBDM    EQU    FCBFT+7        ; Disk group map
  832. FCBCR    EQU    FCBDM+16    ; Current record number
  833.      ENDIF
  834. ;
  835.      IF    NOT EXTFCB
  836. FCBDN:    DS    1        ; Disk name
  837. FCBFN:    DS    8        ; File name
  838. FCBFT:    DS    3        ; File type
  839.     DS    1        ; Extent number
  840.     DS    2        ; S1 and S2
  841.     DS    1        ; Record count
  842. FCBDM:    DS    16        ; Disk group map
  843. FCBCR:    DS    1        ; Current record number
  844.      ENDIF
  845. ;
  846. ; Line count buffer
  847. ;
  848. PAGCNT:    DB    NLINES-2    ; Lines left on page
  849. ;
  850. ; CCP command name table - each table entry is composed of the four-byte
  851. ; command and two-byte address.
  852. ;
  853. CMDTBL:    CTABLE            ; Define command table via macro
  854. ;
  855. NCMNDS    EQU    ($-CMDTBL)/(NCHARS+2)
  856. ;
  857. ;-----
  858. ;
  859. ; **** Section 2 ****
  860. ;
  861. ; ZCMD2 starting points
  862. ;
  863. ; Now see if BYE is running
  864. ;
  865. CCP:    LXI    SP,STACK    ; Set the stack
  866.     PUSH    B
  867.     PUSH    D
  868.     MVI    A,CR
  869.     CALL    CONOUT        ; This is required to make BYE's BDCHEK
  870.     MVI    C,32        ; Reset locations 6 and 7 after warmboot
  871.     MVI    E,241
  872.     CALL    BDOS        ; Call BYE's BDOS
  873.     POP    D
  874.     POP    B
  875.     CPI    77        ; Running?
  876.     JRZ    CCP2        ; Yes, continue without setting defaults
  877. ;
  878.      IF    USRMAX
  879.     MVI    A,MAXUSR+1    ; Set USRMAX on cold boot
  880.     STA    USRMAX
  881.      ENDIF
  882. ;
  883.      IF    DRVMAX
  884.     MVI    A,MAXDISK-1    ; Set DRVMAX on cold boot
  885.     STA    DRVMAX
  886.      ENDIF
  887. ;
  888.      IF    USRMAX OR DRVMAX
  889.     MVI    A,0FFH
  890.     STA    WHLADR        ; Set WHEEL
  891.      ENDIF
  892. ;
  893.     JR    CCP2        ; On to coldboot routine
  894. ;
  895. ; Start ZCMD2 and don't process default command stored if multiple com-
  896. ; mands are not allowed.  This is the warmboot entry.
  897. ;
  898. CCP1:     IF    NOT MULTCMD
  899.     XRA    A        ; For no default command
  900.     STA    CMDLIN        ; First char of buffer
  901.      ENDIF
  902. ;
  903. ; Start ZCMD2 and possibly process default command
  904. ;
  905. ; NOTE: BDOS returns 0FFH in A-register whenever it logs in a directory,
  906. ; if any file name contains a '$' in it.  This is now used as a clue to
  907. ; determine whether or not to do a search for submit file, in order to
  908. ; eliminate wasteful searches.
  909. ;
  910. ; Process default command if present (this is the cold boot entry).
  911. ;
  912. CCP2:    LXI    SP,STACK    ; Reset stack
  913. ;
  914.      IF    NOT MULTCMD
  915.     LXI    H,CMDLIN    ; Set ptr to beginning of command line
  916.     SHLD    NXTCHR
  917.      ENDIF
  918. ;
  919.     PUSH    B
  920.     MOV    A,C        ; C=user/disk number (see loc 4)
  921.     RAR            ; Extract user number
  922.     RAR
  923.     RAR
  924.     RAR
  925.     ANI    0FH
  926.     STA    CURUSR        ; Set user
  927.     CALL    SETUSR
  928.     CALL    RESET        ; Reset disk system
  929. ;
  930.      IF    SUBON
  931.     STA    RNGSUB        ; Save submit clue from drive a:
  932.      ENDIF
  933. ;
  934.      IF    MAKESPR
  935. BIOS    EQU    0        ; So we don't get assembler errors <wm>
  936.     PUSH    H
  937.     LHLD    0000H+1        ; Get BIOS vector
  938.     LXI    B,3
  939.     DAD    B        ; Point to BIOS+6 (console status)
  940.     SHLD    BIOCAL2+1
  941.     DAD    B        ; Point to BIOS+9 (console input)
  942.     SHLD    BIOCAL1+1
  943.     SHLD    BIOCAL3+1
  944.     SHLD    BIOCAL4+1
  945.     POP    H        ; This was missing from v2.0  < wm >
  946.      ENDIF
  947. ;
  948.     POP    B
  949.     MOV    A,C        ; C=user/disk number (see loc 4)
  950.     ANI    0FH        ; Extract current disk drive
  951.     STA    CURDR        ; Set it
  952.     CALL    LOGIN        ; Log in default disk
  953.     CALL    SETUD        ; Set user/disk flag
  954.     CALL    DEFDMA        ; Set default dma address
  955. ;
  956.      IF    SUBON
  957.     LXI    D,SUBFCB    ; Check for $$$.sub on current disk
  958. ;
  959. RNGSUB    EQU    $+1        ; Pointer for in-the-code modification
  960.     MVI    A,0        ; 2nd byte (immediate arg)
  961.     ORA    A        ; Set flags on clue
  962.     CNZ    SEAR1
  963.     STA    RNGSUB        ; Set flag (0=no $$$.sub)
  964.      ENDIF
  965. ;
  966. ; Test for next command in continuous loop if multiple command line buf-
  967. ; fer is enabled.
  968. ;
  969.      IF    MULTCMD
  970. CONT:
  971.      ENDIF
  972. ;
  973.     LHLD    NXTCHR        ; Point to next character to process
  974.     MOV    A,M        ; Get it
  975.     CPI    3        ; Restart if CTL-C
  976.     JRZ    RESTRT
  977.     ORA    A        ; 0 if no command line present
  978.     JRNZ    RS1
  979. ;
  980. ; Test for any default command before continuous loop entered if mul-
  981. ; tiple command line buffer is disabled.
  982. ;
  983.      IF    NOT MULTCMD
  984. CONT:
  985.      ENDIF
  986. ;
  987. ; Ppompt user and input command line from him
  988. ;
  989. RESTRT:    LXI    SP,STACK    ; Reset stack
  990. ;
  991. ; The following code added to dynamically set INTPATH to extra search
  992. ; level if WHEEL is ON, and reset that level if Wheel is off.
  993. ;
  994.      IF    WHEEL AND INTPATH
  995.     LDA    WHLADR        ; Get wheel byte
  996.     ORA    A
  997.     MVI    A,0        ; Reset search path if off
  998.     JZ    $+5
  999.     MVI    A,SYSDRV    ; Set search drive if wheel on
  1000.     STA    WHLPTH        ; Into the search path
  1001.      ENDIF
  1002. ;
  1003. ; Print prompt: DU>
  1004. ;
  1005.     CALL    CRLF        ; Print prompt
  1006. ;
  1007.      IF    PRIVDIR        ; If private directories
  1008.     LDA    WHLADR        ; Don't print drive/user prompt
  1009.     ORA    A        ; If wheel not enabled
  1010.     JRZ    RS000
  1011.      ENDIF
  1012. ;
  1013.      IF    (BYCLOCK OR BYTLOS) AND (NOT CLOCK)
  1014.     MVI    C,32
  1015.     MVI    E,241
  1016.     CALL    BDOS
  1017.     CPI    77        ; Is NUBYE/BYE5 running?
  1018.     CZ    TIME        ; Yes, display time prompts
  1019.      ENDIF
  1020. ;
  1021.      IF    CLOCK AND (NOT BYCLOCK) AND (NOT BYTLOS)
  1022.     CKCLOK            ; Predefined macro for clock check 
  1023.      ENDIF
  1024. ;
  1025.      IF    BYCLOCK OR BYTLOS OR CLOCK
  1026.     LDA    CURUSR
  1027.     CALL    SETUSR        ; Fixes the submit function
  1028.      ENDIF
  1029. ;
  1030.     LDA    CURDR        ; Current drive is part of prompt
  1031.     ADI    'A'        ; Convert to ASCII A-P
  1032.     CALL    CONOUT
  1033.     LDA    CURUSR        ; Get user number
  1034. ;
  1035.      IF    SUPRES
  1036.     ORA    A
  1037.     JRZ    RS000
  1038.      ENDIF
  1039. ;
  1040.     CPI    10        ; User < 10?
  1041.     JRC    RS00
  1042.     SUI    10        ; Subtract 10 from it
  1043.     PUSH    PSW        ; Save it
  1044.     MVI    A,'1'        ; Output 10's digit
  1045.     CALL    CONOUT
  1046.     POP    PSW
  1047. ;
  1048. RS00:    ADI    '0'        ; Output 1's digit (convert to ASCII)
  1049.     CALL    CONOUT
  1050. ;
  1051. ; Read input line from user or $$$.SUB
  1052. ;
  1053. RS000:    LXI    H,CMDLIN    ; Set pointer to first character
  1054.     SHLD    NXTCHR        ; Pointer to next character to process
  1055.     MVI    M,0        ; Zero out command line
  1056.     PUSH    H        ; Save pointer
  1057.     CALL    REDBUF        ; Input command line from user
  1058.     POP    H        ; Get pointer
  1059.     MOV    A,M        ; Check for comment line
  1060.     CPI    COMMENT        ; Begins with comment character?
  1061.     JRZ    RESTRT        ; Input another line if so
  1062.     ORA    A        ; No input?
  1063.     JRZ    RESTRT
  1064. ;
  1065. ; Process input line - HL points to first letter of command
  1066. ;
  1067. RS1:    LXI    SP,STACK    ; Reset stack
  1068. ;
  1069.      IF    MULTCMD
  1070.     MOV    A,M        ; Get first char of command
  1071.     CPI    CMDSEP        ; Is it a command separator?
  1072.     JRNZ    RS2
  1073.     INX    H        ; Skip it if it is
  1074.     SHLD    NXTCHR        ; Set pointer back
  1075.      ENDIF
  1076. ;
  1077. ; Set pointer fro multiple command line processing to first character of
  1078. ; new command
  1079. ;
  1080. RS2:    SHLD    CMDCH1        ; Set pointer to first character
  1081. ;
  1082. ; Capitalize command line
  1083. ;
  1084. CAPBUF:    MOV    A,M        ; Capitalize command character
  1085.     CALL    UCASE
  1086.     MOV    M,A
  1087.     INX    H        ; Point to next character
  1088.     ORA    A        ; Eol?
  1089.     JRNZ    CAPBUF
  1090.     CALL    SCANER        ; Parse command name from command line
  1091.     JRNZ    ERROR        ; Error if command name contains a '?'
  1092.     LXI    D,RSTCCP    ; Put return address of command
  1093.     PUSH    D        ; On the stack
  1094. ;
  1095. COLON    EQU    $+1        ; Flag for in-the-code modification
  1096.     MVI    A,0        ; Command of the form 'DU:command'?
  1097.     ORA    A        ; 0=no
  1098.     JNZ    COM        ; Process as com file if not
  1099.     CALL    CMDSER        ; Scan for cpr-resident command
  1100.     JNZ    COM        ; Not cpr-resident
  1101.     MOV    A,M        ; Found it:  get low-order part
  1102.     INX    H        ; Get high-order part
  1103.     MOV    H,M        ; Store high
  1104.     MOV    L,A        ; Store low
  1105.     PCHL            ; Execute cpr routine
  1106. ;
  1107. ; Entry point for restarting CCP and logging in default drive
  1108. ;
  1109. RSTCCP:    CALL    DLOGIN        ; Log in current user/disk
  1110. ;
  1111. ; Entry point for restarting CCP without logging in default drive
  1112. ;
  1113. RCCPNL:    CALL    SCANER        ; Extract next token from command line
  1114.     LDA    FCBFN        ; Get first char of token
  1115.     CPI    ' '        ; Any char?
  1116.     JZ    CONT        ; Continue with next command if no error
  1117. ;
  1118. ; Invalie command - print it
  1119. ;
  1120. ERROR:    CALL    CRLF        ; New line
  1121. ;
  1122. CURTOK    EQU    $+1        ; Pointer for in-the-code modification
  1123.     LXI    H,0        ; Pt to beginning of command line
  1124. ;
  1125. ERR1:    MOV    A,M        ; Get character
  1126.     CPI    ' '+1        ; Simple '?' if <sp> or less
  1127.     JRC    ERR2
  1128.     CALL    CONOUT        ; Print command char
  1129.     INX    H        ; Pt to next char
  1130.     JR    ERR1        ; Continue
  1131. ;
  1132. ERR2:    CALL    PRINT        ; Show input error
  1133.     DB    ' <-- Erro','r'+80H
  1134. ;
  1135. ERR3:    CALL    DLOGIN        ; Panic restore of default user/disk
  1136. ;
  1137.      IF    SUBON
  1138.     CALL    SUBKIL        ; Terminate active $$$.SUB if any
  1139.      ENDIF
  1140. ;
  1141.     JMP    RESTRT        ; Restart CCP
  1142. ;
  1143. ; No File Error Message
  1144. ;
  1145. PRNNF:    CALL    PRINTC        ; No file message
  1146.     DB    'No Fil','e'+80H
  1147.     RET
  1148. ;
  1149. ;-----
  1150. ;
  1151. ; * Section 3 ****
  1152. ;
  1153. ; I/O utilities
  1154. ;
  1155. ; Output character in A-register to CRT and don't change 'BC'
  1156. ; Output <CRLF>
  1157. ;
  1158. CRLF:    MVI    A,CR
  1159.     CALL    CONOUT
  1160.     MVI    A,LF
  1161.     JR    CONOUT
  1162. ;
  1163. CONIN:    MVI    C,1        ; Input character
  1164.     CALL    BDOS        ; Get input character with ^S
  1165.     JMP    UCASE        ; Capitalize
  1166. ;
  1167. CONOUT:    PUSH    B
  1168.     PUSH    D
  1169.     PUSH    H
  1170.     MVI    C,2
  1171. ;
  1172.      IF    HBLST AND (NOT HBCON)
  1173.     ANI    7FH        ; Wipe out Hi bit for CON, not LST
  1174.      ENDIF
  1175. ;
  1176. OUTPUT:     IF    NOT (HBCON AND HBLST)
  1177.     ANI    7FH        ; Wipe out Hi bit for CON and LST
  1178.      ENDIF
  1179. ;
  1180.     MOV    E,A
  1181.     CALL    BDOS
  1182.     POP    H
  1183.     POP    D
  1184.     POP    B
  1185.     RET
  1186. ;
  1187. LCOUT:    PUSH    PSW        ; Output character to CRT
  1188. ;
  1189. PRFLG    EQU    $+1        ; Pointer for in-the-code modification
  1190.     MVI    A,0        ; 2nd byte (immediate argument)
  1191.     ORA    A        ; 0=type
  1192.     JRZ    LC1
  1193.     POP    PSW        ; Get character
  1194. ;
  1195. ; Output character in A-register to list device
  1196. ;
  1197. LSTOUT:    PUSH    B        ; Save regs
  1198.     PUSH    D
  1199.     PUSH    H
  1200.     MVI    C,5
  1201. ;
  1202.      IF    HBCON AND (NOT HBLST)
  1203.     ANI    7FH        ; Wipe out Hi bit for LST but not CON
  1204.      ENDIF
  1205. ;
  1206.     JR    OUTPUT
  1207. ;
  1208. LC1:    POP    PSW        ; Get character
  1209.     PUSH    PSW
  1210.     CALL    CONOUT        ; Output to CRT
  1211.     POP    PSW
  1212.     CPI    LF        ; Check for paging
  1213.     RNZ
  1214. ;
  1215. ; Paging routines - PAGER counts down lines and pauses for direct input
  1216. ; if count expires, PAGSET sets lines per page count.
  1217. ;
  1218. PAGER:    PUSH    H
  1219.     LXI    H,PAGCNT    ; Count down
  1220.     DCR    M
  1221.     JRNZ    PAGER1        ; Jump if not end of page
  1222.     MVI    M,NLINES-2    ; Refill counter
  1223. ;
  1224. PGFLG    EQU    $+1        ; Pointer to in-the-code buffer pgflg
  1225.     MVI    A,0        ; 0 may be changed by pgflg equate
  1226.     CPI    PGDFLG        ; Page default override option wanted?
  1227. ;
  1228.      IF    PGDFLT
  1229.     JRZ    PAGER1        ; PGDFLG means no paging, please
  1230.      ENDIF
  1231. ;
  1232.      IF    NOT PGDFLT
  1233.     JRNZ    PAGER1        ; Pgdflg means please paginate
  1234.      ENDIF
  1235. ;
  1236.     PUSH    B        ; Save registers
  1237. ;
  1238. BIOCAL1:CALL    BIOS+9        ; BIOS console input routine
  1239.     POP    B        ; Get register
  1240.     CPI    'C'-'@'        ; ^C
  1241.     JZ    RSTCCP        ; Restart CCP
  1242. ;
  1243. PAGER1:    POP    H        ; Restore HL
  1244.     RET
  1245. ;
  1246. ; Read file block function
  1247. ;
  1248. READF:    LXI    D,FCBDN        ; Fall through to read
  1249. ;
  1250. READ:    MVI    C,14H        ; Fall through to BDOSB
  1251. ;
  1252. ; Call BDOS and save 'BC'
  1253. ;
  1254. BDOSB:    PUSH    B
  1255.     CALL    BDOS
  1256.     POP    B
  1257.     ORA    A
  1258.     RET
  1259. ;
  1260. ; Print string (ending in character with MSB set) pointed to by return
  1261. ; address - start with <CRLF>
  1262. ;
  1263. PRINTC:    CALL    CRLF        ; New line
  1264. ;
  1265. PRINT:    XTHL            ; Get ptointer to string
  1266.     CALL    PRIN1        ; Print string
  1267.     XTHL            ; Restore HL and return address
  1268.     RET
  1269. ;
  1270. ; Print string (ending in 0 or byte with MSB set) pointed to by 'HL'
  1271. ;
  1272. PRIN1:    MOV    A,M        ; Get next byte
  1273.     INX    H        ; Point to next byte
  1274.     ORA    A        ; End of string?
  1275.     RZ            ; String terminated by binary 0
  1276.     PUSH    PSW        ; Save flags
  1277.     ANI    7FH        ; Mask out MSG
  1278.     CALL    CONOUT        ; Print character
  1279.     POP    PSW        ; Get flags
  1280.     RM            ; String terminated by MSB set
  1281.     JR    PRIN1
  1282. ;
  1283. ; BDOS function routines
  1284. ;
  1285. ; Return number of current disk in 'A'
  1286. ;
  1287. GETDRV:    MVI    C,19H
  1288.     JR    BDOSJP
  1289. ;
  1290. ; Set 80H as DMA address
  1291. ;
  1292. DEFDMA:    LXI    D,TBUFF        ; 80H=TBUFF
  1293. ;
  1294. DMASET:    MVI    C,1AH
  1295.     JR    BDOSJP
  1296. ;
  1297. RESET:    MVI    C,0DH
  1298. ;
  1299. BDOSJP:    JMP    BDOS
  1300. ;
  1301. LOGIN:    MOV    E,A
  1302.     MVI    C,0EH
  1303.     JR    BDOSJP        ; Save some code space
  1304. ;
  1305. OPENF:    XRA    A
  1306.     STA    FCBCR
  1307.     LXI    D,FCBDN        ; Fall thrrough to OPEN
  1308. ;
  1309. OPEN:    MVI    C,0FH        ; Fall through to GRBDOS
  1310. ;
  1311. GRBDOS:    CALL    BDOS
  1312.     INR    A        ; Set zero flag for error return
  1313.     RET
  1314. ;
  1315. CLOSE:    MVI    C,10H
  1316.     JR    GRBDOS
  1317. ;
  1318. SEARF:    LXI    D,FCBDN        ; Specify FCB
  1319. ;
  1320. SEAR1:    MVI    C,11H
  1321.     JR    GRBDOS
  1322. ;
  1323. SEARN:    MVI    C,12H
  1324.     JR    GRBDOS
  1325. ;
  1326. ; Check for submit file in execution and abort if so
  1327. ;
  1328.      IF    SUBON
  1329. SUBKIL:    LXI    H,RNGSUB    ; Check for submit file in execution
  1330.     MOV    A,M
  1331.     ORA    A        ; 0=no
  1332.     RZ
  1333.     MVI    M,0        ; Abort submit file
  1334.     LXI    D,SUBFCB    ; Delete $$$.SUB
  1335.      ENDIF
  1336. ;
  1337. DELETE:    MVI    C,13H
  1338.     JR    BDOSJP        ; Save more space
  1339. ;
  1340. ; Get/set user number
  1341. ;
  1342. GETUSR:    MVI    A,0FFH        ; Get current user number
  1343. ;
  1344. SETUSR:    MOV    E,A        ; User number in 'E'
  1345.     MVI    C,20H        ; Set user number to value in 'E'
  1346.     JR    BDOSJP        ; More space saving
  1347. ;
  1348. ; end of BDOS Functions
  1349. ;-----
  1350. ;
  1351. ; * Section 4 ****
  1352. ;
  1353. ; ZCMD2 utilities
  1354. ;
  1355. ; Set user/disk flag to current user and default disk
  1356. ;
  1357. SETUD:    CALL    GETUSR        ; Get number of current user
  1358.     ANI    0FH        ; Mask sure 4 bits
  1359.     ADD    A        ; Place it in high nybble
  1360.     ADD    A
  1361.     ADD    A
  1362.     ADD    A
  1363.     LXI    H,CURDR        ; Mask in current drive number
  1364.     ORA    M        ; Mask in
  1365.     STA    UDFLAG        ; Set user/disk number
  1366.     RET
  1367. ;
  1368. ; Convert character in 'A' to upper-case
  1369. ;
  1370. UCASE:    ANI    7FH        ; Mask out MSB
  1371.     CPI    61H        ; Lower-case 'A'
  1372.     RC
  1373.     CPI    7BH        ; Greater than lower-case Z?
  1374.     RNC
  1375.     ANI    5FH        ; Capitalize
  1376.     RET
  1377. ;
  1378. ; Input next command to CCP - This routine determines if a SUBMIT file
  1379. ; is being processed and extracts the command line from it if so or from
  1380. ;  the user's console
  1381. ;
  1382. REDBUF:     IF    SUBON
  1383.     LDA    RNGSUB        ; Submit file currently in execution?
  1384.     ORA    A        ; 0=no
  1385.     JRZ    RB1        ; Get line from console if not
  1386.     LXI    D,SUBFCB    ; Open $$$.SUB
  1387.     PUSH    D        ; Save DE
  1388.     CALL    OPEN
  1389.     POP    D        ; Restore DE
  1390.     JRZ    RB1        ; Erase $$$.SUB if end of file
  1391.     LDA    SUBFRC        ; Get value of last record in file
  1392.     DCR    A        ; Pt to next to last record
  1393.     STA    SUBFCR        ; New value of last record in $$$.SUB
  1394.     CALL    READ        ; DE=SUBFCB
  1395.     JRNZ    RB1        ; Abort $$$.SUB if error
  1396.     LXI    D,CHRCNT    ; Copy last record (next submit cmnd)
  1397.     LXI    H,TBUFF        ; From TBUFF
  1398.     LXI    B,BUFLEN    ; Number of bytes
  1399.     LDIR
  1400.     LXI    H,SUBFS2    ; Point to S2 of $$$.SUB FCB
  1401.     MVI    M,0        ; Set S2 to zero
  1402.     INX    H        ; Point to record count
  1403.     DCR    M        ; Decrement record count of $$$.SUB
  1404.     LXI    D,SUBFCB    ; Close $$$.SUB
  1405.     CALL    CLOSE
  1406.     JRZ    RB1        ; Abort $$$.SUB if error
  1407.     MVI    A,SPRMPT    ; Print submit prompt
  1408.     CALL    CONOUT
  1409.     LXI    H,CMDLIN    ; Print command line from $$$.SUB
  1410.     CALL    PRIN1
  1411.     CALL    BREAK        ; Check for abort (any char)
  1412.     RNZ            ; If no ^C, return to caller and run
  1413.     CALL    SUBKIL        ; Kill $$$.SUB if abort
  1414.     JMP    RESTRT        ; Restart CCP
  1415. ;
  1416. ; Input command line from user console
  1417. ;
  1418. RB1:    CALL    SUBKIL        ; Erase $$$.sub if present
  1419.      ENDIF
  1420. ;
  1421.     MVI    A,':'
  1422.     CALL    CONOUT
  1423. ;
  1424.      IF    WHEEL
  1425.     LDA    WHLADR
  1426.     ORA    A        ; WHEEL on?
  1427.      ENDIF
  1428. ;
  1429.     MVI    A,NPROMPT    ; Normal prompt
  1430. ;
  1431.      IF    WHEEL
  1432.     JRZ    RB2        ; No, show normal prompt
  1433.     MVI    A,WPROMPT    ; ...else, show WHEEL prompt
  1434.      ENDIF
  1435. ;
  1436. RB2:    CALL    CONOUT
  1437.     MVI    C,0AH        ; Read command line from user
  1438.     LXI    D,BUFSIZ
  1439.     CALL    BDOS
  1440. ;
  1441. ; Store zero at end of command line
  1442. ;
  1443.     LXI    H,CHRCNT    ; Point to character count
  1444.     MOV    A,M        ; Get character count
  1445.     INX    H        ; Pt to first character of command line
  1446.     CALL    ADDAH        ; Pt to after last char of command line
  1447.     MVI    M,0        ; Store ending zero
  1448.     RET
  1449. ;
  1450. ; Check for any character from user console, return with zero set if
  1451. ; none.
  1452. ;
  1453. BREAK:    PUSH    B        ; Save registers
  1454.     PUSH    D
  1455.     PUSH    H
  1456. ;
  1457. BIOCAL2:CALL    BIOS+6        ; Console status check
  1458.     ORA    A        ; Set flags
  1459. ;
  1460. BIOCAL3:CNZ    BIOS+9        ; Get input char with ^s processing
  1461.     CPI    'S'-'@'        ; Pause if ^S
  1462. ;
  1463. BIOCAL4:CZ    BIOS+9        ; Get next character
  1464.     POP    H        ; Restore registers
  1465.     POP    D
  1466.     POP    B
  1467.     CPI    'C'-'@'        ; Check for abort
  1468.     RET
  1469. ;
  1470. ; Check to see if DE points to delimiter, if so return with zero flag
  1471. ; set.
  1472. ;
  1473. SDELM:    LDAX    D
  1474.     ORA    A        ; 0=delimiter
  1475.     RZ
  1476.     CPI    ' '+1        ; Delim if <= <SP>
  1477.     JRC    ZERO
  1478.     CPI    '='        ; '='=delimiter
  1479.     RZ
  1480.     CPI    5FH        ; Underscore=delimiter
  1481.     RZ
  1482.     CPI    '.'        ; '.'=delimiter
  1483.     RZ
  1484.     CPI    ':'        ; ':'=delimiter
  1485.     RZ
  1486.     CPI    ','        ; ','=delimiter
  1487.     RZ
  1488.     CPI    ';'        ; ';'=delimiter
  1489.     RZ
  1490.     CPI    '<'        ; '<'=delimiter
  1491.     RZ
  1492.     CPI    '>'        ; '>'=delimiter
  1493. ;
  1494.      IF    MULTCMD
  1495.     RZ
  1496.     CPI    CMDSEP        ; Command separator
  1497.      ENDIF
  1498. ;
  1499.     RET
  1500. ;
  1501. ZERO:    XRA    A        ; Set zero flag
  1502.     RET
  1503. ;
  1504. ; Advance input pointer to first non-blank and fall through to SBLANK
  1505. ;
  1506. ADVAN:    LDED    NXTCHR        ; Point to next character
  1507. ;
  1508. ; Skip string pointed to by DE (string ends in 0 OR CMDSEP) until end of
  1509. ; string or non-delimited encounterd (beginning of token).
  1510. ;
  1511. SBLANK:    LDAX    D        ; Get character
  1512.     ORA    A        ; Zero?
  1513.     RZ
  1514. ;
  1515.      IF    MULTCMD
  1516.     CPI    CMDSEP        ; Command separator?
  1517.     RZ
  1518.      ENDIF
  1519. ;
  1520.     CALL    SDELM        ; Skip over delimiter
  1521.     RNZ
  1522.     INX    D        ; Advance to next char
  1523.     JR    SBLANK
  1524. ;
  1525. ; Add A ro HL (HL=HL+A)
  1526. ;
  1527. ADDAH:    ADD    L
  1528.     MOV    L,A
  1529.     RNC
  1530.     INR    H
  1531.     RET
  1532. ;
  1533. ; Extract decimal number from command line - return with value in A-reg.
  1534. ; All registers may be affected.
  1535. ;
  1536. NUMBER:    CALL    SCANER        ; Parse number and place in fcbfn
  1537.     LXI    H,FCBFN+10    ; Pt to end of token for conversion
  1538.     MVI    B,11        ; 11 characters maximum
  1539. ;
  1540. ; Check for suffix for hexadecimal number
  1541. ;
  1542. NUMS:    MOV    A,M        ; Get character from end
  1543.     DCX    H        ; Back up
  1544.     CPI    ' '        ; Space?
  1545.     JRNZ    NUMS1        ; Check for suffix
  1546.     DJNZ    NUMS        ; Count down
  1547.     JR    NUM0        ; By default, process
  1548. ;
  1549. NUMS1:    CPI    NUMBASE        ; Check against base switch flag
  1550.     JRZ    HNUM0
  1551. ;
  1552. ; Process decimal number
  1553. ;
  1554. NUM0:    LXI    H,FCBFN        ; Point to beginning of token
  1555. ;
  1556. NUM0A:    LXI    B,1100H        ; C=accumulated value, b=char count
  1557. ;                ; (c=0, b=11)
  1558. NUM1:    MOV    A,M        ; Get character
  1559.     CPI    ' '        ; Done if <SP>
  1560.     JRZ    NUM2
  1561.     CPI    ':'        ; Done if colon
  1562.     JRZ    NUM2
  1563.     INX    H        ; Pt to next char
  1564.     SUI    '0'        ; Convert to binary
  1565.     CPI    10        ; Error if >= 10
  1566.     JRNC    NUMERR
  1567.     MOV    D,A        ; Digit in d
  1568.     MOV    A,C        ; New value = old value * 10
  1569.     RLC            ; *2
  1570.     JRC    NUMERR
  1571.     RLC            ; *4
  1572.     JRC    NUMERR
  1573.     RLC            ; *8
  1574.     JRC    NUMERR
  1575.     ADD    C        ; *9
  1576.     JRC    NUMERR
  1577.     ADD    C        ; *10
  1578.     JRC    NUMERR
  1579.     ADD    D        ; New value = old value * 10 + digit
  1580.     JRC    NUMERR        ; Check for range error
  1581.     MOV    C,A        ; Set new value
  1582.     DJNZ    NUM1        ; Count down
  1583. ;
  1584. ; Return from number
  1585. ;
  1586. NUM2:    MOV    A,C        ; Get accumulated value
  1587.     RET
  1588. ;
  1589. ; Number error routine for space conservation
  1590. ;
  1591. NUMERR:    JMP    ERROR        ; Use error routine
  1592. ;
  1593. ; Extract hexadecimal number from command line - return with value in
  1594. ; A-reg, all registers may be affected.
  1595. ;
  1596. HEXNUM:    CALL    SCANER        ; Parse number and place in FCBFN
  1597. ;
  1598. HNUM0:    LXI    H,FCBFN        ; Point to token for conversion
  1599.     LXI    D,0        ; De=accumulated value
  1600.     MVI    B,11        ; B=character
  1601. ;
  1602. HNUM1:    MOV    A,M        ; Get character
  1603.     CPI    ' '        ; Done?
  1604.     JRZ    HNUM3        ; Return if so
  1605.     CPI    NUMBASE        ; Done if numbase suffix
  1606.     JRZ    HNUM3
  1607.     SUI    '0'        ; Convert to binary
  1608.     JRC    NUMERR        ; Return and done if error
  1609.     CPI    10        ; 0-9?
  1610.     JRC    HNUM2
  1611.     SUI    7        ; A-F?
  1612.     CPI    10H        ; Error?
  1613.     JRNC    NUMERR
  1614. ;
  1615. HNUM2:    INX    H        ; Point to next characer
  1616.     MOV    C,A        ; Digit in 'C'
  1617.     MOV    A,D        ; Get accumulated value
  1618.     RLC            ; Exchange nybbles
  1619.     RLC
  1620.     RLC
  1621.     RLC
  1622.     ANI    0F0H        ; Mask out low nybble
  1623.     MOV    D,A
  1624.     MOV    A,E        ; Switch low-order nybbles
  1625.     RLC
  1626.     RLC
  1627.     RLC
  1628.     RLC
  1629.     MOV    E,A        ; High nybble of e=new high of e
  1630.     ANI    0FH        ; Get new low of d
  1631.     ORA    D        ; Mask in high of d
  1632.     MOV    D,A        ; New high byte in d
  1633.     MOV    A,E
  1634.     ANI    0F0H        ; Mask out low of e
  1635.     ORA    C        ; Mask in new low
  1636.     MOV    E,A        ; New low byte in e
  1637.     DJNZ    HNUM1        ; Count down
  1638. ;
  1639. ; Return from HEXNUM
  1640. ;
  1641. HNUM3:    XCHG            ; Returned value in hl
  1642.     MOV    A,L        ; Low-order byte in a
  1643.     RET
  1644. ;
  1645. ; point to directory entry in TBUFF whose offset is specified by A and C
  1646. ;
  1647. DIRPTR:    LXI    H,TBUFF        ; Point to temporary buffer
  1648.     ADD    C        ; Point to 1st byte of directory entry
  1649.     CALL    ADDAH        ; Point to desired byte in dir entry
  1650.     MOV    A,M        ; Get desired byte
  1651.     RET
  1652. ;
  1653. ; Check for specified drive and log it in
  1654. ;
  1655. SLOGIN:    XRA    A        ; A=0 for default disk
  1656.     STA    FCBDN        ; Select default disk since user/disk
  1657. ;
  1658. TEMPDR    EQU    $+1        ; Pointer for in-the-code modification
  1659.     MVI    A,0        ; 2nd byte (immediate arg) is tempdr
  1660.     ORA    A        ; 0=current drive
  1661.     JRNZ    SLOG1
  1662.     LDA    CURDR        ; Log in current drive
  1663.     INR    A        ; Add 1 for next dcr
  1664. ;
  1665. SLOG1:    DCR    A        ; Adjust for proper disk number (a=0)
  1666.     CALL    LOGIN        ; Log in new drive
  1667. ;
  1668. TEMPUSR    EQU    $+1        ; Pointer for in-the-code modification
  1669.     MVI    A,0        ; 2nd byte is user to be selected
  1670.     JMP    SETUSR        ; Log in new user
  1671. ;
  1672. ; Check for specified drive and log in default drive
  1673. ;
  1674. DLOGIN:    DS    0
  1675. ;
  1676. CURDR    EQU    $+1        ; Pointer for in-the-code modification
  1677.     MVI    A,0        ; Prep to log in current drive
  1678.     CALL    LOGIN        ; Login current drive
  1679. ;
  1680. CURUSR    EQU    $+1        ; Pointer for in-the-code modification
  1681.     MVI    A,0        ; Prep to log in current user number
  1682.     JMP    SETUSR        ; Log in new user
  1683. ;
  1684. ; Routine to check for a wheel byte as non-zero, if wheel byte is zero,
  1685. ; then abort (pop stack and return).
  1686. ;
  1687.      IF    WHEEL
  1688. WHLCHK:    LDA    WHLADR        ; Get wheel byte
  1689.     ORA    A        ; Zero?
  1690.     RNZ            ; Ok if not
  1691.     JMP    ERROR        ; Process as error
  1692.      ENDIF
  1693. ;
  1694. ; Extract token from command line and place it into FCBDN, format FCBDN
  1695. ; FCB if token resembles file name and type (filename.typ).  On input,
  1696. ; MXTCHR points to character at which to start scan.  On output, NXTCHR
  1697. ; points to character at which to continue and zero flag is reset if
  1698. ; if '?' is in token
  1699. ;
  1700. ; Entry points:
  1701. ;    SCANLOG - load token into first FCB and log in temp user/disk
  1702. ;    SCANER    - load token into first FCB
  1703. ;    SCANX    - load token into FCB pointed to by 'HL'
  1704. ;
  1705. SCANLOG:CALL    SCANER        ; Do scan
  1706.     PUSH    PSW        ; Save flag
  1707.     CALL    SLOGIN        ; Log in temporary user/disk
  1708.     POP    PSW        ; Get flag
  1709.     RET
  1710. ;
  1711. SCANER:    LXI    H,FCBDN        ; Point to FCBDN
  1712. ;
  1713. SCANX:    XRA    A        ; A=0
  1714.     STA    TEMPDR        ; Set temporary drive number to default
  1715.     MOV    M,A        ; Set first byte of FCBDN
  1716.     STA    COLON        ; Set no colon flag
  1717.     LDA    CURUSR        ; Get current user
  1718.     STA    TEMPUSR        ; Set tempusr
  1719.     CALL    ADVAN        ; Skip to non-blank or end of line
  1720.     SDED    CURTOK        ; Set ptr to non-blank or end of line
  1721.     MVI    B,11        ; Prep for possible space fill
  1722.     JRZ    SCAN4        ; Done if eol
  1723. ;
  1724. ; Scan token for DU: form, which means we have a user/disk specification
  1725. ; DE points to next character in line, HL points ro FCBDN.
  1726. ;
  1727.     PUSH    D        ; Save pointer to first character
  1728.     CALL    SDELM        ; Check for delimiter and get first char
  1729.     CPI    'A'        ; In letter range?
  1730.     JRC    SCAN1
  1731.     CPI    'P'+1        ; In letter range?
  1732.     JRC    SCAN1A
  1733. ;
  1734. SCAN1:    CPI    '0'        ; Check for digit range
  1735.     JRC    SCAN2
  1736.     CPI    '9'+1        ; In digit range?
  1737.     JRNC    SCAN2
  1738. ;
  1739. SCAN1A:    INX    D        ; Pt to next char
  1740.     CALL    SDELM        ; Check for delimiter, else digit
  1741.     JR    SCAN1
  1742. ;
  1743. SCAN2:    POP    D        ; Restore ptr to first char
  1744.     CPI    ':'        ; Was delimiter a colon?
  1745.     JRNZ    SCAN3        ; Done if no colon
  1746.     STA    COLON        ; Set colon found
  1747. ;
  1748.      IF    PRIVDIR
  1749.     CALL    WHLCHK        ; Mod by PST to not allow ':' in FCB
  1750.      ENDIF
  1751. ;
  1752. ; Scan for and extract user/disk info - on entry, HL point to FCBDN, DE
  1753. ; points to first character and A-register contains the first character.
  1754. ;
  1755.     LDAX    D        ; Get first character
  1756.     CPI    'A'        ; Convert possible drive spec to number
  1757.     JRC    SUD1        ; If less than 'a', must be digit
  1758. ;
  1759. ; Set disk number (A=1)
  1760. ;
  1761.     SUI    'A'-1
  1762. ;
  1763.      IF    DRVMAX
  1764.     PUSH    B        ; Save 'BC'
  1765.     PUSH    PSW        ; Save drive request
  1766.     LDA    DRVMAX        ; Get maximum legal drive
  1767.     ADI    2        ; Bump it two for the compare
  1768.     MOV    B,A        ; Save maximum drive in 'B'
  1769.     POP    PSW        ; Restore drive request
  1770.     CMP    B        ; See if illegal drive
  1771.     POP    B        ; Restore bc
  1772.      ENDIF
  1773. ;
  1774.      IF    NOT DRVMAX
  1775.     CPI    MAXDISK+1    ; Within range?
  1776.      ENDIF
  1777. ;
  1778.     JNC    ERROR        ; Invalid disk number
  1779.     STA    TEMPDR        ; Set temporary drive number
  1780.     MOV    M,A        ; Set fcbdn
  1781.     INX    D        ; Pt to next char
  1782.     LDAX    D        ; See if it is a colon (:)
  1783.     CPI    ':'
  1784.     JRZ    SUD2        ; Done if no user number (it is a colon)
  1785. ;
  1786. ; Set user number
  1787. ;
  1788. SUD1:    PUSH    H        ; Save pointer to FCBDN
  1789.     XCHG            ; Hl pts to first digit
  1790.     CALL    NUM0A        ; Get number
  1791.     XCHG            ; De pts to terminating colon
  1792. ;
  1793.      IF    USRMAX
  1794.     LXI    H,USRMAX
  1795.     CMP    M
  1796.      ENDIF
  1797. ;
  1798.      IF    NOT USRMAX
  1799.     CPI    MAXUSR+1    ; Within limit?
  1800.      ENDIF
  1801. ;
  1802.     POP    H        ; Get pointer to FCBDN
  1803.     JNC    ERROR
  1804. ;
  1805.      IF    USERON
  1806.     STA    TEMPUSR        ; Save user number
  1807.      ENDIF
  1808. ;
  1809. SUD2:    INX    D        ; Point to character after colon
  1810. ;
  1811. ; Extract filename from possible FILENAME.TYP - DE points to next char-
  1812. ; acter to process, HL points tao FCBDN.
  1813. ;
  1814. SCAN3:    XRA    A        ; A=0
  1815.     STA    QMCNT        ; Init question mark count
  1816.     MVI    B,8        ; Max of 8 chars in file name
  1817.     CALL    SCANF        ; Fill FCB file name
  1818. ;
  1819. ; Extract file type from possible FILENAME.TYP
  1820. ;
  1821.     MVI    B,3        ; Prepare to extract type
  1822.     LDAX    D        ; Get last char which stopped scan
  1823.     CPI    '.'        ; Have a type if de) delimiter is a '.'
  1824.     JRNZ    SCAN4        ; Fill file type bytes with <sp>
  1825.     INX    D        ; Pt to char in command line after '.'
  1826.     CALL    SCANF        ; Fill fcb file type
  1827.     JR    SCAN5        ; Skip to next processing
  1828. ;
  1829. SCAN4:    CALL    SCANF4        ; Space fill
  1830. ;
  1831. ; Fill in EX, S1, S2, and RC with zeroes
  1832. ;
  1833. SCAN5:    MVI    B,4        ; 4 bytes
  1834.     XRA    A        ; A=0
  1835.     CALL    SCANF5        ; Fill with zeroes
  1836. ;
  1837. ; Scan complete -- DE points to delimiter byte after token
  1838. ;
  1839.     SDED    NXTCHR
  1840. ;
  1841. ; Set zero flag to indicate presence of '?' in FILENAME.TYPE
  1842. ;
  1843. QMCNT    EQU    $+1        ; Pointer for in-the-code modification
  1844.     MVI    A,0        ; Number of question marks
  1845.     ORA    A        ; Set zero flag to indicate any '?'
  1846.     RET
  1847. ;
  1848. ; Scan token pointed to by DE for a max of B bytes; place it into file
  1849. ; name field pointed to by HL; expand and interpret wild cards of '*'
  1850. ; '?'; on exit, DE points to terminating delimiter.
  1851. ;
  1852. SCANF:    CALL    SDELM        ; Done if delimiter encountered
  1853.     JRZ    SCANF4
  1854.     INX    H        ; Point to next byte in FCBDN
  1855.     CPI    '*'        ; Is (DE) a wild card?
  1856.     JRNZ    SCANF1        ; Continue if not
  1857.     MVI    M,'?'        ; Place '?' in FCB
  1858.     CALL    SCQ        ; Scanner count question marks
  1859.     JR    SCANF2
  1860. ;
  1861. SCANF1:    MOV    M,A        ; Store filename char in fcb
  1862.     INX    D        ; Pt to next char in command line
  1863.     CPI    '?'        ; Check for question mark (wild)
  1864.     CZ    SCQ        ; Scanner count question marks
  1865. ;
  1866. SCANF2:    DJNZ    SCANF        ; Decrement char count until 8 elapsed
  1867. ;
  1868. SCANF3:    CALL    SDELM        ; 8 chars or more - skip until delimiter
  1869.     RZ            ; Zero flag set if delimiter found
  1870.     INX    D        ; Pt to next char in command line
  1871.     JR    SCANF3
  1872. ;
  1873. ; Fill memory pointed to by HL with spaces for B bytes
  1874. ;
  1875. SCANF4:    MVI    A,' '        ; Fill with spaces
  1876. ;
  1877. SCANF5:    INX    H        ; Point to next byte in FCB
  1878.     MOV    M,A        ; Fill with byte in A-reg.
  1879.     DJNZ    SCANF5
  1880.     RET
  1881. ;
  1882. ; Increment question mark count for scanner - this routine increments
  1883. ; the count of the number of question marks in the current FCB entry.
  1884. ;
  1885. SCQ:    PUSH    H        ; Save HL
  1886.     LXI    H,QMCNT        ; Get count
  1887.     INR    M        ; Increment
  1888.     POP    H        ; Get HL
  1889.     RET
  1890. ;
  1891. ; CMDTBL (command table) scanner
  1892. ;   On return, HL points to address of command if CCP-resident
  1893. ;   On return, zero flag set means CCP-resident command
  1894. ;
  1895. CMDSER:    LXI    H,CMDTBL    ; Point to command table
  1896.     MVI    C,NCMNDS    ; Set command counter
  1897.     MOV    A,C        ; Check number of commands
  1898.     ORA    A        ; If none, then abort
  1899.     JRZ    CMS5
  1900. ;
  1901. CMS1:    LXI    D,FCBFN        ; Point to stored command name
  1902.     MVI    B,NCHARS    ; Number of chars/command (8 max)
  1903. ;
  1904. CMS2:    LDAX    D        ; Compare against table entry
  1905.     CMP    M
  1906.     JRNZ    CMS3        ; No match
  1907.     INX    D        ; Point to next character
  1908.     INX    H
  1909.     DJNZ    CMS2        ; Count down
  1910.     LDAX    D        ; Next char must be a space
  1911.     CPI    ' '
  1912.     JRNZ    CMS4
  1913.     RET            ; Command is CCP-resident
  1914. ;
  1915. CMS3:    INX    H        ; Skip to next command table entry
  1916.     DJNZ    CMS3
  1917. ;
  1918. CMS4:    INX    H        ; Skip address
  1919.     INX    H
  1920.     DCR    C        ; Decrement table entry number
  1921.     JRNZ    CMS1
  1922. ;
  1923. CMS5:    INR    C        ; Clear zero flag
  1924.     RET            ; Command is disk-resident
  1925. ;
  1926. ;-----
  1927. ;
  1928. ; **** section 5 ****
  1929. ;
  1930. ; CCP-resident commands
  1931. ;
  1932. ; Section:  5A
  1933. ; Command:  DIR
  1934. ; Function: To display a directory of the files on disk
  1935. ; Forms:
  1936. ;    DIR <AFN>    displays the DIR files
  1937. ;    DIR <AFN> s    displays the SYS files
  1938. ;    DIR <AFN> a    display both DIR and SYS files
  1939. ;
  1940. ;   NOTES:
  1941. ;    the flag SYSFLG defines the letter used to display both DIR and
  1942. ;        SYS files (A in the above forms section)
  1943. ;    the flag SOFLG defines the letter used to display only the SYS
  1944. ;        files (S in the above forms section)
  1945. ;    the flag WIDE determines if the file names are spaced further
  1946. ;        apart (wide=yes) for 80-col screens
  1947. ;    the flag FENCE defines the character used to separate the file
  1948. ;        names
  1949. ;
  1950.      IF    DIRON        ; Dir enabled
  1951. DIR:    CALL    SCANLOG        ; Extract possible D:FILENAME.TYP token
  1952.     LXI    H,FCBFN        ; Make FCB wild (all '?') if no NAME.TYP
  1953.     MOV    A,M        ; Get first chararacter of NAME.TYPE
  1954.     CPI    ' '        ; If space, all wild
  1955.     CZ    FILLQ
  1956.     CALL    ADVAN        ; Look at next input char
  1957.     MVI    B,80H        ; Prepare for dir-only selection
  1958.     JRZ    DIRDN        ; There is no flag, so dir only
  1959.     MVI    B,1        ; Set for both dir and sys files
  1960.     CPI    SYSFLG        ; System and dir flag specifier?
  1961.     JRZ    GOTFLG        ; Got system specifier
  1962.     CPI    SOFLG        ; Sys only?
  1963.     JRNZ    DIRDN
  1964.     DCR    B        ; B=0 for sys files only
  1965. ;
  1966. GOTFLG:    INX    D        ; Pt to char after flag
  1967. ;
  1968. DIRDN:    SDED    NXTCHR        ; Set pointer for next pass then drop
  1969.                 ;   DIRRPR to print directory and go
  1970.                 ;   restart CCP
  1971.      ENDIF
  1972. ;
  1973. ; Directory print routine; on entry, B- reg is set as follows:
  1974. ;    0 for only system files, 80H for only DIR files, 1 for both
  1975. ;
  1976.      IF    DIRON OR ERAON
  1977. DIRPR:    MOV    A,B        ; Get flag
  1978.     STA    SYSTST        ; Set system test flag
  1979.     MVI    E,0        ; Set column counter to zero
  1980.     PUSH    D        ; Save column counter (e)
  1981.     CALL    SEARF        ; Search for specified file
  1982.     JRNZ    DIR3
  1983.     CALL    PRNNF        ; Print no file msg; reg a not changed
  1984.     XRA    A        ; Set zero flag
  1985.     POP    D        ; Restore de
  1986.     RET
  1987. ;
  1988. ; Entry selection loop; on entry, A=offset from SEARF or SEARN
  1989. ;
  1990. DIR3:    CALL    GETSBIT        ; Get and test for type of files
  1991.     JRZ    DIR6
  1992.     POP    D        ; Get entry count (=<CR> counter)
  1993.     MOV    A,E        ; Add 1 to it
  1994.     INR    E
  1995.     PUSH    D        ; Save it
  1996.     ANI    03H        ; Output <CRLF> if 4 entries printed
  1997.     JRNZ    DIR4
  1998.     CALL    CRLF        ; New line
  1999.     JR    DIR5
  2000. ;
  2001. DIR4:    CALL    PRINT
  2002. ;
  2003.      IF    WIDE
  2004.     DB    '  '        ; 2 spaces
  2005.     DB    FENCE        ; Then fence char
  2006.     DB    ' ',' '+80H    ; Then 2 more spaces
  2007.      ENDIF
  2008. ;
  2009.      IF    NOT WIDE
  2010.     DB    ' '        ; Space
  2011.     DB    FENCE        ; Then fence char
  2012.     DB    ' '+80H        ; Then space
  2013.      ENDIF
  2014. ;
  2015. DIR5:    MVI    B,01H        ; Pt to 1st byte of file name
  2016.     MOV    A,B        ; A=offset
  2017.     CALL    DIRPTR        ; Hl now pts to 1st byte of file name
  2018.     CALL    PRFN        ; Print file name
  2019. ;
  2020. DIR6:    CALL    BREAK        ; Check for abort
  2021.     JRZ    DIR7
  2022.     CALL    SEARN        ; Search for next file
  2023.     JRNZ    DIR3        ; Continue if file found
  2024. ;
  2025. DIR7:    POP    D        ; Restore stack
  2026.     MVI    A,0FFH        ; Set nz flag
  2027.     ORA    A
  2028.     RET
  2029.      ENDIF
  2030. ;
  2031. ; Print file name pointed to by HL
  2032. ;
  2033. PRFN:    MVI    B,8        ; 8 chars
  2034.     CALL    PRFN1
  2035.     MVI    A,'.'        ; Dot
  2036.     CALL    CONOUT
  2037.     MVI    B,3        ; 3 chars
  2038. ;
  2039. PRFN1:    MOV    A,M        ; Get char
  2040.     INX    H        ; Pt to next
  2041.     CALL    CONOUT        ; Print char
  2042.     DCR    B        ; Count down
  2043.     JRNZ    PRFN1
  2044.     RET
  2045. ;
  2046. ; After a search, return NZ set if desired type of file found, Z if not.
  2047. ; This algorithm looks at the system bit of the located file.  This bit
  2048. ; is set to 1 if the file is a system file and 0 if not a system file.
  2049. ; The following exclusive or masks are applied to return Z or NZ as re-
  2050. ; quired by the calling program:
  2051. ;
  2052. ;   System byte: x 0 0 0  0 0 0 0    after 80H mask, x=1 if SYS
  2053. ;
  2054. ;   SYS-only   : 0 0 0 0  0 0 0 0    XOR 0   = 0 if X=0   (or 80H if X=1)
  2055. ;   DIR-only   : 1 0 0 0  0 0 0 0    XOR 80H = 80H if X=0 (or 0 if X=1)
  2056. ;    both   : 0 0 0 0  0 0 0 1    XOR 1   = 81H or 1H  (or NZ for both)
  2057. ;
  2058. GETSBIT:DCR    A        ; Adjust to returned value
  2059.     RRC            ; Convert number to offset into tbuff
  2060.     RRC
  2061.     RRC
  2062.     ANI    60H
  2063.     MOV    C,A        ; Offset into TBUFF in c
  2064.     MVI    A,10        ; Add 10 to point to SYS file attribute
  2065.     CALL    DIRPTR        ; A=system byte
  2066.     ANI    80H        ; Look at only system bit
  2067. ;
  2068. SYSTST    EQU    $+1        ; In-the-code variable
  2069.     XRI    0        ; If SYSTST=0, sys only; if =80h, DIR
  2070.     RET            ; NZ if ok, Z if not ok
  2071. ;
  2072. ; Fill FCB @HL with '?'
  2073. ;
  2074. FILLQ:    MVI    B,11        ; Number of characters in FN & FT
  2075. ;
  2076. FQLP:    MVI    M,'?'        ; Store '?'
  2077.     INX    H
  2078.     DJNZ    FQLP
  2079.     RET
  2080. ;
  2081. ; Section:  5B
  2082. ; Command:  ERA
  2083. ; Function: Erase files
  2084. ; Forms:
  2085. ;    ERA <AFN>    erase specified files and print their names
  2086. ;    ERA <AFN> V    erase specified files and print their names,
  2087. ;              but ask for verification before erase is done
  2088. ;   NOTES::
  2089. ;    Several key flags affect this command:
  2090. ;        ERAV  - if yes, the V- option is enabled, and the char-
  2091. ;              acter which turns it on (the V) is defined by
  2092. ;              ERDFLG.
  2093. ;        ERACK - if yes, the ok? prompt is enabled
  2094. ;              If ERAO is NO, the verification feature is
  2095. ;                disabled regardless of what value ERAV has
  2096. ;              If ERAOK is yes, then:
  2097. ;                If ERAV is yes, verification is request-
  2098. ;                  ed only if the V-flag (actual letter
  2099. ;                  defined by ERDFLG) is in the cmd line
  2100. ;                If ERAV is NO, verification is always
  2101. ;                   requested, and a V-flag in the com-
  2102. ;                   mand line will cause an error message
  2103. ;                   to be printed (v?) after the ERA is
  2104. ;                   completed.
  2105. ;
  2106.      IF    ERAON
  2107. ERA:     IF    WERA
  2108.     CALL    WHLCHK        ; Check for it
  2109.      ENDIF
  2110. ;
  2111.     CALL    SCANLOG        ; Parse file specification
  2112. ;
  2113.      IF    ERAV AND ERAOK
  2114.     CALL    ADVAN        ; Get ERAFLG if it's there
  2115.     STA    ERAFLG        ; Save it as a flag
  2116.     JRZ    ERA1        ; Jump if input ended
  2117.     INX    D        ; Put new buffer pointer
  2118. ;
  2119. ERA1:    XCHG            ; Put pointer into HL
  2120.     SHLD    NXTCHR        ; Set pointer to byte for next command
  2121.      ENDIF
  2122. ;
  2123.     MVI    B,1        ; Display all matching files
  2124.     CALL    DIRPR        ; Print directory of erased files
  2125.     RZ            ; Abort if no files
  2126. ;
  2127.      IF    ERAOK
  2128.      IF    ERAV
  2129. ERAFLG    EQU    $+1        ; Address of flag
  2130.     MVI    A,0        ; 2nd byte is flag
  2131.     CPI    ERDFLG        ; Is it a verify option?
  2132.     JRNZ    ERA2        ; Skip prompt if it is not
  2133.      ENDIF
  2134. ;
  2135.     CALL    PRINTC
  2136.     DB    'OK to Erase','?'+80H
  2137.     CALL    CONIN        ; Get reply
  2138.     CPI    'Y'        ; Yes?
  2139.     RNZ            ; Abort if not
  2140.      ENDIF
  2141. ;
  2142. ERA2:    LXI    D,FCBDN        ; Delete file specified
  2143.     CALL    DELETE
  2144.     RET            ; Reenter cpr
  2145.      ENDIF
  2146. ;
  2147. ; Section:  5C
  2148. ; Command:  LIST
  2149. ; Function: Print out specified file on the lst device
  2150. ; Fforms:
  2151. ;    LIST <UFN>    print file (no paging)
  2152. ;
  2153. ; NOTES: The flags which apply to type do not take effect with list
  2154. ;
  2155.      IF    LTON
  2156. LIST:    MVI    A,0FFH        ; Turn on printer flag
  2157.     JR    TYPE0
  2158. ;
  2159. ; Section:  5D
  2160. ; Command:  TYPE
  2161. ; Function: Print out specified file on the con: device
  2162. ; Forms:
  2163. ;    TYPE <UFN>    print file
  2164. ;    TYPE <UFN> P    print file with paging flag
  2165. ;
  2166. ;   NOTES:
  2167. ;    The flag PGDFLG defines the letter which toggles the paging
  2168. ;        facility (P in the forms section above)
  2169. ;    The flag PGDFLT determines if type is to page by default
  2170. ;        (PGDFLT=YES if type pages by default); combined with
  2171. ;        PGDFLG, the following events occur --
  2172. ;            If PGDFLT = YES, PGDFLG turns off paging
  2173. ;            If PGDFLT = NO, PGDFLG turns on paging
  2174. ;
  2175. TYPE:    XRA    A        ; Turn off printer flag
  2176. ;
  2177. ; Entry point for CCP list function (list)
  2178. ;
  2179. TYPE0:    STA    PRFLG        ; Set flag
  2180. ;
  2181.      IF    WLT
  2182.     CALL    WHLCHK        ; Check wheel byte
  2183.      ENDIF
  2184. ;
  2185.     CALL    SCANLOG        ; Extract FILENAME.TYP toden
  2186.     JNZ    ERROR        ; Error if any question marks
  2187.     CALL    ADVAN        ; Get pgdflg if it's there
  2188.     STA    PGFLG        ; Save it as a flag
  2189.     JRZ    TYPE1        ; Jump if input ended
  2190.     INX    D        ; Put new buf pointer
  2191. ;
  2192. TYPE1:    SDED    NXTCHR        ; Set pointer for next command
  2193.     CALL    OPENF        ; Open selected file
  2194.     JZ    ERROR        ; Abort if error
  2195.     CALL    CRLF        ; New line
  2196.     MVI    A,NLINES-1    ; Set line count
  2197.     STA    PAGCNT
  2198.     LXI    B,80H        ; Set character position and tab count
  2199. ;
  2200. ; Main loop for loading next block
  2201. ;
  2202. TYPE2:    MOV    A,C        ; Get character count
  2203.     CPI    80H
  2204.     JRC    TYPE3
  2205.     PUSH    H        ; Read next block
  2206.     PUSH    B
  2207.     CALL    READF
  2208.     POP    B
  2209.     POP    H
  2210.     JRNZ    TYPE7        ; Error?
  2211.     MVI    C,0        ; Set character count
  2212.     LXI    H,TBUFF        ; Poin to first character
  2213. ;
  2214. ; Main loop for printing character in TBUFF
  2215. ;
  2216. TYPE3:    MOV    A,M        ; Get next char
  2217.     ANI    7FH        ; Mask out msb
  2218.     CPI    1AH        ; End of file (^z)?
  2219.     RZ            ; Restart cpr if so
  2220. ;
  2221. ; Output character to CRT or list device with tabulation
  2222. ;
  2223.     CPI    CR        ; Reset tab count?
  2224.     JRZ    TYPE4
  2225.     CPI    LF        ; Reset tab count?
  2226.     JRZ    TYPE4
  2227.     CPI    TAB        ; Tab?
  2228.     JRZ    TYPE5
  2229. ;
  2230. ; Output character and increment character count
  2231. ;
  2232.     CALL    LCOUT        ; Output char
  2233.     INR    B        ; Increment tab count
  2234.     JR    TYPE6
  2235. ;
  2236. ; Output <CR> or <LF> and reset tab count
  2237. ;
  2238. TYPE4:    CALL    LCOUT        ; Output <CR> or <LF>
  2239.     MVI    B,0        ; Reset tab counter
  2240.     JR    TYPE6
  2241. ;
  2242. ; Tabulate
  2243. ;
  2244. TYPE5:    MVI    A,' '        ; Space
  2245.     CALL    LCOUT
  2246.     INR    B        ; Increment position count
  2247.     MOV    A,B
  2248.     ANI    7
  2249.     JRNZ    TYPE5
  2250. ;
  2251. ; Continue processing
  2252. ;
  2253. TYPE6:    INR    C        ; Increment char count
  2254.     INX    H        ; Pt to next char
  2255.     CALL    BREAK        ; Check for abort
  2256.     RZ            ; Restart if so
  2257.     JR    TYPE2
  2258. ;
  2259. TYPE7:    DCR    A        ; No error?
  2260.     RZ            ; Restart cpr
  2261.     JMP    ERROR
  2262.      ENDIF
  2263. ;
  2264. ; Section:  5E
  2265. ; Command:  SAVE
  2266. ; Function: To save the contents of the TPA onto disk as a file
  2267. ; Forms:
  2268. ;    SAVE <number of pages> <UFN>
  2269. ;        save specified number of pages (start at 100H)
  2270. ;        from TPA into specified file; <number of pages> in DEC
  2271. ;    SAVE <number of sectors> <UFN> s
  2272. ;        like SAVE above, but numeric argument specifies number
  2273. ;        of sectors rather than pages
  2274. ;NOTES:
  2275. ;    The MULTCMD flag (multiple commands allowed) expands the code
  2276. ;        slightly, but is required to support multiple commands
  2277. ;         with SAVE
  2278. ;    The SECTFLG defines the letter which indicates a sector count
  2279. ;        (S in the forms section above)
  2280. ;
  2281.      IF    SAVEON
  2282. SAVE:     IF    WSAVE
  2283.     CALL    WHLCHK        ; Check for wheel byte
  2284.      ENDIF
  2285. ;
  2286.     CALL    NUMBER        ; Extract number from command line
  2287.     MOV    L,A        ; HL=page count
  2288.     MVI    H,0
  2289.     PUSH    H        ; Save page count
  2290.     CALL    EXTEST        ; Test for existence of file
  2291.     MVI    C,16H        ; Bdos make file
  2292.     CALL    GRBDOS
  2293.     POP    H        ; Get page count
  2294.     JRZ    SAVE3        ; Error?
  2295.     XRA    A        ; Set record count field
  2296.     STA    FCBCR
  2297.     CALL    ADVAN        ; Look for 's' for sector option
  2298.     INX    D        ; Pt to after 's' token
  2299.     CPI    SECTFLG
  2300.     JRZ    SAVE0
  2301.     DCX    D        ; No 's' token, so back up
  2302.     DAD    H        ; Double it for HL=record (128 bytes)
  2303. ;
  2304. SAVE0:    SDED    NXTCHR        ; Set pointer to bad token
  2305.     LXI    D,TPA        ; Point to start of SAVE area (TPA)
  2306. ;
  2307. SAVE1:    MOV    A,H        ; Done with save?
  2308.     ORA    L        ; HL=0 if so
  2309.     JRZ    SAVE2
  2310.     DCX    H        ; Count down on record
  2311.     PUSH    H        ; Save pointer to block to save
  2312.     LXI    H,128        ; 128 bytes per record
  2313.     DAD    D        ; Point to next record
  2314.     PUSH    H        ; Save on stack
  2315.     CALL    DMASET        ; Set DMA address for write (addr in DE)
  2316.     LXI    D,FCBDN        ; Write record
  2317.     MVI    C,15H        ; Bdos write record
  2318.     CALL    BDOSB        ; Save bc
  2319.     POP    D        ; Get ptr to next record in DE
  2320.     POP    H        ; Get record count
  2321.     JRNZ    SAVE3        ; Write error?
  2322.     JR    SAVE1        ; Continue
  2323. ;
  2324. SAVE2:    LXI    D,FCBDN        ; Close saved file
  2325.     CALL    CLOSE
  2326.     INR    A        ; Error?
  2327.     JRNZ    SAVE4
  2328. ;
  2329. SAVE3:    CALL    PRNLE        ; Print 'no space' error
  2330. ;
  2331. SAVE4:    JMP    DEFDMA        ; Set DMA to 80 and restart cpr
  2332.      ENDIF
  2333. ;
  2334. ; Test file in FCB for existence, ask user to delete if so, and abort if
  2335. ; he chooses not to.
  2336. ;
  2337.      IF    SAVEON OR RENON
  2338. EXTEST:    CALL    SCANLOG        ; Extract file name and log in user/disk
  2339.     JNZ    ERROR        ; '?' is not permitted
  2340.     CALL    SEARF        ; Look for specified file
  2341.     LXI    D,FCBDN        ; Point to file FCB
  2342.     RZ            ; Ok if not found
  2343.     PUSH    D        ; Save pointer to FCB
  2344.     CALL    PRINTC
  2345.     DB    'Erase',' '+80H
  2346.     LXI    H,FCBFN        ; Point to file name field
  2347.     CALL    PRFN        ; Print it
  2348.     MVI    A,'?'        ; Print question
  2349.     CALL    CONOUT
  2350.     CALL    CONIN        ; Get response
  2351.     POP    D        ; Get ptr to fcb
  2352.     CPI    'Y'        ; Key on yes
  2353.     JNZ    ERR3        ; Restart as error if no
  2354.     PUSH    D        ; Save ptr to fcb
  2355.     CALL    DELETE        ; Delete file
  2356.     POP    D        ; Get ptr to fcb
  2357.     RET
  2358.      ENDIF
  2359. ;
  2360. ; Section:  5F
  2361. ; Command:  REN
  2362. ; Function: To change the name of an existing file
  2363. ; Forms:
  2364. ;    REN <new UFN>=<old UFN> perform function
  2365. ;
  2366.      IF    RENON
  2367. REN:     IF    WREN
  2368.     CALL    WHLCHK        ; Check for wheel byte
  2369.      ENDIF
  2370. ;
  2371.     CALL    EXTEST        ; Test for file existence and return
  2372.     LDA    TEMPDR        ; Save selected disk
  2373.     PUSH    PSW        ; Save on stack
  2374. ;
  2375. REN0:    LXI    H,FCBDN        ; Save new file name
  2376.     LXI    D,FCBDM
  2377.     LXI    B,16        ; 16 bytes
  2378.     LDIR
  2379.     CALL    ADVAN        ; Advance to next character (non-delim)
  2380.     JRZ    REN4        ; Error if none
  2381. ;
  2382. ; Perform rename function
  2383. ;
  2384. REN1:    SDED    NXTCHR        ; Save pointer to old file name
  2385.     CALL    SCANER        ; Extract FILENAME.TYP token
  2386.     JRNZ    REN4        ; Error if any '?'
  2387.     POP    PSW        ; Get old default drive
  2388.     MOV    B,A        ; Save it
  2389.     LXI    H,TEMPDR    ; Compare it against selected drive
  2390.     MOV    A,M        ; Default?
  2391.     ORA    A
  2392.     JRZ    REN2
  2393.     CMP    B        ; Check for drive error
  2394.     JRNZ    REN4
  2395. ;
  2396. REN2:    MOV    M,B
  2397.     XRA    A
  2398.     STA    FCBDN        ; Set default drive
  2399.     LXI    D,FCBDN        ; Rename file
  2400.     MVI    C,17H        ; BDOS rename FCT
  2401.     CALL    GRBDOS
  2402.     RNZ
  2403. ;
  2404. REN3:    CALL    PRNNF        ; Print NO FILE message
  2405. ;
  2406. REN4:    JMP    ERROR
  2407.      ENDIF
  2408. ;
  2409. RSTJMP:    JMP    RCCPNL        ; Restart CCP
  2410. ;
  2411. ; Section:  5G
  2412. ; Command:  JUMP
  2413. ; Function: To call the program (subroutine) at the specified address
  2414. ;         without loading from disk
  2415. ; Forms:
  2416. ;    JMMP <adr>        call at <ADR>;<ADR> is in hex
  2417. ;
  2418.      IF    JUMPON
  2419. JUMP:     IF    WJUMP
  2420.     CALL    WHLCHK        ; Check for wheel byte
  2421.        ENDIF
  2422. ;
  2423.     CALL    HEXNUM        ; Get load address in HL
  2424.     JR    CALLPROG    ; Perform call
  2425.      ENDIF
  2426. ;
  2427. ; Section:  5H
  2428. ; Command:  GO
  2429. ; Function: To call the program in the TPA without loading from disk.
  2430. ;        Same as JMP 100H, but much more convenient, especially
  2431. ;        when used with parameters for programs like STAT.  Also,
  2432. ;        can be allowed on remote-access systems.
  2433. ; Form:
  2434. ;    GO <parameters like for command>
  2435. ;
  2436.      IF    GOON
  2437. GO:     IF    WGO
  2438.     CALL    WHLCHK        ; Check for wheel byte
  2439.      ENDIF
  2440. ;
  2441.     LXI    H,TPA        ; Always to TPA
  2442.     JR    CALLPROG    ; Perform call
  2443.      ENDIF
  2444. ;
  2445. ; Section:  5I
  2446. ; Command:  COM file processing
  2447. ; Function: To load the specified .COM file from disk and execute it
  2448. ; Forms:    <command line>
  2449. ; NOTES:    .COM files are processed as follows --
  2450. ;        1. file name buffers are initialized and a preliminary
  2451. ;            error check is done
  2452. ;        2. MLOAD is used to search for the file along the path
  2453. ;            and load it into the TPA
  2454. ;        3. CALLPROG is used to set up the buffers to be used by
  2455. ;            the transient (FCB at 5CH, FCB at 6CH, TBUFF at
  2456. ;            80H) and run the program
  2457. ;    The flag MULTCMD comes into play frequently here; it mainly
  2458. ;        serves to save space if MULTCMD is NO and and enables
  2459. ;        multiple commands on the same line if MULTCMD is YES.
  2460. ;
  2461. COM:    LDA    FCBFN        ; Any command?
  2462.     CPI    ' '        ; ' ' means command was 'D:' to switch
  2463.     JRNZ    COM1        ; Must be transient or error
  2464. ;
  2465. ; Entry point to select user/disk
  2466. ;
  2467.      IF    WDU
  2468.     CALL    WHLCHK        ; Check for wheel byte
  2469.      ENDIF
  2470. ;
  2471.     LDA    COLON        ; Look for colon flag
  2472.     ORA    A        ; If zero, just blank
  2473.     RZ            ; Return to main routine
  2474. ;
  2475. ; Command is DU:, so log in user/disk
  2476. ;
  2477.     LDA    TEMPUSR        ; Get selected user
  2478.     CPI    10H        ; Make sure 4 bits
  2479.     JNC    ERROR        ; Range error?
  2480.     STA    CURUSR        ; Set current user
  2481.     CALL    SLOGIN        ; Log in user/disk as if temporarily
  2482. ;
  2483. ; Now, make login permanent
  2484. ;
  2485.     LDA    TEMPDR        ; Get selected drive
  2486.     ORA    A        ; If 0 (default), no change
  2487.     JRZ    COM0
  2488.     DCR    A        ; Adjust for log in
  2489.     STA    CURDR        ; Set current drive
  2490. ;
  2491. COM0:    JMP    SETUD        ; Set current user/disk
  2492. ;
  2493. ; Process command
  2494. ;
  2495. COM1:    LXI    D,FCBFT        ; Point to file type
  2496.     LDAX    D        ; Get first character of file type
  2497.     CPI    ' '        ; Must be blank, or error
  2498.     JNZ    ERROR
  2499.     LXI    H,COMMSG    ; Place default file type (com) into fcb
  2500.     LXI    B,3        ; 3 bytes
  2501.     LDIR
  2502.     LXI    H,TPA        ; Set execution/load address
  2503.     PUSH    H        ; Save for execution
  2504. ;
  2505.      IF    CMDRUN
  2506.     MVI    A,0FFH        ; Use it if available
  2507.      ENDIF
  2508. ;
  2509.     CALL    MLOAD        ; Load memory with file specified
  2510.     POP    H        ; Get execution address
  2511. ;
  2512. ; Entry point for the execution of the loaded program; on entry to this
  2513. ; routine, HL must contain the execution address of the program (subrou-
  2514. ; tine) to execute.
  2515. ;
  2516. CALLPROG:
  2517.     SHLD    EXECADR        ; Perform in-line code modification
  2518.     CALL    SCANER        ; Search command line for next token
  2519.     LXI    H,TEMPDR    ; Save pointer to drive specification
  2520.     PUSH    H
  2521.     MOV    A,M        ; Set drive specification
  2522.     STA    FCBDN
  2523.     LXI    H,FCBDN+10H    ; Pt to 2nd file name
  2524.     CALL    SCANX        ; Scan for it and load it into fcb+16
  2525.     POP    H        ; Set up drive specs
  2526.     MOV    A,M
  2527.     STA    FCBDM
  2528.     XRA    A
  2529.     STA    FCBCR
  2530.     LXI    D,TFCB        ; Copy to default FCB
  2531.     LXI    H,FCBDN        ; From FCBDN
  2532.     LXI    B,33        ; Set up default FCB
  2533.     LDIR
  2534. ;
  2535. CMDCH1    EQU    $+1        ; In-the-code buffer address of 1st char
  2536.     LXI    H,CMDLIN
  2537. ;
  2538. CALLP1:    MOV    A,M        ; Skip to end of 2nd file name
  2539.     ORA    A        ; End of line?
  2540.     JRZ    CALLP2
  2541. ;
  2542.      IF    MULTCMD
  2543.     CPI    CMDSEP        ; Command separator?
  2544.     JRZ    CALLP2
  2545.      ENDIF
  2546. ;
  2547.     CPI    ' '        ; End of token?
  2548.     JRZ    CALLP2
  2549.     INX    H
  2550.     JR    CALLP1
  2551. ;
  2552. ; Load command line into TBUFF
  2553. ;
  2554. CALLP2:    MVI    B,0        ; Set character count
  2555.     LXI    D,TBUFF+1    ; Point to character position
  2556. ;
  2557. CALLP3:    MOV    A,M        ; Copy command line to TBUFF
  2558.     STAX    D
  2559.     ORA    A        ; Done if zero
  2560.     JRZ    CALLP5
  2561. ;
  2562.      IF    MULTCMD
  2563.     CPI    CMDSEP        ; Done if command separator
  2564.     JRZ    CALLP4
  2565.      ENDIF
  2566. ;
  2567.     INR    B        ; Increment character count
  2568.     INX    H        ; Point to next
  2569.     INX    D
  2570.     JR    CALLP3
  2571. ;
  2572.      IF    MULTCMD
  2573. CALLP4:    XRA    A        ; Store ending zero
  2574.     STAX    D        ; Instead of cmdsep
  2575.      ENDIF
  2576. ;
  2577. ; Run loaded transient program
  2578. ;
  2579. CALLP5:     IF    MULTCMD
  2580.     SHLD    NXTCHR        ; Save pointer to continue processing
  2581.      ENDIF
  2582. ;
  2583.     MOV    A,B        ; Save character count
  2584.     STA    TBUFF
  2585.     CALL    CRLF        ; New line
  2586.     CALL    DEFDMA        ; Set DMA to 80
  2587. ;
  2588. ; Execution (call) of program (subroutine) occurs here
  2589. ;
  2590. EXECADR    EQU    $+1        ; Change address for in-line code mod.
  2591.     CALL    TPA        ; Call transient
  2592.     CALL    DEFDMA        ; Set DMA to 80 in case it was changed
  2593.     CALL    DLOGIN        ; Login current user/disk
  2594.     JMP    CONT        ; Restart CCP and continue command
  2595. ;
  2596. ; Section:  5J
  2597. ; Command: GET
  2598. ; Function: To load the specified file from disk to the specified
  2599. ;         address
  2600. ; Forms:
  2601. ;    GET <adr> <UFN> load the specified file at the specified page;
  2602. ;        <adr> is in hex
  2603. ;
  2604.      IF    GETON
  2605. GET:     IF    WGET
  2606.     CALL    WHLCHK        ; Check wheel byte
  2607.      ENDIF
  2608. ;
  2609.     CALL    HEXNUM        ; Get load address in hl
  2610.     PUSH    H        ; Save address
  2611.     CALL    SCANER        ; Get file name
  2612.     POP    H        ; Restore address
  2613.     JNZ    ERROR        ; Must be unambiguous
  2614. ;
  2615. ;
  2616. ; Fall through to MLOAD
  2617. ;
  2618.      IF    CMDRUN
  2619.     XRA    A        ; No cmdrun if facility is there
  2620.      ENDIF
  2621.      ENDIF
  2622. ;
  2623. ;
  2624. ; Memory load subroutine
  2625. ;
  2626. ; Load memory with the file whose name is specified in the command line.
  2627. ; On input, HL contains starting address to load.  Exit points are a re-
  2628. ; turn and log-in current user/disk if no error, a jmp to error if .COM
  2629. ; file not found or a message and abort if memory full.
  2630. ;
  2631. MLOAD:     IF    CMDRUN
  2632.     STA    CRFLAG        ; Save flag
  2633.      ENDIF
  2634. ;
  2635.     SHLD    LOADADR        ; Set load address
  2636. ;
  2637. ; Reentry point for a non-standard CP/M modification.  The path command-
  2638. ; search is implemented by this routine
  2639. ;
  2640. MLA:     IF    DRVPREFIX
  2641.      IF    PRIVDIR
  2642.     LDA    WHLADR        ; Don't allow prefixes unless
  2643.     ORA    A        ; User is a wheel
  2644.     LXI    H,PATH
  2645.     JRZ    MLA0
  2646.      ENDIF
  2647. ;
  2648.     MVI    A,DRVPFATT    ; Set flag per user spec for sys/non-sys
  2649.     STA    SYSTST        ; Test flag in getsbit
  2650.     CALL    SLOGIN        ; Look under temporary user/disk
  2651.     CALL    SEARF        ; Look for file
  2652. ;
  2653. MLARUN:    LXI    H,PATH        ; Point to path for failure possibility
  2654.     JRNZ    MLA4        ; Found it -- load it and run
  2655.      ENDIF
  2656. ;
  2657.      IF    NOT DRVPREFIX
  2658. MLARUN:    LXI    H,PATH        ; Point to path
  2659.      ENDIF
  2660. ;
  2661. MLA0:    MOV    A,M        ; Get drive
  2662.     ORA    A        ; 0=done=command not found
  2663. ;
  2664.      IF    CMDRUN
  2665.     JRNZ    NOCRUN        ; Not ready for cmd run yet
  2666. ;
  2667. CRFLAG    EQU    $+1        ; Pointer for in-the-code modification
  2668.     MVI    A,0        ; Check crflag
  2669.     ORA    A        ; 0=no
  2670.     JZ    ERROR        ; Process as error
  2671. ;
  2672.      IF    ROOTONLY
  2673.     PUSH    H
  2674.      ENDIF
  2675. ;
  2676.     XRA    A        ; Do not reenter this code
  2677.     STA    CRFLAG        ; Set zero for no entry
  2678.     LHLD    CMDCH1        ; Get pointer to first char of command
  2679.     DCX    H        ; Pt to char count
  2680.     MVI    M,' '        ; Store leading space
  2681.     SHLD    CMDCH1        ; Point to leading space as first char
  2682.     SHLD    NXTCHR        ; Next char is first char of command
  2683.     LXI    H,CFCB        ; Set cfcb as command
  2684.     LXI    D,FCBDN        ; By copying it into fcbdn
  2685.     LXI    B,12        ; Only 12 bytes required
  2686.     LDIR
  2687. ;
  2688.      IF    ROOTONLY
  2689.     JR    MLA3RT
  2690.      ENDIF
  2691. ;
  2692.      IF    NOT ROOTONLY
  2693.     XRA    A        ; A=0
  2694.     JR    MLARUN        ; Now try the run
  2695.      ENDIF
  2696. ;
  2697. CFCB:    CMDFCB            ; FCB defining initial command
  2698. ;
  2699. NOCRUN:     ENDIF            ; CMDRUN
  2700. ;
  2701.      IF    NOT CMDRUN
  2702.     JZ    ERROR        ; Transient load error -- file not found
  2703.      ENDIF
  2704. ;
  2705. ; Look for command in directory pointed to by HL; drive in 'A:'
  2706. ;
  2707.     CPI    CURIND        ; Current drive specified?
  2708.     JRNZ    MLA1        ; Skip default drive selection if so
  2709.     LDA    CURDR        ; Get current drive
  2710.     INR    A        ; Set a=1
  2711. ;
  2712. MLA1:    STA    TEMPDR        ; Select different drive if not current
  2713.     MVI    A,1        ; Accept both SYS and DIR files
  2714.     STA    SYSTST        ; Test flag is 1 for both
  2715.     INX    H        ; Point to user number
  2716.     MOV    A,M        ; Get user number
  2717.     INX    H        ; Poin to next entry in path
  2718.     PUSH    H        ; Save pointer
  2719.     ANI    7FH        ; Mask out system bit
  2720.     CPI    CURIND        ; Current user specified?
  2721.     JRNZ    MLA2        ; Do not select current user if so
  2722.     LDA    CURUSR        ; Get current user number
  2723. ;
  2724. MLA2:    STA    TEMPUSR        ; Set temporary user number
  2725.     CMA            ; System bit is 0 if SYS-only
  2726.     ANI    80H
  2727.     JRNZ    MLA3        ; Flag not set if system bit=0
  2728.     STA    SYSTST        ; Flag is 0 for SYS-only, 1 for both
  2729. ;
  2730. MLA3:    CALL    SLOGIN        ; Log in path-specified user/disk
  2731. ;
  2732. MLA3RT:    CALL    SEARF        ; Look for file
  2733.     POP    H        ; Get ptr to next path entry
  2734.     JRZ    MLA0        ; Continue path search if search failed
  2735.                 ; Load if search succeeded
  2736. ;
  2737. ; File found -- perform system test and proceed if approved
  2738. ;
  2739. MLA4:    PUSH    H        ; Save pointer
  2740.     CALL    GETSBIT        ; Check system bit
  2741.     POP    H        ; Get pointer
  2742.     JRZ    MLA0        ; Continue if no match
  2743.     CALL    OPENF        ; Open file for input
  2744. ;
  2745. LOADADR    EQU    $+1        ; Memory load address (in-line code mod)
  2746.     LXI    H,TPA        ; Set start address of memory load
  2747. ;
  2748. MLA5:     IF    NOT MAKESPR    ; Can't reconcile the MVI if SPR
  2749.     MVI    A,ENTRY/256-1    ; Get high-order adr of just below CCP
  2750.      ENDIF
  2751. ;
  2752.      IF    MAKESPR        ; Do different way
  2753.     PUSH    B
  2754.     LXI    B,ENTRY
  2755.     MOV    A,B        ; Put high order address in A
  2756.     DCR    A        ; Minus 1
  2757.     POP    B        ; Restore B
  2758.      ENDIF
  2759. ;
  2760.     CMP    H        ; Are we going to overwrite the CCP?
  2761.     JRC    PRNLE        ; Error if so
  2762.     PUSH    H        ; Save address of next sector
  2763.     XCHG            ; In DE
  2764.     CALL    DMASET        ; Set DMA address for load
  2765.     LXI    D,FCBDN        ; Read next sector
  2766.     CALL    READ
  2767.     POP    H        ; Get address of next sector
  2768.     JRNZ    MLA6        ; Read error or EOF?
  2769.     LXI    D,128        ; Move 128 bytes per sector
  2770.     DAD    D        ; Point to next sector in HL
  2771.     JR    MLA5
  2772. ;
  2773. MLA6:    DCR    A        ; Load complete
  2774.     JZ    DLOGIN        ; Ok if zero, else fall thru to prnle
  2775. ;
  2776. ; Load error
  2777. ;
  2778. PRNLE:    CALL    PRINTC
  2779.     DB    'Ful','l'+80H
  2780.     CALL    DLOGIN        ; Restore current user/disk
  2781.     JMP    RESTRT        ; Restart zcmd
  2782. ;
  2783. ; The following routine will fetch HHMM from NUBYE/BYE5 (or your clock
  2784. ;  if BYCLOCK/BYTLOS is NO and CLOCK is YES) and display it as [hh:mm]
  2785. ;  in front of your du> prompt.
  2786. ;
  2787.      IF    BYCLOCK    AND (NOT BYTLOS) AND (NOT CLOCK)
  2788. TIME:    MVI    C,79
  2789.     CALL    BDOS        ; Get BYE's RTC address
  2790.     MOV    A,M        ; Get HH (it's in BCD)
  2791.     PUSH    H        ; Save address
  2792.     LXI    H,ANSHH        ; Storage location
  2793.     CALL    ASCII        ; Convert and store ascii
  2794.     POP    H        ; Get address back
  2795.     INX    H
  2796.     MOV    A,M        ; Get MM, also in bcd
  2797.     LXI    H,ANSMM        ; Storage location
  2798.     CALL    ASCII        ; Convert and store ascii
  2799.     LXI    H,TMSG
  2800.     JMP    PRIN1        ; And print it, return from prin1
  2801.      ENDIF
  2802. ;
  2803.      IF    CLOCK AND (NOT BYCLOCK) AND (NOT BYTLOS)
  2804. TIME:    RDCLOK            ; Predefined macro clock read code
  2805.      ENDIF
  2806. ;
  2807.      IF    (BYCLOCK AND (NOT BYTLOS)) OR CLOCK
  2808. ASCII:    PUSH    PSW        ; Save BCD pair
  2809.     RAR
  2810.     RAR
  2811.     RAR
  2812.     RAR
  2813.     ANI    0FH        ; Get MSB of BCD pair
  2814.     ADI    '0'        ; Make ASCII
  2815.     MOV    M,A        ; Store it
  2816.     INX    H        ; Point to next store location
  2817.     POP    PSW
  2818.     ANI    0FH        ; Get LSB of BCD pair
  2819.     ADI    '0'        ; Convert to ASCII
  2820.     MOV    M,A        ; Store it
  2821.     RET
  2822. ;
  2823. TMSG:    DB    '['
  2824. ANSHH:    DB    '00:'
  2825. ANSMM:    DB    '00] ',0
  2826.      ENDIF
  2827. ;
  2828. ; The following routine will display [Left:nn] or [On:nn], depending
  2829. ;  on your equate settings (BYTLOS and SHOW).  Normal users will be
  2830. ;  shown their time-left-on-system (i.e. [Left:nn]), while those with
  2831. ;  WHEEL privileges or unlimited time will be shown their time-on-system
  2832. ;  (i.e. [On:nn]). 
  2833. ;
  2834.      IF    BYTLOS AND (NOT    BYCLOCK) AND (NOT CLOCK)
  2835. TIME:    MVI    C,79
  2836.     CALL    BDOS        ; Get current time-on-system
  2837.     PUSH    PSW        ; And save it
  2838.     MVI    C,81
  2839.     MVI    E,255        ; Get maxtime allowed
  2840.     CALL    BDOS
  2841.     MOV    B,A        ; Put it in B
  2842.     ORA    A
  2843.     JRZ    TIME1        ; User has unlimited time
  2844.     LDA    WHLADR
  2845.     ORA    A
  2846.     JRNZ    TIME1        ; Wheel byte is on
  2847.     POP    PSW        ; TOS in A
  2848.     MOV    C,A        ; Now in C
  2849.     MOV    A,B        ; Maxtime in A
  2850.     SUB    C        ; Maxtime-TOS=TLOS
  2851.     LXI    H,TLOS        ; Storage area
  2852.     CALL    DEC8        ; Convert/store to ascii
  2853.     LXI    H,TLOSM
  2854.     CALL    PRIN1        ; Print first part
  2855.     LXI    H,TLOS2
  2856.     JMP    PRIN1        ; And second part, exit from prin1
  2857. ;
  2858. TIME1:    POP    PSW        ; Get TOS for wheel or unlimited time users
  2859. ;
  2860.      IF    NOT SHOW
  2861.     RET
  2862.      ENDIF
  2863. ;
  2864.      IF    SHOW
  2865.     LXI    H,TLOS1        ; Storage area
  2866.     CALL    DEC8        ; Convert/ store to ascii
  2867.     LXI    H,TLOSM1
  2868.     CALL    PRIN1        ; Print first part [On:xx 
  2869.     LXI    H,TLOS2
  2870.     JMP    PRIN1        ; second part, then exit from prin1    
  2871.      ENDIF
  2872. ;
  2873. TLOSM:    DB    '[Left:'
  2874. TLOS:    DB    '   ',0        ; Buffer for tlos or tos
  2875. ;
  2876.      IF    SHOW
  2877. TLOSM1:    DB    '[On:'
  2878. TLOS1:    DB    '   ',0        ; Buffer for tlos or tos
  2879.      ENDIF
  2880. ;
  2881. TLOS2:    DB    '] ',0
  2882. ;
  2883. ;-----
  2884. ;
  2885. ; DEC8 will convert an 8-bit binary number in a to three ASCII bytes.
  2886. ; HL points to the MSB location where the ASCII bytes will be stored.
  2887. ; Leading zeros are suppressed.
  2888. ;
  2889. DEC8:    PUSH    PSW
  2890.     PUSH    H
  2891.     XRA    A
  2892.     MOV    M,A        ; Clear destination
  2893.     INX    H
  2894.     MOV    M,A
  2895.     INX    H
  2896.     MOV    M,A
  2897.     POP    H
  2898.     POP    PSW
  2899.     PUSH    B
  2900.     PUSH    D
  2901.     MVI    E,0        ; Leading zero flag
  2902.     MVI    D,100
  2903. ;
  2904. DEC81:    MVI    C,'0'-1
  2905. ;JDEBª⌐dÆöñÆ媬äêv@b``@▐Σ@b`ö£åêèåpdv@ªΦ╥╪╪@VéêêêRH£╥∞@┬╚╔D╥Φ@─┬╞╓₧¼äXév@ñ╩┌┬╥▄╚╩ΣÜ₧¼éXåv@Ä╩Φ@b``^b`åáÆ'1'        ; Zero?
  2906.     JNC    DEC84        ; Yes
  2907.     MOV    A,E        ; Check flag
  2908.     ORA    A        ; Reset?
  2909.     MOV    A,C        ; Restore byte
  2910.     JZ    DEC85        ; Leading zeros are skipped
  2911. ;
  2912. DEC84:    MOV    M,A        ; Store it in buffer pointed at by HL
  2913.     INX    H        ; Increment storage location
  2914.     MVI    E,0FFH        ; Set zero flag
  2915. ;
  2916. DEC85:    MOV    A,D
  2917.     SUI    90        ; 100 to 10
  2918.     MOV    D,A
  2919.     MOV    A,B        ; Remainder
  2920.     JNC    DEC81        ; Do it again
  2921.     ADI    '0'        ; Make ASCII
  2922.     MOV    M,A        ; And store it
  2923.     POP    D
  2924.     POP    B
  2925.     RET
  2926.      ENDIF            ; BYTLOS AND NOT BYCLOCK
  2927. ;
  2928. ;-----
  2929. ;
  2930. ; Default path used for path command-search
  2931. ;
  2932.      IF    INTPATH
  2933. PATH:    IPATH            ; Macro defined up front
  2934. ;
  2935.      IF    WHEEL
  2936. WHLPTH:    DB    0,SYSUSR    ; Filled dynamically based on wheel byte
  2937.      ENDIF
  2938. ;
  2939.     DB    0        ; Terminating 0 for last pair
  2940.      ENDIF
  2941. ;
  2942. ; Stack area
  2943. ;
  2944.      IF    INTSTACK    ; Internal stack
  2945.     DS    48        ; Stack area
  2946. ;
  2947. STACK    EQU    $        ; Top of stack
  2948.      ENDIF
  2949. ;
  2950. ; The following will cause an error message to appear if the size of
  2951. ; ZCMD2 is over 2k bytes.
  2952. ;
  2953.      IF    NOT MAKESPR
  2954.      IF    ($ GT CCPLOC+800H)
  2955. ZCMDER1    EQU    NOVALU1        ;    *** WARNING ***
  2956. ZCMDER2    EQU    NOVALU2        ; ZCMD2 is larger than 2k
  2957.      ENDIF
  2958.      ENDIF
  2959. ;
  2960.     END
  2961.