home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / old / misc / cpmtools / mload.asm < prev    next >
Assembly Source File  |  2020-01-01  |  35KB  |  1,453 lines
  1.     TITLE    'MLOAD MULTI-FILE HEX LOAD UTILITY'
  2. ;
  3. ;         *********************************
  4. ;        *          MLOAD.ASM        *
  5. ;        *   MULTI-FILE HEX LOAD UTILITY *
  6. ;        *          FOR CP/M        *
  7. ;        *********************************
  8. ;
  9. ;
  10. ;    REPLACEMENT FOR THE CP/M "LOAD" PROGRAM: THIS PROGRAM
  11. ;    FIXES MANY OF THE PROBLEMS ASSOCIATED WITH THE "CP/M"
  12. ;    LOAD PROGRAM, AND ADDS MANY NEW FEATURES.
  13. ;
  14. ; ----------------
  15. ;
  16. ;    REV 2.1
  17. ;    03/08/84
  18. ;    WRITTEN BY RON FOWLER, FORT ATKINSON, WI
  19. ;
  20. ; ----------------
  21. ;
  22. ; MODIFICATION HISTORY:
  23. ;
  24. ; 2.1   (RGF)   FIXED PROBLEM ON DISK-FULL WHEN WRITING OUTPUT FILE
  25. ;        (MLOAD PREVIOUSLY DIDN'T ERROR OUT ON A FULL DISK)
  26. ; 2.0   (RGF)   ADDED THE ABILITY TO PRE-LOAD A NON-HEX FILE, ALLOWING
  27. ;        MLOAD TO BE USED TO LOAD HEX FILE PATCHES (OBVIATING ANY
  28. ;        NEED TO USE DDT).  THE NORMAL MLOAD SYNTAX IS PRESERVED.
  29. ;        THE FIRST (AND ONLY THE FIRST) FILESPEC (AFTER THE "=",
  30. ;        IF USED) MAY BE NON-HEX; THE FILETYPE MUST BE SPECIFIED.
  31. ;        EXAMPLES:
  32. ;
  33. ;            1)    MLOAD WS.COM,WSPATCH
  34. ;            2)    MLOAD MDM7TEST=MDM720.COM,MDM7US
  35. ;            3)    MLOAD WS.OVR,OVRPATCH
  36. ;
  37. ;        THE FIRST EXAMPLE LOADS WS.COM, OVERLAYS IT WITH
  38. ;        WSPATCH.HEX, AND WRITES THE OUTPUT TO WS.COM.  THE
  39. ;        SECOND EXAMPLE LOADS MDM720.COM, OVERLAYS IT WITH
  40. ;        MDM7US.HEX, AND WRITES THE OUTPUT FILE TO MDM7TEST.COM.
  41. ;        (NOTE THAT THE SECOND EXAMPLE IS THE RECOMMENDED TECHNIQUE,
  42. ;        SINCE IT PRESERVES THE ORIGINAL FILE). THE THIRD EXAMPLE
  43. ;        LOADS WS.OVR AND PATCHES IT WITH THE FILE "OVRPATCH.HEX".
  44. ;
  45. ;        ALSO ADDED THIS REV: ZCPR2-STYLE DU SPECS ARE NOW FULLY
  46. ;        SUPPORTED, FOR BOTH INPUT AND OUTPUT FILES.  THUS, THE
  47. ;        FOLLOWING COMMAND LINES ARE PERMISSABLE:
  48. ;
  49. ;            B3>MLOAD A4:MYFILE.COM=0:BIGFIL,B6:PATCH1,C9:PATCH2
  50. ;            A6>MLOAD B5:=C3:MDM717.COM,MDMPATCH
  51. ;
  52. ;        AFTER LOADING, AN ADDITIONAL INFORMATION LINE IS NOW PRINTED
  53. ;        IN THE STATISTICS REPORT, WHICH DISPLAYS THE TRUE SIZE OF THE
  54. ;        SAVED IMAGE (THE PREVIOUS REPORT WAS TECHNICALLY CORRECT, BUT
  55. ;        COULD RESULT IN CONFUSION FOR CERTAIN KINDS OF FILES WITH
  56. ;        IMBEDDED "DS" AND "ORG" STATEMENTS IN THE ORIGINAL SOURCE CODE).
  57. ;        
  58. ; 1.0 - 1.4    (RGF) CHANGE LOG REMOVED TO CONSERVE SPACE
  59. ;
  60. ;    ORIGINALLY WRITTEN BY RON FOWLER, FORT ATKINSON, WISCONSIN
  61. ;
  62. ;
  63. ;
  64. ; FOR ASSEMBLY WITH ASM.COM OR MAC (DELETE ABOVE TITLE LINE IF
  65. ; ASSEMBLING WITH ASM.COM)
  66. ;
  67. ; THIS PROGRAM IS A REPLACEMENT FOR THE CP/M "LOAD" PROGRAM.
  68. ; WHY REPLACE "LOAD"?  WELL... LOAD.COM HAS A FEW DEFICIENCIES.
  69. ; FOR EXAMPLE, IF YOUR HEX FILE'S ORIGIN IS ABOVE 100H, LOAD.COM
  70. ; PREPENDS BLANK SPACE TO THE OUTPUT FILE TO INSURE IT WILL WORK
  71. ; AS A CP/M TRANSIENT.  IT CARES NOT IF THE FILE IS NOT INTENDED
  72. ; AS A CP/M TRANSIENT.  IT ALSO DOESN'T LIKE HEX RECORDS WITH MIXED
  73. ; LOAD ADDRESSES  (FOR EXAMPLE, ONE THAT LOADS BELOW A PREVIOUS RECORD --
  74. ; WHICH IS A PERFECTLY LEGITIMATE HAPPENSTANCE).  ALSO, LOAD.COM
  75. ; CAN LOAD ONLY ONE PROGRAM AT A TIME, AND HAS NO PROVISION FOR
  76. ; A LOAD BIAS IN THE COMMAND SPECIFICATION. FINALLY, THERE IS NO
  77. ; PROVISION FOR USER SPECIFICATION OF OUTPUT FILE NAME.
  78. ;
  79. ;
  80. ; HENCE, THIS PROGRAM....
  81. ;
  82. ;------------------------------------------------------------
  83. ;
  84. ; SYNTAX IS AS FOLLOWS:
  85. ;
  86. ;    MLOAD [<OUTNAM=] <FILENAME>[,<FILENAME>...] [BIAS]
  87. ;
  88. ; WHERE <OUTNAM IS THE (OPTIONAL!;) OUTPUT FILE NAME (ONLY THE DRIVE
  89. ; SPEC AND PRIMARY FILENAME MAY BE SPECIFIED; THE OUTPUT FILETYPE IS
  90. ; DERIVED EXCLUSIVELY FROM THE 3-BYTE STRING AT 103H WITHIN MLOAD),
  91. ; <FILENAME> SPECIFIES FILES TO LOAD AND <BIAS> IS THE OFFSET WITHIN
  92. ; THE SAVED IMAGE TO APPLY WHEN LOADING THE FILE.
  93. ;
  94. ; MLOAD WITH NO ARGUMENTS PRINTS A SMALL HELP MESSAGE -- THIS MESSAGE
  95. ; IS ALSO PRINTED WHENEVER A COMMAND LINE SYNTAX ERROR OCCURS.
  96. ;
  97. ; FILENAMES MAY CONTAIN DRIVE SPECS, AND MUST NOT CONTAIN WILDCARDS.
  98. ; INPUT FILENAMES MUST BE SEPARATED BY COMMAS, AND A SPACE IS REQUIRED
  99. ; BETWEEN THE LAST FILENAME AND THE OPTIONAL BIAS.
  100. ;
  101. ; A LOAD INFORMATION SUMMARY IS PRINTED AT THE SUCCESSFUL CONCLUSION
  102. ; OF THE LOAD.  ANY ERRORS IN LOADING WILL GENERALLY INCLUDE THE NAME
  103. ; OF THE FILE IN QUESTION.
  104. ;
  105. ; IF NO OUTPUT FILENAME IS SPECIFIED, IT WILL BE DERIVED FROM THE FIRST
  106. ; INPUT FILENAME, WITH FILETYPE OF 'COM', IF NOT OTHERWISE SPECIFIED
  107. ; (THIS DEFAULT FILETYPE MAY BE PATCHED DIRECTLY INTO MLOAD VIA DDT
  108. ; -- ITS LOCATION IS AT 103H IN MLOAD.COM). NOTE THAT A COMMAND LINE OF
  109. ; THE FORM "C:=<FILENAME>" WILL PLACE THE OUTPUT FILE ON THE "C" DRIVE
  110. ; WITH THE SAME PRIMARY FILENAME AS THE INPUT FILE.
  111. ;
  112. ; IN ITS SIMPLEST FORM, MLOAD'S SYNTAX IS IDENTICAL TO LOAD.COM; THUS
  113. ; THERE SHOULD BE NO PROBLEM IN LEARNING TO USE THE NEW PROGRAM.  THE
  114. ; ONLY SIGNIFICANT DIFFERENCE HERE IS THAT, UNDER LOAD.COM, ALL FILES
  115. ; ARE OUTPUT STARTING AT 100H, EVEN IF THEY ORIGINATE ELSEWHERE.  MLOAD
  116. ; OUTPUTS STARTING AT THE HEX FILE ORIGIN (ACTUALLY, THE FIRST HEXT REC-
  117. ; ORD SPECIFIES THE OUTPUT LOAD ADDRESS).  THE BIAS OPTION MAY BE USED
  118. ; TO OVERRIDE THIS.
  119. ;
  120. ; AN EXAMPLE SHOULD CLARIFY THIS.  SUPPOSE YOU HAVE A FILE THAT LOADS
  121. ; AT 1000H.  LOAD.COM WOULD SAVE AN OUTPUT FILE THAT BEGINS AT 100H AND
  122. ; LOADS PAST 1000H (TO WHEREVER THE PROGRAM ENDS).  MLOAD WILL SAVE AN
  123. ; OUTPUT FILE STARTING FROM 1000H ONLY.  IF, FOR SOME REASON YOU NEED THE
  124. ; FILE TO START AT 100H IN SPITE OF ITS 1000H ORIGIN (I CAN THINK OF SEV-
  125. ; ERAL CIRCUMSTANCES WHERE THIS WOULD BE NECESSARY), YOU'D HAVE TO SPECIFY
  126. ; A BIAS TO MLOAD.  THUS, USING THIS EXAMPLE, "MLOAD MYFILE 0F00" WOULD DO.
  127. ;
  128. ; NOTE THAT THIS PROGRAM RE-INITIALIZES ITSELF EACH TIME IT IS RUN.
  129. ; THUS, IF YOUR SYSTEM SUPPORTS A DIRECT BRANCH TO THE TPA (VIA A ZERO-LENGTH
  130. ; .COM FILE, OR THE ZCPR "GO" COMMAND), YOU MAY SAFELY RE-EXECUTE MLOAD.
  131. ;
  132. ; PLEASE REPORT ANY BUGS, BUG FIXES, OR ENHANCEMENTS TO ME AT:
  133. ;
  134. ;        "FORT FONE FILE FOLDER" RCPM/CBBS
  135. ;        FORT ATKINSON, WISCONSIN
  136. ;        (414) 563-9932 (NO RING BACK)
  137. ;
  138. ;                --RON FOWLER
  139. ;                  03/08/84
  140. ; 
  141. ;------------------------------------------------------------
  142. ;
  143. ; CP/M EQUATES
  144. ;
  145. WARMBT    EQU    0        ;WARM BOOT
  146. SYSTEM    EQU    5        ;SYSTEM ENTRY (ALSO TOP OF MEM PNTR)
  147. DFCB    EQU    5CH        ;DEFAULT FILE CONTROL BLOCK
  148. FT    EQU    9        ;FCB OFFSET TO FILETYPE
  149. TBUF    EQU    80H        ;DEFAULT BUFFER
  150. TPA    EQU    100H        ;TRANSIENT PROGRAM AREA
  151. EOF    EQU    1AH        ;CP/M END-OF-FILE MARK
  152. FCBSIZ    EQU    33        ;SIZE OF FILE CONTROL BLOCK
  153. ;
  154. ; CP/M SYSTEM CALLS
  155. ;
  156. PCHARF    EQU    2        ;PRINT CHAR
  157. SELDF    EQU    14        ;SELECT DISK DRIVE
  158. OPENF    EQU    15        ;OPEN FILE
  159. CLOSEF    EQU    16        ;CLOSE FILE
  160. FSRCHF    EQU    17        ;SEARCH FOR FIRST
  161. FSRCHN    EQU    18        ;SEARCH FOR NEXT
  162. ERASEF    EQU    19        ;DELETE FILE
  163. READF    EQU    20        ;READ RECORD
  164. WRITEF    EQU    21        ;WRITE RECORD
  165. CREATF    EQU    22        ;CREATE FILE
  166. GETDRF    EQU    25        ;RETURN DFLT DRIVE #
  167. SDMAF    EQU    26        ;SET DMA ADDRESS
  168. GSUSER    EQU    32        ;GET/SET USER #
  169. RRAND    EQU    33        ;READ RANDOM
  170. WRAND    EQU    34        ;WRITE RANDOM
  171. FILSZF    EQU    35        ;COMPUTE FILE SIZE
  172. SRAND    EQU    36        ;SET RANDOM
  173. ;
  174. ; ASCII CHARACTER CONSTANTS
  175. ;
  176. CR    EQU    13
  177. LF    EQU    10
  178. BEL    EQU    7
  179. TAB    EQU    9
  180. ;
  181. ; WITHOUT FURTHER ADO...
  182. ;
  183.     ORG    TPA
  184. ;
  185.     JMP    BEGIN        ;JUMP OVER DEFAULT OUTPUT FILETYPE
  186. ;
  187. ; THE DEFAULT OUTPUT FILETYPE IS LOCATED AT 103H FOR EASY PATCHING
  188. ;
  189. OUTTYP:    DB    'COM'
  190. ;
  191. BEGIN:    LXI    H,0        ;SAVE SYSTEM STACKPOINTER
  192.     DAD    SP
  193.     SHLD    SPSAVE
  194.     LXI    SP,STACK    ;LOAD LOCAL STACK
  195.     CALL    ILPRNT        ;SIGN ON
  196.     DB    'MLOAD ver. 2.1   Copyright (C) 1983,1984 by Ronald G. Fowler'
  197.     DB    CR,LF,0
  198.     CALL    SETUP        ;INITIALIZE
  199. MAIN:    CALL    NXTFIL        ;PARSE AND READ NEXT INPUT FILE
  200.     JC    DONE        ;NO MORE...
  201.     CALL    LODFIL        ;YEP, LOAD IT
  202.     CALL    CLOSFL        ;CLOSE IT (IN CASE MP/M)
  203.     JMP    MAIN        ;MAYBE MORE
  204. DONE:    CALL    WRTFIL        ;WRITE THE OUTPUT FILE
  205. ;
  206. ; EXIT TO CP/M
  207. ;
  208. EXIT:    LXI    D,TBUF        ;RESTORE DMA ADDRESS
  209.     MVI    C,SDMAF
  210.     CALL    BDOS
  211.     LDA    SYSTEM+2    ;GET TOP OF MEMORY POINTER
  212.     SUI    9        ;ALLOW FOR CCP+SLOP
  213.     LXI    H,HILOAD+1    ;HIGHEST LOAD ADDRESS
  214.     SUB    M        ;ABOVE CCP?
  215.     JC    WARMBT        ;THEN WARM-BOOT
  216.     LHLD    SPSAVE        ;NOPE, CCP STILL IN MEMORY
  217.     SPHL            ;RESTORE ITS STACK
  218.     RET            ;RETURN TO CCP
  219. ;
  220. ; LOAD PROGRAM INITIALIZATION
  221. ;
  222. SETUP:    LXI    H,VARSET    ;INITIALIZE VARIABLES
  223.     LXI    D,VARS
  224.     MVI    B,VARLEN    ;BY MOVING IN DEFAULT VALUES
  225.     CALL    MOVE
  226.     LHLD    CMDPTR        ;GET FIRST FREE MEM POINTER
  227.     XCHG            ;IN DE
  228.     LXI    H,TBUF        ;POINT TO COMMAND TAIL BUFR
  229.     MOV    A,M        ;GET ITS LENGTH
  230.     INX    H
  231.     ORA    A        ;DOES IT HAVE ANY LENGTH?
  232.     JZ    HELP        ;NOPE, GO GIVE USAGE HELP
  233.     MOV    B,A        ;YEP, GET LENGTH TO B
  234.     CALL    MOVE        ;MOVE CMD TAIL TO BUFFER
  235.     XCHG            ;END OF DEST TO HL
  236.     MVI    M,0        ;STUFF A TERMINATOR
  237.     INX    H        ;POINT TO FIRST FREE MEMORY
  238.     SHLD    FILBUF        ;SET UP FILE BUFFER
  239.     XCHG            ;FILE BUFR ADRS TO DE
  240.     LHLD    SYSTEM+1    ;GET TOP OF MEMORY POINTER
  241.     MOV    A,L        ;COMPUTE SIZE OF FILE BUFFER
  242.     SUB    E
  243.     MOV    C,A        ;WITH RESULT IN BC
  244.     MOV    A,H
  245.     SUI    9        ;ALLOW FOR CCP
  246.     SBB    D
  247.     MOV    B,A
  248.     XCHG            ;BUFFER POINTER TO HL
  249. NITMEM:    MVI    M,0        ;CLEAR BUFFER
  250.     INX    H
  251.     DCX    B
  252.     MOV    A,B
  253.     ORA    C
  254.     JNZ    NITMEM
  255. ;
  256. ; LOOK FOR A BIAS SPECIFICATION IN COMMAND LINE
  257. ;
  258.     LHLD    CMDPTR        ;POINT TO COMMAND BUFFER-1
  259.     DCX    H
  260.     CALL    SCANBK        ;SCAN PAST BLANKS
  261.     ORA    A        ;NO NON-BLANK CHARS?
  262.     JZ    HELP        ;THEN GO PRINT HELP TEXT
  263. FNDSPC:    INX    H        ;POINT TO NEXT
  264.     MOV    A,M        ;FETCH IT
  265.     ORA    A        ;TEST IT
  266.     RZ            ;LINE ENDED, RETURN
  267.     CPI    ' '        ;NOPE, TEST FOR BLANK
  268.     JNZ    FNDSPC        ;NOT BLANK, CONTINUE
  269.     CALL    SCANBK        ;SKIP BLANKS
  270.     ORA    A        ;END-OF-LINE?
  271.     RZ            ;RETURN IF SO
  272. ;
  273. ; HL POINTS TO BIAS IN COMMAND LINE
  274. ;
  275.     LXI    D,0        ;INIT BIAS
  276.     CALL    HEXDIG        ;INSURE A HEX DIGIT
  277.     JC    SYNERR        ;BAD...
  278. HEXLP:    MOV    A,M        ;NO.  GET NEXT CHAR
  279.     INX    H        ;SKIP OVER IT
  280.     CALL    HEXDIG        ;TEST FOR HEX DIGIT
  281.     JNC    DIGOK        ;JUMP IF GOOD HEX DIGIT
  282.     ORA    A        ;MUST END ON NULL TERMINATOR
  283.     JNZ    SYNERR
  284.     XCHG            ;GOOD END, GET BIAS TO HL
  285.     SHLD    BIAS        ;STUFF IT
  286.     RET            ;DONE
  287. DIGOK:    XCHG            ;BIAS TO HL
  288.     DAD    H        ;SKIFT LEFT 4 TO MAKE ROOM
  289.     DAD    H        ;   FOR NEW HEX DIGIT
  290.     DAD    H
  291.     DAD    H
  292.     XCHG            ;BACK TO DE
  293.     ADD    E        ;ADD IN NEW DIGIT
  294.     MOV    E,A
  295.     JNC    HEXLP        ;JUMP IF NO 8-BIT OVFL
  296.     INR    D        ;CARRY
  297.     JMP    HEXLP
  298. ;
  299. ; PARSE NEXT INPUT NAME, AND OPEN RESULTANT FILE
  300. ;
  301. NXTFIL:    LHLD    CMDPTR        ;GET COMMAND LINE POINTER
  302. NEXT2:    LXI    D,DFCB        ;DESTINATION FCB
  303.     CALL    FPARSE        ;PARSE A FILENAME
  304.     CPI    '='        ;STOPPED ON OUTPUT SPECIFIER?
  305.     JNZ    NOTEQ
  306.     LDA    OUTNAM+2    ;INSURE NO NAME YET SPECIFIED
  307.     CPI    ' '
  308.     JNZ    SYNERR        ;SYNTAX ERROR IF ALREADY NAMED
  309.     LDA    OUTFLG        ;ALREADY BEEN HERE?
  310.     ORA    A
  311.     JNZ    SYNERR        ;CAN'T BE HERE TWICE
  312.     INR    A        ;FLAG THAT WE'VE BEEN HERE
  313.     STA    OUTFLG
  314.     INR    B        ;INSURE NO AMBIGUOUS OUTPUT NAME
  315.     DCR    B
  316.     JNZ    AFNERR
  317.     INX    H        ;SKIP OVER '='
  318.     PUSH    H        ;SAVE CMD LINE POINTER
  319.     LXI    H,DFCB-1    ;MOVE THE NAME TO OUTPUT NAME HOLD
  320.     LXI    D,OUTNAM
  321.     MVI    B,13        ;DRIVE SPEC TOO
  322.     CALL    MOVE
  323.     POP    H        ;RESTORE COMMAND LINE POINTER
  324.     JMP    NEXT2        ;GO PARSE ANOTHER
  325. NOTEQ:    CPI    ','        ;STOPPED ON COMMA?
  326.     JZ    GCOMMA        ;JUMP IF SO
  327.     MVI    M,0        ;NOPE, INSURE END OF INPUT
  328.     JMP    NXT2        ;DON'T ADVANCE OVER FAKE END
  329. GCOMMA:    INX    H        ;SKIP OVER COMMA
  330. NXT2:    SHLD    CMDPTR        ;SAVE NEW COMMAND LINE PNTR
  331.     MOV    A,B        ;GET AMBIG CHAR COUNT
  332.     ORA    A        ;TEST IT
  333.     JNZ    AFNERR        ;ALLOW NO AMBIG CHARACTERS
  334.     STA    BUFPTR        ;FORCE A DISK READ
  335.     LXI    D,DFCB+1    ;LOOK AT PARSED FILENAME
  336.     LDAX    D
  337.     CPI    ' '        ;BLANK? (INPUT ENDED?)
  338.     STC            ;GET CARRY READY IN CASE SO
  339.     RZ            ;RETURN CY IF INPUT GONE
  340.     DCX    D        ;NOPE, POINT DE TO START OF FCB
  341. OPEN2:    PUSH    D        ;TRY TO OPEN THE FILE
  342.     MVI    C,OPENF
  343.     CALL    BDOS
  344.     POP    D
  345.     INR    A        ;RETURN=0FFH?
  346.     JNZ    OPENOK        ;JUMP IF NOT
  347. ;
  348. ; FILE NOT FOUND: IF FILETYPE BLANK, SET TO 'HEX' AND TRY AGAIN
  349. ;
  350.     LXI    H,DFCB+FT    ;POINT TO FILE TYPE
  351.     MOV    A,M        ;ANYTHING THERE?
  352.     CPI    ' '
  353.     JNZ    FNFERR        ;YES, SO FILE NOT FOUND
  354.     MVI    M,'H'        ;NOPE, FILL IN 'HEX'
  355.     INX    H
  356.     MVI    M,'E'
  357.     INX    H
  358.     MVI    M,'X'
  359.     JMP    OPEN2        ;GO TRY AGAIN
  360. ;
  361. ; HERE AFTER A GOOD FILE OPEN
  362. ;
  363. OPENOK:    CALL    HEXCHK        ;IS THIS A HEX FILE?
  364.     RZ            ;IF SO, ALL DONE
  365.     LXI    H,COMFLG    ;NO, GET POINTER TO FLAG
  366.     MOV    A,M        ;LOADING FIRST FILE?
  367.     ORA    A
  368.     RNZ            ;IF NOT, IGNORE TYPE, CONSIDER HEX
  369.     INR    M        ;ELSE, SET THE FLAG
  370.     RET
  371. ;
  372. ; LOAD CURRENT FILE
  373. ;
  374. LODFIL:    LXI    H,COMFLG    ;LOADING A COM FILE?
  375.     MOV    A,M        ;GET FLAG
  376.     ANI    1
  377.     JNZ    LODCOM        ;JUMP IF SO
  378.     LHLD    BIAS        ;ELSE GET BIAS ON TOP OF STACK
  379.     PUSH    H
  380. ;
  381. ; LOAD A HEX RECORD
  382. ;
  383. LOADLP:    CALL    GNB        ;GET NEXT FILE BYTE
  384.     SBI    ':'        ;LOOK FOR START-RECORD MARK
  385.     JNZ    LOADLP        ;SCAN UNTIL FOUND
  386.     STA    CKSUM        ;GOT IT, INIT CHECKSUM TO ZERO
  387.     MOV    D,A        ;UPPER BYTE OF REC CNT=0
  388.     POP    B        ;RETRIEVE BIAS ADRS
  389.     PUSH    B        ;SAVE IT AGAIN
  390.     CALL    GHBCKS        ;GET HEX BYTE W/CHECKSUM
  391.     MOV    E,A        ;DE NOW HAS RECORD LENGTH
  392.     ORA    A        ;TEST IT
  393.     JNZ    NOTEND        ;JUMP IF LEN<>0 (NOT EOF REC)
  394.     POP    H        ;ALL DONE
  395.     RET
  396. NOTEND:    CALL    GHBCKS        ;HI BYTE OF REC LD ADRS
  397.     MOV    H,A        ;ACCUMULATE IN HL
  398.     CALL    GHBCKS        ;GET LO BYTE
  399.     MOV    L,A        ;PUT LO IN L
  400.     LDA    LODFLG        ;TEST LOAD FLAG
  401.     ORA    A
  402.     CZ    LODNIT        ;NOT FIRST RECORD, INITIALIZE
  403.     PUSH    H        ;SAVE LOAD ADDRESS
  404.     DAD    D        ;ADD IN RECORD LENGTH
  405.     DCX    H        ;MAKE HIGHEST, NOT NEXT
  406.     LDA    HIPC        ;A NEW HIGH?
  407.     SUB    L
  408.     LDA    HIPC+1
  409.     SBB    H
  410.     JNC    NOTGT        ;JUMP IF NOT
  411.     SHLD    HIPC        ;YEP, UPDATE HIPC
  412.     PUSH    D        ;SAVE RECLEN
  413.     XCHG            ;LOAD ADRS TO DE
  414.     LHLD    OFFSET        ;GET OFFSET TO FORM TRUE MEMORY ADRS
  415.     DAD    D        ;ADD IN OFFSET
  416.     DAD    B        ;AND BIAS
  417.     SHLD    HILOAD        ;MARK HIGHEST TRUE MEMORY LOAD ADRS
  418.     LDA    SYSTEM+2    ;VALIDATE AGAINST TOP-MEM POINTER
  419.     CMP    H
  420.     JC    MEMFUL        ;JUMP IF OUT OF MEMORY
  421.     POP    D        ;RESTORE RECLEN
  422. NOTGT:    POP    H        ;RESTORE LOAD ADDRESS
  423.     DAD    B        ;ADD BIAS TO LOAD ADRS
  424.     PUSH    D        ;SAVE RECORD LENGTH
  425.     PUSH    H
  426.     LHLD    BYTCNT        ;ADD RECORD LENGTH TO BYTE COUNT
  427.     DAD    D
  428.     SHLD    BYTCNT
  429.     POP    H
  430.     XCHG
  431.     LHLD    OFFSET        ;CALCULATE TRUE MEMORY ADRS
  432.     DAD    D        ;HL=TRUE LOADING ADRS
  433.     POP    D        ;RESTORE RECORD LENGTH
  434.     CALL    GHBCKS        ;SKIP UNUSED BYTE OF INTEL FORMAT
  435. ;
  436. ; MOVE THE RECORD INTO MEMORY
  437. ;
  438. RECLP:    CALL    GHBCKS        ;GET HEX BYTE
  439.     MOV    M,A        ;STORE IT IN BUFFER
  440.     INX    H        ;POINT TO NEXT
  441.     DCR    E        ;COUNT DOWN
  442.     JNZ    RECLP        ;UNTIL RECORD ALL READ
  443.     CALL    GHBCKS        ;GET CHECKSUM BYTE
  444.     JNZ    CSERR        ;FINAL ADD CKSUM SHOULD SUM 0
  445.     JMP    LOADLP        ;GOOD LOAD, GO DO NXT RECORD
  446. ;
  447. ; GET NEXT HEX BYTE FROM INPUT, AND
  448. ; ACCUMULATE A CHECKSUM
  449. ;
  450. GHBCKS: PUSH    B        ;SAVE EM ALL
  451.     PUSH    H
  452.     PUSH    D
  453.     CALL    HEXIN        ;GET HEX BYTE
  454.     MOV    B,A        ;SAVE IN B
  455.     LXI    H,CKSUM        ;ADD TO CHECKSUM
  456.     MOV    A,M
  457.     ADD    B
  458.     MOV    M,A
  459.     MOV    A,B        ;GET BYTE BACK
  460.     POP    D        ;RESTORE CHECKSUM
  461.     POP    H        ;RESTORE OTHER REGS
  462.     POP    B
  463.     RET
  464. ;
  465. ; ROUTINE TO GET NEXT BYTE FROM INPUT...FORMS
  466. ; BYTE FROM TWO ASCII HEX CHARACTERS
  467. ;
  468. HEXIN:    CALL    GNB        ;GET NEXT INPUT FILE BYTE
  469.     CALL    HEXVAL        ;CONVERT TO BINARY W/VALIDATION
  470.     RLC            ;MOVE INTO MS NYBBLE
  471.     RLC
  472.     RLC
  473.     RLC
  474.     ANI    0F0H        ;KILL POSSIBLE GARBAGE
  475.     PUSH    PSW        ;SAVE IT
  476.     CALL    GNB        ;GET NEXT BYTE
  477.     CALL    HEXVAL        ;CONVERT IT, W/VALIDATION
  478.     POP    B        ;GET BACK FIRST
  479.     ORA    B        ;OR IN SECOND
  480.     RET            ;GOOD BYTE IN A
  481. ;
  482. ; GNB - UTILITY SUBROUTINE TO GET NEXT
  483. ;    BYTE FROM DISK FILE
  484. GNB:    PUSH    H        ;SAVE ALL REGS
  485.     PUSH    D
  486.     PUSH    B
  487.     LDA    BUFPTR        ;GET INPUT BUFR POINTER
  488.     ANI    7FH        ;WOUND BACK TO 0?
  489.     JZ    DISKRD        ;GO READ SECTOR IF SO
  490. GNB1:    MVI    D,0        ;ELSE FORM 16 BIT OFFSET
  491.     MOV    E,A
  492.     LXI    H,TBUF        ;FROM TBUF
  493.     DAD    D        ;ADD IN OFFSET
  494.     MOV    A,M        ;GET NEXT BYTE
  495.     CPI    EOF        ;END OF FILE?
  496.     JZ    EOFERR        ;ERROR IF SO
  497.     LXI    H,BUFPTR     ;ELSE BUMP BUF PTR
  498.     INR    M
  499.     ORA    A        ;RETURN CARRY CLEAR
  500.     POP    B        ;RESTORE AND RETURN
  501.     POP    D
  502.     POP    H
  503.     RET
  504. ;
  505. ; READ NEXT SECTOR FROM DISK
  506. ;
  507. DISKRD: MVI    C,READF        ;BDOS "READ SEC" FUNCTION
  508.     LXI    D,DFCB
  509.     CALL    BDOS        ;READ SECTOR
  510.     ORA    A
  511.     JNZ    EOFERR        ;ERROR IF PHYS END OF FILE
  512.     STA    BUFPTR        ;STORE 0 AS NEW BUF PTR
  513.     JMP    GNB1        ;GO RE-JOIN GNB CODE
  514. ;
  515. ; LOAD A COM FILE
  516. ;
  517. LODCOM:    INR    M        ;BUMP THE COMFILE FLAG
  518.     LXI    H,TPA        ;SET ORIGIN
  519.     CALL    LODNIT        ;AND INITIALIZE
  520.     XCHG            ;LOAD ADDRESS IN DE
  521.     LHLD    BIAS        ;ADD IN BIAS
  522.     DAD    D
  523.     XCHG
  524.     LHLD    OFFSET        ;AND OFFSET
  525.     DAD    D
  526.     XCHG            ;DE HAS ABSOLUTE MEM ADRS OF LOAD
  527. ;
  528. COMLP:    LXI    H,128        ;CALCULATE NEXT DMA
  529.     DAD    D
  530.     LDA    SYSTEM+2    ;CHECK FOR SPACE
  531.     CMP    H
  532.     JC    MEMFUL        ;JUMP IF NONE
  533.     PUSH    H        ;ELSE SAVE NEXT DMA
  534.     PUSH    D        ;AND THIS DMA
  535.     MVI    C,SDMAF        ;SET THIS DMA
  536.     CALL    BDOS
  537.     LXI    D,DFCB        ;READ NEXT RECORD
  538.     MVI    C,READF
  539.     CALL    BDOS
  540.     POP    H        ;RECALL THIS DMA
  541.     POP    D        ;DE=NEXT DMA
  542.     ORA    A        ;END OF READ?
  543.     JNZ    LODEND        ;JUMP IF SO
  544.     LHLD    COMSIZ        ;NO, ADVANCE COM BYTE COUNT
  545.     LXI    B,128
  546.     DAD    B
  547.     SHLD    COMSIZ
  548.     JMP    COMLP        ;CONTINUE
  549. ;
  550. LODEND:    DCX    H        ;ONE LESS BYTE IS HIGHEST
  551.     SHLD    HILOAD        ;SET A NEW HIGH
  552.     LHLD    COMSIZ        ;HI PC=BYTECOUNT+100H
  553.     LXI    D,TPA
  554.     DAD    D
  555.     XCHG            ;TO DE
  556.     LHLD    BIAS        ;ADD IN BIAS
  557.     DAD    D
  558.     SHLD    HIPC
  559.     LXI    D,TBUF        ;RESET DMA FOR HEX FILES
  560.     MVI    C,SDMAF
  561.     CALL    BDOS
  562.     RET
  563. ;
  564. ; WRITE OUTPUT FILE
  565. ;
  566. WRTFIL:    LXI    D,DFCB        ;POINT TO FCB
  567.     PUSH    D        ;SAVE 2 COPIES OF POINTER
  568.     PUSH    D
  569.     CALL    NITFCB        ;INITIALIZE OUTPUT FCB
  570.     LXI    H,OUTNAM    ;MOVE OUTPUT NAME IN
  571.     DCX    D        ;POINT TO USER # (PRIOR TO FCB)
  572.     MVI    B,10        ;MOVE USER, DRIVE, PRIMARY NAME
  573.     CALL    MOVE
  574.     MOV    A,M        ;OUTPUT TYPE BLANK?
  575.     CPI    ' '
  576.     JNZ    WRTNB        ;JUMP IF NOT
  577.     LXI    H,OUTTYP    ;YES, MOVE DFLT OUTPUT FILETYPE IN
  578. WRTNB:    MVI    B,3
  579.     CALL    MOVE
  580.     POP    D        ;RESTORE FCB POINTER
  581.     MVI    C,ERASEF    ;ERASE ANY EXISTING FILE
  582.     CALL    BDOS
  583.     POP    D        ;RESTORE FCB POINTER
  584.     MVI    C,CREATF    ;CREATE A NEW FILE
  585.     CALL    BDOS
  586.     INR    A        ;GOOD CREATE?
  587.     JZ    DIRFUL        ;GOTO DIRECTORY FULL ERROR IF NOT
  588.     LHLD    HILOAD        ;YEP, GET TOP OF BUFR PNTR
  589.     XCHG            ;IN DE
  590.     LHLD    FILBUF        ;GET START OF BUFR ADRS
  591.     MOV    A,E        ;CALCULATE OUTPUT FILE SIZE
  592.     SUB    L
  593.     MOV    C,A        ;WITH RESULT IN BC
  594.     MOV    A,D
  595.     SBB    H
  596.     MOV    B,A
  597.     MOV    A,B        ;TEST LENGTH
  598.     ORA    C
  599.     JZ    LODERR        ;NOTHING TO WRITE???
  600.     LXI    D,DFCB        ;GET FCB POINTER
  601. WRLP:    PUSH    B        ;SAVE COUNT
  602.     PUSH    D        ;AND FCB POINTER
  603.     XCHG            ;GET MEMORY POINTER TO DE
  604.     LXI    H,128        ;ADD IN SECTOR LENGTH FOR NEXT PASS
  605.     DAD    D
  606.     XTHL            ;SAVE NEXT DMA
  607.     PUSH    H        ;ABOVE FCB
  608.     MVI    C,SDMAF        ;SET TRANSFER ADDRESS
  609.     CALL    BDOS
  610.     POP    D        ;FETCH FCB POINTER
  611.     PUSH    D        ;SAVE IT AGAIN
  612.     MVI    C,WRITEF    ;WRITE A SECTOR
  613.     CALL    BDOS
  614.     ORA    A        ;TEST RESULT
  615.     JNZ    DSKFUL        ;DISK FULL ERROR...
  616.     LHLD    RECCNT        ;NO,INCREMENT COUNT OF RECORDS
  617.     INX    H
  618.     SHLD    RECCNT
  619.     POP    D        ;RESTORE FCB POINTER
  620.     POP    H        ;AND MEMORY WRITE POINTER
  621.     POP    B        ;AND COUNT
  622.     MOV    A,C        ;SUBTRACT 128 (SEC SIZE) FROM COUNT
  623.     SUI    128
  624.     MOV    C,A
  625.     JNC    WRLP        ;JUMP IF SOME LEFT
  626.     MOV    A,B        ;HI-ORDER BORROW
  627.     SUI    1        ;DO IT (CAN'T "DCR B", DOESN'T AFFECT CY)
  628.     MOV    B,A        ;RESTORE
  629.     JNC    WRLP        ;JUMP IF MORE LEFT
  630.     CALL    CLOSFL        ;CLOSE OUTPUT FILE
  631. ;
  632. ; REPORT STATISTICS TO CONSOLE
  633. ;
  634.     CALL    ILPRNT
  635.     DB    'Loaded ',0
  636.     LHLD    BYTCNT        ;PRINT # BYTES
  637.     CALL    DECOUT
  638.     CALL    ILPRNT
  639.     DB    ' bytes (',0
  640.     CALL    HEXOUT
  641.     CALL    ILPRNT
  642.     DB    'H)',0
  643.     CALL    ILPRNT
  644.     DB    ' to file %',0
  645.     LDA    COMFLG        ;DID WE LOAD A COMFILE TOO?
  646.     ORA    A
  647.     JZ    NOTCOM        ;JUMP IF NOT
  648.     CALL    ILPRNT
  649.     DB    CR,LF,'Over a ',0
  650.     LHLD    COMSIZ
  651.     CALL    DECOUT
  652.     CALL    ILPRNT
  653.     DB    ' byte binary file',0
  654. NOTCOM:    CALL    ILPRNT
  655.     DB    CR,LF,'Start address: ',0
  656.     LHLD    LODADR        ;PRINT LOADING ADDRESS
  657.     CALL    HEXOUT
  658.     CALL    ILPRNT
  659.     DB    'H  Ending address: ',0
  660.     LHLD    HIPC        ;PRINT ENDING LOAD ADDRESS
  661.     CALL    HEXOUT
  662.     CALL    ILPRNT
  663.     DB    'H  Bias: ',0
  664.     LHLD    BIAS
  665.     CALL    HEXOUT
  666.     CALL    ILPRNT
  667.     DB    'H',CR,LF,0
  668.     CALL    ILPRNT
  669.     DB    'Saved image size: ',0
  670.     LHLD    RECCNT        ;GET COUNT OF IMAGE RECORDS
  671.     PUSH    H        ;SAVE IT
  672.     MVI    B,7        ;CONVERT TO BYTES
  673. XLP:    DAD    H
  674.     DCR    B
  675.     JNZ    XLP
  676.     CALL    DECOUT        ;PRINT IT
  677.     CALL    ILPRNT
  678.     DB    ' bytes (',0
  679.     CALL    HEXOUT        ;NOW IN HEX
  680.     CALL    ILPRNT
  681.     DB    'H, - ',0
  682.     POP    H        ;RECALL RECORD COUNT
  683.     CALL    DECOUT        ;PRINT IT
  684.     CALL    ILPRNT
  685.     DB    ' records)',CR,LF,0
  686.     LHLD    LODADR        ;FETCH LOADING ADDRESS
  687.     MOV    A,L        ;TEST IF =TPA
  688.     ORA    A
  689.     JNZ    NOTTPA        ;TPA ALWAYS ON PAGE BOUNDARY
  690.     MOV    A,H        ;LO OK, TEST HI
  691.     CPI    (TPA SHR 8) AND 0FFH
  692.     RZ            ;RETURN IF TPA
  693. NOTTPA:    CALL    ILPRNT        ;NOT, SO PRINT WARNING MSG
  694.     DB    CR,LF,BEL
  695.     DB    '++ Warning: program origin NOT at 100H ++'
  696.     DB    CR,LF,0
  697.     RET            ;DONE
  698. ;
  699. ;    ***********************
  700. ;    * UTILITY SUBROUTINES *
  701. ;    ***********************
  702. ;
  703. ;
  704. ; ROUTINE TO CLOSE ANY OPEN FILE
  705. ;
  706. CLOSFL:    LXI    D,DFCB
  707.     MVI    C,CLOSEF
  708.     CALL    BDOS
  709.     INR    A        ;TEST CLOSE RESULT
  710.     JZ    CLSERR        ;JUMP IF ERROR
  711.     RET
  712. ;
  713. ; PRINT MESSAGE IN-LINE WITH CODE
  714. ;
  715. ILPRNT:    XTHL            ;MESSAGE PNTR TO HL
  716.     CALL    PRATHL        ;PRINT IT
  717.     XTHL            ;RESTORE AND RETURN
  718.     RET
  719. ;
  720. ; PRINT MSG POINTED TO BY HL UNTIL NULL.  EXPAND
  721. ; '%' CHAR TO CURRENT FILENAME.
  722. ;
  723. PRATHL:    MOV    A,M        ;FETCH CHAR
  724.     INX    H        ;POINT TO NEXT
  725.     ORA    A        ;TERMINATOR?
  726.     RZ            ;THEN DONE
  727.     CPI    '%'        ;WANT FILENAME?
  728.     JZ    PRTFN        ;GO DO IT IF SO
  729.     CALL    TYPE        ;NOPE, JUST PRINT CHAR
  730.     JMP    PRATHL        ;CONTINUE
  731. ;
  732. PRTFN:    PUSH    H        ;SAVE POINTER
  733.     PUSH    B
  734.     LDA    DFCB        ;FETCH DR FIELD OF DFCB
  735.     ORA    A        ;DEFAULT DRIVE?
  736.     JNZ    PRNDF        ;JUMP IF NOT
  737.     CALL    GETDSK        ;GET LOGGED-IN DRIVE #
  738.     INR    A        ;MAKE IT ONE-RELATIVE (AS IN FCB)
  739. PRNDF:    ADI    'A'-1        ;MAKE DRIVE NAME PRINTABLE
  740.     CALL    TYPE        ;PRINT IT
  741.     LDA    DFCB-1        ;GET USER #
  742.     CPI    0FFH        ;NULL?
  743.     CZ    GETUSR        ;IFF SO, GET CURRENT USER    
  744.     MOV    L,A        ;TO HL
  745.     MVI    H,0
  746.     CALL    DECOUT        ;PRINT IT
  747.     MVI    A,':'        ;DRIVE NAMES FOLLOWED BY COLON
  748.     CALL    TYPE
  749.     LXI    H,DFCB+1    ;SETUP FOR NAME
  750.     MVI    B,8        ;PRINT UP TO 8
  751.     CALL    PRTNAM
  752.     MVI    A,'.'        ;PRINT DOT
  753.     CALL    TYPE
  754.     MVI    B,3        ;PRINT FILETYPE FIELD
  755.     CALL    PRTNAM
  756.     POP    B
  757.     POP    H        ;RESTORE AND CONTINUE
  758.     JMP    PRATHL
  759. ;
  760. ; PRINT FILE NAME @HL MAX LENGTH IN B.  DON'T PRINT SPACES
  761. ;
  762. PRTNAM:    MOV    A,M        ;FETCH A CHAR
  763.     CPI    ' '        ;BLANK?
  764.     JZ    PWIND        ;GO WIND IF SO
  765.     INX    H        ;NOPE, MOVE TO NEXT
  766.     CALL    TYPE        ;PRINT IT
  767.     DCR    B        ;COUNT DOWN
  768.     JNZ    PRTNAM        ;CONTINUE
  769.     RET
  770. PWIND:    INX    H        ;SKIP REMAINDER OF BLANK NAME
  771.     DCR    B
  772.     JNZ    PWIND
  773.     RET
  774. ;
  775. ; PRINT HL IN DECIMAL ON CONSOLE
  776. ;
  777. DECOUT:    PUSH    H        ;SAVE EVERYBODY
  778.     PUSH    D
  779.     PUSH    B
  780.     LXI    B,-10        ;CONVERSION RADIX
  781.     LXI    D,-1
  782. DECLP:    DAD    B
  783.     INX    D
  784.     JC    DECLP
  785.     LXI    B,10
  786.     DAD    B
  787.     XCHG
  788.     MOV    A,H
  789.     ORA    L
  790.     CNZ    DECOUT        ;THIS IS RECURSIVE
  791.     MOV    A,E
  792.     ADI    '0'
  793.     CALL    TYPE
  794.     POP    B
  795.     POP    D
  796.     POP    H
  797.     RET
  798. ;
  799. ; NEWLINE ON CONSOLE
  800. ;
  801. CRLF:    MVI    A,CR
  802.     CALL    TYPE
  803.     MVI    A,LF
  804.     JMP    TYPE
  805. ;
  806. ; PRINT HL ON CONSOLE IN HEX
  807. ;
  808. HEXOUT:    MOV    A,H        ;GET HI
  809.     CALL    HEXBYT        ;PRINT IT
  810.     MOV    A,L        ;GET LO, FALL INTO HEXBYT
  811. ;
  812. ; TYPE ACCUMULATOR ON CONSOLE IN HEX
  813. ;
  814. HEXBYT: PUSH    PSW        ;SAVE BYTE
  815.     RAR            ;GET MS NYBBLE..
  816.     RAR            ;..INTO LO 4 BITS
  817.     RAR
  818.     RAR
  819.     CALL    NYBBLE
  820.     POP    PSW        ;GET BACK BYTE
  821. NYBBLE:    ANI    0FH        ;MASK MS NYBBLE
  822.     ADI    90H        ;ADD OFFSET
  823.     DAA            ;DECIMAL ADJUST A-REG
  824.     ACI    40H        ;ADD OFFSET
  825.     DAA            ;FALL INTO TYPE
  826. ;
  827. ; TYPE CHAR IN A ON CONSOLE
  828. ;
  829. TYPE:    PUSH    H        ;SAVE ALL
  830.     PUSH    D
  831.     PUSH    B
  832.     MOV    E,A        ;CP/M OUTPUTS FROM E
  833.     MVI    C,PCHARF
  834.     CALL    BDOS
  835.     POP    B
  836.     POP    D
  837.     POP    H
  838.     RET
  839. ;
  840. ; MOVE: FROM @HL TO @DE, COUNT IN B
  841. ;
  842. MOVE:    INR    B        ;UP ONE
  843. MOVLP:    DCR    B        ;COUNT DOWN
  844.     RZ            ;RETURN IF DONE
  845.     MOV    A,M        ;NOT DONE, CONTINUE
  846.     STAX    D
  847.     INX    H        ;POINTERS=POINTERS+1
  848.     INX    D
  849.     JMP    MOVLP
  850. ;
  851. ; SCAN TO FIRST NON-BLANK CHAR IN STRING @HL
  852. ;
  853. SCANBK:    INX    H        ;NEXT
  854.     MOV    A,M        ;FETCH IT
  855.     CPI    ' '
  856.     JZ    SCANBK
  857.     RET
  858. ;
  859. ; GET HEX DIGIT AND VALIDATE
  860. ;
  861. HEXVAL:    CALL    HEXDIG        ;GET HEX DIGIT
  862.     JC    FORMERR        ;JUMP IF BAD
  863.     RET
  864. ;
  865. ; GET HEX DIGIT, RETURN CY=1 IF BAD DIGIT
  866. ;
  867. HEXDIG:    CPI    '0'        ;LO BOUNDARY TEST
  868.     RC            ;BAD ALREADY?
  869.     CPI    '9'+1        ;NO, TEST HI
  870.     JC    HEXCVT        ;JUMP IF NUMERIC
  871.     CPI    'A'        ;TEST ALPHA
  872.     RC            ;BAD?
  873.     CPI    'F'+1        ;NO, UPPER ALPHA BOUND
  874.     CMC            ;PERVERT CARRY
  875.     RC            ;BAD?
  876.     SUI    7        ;NO, ADJUST TO 0-F
  877. HEXCVT:    ANI    0FH        ;MAKE IT BINARY
  878.     RET
  879. ;
  880. ;    ******************
  881. ;    * ERROR HANDLERS *
  882. ;    ******************
  883. ;
  884. SYNERR:    CALL    CRLF
  885.     CALL    ILPRNT
  886.     DB    '      Command line syntax error',CR,LF,CR,LF,0
  887.     JMP    HELP        ;GIVE HELP MSG TOO
  888. ;
  889. AFNERR:    CALL    ERRXIT        ;EXIT WITH MESSAGE
  890.     DB    'Ambiguous file name: % not allowed.',0
  891. ;
  892. FNFERR:    CALL    ERRXIT
  893.     DB    'File % not found.',0
  894. ;
  895. DSKFUL:    CALL    ERRXIT
  896.     DB    'Disk full.',0
  897. ;
  898. DIRFUL:    CALL    ERRXIT
  899.     DB    'Directory full.',0
  900. ;
  901. EOFERR:    CALL    ERRXIT
  902.     DB    'Premature end-of-file in %',0
  903. ;
  904. CSERR:    CALL    ERRXIT
  905.     DB    'Checksum error in %',0
  906. ;
  907. CLSERR:    CALL    ERRXIT
  908.     DB    'Can''t close %',0
  909. ;
  910. MEMFUL:    CALL    ERRXIT
  911.     DB    'Memory full while loading %',0
  912. ;
  913. FORMERR:CALL    ERRXIT
  914.     DB    'Format error in file %',0
  915. ;
  916. LODERR:    CALL    ERRXIT
  917.     DB    'Writing %, nothing loaded',0
  918. ;
  919. HELP:    CALL    ERRXIT        ;PRINT HELP TEXT
  920.     DB    'MLOAD syntax:',CR,LF,CR,LF
  921.     DB    'MLOAD [<OUTFIL>=] <FILE1>[,<FILE2>...] [<BIAS>]',CR,LF
  922.     DB    TAB,'    (brackets denote optional items)',CR,LF,CR,LF
  923.     DB    TAB,'<OUTFIL> is the optional output filename',CR,LF
  924.     DB    TAB,'<FILEn>  are input file(s)',CR,LF
  925.     DB    TAB,'<BIAS>   is a hex load offset within the output file'
  926.     DB    CR,LF,CR,LF
  927.     DB    TAB,'<FILE1> may be an optional non-HEX file to be patched',CR,LF
  928.     DB    TAB,'by subsequently named HEX files (specifying',CR,LF
  929.     DB    TAB,'The filetype enables this function).'
  930.     DB    CR,LF,CR,LF
  931.     DB    'Note that ZCPR2-style drive/user notation may be used in all'
  932.     DB    CR,LF
  933.     DB    'file specifications (e.g., "B3:MYFILE.COM, "A14:MDM7.HEX").'
  934.     DB    CR,LF,0
  935. ;
  936. ; GENERAL ERROR HANDLER
  937. ;
  938. ERRXIT:    CALL    CRLF        ;NEW LINE
  939.     POP    H        ;FETCH ERROR MSG POINTER
  940.     CALL    PRATHL        ;PRINT IT
  941.     CALL    CRLF
  942.     JMP    EXIT        ;DONE
  943. ; 
  944. ; INITIALIZE LOAD PARAMETERS
  945. ;
  946. LODNIT:    MVI    A,1        ;FIRST RECORD, SET LOAD FLAG
  947.     STA    LODFLG
  948.     SHLD    LODADR        ;SAVE LOAD ADDRESS
  949.     SHLD    HIPC        ;AND HI LOAD
  950.     PUSH    D        ;SAVE RECORD LENGTH
  951.     XCHG            ;DE=LOAD ADDRESS
  952.     LHLD    FILBUF        ;GET ADDRESS OF FILE BUFFER
  953.     MOV    A,L        ;SUBTRACT LOAD ADRS FROM FILE BUFFER
  954.     SUB    E
  955.     MOV    L,A
  956.     MOV    A,H
  957.     SBB    D
  958.     MOV    H,A
  959.     SHLD    OFFSET        ;SAVE AS LOAD OFFSET
  960.     PUSH    D        ;SAVE LOAD ADDRESS ON STACK
  961.     PUSH    B        ;SAVE BIAS
  962.     LXI    D,OUTNAM+2    ;CHECK OUTPUT FILENAME
  963.     LDAX    D        ;(FIRST CHAR)
  964.     CPI    ' '
  965.     JNZ    NAMSKP        ;JUMP IF SO
  966.     LXI    H,DFCB+1    ;GET FIRST NAME POINTER
  967.     MVI    B,8        ;(DON'T INCLUDE DRIVE SPEC)
  968.     CALL    MOVE
  969. ;
  970. ; CHECK FOR OUTFLG=1 (PRESENCE OF AN "=").  NOTE THAT THE
  971. ; FILENAME MAY WELL BE BLANK, AND YET OUTFLG <>0, FOR EXAMPLE
  972. ; IN THE CASE OF "A:=<FILENAME>" OR "C4:=<FILENAME>". IN 
  973. ; THIS CASE, WE WANT TO REMEMBER THE DRIVE/USER SPECIFIED, BUT
  974. ; USE THE FIRST INPUT FILE TO FORM THE OUTPUT NAME. OTHERWISE,
  975. ; WE USE THE CURRENT DRIVE/USER.
  976. ;
  977.     LDA    OUTFLG        ;WAS THERE AN "="?
  978.     ORA    A
  979.     JNZ    NAMSKP        ;JUMP IF SO
  980.     LXI    H,OUTNAM    ;GET DESTINATION POINTER
  981.     CALL    GETUSR        ;GET CURRENT USER #
  982.     MOV    M,A
  983.     INX    H        ;POINT TO DRIVE
  984.     CALL    GETDSK        ;GET IT
  985.     INR    A        ;FCB'S DRIVE IS 1-RELATIVE
  986.     MOV    M,A
  987. NAMSKP:    MVI    A,1        ;INSURE "=" CANNOT OCCUR ANYMORE
  988.     STA    OUTFLG
  989.     POP    B        ;RESTORE BIAS
  990.     POP    H        ;LOAD ADDRESS TO HL
  991.     POP    D        ;RESTORE RECORD LENGTH
  992.     RET
  993. ;
  994. ;    *********************************
  995. ;    * FILE NAME PARSING SUBROUTINES *
  996. ;    *********************************
  997. ;
  998. ; CREDIT WHERE CREDIT'S DUE:
  999. ; --------------------------
  1000. ; THESE ROUTINES WERE LIFTED FROM BOB VAN VALZAH'S
  1001. ; "FAST" PROGRAM.
  1002. ;
  1003. ; 
  1004. ;
  1005. ;    *********************************
  1006. ;    * FILE NAME PARSING SUBROUTINES *
  1007. ;    *********************************
  1008. ;
  1009. ;
  1010. ; GETFN GETS A FILE NAME FROM TEXT POINTED TO BY REG HL INTO
  1011. ; AN FCB POINTED TO BY REG DE.    LEADING DELIMETERS ARE 
  1012. ; IGNORED. ALLOWS DRIVE SPEC OF THE FORM <DU:> (DRIVE/USER).
  1013. ; THIS ROUTINE FORMATS ALL 33 BYTES OF THE FCB (BUT NOT RAN REC).
  1014. ;
  1015. ; ENTRY DE    FIRST BYTE OF FCB
  1016. ; EXIT B=# OF '?' IN NAME
  1017. ; FCB-1= USER # PARSED (IF SPECIFIED) OR 255
  1018. ;
  1019. ;
  1020. FPARSE:    CALL    NITFCB        ;INIT 1ST HALF OF FCB
  1021.     CALL    GSTART        ;SCAN TO FIRST CHARACTER OF NAME
  1022.     CALL    GETDRV        ;GET DRIVE/USER SPEC. IF PRESENT
  1023.      MOV    A,B        ;GET USER # OR 255
  1024.     CPI    0FFH        ;255?
  1025.     JZ    FPARS1        ;JUMP IF SO
  1026.     DCX    D        ;BACK UP TO BYTE PRECEEDING FCB
  1027.     DCX    D
  1028.     STAX    D        ;STUFF USER #
  1029.     INX    D        ;ONWARD
  1030.     INX    D
  1031. FPARS1:    CALL    GETPS        ;GET PRIMARY AND SECONDARY NAME
  1032.     RET
  1033. ;
  1034. ; NITFCB FILLS THE FCB WITH DFLT INFO - 0 IN DRIVE FIELD
  1035. ; ALL-BLANK IN NAME FIELD, AND 0 IN EX,S1,S2,RC, DISK
  1036. ; ALLOCATION MAP, AND RANDOM RECORD # FIELDS
  1037. ;
  1038. NITFCB:    PUSH    H
  1039.     PUSH    D
  1040.     CALL    GETUSR        ;INIT USER FIELD
  1041.     POP    D
  1042.     POP    H
  1043.     PUSH    D        ;SAVE FCB LOC
  1044.     DCX    D
  1045.     STAX    D        ;INIT USER # TO CURRNT USER #
  1046.     INX    D
  1047.     XCHG            ;MOVE IT TO HL
  1048.     MVI    M,0        ;DRIVE=DEFAULT
  1049.     INX    H        ;BUMP TO NAME FIELD
  1050.     MVI    B,11        ;ZAP ALL OF NAME FLD
  1051. NITLP:    MVI    M,' '
  1052.     INX    H
  1053.     DCR    B
  1054.     JNZ    NITLP
  1055.     MVI    B,33-11        ;ZERO OTHERS, UP TO NR FIELD
  1056. ZLP:    MVI    M,0
  1057.     INX    H
  1058.     DCR    B
  1059.     JNZ    ZLP
  1060.     XCHG            ;RESTORE HL
  1061.     POP    D        ;RESTORE FCB POINTER
  1062.     RET
  1063. ;
  1064. ; GSTART ADVANCES THE TEXT POINTER (REG HL) TO THE FIRST
  1065. ; NON DELIMITER CHARACTER (I.E. IGNORES BLANKS).  RETURNS A
  1066. ; FLAG IF END OF LINE (00H OR ';') IS FOUND WHILE SCANING.
  1067. ; EXIT    HL    POINTING TO FIRST NON DELIMITER
  1068. ;    A    CLOBBERED
  1069. ;    ZERO    SET IF END OF LINE WAS FOUND
  1070. ;
  1071. GSTART: CALL    GETCH        ;SEE IF POINTING TO DELIM?
  1072.     RNZ            ;NOPE - RETURN
  1073.     ORA    A        ;PHYSICAL END?
  1074.     RZ            ;YES - RETURN W/FLAG
  1075.     INX    H        ;NOPE - MOVE OVER IT
  1076.     JMP    GSTART         ;AND TRY NEXT CHAR
  1077. ;
  1078. ; GETDRV CHECKS FOR THE PRESENCE OF A DU: SPEC AT THE TEXT
  1079. ; POINTER, AND IF PRESENT FORMATS DRIVE INTO FCB AND RETURNS
  1080. ; USER # IN B.
  1081. ;
  1082. ; ENTRY HL    TEXT POINTER
  1083. ;    DE    POINTER TO FIRST BYTE OF FCB
  1084. ; EXIT    HL    POSSIBLY UPDATED TEXT POINTER
  1085. ;    DE    POINTER TO SECOND (PRIMARY NAME) BYTE OF FCB
  1086. ;    B    USER # IF SPECIFIED OR 0FFH
  1087. ;
  1088. GETDRV:    MVI    B,0FFH        ;DEFAULT NO USER #
  1089.     PUSH    H        ;SAVE TEXT POINTER
  1090. DSCAN:    CALL    GETCH        ;GET NEXT CHAR
  1091.     INX    H        ;SKIP POINTER OVER IT
  1092.     JNZ    DSCAN        ;SCAN UNTIL DELIMITER
  1093.     CPI    ':'        ;DELIMITER A COLON?
  1094.     INX    D        ;SKIP DR FIELD IN FCB IN CASE NOT
  1095.     POP    H        ;AND RESTORE TEXT POINTER
  1096.     RNZ            ;RETURN IF NO DU: SPEC
  1097.     MOV    A,M        ;GOT ONE, GET FIRST CHAR
  1098.     CALL    CVTUC        ;MAY BE DRIVE NAME, CVT TO UPPER CASE
  1099.     CPI    'A'        ;ALPHA?
  1100.     JC    ISNUM        ;JUMP TO GET USER # IF NOT
  1101.     SUI    'A'-1        ;YES, CONVERT FROM ASCII TO #
  1102.     DCX    D        ;BACK UP FCB POINTER TO DR FIELD
  1103.     STAX    D        ;STORE DRIVE # INTO FCB
  1104.     INX    D        ;PASS POINTER OVER DRV
  1105.     INX    H        ;SKIP DRIVE SPEC IN TEXT
  1106. ISNUM:    MOV    A,M        ;FETCH NEXT
  1107.     INX    H
  1108.            CPI    ':'        ;DU DELIMITER?
  1109.     RZ            ;DONE THEN
  1110.     DCX    H        ;NOPE, BACK UP TEXT POINTER
  1111.     MVI    B,0        ;GOT A DIGIT, INIT USER VALUE
  1112. ULOOP:    MOV    A,B        ;GET ACCUMULATED USER #
  1113.     ADD    A        ;* 10 FOR NEW DIGIT
  1114.     ADD    A
  1115.     ADD    B
  1116.     ADD    A
  1117.     MOV    B,A        ;BACK TO B
  1118.     MOV    A,M        ;GET TEXT CHAR
  1119.     SUI    '0'        ;MAKE BINARY
  1120.     ADD    B        ;ADD TO USER #
  1121.     MOV    B,A        ;UPDATED USER #
  1122.     INX    H        ;SKIP OVER IT
  1123.     MOV    A,M        ;GET NEXT
  1124.     CPI    ':'        ;END OF SPEC?
  1125.     JNZ    ULOOP        ;JUMP IF NOT
  1126.     INX    H        ;YEP, RETURN TXT POINTER PAST DU:
  1127.     RET
  1128. ;
  1129. ; GETPS GETS THE PRIMARY AND SECONDARY NAMES INTO THE FCB.
  1130. ; ENTRY HL    TEXT POINTER
  1131. ; EXIT    HL    CHARACTER FOLLOWING SECONDARY NAME (IF PRESENT)
  1132. ;
  1133. GETPS:    MVI    C,8        ;MAX LENGTH OF PRIMARY NAME
  1134.     MVI    B,0        ;INIT COUNT OF '?'
  1135.     CALL    GETNAM        ;PACK PRIMARY NAME INTO FCB
  1136.     MOV    A,M        ;SEE IF TERMINATED BY A PERIOD
  1137.     CPI    '.'
  1138.     RNZ            ;NOPE - SECONDARY NAME NOT GIVEN
  1139.                 ;RETURN DEFAULT (BLANKS)
  1140.     INX    H        ;YUP - MOVE TEXT POINTER OVER PERIOD
  1141. FTPOINT:MOV    A,C        ;YUP - UPDATE FCB POINTER TO SECONDARY
  1142.     ORA    A
  1143.     JZ    GETFT
  1144.     INX    D
  1145.     DCR    C
  1146.     JMP    FTPOINT
  1147. GETFT:    MVI    C,3        ;MAX LENGTH OF SECONDARY NAME
  1148.     CALL    GETNAM        ;PACK SECONDARY NAME INTO FCB
  1149.     RET
  1150. ;
  1151. ; GETNAM COPIES A NAME FROM THE TEXT POINTER INTO THE FCB FOR
  1152. ; A GIVEN MAXIMUM LENGTH OR UNTIL A DELIMITER IS FOUND, WHICH
  1153. ; EVER OCCURS FIRST.  IF MORE THAN THE MAXIMUM NUMBER OF
  1154. ; CHARACTERS IS PRESENT, CHARACTER ARE IGNORED UNTIL A
  1155. ; A DELIMITER IS FOUND.
  1156. ; ENTRY HL    FIRST CHARACTER OF NAME TO BE SCANNED
  1157. ;    DE    POINTER INTO FCB NAME FIELD
  1158. ;    C    MAXIMUM LENGTH
  1159. ; EXIT    HL    POINTING TO TERMINATING DELIMITER
  1160. ;    DE    NEXT EMPTY BYTE IN FCB NAME FIELD
  1161. ;    C    MAX LENGTH - NUMBER OF CHARACTERS TRANSFERED
  1162. ;
  1163. GETNAM: CALL    GETCH        ;ARE WE POINTING TO A DELIMITER YET?
  1164.     RZ            ;IF SO, NAME IS TRANSFERED
  1165.     INX    H        ;IF NOT, MOVE OVER CHARACTER
  1166.     CPI    '*'        ;AMBIGIOUS FILE REFERENCE?
  1167.     JZ    AMBIG        ;IF SO, FILL THE REST OF FIELD WITH '?'
  1168.     CPI    '?'        ;AFN REFERENCE?
  1169.     JNZ    NOTQM        ;SKIP IF NOT
  1170.     INR    B        ;ELSE BUMP AFN COUNT
  1171. NOTQM:    CALL    CVTUC        ;IF NOT, CONVERT TO UPPER CASE
  1172.     STAX    D        ;AND COPY INTO NAME FIELD
  1173.     INX    D        ;INCREMENT NAME FIELD POINTER
  1174.     DCR    C        ;IF NAME FIELD FULL?
  1175.     JNZ    GETNAM        ;NOPE - KEEP FILLING
  1176.     JMP    GETDEL        ;YUP - IGNORE UNTIL DELIMITER
  1177. AMBIG:    MVI    A,'?'        ;FILL CHARACTER FOR WILD CARD MATCH
  1178. FILLQ:    STAX    D        ;FILL UNTIL FIELD IS FULL
  1179.     INX    D
  1180.     INR    B        ;INCREMENT COUNT OF '?'
  1181.     DCR    C
  1182.     JNZ    FILLQ        ;FALL THRU TO INGORE REST OF NAME
  1183. GETDEL: CALL    GETCH        ;POINTING TO A DELIMITER?
  1184.     RZ            ;YUP - ALL DONE
  1185.     INX    H        ;NOPE - IGNORE ANTOHER ONE
  1186.     JMP    GETDEL
  1187. ;
  1188. ; GETCH GETS THE CHARACTER POINTED TO BY THE TEXT POINTER
  1189. ; AND SETS THE ZERO FLAG IF IT IS A DELIMITER.
  1190. ; ENTRY HL    TEXT POINTER
  1191. ; EXIT    HL    PRESERVED
  1192. ;    A    CHARACTER AT TEXT POINTER
  1193. ;    Z    SET IF A DELIMITER
  1194. ;
  1195. GETCH:    MOV    A,M        ;GET THE CHARACTER, TEST FOR DELIM
  1196. ;
  1197. ; GLOBAL ENTRY: TEST CHAR IN A FOR FILENAME DELIMITER
  1198. ;
  1199. FNDELM:    CPI    '/'
  1200.     RZ
  1201.     CPI    '.'
  1202.     RZ
  1203.     CPI    ','
  1204.     RZ      
  1205.     CPI    ' '
  1206.     RZ
  1207.     CPI    ':'
  1208.     RZ
  1209.     CPI    '='
  1210.     RZ
  1211.     ORA    A        ;SET ZERO FLAG ON END OF TEXT
  1212.     RET
  1213. ;
  1214. ; BDOS ENTRY: PRESERVES BC, DE.  IF SYSTEM CALL IS A FILE
  1215. ;           FUNCTION, THIS ROUTINE LOGS INTO THE DRIVE/
  1216. ;          USER AREA SPECIFIED, THEN LOGS BACK AFTER
  1217. ;          THE CALL.
  1218. ;
  1219. BDOS:    CALL    FILFCK        ;CHECK FOR A FILE FUNCTION
  1220.     JNZ    BDOS1        ;JUMP IF NOT A FILE FUNCTION
  1221.     CALL    GETDU        ;GET DRIVE/USER
  1222.     SHLD    SAVEDU
  1223.     LDAX    D        ;GET FCB'S DRIVE
  1224.     STA    FCBDRV        ;SAVE IT
  1225.     DCR    A        ;MAKE 0-RELATIVE
  1226.     JM    BDOS0        ;IF NOT DEFAULT DRIVE, JUMP
  1227.     MOV    H,A        ;COPY TO H
  1228. BDOS0:    XRA    A        ;SET FCB TO DEFAULT
  1229.     STAX    D
  1230.     DCX    D        ;GET FCB'S USER #
  1231.     LDAX    D
  1232.     MOV    L,A
  1233.     INX    D        ;RESTORE DE
  1234.     CALL    SETDU        ;SET FCB'S USER
  1235. ;
  1236. ; NOTE THAT UNSPECIFIED USER # (VALUE=0FFH) BECOMES
  1237. ; A GETUSR CALL, PREVENTING AMBIGUITY.
  1238. ; 
  1239.     CALL    BDOS1        ;DO USER'S SYSTEM CALL
  1240.     PUSH    PSW        ;SAVE RESULT
  1241.     PUSH    H
  1242.     LDA    FCBDRV        ;RESTORE FCB'S DRIVE
  1243.     STAX    D
  1244.     LHLD    SAVEDU        ;RESTORE PRIOR DRIVE/USER
  1245.     CALL    SETDU
  1246.     POP    H        ;RESTORE BDOS RESULT REGISTERS
  1247.     POP    PSW
  1248.     RET
  1249. ;
  1250. ; LOCAL VARIABLES FOR BDOS REPLACEMENT ROUTINE
  1251. ;
  1252. SAVEDU:    DW    0        ;SAVED DRIVE,USER
  1253. FCBDRV:    DB    0        ;FCB'S DRIVE
  1254. DMADR:    DW    80H        ;CURRENT DMA ADRS
  1255. ;
  1256. BDOS1:    PUSH    D
  1257.     PUSH    B
  1258.     MOV    A,C        ;DOING SETDMA?
  1259.     CPI    SDMAF
  1260.     JNZ    BDOS1A        ;JUMP IF NOT
  1261.     XCHG            ;YEP, KEEP A RECORD OF DMA ADDRESSES
  1262.     SHLD    DMADR
  1263.     XCHG
  1264. BDOS1A:    CALL    SYSTEM
  1265.     POP    B
  1266.     POP    D
  1267.     RET
  1268. ;
  1269. ; GET DRIVE, USER: H=DRV, L=USER
  1270. ;
  1271. GETDU:    PUSH    B        ;DON'T MODIFY BC
  1272.     PUSH    D
  1273.     MVI    C,GSUSER    ;GET USER #
  1274.     MVI    E,0FFH
  1275.     CALL    BDOS1
  1276.     PUSH    PSW        ;SAVE IT
  1277.     MVI    C,GETDRF    ;GET DRIVE
  1278.     CALL    BDOS1
  1279.     MOV    H,A        ;DRIVE RETURNED IN H
  1280.     POP    PSW
  1281.     MOV    L,A        ;USER IN L
  1282.     POP    D
  1283.     POP    B        ;RESTORE CALLER'S BC
  1284.     RET
  1285. ;
  1286. ; SET DRIVE, USER: H=DRV, L=USER
  1287. ;
  1288. SETDU:    PUSH    B        ;DON'T MODIFY BC
  1289.     PUSH    D
  1290.     PUSH    H        ;SAVE INFO
  1291.     MOV    E,H        ;DRIVE TO E
  1292.     MVI    C,SELDF        ;SET IT
  1293.     CALL    BDOS1
  1294.     POP    H        ;RECALL INFO
  1295.     PUSH    H
  1296.     MOV    E,L        ;USER # TO E
  1297.     MVI    C,GSUSER
  1298.     CALL    BDOS1        ;SET IT
  1299.     POP    H
  1300.     POP    D
  1301.     POP    B
  1302.     RET
  1303. ;
  1304. ; CHECK FOR FILE-FUNCTION: OPEN, CLOSE, READ RANDOM, WRITE
  1305. ;    RANDOM, READ SEQUENTIAL, WRITE SEQUENTIAL.
  1306. ;            
  1307. FILFCK:    MOV    A,C        ;GET FUNCTION #
  1308.     CPI    OPENF
  1309.     RZ
  1310.     RC            ;IGNORE LOWER FUNCTION #'S
  1311.     CPI    CLOSEF        ;(THEY'RE NOT FILE-RELATED)
  1312.     RZ
  1313.     CPI    READF
  1314.     RZ
  1315.     CPI    WRITEF
  1316.     RZ
  1317.     CPI    RRAND
  1318.     RZ
  1319.     CPI    WRAND
  1320.     RZ
  1321.     CPI    FSRCHF
  1322.     RZ
  1323.     CPI    FSRCHN
  1324.     RZ
  1325.     CPI    ERASEF
  1326.     RZ
  1327.     CPI    CREATF
  1328.     RZ
  1329.     CPI    FILSZF
  1330.     RZ
  1331.     CPI    SRAND
  1332.     RET
  1333. ;
  1334. ; CONVERT CHAR TO UPPER CASE
  1335. ;
  1336. CVTUC:    CPI    'a'        ;CHECK LO BOUND
  1337.     RC
  1338.     CPI    'z'+1        ;CHECK HI
  1339.     RNC
  1340.     SUI    20H        ;CONVERT
  1341.     RET
  1342. ;
  1343. ; CHECK FOR HEX FILETYPE IN FCB NAME
  1344. ;
  1345. HEXCHK:    PUSH    H
  1346.     PUSH    D
  1347.     PUSH    B
  1348.     MVI    B,3        ;TYPE IS 3 CHARS
  1349.     LXI    D,DFCB+9    ;POINT DE TO TYPE FIELD
  1350.     LXI    H,HEXTYP    ;POINT HL TO "COM"
  1351. HEXLOP:    LDAX    D
  1352.     ANI    7FH        ;IGNORE ATTRIBUTES
  1353.     CMP    M
  1354.     INX    H
  1355.     INX    D
  1356.     JNZ    HEXIT        ;JUMP IF NOT COM
  1357.     DCR    B
  1358.     JNZ    HEXLOP
  1359. HEXIT:    POP    B        ;Z REG HAS RESULT
  1360.     POP    D
  1361.     POP    H
  1362.     RET
  1363. ;
  1364. HEXTYP:    DB    'HEX'
  1365. ;
  1366. ; ROUTINE TO RETURN USER # WITHOUT DISTURBING REGISTERS
  1367. ;
  1368. GETUSR:    PUSH    H
  1369.     PUSH    D
  1370.     PUSH    B
  1371.     MVI    C,GSUSER
  1372.     MVI    E,0FFH
  1373.     CALL    BDOS
  1374.     POP    B
  1375.     POP    D
  1376.     POP    H
  1377.     RET
  1378. ;
  1379. ; ROUTINE TO RETURN DRIVE # WITHOUT DISTURBING REGISTERS
  1380. ;
  1381. GETDSK:    PUSH    H
  1382.     PUSH    D
  1383.     PUSH    B
  1384.     MVI    C,GETDRF
  1385.     CALL    BDOS
  1386.     POP    B
  1387.     POP    D
  1388.     POP    H
  1389.     RET
  1390. ;
  1391. ; THESE ARE THE INITIAL VALUES OF THE VARIABLES, AND
  1392. ; ARE MOVED INTO THE VARIABLES AREA BY THE SETUP ROUTINE.
  1393. ; IF YOU ADD VARIABLES, BE SURE TO ADD THEIR INTIAL VALUE
  1394. ; INTO THIS TABLE IN THE ORDER CORRESPONDING TO THEIR
  1395. ; OCCURANCE IN THE VARIABLES SECTION.
  1396. ;
  1397. VARSET:    DW    0            ;BIAS
  1398.     DW    0            ;HILOAD
  1399.     DW    0            ;HIPC
  1400.     DB    0            ;CKSUM
  1401.     DW    CMDBUF            ;CMDPTR
  1402.     DB    0            ;BUFPTR
  1403.     DB    0            ;LODFLG
  1404.     DW    CMDBUF            ;FILBUF
  1405.     DW    0            ;OFFSET
  1406.     DW    0            ;LODADR
  1407.     DB    0,0,'           '    ;OUTNAM
  1408.     DW    0            ;RECCNT
  1409.     DW    0            ;BYTCNT
  1410.     DB    0            ;COMFLG
  1411.     DW    0            ;COMSIZ
  1412.     DB    0            ;OUTFLG
  1413. ;
  1414. VARLEN    EQU    $-VARSET    ;DEFINE LENGTH OF INIT TABLE
  1415. ;
  1416. ; WORKING VARIABLES
  1417. ;
  1418. VARS    EQU    $        ;DEFINE VARIABLES AREA START
  1419. ;
  1420. BIAS:    DS    2        ;LOAD OFFSET
  1421. HILOAD:    DS    2        ;HIGHEST TRUE LOAD ADDRESS
  1422. HIPC:    DS    2        ;HIGHEST PC
  1423. CKSUM:    DS    1        ;RECORD CHECKSUM
  1424. CMDPTR:    DS    2        ;COMMAND LINE POINTER
  1425. BUFPTR:    DS    1        ;INPUT BUFFER POINTER
  1426. LODFLG:    DS    1        ;SOMETHING-LOADED FLAG
  1427. FILBUF:    DS    2        ;FILE BUFFER LOCATION
  1428. OFFSET:    DS    2        ;LOAD OFFSET INTO BUFFER
  1429. LODADR:    DS    2        ;LOAD ADDRESS
  1430. OUTNAM:    DS    13        ;OUTPUT DRIVE+NAME
  1431. RECCNT:    DS    2        ;OUTPUT FILE RECORD COUNT
  1432. BYTCNT:    DS    2        ;OUTPUT FILE BYTES LOADED  COUNT
  1433. COMFLG:    DS    1        ;FLAGS COM FILE ENCOUNTERED
  1434. COMSIZ:    DS    2        ;SIZE OF A LOADED COM FILE
  1435. OUTFLG:    DS    1        ;FLAGS AN "=" PRESENT IN CMD LINE
  1436. ;
  1437. ; END OF WORKING VARIABLES
  1438. ;
  1439. ;
  1440. ;
  1441. ; STACK STUFF
  1442. ;
  1443. SPSAVE:    DS    2        ;SYSTEM STACK PNTR SAVE
  1444. ;
  1445. ;
  1446.     DS    100        ;50-LEVEL STACK
  1447. ;
  1448. STACK    EQU    $
  1449. CMDBUF    EQU    $        ;COMMAND BUFFER LOCATION
  1450. ;
  1451. ;
  1452.     END
  1453.